fogeval.pl

   1 use strict;
   2 use warnings;
   3
   4 # generates the blendfunc flags function in gl_rmain.c
   5
   6 my %blendfuncs =
   7 (
   8         GL_ONE                 => sub { (1, 1); },
   9         GL_ZERO                => sub { (0, 0); },
  10         GL_SRC_COLOR           => sub { ($_[0], $_[1]); },
  11         GL_ONE_MINUS_SRC_COLOR => sub { (1-$_[0], 1-$_[1]); },
  12         GL_SRC_ALPHA           => sub { ($_[1], $_[1]); },
  13         GL_ONE_MINUS_SRC_ALPHA => sub { (1-$_[1], 1-$_[1]); },
  14         GL_DST_COLOR           => sub { ($_[2], $_[3]); },
  15         GL_ONE_MINUS_DST_COLOR => sub { (1-$_[2], 1-$_[3]); },
  16         GL_DST_ALPHA           => sub { ($_[3], $_[3]); },
  17         GL_ONE_MINUS_DST_ALPHA => sub { (1-$_[3], 1-$_[3]); },
  18 );
  19
  20 sub evalblend($$$$$$)
  21 {
  22         my ($fs, $fd, $s, $sa, $d, $da) = @_;
  23         my @fs = $fs->($s, $sa, $d, $da);
  24         my @fd = $fd->($s, $sa, $d, $da);
  25         return (
  26                 $fs[0] * $s  + $fd[0] * $d,
  27                 $fs[1] * $sa + $fd[1] * $da
  28         );
  29 }
  30
  31 sub isinvariant($$$$)
  32 {
  33         my ($fs, $fd, $s, $sa) = @_;
  34         my ($d, $da) = (0.7823, 0.3289);
  35         my ($out, $outa) = evalblend $fs, $fd, $s, $sa, $d, $da;
  36         return abs($out - $d) < 0.001 && abs($outa - $da) < 0.001;
  37 }
  38
  39 sub isfogfriendly($$$$$)
  40 {
  41         my ($fs, $fd, $s, $sa, $foghack) = @_;
  42         my ($d, $da) = (0.7823, 0.3289);
  43         my $fogamount = 0.3237;
  44         my $fogcolor = 0.8612;
  45
  46         # compare:
  47         # 1. blend(fog(s), sa, fog(d), da)
  48         # 2. fog(blend(s, sa, d, da))
  49
  50         my ($out1, $out1a) = evalblend $fs, $fd, $s + ((defined $foghack ? $foghack eq 'ALPHA' ? $fogcolor*$sa : $foghack : $fogcolor) - $s) * $fogamount, $sa, $d + ($fogcolor - $d) * $fogamount, $da;
  51         my ($out2, $out2a) = evalblend $fs, $fd, $s, $sa, $d, $da;
  52                 $out2 = $out2 + ($fogcolor - $out2) * $fogamount;
  53
  54         return abs($out1 - $out2) < 0.001 && abs($out1a - $out2a) < 0.001;
  55 }
  56
  57 #die isfogfriendly $blendfuncs{GL_ONE}, $blendfuncs{GL_ONE}, 1, 0, 0;
  58 # out1 = 0 + fog($d)
  59 # out2 = fog(1 + $d)
  60
  61 sub willitblend($$)
  62 {
  63         my ($fs, $fd) = @_;
  64         for my $s(0, 0.25, 0.5, 0.75, 1)
  65         {
  66                 for my $sa(0, 0.25, 0.5, 0.75, 1)
  67                 {
  68                         if(isinvariant($fs, $fd, $s, $sa))
  69                         {
  70                                 if(!isinvariant($fs, $fd, 0, $sa))
  71                                 {
  72                                         return 0; # no colormod possible
  73                                 }
  74                         }
  75                 }
  76         }
  77         return 1;
  78 }
  79
  80 sub willitfog($$)
  81 {
  82         my ($fs, $fd) = @_;
  83
  84         FOGHACK:
  85         for my $foghack(undef, 0, 'ALPHA')
  86         {
  87                 for my $s(0, 0.25, 0.5, 0.75, 1)
  88                 {
  89                         for my $sa(0, 0.25, 0.5, 0.75, 1)
  90                         {
  91                                 if(!isfogfriendly($fs, $fd, $s, $sa, $foghack))
  92                                 {
  93                                         next FOGHACK;
  94                                 }
  95                         }
  96                 }
  97                 return (1, $foghack);
  98         }
  99         return (0, undef);
 100 }
 101
 102 print "\tr |= BLENDFUNC_ALLOWS_COLORMOD;\n";
 103 for my $s(sort keys %blendfuncs)
 104 {
 105         for my $d(sort keys %blendfuncs)
 106         {
 107                 if(!willitblend $blendfuncs{$s}, $blendfuncs{$d})
 108                 {
 109                         print "\tif(src == $s && dst == $d) r &= ~BLENDFUNC_ALLOWS_COLORMOD;\n";
 110                 }
 111                 my ($result, $h) = willitfog $blendfuncs{$s}, $blendfuncs{$d};
 112                 if($result)
 113                 {
 114                         if(defined $h)
 115                         {
 116                                 print "\tif(src == $s && dst == $d) r |= BLENDFUNC_ALLOWS_FOG_HACK$h;\n";
 117                         }
 118                         else
 119                         {
 120                                 print "\tif(src == $s && dst == $d) r |= BLENDFUNC_ALLOWS_FOG;\n";
 121                         }
 122                 }
 123         }
 124 }
 125