qcsrc/server/vehicles/vehicles.qc

   1 float autocvar_g_vehicles_crush_dmg;
   2 float autocvar_g_vehicles_crush_force;
   3 float autocvar_g_vehicles_delayspawn;
   4 float autocvar_g_vehicles_delayspawn_jitter;
   5 float autocvar_g_vehicles_allow_flagcarry;
   6
   7 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
   8 void vehicles_return();
   9 void vehicles_enter();
  10 void vehicles_touch();
  11 void vehicles_reset_colors();
  12 void vehicles_clearrturn();
  13 void vehicles_setreturn();
  14
  15
  16 /** AuxiliaryXhair*
  17     Send additional points of interest to be drawn, to vehicle owner
  18 **/
  19 float MAX_AXH = 4;
  20 .entity AuxiliaryXhair[MAX_AXH];
  21
  22 float SendAuxiliaryXhair(entity to, float sf)
  23 {
  24
  25         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  26
  27         WriteByte(MSG_ENTITY, self.cnt);
  28
  29         WriteCoord(MSG_ENTITY, self.origin_x);
  30         WriteCoord(MSG_ENTITY, self.origin_y);
  31         WriteCoord(MSG_ENTITY, self.origin_z);
  32
  33     WriteByte(MSG_ENTITY, rint(self.colormod_x * 255));
  34     WriteByte(MSG_ENTITY, rint(self.colormod_y * 255));
  35     WriteByte(MSG_ENTITY, rint(self.colormod_z * 255));
  36
  37     return TRUE;
  38 }
  39
  40 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  41 {
  42     entity axh;
  43
  44     axh_id = bound(0, axh_id, MAX_AXH);
  45     axh = own.(AuxiliaryXhair[axh_id]);
  46
  47     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  48     {
  49         axh                     = spawn();
  50         axh.cnt                 = axh_id;
  51         axh.drawonlytoclient    = own;
  52         axh.owner               = own;
  53         Net_LinkEntity(axh, FALSE, 0, SendAuxiliaryXhair);
  54     }
  55
  56     setorigin(axh, loc);
  57     axh.colormod            = clr;
  58     axh.SendFlags           = 0x01;
  59     own.(AuxiliaryXhair[axh_id]) = axh;
  60 }
  61
  62 /*
  63 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  64 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  65 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  66 {
  67         msg_entity = own;
  68
  69         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  70         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  71
  72         WriteByte(MSG_ONE, axh_id);
  73
  74         WriteCoord(MSG_ONE, loc_x);
  75         WriteCoord(MSG_ONE, loc_y);
  76         WriteCoord(MSG_ONE, loc_z);
  77
  78     WriteByte(MSG_ONE, rint(clr_x * 255));
  79     WriteByte(MSG_ONE, rint(clr_y * 255));
  80     WriteByte(MSG_ONE, rint(clr_z * 255));
  81
  82 }
  83 */
  84 // End AuxiliaryXhair
  85
  86 /**
  87     Notifies the client that he enterd a vehicle, and sends
  88     realavent data.
  89
  90     only sends vehicle_id atm (wich is a HUD_* constant, ex. HUD_SPIDERBOT)
  91 **/
  92 void CSQCVehicleSetup(entity own, float vehicle_id)
  93 {
  94         msg_entity = own;
  95
  96         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  97         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
  98         WriteByte(MSG_ONE, vehicle_id);
  99 }
 100
 101 /** vehicles_locktarget
 102
 103     Generic target locking.
 104
 105     Figure out if what target is "locked" (if any), for missile tracking as such.
 106
 107     after calling, "if(self.lock_target != world && self.lock_strength == 1)" mean
 108     you have a locked in target.
 109
 110     Exspects a crosshair_trace() or equivalent to be
 111     dont before calling.
 112
 113 **/
 114 .entity lock_target;
 115 .float  lock_strength;
 116 .float  lock_time;
 117 .float  lock_soundtime;
 118 void vehicles_locktarget(float incr, float decr, float _lock_time)
 119 {
 120     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
 121     {
 122         self.lock_target    = world;
 123         self.lock_strength  = 0;
 124         self.lock_time      = 0;
 125     }
 126
 127     if(self.lock_time > time)
 128     {
 129         if(self.lock_target)
 130         if(self.lock_soundtime < time)
 131         {
 132             self.lock_soundtime = time + 0.5;
 133             play2(self.owner, "vehicles/locked.wav");
 134         }
 135
 136         return;
 137     }
 138
 139     if(trace_ent != world)
 140     {
 141         if(teamplay && trace_ent.team == self.team)
 142             trace_ent = world;
 143
 144         if(trace_ent.deadflag != DEAD_NO)
 145             trace_ent = world;
 146
 147         if not (trace_ent.vehicle_flags & VHF_ISVEHICLE || trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 148             trace_ent = world;
 149     }
 150
 151     if(self.lock_target == world && trace_ent != world)
 152         self.lock_target = trace_ent;
 153
 154     if(self.lock_target && trace_ent == self.lock_target)
 155     {
 156         if(self.lock_strength != 1 && self.lock_strength + incr >= 1)
 157         {
 158             play2(self.owner, "vehicles/lock.wav");
 159             self.lock_soundtime = time + 0.8;
 160         }
 161         else if (self.lock_strength != 1 && self.lock_soundtime < time)
 162         {
 163             play2(self.owner, "vehicles/locking.wav");
 164             self.lock_soundtime = time + 0.3;
 165         }
 166
 167     }
 168
 169     // Have a locking target
 170     // Trace hit current target
 171     if(trace_ent == self.lock_target && trace_ent != world)
 172     {
 173         self.lock_strength = min(self.lock_strength + incr, 1);
 174         if(self.lock_strength == 1)
 175             self.lock_time = time + _lock_time;
 176     }
 177     else
 178     {
 179         if(trace_ent)
 180             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 181         else
 182             self.lock_strength = max(self.lock_strength - decr, 0);
 183
 184         if(self.lock_strength == 0)
 185             self.lock_target = world;
 186     }
 187 }
 188
 189 #define VEHICLE_UPDATE_PLAYER(fld,vhname) \
 190 self.owner.vehicle_##fld = (self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld) * 100
 191
 192 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 193 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 194 if(trace_fraction != 1) \
 195     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 196
 197 // Hover movement support
 198 float  force_fromtag_power;
 199 float  force_fromtag_normpower;
 200 vector force_fromtag_origin;
 201 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 202 {
 203     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 204     v_forward  = normalize(v_forward) * -1;
 205     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 206
 207     force_fromtag_power = (1 - trace_fraction) * max_power;
 208     force_fromtag_normpower = force_fromtag_power / max_power;
 209
 210     return v_forward  * force_fromtag_power;
 211 }
 212
 213 // Experimental hovermode wich uses attraction/repulstion from surface insted of gravity/repulsion
 214 // Can possibly be use to move abt any surface (inclusing walls/celings)
 215 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 216 {
 217
 218     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 219     v_forward  = normalize(v_forward) * -1;
 220     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 221
 222     // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 223     if(trace_fraction == 1.0)
 224     {
 225         force_fromtag_normpower = -0.25;
 226         return '0 0 -200';
 227     }
 228
 229     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 230     force_fromtag_normpower = force_fromtag_power / max_power;
 231
 232     return v_forward  * force_fromtag_power;
 233 }
 234
 235 // Generic vehile projectile system
 236 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 237 {
 238     // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 239     if(inflictor.owner == self.owner)
 240         return;
 241
 242     self.health -= damage;
 243     self.velocity += force;
 244     if(self.health < 1)
 245     {
 246         self.takedamage = DAMAGE_NO;
 247         self.event_damage = SUB_Null;
 248         self.think = self.use;
 249         self.nextthink = time;
 250     }
 251
 252 }
 253
 254 void vehicles_projectile_explode()
 255 {
 256     if(self.owner && other != world)
 257     {
 258         if(other == self.owner.vehicle)
 259             return;
 260
 261         if(other == self.owner.vehicle.tur_head)
 262             return;
 263     }
 264
 265         PROJECTILE_TOUCH;
 266
 267         self.event_damage = SUB_Null;
 268     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, self.shot_force, self.totalfrags, other);
 269
 270     remove (self);
 271 }
 272
 273 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 274                            vector _org, vector _vel,
 275                            float _dmg, float _radi, float _force,  float _size,
 276                            float _deahtype, float _projtype, float _health,
 277                            float _cull, float _clianim)
 278 {
 279     entity proj;
 280
 281     proj = spawn();
 282
 283     PROJECTILE_MAKETRIGGER(proj);
 284     setorigin(proj, _org);
 285
 286     proj.shot_dmg         = _dmg;
 287     proj.shot_radius      = _radi;
 288     proj.shot_force       = _force;
 289     proj.totalfrags       = _deahtype;
 290     proj.solid            = SOLID_BBOX;
 291     proj.movetype         = MOVETYPE_FLYMISSILE;
 292     proj.flags            = FL_PROJECTILE;
 293     proj.bot_dodge        = TRUE;
 294     proj.bot_dodgerating  = _dmg;
 295     proj.velocity         = _vel;
 296     proj.touch            = vehicles_projectile_explode;
 297     proj.use              = vehicles_projectile_explode;
 298     proj.owner            = self;
 299     proj.realowner        = self.owner;
 300     proj.think            = SUB_Remove;
 301     proj.nextthink        = time + 30;
 302
 303     if(_health)
 304     {
 305         proj.takedamage       = DAMAGE_AIM;
 306         proj.event_damage     = vehicles_projectile_damage;
 307         proj.health           = _health;
 308     }
 309     else
 310         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 311
 312     if(_mzlsound)
 313         sound (self, CH_WEAPON_A, _mzlsound, VOL_BASE, ATTN_NORM);
 314
 315     if(_mzlfx)
 316         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 317
 318
 319     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 320
 321     CSQCProjectile(proj, _clianim, _projtype, _cull);
 322
 323     return proj;
 324 }
 325 // End generic vehile projectile system
 326
 327 /** vehicles_spawn
 328     Exetuted for all vehicles on (re)spawn.
 329     Sets defaults for newly spawned units.
 330 **/
 331 void vehicles_spawn()
 332 {
 333     dprint("Spawning vehicle: ", self.netname, "\n");
 334
 335     // De-own & reset
 336     self.vehicle_hudmodel.viewmodelforclient = self;
 337
 338     self.owner              = world;
 339     self.touch              = vehicles_touch;
 340     self.event_damage       = vehicles_damage;
 341     self.iscreature         = TRUE;
 342     self.damagedbycontents      = TRUE;
 343     self.movetype           = MOVETYPE_WALK;
 344     self.solid              = SOLID_SLIDEBOX;
 345     self.takedamage         = DAMAGE_AIM;
 346         self.deadflag           = DEAD_NO;
 347     self.bot_attack         = TRUE;
 348     self.flags              = FL_NOTARGET;
 349     self.avelocity          = '0 0 0';
 350     self.velocity           = '0 0 0';
 351
 352     // Reset locking
 353     self.lock_strength      = 0;
 354     self.lock_target        = world;
 355     self.misc_bulletcounter = 0;
 356
 357     // Return to spawn
 358     self.angles             = self.pos2;
 359     setorigin(self, self.pos1 + '0 0 0');
 360     // Show it
 361     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 362
 363     vehicles_reset_colors();
 364     self.vehicle_spawn();
 365 }
 366
 367 // Better way of determening whats crushable needed! (fl_crushable?)
 368 float vehicles_crushable(entity e)
 369 {
 370     if(e.classname == "player")
 371         return TRUE;
 372
 373     if(e.classname == "monster_zombie")
 374         return TRUE;
 375
 376     return FALSE;
 377 }
 378
 379 void vehilces_impact(float _minspeed, float _speedfac, float _maxpain)
 380 {
 381     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 382         return;
 383
 384     if(self.play_time < time)
 385     {
 386         float wc = vlen(self.velocity - self.oldvelocity);
 387         //dprint("oldvel: ", vtos(self.oldvelocity), "\n");
 388         //dprint("vel: ", vtos(self.velocity), "\n");
 389         if(_minspeed < wc)
 390         {
 391             float take = take = min(_speedfac * wc, _maxpain);
 392             Damage (self, world, world, take, DEATH_FALL, self.origin, '0 0 0');
 393             self.play_time = time + 0.25;
 394
 395             //dprint("wc: ", ftos(wc), "\n");
 396             //dprint("take: ", ftos(take), "\n");
 397         }
 398     }
 399 }
 400
 401 .void() vehicle_impact;
 402 void vehicles_touch()
 403 {
 404     // Vehicle currently in use
 405     if(self.owner)
 406     {
 407         if(other != world)
 408         if(vehicles_crushable(other))
 409         {
 410             if(vlen(self.velocity) != 0)
 411                 Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VHCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 412
 413             return; // Dont do selfdamage when hitting "soft targets".
 414         }
 415
 416         if(self.play_time < time)
 417         if(self.vehicle_impact)
 418             self.vehicle_impact();
 419
 420         return;
 421     }
 422
 423     if(other.classname != "player")
 424         return;
 425
 426     if(other.deadflag != DEAD_NO)
 427         return;
 428
 429     if(other.vehicle != world)
 430         return;
 431
 432     // Remove this when bots know how to use vehicles.
 433     if (clienttype(other) != CLIENTTYPE_REAL)
 434         return;
 435
 436     vehicles_enter();
 437 }
 438
 439 void vehicles_enter()
 440 {
 441    // Remove this when bots know how to use vehicles
 442     if (clienttype(other) != CLIENTTYPE_REAL)
 443         return;
 444
 445     if(self.phase > time)
 446         return;
 447
 448     if(teamplay)
 449     if(self.team)
 450     if(self.team != other.team)
 451         return;
 452
 453     RemoveGrapplingHook(other);
 454
 455     self.vehicle_ammo1   = 0;
 456     self.vehicle_ammo2   = 0;
 457     self.vehicle_reload1 = 0;
 458     self.vehicle_reload2 = 0;
 459     self.vehicle_energy  = 0;
 460
 461     self.owner          = other;
 462     self.switchweapon   = other.switchweapon;
 463
 464     // .viewmodelforclient works better.
 465     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 466
 467     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 468
 469     self.event_damage         = vehicles_damage;
 470     self.nextthink            = 0;
 471     self.owner.angles         = self.angles;
 472     self.owner.takedamage     = DAMAGE_NO;
 473     self.owner.solid          = SOLID_NOT;
 474     self.owner.movetype       = MOVETYPE_NOCLIP;
 475     self.owner.alpha          = -1;
 476     self.owner.vehicle        = self;
 477     self.owner.event_damage   = SUB_Null;
 478     self.owner.view_ofs       = '0 0 0';
 479     self.colormap             = self.owner.colormap;
 480     if(self.tur_head)
 481         self.tur_head.colormap    = self.owner.colormap;
 482
 483     self.owner.hud            = self.hud;
 484     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 485
 486     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 487     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 488     self.owner.vehicle_reload1  = self.vehicle_reload1;
 489     self.owner.vehicle_reload2  = self.vehicle_reload2;
 490
 491     // Cant do this, hides attached objects too.
 492     //self.exteriormodeltoclient = self.owner;
 493     //self.tur_head.exteriormodeltoclient = self.owner;
 494
 495     other.flags &~= FL_ONGROUND;
 496     self.flags  &~= FL_ONGROUND;
 497
 498     self.team                 = self.owner.team;
 499     self.flags               -= FL_NOTARGET;
 500
 501     msg_entity = other;
 502
 503     WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 504     if(self.tur_head)
 505     {
 506         WriteAngle(MSG_ONE, self.tur_head.angles_x + self.angles_x); // tilt
 507         WriteAngle(MSG_ONE, self.tur_head.angles_y + self.angles_y); // yaw
 508         WriteAngle(MSG_ONE, 0);                                      // roll
 509     }
 510     else
 511     {
 512         WriteAngle(MSG_ONE,  self.angles_x * -1); // tilt
 513         WriteAngle(MSG_ONE,  self.angles_y);      // yaw
 514         WriteAngle(MSG_ONE,  0);                  // roll
 515     }
 516
 517     vehicles_clearrturn();
 518
 519     CSQCVehicleSetup(self.owner, self.hud);
 520
 521     if(other.flagcarried)
 522     {
 523         if(!autocvar_g_vehicles_allow_flagcarry)
 524             DropFlag(other.flagcarried, world, world);
 525         else
 526         {
 527             other.flagcarried.scale = 1;
 528             setattachment(other.flagcarried, self, "");
 529             setorigin(other, '0 0 96');
 530         }
 531     }
 532
 533     self.vehicle_enter();
 534 }
 535
 536 /** vehicles_findgoodexit
 537     Locates a valid location for the player to exit the vehicle.
 538     Will first try prefer_spot, then up 100 random spots arround the vehicle
 539     wich are in direct line of sight and empty enougth to hold a players bbox
 540 **/
 541 vector vehicles_findgoodexit(vector prefer_spot)
 542 {
 543     //vector exitspot;
 544     float mysize;
 545
 546     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, prefer_spot, MOVE_NORMAL, self.owner);
 547     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 548         return prefer_spot;
 549
 550     mysize = vlen(self.maxs - self.mins);
 551     float i;
 552     vector v, v2;
 553     v2 = 0.5 * (self.absmin + self.absmax);
 554     for(i = 0; i < 100; ++i)
 555     {
 556         v = randomvec();
 557         v_z = 0;
 558         v = v2 + normalize(v) * mysize;
 559         tracebox(v2, PL_MIN, PL_MAX, v, MOVE_NORMAL, self.owner);
 560         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 561             return v;
 562     }
 563
 564     /*
 565     exitspot = (self.origin + '0 0 48') + v_forward * mysize;
 566     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 567     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 568         return exitspot;
 569
 570     exitspot = (self.origin + '0 0 48') - v_forward * mysize;
 571     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 572     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 573         return exitspot;
 574
 575     exitspot = (self.origin + '0 0 48') + v_right * mysize;
 576     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 577     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 578         return exitspot;
 579
 580     exitspot = (self.origin + '0 0 48') - v_right * mysize;
 581     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 582     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 583         return exitspot;
 584     */
 585
 586     return self.origin;
 587 }
 588
 589 /** vehicles_exit
 590     Standarrd vehicle release fucntion.
 591     custom code goes in self.vehicle_exit
 592 **/
 593 void vehicles_exit(float eject)
 594 {
 595     entity oldself;
 596     if(self.flags & FL_CLIENT)
 597     {
 598         oldself = self;
 599         self = self.vehicle;
 600     }
 601
 602         self.flags |= FL_NOTARGET;
 603
 604     if (self.owner)
 605     {
 606         msg_entity = self.owner;
 607         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 608         WriteEntity( MSG_ONE, self.owner);
 609
 610         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 611         WriteAngle(MSG_ONE, 0);                 // pich
 612         WriteAngle(MSG_ONE, self.angles_y);     // yaw
 613         WriteAngle(MSG_ONE, 0);                 // roll
 614
 615         setsize(self.owner, PL_MIN,PL_MAX);
 616
 617         self.owner.takedamage     = DAMAGE_AIM;
 618         self.owner.solid          = SOLID_SLIDEBOX;
 619         self.owner.movetype       = MOVETYPE_WALK;
 620         self.owner.effects        &~= EF_NODRAW;
 621         self.owner.alpha          = 1;
 622         self.owner.PlayerPhysplug = SUB_Null;
 623         self.owner.vehicle        = world;
 624         self.owner.view_ofs       = PL_VIEW_OFS;
 625         self.owner.event_damage   = PlayerDamage;
 626         self.owner.hud            = HUD_NORMAL;
 627         self.owner.switchweapon   = self.switchweapon;
 628         //self.owner.BUTTON_USE     = 0;
 629
 630         CSQCVehicleSetup(self.owner, HUD_NORMAL);
 631     }
 632
 633     if(self.deadflag == DEAD_NO)
 634         self.avelocity          = '0 0 0';
 635
 636     self.vehicle_hudmodel.viewmodelforclient = self;
 637         self.tur_head.nodrawtoclient             = world;
 638     vehicles_setreturn();
 639
 640     self.phase = time + 1;
 641
 642     if(!teamplay)
 643         self.team = 0;
 644     else
 645         self.team = self.tur_head.team;
 646
 647     if(self.owner.flagcarried)
 648     {
 649         self.owner.flagcarried.scale = 0.6;
 650         setattachment(self.owner.flagcarried, self.owner, "");
 651         setorigin(self.owner.flagcarried, FLAG_CARRY_POS);
 652     }
 653
 654     sound (self, CH_TRIGGER_SINGLE, "misc/null.wav", 1, ATTN_NORM);
 655     self.vehicle_exit(eject);
 656     self.owner = world;
 657     vehicles_reset_colors();
 658
 659     if(oldself)
 660         self = oldself;
 661 }
 662
 663
 664 void vehicles_regen(.float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time)
 665 {
 666     if(self.regen_field < field_max)
 667     if(self.timer + rpause < time)
 668     {
 669         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 670
 671         if(self.owner)
 672             self.owner.regen_field = (self.regen_field / field_max) * 100;
 673     }
 674 }
 675
 676 void shieldhit_think()
 677 {
 678     self.alpha -= 0.1;
 679     if (self.alpha <= 0)
 680     {
 681         //setmodel(self, "");
 682         self.alpha = -1;
 683     }
 684     else
 685     {
 686         self.nextthink = time + 0.1;
 687     }
 688 }
 689
 690 void vehicles_painframe()
 691 {
 692     if(self.owner.vehicle_health <= 50)
 693     if(self.pain_frame < time)
 694     {
 695         float _ftmp;
 696         _ftmp = self.owner.vehicle_health / 50;
 697         self.pain_frame = time + 0.1 + (random() * 0.5 * _ftmp);
 698         pointparticles(particleeffectnum("smoke_small"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 699
 700         if(self.vehicle_flags & VHF_DMGSHAKE)
 701             self.velocity += randomvec() * 30;
 702
 703         if(self.vehicle_flags & VHF_DMGROLL)
 704             if(self.vehicle_flags & VHF_DMGHEADROLL)
 705                 self.tur_head.angles += randomvec();
 706             else
 707                 self.angles += randomvec();
 708
 709     }
 710 }
 711
 712 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 713 {
 714     self.dmg_time = time;
 715
 716     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 717     {
 718         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 719         {
 720             self.vehicle_shieldent = spawn();
 721             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 722
 723             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 724             setattachment(self.vehicle_shieldent, self, "");
 725             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 726             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 727             self.vehicle_shieldent.think       = shieldhit_think;
 728         }
 729
 730         self.vehicle_shieldent.colormod    = '1 1 1';
 731         self.vehicle_shieldent.alpha       = 0.45;
 732         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 733         self.vehicle_shieldent.nextthink   = time;
 734
 735         self.vehicle_shield -= damage;
 736
 737         if(self.vehicle_shield < 0)
 738         {
 739             self.vehicle_health            -= fabs(self.vehicle_shield);
 740             self.vehicle_shieldent.colormod = '2 0 0';
 741             self.vehicle_shield             = 0;
 742             self.vehicle_shieldent.alpha    = 0.75;
 743
 744                 if(sound_allowed(MSG_BROADCAST, attacker))
 745                 spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);   // FIXME: PLACEHOLDER
 746         }
 747         else
 748                 if(sound_allowed(MSG_BROADCAST, attacker))
 749                 spamsound (self, CH_PAIN, "onslaught/electricity_explode.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 750
 751     }
 752     else
 753     {
 754         self.vehicle_health -= damage;
 755
 756         if(sound_allowed(MSG_BROADCAST, attacker))
 757             spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 758     }
 759
 760     self.velocity += force; // * (vlen(force) / self.mass);
 761
 762     if(self.vehicle_health <= 0)
 763     {
 764         if(self.owner)
 765             if(self.vehicle_flags & VHF_DEATHEJECT)
 766                 vehicles_exit(VHEF_EJECT);
 767             else
 768                 vehicles_exit(VHEF_RELESE);
 769
 770         self.vehicle_die();
 771         vehicles_setreturn();
 772     }
 773 }
 774
 775 void vehicles_clearrturn()
 776 {
 777     entity ret;
 778     // Remove "return helper", if any.
 779     ret = findchain(classname, "vehicle_return");
 780     while(ret)
 781     {
 782         if(ret.enemy == self)
 783         {
 784             ret.classname   = "";
 785             ret.think       = SUB_Remove;
 786             ret.nextthink   = time + 0.1;
 787
 788             if(ret.waypointsprite_attached)
 789                 WaypointSprite_Kill(ret.waypointsprite_attached);
 790
 791             return;
 792         }
 793         ret = ret.chain;
 794     }
 795 }
 796
 797 void vehicles_return()
 798 {
 799     pointparticles(particleeffectnum("teleport"), self.enemy.origin + '0 0 64', '0 0 0', 1);
 800
 801     self.enemy.think     = vehicles_spawn;
 802     self.enemy.nextthink = time;
 803
 804     if(self.waypointsprite_attached)
 805         WaypointSprite_Kill(self.waypointsprite_attached);
 806
 807     remove(self);
 808 }
 809
 810 void vehicles_showwp_goaway()
 811 {
 812     if(self.waypointsprite_attached)
 813         WaypointSprite_Kill(self.waypointsprite_attached);
 814
 815     remove(self);
 816
 817 }
 818
 819 void vehicles_showwp()
 820 {
 821     entity oldself;
 822     vector rgb;
 823
 824     if(self.cnt)
 825     {
 826         self.think      = vehicles_return;
 827         self.nextthink  = self.cnt;
 828     }
 829     else
 830     {
 831         self.think      = vehicles_return;
 832         self.nextthink  = time +1;
 833
 834         oldself = self;
 835         self = spawn();
 836         setmodel(self, "null");
 837         self.team = oldself.enemy.team;
 838         self.enemy = oldself.enemy;
 839         setorigin(self, oldself.enemy.pos1);
 840
 841         self.nextthink = time + 5;
 842         self.think = vehicles_showwp_goaway;
 843     }
 844
 845     if(teamplay && self.team)
 846             rgb = TeamColor(self.team);
 847     else
 848             rgb = '1 1 1';
 849     WaypointSprite_Spawn("vehicle", 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 850     if(self.waypointsprite_attached)
 851     {
 852         WaypointSprite_UpdateRule(self.waypointsprite_attached, self.enemy.team, SPRITERULE_DEFAULT);
 853         if(oldself == world)
 854             WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, self.nextthink);
 855         WaypointSprite_Ping(self.waypointsprite_attached);
 856     }
 857
 858     if(oldself != world)
 859         self = oldself;
 860 }
 861
 862 void vehicles_setreturn()
 863 {
 864     entity ret;
 865
 866     vehicles_clearrturn();
 867
 868     ret = spawn();
 869     ret.classname   = "vehicle_return";
 870     ret.enemy       = self;
 871     ret.team        = self.team;
 872     ret.think       = vehicles_showwp;
 873
 874     if(self.deadflag != DEAD_NO)
 875     {
 876         ret.cnt         = time + self.vehicle_respawntime;
 877         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 5);
 878     }
 879     else
 880     {
 881         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 1);
 882     }
 883
 884     setmodel(ret, "null");
 885     setorigin(ret, self.pos1 + '0 0 96');
 886
 887 }
 888
 889 void vehicles_configcheck(string  configname, float check_cvar)
 890 {
 891     if(check_cvar == 0)
 892         localcmd(strcat("exec ", configname, "\n"));
 893 }
 894
 895 void vehicles_reset_colors()
 896 {
 897     entity e;
 898     float _effects, _colormap;
 899     vector _glowmod, _colormod;
 900
 901     if(autocvar_g_nodepthtestplayers)
 902         _effects = EF_NODEPTHTEST;
 903
 904     if(autocvar_g_fullbrightplayers)
 905         _effects |= EF_FULLBRIGHT;
 906
 907     if(self.team)
 908         _colormap = 1024 + (self.team - 1) * 17;
 909     else
 910         _colormap = 1024;
 911
 912     _glowmod  = '0 0 0';
 913     _colormod = '0 0 0';
 914
 915     // Find all ents attacked to main model and setup effects, colormod etc.
 916     e = findchainentity(tag_entity, self);
 917     while(e)
 918     {
 919         if(e != self.vehicle_shieldent)
 920         {
 921             e.effects   = _effects; //  | EF_LOWPRECISION;
 922             e.colormod  = _colormod;
 923             e.colormap  = _colormap;
 924             e.alpha     = 1;
 925         }
 926         e = e.chain;
 927     }
 928
 929     self.vehicle_hudmodel.effects  = self.effects  = _effects; // | EF_LOWPRECISION;
 930     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
 931     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
 932     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 933
 934     self.alpha     = 1;
 935     self.avelocity = '0 0 0';
 936     self.velocity  = '0 0 0';
 937     self.effects   = _effects;
 938 }
 939
 940 float vehicle_initialize(string  net_name,
 941                          string  bodymodel,
 942                          string  topmodel,
 943                          string  hudmodel,
 944                          string  toptag,
 945                          string  hudtag,
 946                          string  viewtag,
 947                          float   vhud,
 948                          vector  min_s,
 949                          vector  max_s,
 950                          float   nodrop,
 951                          void()  spawnproc,
 952                          float   _respawntime,
 953                          float() physproc,
 954                          void()  enterproc,
 955                          void(float extflag) exitfunc,
 956                          void() dieproc,
 957                          void() thinkproc,
 958                          float  use_csqc)
 959 {
 960     addstat(STAT_HUD, AS_INT,  hud);
 961         addstat(STAT_VEHICLESTAT_HEALTH,  AS_INT, vehicle_health);
 962         addstat(STAT_VEHICLESTAT_SHIELD,  AS_INT, vehicle_shield);
 963         addstat(STAT_VEHICLESTAT_ENERGY,  AS_INT, vehicle_energy);
 964
 965         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT,   vehicle_ammo1);
 966         addstat(STAT_VEHICLESTAT_RELOAD1, AS_INT, vehicle_reload1);
 967
 968         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT,   vehicle_ammo2);
 969         addstat(STAT_VEHICLESTAT_RELOAD2, AS_INT, vehicle_reload2);
 970
 971     if(bodymodel == "")
 972         error("vehicles: missing bodymodel!");
 973
 974     if(hudmodel == "")
 975         error("vehicles: missing hudmodel!");
 976
 977     if(net_name == "")
 978         self.netname = self.classname;
 979     else
 980         self.netname = net_name;
 981
 982     if(self.team && !teamplay)
 983         self.team = 0;
 984
 985     self.vehicle_flags |= VHF_ISVEHICLE;
 986
 987     setmodel(self, bodymodel);
 988
 989     self.vehicle_viewport   = spawn();
 990     self.vehicle_hudmodel   = spawn();
 991     self.tur_head           = spawn();
 992     self.tur_head.owner     = self;
 993     self.takedamage         = DAMAGE_AIM;
 994     self.bot_attack         = TRUE;
 995     self.iscreature         = TRUE;
 996     self.damagedbycontents      = TRUE;
 997     self.hud                = vhud;
 998
 999     self.vehicle_die         = dieproc;
