qcsrc/server/mutators/mutator/gamemode_lms.qc

   1 #include "gamemode_lms.qh"
   2 #ifndef GAMEMODE_LMS_H
   3 #define GAMEMODE_LMS_H
   4
   5 #define autocvar_g_lms_lives_override cvar("g_lms_lives_override")
   6 void lms_Initialize();
   7
   8 REGISTER_MUTATOR(lms, false)
   9 {
  10         MUTATOR_ONADD
  11         {
  12                 if (time > 1) // game loads at time 1
  13                         error("This is a game type and it cannot be added at runtime.");
  14                 lms_Initialize();
  15
  16                 SetLimits(((!autocvar_g_lms_lives_override) ? -1 : autocvar_g_lms_lives_override), 0, autocvar_timelimit_override, -1);
  17         }
  18
  19         MUTATOR_ONROLLBACK_OR_REMOVE
  20         {
  21                 // we actually cannot roll back lms_Initialize here
  22                 // BUT: we don't need to! If this gets called, adding always
  23                 // succeeds.
  24         }
  25
  26         MUTATOR_ONREMOVE
  27         {
  28                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  29                 return -1;
  30         }
  31
  32         return 0;
  33 }
  34
  35 // scoreboard stuff
  36 const float SP_LMS_LIVES = 4;
  37 const float SP_LMS_RANK = 5;
  38
  39 // lives related defs
  40 float lms_lowest_lives;
  41 float lms_next_place;
  42 float LMS_NewPlayerLives();
  43
  44 #endif
  45
  46 #ifdef IMPLEMENTATION
  47
  48 #include <common/mutators/mutator/instagib/items.qc>
  49 #include <server/campaign.qh>
  50 #include <server/command/cmd.qh>
  51
  52 int autocvar_g_lms_extra_lives;
  53 bool autocvar_g_lms_join_anytime;
  54 int autocvar_g_lms_last_join;
  55 bool autocvar_g_lms_regenerate;
  56
  57 // main functions
  58 float LMS_NewPlayerLives()
  59 {
  60         float fl;
  61         fl = autocvar_fraglimit;
  62         if(fl == 0)
  63                 fl = 999;
  64
  65         // first player has left the game for dying too much? Nobody else can get in.
  66         if(lms_lowest_lives < 1)
  67                 return 0;
  68
  69         if(!autocvar_g_lms_join_anytime)
  70                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
  71                         return 0;
  72
  73         return bound(1, lms_lowest_lives, fl);
  74 }
  75
  76 void ClearWinners();
  77
  78 // LMS winning condition: game terminates if and only if there's at most one
  79 // one player who's living lives. Top two scores being equal cancels the time
  80 // limit.
  81 int WinningCondition_LMS()
  82 {
  83         entity head, head2;
  84         bool have_player = false;
  85         bool have_players = false;
  86
  87         int l = LMS_NewPlayerLives();
  88
  89         head = find(world, classname, STR_PLAYER);
  90         if(head)
  91                 have_player = true;
  92         head2 = find(head, classname, STR_PLAYER);
  93         if(head2)
  94                 have_players = true;
  95
  96         if(have_player)
  97         {
  98                 // we have at least one player
  99                 if(have_players)
 100                 {
 101                         // two or more active players - continue with the game
 102                 }
 103                 else
 104                 {
 105                         // exactly one player?
 106
 107                         ClearWinners();
 108                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
 109
 110                         if(l)
 111                         {
 112                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
 113                                 return WINNING_NO;
 114                         }
 115                         else
 116                         {
 117                                 // a winner!
 118                                 // and assign him his first place
 119                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
 120                                 return WINNING_YES;
 121                         }
 122                 }
 123         }
 124         else
 125         {
 126                 // nobody is playing at all...
 127                 if(l)
 128                 {
 129                         // wait for players...
 130                 }
 131                 else
 132                 {
 133                         // SNAFU (maybe a draw game?)
 134                         ClearWinners();
 135                         LOG_TRACE("No players, ending game.\n");
 136                         return WINNING_YES;
 137                 }
 138         }
 139
 140         // When we get here, we have at least two players who are actually LIVING,
 141         // now check if the top two players have equal score.
 142         WinningConditionHelper();
 143
 144         ClearWinners();
 145         if(WinningConditionHelper_winner)
 146                 WinningConditionHelper_winner.winning = true;
 147         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
 148                 return WINNING_NEVER;
 149
 150         // Top two have different scores? Way to go for our beloved TIMELIMIT!
 151         return WINNING_NO;
 152 }
 153
 154 // mutator hooks
 155 MUTATOR_HOOKFUNCTION(lms, reset_map_global)
 156 {
 157         lms_lowest_lives = 999;
 158         lms_next_place = player_count;
 159
 160         return false;
 161 }
 162
 163 MUTATOR_HOOKFUNCTION(lms, reset_map_players)
 164 {
 165         if(restart_mapalreadyrestarted || (time < game_starttime))
 166         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(PlayerScore_Add(it, SP_LMS_LIVES, LMS_NewPlayerLives())));
 167         return false;
 168 }
 169
 170 MUTATOR_HOOKFUNCTION(lms, PutClientInServer)
 171 {
 172         entity player = M_ARGV(0, entity);
 173
 174         // player is dead and becomes observer
 175         // FIXME fix LMS scoring for new system
 176         if(PlayerScore_Add(player, SP_LMS_RANK, 0) > 0)
 177         {
 178                 TRANSMUTE(Observer, player);
 179                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_LMS_NOLIVES);
 180         }
 181 }
 182
 183 MUTATOR_HOOKFUNCTION(lms, PlayerDies)
 184 {
 185         entity frag_target = M_ARGV(2, entity);
 186
 187         frag_target.respawn_flags |= RESPAWN_FORCE;
 188         return false;
 189 }
 190
 191 void lms_RemovePlayer(entity player)
 192 {
 193         // Only if the player cannot play at all
 194         if(PlayerScore_Add(player, SP_LMS_RANK, 0) == 666)
 195                 player.frags = FRAGS_SPECTATOR;
 196         else
 197                 player.frags = FRAGS_LMS_LOSER;
 198
 199         if(player.killcount != FRAGS_SPECTATOR)
 200                 if(PlayerScore_Add(player, SP_LMS_RANK, 0) > 0 && player.lms_spectate_warning != 2)
 201                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, player.netname);
 202                 else
 203                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, player.netname);
 204 }
 205
 206 MUTATOR_HOOKFUNCTION(lms, ClientDisconnect)
 207 {SELFPARAM();
 208         lms_RemovePlayer(self);
 209         return false;
 210 }
 211
 212 MUTATOR_HOOKFUNCTION(lms, MakePlayerObserver)
 213 {
 214     SELFPARAM();
 215         lms_RemovePlayer(this);
 216         return true;  // prevent team reset
 217 }
 218
 219 MUTATOR_HOOKFUNCTION(lms, ClientConnect)
 220 {SELFPARAM();
 221         TRANSMUTE(Player, self);
 222         campaign_bots_may_start = true;
 223
 224         if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
 225         {
 226                 PlayerScore_Add(self, SP_LMS_RANK, 666);
 227                 self.frags = FRAGS_SPECTATOR;
 228         }
 229
 230         return false;
 231 }
 232
 233 MUTATOR_HOOKFUNCTION(lms, PlayerPreThink)
 234 {SELFPARAM();
 235         if(this.deadflag == DEAD_DYING)
 236                 this.deadflag = DEAD_RESPAWNING;
 237
 238         return false;
 239 }
 240
 241 MUTATOR_HOOKFUNCTION(lms, PlayerRegen)
 242 {
 243         if(autocvar_g_lms_regenerate)
 244                 return false;
 245         return true;
 246 }
 247
 248 MUTATOR_HOOKFUNCTION(lms, ForbidThrowCurrentWeapon)
 249 {
 250         // forbode!
 251         return true;
 252 }
 253
 254 MUTATOR_HOOKFUNCTION(lms, GiveFragsForKill)
 255 {
 256         entity frag_target = M_ARGV(1, entity);
 257
 258         // remove a life
 259         float tl;
 260         tl = PlayerScore_Add(frag_target, SP_LMS_LIVES, -1);
 261         if(tl < lms_lowest_lives)
 262                 lms_lowest_lives = tl;
 263         if(tl <= 0)
 264         {
 265                 if(!lms_next_place)
 266                         lms_next_place = player_count;
 267                 else
 268                         lms_next_place = min(lms_next_place, player_count);
 269                 PlayerScore_Add(frag_target, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 270                 --lms_next_place;
 271         }
 272         M_ARGV(2, float) = 0;
 273
 274         return true;
 275 }
 276
 277 MUTATOR_HOOKFUNCTION(lms, SetStartItems)
 278 {
 279         start_items &= ~IT_UNLIMITED_AMMO;
 280         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 281         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 282         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 283         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 284         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 285         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 286         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 287         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 288
 289         return false;
 290 }
 291
 292 MUTATOR_HOOKFUNCTION(lms, ForbidPlayerScore_Clear)
 293 {
 294         // don't clear player score
 295         return true;
 296 }
 297
 298 MUTATOR_HOOKFUNCTION(lms, FilterItem)
 299 {SELFPARAM();
 300         if(autocvar_g_lms_extra_lives)
 301         if(self.itemdef == ITEM_ExtraLife)
 302                 return false;
 303
 304         return true;
 305 }
 306
 307 void lms_extralife(entity this)
 308 {
 309         StartItem(this, ITEM_ExtraLife);
 310 }
 311
 312 MUTATOR_HOOKFUNCTION(lms, OnEntityPreSpawn)
 313 {SELFPARAM();
 314         if (!autocvar_g_powerups) return false;
 315         if (!autocvar_g_lms_extra_lives) return false;
 316
 317         // Can't use .itemdef here
 318         if (self.classname != "item_health_mega") return false;
 319
 320         entity e = spawn();
 321         setthink(e, lms_extralife);
 322
 323         e.nextthink = time + 0.1;
 324         e.spawnflags = self.spawnflags;
 325         e.noalign = self.noalign;
 326         setorigin(e, self.origin);
 327
 328         return true;
 329 }
 330
 331 MUTATOR_HOOKFUNCTION(lms, ItemTouch)
 332 {SELFPARAM();
 333         if(self.itemdef == ITEM_ExtraLife)
 334         {
 335                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
 336                 PlayerScore_Add(other, SP_LMS_LIVES, autocvar_g_lms_extra_lives);
 337                 return MUT_ITEMTOUCH_PICKUP;
 338         }
 339
 340         return MUT_ITEMTOUCH_CONTINUE;
 341 }
 342
 343 MUTATOR_HOOKFUNCTION(lms, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
 344 {
 345         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
 346                 ++bot_activerealplayers;
 347                 ++bot_realplayers;
 348         ));
 349
 350         return true;
 351 }
 352
 353 MUTATOR_HOOKFUNCTION(lms, ClientCommand_Spectate)
 354 {
 355     SELFPARAM();
 356         if(self.lms_spectate_warning)
 357         {
 358                 // for the forfeit message...
 359                 self.lms_spectate_warning = 2;
 360                 // mark player as spectator
 361                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 362         }
 363         else
 364         {
 365                 self.lms_spectate_warning = 1;
 366                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 367                 return MUT_SPECCMD_RETURN;
 368         }
 369         return MUT_SPECCMD_CONTINUE;
 370 }
 371
 372 MUTATOR_HOOKFUNCTION(lms, CheckRules_World)
 373 {
 374         ret_float = WinningCondition_LMS();
 375         return true;
 376 }
 377
 378 MUTATOR_HOOKFUNCTION(lms, WantWeapon)
 379 {
 380         want_allguns = true;
 381         return false;
 382 }
 383
 384 MUTATOR_HOOKFUNCTION(lms, GetPlayerStatus)
 385 {
 386         return true;
 387 }
 388
 389 MUTATOR_HOOKFUNCTION(lms, AddPlayerScore)
 390 {
 391         if(gameover)
 392         if(score_field == SP_LMS_RANK)
 393                 return true; // allow writing to this field in intermission as it is needed for newly joining players
 394         return false;
 395 }
 396
 397 // scoreboard stuff
 398 void lms_ScoreRules()
 399 {
 400         ScoreRules_basics(0, 0, 0, false);
 401         ScoreInfo_SetLabel_PlayerScore(SP_LMS_LIVES,    "lives",     SFL_SORT_PRIO_SECONDARY);
 402         ScoreInfo_SetLabel_PlayerScore(SP_LMS_RANK,     "rank",      SFL_LOWER_IS_BETTER | SFL_RANK | SFL_SORT_PRIO_PRIMARY | SFL_ALLOW_HIDE);
 403         ScoreRules_basics_end();
 404 }
 405
 406 void lms_Initialize()
 407 {
 408         lms_lowest_lives = 9999;
 409         lms_next_place = 0;
 410
 411         lms_ScoreRules();
 412 }
 413
 414
 415 #endif