qcsrc/server/tturrets/units/unit_phaser.qc

   1 #include "../../_.qh"
   2
   3 void spawnfunc_turret_phaser();
   4 void turret_phaser_dinit();
   5 void turret_phaser_attack();
   6
   7 .float fireflag;
   8
   9 float turret_phaser_firecheck()
  10 {
  11     if (self.fireflag != 0) return 0;
  12     return turret_stdproc_firecheck();
  13 }
  14
  15 void turret_phaser_postthink()
  16 {
  17     if (self.tur_head.frame == 0)
  18         return;
  19
  20     if (self.fireflag == 1)
  21     {
  22         if (self.tur_head.frame == 10)
  23             self.tur_head.frame = 1;
  24         else
  25             self.tur_head.frame = self.tur_head.frame +1;
  26     }
  27     else if (self.fireflag == 2 )
  28     {
  29         self.tur_head.frame = self.tur_head.frame +1;
  30         if (self.tur_head.frame == 15)
  31         {
  32             self.tur_head.frame = 0;
  33             self.fireflag = 0;
  34         }
  35     }
  36 }
  37
  38 void beam_think()
  39 {
  40     if ((time > self.cnt) || (self.owner.deadflag != DEAD_NO))
  41     {
  42         self.owner.attack_finished_single = time + self.owner.shot_refire;
  43         self.owner.fireflag = 2;
  44         self.owner.tur_head.frame = 10;
  45         sound (self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
  46         remove(self);
  47         return;
  48     }
  49
  50     turret_do_updates(self.owner);
  51
  52     if (time - self.shot_spread > 0)
  53     {
  54         self.shot_spread = time + 2;
  55         sound (self, CH_SHOTS_SINGLE, "turrets/phaser.wav", VOL_BASE, ATTEN_NORM);
  56     }
  57
  58
  59     self.nextthink = time + self.ticrate;
  60
  61     self.owner.attack_finished_single = time + frametime;
  62     entity oldself;
  63     oldself = self;
  64     self = self.owner;
  65     FireImoBeam (   self.tur_shotorg,
  66                     self.tur_shotorg + self.tur_shotdir_updated * self.target_range,
  67                     '-1 -1 -1' * self.shot_radius,
  68                     '1 1 1' * self.shot_radius,
  69                     self.shot_force,
  70                     oldself.shot_dmg,
  71                     0.75,
  72                     DEATH_TURRET_PHASER);
  73     self = oldself;
  74     self.scale = vlen(self.owner.tur_shotorg - trace_endpos) / 256;
  75
  76 }
  77
  78 void turret_phaser_attack()
  79 {
  80     entity beam;
  81
  82     beam = spawn();
  83     beam.ticrate = 0.1; //autocvar_sys_ticrate;
  84     setmodel(beam,"models/turrets/phaser_beam.md3");
  85     beam.effects = EF_LOWPRECISION;
  86     beam.solid = SOLID_NOT;
  87     beam.think = beam_think;
  88     beam.cnt = time + self.shot_speed;
  89     beam.shot_spread = time + 2;
  90     beam.nextthink = time;
  91     beam.owner = self;
  92     beam.shot_dmg = self.shot_dmg / (self.shot_speed / beam.ticrate);
  93     beam.scale = self.target_range / 256;
  94     beam.movetype = MOVETYPE_NONE;
  95     beam.enemy = self.enemy;
  96     beam.bot_dodge = true;
  97     beam.bot_dodgerating = beam.shot_dmg;
  98     sound (beam, CH_SHOTS_SINGLE, "turrets/phaser.wav", VOL_BASE, ATTEN_NORM);
  99     self.fireflag = 1;
 100
 101     beam.attack_finished_single = self.attack_finished_single;
 102     self.attack_finished_single = time; // + autocvar_sys_ticrate;
 103
 104     setattachment(beam,self.tur_head,"tag_fire");
 105
 106     soundat (self, trace_endpos, CH_SHOTS, "weapons/neximpact.wav", VOL_BASE, ATTEN_NORM);
 107
 108     if (self.tur_head.frame == 0)
 109         self.tur_head.frame = 1;
 110 }
 111
 112 void turret_phaser_dinit()
 113 {
 114     if (self.netname == "")      self.netname  = "Phaser Cannon";
 115
 116     self.turrcaps_flags = TFL_TURRCAPS_SNIPER|TFL_TURRCAPS_HITSCAN|TFL_TURRCAPS_PLAYERKILL;
 117     self.ammo_flags = TFL_AMMO_ENERGY | TFL_AMMO_RECHARGE | TFL_AMMO_RECIVE;
 118     self.aim_flags = TFL_AIM_LEAD;
 119
 120     if (turret_stdproc_init("phaser_std", "models/turrets/base.md3","models/turrets/phaser.md3", TID_PHASER) == 0)
 121     {
 122         remove(self);
 123         return;
 124     }
 125
 126     self.turret_firecheckfunc = turret_phaser_firecheck;
 127     self.turret_firefunc  = turret_phaser_attack;
 128     self.turret_postthink = turret_phaser_postthink;
 129
 130 }
 131
 132 /*QUAKED turret_phaser(0 .5 .8) ?
 133 */
 134 void spawnfunc_turret_phaser()
 135 {
 136     precache_sound ("turrets/phaser.wav");
 137     precache_model ("models/turrets/phaser.md3");
 138     precache_model ("models/turrets/phaser_beam.md3");
 139     precache_model ("models/turrets/base.md3");
 140
 141     self.think = turret_phaser_dinit;
 142     self.nextthink = time + 0.5;
 143 }
 144