qcsrc/server/vehicles/vehicles.qc

   1 float autocvar_g_vehicles_crush_dmg;
   2 float autocvar_g_vehicles_crush_force;
   3 float autocvar_g_vehicles_delayspawn;
   4 float autocvar_g_vehicles_delayspawn_jitter;
   5 float autocvar_g_vehicles_allow_flagcarry;
   6
   7 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
   8 void vehicles_return();
   9 void vehicles_enter();
  10 void vehicles_touch();
  11 void vehicles_reset_colors();
  12 void vehicles_clearrturn();
  13 void vehicles_setreturn();
  14
  15
  16 /** AuxiliaryXhair*
  17     Send additional points of interest to be drawn, to vehicle owner
  18 **/
  19 float MAX_AXH = 4;
  20 .entity AuxiliaryXhair[MAX_AXH];
  21
  22 float SendAuxiliaryXhair(entity to, float sf)
  23 {
  24
  25         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  26
  27         WriteByte(MSG_ENTITY, self.cnt);
  28
  29         WriteCoord(MSG_ENTITY, self.origin_x);
  30         WriteCoord(MSG_ENTITY, self.origin_y);
  31         WriteCoord(MSG_ENTITY, self.origin_z);
  32
  33     WriteByte(MSG_ENTITY, rint(self.colormod_x * 255));
  34     WriteByte(MSG_ENTITY, rint(self.colormod_y * 255));
  35     WriteByte(MSG_ENTITY, rint(self.colormod_z * 255));
  36
  37     return TRUE;
  38 }
  39
  40 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  41 {
  42     entity axh;
  43
  44     axh_id = bound(0, axh_id, MAX_AXH);
  45     axh = own.(AuxiliaryXhair[axh_id]);
  46
  47     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  48     {
  49         axh                     = spawn();
  50         axh.cnt                 = axh_id;
  51         axh.drawonlytoclient    = own;
  52         axh.owner               = own;
  53         Net_LinkEntity(axh, FALSE, 0, SendAuxiliaryXhair);
  54     }
  55
  56     setorigin(axh, loc);
  57     axh.colormod            = clr;
  58     axh.SendFlags           = 0x01;
  59     own.(AuxiliaryXhair[axh_id]) = axh;
  60 }
  61
  62 /*
  63 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  64 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  65 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  66 {
  67         msg_entity = own;
  68
  69         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  70         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  71
  72         WriteByte(MSG_ONE, axh_id);
  73
  74         WriteCoord(MSG_ONE, loc_x);
  75         WriteCoord(MSG_ONE, loc_y);
  76         WriteCoord(MSG_ONE, loc_z);
  77
  78     WriteByte(MSG_ONE, rint(clr_x * 255));
  79     WriteByte(MSG_ONE, rint(clr_y * 255));
  80     WriteByte(MSG_ONE, rint(clr_z * 255));
  81
  82 }
  83 */
  84 // End AuxiliaryXhair
  85
  86 /**
  87     Notifies the client that he enterd a vehicle, and sends
  88     realavent data.
  89
  90     only sends vehicle_id atm (wich is a HUD_* constant, ex. HUD_SPIDERBOT)
  91 **/
  92 void CSQCVehicleSetup(entity own, float vehicle_id)
  93 {
  94         msg_entity = own;
  95
  96         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  97         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
  98         WriteByte(MSG_ONE, vehicle_id);
  99 }
 100
 101 /** vehicles_locktarget
 102
 103     Generic target locking.
 104
 105     Figure out if what target is "locked" (if any), for missile tracking as such.
 106
 107     after calling, "if(self.lock_target != world && self.lock_strength == 1)" mean
 108     you have a locked in target.
 109
 110     Exspects a crosshair_trace() or equivalent to be
 111     dont before calling.
 112
 113 **/
 114 .entity lock_target;
 115 .float  lock_strength;
 116 .float  lock_time;
 117 .float  lock_soundtime;
 118 void vehicles_locktarget(float incr, float decr, float _lock_time)
 119 {
 120     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
 121     {
 122         self.lock_target    = world;
 123         self.lock_strength  = 0;
 124         self.lock_time      = 0;
 125     }
 126
 127     if(self.lock_time > time)
 128     {
 129         if(self.lock_target)
 130         if(self.lock_soundtime < time)
 131         {
 132             self.lock_soundtime = time + 0.5;
 133             play2(self.owner, "vehicles/locked.wav");
 134         }
 135
 136         return;
 137     }
 138
 139     if(trace_ent != world)
 140     {
 141         if(teamplay && trace_ent.team == self.team)
 142             trace_ent = world;
 143
 144         if(trace_ent.deadflag != DEAD_NO)
 145             trace_ent = world;
 146
 147         if not (trace_ent.vehicle_flags & VHF_ISVEHICLE || trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 148             trace_ent = world;
 149     }
 150
 151     if(self.lock_target == world && trace_ent != world)
 152         self.lock_target = trace_ent;
 153
 154     if(self.lock_target && trace_ent == self.lock_target)
 155     {
 156         if(self.lock_strength != 1 && self.lock_strength + incr >= 1)
 157         {
 158             play2(self.owner, "vehicles/lock.wav");
 159             self.lock_soundtime = time + 0.8;
 160         }
 161         else if (self.lock_strength != 1 && self.lock_soundtime < time)
 162         {
 163             play2(self.owner, "vehicles/locking.wav");
 164             self.lock_soundtime = time + 0.3;
 165         }
 166
 167     }
 168
 169     // Have a locking target
 170     // Trace hit current target
 171     if(trace_ent == self.lock_target && trace_ent != world)
 172     {
 173         self.lock_strength = min(self.lock_strength + incr, 1);
 174         if(self.lock_strength == 1)
 175             self.lock_time = time + _lock_time;
 176     }
 177     else
 178     {
 179         if(trace_ent)
 180             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 181         else
 182             self.lock_strength = max(self.lock_strength - decr, 0);
 183
 184         if(self.lock_strength == 0)
 185             self.lock_target = world;
 186     }
 187 }
 188
 189 #define VEHICLE_UPDATE_PLAYER(fld,vhname) \
 190 self.owner.vehicle_##fld = (self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld) * 100
 191
 192 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 193 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 194 if(trace_fraction != 1) \
 195     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 196
 197 // Hover movement support
 198 float  force_fromtag_power;
 199 float  force_fromtag_normpower;
 200 vector force_fromtag_origin;
 201 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 202 {
 203     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 204     v_forward  = normalize(v_forward) * -1;
 205     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 206
 207     force_fromtag_power = (1 - trace_fraction) * max_power;
 208     force_fromtag_normpower = force_fromtag_power / max_power;
 209
 210     return v_forward  * force_fromtag_power;
 211 }
 212
 213 // Experimental hovermode wich uses attraction/repulstion from surface insted of gravity/repulsion
 214 // Can possibly be use to move abt any surface (inclusing walls/celings)
 215 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 216 {
 217
 218     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 219     v_forward  = normalize(v_forward) * -1;
 220     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 221
 222     // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 223     if(trace_fraction == 1.0)
 224     {
 225         force_fromtag_normpower = -0.25;
 226         return '0 0 -200';
 227     }
 228
 229     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 230     force_fromtag_normpower = force_fromtag_power / max_power;
 231
 232     return v_forward  * force_fromtag_power;
 233 }
 234
 235 // Generic vehile projectile system
 236 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 237 {
 238     // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 239     if(inflictor.owner == self.owner)
 240         return;
 241
 242     self.health -= damage;
 243     self.velocity += force;
 244     if(self.health < 1)
 245     {
 246         self.takedamage = DAMAGE_NO;
 247         self.event_damage = SUB_Null;
 248         self.think = self.use;
 249         self.nextthink = time;
 250     }
 251
 252 }
 253
 254 void vehicles_projectile_explode()
 255 {
 256     if(self.owner && other != world)
 257     {
 258         if(other == self.owner.vehicle)
 259             return;
 260
 261         if(other == self.owner.vehicle.tur_head)
 262             return;
 263     }
 264
 265         PROJECTILE_TOUCH;
 266
 267         self.event_damage = SUB_Null;
 268     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, self.shot_force, self.totalfrags, other);
 269
 270     remove (self);
 271 }
 272
 273 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 274                            vector _org, vector _vel,
 275                            float _dmg, float _radi, float _force,  float _size,
 276                            float _deahtype, float _projtype, float _health,
 277                            float _cull, float _clianim)
 278 {
 279     entity proj;
 280
 281     proj = spawn();
 282
 283     PROJECTILE_MAKETRIGGER(proj);
 284     setorigin(proj, _org);
 285
 286     proj.shot_dmg         = _dmg;
 287     proj.shot_radius      = _radi;
 288     proj.shot_force       = _force;
 289     proj.totalfrags       = _deahtype;
 290     proj.solid            = SOLID_BBOX;
 291     proj.movetype         = MOVETYPE_FLYMISSILE;
 292     proj.flags            = FL_PROJECTILE;
 293     proj.bot_dodge        = TRUE;
 294     proj.bot_dodgerating  = _dmg;
 295     proj.velocity         = _vel;
 296     proj.touch            = vehicles_projectile_explode;
 297     proj.use              = vehicles_projectile_explode;
 298     proj.owner            = self;
 299     proj.realowner        = self.owner;
 300     proj.think            = SUB_Remove;
 301     proj.nextthink        = time + 30;
 302
 303     if(_health)
 304     {
 305         proj.takedamage       = DAMAGE_AIM;
 306         proj.event_damage     = vehicles_projectile_damage;
 307         proj.health           = _health;
 308     }
 309     else
 310         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 311
 312     if(_mzlsound)
 313         sound (self, CH_WEAPON_A, _mzlsound, VOL_BASE, ATTN_NORM);
 314
 315     if(_mzlfx)
 316         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 317
 318
 319     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 320
 321     CSQCProjectile(proj, _clianim, _projtype, _cull);
 322
 323     return proj;
 324 }
 325 // End generic vehile projectile system
 326
 327 /** vehicles_spawn
 328     Exetuted for all vehicles on (re)spawn.
 329     Sets defaults for newly spawned units.
 330 **/
 331 void vehicles_spawn()
 332 {
 333     dprint("Spawning vehicle: ", self.netname, "\n");
 334
 335     // De-own & reset
 336     self.vehicle_hudmodel.viewmodelforclient = self;
 337
 338     self.owner              = world;
 339     self.touch              = vehicles_touch;
 340     self.event_damage       = vehicles_damage;
 341     self.iscreature         = TRUE;
 342     self.damagedbycontents      = TRUE;
 343     self.movetype           = MOVETYPE_WALK;
 344     self.solid              = SOLID_SLIDEBOX;
 345     self.takedamage         = DAMAGE_AIM;
 346         self.deadflag           = DEAD_NO;
 347     self.bot_attack         = TRUE;
 348     self.flags              = FL_NOTARGET;
 349     self.avelocity          = '0 0 0';
 350     self.velocity           = '0 0 0';
 351
 352     // Reset locking
 353     self.lock_strength      = 0;
 354     self.lock_target        = world;
 355     self.misc_bulletcounter = 0;
 356
 357     // Return to spawn
 358     self.angles             = self.pos2;
 359     setorigin(self, self.pos1 + '0 0 128');
 360     // Show it
 361     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 362
 363     vehicles_reset_colors();
 364     self.vehicle_spawn();
 365 }
 366
 367 // Better way of determening whats crushable needed! (fl_crushable?)
 368 float vehicles_crushable(entity e)
 369 {
 370     if(e.classname == "player")
 371         return TRUE;
 372
 373     if(e.classname == "monster_zombie")
 374         return TRUE;
 375
 376     return FALSE;
 377 }
 378
 379 void vehilces_impact(float _minspeed, float _speedfac, float _maxpain)
 380 {
 381     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 382         return;
 383
 384     if(self.play_time < time)
 385     {
 386         float wc = vlen(self.velocity - self.oldvelocity);
 387         //dprint("oldvel: ", vtos(self.oldvelocity), "\n");
 388         //dprint("vel: ", vtos(self.velocity), "\n");
 389         if(_minspeed < wc)
 390         {
 391             float take = take = min(_speedfac * wc, _maxpain);
 392             Damage (self, world, world, take, DEATH_FALL, self.origin, '0 0 0');
 393             self.play_time = time + 0.25;
 394
 395             //dprint("wc: ", ftos(wc), "\n");
 396             //dprint("take: ", ftos(take), "\n");
 397         }
 398     }
 399 }
 400
 401 .void() vehicle_impact;
 402 void vehicles_touch()
 403 {
 404     // Vehicle currently in use
 405     if(self.owner)
 406     {
 407         if(other != world)
 408         if(vehicles_crushable(other))
 409         {
 410             if(vlen(self.velocity) != 0)
 411                 Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VHCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 412
 413             return; // Dont do selfdamage when hitting "soft targets".
 414         }
 415
 416         if(self.play_time < time)
 417         if(self.vehicle_impact)
 418             self.vehicle_impact();
 419
 420         return;
 421     }
 422
 423     if(other.classname != "player")
 424         return;
 425
 426     if(other.deadflag != DEAD_NO)
 427         return;
 428
 429     if(other.vehicle != world)
 430         return;
 431
 432     // Remove this when bots know how to use vehicles.
 433     if (clienttype(other) != CLIENTTYPE_REAL)
 434         return;
 435
 436     vehicles_enter();
 437 }
 438
 439 void vehicles_enter()
 440 {
 441    // Remove this when bots know how to use vehicles
 442     if (clienttype(other) != CLIENTTYPE_REAL)
 443         return;
 444
 445     if(self.phase > time)
 446         return;
 447
 448     if(teamplay)
 449     if(self.team)
 450     if(self.team != other.team)
 451         return;
 452
 453     RemoveGrapplingHook(other);
 454
 455     self.vehicle_ammo1   = 0;
 456     self.vehicle_ammo2   = 0;
 457     self.vehicle_reload1 = 0;
 458     self.vehicle_reload2 = 0;
 459     self.vehicle_energy  = 0;
 460
 461     self.owner          = other;
 462     self.switchweapon   = other.switchweapon;
 463
 464     // .viewmodelforclient works better.
 465     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 466
 467     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 468
 469     self.event_damage         = vehicles_damage;
 470     self.nextthink            = 0;
 471     self.owner.angles         = self.angles;
 472     self.owner.takedamage     = DAMAGE_NO;
 473     self.owner.solid          = SOLID_NOT;
 474     self.owner.movetype       = MOVETYPE_NOCLIP;
 475     self.owner.alpha          = -1;
 476     self.owner.vehicle        = self;
 477     self.owner.event_damage   = SUB_Null;
 478     self.owner.view_ofs       = '0 0 0';
 479     self.colormap             = self.owner.colormap;
 480     if(self.tur_head)
 481         self.tur_head.colormap    = self.owner.colormap;
 482
 483     self.owner.hud            = self.hud;
 484     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 485
 486     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 487     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 488     self.owner.vehicle_reload1  = self.vehicle_reload1;
 489     self.owner.vehicle_reload2  = self.vehicle_reload2;
 490
 491     // Cant do this, hides attached objects too.
 492     //self.exteriormodeltoclient = self.owner;
 493     //self.tur_head.exteriormodeltoclient = self.owner;
 494
 495     other.flags &~= FL_ONGROUND;
 496     self.flags  &~= FL_ONGROUND;
 497
 498     self.team                 = self.owner.team;
 499     self.flags               -= FL_NOTARGET;
 500
 501     msg_entity = other;
 502     WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 503     WriteEntity(MSG_ONE, self.vehicle_viewport);
 504
 505     WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 506     if(self.tur_head)
 507     {
 508         WriteAngle(MSG_ONE, self.tur_head.angles_x + self.angles_x); // tilt
 509         WriteAngle(MSG_ONE, self.tur_head.angles_y + self.angles_y); // yaw
 510         WriteAngle(MSG_ONE, 0);                                      // roll
 511     }
 512     else
 513     {
 514         WriteAngle(MSG_ONE,  self.angles_x * -1); // tilt
 515         WriteAngle(MSG_ONE,  self.angles_y);      // yaw
 516         WriteAngle(MSG_ONE,  0);                  // roll
 517     }
 518
 519     vehicles_clearrturn();
 520
 521     CSQCVehicleSetup(self.owner, self.hud);
 522
 523     if(other.flagcarried)
 524     {
 525         if(!autocvar_g_vehicles_allow_flagcarry)
 526             DropFlag(other.flagcarried, world, world);
 527         else
 528         {
 529             other.flagcarried.scale = 1;
 530             setattachment(other.flagcarried, self, "");
 531             setorigin(other, '0 0 96');
 532         }
 533     }
 534
 535     self.vehicle_enter();
 536 }
 537
 538 /** vehicles_findgoodexit
 539     Locates a valid location for the player to exit the vehicle.
 540     Will first try prefer_spot, then up 100 random spots arround the vehicle
 541     wich are in direct line of sight and empty enougth to hold a players bbox
 542 **/
 543 vector vehicles_findgoodexit(vector prefer_spot)
 544 {
 545     //vector exitspot;
 546     float mysize;
 547
 548     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, prefer_spot, MOVE_NORMAL, self.owner);
 549     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 550         return prefer_spot;
 551
 552     mysize = vlen(self.maxs - self.mins);
 553     float i;
 554     vector v, v2;
 555     v2 = 0.5 * (self.absmin + self.absmax);
 556     for(i = 0; i < 100; ++i)
 557     {
 558         v = randomvec();
 559         v_z = 0;
 560         v = v2 + normalize(v) * mysize;
 561         tracebox(v2, PL_MIN, PL_MAX, v, MOVE_NORMAL, self.owner);
 562         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 563             return v;
 564     }
 565
 566     /*
 567     exitspot = (self.origin + '0 0 48') + v_forward * mysize;
 568     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 569     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 570         return exitspot;
 571
 572     exitspot = (self.origin + '0 0 48') - v_forward * mysize;
 573     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 574     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 575         return exitspot;
 576
 577     exitspot = (self.origin + '0 0 48') + v_right * mysize;
 578     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 579     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 580         return exitspot;
 581
 582     exitspot = (self.origin + '0 0 48') - v_right * mysize;
 583     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 584     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 585         return exitspot;
 586     */
 587
 588     return self.origin;
 589 }
 590
 591 /** vehicles_exit
 592     Standarrd vehicle release fucntion.
 593     custom code goes in self.vehicle_exit
 594 **/
 595 void vehicles_exit(float eject)
 596 {
 597     entity oldself;
 598     if(self.flags & FL_CLIENT)
 599     {
 600         oldself = self;
 601         self = self.vehicle;
 602     }
 603
 604         self.flags |= FL_NOTARGET;
 605
 606     if (self.owner)
 607     {
 608         msg_entity = self.owner;
 609         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 610         WriteEntity( MSG_ONE, self.owner);
 611
 612         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 613         WriteAngle(MSG_ONE, 0);                 // pich
 614         WriteAngle(MSG_ONE, self.angles_y);     // yaw
 615         WriteAngle(MSG_ONE, 0);                 // roll
 616
 617         setsize(self.owner, PL_MIN,PL_MAX);
 618
 619         self.owner.takedamage     = DAMAGE_AIM;
 620         self.owner.solid          = SOLID_SLIDEBOX;
 621         self.owner.movetype       = MOVETYPE_WALK;
 622         self.owner.effects        &~= EF_NODRAW;
 623         self.owner.alpha          = 1;
 624         self.owner.PlayerPhysplug = SUB_Null;
 625         self.owner.vehicle        = world;
 626         self.owner.view_ofs       = PL_VIEW_OFS;
 627         self.owner.event_damage   = PlayerDamage;
 628         self.owner.hud            = HUD_NORMAL;
 629         self.owner.switchweapon   = self.switchweapon;
 630         //self.owner.BUTTON_USE     = 0;
 631
 632         CSQCVehicleSetup(self.owner, HUD_NORMAL);
 633     }
 634
 635     if(self.deadflag == DEAD_NO)
 636         self.avelocity          = '0 0 0';
 637
 638     self.vehicle_hudmodel.viewmodelforclient = self;
 639         self.tur_head.nodrawtoclient             = world;
 640     vehicles_setreturn();
 641
 642     self.phase = time + 1;
 643
 644     if(!teamplay)
 645         self.team = 0;
 646     else
 647         self.team = self.tur_head.team;
 648
 649     if(self.owner.flagcarried)
 650     {
 651         self.owner.flagcarried.scale = 0.6;
 652         setattachment(self.owner.flagcarried, self.owner, "");
 653         setorigin(self.owner.flagcarried, FLAG_CARRY_POS);
 654     }
 655
 656     sound (self, CH_TRIGGER_SINGLE, "misc/null.wav", 1, ATTN_NORM);
 657     self.vehicle_exit(eject);
 658     self.owner = world;
 659     vehicles_reset_colors();
 660
 661     if(oldself)
 662         self = oldself;
 663 }
 664
 665
 666 void vehicles_regen(.float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time)
 667 {
 668     if(self.regen_field < field_max)
 669     if(self.timer + rpause < time)
 670     {
 671         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 672
 673         if(self.owner)
 674             self.owner.regen_field = (self.regen_field / field_max) * 100;
 675     }
 676 }
 677
 678 void shieldhit_think()
 679 {
 680     self.alpha -= 0.1;
 681     if (self.alpha <= 0)
 682     {
 683         //setmodel(self, "");
 684         self.alpha = -1;
 685     }
 686     else
 687     {
 688         self.nextthink = time + 0.1;
 689     }
 690 }
 691
 692 void vehicles_painframe()
 693 {
 694 //.float        pain_finished;                  //Added by Supajoe
 695
 696     if(self.owner.vehicle_health <= 50)
 697     if(self.pain_frame < time)
 698     {
 699         float _ftmp;
 700         _ftmp = self.owner.vehicle_health / 50;
 701         self.pain_frame = time + 0.1 + (random() * 0.5 * _ftmp);
 702         pointparticles(particleeffectnum("smoke_small"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 703
 704         if(self.vehicle_flags & VHF_DMGSHAKE)
 705             self.velocity += randomvec() * 30;
 706
 707         if(self.vehicle_flags & VHF_DMGROLL)
 708             if(self.vehicle_flags & VHF_DMGHEADROLL)
 709                 self.tur_head.angles += randomvec();
 710             else
 711                 self.angles += randomvec();
 712
 713     }
 714 }
 715
 716 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 717 {
 718     self.dmg_time = time;
 719
 720     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 721     {
 722         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 723         {
 724             self.vehicle_shieldent = spawn();
 725             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 726
 727             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 728             setattachment(self.vehicle_shieldent, self, "");
 729             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 730             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 731             self.vehicle_shieldent.think       = shieldhit_think;
 732         }
 733
 734         self.vehicle_shieldent.colormod    = '1 1 1';
 735         self.vehicle_shieldent.alpha       = 0.45;
 736         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 737         self.vehicle_shieldent.nextthink   = time;
 738
 739         self.vehicle_shield -= damage;
 740
 741         if(self.vehicle_shield < 0)
 742         {
 743             self.vehicle_health            -= fabs(self.vehicle_shield);
 744             self.vehicle_shieldent.colormod = '2 0 0';
 745             self.vehicle_shield             = 0;
 746             self.vehicle_shieldent.alpha    = 0.75;
 747
 748                 if(sound_allowed(MSG_BROADCAST, attacker))
 749                 spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);   // FIXME: PLACEHOLDER
 750         }
 751         else
 752                 if(sound_allowed(MSG_BROADCAST, attacker))
 753                 spamsound (self, CH_PAIN, "onslaught/electricity_explode.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 754
 755     }
 756     else
 757     {
 758         self.vehicle_health -= damage;
 759
 760         if(sound_allowed(MSG_BROADCAST, attacker))
 761             spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 762     }
 763
 764     self.velocity += force; // * (vlen(force) / self.mass);
 765
 766     if(self.vehicle_health <= 0)
 767     {
 768         if(self.owner)
 769             if(self.vehicle_flags & VHF_DEATHEJECT)
 770                 vehicles_exit(VHEF_EJECT);
 771             else
 772                 vehicles_exit(VHEF_RELESE);
 773
 774         self.vehicle_die();
 775         vehicles_setreturn();
 776     }
 777 }
 778
 779 void vehicles_clearrturn()
 780 {
 781     entity ret;
 782     // Remove "return helper", if any.
 783     ret = findchain(classname, "vehicle_return");
 784     while(ret)
 785     {
 786         if(ret.enemy == self)
 787         {
 788             ret.classname   = "";
 789             ret.think       = SUB_Remove;
 790             ret.nextthink   = time + 0.1;
 791
 792             if(ret.waypointsprite_attached)
 793                 WaypointSprite_Kill(ret.waypointsprite_attached);
 794
 795             return;
 796         }
 797         ret = ret.chain;
 798     }
 799 }
 800
 801 void vehicles_return()
 802 {
 803     pointparticles(particleeffectnum("teleport"), self.enemy.origin + '0 0 64', '0 0 0', 1);
 804
 805     self.enemy.think     = vehicles_spawn;
 806     self.enemy.nextthink = time;
 807
 808     if(self.waypointsprite_attached)
 809         WaypointSprite_Kill(self.waypointsprite_attached);
 810
 811     remove(self);
 812 }
 813
 814 void vehicles_showwp_goaway()
 815 {
 816     if(self.waypointsprite_attached)
 817         WaypointSprite_Kill(self.waypointsprite_attached);
 818
 819     remove(self);
 820
 821 }
 822
 823 void vehicles_showwp()
 824 {
 825     entity oldself;
 826     vector rgb;
 827
 828     if(self.cnt)
 829     {
 830         self.think      = vehicles_return;
 831         self.nextthink  = self.cnt;
 832     }
 833     else
 834     {
 835         self.think      = vehicles_return;
 836         self.nextthink  = time +1;
 837
 838         oldself = self;
 839         self = spawn();
 840         setmodel(self, "null");
 841         self.team = oldself.enemy.team;
 842         self.enemy = oldself.enemy;
 843         setorigin(self, oldself.enemy.pos1);
 844
 845         self.nextthink = time + 5;
 846         self.think = vehicles_showwp_goaway;
 847     }
 848
 849     if(teamplay && self.team)
 850             rgb = TeamColor(self.team);
 851     else
 852             rgb = '1 1 1';
 853     WaypointSprite_Spawn("vehicle", 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 854     if(self.waypointsprite_attached)
 855     {
 856         WaypointSprite_UpdateRule(self.waypointsprite_attached, self.enemy.team, SPRITERULE_DEFAULT);
 857         if(oldself == world)
 858             WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, self.nextthink);
 859         WaypointSprite_Ping(self.waypointsprite_attached);
 860     }
 861
 862     if(oldself != world)
 863         self = oldself;
 864 }
 865
 866 void vehicles_setreturn()
 867 {
 868     entity ret;
 869
 870     vehicles_clearrturn();
 871
 872     ret = spawn();
 873     ret.classname   = "vehicle_return";
 874     ret.enemy       = self;
 875     ret.team        = self.team;
 876     ret.think       = vehicles_showwp;
 877
 878     if(self.deadflag != DEAD_NO)
 879     {
 880         ret.cnt         = time + self.vehicle_respawntime;
 881         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 5);
 882     }
 883     else
 884     {
 885         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 1);
 886     }
 887
 888     setmodel(ret, "null");
 889     setorigin(ret, self.pos1 + '0 0 96');
 890
 891 }
 892
 893 void vehicles_configcheck(string  configname, float check_cvar)
 894 {
 895     if(check_cvar == 0)
 896         localcmd(strcat("exec ", configname, "\n"));
 897 }
 898
 899 void vehicles_reset_colors()
 900 {
 901     entity e;
 902     float _effects, _colormap;
 903     vector _glowmod, _colormod;
 904
 905     if(autocvar_g_nodepthtestplayers)
 906         _effects = EF_NODEPTHTEST;
 907
 908     if(autocvar_g_fullbrightplayers)
 909         _effects |= EF_FULLBRIGHT;
 910
 911     if(self.team)
 912         _colormap = 1024 + (self.team - 1) * 17;
 913     else
 914         _colormap = 1024;
 915
 916     _glowmod  = '0 0 0';
 917     _colormod = '0 0 0';
 918
 919     // Find all ents attacked to main model and setup effects, colormod etc.
 920     e = findchainentity(tag_entity, self);
 921     while(e)
 922     {
 923         if(e != self.vehicle_shieldent)
 924         {
 925             e.effects   = _effects; //  | EF_LOWPRECISION;
 926             e.colormod  = _colormod;
 927             e.colormap  = _colormap;
 928             e.alpha     = 1;
 929         }
 930         e = e.chain;
 931     }
 932
 933     self.vehicle_hudmodel.effects  = self.effects  = _effects; // | EF_LOWPRECISION;
 934     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
 935     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
 936     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 937
 938     self.alpha     = 1;
 939     self.avelocity = '0 0 0';
 940     self.velocity  = '0 0 0';
 941     self.effects   = _effects;
 942 }
 943
 944 float vehicle_initialize(string  net_name,
 945                          string  bodymodel,
 946                          string  topmodel,
 947                          string  hudmodel,
 948                          string  toptag,
 949                          string  hudtag,
 950                          string  viewtag,
 951                          float   vhud,
 952                          vector  min_s,
 953                          vector  max_s,
 954                          float   nodrop,
 955                          void()  spawnproc,
 956                          float   _respawntime,
 957                          float() physproc,
 958                          void()  enterproc,
 959                          void(float extflag) exitfunc,
 960                          void() dieproc,
 961                          void() thinkproc,
 962                          float  use_csqc)
 963 {
 964     addstat(STAT_HUD, AS_INT,  hud);
 965         addstat(STAT_VEHICLESTAT_HEALTH,  AS_INT, vehicle_health);
 966         addstat(STAT_VEHICLESTAT_SHIELD,  AS_INT, vehicle_shield);
 967         addstat(STAT_VEHICLESTAT_ENERGY,  AS_INT, vehicle_energy);
 968
 969         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT,   vehicle_ammo1);
 970         addstat(STAT_VEHICLESTAT_RELOAD1, AS_INT, vehicle_reload1);
 971
 972         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT,   vehicle_ammo2);
 973         addstat(STAT_VEHICLESTAT_RELOAD2, AS_INT, vehicle_reload2);
 974
 975     if(bodymodel == "")
 976         error("vehicles: missing bodymodel!");
 977
 978     if(hudmodel == "")
 979         error("vehicles: missing hudmodel!");
 980
 981     if(net_name == "")
 982         self.netname = self.classname;
 983     else
 984         self.netname = net_name;
 985
 986     if(self.team && !teamplay)
 987         self.team = 0;
 988
 989     self.vehicle_flags |= VHF_ISVEHICLE;
 990
 991     setmodel(self, bodymodel);
 992
 993     self.vehicle_viewport   = spawn();
 994     self.vehicle_hudmodel   = spawn();
 995     self.tur_head           = spawn();
 996     self.tur_head.owner     = self;
 997     self.takedamage         = DAMAGE_AIM;
 998     self.bot_attack         = TRUE;
 999     self.iscreature         = TRUE;
