qcsrc/server/waypointsprites.qc

   1 ..entity owned_by_field;
   2 .float rule;
   3 .string model1;
   4 .string model2;
   5 .string model3;
   6
   7 .float(entity) waypointsprite_visible_for_player;
   8
   9 void WaypointSprite_UpdateSprites(entity e, string m1, string m2, string m3)
  10 {
  11         if(m1 != e.model1)
  12         {
  13                 e.model1 = m1;
  14                 e.SendFlags |= 2;
  15         }
  16         if(m2 != e.model2)
  17         {
  18                 e.model2 = m2;
  19                 e.SendFlags |= 4;
  20         }
  21         if(m3 != e.model3)
  22         {
  23                 e.model3 = m3;
  24                 e.SendFlags |= 8;
  25         }
  26 }
  27
  28 void WaypointSprite_UpdateHealth(entity e, float f)
  29 {
  30         f = bound(0, f, e.max_health);
  31         if(f != e.health || e.pain_finished)
  32         {
  33                 e.health = f;
  34                 e.pain_finished = 0;
  35                 e.SendFlags |= 0x80;
  36         }
  37 }
  38
  39 void WaypointSprite_UpdateMaxHealth(entity e, float f)
  40 {
  41         if(f != e.max_health || e.pain_finished)
  42         {
  43                 e.max_health = f;
  44                 e.pain_finished = 0;
  45                 e.SendFlags |= 0x80;
  46         }
  47 }
  48
  49 void WaypointSprite_UpdateBuildFinished(entity e, float f)
  50 {
  51         if(f != e.pain_finished || e.max_health)
  52         {
  53                 e.max_health = 0;
  54                 e.pain_finished = f;
  55                 e.SendFlags |= 0x80;
  56         }
  57 }
  58
  59 void WaypointSprite_UpdateOrigin(entity e, vector o)
  60 {
  61         if(o != e.origin)
  62         {
  63                 setorigin(e, o);
  64                 e.SendFlags |= 64;
  65         }
  66 }
  67
  68 void WaypointSprite_UpdateRule(entity e, float t, float r)
  69 {
  70         // no check, as this is never called without doing an actual change (usually only once)
  71         e.rule = r;
  72         e.team = t;
  73         e.SendFlags |= 1;
  74 }
  75
  76 void WaypointSprite_UpdateTeamRadar(entity e, float icon, vector col)
  77 {
  78         // no check, as this is never called without doing an actual change (usually only once)
  79         e.cnt = (icon & 0x7F) | (e.cnt & 0x80);
  80         e.colormod = col;
  81         e.SendFlags |= 32;
  82 }
  83
  84 .float waypointsprite_pingtime;
  85 .float waypointsprite_helpmetime;
  86 void WaypointSprite_Ping(entity e)
  87 {
  88         // anti spam
  89         if(time < e.waypointsprite_pingtime)
  90                 return;
  91         e.waypointsprite_pingtime = time + 0.3;
  92         // ALWAYS sends (this causes a radar circle), thus no check
  93         e.cnt |= 0x80;
  94         e.SendFlags |= 32;
  95 }
  96
  97 float waypointsprite_limitedrange, waypointsprite_deployed_lifetime, waypointsprite_deadlifetime;
  98
  99 void WaypointSprite_HelpMePing(entity e)
 100 {
 101         WaypointSprite_Ping(e);
 102         e.waypointsprite_helpmetime = time + waypointsprite_deployed_lifetime;
 103         e.SendFlags |= 32;
 104 }
 105
 106 void WaypointSprite_FadeOutIn(entity e, float t)
 107 {
 108         if(!e.fade_time)
 109         {
 110                 e.fade_time = t;
 111                 e.teleport_time = time + t;
 112         }
 113         else if(t < (e.teleport_time - time))
 114         {
 115                 // accelerate the waypoint's dying
 116                 // ensure:
 117                 //   (e.teleport_time - time) / wp.fade_time stays
 118                 //   e.teleport_time = time + fadetime
 119                 float current_fadetime;
 120                 current_fadetime = e.teleport_time - time;
 121                 e.teleport_time = time + t;
 122                 e.fade_time = e.fade_time * t / current_fadetime;
 123         }
 124
 125         e.SendFlags |= 16;
 126 }
 127
 128 void WaypointSprite_Init()
 129 {
 130         waypointsprite_limitedrange = autocvar_sv_waypointsprite_limitedrange;
 131         waypointsprite_deployed_lifetime = autocvar_sv_waypointsprite_deployed_lifetime;
 132         waypointsprite_deadlifetime = autocvar_sv_waypointsprite_deadlifetime;
 133 }
 134 void WaypointSprite_InitClient(entity e)
 135 {
 136 }
 137
 138 void WaypointSprite_Kill(entity wp)
 139 {
 140         if(!wp)
 141                 return;
 142         if(wp.owner)
 143                 wp.owner.(wp.owned_by_field) = world;
 144         remove(wp);
 145 }
 146
 147 void WaypointSprite_Disown(entity wp, float fadetime)
 148 {
 149         if(!wp)
 150                 return;
 151         if(wp.classname != "sprite_waypoint")
 152         {
 153                 backtrace("Trying to disown a non-waypointsprite");
 154                 return;
 155         }
 156         if(wp.owner)
 157         {
 158                 if(wp.exteriormodeltoclient == wp.owner)
 159                         wp.exteriormodeltoclient = world;
 160                 wp.owner.(wp.owned_by_field) = world;
 161                 wp.owner = world;
 162
 163                 WaypointSprite_FadeOutIn(wp, fadetime);
 164         }
 165 }
 166
 167 void WaypointSprite_Think()
 168 {
 169         float doremove;
 170
 171         doremove = FALSE;
 172
 173         if(self.fade_time)
 174         {
 175                 if(time >= self.teleport_time)
 176                         doremove = TRUE;
 177         }
 178
 179         if(self.exteriormodeltoclient)
 180                 WaypointSprite_UpdateOrigin(self, self.exteriormodeltoclient.origin + self.view_ofs);
 181
 182         if(doremove)
 183                 WaypointSprite_Kill(self);
 184         else
 185                 self.nextthink = time; // WHY?!?
 186 }
 187
 188 float WaypointSprite_visible_for_player(entity e)
 189 {
 190         // personal waypoints
 191         if(self.enemy)
 192                 if(self.enemy != e)
 193                         return FALSE;
 194
 195         // team waypoints
 196         if(self.rule == SPRITERULE_SPECTATOR)
 197         {
 198                 if(!inWarmupStage && e.classname == "player")
 199                         return FALSE;
 200         }
 201         else if(self.team && self.rule == SPRITERULE_DEFAULT)
 202         {
 203                 if(self.team != e.team)
 204                         return FALSE;
 205                 if(e.classname != "player")
 206                         return FALSE;
 207         }
 208
 209         return TRUE;
 210 }
 211
 212 entity WaypointSprite_getviewentity(entity e)
 213 {
 214         if(e.classname == "spectator")
 215                 e = e.enemy;
 216         /* TODO idea (check this breaks nothing)
 217         else if(e.classname == "observer")
 218                 e = world;
 219         */
 220         return e;
 221 }
 222
 223 float WaypointSprite_isteammate(entity e, entity e2)
 224 {
 225         if(teamplay)
 226         {
 227                 if(e2.team != e.team)
 228                         return FALSE;
 229         }
 230         else
 231         {
 232                 if(e2 != e)
 233                         return FALSE;
 234         }
 235         return TRUE;
 236 }
 237
 238 float WaypointSprite_Customize()
 239 {
 240         // this is not in SendEntity because it shall run every frame, not just every update
 241
 242         // make spectators see what the player would see
 243         entity e;
 244         e = WaypointSprite_getviewentity(other);
 245
 246         // as a GENERAL rule:
 247         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 248         // but only apply this to real players, not to spectators
 249         if(g_minstagib && (self.owner.flags & FL_CLIENT) && (self.owner.items & IT_STRENGTH) && (e == other))
 250         {
 251                 if(!WaypointSprite_isteammate(self.owner, e))
 252                         return FALSE;
 253         }
 254
 255         return self.waypointsprite_visible_for_player(e);
 256 }
 257
 258 float WaypointSprite_SendEntity(entity to, float sendflags)
 259 {
 260         float dt;
 261
 262         WriteByte(MSG_ENTITY, ENT_CLIENT_WAYPOINT);
 263
 264         sendflags = sendflags & 0x7F;
 265
 266         if(g_nexball)
 267                 sendflags &~= 0x80;
 268         else if(self.max_health || (self.pain_finished && (time < self.pain_finished + 0.25)))
 269                 sendflags |= 0x80;
 270
 271         WriteByte(MSG_ENTITY, sendflags);
 272
 273         if(sendflags & 0x80)
 274         {
 275                 if(self.max_health)
 276                 {
 277                         WriteByte(MSG_ENTITY, (self.health / self.max_health) * 191.0);
 278                 }
 279                 else
 280                 {
 281                         dt = self.pain_finished - time;
 282                         dt = bound(0, dt * 32, 16383);
 283                         WriteByte(MSG_ENTITY, (dt & 0xFF00) / 256 + 192);
 284                         WriteByte(MSG_ENTITY, (dt & 0x00FF));
 285                 }
 286         }
 287
 288         if(sendflags & 64)
 289         {
 290                 WriteCoord(MSG_ENTITY, self.origin_x);
 291                 WriteCoord(MSG_ENTITY, self.origin_y);
 292                 WriteCoord(MSG_ENTITY, self.origin_z);
 293         }
 294
 295         if(sendflags & 1)
 296         {
 297                 WriteByte(MSG_ENTITY, self.team);
 298                 WriteByte(MSG_ENTITY, self.rule);
 299         }
 300
 301         if(sendflags & 2)
 302                 WriteString(MSG_ENTITY, self.model1);
 303
 304         if(sendflags & 4)
 305                 WriteString(MSG_ENTITY, self.model2);
 306
 307         if(sendflags & 8)
 308                 WriteString(MSG_ENTITY, self.model3);
 309
 310         if(sendflags & 16)
 311         {
 312                 WriteCoord(MSG_ENTITY, self.fade_time);
 313                 WriteCoord(MSG_ENTITY, self.teleport_time);
 314                 WriteShort(MSG_ENTITY, self.fade_rate); // maxdist
 315                 float f;
 316                 f = 0;
 317                 if(self.currentammo)
 318                         f |= 1; // hideable
 319                 if(self.exteriormodeltoclient == to)
 320                         f |= 2; // my own
 321                 WriteByte(MSG_ENTITY, f);
 322         }
 323
 324         if(sendflags & 32)
 325         {
 326                 WriteByte(MSG_ENTITY, self.cnt); // icon on radar
 327                 WriteByte(MSG_ENTITY, self.colormod_x * 255.0);
 328                 WriteByte(MSG_ENTITY, self.colormod_y * 255.0);
 329                 WriteByte(MSG_ENTITY, self.colormod_z * 255.0);
 330
 331                 if(WaypointSprite_isteammate(self.owner, WaypointSprite_getviewentity(to)))
 332                 {
 333                         dt = (self.waypointsprite_helpmetime - time) / 0.1;
 334                         if(dt < 0)
 335                                 dt = 0;
 336                         if(dt > 255)
 337                                 dt = 255;
 338                         WriteByte(MSG_ENTITY, dt);
 339                 }
 340                 else
 341                         WriteByte(MSG_ENTITY, 0);
 342         }
 343
 344         return TRUE;
 345 }
 346
 347 void WaypointSprite_Reset()
 348 {
 349         // if a WP wants to time out, let it time out immediately; other WPs ought to be reset/killed by their owners
 350
 351         if(self.fade_time) // there was there before: || g_keyhunt, do we really need this?
 352                 WaypointSprite_Kill(self);
 353 }
 354
 355 entity WaypointSprite_Spawn(
 356         string spr, // sprite
 357         float lifetime, float maxdistance, // lifetime, max distance
 358         entity ref, vector ofs, // position
 359         entity showto, float t, // show to whom? Use a flag to indicate a team
 360         entity own, .entity ownfield, // remove when own gets killed
 361         float hideable, // true when it should be controlled by cl_hidewaypoints
 362         float icon, vector rgb // initial icon and color
 363 )
 364 {
 365         entity wp;
 366         wp = spawn();
 367         wp.classname = "sprite_waypoint";
 368         wp.teleport_time = time + lifetime;
 369         wp.fade_time = lifetime;
 370         wp.exteriormodeltoclient = ref;
 371         if(ref)
 372         {
 373                 wp.view_ofs = ofs;
 374                 setorigin(wp, ref.origin + ofs);
 375         }
 376         else
 377                 setorigin(wp, ofs);
 378         wp.enemy = showto;
 379         wp.team = t;
 380         wp.owner = own;
 381         wp.currentammo = hideable;
 382         if(own)
 383         {
 384                 if(own.ownfield)
 385                         remove(own.ownfield);
 386                 own.ownfield = wp;
 387                 wp.owned_by_field = ownfield;
 388         }
 389         wp.fade_rate = maxdistance;
 390         wp.think = WaypointSprite_Think;
 391         wp.nextthink = time;
 392         wp.model1 = spr;
 393         wp.customizeentityforclient = WaypointSprite_Customize;
 394         wp.waypointsprite_visible_for_player = WaypointSprite_visible_for_player;
 395         wp.reset2 = WaypointSprite_Reset;
 396         wp.cnt = icon;
 397         wp.colormod = rgb;
 398         Net_LinkEntity(wp, FALSE, 0, WaypointSprite_SendEntity);
 399         return wp;
 400 }
 401
 402 entity WaypointSprite_SpawnFixed(
 403         string spr,
 404         vector ofs,
 405         entity own,
 406         .entity ownfield,
 407         float icon, vector rgb // initial icon and color
 408 )
 409 {
 410         return WaypointSprite_Spawn(spr, 0, 0, world, ofs, world, 0, own, ownfield, TRUE, icon, rgb);
 411 }
 412
 413 .entity waypointsprite_deployed_fixed;
 414 entity WaypointSprite_DeployFixed(
 415         string spr,
 416         float limited_range,
 417         vector ofs,
 418         float icon, vector rgb // initial icon and color
 419 )
 420 {
 421         float t, maxdistance;
 422         if(teamplay)
 423                 t = self.team;
 424         else
 425                 t = 0;
 426         if(limited_range)
 427                 maxdistance = waypointsprite_limitedrange;
 428         else
 429                 maxdistance = 0;
 430         return WaypointSprite_Spawn(spr, waypointsprite_deployed_lifetime, maxdistance, world, ofs, world, t, self, waypointsprite_deployed_fixed, FALSE, icon, rgb);
 431 }
 432
 433 .entity waypointsprite_deployed_personal;
 434 entity WaypointSprite_DeployPersonal(
 435         string spr,
 436         vector ofs,
 437         float icon, vector rgb // initial icon and color
 438 )
 439 {
 440         return WaypointSprite_Spawn(spr, 0, 0, world, ofs, world, 0, self, waypointsprite_deployed_personal, FALSE, icon, rgb);
 441 }
 442
 443 .entity waypointsprite_attached;
 444 .entity waypointsprite_attachedforcarrier;
 445 entity WaypointSprite_Attach(
 446         string spr,
 447         float limited_range,
 448         float icon, vector rgb // initial icon and color
 449 )
 450 {
 451         float t, maxdistance;
 452         if(self.waypointsprite_attachedforcarrier)
 453                 return world; // can't attach to FC
 454         if(teamplay)
 455                 t = self.team;
 456         else
 457                 t = 0;
 458         if(limited_range)
 459                 maxdistance = waypointsprite_limitedrange;
 460         else
 461                 maxdistance = 0;
 462         return WaypointSprite_Spawn(spr, waypointsprite_deployed_lifetime, maxdistance, self, '0 0 64', world, t, self, waypointsprite_attached, FALSE, icon, rgb);
 463 }
 464
 465 entity WaypointSprite_AttachCarrier(
 466         string spr,
 467         entity carrier,
 468         float icon, vector rgb // initial icon and color
 469 )
 470 {
 471         entity e;
 472         WaypointSprite_Kill(carrier.waypointsprite_attached); // FC overrides attached
 473         e = WaypointSprite_Spawn(spr, 0, 0, carrier, '0 0 64', world, carrier.team, carrier, waypointsprite_attachedforcarrier, FALSE, icon, rgb);
 474         if(e)
 475         {
 476                 WaypointSprite_UpdateMaxHealth(e, '1 0 0' * healtharmor_maxdamage(start_health, start_armorvalue, autocvar_g_balance_armor_blockpercent) * 2);
 477                 WaypointSprite_UpdateHealth(e, '1 0 0' * healtharmor_maxdamage(carrier.health, carrier.armorvalue, autocvar_g_balance_armor_blockpercent));
 478         }
 479         return e;
 480 }
 481
 482 void WaypointSprite_DetachCarrier(entity carrier)
 483 {
 484         WaypointSprite_Disown(carrier.waypointsprite_attachedforcarrier, waypointsprite_deadlifetime);
 485 }
 486
 487 void WaypointSprite_ClearPersonal()
 488 {
 489         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 490 }
 491
 492 void WaypointSprite_ClearOwned()
 493 {
 494         WaypointSprite_Kill(self.waypointsprite_deployed_fixed);
 495         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 496         WaypointSprite_Kill(self.waypointsprite_attached);
 497 }
 498
 499 void WaypointSprite_PlayerDead()
 500 {
 501         WaypointSprite_Disown(self.waypointsprite_attached, waypointsprite_deadlifetime);
 502         WaypointSprite_DetachCarrier(self);
 503 }
 504
 505 void WaypointSprite_PlayerGone()
 506 {
 507         WaypointSprite_Disown(self.waypointsprite_deployed_fixed, waypointsprite_deadlifetime);
 508         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 509         WaypointSprite_Disown(self.waypointsprite_attached, waypointsprite_deadlifetime);
 510         WaypointSprite_DetachCarrier(self);
 511 }