qcsrc/server/vehicles/bumblebee.qc

   1 #define BRG_SETUP 2
   2 #define BRG_START 4
   3 #define BRG_END 8
   4
   5 #ifdef SVQC
   6 // Auto cvars
   7 float autocvar_g_vehicle_bumblebee_speed_forward;
   8 float autocvar_g_vehicle_bumblebee_speed_strafe;
   9 float autocvar_g_vehicle_bumblebee_speed_up;
  10 float autocvar_g_vehicle_bumblebee_speed_down;
  11 float autocvar_g_vehicle_bumblebee_turnspeed;
  12 float autocvar_g_vehicle_bumblebee_pitchspeed;
  13 float autocvar_g_vehicle_bumblebee_pitchlimit;
  14 float autocvar_g_vehicle_bumblebee_friction;
  15
  16 float autocvar_g_vehicle_bumblebee_energy;
  17 float autocvar_g_vehicle_bumblebee_energy_regen;
  18 float autocvar_g_vehicle_bumblebee_energy_regen_pause;
  19
  20 float autocvar_g_vehicle_bumblebee_health;
  21 float autocvar_g_vehicle_bumblebee_health_regen;
  22 float autocvar_g_vehicle_bumblebee_health_regen_pause;
  23
  24 float autocvar_g_vehicle_bumblebee_shield;
  25 float autocvar_g_vehicle_bumblebee_shield_regen;
  26 float autocvar_g_vehicle_bumblebee_shield_regen_pause;
  27
  28 float autocvar_g_vehicle_bumblebee_cannon_cost;
  29 float autocvar_g_vehicle_bumblebee_cannon_damage;
  30 float autocvar_g_vehicle_bumblebee_cannon_radius;
  31 float autocvar_g_vehicle_bumblebee_cannon_refire;
  32 float autocvar_g_vehicle_bumblebee_cannon_speed;
  33 float autocvar_g_vehicle_bumblebee_cannon_spread;
  34 float autocvar_g_vehicle_bumblebee_cannon_force;
  35
  36 float autocvar_g_vehicle_bumblebee_cannon_ammo;
  37 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen;
  38 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause;
  39
  40 var float autocvar_g_vehicle_bumblebee_cannon_lock = 0;
  41
  42 float autocvar_g_vehicle_bumblebee_cannon_turnspeed;
  43 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down;
  44 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up;
  45 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
  46 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
  47
  48
  49 float autocvar_g_vehicle_bumblebee_raygun_turnspeed;
  50 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down;
  51 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up;
  52 float autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides;
  53
  54 float autocvar_g_vehicle_bumblebee_raygun_range;
  55 float autocvar_g_vehicle_bumblebee_raygun_dps;
  56 float autocvar_g_vehicle_bumblebee_raygun_aps;
  57 float autocvar_g_vehicle_bumblebee_raygun_fps;
  58
  59 float autocvar_g_vehicle_bumblebee_raygun;
  60 float autocvar_g_vehicle_bumblebee_healgun_hps;
  61 float autocvar_g_vehicle_bumblebee_healgun_hmax;
  62 float autocvar_g_vehicle_bumblebee_healgun_aps;
  63 float autocvar_g_vehicle_bumblebee_healgun_amax;
  64 float autocvar_g_vehicle_bumblebee_healgun_sps;
  65 float autocvar_g_vehicle_bumblebee_healgun_locktime;
  66
  67 float autocvar_g_vehicle_bumblebee_respawntime;
  68
  69 float autocvar_g_vehicle_bumblebee_blowup_radius;
  70 float autocvar_g_vehicle_bumblebee_blowup_coredamage;
  71 float autocvar_g_vehicle_bumblebee_blowup_edgedamage;
  72 float autocvar_g_vehicle_bumblebee_blowup_forceintensity;
  73 var vector autocvar_g_vehicle_bumblebee_bouncepain;
  74
  75 var float autocvar_g_vehicle_bumblebee = 0;
  76
  77
  78 float bumble_raygun_send(entity to, float sf);
  79
  80 #define BUMB_MIN '-130 -130 -130'
  81 #define BUMB_MAX '130 130 130'
  82
  83 void bumb_fire_cannon(entity _gun, string _tagname, entity _owner)
  84 {
  85         vector v = gettaginfo(_gun, gettagindex(_gun, _tagname));
  86         vehicles_projectile("bigplasma_muzzleflash", "weapons/flacexp3.wav",
  87                                                 v, normalize(v_forward + randomvec() * autocvar_g_vehicle_bumblebee_cannon_spread) * autocvar_g_vehicle_bumblebee_cannon_speed,
  88                                                 autocvar_g_vehicle_bumblebee_cannon_damage, autocvar_g_vehicle_bumblebee_cannon_radius, autocvar_g_vehicle_bumblebee_cannon_force,  0,
  89                                                 DEATH_BUMB_GUN, PROJECTILE_BUMBLE_GUN, 0, TRUE, TRUE, _owner);
  90 }
  91
  92 float bumb_gunner_frame()
  93 {
  94         entity vehic    = self.vehicle.owner;
  95         entity gun      = self.vehicle;
  96         entity gunner   = self;
  97         self = vehic;
  98
  99
 100
 101
 102         vehic.solid = SOLID_NOT;
 103         //setorigin(gunner, vehic.origin);
 104         gunner.velocity = vehic.velocity;
 105
 106         float _in, _out;
 107         vehic.angles_x *= -1;
 108         makevectors(vehic.angles);
 109         vehic.angles_x *= -1;
 110         if((gun == vehic.gun1))
 111         {
 112                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
 113                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
 114                 setorigin(gunner, vehic.origin + v_up * -16 + v_forward * -16 + v_right * 128);
 115         }
 116         else
 117         {
 118                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
 119                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
 120                 setorigin(gunner, vehic.origin + v_up * -16 + v_forward * -16 + v_right * -128);
 121         }
 122
 123         crosshair_trace(gunner);
 124         vector _ct = trace_endpos;
 125         vector ad;
 126
 127         if(autocvar_g_vehicle_bumblebee_cannon_lock)
 128         {
 129                 if(gun.lock_time < time)
 130                         gun.enemy = world;
 131
 132                 if(trace_ent)
 133                         if(trace_ent.movetype)
 134                                 if(trace_ent.takedamage)
 135                                         if(!trace_ent.deadflag)
 136                                         {
 137                                                 if(teamplay)
 138                                                 {
 139                                                         if(trace_ent.team != gunner.team)
 140                                                         {
 141                                                                 gun.enemy = trace_ent;
 142                                                                 gun.lock_time = time + 5;
 143                                                         }
 144                                                 }
 145                                                 else
 146                                                 {
 147                                                         gun.enemy = trace_ent;
 148                                                         gun.lock_time = time + 5;
 149                                                 }
 150                                         }
 151         }
 152
 153         if(gun.enemy)
 154         {
 155                 float i, distance, impact_time;
 156
 157                 vector vf = real_origin(gun.enemy);
 158                 vector _vel = gun.enemy.velocity;
 159                 if(gun.enemy.movetype == MOVETYPE_WALK)
 160                         _vel_z *= 0.1;
 161
 162
 163                 ad = vf;
 164                 for(i = 0; i < 4; ++i)
 165                 {
 166                         distance = vlen(ad - gunner.origin);
 167                         impact_time = distance / autocvar_g_vehicle_bumblebee_cannon_speed;
 168                         ad = vf + _vel * impact_time;
 169                 }
 170                 trace_endpos = ad;
 171
 172
 173                 UpdateAuxiliaryXhair(gunner, ad, '1 0 1', 1);
 174                 vehicle_aimturret(vehic, trace_endpos, gun, "fire",
 175                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 176                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 177
 178         }
 179         else
 180                 vehicle_aimturret(vehic, _ct, gun, "fire",
 181                                                   autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 182                                                   _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 183
 184         if(gunner.BUTTON_ATCK)
 185                 if(time > gun.attack_finished_single)
 186                         if(gun.vehicle_energy >= autocvar_g_vehicle_bumblebee_cannon_cost)
 187                         {
 188                                 gun.vehicle_energy -= autocvar_g_vehicle_bumblebee_cannon_cost;
 189                                 bumb_fire_cannon(gun, "fire", gunner);
 190                                 gun.delay = time;
 191                                 gun.attack_finished_single = time + autocvar_g_vehicle_bumblebee_cannon_refire;
 192                         }
 193
 194         VEHICLE_UPDATE_PLAYER(gunner, health, bumblebee);
 195
 196         if(vehic.vehicle_flags & VHF_HASSHIELD)
 197                 VEHICLE_UPDATE_PLAYER(gunner, shield, bumblebee);
 198
 199         ad = gettaginfo(gun, gettagindex(gun, "fire"));
 200         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, gun);
 201
 202         UpdateAuxiliaryXhair(gunner, trace_endpos, ('1 0 0' * gunner.vehicle_reload1) + ('0 1 0' *(1 - gunner.vehicle_reload1)), 0);
 203
 204         if(vehic.owner)
 205                 UpdateAuxiliaryXhair(vehic.owner, trace_endpos, ('1 0 0' * gunner.vehicle_reload1) + ('0 1 0' *(1 - gunner.vehicle_reload1)), ((gunner == vehic.gunner1) ? 1 : 2));
 206
 207         vehic.solid = SOLID_BBOX;
 208         gunner.BUTTON_ATCK = gunner.BUTTON_ATCK2 = gunner.BUTTON_CROUCH = 0;
 209         gunner.vehicle_energy = (gun.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 210
 211         self = gunner;
 212         return 1;
 213 }
 214
 215 void bumb_gunner_exit(float _exitflag)
 216 {
 217
 218
 219         if(clienttype(self) == CLIENTTYPE_REAL)
 220         {
 221                 msg_entity = self;
 222                 WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 223                 WriteEntity(MSG_ONE, self);
 224
 225                 WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 226                 WriteAngle(MSG_ONE, 0);
 227                 WriteAngle(MSG_ONE, self.vehicle.angles_y);
 228                 WriteAngle(MSG_ONE, 0);
 229         }
 230
 231         CSQCVehicleSetup(self, HUD_NORMAL);
 232         setsize(self, PL_MIN, PL_MAX);
 233
 234         self.takedamage     = DAMAGE_AIM;
 235         self.solid          = SOLID_SLIDEBOX;
 236         self.movetype       = MOVETYPE_WALK;
 237         self.effects        &~= EF_NODRAW;
 238         self.alpha          = 1;
 239         self.PlayerPhysplug = SUB_Null;
 240         self.view_ofs       = PL_VIEW_OFS;
 241         self.event_damage   = PlayerDamage;
 242         self.hud            = HUD_NORMAL;
 243         self.switchweapon   = self.vehicle.switchweapon;
 244
 245         // FIXCTF TODO
 246
 247         self.vehicle.vehicle_hudmodel.viewmodelforclient = self.vehicle;
 248
 249         fixedmakevectors(self.vehicle.owner.angles);
 250
 251         if(self == self.vehicle.owner.gunner1)
 252         {
 253                 self.vehicle.owner.gunner1 = world;
 254         }
 255         else if(self == self.vehicle.owner.gunner2)
 256         {
 257                 self.vehicle.owner.gunner2 = world;
 258                 v_right *= -1;
 259         }
 260         else
 261                 dprint("^1self != gunner1 or gunner2, this is a BIG PROBLEM, tell tZork this happend.\n");
 262
 263         vector spot = self.vehicle.owner.origin + + v_up * 128 + v_right * 300;
 264         spot = vehicles_findgoodexit(spot);
 265         //setorigin(self , spot);
 266
 267         self.velocity = 0.75 * self.vehicle.owner.velocity + normalize(spot - self.vehicle.owner.origin) * 200;
 268         self.velocity_z += 10;
 269
 270         self.vehicle.phase = time + 5;
 271         self.vehicle        = world;
 272 }
 273
 274 float bumb_gunner_enter()
 275 {
 276         RemoveGrapplingHook(other);
 277         entity _gun, _gunner;
 278         if(!self.gunner1)
 279         {
 280                 _gun = self.gun1;
 281                 _gunner = self.gunner1;
 282                 self.gunner1 = other;
 283         }
 284         else if(!self.gunner2)
 285         {
 286                 _gun = self.gun2;
 287                 _gunner = self.gunner2;
 288                 self.gunner2 = other;
 289         }
 290         else
 291         {
 292                 dprint("^1ERROR:^7Tried to enter a fully occupied vehicle!\n");
 293                 return FALSE;
 294         }
 295
 296         _gunner            = other;
 297         _gunner.vehicle    = _gun;
 298         _gun.switchweapon  = other.switchweapon;
 299         _gun.vehicle_exit  = bumb_gunner_exit;
 300
 301         other.angles            = self.angles;
 302         other.takedamage        = DAMAGE_NO;
 303         other.solid             = SOLID_NOT;
 304         other.movetype          = MOVETYPE_NOCLIP;
 305         other.alpha             = -1;
 306         other.event_damage      = SUB_Null;
 307         other.view_ofs          = '0 0 0';
 308         other.hud               = _gun.hud;
 309         other.PlayerPhysplug    = _gun.PlayerPhysplug;
 310         other.vehicle_ammo1     = self.vehicle_ammo1;
 311         other.vehicle_ammo2     = self.vehicle_ammo2;
 312         other.vehicle_reload1   = self.vehicle_reload1;
 313         other.vehicle_reload2   = self.vehicle_reload2;
 314         other.vehicle_energy    = self.vehicle_energy;
 315         other.PlayerPhysplug    = bumb_gunner_frame;
 316         other.flags             &~= FL_ONGROUND;
 317
 318         msg_entity = other;
 319         WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 320         WriteEntity(MSG_ONE, _gun.vehicle_viewport);
 321         WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 322         WriteAngle(MSG_ONE, _gun.angles_x + self.angles_x);    // tilt
 323         WriteAngle(MSG_ONE, _gun.angles_y + self.angles_y);    // yaw
 324         WriteAngle(MSG_ONE, 0);                             // roll
 325         _gun.vehicle_hudmodel.viewmodelforclient = other;
 326
 327         CSQCVehicleSetup(other, other.hud);
 328
 329     // FIXCTF TODO
 330
 331         return TRUE;
 332 }
 333
 334 float vehicles_valid_pilot()
 335 {
 336         if(other.classname != "player")
 337                 return FALSE;
 338
 339         if(other.deadflag != DEAD_NO)
 340                 return FALSE;
 341
 342         if(other.vehicle != world)
 343                 return FALSE;
 344
 345         if(clienttype(other) != CLIENTTYPE_REAL)
 346                 if(!autocvar_g_vehicles_allow_bots)
 347                         return FALSE;
 348
 349         if(teamplay && other.team != self.team)
 350                 return FALSE;
 351
 352         return TRUE;
 353 }
 354
 355 void bumb_touch()
 356 {
 357
 358         if(self.gunner1 != world && self.gunner2 != world)
 359         {
 360                 vehicles_touch();
 361                 return;
 362         }
 363
 364         if(vehicles_valid_pilot())
 365         {
 366                 if(self.gun1.phase <= time)
 367                         if(bumb_gunner_enter())
 368                                 return;
 369
 370                 if(self.gun2.phase <= time)
 371                         if(bumb_gunner_enter())
 372                                 return;
 373         }
 374
 375         vehicles_touch();
 376 }
 377
 378 void bumb_regen()
 379 {
 380         if(self.gun1.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 381                 self.gun1.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 382                                                                            self.gun1.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 383
 384         if(self.gun2.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time)
 385                 self.gun2.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 386                                                                            self.gun2.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * frametime);
 387
 388         if(self.vehicle_flags  & VHF_SHIELDREGEN)
 389                 vehicles_regen(self.dmg_time, vehicle_shield, autocvar_g_vehicle_bumblebee_shield, autocvar_g_vehicle_bumblebee_shield_regen_pause, autocvar_g_vehicle_bumblebee_shield_regen, frametime, TRUE);
 390
 391         if(self.vehicle_flags  & VHF_HEALTHREGEN)
 392                 vehicles_regen(self.dmg_time, vehicle_health, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_health_regen_pause, autocvar_g_vehicle_bumblebee_health_regen, frametime, FALSE);
 393
 394         if(self.vehicle_flags  & VHF_ENERGYREGEN)
 395                 vehicles_regen(self.wait, vehicle_energy, autocvar_g_vehicle_bumblebee_energy, autocvar_g_vehicle_bumblebee_energy_regen_pause, autocvar_g_vehicle_bumblebee_energy_regen, frametime, FALSE);
 396
 397 }
 398
 399 float bumb_pilot_frame()
 400 {
 401         entity pilot, vehic;
 402         vector newvel;
 403
 404         pilot = self;
 405         vehic = self.vehicle;
 406         self   = vehic;
 407
 408
 409         if(vehic.deadflag != DEAD_NO)
 410         {
 411                 self = pilot;
 412                 pilot.BUTTON_ATCK = pilot.BUTTON_ATCK2 = 0;
 413                 return 1;
 414         }
 415
 416         bumb_regen();
 417
 418         crosshair_trace(pilot);
 419
 420         vector vang;
 421         float ftmp;
 422
 423         vang = vehic.angles;
 424         newvel = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 425         vang_x *= -1;
 426         newvel_x *= -1;
 427         if(newvel_x > 180)  newvel_x -= 360;
 428         if(newvel_x < -180) newvel_x += 360;
 429         if(newvel_y > 180)  newvel_y -= 360;
 430         if(newvel_y < -180) newvel_y += 360;
 431
 432         ftmp = shortangle_f(pilot.v_angle_y - vang_y, vang_y);
 433         if(ftmp > 180)  ftmp -= 360;
 434         if(ftmp < -180) ftmp += 360;
 435         vehic.avelocity_y = bound(-autocvar_g_vehicle_bumblebee_turnspeed, ftmp + vehic.avelocity_y * 0.9, autocvar_g_vehicle_bumblebee_turnspeed);
 436
 437         // Pitch
 438         ftmp = 0;
 439         if(pilot.movement_x > 0 && vang_x < autocvar_g_vehicle_bumblebee_pitchlimit)
 440                 ftmp = 4;
 441         else if(pilot.movement_x < 0 && vang_x > -autocvar_g_vehicle_bumblebee_pitchlimit)
 442                 ftmp = -8;
 443
 444         newvel_x = bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel_x , autocvar_g_vehicle_bumblebee_pitchlimit);
 445         ftmp = vang_x - bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel_x + ftmp, autocvar_g_vehicle_bumblebee_pitchlimit);
 446         vehic.avelocity_x = bound(-autocvar_g_vehicle_bumblebee_pitchspeed, ftmp + vehic.avelocity_x * 0.9, autocvar_g_vehicle_bumblebee_pitchspeed);
 447
 448         vehic.angles_x = anglemods(vehic.angles_x);
 449         vehic.angles_y = anglemods(vehic.angles_y);
 450         vehic.angles_z = anglemods(vehic.angles_z);
 451
 452         makevectors('0 1 0' * vehic.angles_y);
 453         newvel = vehic.velocity * -autocvar_g_vehicle_bumblebee_friction;
 454
 455         if(pilot.movement_x != 0)
 456         {
 457                 if(pilot.movement_x > 0)
 458                         newvel += v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 459                 else if(pilot.movement_x < 0)
 460                         newvel -= v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 461         }
 462
 463         if(pilot.movement_y != 0)
 464         {
 465                 if(pilot.movement_y < 0)
 466                         newvel -= v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 467                 else if(pilot.movement_y > 0)
 468                         newvel += v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 469                 ftmp = newvel * v_right;
 470                 ftmp *= frametime * 0.1;
 471                 vehic.angles_z = bound(-15, vehic.angles_z + ftmp, 15);
 472         }
 473         else
 474         {
 475                 vehic.angles_z *= 0.95;
 476                 if(vehic.angles_z >= -1 && vehic.angles_z <= -1)
 477                         vehic.angles_z = 0;
 478         }
 479
 480         if(pilot.BUTTON_CROUCH)
 481                 newvel -=   v_up * autocvar_g_vehicle_bumblebee_speed_down;
 482         else if(pilot.BUTTON_JUMP)
 483                 newvel +=  v_up * autocvar_g_vehicle_bumblebee_speed_up;
 484
 485         vehic.velocity  += newvel * frametime;
 486         pilot.velocity = pilot.movement  = vehic.velocity;
 487
 488
 489         if(autocvar_g_vehicle_bumblebee_healgun_locktime)
 490         {
 491                 if(vehic.tur_head.lock_time < time || vehic.tur_head.enemy.deadflag)
 492                         vehic.tur_head.enemy = world;
 493
 494                 if(trace_ent)
 495                 if(trace_ent.movetype)
 496                 if(trace_ent.takedamage)
 497                 if(!trace_ent.deadflag)
 498                 {
 499                         if(teamplay)
 500                         {
 501                                 if(trace_ent.team == pilot.team)
 502                                 {
 503                                         vehic.tur_head.enemy = trace_ent;
 504                                         vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 505                                 }
 506                         }
 507                         else
 508                         {
 509                                 vehic.tur_head.enemy = trace_ent;
 510                                 vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 511                         }
 512                 }
 513
 514                 if(vehic.tur_head.enemy)
 515                 {
 516                         trace_endpos = real_origin(vehic.tur_head.enemy);
 517                         UpdateAuxiliaryXhair(pilot, trace_endpos, '0 0.75 0', 0);
 518                 }
 519         }
 520
 521         vang = vehicle_aimturret(vehic, trace_endpos, self.gun3, "fire",
 522                                           autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down * -1,  autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up,
 523                                           autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides * -1,  autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides,  autocvar_g_vehicle_bumblebee_raygun_turnspeed);
 524
 525         if((pilot.BUTTON_ATCK || pilot.BUTTON_ATCK2) && (vehic.vehicle_energy > autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime || autocvar_g_vehicle_bumblebee_raygun == 0))
 526         {
 527                 vehic.gun3.enemy.realowner = pilot;
 528                 vehic.gun3.enemy.effects &~= EF_NODRAW;
 529
 530                 vehic.gun3.enemy.hook_start = gettaginfo(vehic.gun3, gettagindex(vehic.gun3, "fire"));
 531                 vehic.gun3.enemy.SendFlags |= BRG_START;
 532
 533                 traceline(vehic.gun3.enemy.hook_start, vehic.gun3.enemy.hook_start + v_forward * autocvar_g_vehicle_bumblebee_raygun_range, MOVE_NORMAL, vehic);
 534
 535                 if(trace_ent)
 536                 {
 537                         if(autocvar_g_vehicle_bumblebee_raygun)
 538                         {
 539                                 Damage(trace_ent, vehic, pilot, autocvar_g_vehicle_bumblebee_raygun_dps * sys_frametime, DEATH_GENERIC, trace_endpos, v_forward * autocvar_g_vehicle_bumblebee_raygun_fps * sys_frametime);
 540                                 vehic.vehicle_energy -= autocvar_g_vehicle_bumblebee_raygun_aps * sys_frametime;
 541                         }
 542                         else
 543                         {
 544                                 if(trace_ent.deadflag == DEAD_NO)
 545                                         if((teamplay && trace_ent.team == pilot.team) || !teamplay)
 546                                         {
 547
 548                                                 if(trace_ent.vehicle_flags & VHF_ISVEHICLE)
 549                                                 {
 550                                                         if(autocvar_g_vehicle_bumblebee_healgun_sps && trace_ent.vehicle_health <= trace_ent.tur_health)
 551                                                                 trace_ent.vehicle_shield = min(trace_ent.vehicle_shield + autocvar_g_vehicle_bumblebee_healgun_sps * frametime, trace_ent.tur_head.tur_health);
 552
 553                                                         if(autocvar_g_vehicle_bumblebee_healgun_hps)
 554                                                                 trace_ent.vehicle_health = min(trace_ent.vehicle_health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.tur_health);
 555                                                 }
 556                                                 else if(trace_ent.flags & FL_CLIENT)
 557                                                 {
 558                                                         if(trace_ent.health <= autocvar_g_vehicle_bumblebee_healgun_hmax && autocvar_g_vehicle_bumblebee_healgun_hps)
 559                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 560
 561                                                         if(trace_ent.armorvalue <= autocvar_g_vehicle_bumblebee_healgun_amax && autocvar_g_vehicle_bumblebee_healgun_aps)
 562                                                                 trace_ent.armorvalue = min(trace_ent.armorvalue + autocvar_g_vehicle_bumblebee_healgun_aps * frametime, autocvar_g_vehicle_bumblebee_healgun_amax);
 563
 564                                                         trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, autocvar_g_vehicle_bumblebee_healgun_hmax);
 565                                                 }
 566                                                 else if(trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 567                                                 {
 568                                                         if(trace_ent.health  <= trace_ent.tur_health && autocvar_g_vehicle_bumblebee_healgun_hps)
 569                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * frametime, trace_ent.tur_health);
 570                                                         //else ..hmmm what? ammo?
 571
 572                                                         trace_ent.SendFlags |= TNSF_STATUS;
 573                                                 }
 574                                         }
 575                         }
 576                 }
 577
 578                 vehic.gun3.enemy.hook_end = trace_endpos;
 579                 setorigin(vehic.gun3.enemy, trace_endpos);
 580                 vehic.gun3.enemy.SendFlags |= BRG_END;
 581
 582                 vehic.wait = time + 1;
 583         }
 584         else
 585                 vehic.gun3.enemy.effects |= EF_NODRAW;
 586         /*{
 587                 if(vehic.gun3.enemy)
 588                         remove(vehic.gun3.enemy);
 589
 590                 vehic.gun3.enemy = world;
 591         }
 592         */
 593
 594         VEHICLE_UPDATE_PLAYER(pilot, health, bumblebee);
 595         VEHICLE_UPDATE_PLAYER(pilot, energy, bumblebee);
 596
 597         pilot.vehicle_ammo1 = (vehic.gun1.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 598         pilot.vehicle_ammo2 = (vehic.gun2.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 599
 600         if(vehic.vehicle_flags & VHF_HASSHIELD)
 601                 VEHICLE_UPDATE_PLAYER(pilot, shield, bumblebee);
 602
 603         vehic.angles_x *= -1;
 604         makevectors(vehic.angles);
 605         vehic.angles_x *= -1;
 606         setorigin(pilot, vehic.origin + v_up * 48 + v_forward * 160);
 607
 608         pilot.BUTTON_ATCK = pilot.BUTTON_ATCK2 = pilot.BUTTON_CROUCH = 0;
 609         self = pilot;
 610
 611         return 1;
 612 }
 613
 614 void bumb_think()
 615 {
 616         self.movetype = MOVETYPE_TOSS;
 617
 618                 //self.velocity = self.velocity * 0.5;
 619         self.angles_z *= 0.8;
 620         self.angles_x *= 0.8;
 621
 622         self.nextthink = time + 0.05;
 623
 624         if(!self.owner)
 625         {
 626                 entity oldself = self;
 627                 if(self.gunner1)
 628                 {
 629                         self = self.gunner1;
 630                         oldself.gun1.vehicle_exit(VHEF_EJECT);
 631                         entity oldother = other;
 632                         other = self;
 633                         self = oldself;
 634                         self.phase = 0;
 635                         self.touch();
 636                         other = oldother;
 637                         return;
 638                 }
 639
 640                 if(self.gunner2)
 641                 {
 642                         self = self.gunner2;
 643                         oldself.gun2.vehicle_exit(VHEF_EJECT);
 644                         entity oldother = other;
 645                         other = self;
 646                         self = oldself;
 647                         self.phase = 0;
 648                         self.touch();
 649                         other = oldother;
 650                         return;
 651                 }
 652         }
 653
 654 }
 655
 656 void bumb_enter()
 657 {
 658         self.touch = bumb_touch;
 659         self.nextthink = 0;
 660         self.movetype = MOVETYPE_BOUNCEMISSILE;
 661         //setattachment(self.owner, self.vehicle_viewport, "");
 662 }
 663
 664 void bumb_exit(float eject)
 665 {
 666         self.touch = vehicles_touch;
 667         self.think = bumb_think;
 668         self.nextthink = time;
 669
 670         if(!self.owner)
 671                 return;
 672
 673         fixedmakevectors(self.angles);
 674         vector spot;
 675         if(vlen(self.velocity) > autocvar_g_vehicle_bumblebee_speed_forward * 0.5)
 676                 spot = self.origin + v_up * 128 + v_forward * 200;
 677         else
 678                 spot = self.origin + v_up * 128 - v_forward * 200;
 679
 680         spot = vehicles_findgoodexit(spot);
 681
 682
 683         self.owner.velocity = 0.75 * self.vehicle.velocity + normalize(spot - self.vehicle.origin) * 200;
 684         self.owner.velocity_z += 10;
 685         setorigin(self.owner, spot);
 686
 687         /*if(eject)
 688         {
 689             spot = self.origin + v_forward * 100 + '0 0 64';
 690             spot = vehicles_findgoodexit(spot);
 691             //setorigin(self.owner , spot);
 692             self.owner.velocity = (v_up + v_forward * 0.25) * 250;
 693             self.owner.oldvelocity = self.owner.velocity;
 694         }
 695         else
 696         {
 697                 if(vlen(self.velocity) > autocvar_g_vehicle_bumblebee_speed_forward * 0.5)
 698                 {
 699                         if(vlen(self.velocity) > autocvar_sv_maxairspeed)
 700                                 self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed;
 701                         else
 702                                 self.owner.velocity = self.velocity + v_forward * 100;
 703
 704                         self.owner.velocity_z += 200;
 705                         spot = self.origin + v_forward * 128 + '0 0 32';
 706                         spot = vehicles_findgoodexit(spot);
 707                 }
 708                 else
 709                 {
 710                         self.owner.velocity = self.velocity * 0.5;
 711                         self.owner.velocity_z += 10;
 712                         spot = self.origin - v_forward * 300 + '0 0 32';
 713                         spot = vehicles_findgoodexit(spot);
 714                 }
 715             self.owner.oldvelocity = self.owner.velocity;
 716             //setorigin(self.owner , spot);
 717         }
 718         */
 719
 720         antilag_clear(self.owner);
 721     self.owner = world;
 722 }
 723
 724 void bumb_blowup()
 725 {
 726         RadiusDamage(self, self.enemy, autocvar_g_vehicle_bumblebee_blowup_coredamage,
 727                                  autocvar_g_vehicle_bumblebee_blowup_edgedamage,
 728                                  autocvar_g_vehicle_bumblebee_blowup_radius, self,
 729                                  autocvar_g_vehicle_bumblebee_blowup_forceintensity,
 730                                  DEATH_WAKIBLOWUP, world);
 731
 732         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 733         pointparticles(particleeffectnum("explosion_large"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 734
 735         if(self.owner.deadflag == DEAD_DYING)
 736                 self.owner.deadflag = DEAD_DEAD;
 737
 738         remove(self);
 739 }
 740
 741 void bumb_diethink()
 742 {
 743         if(time >= self.wait)
 744                 self.think = bumb_blowup;
 745
 746         if(random() < 0.1)
 747         {
 748                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 749                 pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 750         }
 751
 752         self.nextthink = time + 0.1;
 753 }
 754
 755 void bumb_die()
 756 {
 757         entity oldself = self;
 758
 759         // Hide beam
 760         if(self.gun3.enemy || !wasfreed(self.gun3.enemy))
 761                 self.gun3.enemy.effects |= EF_NODRAW;
 762
 763         if(self.gunner1)
 764         {
 765                 self = self.gunner1;
 766                 oldself.gun1.vehicle_exit(VHEF_EJECT);
 767                 self = oldself;
 768         }
 769
 770         if(self.gunner2)
 771         {
 772                 self = self.gunner2;
 773                 oldself.gun2.vehicle_exit(VHEF_EJECT);
 774                 self = oldself;
 775         }
 776
 777         self.vehicle_exit(VHEF_EJECT);
 778
 779         fixedmakevectors(self.angles);
 780         vehicle_tossgib(self.gun1, self.velocity + v_right * 300 + v_up * 100 + randomvec() * 200, "cannon_right", rint(random()), rint(random()), 6, randomvec() * 200);
 781         vehicle_tossgib(self.gun2, self.velocity + v_right * -300 + v_up * 100 + randomvec() * 200, "cannon_left", rint(random()), rint(random()), 6, randomvec() * 200);
 782         vehicle_tossgib(self.gun3, self.velocity + v_forward * 300 + v_up * -100 + randomvec() * 200, "raygun", rint(random()), rint(random()), 6, randomvec() * 300);
 783
 784         entity _body = vehicle_tossgib(self, self.velocity + randomvec() * 200, "", rint(random()), rint(random()), 6, randomvec() * 100);
 785
 786         if(random() > 0.5)
 787                 _body.touch = bumb_blowup;
 788         else
 789                 _body.touch = SUB_Null;
 790
 791         _body.think = bumb_diethink;
 792         _body.nextthink = time;
 793         _body.wait = time + 2 + (random() * 8);
 794         _body.owner = self;
 795         _body.enemy = self.enemy;
 796
 797         pointparticles(particleeffectnum("explosion_medium"), findbetterlocation(self.origin, 16), '0 0 0', 1);
 798
 799         self.health                     = 0;
 800         self.event_damage       = SUB_Null;
 801         self.solid                      = SOLID_CORPSE;
 802         self.takedamage         = DAMAGE_NO;
 803         self.deadflag           = DEAD_DYING;
 804         self.movetype           = MOVETYPE_NONE;
 805         self.effects            = EF_NODRAW;
 806         self.colormod           = '0 0 0';
 807         self.avelocity          = '0 0 0';
 808         self.velocity           = '0 0 0';
 809         self.touch                      = SUB_Null;
 810         self.nextthink          = 0;
 811
 812         setorigin(self, self.pos1);
 813
 814 }
 815
 816 void bumb_impact()
 817 {
 818     if(autocvar_g_vehicle_bumblebee_bouncepain_x)
 819         vehilces_impact(autocvar_g_vehicle_bumblebee_bouncepain_x,
 820                                                 autocvar_g_vehicle_bumblebee_bouncepain_y,
 821                                                 autocvar_g_vehicle_bumblebee_bouncepain_z);
 822 }
 823
 824 void bumb_spawn(float _f)
 825 {
 826         /*
 827         float i;
 828         for(i=1; gettaginfo(self.gun1, i), gettaginfo_name; ++i)
 829         {
 830
 831             dprint(" ------- ^1gettaginfo_name^2(",ftos(i),") ^3=", gettaginfo_name, "\n");
 832         }
 833         */
 834         if(!self.gun1)
 835         {
 836                 // for some reason, autosizing of the shiled entity refuses to work for this one so set it up in advance.
 837                 self.vehicle_shieldent = spawn();
 838                 self.vehicle_shieldent.effects = EF_LOWPRECISION;
 839                 setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 840                 setattachment(self.vehicle_shieldent, self, "");
 841                 setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 842                 self.vehicle_shieldent.scale       = 512 / vlen(self.maxs - self.mins);
 843                 self.vehicle_shieldent.think       = shieldhit_think;
 844                 self.vehicle_shieldent.alpha = -1;
 845                 self.vehicle_shieldent.effects = EF_LOWPRECISION | EF_NODRAW;
 846
 847                 self.gun1 = spawn();
 848                 self.gun2 = spawn();
 849                 self.gun3 = spawn();
 850
 851                 self.vehicle_flags |= VHF_MULTISLOT;
 852
 853                 self.gun1.owner = self;
 854                 self.gun2.owner = self;
 855                 self.gun3.owner = self;
 856
 857                 setmodel(self.gun1, "models/vehicles/bumblebee_plasma_right.dpm");
 858                 setmodel(self.gun2, "models/vehicles/bumblebee_plasma_left.dpm");
 859                 setmodel(self.gun3, "models/vehicles/bumblebee_ray.dpm");
 860
 861                 setattachment(self.gun1, self, "cannon_right");
 862                 setattachment(self.gun2, self, "cannon_left");
 863
 864                 // Angled bones are no fun, messes up gun-aim; so work arround it.
 865                 self.gun3.pos1 = self.angles;
 866                 self.angles = '0 0 0';
 867                 vector ofs = gettaginfo(self, gettagindex(self, "raygun"));
 868                 ofs -= self.origin;
 869                 setattachment(self.gun3, self, "");
 870                 setorigin(self.gun3, ofs);
 871                 self.angles = self.gun3.pos1;
 872
 873                 vehicle_addplayerslot(self, self.gun1, HUD_BUMBLEBEE_GUN, "models/vehicles/wakizashi_cockpit.dpm", bumb_gunner_frame, bumb_gunner_exit);
 874                 vehicle_addplayerslot(self, self.gun2, HUD_BUMBLEBEE_GUN, "models/vehicles/wakizashi_cockpit.dpm", bumb_gunner_frame, bumb_gunner_exit);
 875
 876                 setorigin(self.vehicle_hudmodel, '50 0 -5');    // Move cockpit forward - down.
 877                 setorigin(self.vehicle_viewport, '5 0 2');    // Move camera forward up
 878
 879                 //fixme-model-bones
 880                 setorigin(self.gun1.vehicle_hudmodel, '90 -27 -23');
 881                 setorigin(self.gun1.vehicle_viewport, '-85 0 50');
 882                 //fixme-model-bones
 883                 setorigin(self.gun2.vehicle_hudmodel, '90 27 -23');
 884                 setorigin(self.gun2.vehicle_viewport, '-85 0 50');
 885
 886                 self.scale = 1.5;
 887
 888                 // Raygun beam
 889                 if(self.gun3.enemy == world)
 890                 {
 891                         self.gun3.enemy = spawn();
 892                         Net_LinkEntity(self.gun3.enemy, TRUE, 0, bumble_raygun_send);
 893                         self.gun3.enemy.SendFlags = BRG_SETUP;
 894                         self.gun3.enemy.cnt = autocvar_g_vehicle_bumblebee_raygun;
 895                         self.gun3.enemy.effects = EF_NODRAW | EF_LOWPRECISION;
 896                 }
 897         }
 898
 899         self.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 900         self.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 901         self.solid          = SOLID_BBOX;
 902         //self.movetype         = MOVETYPE_BOUNCEMISSILE;
 903         self.movetype           = MOVETYPE_TOSS;
 904         self.vehicle_impact = bumb_impact;
 905         self.damageforcescale = 0.025;
 906
 907         setorigin(self, self.origin + '0 0 25');
 908 }
 909
 910 void spawnfunc_vehicle_bumblebee()
 911 {
 912         if(!autocvar_g_vehicle_bumblebee)
 913         {
 914                 remove(self);
 915                 return;
 916         }
 917
 918         precache_model("models/vehicles/bumblebee_body.dpm");
 919         precache_model("models/vehicles/bumblebee_plasma_left.dpm");
 920         precache_model("models/vehicles/bumblebee_plasma_right.dpm");
 921         precache_model("models/vehicles/bumblebee_ray.dpm");
 922         precache_model("models/vehicles/wakizashi_cockpit.dpm");
 923         precache_model("models/vehicles/spiderbot_cockpit.dpm");
 924         precache_model("models/vehicles/raptor_cockpit.dpm");
 925
 926         if(autocvar_g_vehicle_bumblebee_energy)
 927                 if(autocvar_g_vehicle_bumblebee_energy_regen)
 928                         self.vehicle_flags |= VHF_ENERGYREGEN;
 929
 930         if(autocvar_g_vehicle_bumblebee_shield)
 931                 self.vehicle_flags |= VHF_HASSHIELD;
 932
 933         if(autocvar_g_vehicle_bumblebee_shield_regen)
 934                 self.vehicle_flags |= VHF_SHIELDREGEN;
 935
 936         if(autocvar_g_vehicle_bumblebee_health_regen)
 937                 self.vehicle_flags |= VHF_HEALTHREGEN;
 938
 939         if not(vehicle_initialize(
 940                            "Bumblebee", "models/vehicles/bumblebee_body.dpm",
 941                            "", "models/vehicles/spiderbot_cockpit.dpm", "", "", "tag_viewport",
 942                            HUD_BUMBLEBEE, BUMB_MIN, BUMB_MAX, FALSE,
 943                            bumb_spawn, autocvar_g_vehicle_bumblebee_respawntime,
 944                            bumb_pilot_frame, bumb_enter, bumb_exit,
 945                            bumb_die, bumb_think, FALSE, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_shield))
 946         {
 947                 remove(self);
 948                 return;
 949         }
 950 }
 951
 952 float bumble_raygun_send(entity to, float sf)
 953 {
 954         WriteByte(MSG_ENTITY, ENT_CLIENT_BUMBLE_RAYGUN);
 955
 956         WriteByte(MSG_ENTITY, sf);
 957         if(sf & BRG_SETUP)
 958         {
 959                 WriteByte(MSG_ENTITY, num_for_edict(self.realowner));
 960                 WriteByte(MSG_ENTITY, self.realowner.team);
 961                 WriteByte(MSG_ENTITY, self.cnt);
 962         }
 963
 964         if(sf & BRG_START)
 965         {
 966                 WriteCoord(MSG_ENTITY, self.hook_start_x);
 967                 WriteCoord(MSG_ENTITY, self.hook_start_y);
 968                 WriteCoord(MSG_ENTITY, self.hook_start_z);
 969         }
 970
 971         if(sf & BRG_END)
 972         {
 973                 WriteCoord(MSG_ENTITY, self.hook_end_x);
 974                 WriteCoord(MSG_ENTITY, self.hook_end_y);
 975                 WriteCoord(MSG_ENTITY, self.hook_end_z);
 976         }
 977
 978         return TRUE;
 979 }
 980 #endif // SVQC
 981
 982 #ifdef CSQC
 983 /*
 984 .vector raygun_l1
 985 .vector raygun_l2;
 986 .vector raygun_l3;
 987 */
 988
 989 void bumble_raygun_draw()
 990 {
 991         float _len;
 992         vector _dir;
 993         vector _vtmp1, _vtmp2;
 994
 995         _len = vlen(self.origin - self.move_origin);
 996         _dir = normalize(self.move_origin - self.origin);
 997
 998         if(self.total_damages < time)
 999         {
1000                 boxparticles(self.traileffect, self, self.origin, self.origin + _dir * -64, _dir * -_len , _dir * -_len, 1, PARTICLES_USEALPHA);
1001                 boxparticles(self.lip, self, self.move_origin, self.move_origin + _dir * -64, _dir * -200 , _dir * -200, 1, PARTICLES_USEALPHA);
1002                 self.total_damages = time + 0.1;
1003         }
1004
1005         float i, df, sz, al;
1006         for(i = -0.1; i < 0.2; i += 0.1)
1007         {
1008                 df = DRAWFLAG_NORMAL; //((random() < 0.5) ? DRAWFLAG_ADDITIVE : DRAWFLAG_SCREEN);
1009                 sz = 5 + random() * 5;
1010                 al = 0.25 + random() * 0.5;
1011                 _vtmp1 = self.origin + _dir * _len * (0.25 + i);
1012                 _vtmp1 += (randomvec() * (_len * 0.2) * (frametime * 2));       //self.raygun_l1;
1013                 Draw_CylindricLine(self.origin, _vtmp1, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
1014
1015                 _vtmp2 = self.origin + _dir * _len * (0.5 + i);
1016                 _vtmp2 += (randomvec() * (_len * 0.2) * (frametime * 5));       //self.raygun_l2;
1017                 Draw_CylindricLine(_vtmp1, _vtmp2, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
1018
1019                 _vtmp1 = self.origin + _dir * _len * (0.75 + i);
1020                 _vtmp1 += randomvec() * (_len * 0.2) * (frametime * 10);     //self.raygun_l3;
1021                 Draw_CylindricLine(_vtmp2, _vtmp1, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
1022
1023                 Draw_CylindricLine(_vtmp1, self.move_origin +  randomvec() * 32, sz, "gfx/colors/white.tga", 1, 1, self.colormod, al, df, view_origin);
1024         }
1025 }
1026
1027 void bumble_raygun_read(float bIsNew)
1028 {
1029         float sf = ReadByte();
1030
1031         if(sf & BRG_SETUP)
1032         {
1033                 self.cnt  = ReadByte();
1034                 self.team = ReadByte();
1035                 self.cnt  = ReadByte();
1036
1037                 if(self.cnt)
1038                         self.colormod = '1 0 0';
1039                 else
1040                         self.colormod = '0 1 0';
1041
1042                 self.traileffect = particleeffectnum("healray_muzzleflash");
1043                 self.lip = particleeffectnum("healray_impact");
1044
1045                 self.draw = bumble_raygun_draw;
1046         }
1047
1048
1049         if(sf & BRG_START)
1050         {
1051                 self.origin_x = ReadCoord();
1052                 self.origin_y = ReadCoord();
1053                 self.origin_z = ReadCoord();
1054                 setorigin(self, self.origin);
1055         }
1056
1057         if(sf & BRG_END)
1058         {
1059                 self.move_origin_x = ReadCoord();
1060                 self.move_origin_y = ReadCoord();
1061                 self.move_origin_z = ReadCoord();
1062         }
1063 }
1064
1065 void bumblebee_draw()
1066 {
1067
1068 }
1069
1070 void bumblebee_draw2d()
1071 {
1072
1073 }
1074
1075 void bumblebee_read_extra()
1076 {
1077
1078 }
1079
1080 void vehicle_bumblebee_assemble()
1081 {
1082
1083 }
1084 #endif //CSQC