1000     self.damagedbycontents      = TRUE;
1001     self.hud                = vhud;
1002
1003     self.vehicle_die         = dieproc;
1004     self.vehicle_exit        = exitfunc;
1005     self.vehicle_enter       = enterproc;
1006     self.PlayerPhysplug      = physproc;
1007     self.event_damage        = vehicles_damage;
1008     self.touch               = vehicles_touch;
1009     self.think               = vehicles_spawn;
1010     self.nextthink           = time;
1011     self.vehicle_respawntime = _respawntime;
1012     self.vehicle_spawn       = spawnproc;
1013
1014     if(autocvar_g_nodepthtestplayers)
1015         self.effects = self.effects | EF_NODEPTHTEST;
1016
1017     if(autocvar_g_fullbrightplayers)
1018         self.effects = self.effects | EF_FULLBRIGHT;
1019
1020     setmodel(self.vehicle_hudmodel, hudmodel);
1021     setmodel(self.vehicle_viewport, "null");
1022
1023
1024     if(topmodel != "")
1025     {
1026         setmodel(self.tur_head, topmodel);
1027         setattachment(self.tur_head, self, toptag);
1028         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
1029         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1030     }
1031     else
1032     {
1033         setattachment(self.tur_head, self, "");
1034         setattachment(self.vehicle_hudmodel, self, hudtag);
1035         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1036     }
1037
1038     setsize(self, min_s, max_s);
1039     if not (nodrop)
1040     {
1041         setorigin(self, self.origin);
1042         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1043         setorigin(self, trace_endpos);
1044     }
1045
1046     self.pos1 = self.origin;
1047     self.pos2 = self.angles;
1048     self.tur_head.team = self.team;
1049
1050     return TRUE;
1051 }
1052
1053 void bugmenot()
1054 {
1055     self.vehicle_exit       = self.vehicle_exit;
1056     self.vehicle_enter      = self.vehicle_exit;
1057     self.vehicle_die        = self.vehicle_exit;
1058     self.vehicle_spawn      = self.vehicle_exit;
1059     self.AuxiliaryXhair     = self.AuxiliaryXhair;
1060 }