qcsrc/server/mutators/mutator/gamemode_lms.qc

   1 #ifndef GAMEMODE_LMS_H
   2 #define GAMEMODE_LMS_H
   3
   4 #define autocvar_g_lms_lives_override cvar("g_lms_lives_override")
   5 void lms_Initialize();
   6
   7 REGISTER_MUTATOR(lms, false)
   8 {
   9         MUTATOR_ONADD
  10         {
  11                 if (time > 1) // game loads at time 1
  12                         error("This is a game type and it cannot be added at runtime.");
  13                 lms_Initialize();
  14
  15                 SetLimits(((!autocvar_g_lms_lives_override) ? -1 : autocvar_g_lms_lives_override), 0, -1, -1);
  16         }
  17
  18         MUTATOR_ONROLLBACK_OR_REMOVE
  19         {
  20                 // we actually cannot roll back lms_Initialize here
  21                 // BUT: we don't need to! If this gets called, adding always
  22                 // succeeds.
  23         }
  24
  25         MUTATOR_ONREMOVE
  26         {
  27                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  28                 return -1;
  29         }
  30
  31         return 0;
  32 }
  33
  34 // scoreboard stuff
  35 const float SP_LMS_LIVES = 4;
  36 const float SP_LMS_RANK = 5;
  37
  38 // lives related defs
  39 float lms_lowest_lives;
  40 float lms_next_place;
  41 float LMS_NewPlayerLives();
  42
  43 #endif
  44
  45 #ifdef IMPLEMENTATION
  46
  47 #include <server/campaign.qh>
  48 #include <server/command/cmd.qh>
  49
  50 int autocvar_g_lms_extra_lives;
  51 bool autocvar_g_lms_join_anytime;
  52 int autocvar_g_lms_last_join;
  53 bool autocvar_g_lms_regenerate;
  54
  55 // main functions
  56 float LMS_NewPlayerLives()
  57 {
  58         float fl;
  59         fl = autocvar_fraglimit;
  60         if(fl == 0)
  61                 fl = 999;
  62
  63         // first player has left the game for dying too much? Nobody else can get in.
  64         if(lms_lowest_lives < 1)
  65                 return 0;
  66
  67         if(!autocvar_g_lms_join_anytime)
  68                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
  69                         return 0;
  70
  71         return bound(1, lms_lowest_lives, fl);
  72 }
  73
  74 // LMS winning condition: game terminates if and only if there's at most one
  75 // one player who's living lives. Top two scores being equal cancels the time
  76 // limit.
  77 int WinningCondition_LMS()
  78 {
  79         entity head, head2;
  80         bool have_player = false;
  81         bool have_players = false;
  82
  83         int l = LMS_NewPlayerLives();
  84
  85         head = find(world, classname, STR_PLAYER);
  86         if(head)
  87                 have_player = true;
  88         head2 = find(head, classname, STR_PLAYER);
  89         if(head2)
  90                 have_players = true;
  91
  92         if(have_player)
  93         {
  94                 // we have at least one player
  95                 if(have_players)
  96                 {
  97                         // two or more active players - continue with the game
  98                 }
  99                 else
 100                 {
 101                         // exactly one player?
 102
 103                         ClearWinners();
 104                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
 105
 106                         if(l)
 107                         {
 108                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
 109                                 return WINNING_NO;
 110                         }
 111                         else
 112                         {
 113                                 // a winner!
 114                                 // and assign him his first place
 115                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
 116                                 return WINNING_YES;
 117                         }
 118                 }
 119         }
 120         else
 121         {
 122                 // nobody is playing at all...
 123                 if(l)
 124                 {
 125                         // wait for players...
 126                 }
 127                 else
 128                 {
 129                         // SNAFU (maybe a draw game?)
 130                         ClearWinners();
 131                         LOG_TRACE("No players, ending game.\n");
 132                         return WINNING_YES;
 133                 }
 134         }
 135
 136         // When we get here, we have at least two players who are actually LIVING,
 137         // now check if the top two players have equal score.
 138         WinningConditionHelper();
 139
 140         ClearWinners();
 141         if(WinningConditionHelper_winner)
 142                 WinningConditionHelper_winner.winning = true;
 143         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
 144                 return WINNING_NEVER;
 145
 146         // Top two have different scores? Way to go for our beloved TIMELIMIT!
 147         return WINNING_NO;
 148 }
 149
 150 // mutator hooks
 151 MUTATOR_HOOKFUNCTION(lms, reset_map_global)
 152 {
 153         lms_lowest_lives = 999;
 154         lms_next_place = player_count;
 155
 156         return false;
 157 }
 158
 159 MUTATOR_HOOKFUNCTION(lms, reset_map_players)
 160 {
 161         if(restart_mapalreadyrestarted || (time < game_starttime))
 162         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(PlayerScore_Add(it, SP_LMS_LIVES, LMS_NewPlayerLives())));
 163         return false;
 164 }
 165
 166 MUTATOR_HOOKFUNCTION(lms, PutClientInServer)
 167 {SELFPARAM();
 168         // player is dead and becomes observer
 169         // FIXME fix LMS scoring for new system
 170         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 171         {
 172                 self.classname = STR_OBSERVER;
 173                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_LMS_NOLIVES);
 174         }
 175 }
 176
 177 MUTATOR_HOOKFUNCTION(lms, PlayerDies)
 178 {
 179         frag_target.respawn_flags |= RESPAWN_FORCE;
 180         return false;
 181 }
 182
 183 void lms_RemovePlayer(entity player)
 184 {
 185         // Only if the player cannot play at all
 186         if(PlayerScore_Add(player, SP_LMS_RANK, 0) == 666)
 187                 player.frags = FRAGS_SPECTATOR;
 188         else
 189                 player.frags = FRAGS_LMS_LOSER;
 190
 191         if(player.killcount != FRAGS_SPECTATOR)
 192                 if(PlayerScore_Add(player, SP_LMS_RANK, 0) > 0 && player.lms_spectate_warning != 2)
 193                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, player.netname);
 194                 else
 195                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, player.netname);
 196 }
 197
 198 MUTATOR_HOOKFUNCTION(lms, ClientDisconnect)
 199 {SELFPARAM();
 200         lms_RemovePlayer(self);
 201         return false;
 202 }
 203
 204 MUTATOR_HOOKFUNCTION(lms, MakePlayerObserver)
 205 {
 206     SELFPARAM();
 207         lms_RemovePlayer(this);
 208         return true;  // prevent team reset
 209 }
 210
 211 MUTATOR_HOOKFUNCTION(lms, ClientConnect)
 212 {SELFPARAM();
 213         self.classname = STR_PLAYER;
 214         campaign_bots_may_start = 1;
 215
 216         if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
 217         {
 218                 PlayerScore_Add(self, SP_LMS_RANK, 666);
 219                 self.frags = FRAGS_SPECTATOR;
 220         }
 221
 222         return false;
 223 }
 224
 225 MUTATOR_HOOKFUNCTION(lms, PlayerPreThink)
 226 {SELFPARAM();
 227         if(self.deadflag == DEAD_DYING)
 228                 self.deadflag = DEAD_RESPAWNING;
 229
 230         return false;
 231 }
 232
 233 MUTATOR_HOOKFUNCTION(lms, PlayerRegen)
 234 {
 235         if(autocvar_g_lms_regenerate)
 236                 return false;
 237         return true;
 238 }
 239
 240 MUTATOR_HOOKFUNCTION(lms, ForbidThrowCurrentWeapon)
 241 {
 242         // forbode!
 243         return true;
 244 }
 245
 246 MUTATOR_HOOKFUNCTION(lms, GiveFragsForKill)
 247 {
 248         // remove a life
 249         float tl;
 250         tl = PlayerScore_Add(frag_target, SP_LMS_LIVES, -1);
 251         if(tl < lms_lowest_lives)
 252                 lms_lowest_lives = tl;
 253         if(tl <= 0)
 254         {
 255                 if(!lms_next_place)
 256                         lms_next_place = player_count;
 257                 else
 258                         lms_next_place = min(lms_next_place, player_count);
 259                 PlayerScore_Add(frag_target, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 260                 --lms_next_place;
 261         }
 262         frag_score = 0;
 263
 264         return true;
 265 }
 266
 267 MUTATOR_HOOKFUNCTION(lms, SetStartItems)
 268 {
 269         start_items &= ~IT_UNLIMITED_AMMO;
 270         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 271         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 272         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 273         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 274         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 275         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 276         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 277         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 278
 279         return false;
 280 }
 281
 282 MUTATOR_HOOKFUNCTION(lms, ForbidPlayerScore_Clear)
 283 {
 284         // don't clear player score
 285         return true;
 286 }
 287
 288 MUTATOR_HOOKFUNCTION(lms, FilterItem)
 289 {SELFPARAM();
 290         if(autocvar_g_lms_extra_lives)
 291         if(self.itemdef == ITEM_ExtraLife)
 292                 return false;
 293
 294         return true;
 295 }
 296
 297 void lms_extralife()
 298 {SELFPARAM();
 299         StartItem(this, ITEM_ExtraLife);
 300 }
 301
 302 MUTATOR_HOOKFUNCTION(lms, OnEntityPreSpawn)
 303 {SELFPARAM();
 304         if (!autocvar_g_powerups) return false;
 305         if (!autocvar_g_lms_extra_lives) return false;
 306
 307         // Can't use .itemdef here
 308         if (self.classname != "item_health_mega") return false;
 309
 310         entity e = spawn();
 311         e.think = lms_extralife;
 312
 313         e.nextthink = time + 0.1;
 314         e.spawnflags = self.spawnflags;
 315         e.noalign = self.noalign;
 316         setorigin(e, self.origin);
 317
 318         return true;
 319 }
 320
 321 MUTATOR_HOOKFUNCTION(lms, ItemTouch)
 322 {SELFPARAM();
 323         if(self.itemdef == ITEM_ExtraLife)
 324         {
 325                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
 326                 PlayerScore_Add(other, SP_LMS_LIVES, autocvar_g_lms_extra_lives);
 327                 return MUT_ITEMTOUCH_PICKUP;
 328         }
 329
 330         return MUT_ITEMTOUCH_CONTINUE;
 331 }
 332
 333 MUTATOR_HOOKFUNCTION(lms, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
 334 {
 335         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
 336                 ++bot_activerealplayers;
 337                 ++bot_realplayers;
 338         ));
 339
 340         return true;
 341 }
 342
 343 MUTATOR_HOOKFUNCTION(lms, ClientCommand_Spectate)
 344 {
 345         if(self.lms_spectate_warning)
 346         {
 347                 // for the forfeit message...
 348                 self.lms_spectate_warning = 2;
 349                 // mark player as spectator
 350                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 351         }
 352         else
 353         {
 354                 self.lms_spectate_warning = 1;
 355                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 356                 return MUT_SPECCMD_RETURN;
 357         }
 358         return MUT_SPECCMD_CONTINUE;
 359 }
 360
 361 MUTATOR_HOOKFUNCTION(lms, CheckRules_World)
 362 {
 363         ret_float = WinningCondition_LMS();
 364         return true;
 365 }
 366
 367 MUTATOR_HOOKFUNCTION(lms, WantWeapon)
 368 {
 369         want_allguns = true;
 370         return false;
 371 }
 372
 373 MUTATOR_HOOKFUNCTION(lms, GetPlayerStatus)
 374 {
 375         return true;
 376 }
 377
 378 MUTATOR_HOOKFUNCTION(lms, AddPlayerScore)
 379 {
 380         if(gameover)
 381         if(score_field == SP_LMS_RANK)
 382                 return true; // allow writing to this field in intermission as it is needed for newly joining players
 383         return false;
 384 }
 385
 386 // scoreboard stuff
 387 void lms_ScoreRules()
 388 {
 389         ScoreRules_basics(0, 0, 0, false);
 390         ScoreInfo_SetLabel_PlayerScore(SP_LMS_LIVES,    "lives",     SFL_SORT_PRIO_SECONDARY);
 391         ScoreInfo_SetLabel_PlayerScore(SP_LMS_RANK,     "rank",      SFL_LOWER_IS_BETTER | SFL_RANK | SFL_SORT_PRIO_PRIMARY | SFL_ALLOW_HIDE);
 392         ScoreRules_basics_end();
 393 }
 394
 395 void lms_Initialize()
 396 {
 397         lms_lowest_lives = 9999;
 398         lms_next_place = 0;
 399
 400         lms_ScoreRules();
 401 }
 402
 403
 404 #endif