1000     self.vehicle_exit        = exitfunc;
1001     self.vehicle_enter       = enterproc;
1002     self.PlayerPhysplug      = physproc;
1003     self.event_damage        = vehicles_damage;
1004     self.touch               = vehicles_touch;
1005     self.think               = vehicles_spawn;
1006     self.nextthink           = time;
1007     self.vehicle_respawntime = _respawntime;
1008     self.vehicle_spawn       = spawnproc;
1009
1010     if(autocvar_g_nodepthtestplayers)
1011         self.effects = self.effects | EF_NODEPTHTEST;
1012
1013     if(autocvar_g_fullbrightplayers)
1014         self.effects = self.effects | EF_FULLBRIGHT;
1015
1016     setmodel(self.vehicle_hudmodel, hudmodel);
1017     setmodel(self.vehicle_viewport, "null");
1018
1019
1020     if(topmodel != "")
1021     {
1022         setmodel(self.tur_head, topmodel);
1023         setattachment(self.tur_head, self, toptag);
1024         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
1025         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1026     }
1027     else
1028     {
1029         setattachment(self.tur_head, self, "");
1030         setattachment(self.vehicle_hudmodel, self, hudtag);
1031         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1032     }
1033
1034     setsize(self, min_s, max_s);
1035     if not (nodrop)
1036     {
1037         setorigin(self, self.origin);
1038         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1039         setorigin(self, trace_endpos);
1040     }
1041
1042     self.pos1 = self.origin;
1043     self.pos2 = self.angles;
1044     self.tur_head.team = self.team;
1045
1046     return TRUE;
1047 }
1048
1049 void bugmenot()
1050 {
1051     self.vehicle_exit       = self.vehicle_exit;
1052     self.vehicle_enter      = self.vehicle_exit;
1053     self.vehicle_die        = self.vehicle_exit;
1054     self.vehicle_spawn      = self.vehicle_exit;
1055     self.AuxiliaryXhair     = self.AuxiliaryXhair;
1056 }
1057
1058 void vehicles_updateplayer()
1059 {
1060         setorigin(self, gettaginfo(self.vehicle.vehicle_viewport, 0));
1061 }