qcsrc/server/mutators/gamemode_lms.qc

   1 // main functions
   2 float LMS_NewPlayerLives()
   3 {
   4         float fl;
   5         fl = autocvar_fraglimit;
   6         if(fl == 0)
   7                 fl = 999;
   8
   9         // first player has left the game for dying too much? Nobody else can get in.
  10         if(lms_lowest_lives < 1)
  11                 return 0;
  12
  13         if(!autocvar_g_lms_join_anytime)
  14                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
  15                         return 0;
  16
  17         return bound(1, lms_lowest_lives, fl);
  18 }
  19
  20 // mutator hooks
  21 MUTATOR_HOOKFUNCTION(lms_ResetMap)
  22 {
  23         lms_lowest_lives = 999;
  24         lms_next_place = player_count;
  25
  26         return FALSE;
  27 }
  28
  29 MUTATOR_HOOKFUNCTION(lms_ResetPlayers)
  30 {
  31         if(restart_mapalreadyrestarted || (time < game_starttime))
  32         FOR_EACH_CLIENT(self)
  33         if(IS_PLAYER(self))
  34                 PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives());
  35
  36         return FALSE;
  37 }
  38
  39 MUTATOR_HOOKFUNCTION(lms_PlayerPreSpawn)
  40 {
  41         // player is dead and becomes observer
  42         // FIXME fix LMS scoring for new system
  43         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
  44                 self.classname = "observer";
  45
  46         return FALSE;
  47 }
  48
  49 MUTATOR_HOOKFUNCTION(lms_PlayerSpawn)
  50 {
  51         self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
  52         self.lms_traveled_distance = 0;
  53
  54         return FALSE;
  55 }
  56
  57 MUTATOR_HOOKFUNCTION(lms_PlayerDies)
  58 {
  59         self.respawn_flags |= RESPAWN_FORCE;
  60
  61         return FALSE;
  62 }
  63
  64 MUTATOR_HOOKFUNCTION(lms_RemovePlayer)
  65 {
  66         // Only if the player cannot play at all
  67         if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
  68                 self.frags = FRAGS_SPECTATOR;
  69         else
  70                 self.frags = FRAGS_LMS_LOSER;
  71
  72         if(self.killcount != -666)
  73                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0 && self.lms_spectate_warning != 2)
  74                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, self.netname);
  75                 else
  76                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, self.netname);
  77
  78         return FALSE;
  79 }
  80
  81 MUTATOR_HOOKFUNCTION(lms_ClientConnect)
  82 {
  83         self.classname = "player";
  84         campaign_bots_may_start = 1;
  85
  86         if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
  87         {
  88                 PlayerScore_Add(self, SP_LMS_RANK, 666);
  89                 self.frags = FRAGS_SPECTATOR;
  90         }
  91
  92         return FALSE;
  93 }
  94
  95 MUTATOR_HOOKFUNCTION(lms_PlayerThink)
  96 {
  97         if(self.deadflag == DEAD_DYING)
  98                 self.deadflag = DEAD_RESPAWNING;
  99
 100         if not(self.deadflag)
 101         if(autocvar_g_lms_campcheck_interval)
 102         {
 103                 vector dist;
 104
 105                 // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
 106                 dist = self.prevorigin - self.origin;
 107                 dist_z = 0;
 108                 self.lms_traveled_distance += fabs(vlen(dist));
 109
 110                 if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
 111                 {
 112                         self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 113                         self.lms_traveled_distance = 0;
 114                 }
 115
 116                 if(time > self.lms_nextcheck)
 117                 {
 118                         if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
 119                         {
 120                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_LMS_CAMPCHECK);
 121                                 if(self.vehicle)
 122                                         Damage(self.vehicle, self, self, autocvar_g_lms_campcheck_damage * 2, DEATH_CAMP, self.vehicle.origin, '0 0 0');
 123                                 else
 124                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
 125                         }
 126                         self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
 127                         self.lms_traveled_distance = 0;
 128                 }
 129         }
 130
 131         return FALSE;
 132 }
 133
 134 MUTATOR_HOOKFUNCTION(lms_PlayerDamage)
 135 {
 136         if(IS_PLAYER(frag_target))
 137         if(IS_PLAYER(frag_attacker))
 138         if(frag_attacker != frag_target)
 139         {
 140                 frag_target.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 141                 frag_attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 142         }
 143
 144         return FALSE;
 145 }
 146
 147 MUTATOR_HOOKFUNCTION(lms_ForbidThrowing)
 148 {
 149         // forbode!
 150         return TRUE;
 151 }
 152
 153 MUTATOR_HOOKFUNCTION(lms_GiveFragsForKill)
 154 {
 155         // remove a life
 156         float tl;
 157         tl = PlayerScore_Add(frag_target, SP_LMS_LIVES, -1);
 158         if(tl < lms_lowest_lives)
 159                 lms_lowest_lives = tl;
 160         if(tl <= 0)
 161         {
 162                 if(!lms_next_place)
 163                         lms_next_place = player_count;
 164                 else
 165                         lms_next_place = min(lms_next_place, player_count);
 166                 PlayerScore_Add(frag_target, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 167                 --lms_next_place;
 168         }
 169         frag_score = 0;
 170
 171         return TRUE;
 172 }
 173
 174 MUTATOR_HOOKFUNCTION(lms_SetStartItems)
 175 {
 176         start_items &~= IT_UNLIMITED_AMMO;
 177         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 178         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 179         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 180         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 181         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 182         start_health = cvar("g_lms_start_health");
 183         start_armorvalue = cvar("g_lms_start_armor");
 184
 185         return FALSE;
 186 }
 187
 188 MUTATOR_HOOKFUNCTION(lms_KeepScore)
 189 {
 190         // don't clear player score
 191         return TRUE;
 192 }
 193
 194 MUTATOR_HOOKFUNCTION(lms_FilterItem)
 195 {
 196         if(autocvar_g_lms_extra_lives)
 197         if(self.classname == "item_health_mega")
 198         {
 199                 self.max_health = 1;
 200                 return FALSE;
 201         }
 202
 203         return TRUE;
 204 }
 205
 206 MUTATOR_HOOKFUNCTION(lms_ItemTouch)
 207 {
 208         // give extra lives for mega health
 209         if(self.items & IT_HEALTH)
 210         {
 211                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
 212                 PlayerScore_Add(other, SP_LMS_LIVES, autocvar_g_lms_extra_lives);
 213         }
 214
 215         return FALSE;
 216 }
 217
 218 // scoreboard stuff
 219 void lms_ScoreRules()
 220 {
 221         ScoreRules_basics(0, 0, 0, FALSE);
 222         ScoreInfo_SetLabel_PlayerScore(SP_LMS_LIVES,    "lives",     SFL_SORT_PRIO_SECONDARY);
 223         ScoreInfo_SetLabel_PlayerScore(SP_LMS_RANK,     "rank",      SFL_LOWER_IS_BETTER | SFL_RANK | SFL_SORT_PRIO_PRIMARY | SFL_ALLOW_HIDE);
 224         ScoreRules_basics_end();
 225 }
 226
 227 void lms_Initialize()
 228 {
 229         lms_lowest_lives = 9999;
 230         lms_next_place = 0;
 231
 232         lms_ScoreRules();
 233 }
 234
 235 MUTATOR_DEFINITION(gamemode_lms)
 236 {
 237         MUTATOR_HOOK(reset_map_global, lms_ResetMap, CBC_ORDER_ANY);
 238         MUTATOR_HOOK(reset_map_players, lms_ResetPlayers, CBC_ORDER_ANY);
 239         MUTATOR_HOOK(PutClientInServer, lms_PlayerPreSpawn, CBC_ORDER_ANY);
 240         MUTATOR_HOOK(PlayerSpawn, lms_PlayerSpawn, CBC_ORDER_ANY);
 241         MUTATOR_HOOK(PlayerDies, lms_PlayerDies, CBC_ORDER_ANY);
 242         MUTATOR_HOOK(MakePlayerObserver, lms_RemovePlayer, CBC_ORDER_ANY);
 243         MUTATOR_HOOK(ClientConnect, lms_ClientConnect, CBC_ORDER_ANY);
 244         MUTATOR_HOOK(PlayerPreThink, lms_PlayerThink, CBC_ORDER_ANY);
 245         MUTATOR_HOOK(PlayerDamage_Calculate, lms_PlayerDamage, CBC_ORDER_ANY);
 246         MUTATOR_HOOK(ForbidThrowCurrentWeapon, lms_ForbidThrowing, CBC_ORDER_ANY);
 247         MUTATOR_HOOK(GiveFragsForKill, lms_GiveFragsForKill, CBC_ORDER_ANY);
 248         MUTATOR_HOOK(SetStartItems, lms_SetStartItems, CBC_ORDER_ANY);
 249         MUTATOR_HOOK(ForbidPlayerScore_Clear, lms_KeepScore, CBC_ORDER_ANY);
 250         MUTATOR_HOOK(FilterItem, lms_FilterItem, CBC_ORDER_ANY);
 251         MUTATOR_HOOK(ItemTouch, lms_ItemTouch, CBC_ORDER_ANY);
 252
 253         MUTATOR_ONADD
 254         {
 255                 if(time > 1) // game loads at time 1
 256                         error("This is a game type and it cannot be added at runtime.");
 257                 lms_Initialize();
 258         }
 259
 260         MUTATOR_ONROLLBACK_OR_REMOVE
 261         {
 262                 // we actually cannot roll back lms_Initialize here
 263                 // BUT: we don't need to! If this gets called, adding always
 264                 // succeeds.
 265         }
 266
 267         MUTATOR_ONREMOVE
 268         {
 269                 print("This is a game type and it cannot be removed at runtime.");
 270                 return -1;
 271         }
 272
 273         return 0;
 274 }