qcsrc/server/w_porto.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(PORTO, w_porto, 0, 0, WEP_TYPE_OTHER | WEP_FLAG_SUPERWEAPON, 0, "porto" , "porto", _("Port-O-Launch"))
   3 #else
   4 #ifdef SVQC
   5 .entity porto_current;
   6 .vector porto_v_angle; // holds "held" view angles
   7 .float porto_v_angle_held;
   8 .vector right_vector;
   9
  10 void W_Porto_Success (void)
  11 {
  12         if(self.realowner == world)
  13         {
  14                 objerror("Cannot succeed successfully: no owner\n");
  15                 return;
  16         }
  17
  18         self.realowner.porto_current = world;
  19         remove(self);
  20 }
  21
  22 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  23 void W_Porto_Fail (float failhard)
  24 {
  25         if(self.realowner == world)
  26         {
  27                 objerror("Cannot fail successfully: no owner\n");
  28                 return;
  29         }
  30
  31         // no portals here!
  32         if(self.cnt < 0)
  33         {
  34                 Portal_ClearWithID(self.realowner, self.portal_id);
  35         }
  36
  37         self.realowner.porto_current = world;
  38
  39         if(self.cnt < 0 && !failhard && self.realowner.playerid == self.playerid && self.realowner.deadflag == DEAD_NO && !(self.realowner.weapons & WEPBIT_PORTO))
  40         {
  41                 setsize (self, '-16 -16 0', '16 16 32');
  42                 setorigin(self, self.origin + trace_plane_normal);
  43                 if(move_out_of_solid(self))
  44                 {
  45                         self.flags = FL_ITEM;
  46                         self.velocity = trigger_push_calculatevelocity(self.origin, self.realowner, 128);
  47                         tracetoss(self, self);
  48                         if(vlen(trace_endpos - self.realowner.origin) < 128)
  49                         {
  50                                 W_ThrowNewWeapon(self.realowner, WEP_PORTO, 0, self.origin, self.velocity);
  51                                 centerprint(self.realowner, "^1Portal deployment failed.\n\n^2Catch it to try again!");
  52                         }
  53                 }
  54         }
  55         remove(self);
  56 }
  57
  58 void W_Porto_Remove (entity p)
  59 {
  60         if(p.porto_current.realowner == p && p.porto_current.classname == "porto")
  61         {
  62                 entity oldself;
  63                 oldself = self;
  64                 self = p.porto_current;
  65                 W_Porto_Fail(1);
  66                 self = oldself;
  67         }
  68 }
  69
  70 void W_Porto_Think (void)
  71 {
  72         trace_plane_normal = '0 0 0';
  73         if(self.realowner.playerid != self.playerid)
  74                 remove(self);
  75         else
  76                 W_Porto_Fail(0);
  77 }
  78
  79 void W_Porto_Touch (void)
  80 {
  81         vector norm;
  82
  83         // do not use PROJECTILE_TOUCH here
  84         // FIXME but DO handle warpzones!
  85
  86         if(other.classname == "portal")
  87                 return; // handled by the portal
  88
  89         norm = trace_plane_normal;
  90         if(trace_ent.iscreature)
  91         {
  92                 traceline(trace_ent.origin, trace_ent.origin + '0 0 2' * PL_MIN_z, MOVE_WORLDONLY, self);
  93                 if(trace_fraction >= 1)
  94                         return;
  95                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  96                         return;
  97                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  98                         return;
  99         }
 100
 101         if(self.realowner.playerid != self.playerid)
 102         {
 103                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 104                 remove(self);
 105         }
 106         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 107         {
 108                 spamsound(self, CH_SHOTS, "porto/bounce.wav", VOL_BASE, ATTN_NORM);
 109                 // just reflect
 110                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
 111                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
 112         }
 113         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 114         {
 115                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 116                 W_Porto_Fail(0);
 117                 if(self.cnt < 0)
 118                         Portal_ClearAll_PortalsOnly(self.realowner);
 119         }
 120         else if(self.cnt == 0)
 121         {
 122                 // in-portal only
 123                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 124                 {
 125                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTN_NORM);
 126                         trace_plane_normal = norm;
 127                         centerprint(self.realowner, "^1In^7-portal created.");
 128                         W_Porto_Success();
 129                 }
 130                 else
 131                 {
 132                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 133                         trace_plane_normal = norm;
 134                         W_Porto_Fail(0);
 135                 }
 136         }
 137         else if(self.cnt == 1)
 138         {
 139                 // out-portal only
 140                 if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 141                 {
 142                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTN_NORM);
 143                         trace_plane_normal = norm;
 144                         centerprint(self.realowner, "^1Out^7-portal created.");
 145                         W_Porto_Success();
 146                 }
 147                 else
 148                 {
 149                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 150                         trace_plane_normal = norm;
 151                         W_Porto_Fail(0);
 152                 }
 153         }
 154         else if(self.effects & EF_RED)
 155         {
 156                 self.effects += EF_BLUE - EF_RED;
 157                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 158                 {
 159                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTN_NORM);
 160                         trace_plane_normal = norm;
 161                         centerprint(self.realowner, "^1In^7-portal created.");
 162                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * norm);
 163                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * norm));
 164                         CSQCProjectile(self, TRUE, PROJECTILE_PORTO_BLUE, TRUE); // change type
 165                 }
 166                 else
 167                 {
 168                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 169                         trace_plane_normal = norm;
 170                         Portal_ClearAll_PortalsOnly(self.realowner);
 171                         W_Porto_Fail(0);
 172                 }
 173         }
 174         else
 175         {
 176                 if(self.realowner.portal_in.portal_id == self.portal_id)
 177                 {
 178                         if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 179                         {
 180                                 sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTN_NORM);
 181                                 trace_plane_normal = norm;
 182                                 centerprint(self.realowner, "^4Out^7-portal created.");
 183                                 W_Porto_Success();
 184                         }
 185                         else
 186                         {
 187                                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 188                                 Portal_ClearAll_PortalsOnly(self.realowner);
 189                                 W_Porto_Fail(0);
 190                         }
 191                 }
 192                 else
 193                 {
 194                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 195                         Portal_ClearAll_PortalsOnly(self.realowner);
 196                         W_Porto_Fail(0);
 197                 }
 198         }
 199 }
 200
 201 void W_Porto_Attack (float type)
 202 {
 203         entity gren;
 204
 205         if(type == -1)
 206         {
 207                 if not(self.items & IT_UNLIMITED_SUPERWEAPONS)
 208                         self.weapons = self.weapons - (self.weapons & WEPBIT_PORTO);
 209         }
 210
 211         W_SetupShot (self, FALSE, 4, "porto/fire.wav", CH_WEAPON_A, 0);
 212         // always shoot from the eye
 213         w_shotdir = v_forward;
 214         w_shotorg = self.origin + self.view_ofs + ((w_shotorg - self.origin - self.view_ofs) * v_forward) * v_forward;
 215
 216         //pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 217
 218         gren = spawn ();
 219         gren.cnt = type;
 220         gren.owner = gren.realowner = self;
 221         gren.playerid = self.playerid;
 222         gren.classname = "porto";
 223         gren.bot_dodge = TRUE;
 224         gren.bot_dodgerating = 200;
 225         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 226         PROJECTILE_MAKETRIGGER(gren);
 227         gren.effects = EF_RED;
 228         gren.scale = 4;
 229         setorigin(gren, w_shotorg);
 230         setsize(gren, '0 0 0', '0 0 0');
 231
 232         if(type > 0)
 233                 gren.nextthink = time + autocvar_g_balance_porto_secondary_lifetime;
 234         else
 235                 gren.nextthink = time + autocvar_g_balance_porto_primary_lifetime;
 236         gren.think = W_Porto_Think;
 237         gren.touch = W_Porto_Touch;
 238
 239         if(type > 0)
 240         {
 241                 if(self.items & IT_STRENGTH)
 242                         W_SetupProjectileVelocity(gren, autocvar_g_balance_porto_secondary_speed * autocvar_g_balance_powerup_strength_force, 0);
 243                 else
 244                         W_SetupProjectileVelocity(gren, autocvar_g_balance_porto_secondary_speed, 0);
 245         }
 246         else
 247         {
 248                 if(self.items & IT_STRENGTH)
 249                         W_SetupProjectileVelocity(gren, autocvar_g_balance_porto_primary_speed * autocvar_g_balance_powerup_strength_force, 0);
 250                 else
 251                         W_SetupProjectileVelocity(gren, autocvar_g_balance_porto_primary_speed, 0);
 252         }
 253
 254         gren.angles = vectoangles (gren.velocity);
 255         gren.flags = FL_PROJECTILE;
 256
 257         gren.portal_id = time;
 258         self.porto_current = gren;
 259         gren.playerid = self.playerid;
 260         fixedmakevectors(fixedvectoangles(gren.velocity));
 261         gren.right_vector = v_right;
 262
 263         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 264
 265         if(type > 0)
 266                 CSQCProjectile(gren, TRUE, PROJECTILE_PORTO_BLUE, TRUE);
 267         else
 268                 CSQCProjectile(gren, TRUE, PROJECTILE_PORTO_RED, TRUE);
 269
 270         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 271 }
 272
 273 void spawnfunc_weapon_porto (void)
 274 {
 275         weapon_defaultspawnfunc(WEP_PORTO);
 276 }
 277
 278 float w_nexball_weapon(float req);
 279 float w_porto(float req)
 280 {
 281         vector v_angle_save;
 282
 283         if (g_nexball) { return w_nexball_weapon(req); }
 284         if (req == WR_AIM)
 285         {
 286                 self.BUTTON_ATCK = FALSE;
 287                 self.BUTTON_ATCK2 = FALSE;
 288                 if(!autocvar_g_balance_porto_secondary)
 289                         if(bot_aim(autocvar_g_balance_porto_primary_speed, 0, autocvar_g_balance_grenadelauncher_primary_lifetime, FALSE))
 290                                 self.BUTTON_ATCK = TRUE;
 291         }
 292         else if (req == WR_THINK)
 293         {
 294                 if(autocvar_g_balance_porto_secondary)
 295                 {
 296                         if (self.BUTTON_ATCK)
 297                         if (!self.porto_current)
 298                         if (!self.porto_forbidden)
 299                         if (weapon_prepareattack(0, autocvar_g_balance_porto_primary_refire))
 300                         {
 301                                 W_Porto_Attack(0);
 302                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_porto_primary_animtime, w_ready);
 303                         }
 304
 305                         if (self.BUTTON_ATCK2)
 306                         if (!self.porto_current)
 307                         if (!self.porto_forbidden)
 308                         if (weapon_prepareattack(1, autocvar_g_balance_porto_secondary_refire))
 309                         {
 310                                 W_Porto_Attack(1);
 311                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_porto_secondary_animtime, w_ready);
 312                         }
 313                 }
 314                 else
 315                 {
 316                         if(self.porto_v_angle_held)
 317                         {
 318                                 if(!self.BUTTON_ATCK2)
 319                                 {
 320                                         self.porto_v_angle_held = 0;
 321
 322                                         ClientData_Touch(self);
 323                                 }
 324                         }
 325                         else
 326                         {
 327                                 if(self.BUTTON_ATCK2)
 328                                 {
 329                                         self.porto_v_angle = self.v_angle;
 330                                         self.porto_v_angle_held = 1;
 331
 332                                         ClientData_Touch(self);
 333                                 }
 334                         }
 335                         v_angle_save = self.v_angle;
 336                         if(self.porto_v_angle_held)
 337                                 makevectors(self.porto_v_angle); // override the previously set angles
 338
 339                         if (self.BUTTON_ATCK)
 340                         if (!self.porto_current)
 341                         if (!self.porto_forbidden)
 342                         if (weapon_prepareattack(0, autocvar_g_balance_porto_primary_refire))
 343                         {
 344                                 W_Porto_Attack(-1);
 345                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_porto_primary_animtime, w_ready);
 346                         }
 347                 }
 348         }
 349         else if (req == WR_PRECACHE)
 350         {
 351                 precache_model ("models/weapons/g_porto.md3");
 352                 precache_model ("models/weapons/v_porto.md3");
 353                 precache_model ("models/weapons/h_porto.iqm");
 354                 precache_model ("models/portal.md3");
 355                 precache_sound ("porto/bounce.wav");
 356                 precache_sound ("porto/create.wav");
 357                 precache_sound ("porto/expire.wav");
 358                 precache_sound ("porto/explode.wav");
 359                 precache_sound ("porto/fire.wav");
 360                 precache_sound ("porto/unsupported.wav");
 361         }
 362         else if (req == WR_SETUP)
 363         {
 364                 weapon_setup(WEP_PORTO);
 365                 self.current_ammo = ammo_none;
 366         }
 367         else if (req == WR_RESETPLAYER)
 368         {
 369                 self.porto_current = world;
 370         }
 371         return TRUE;
 372 }
 373 #endif
 374 #ifdef CSQC
 375 float w_porto(float req)
 376 {
 377         if(req == WR_IMPACTEFFECT)
 378         {
 379                 print("Since when does Porto send DamageInfo?\n");
 380         }
 381         else if(req == WR_PRECACHE)
 382         {
 383                 // nothing to do
 384         }
 385         else if (req == WR_SUICIDEMESSAGE)
 386                 w_deathtypestring = _("%s did the impossible");
 387         else if (req == WR_KILLMESSAGE)
 388                 w_deathtypestring = _("%s felt %s doing the impossible to him");
 389         return TRUE;
 390 }
 391 #endif
 392 #endif