qcsrc/server/mutators/gamemode_freezetag.qc

   1 .float freezetag_frozen_time;
   2 .float freezetag_frozen_timeout;
   3 .float freezetag_revive_progress;
   4 .entity freezetag_ice;
   5 #define ICE_MAX_ALPHA 0.6
   6 #define ICE_MIN_ALPHA 0.1
   7 float freezetag_teams;
   8
   9 float freezetag_CheckTeams();
  10 float freezetag_CheckWinner();
  11 void freezetag_Initialize()
  12 {
  13         precache_model("models/ice/ice.md3");
  14         ScoreRules_freezetag();
  15
  16         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, func_null, 5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
  17
  18         addstat(STAT_REDALIVE, AS_INT, redalive_stat);
  19         addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
  20         addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
  21         addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
  22
  23         addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
  24         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
  25 }
  26
  27 void freezetag_count_alive_players()
  28 {
  29         entity e;
  30         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  31         FOR_EACH_PLAYER(e) {
  32                 if(e.team == COLOR_TEAM1 && e.health >= 1)
  33                 {
  34                         ++total_players;
  35                         if (!e.freezetag_frozen) ++redalive;
  36                 }
  37                 else if(e.team == COLOR_TEAM2 && e.health >= 1)
  38                 {
  39                         ++total_players;
  40                         if (!e.freezetag_frozen) ++bluealive;
  41                 }
  42                 else if(e.team == COLOR_TEAM3 && e.health >= 1)
  43                 {
  44                         ++total_players;
  45                         if (!e.freezetag_frozen) ++yellowalive;
  46                 }
  47                 else if(e.team == COLOR_TEAM4 && e.health >= 1)
  48                 {
  49                         ++total_players;
  50                         if (!e.freezetag_frozen) ++pinkalive;
  51                 }
  52         }
  53         FOR_EACH_REALCLIENT(e) {
  54                 e.redalive_stat = redalive;
  55                 e.bluealive_stat = bluealive;
  56                 e.yellowalive_stat = yellowalive;
  57                 e.pinkalive_stat = pinkalive;
  58         }
  59 }
  60 #define FREEZETAG_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  61 #define FREEZETAG_ALIVE_TEAMS_OK() (FREEZETAG_ALIVE_TEAMS() == freezetag_teams)
  62
  63 float prev_total_players;
  64 float freezetag_CheckTeams()
  65 {
  66         entity e;
  67         if(FREEZETAG_ALIVE_TEAMS_OK())
  68         {
  69                 if(prev_total_players != -1)
  70                 {
  71                         FOR_EACH_REALCLIENT(e)
  72                                 Send_CSQC_Centerprint_Generic_Expire(e, CPID_WAITING_PLAYERS);
  73                 }
  74                 prev_total_players = -1;
  75                 return 1;
  76         }
  77         if(prev_total_players != total_players)
  78         {
  79                 string teams_missing = "";
  80                 if(!redalive)   teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM1), ", ");
  81                 if(!bluealive)  teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM2), ", ");
  82                 if(freezetag_teams >= 3)
  83                 if(!yellowalive)        teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM3), ", ");
  84                 if(freezetag_teams == 4)
  85                 if(!pinkalive)  teams_missing = strcat(teams_missing, ColoredTeamName(COLOR_TEAM4), ", ");
  86                 teams_missing = substring(teams_missing, 0, strlen(teams_missing)-2);
  87
  88                 FOR_EACH_REALCLIENT(e)
  89                         Send_CSQC_Centerprint_Generic(e, CPID_WAITING_PLAYERS, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), -1, 0);
  90                 prev_total_players = total_players;
  91         }
  92         return 0;
  93 }
  94
  95 float freezetag_getWinnerTeam()
  96 {
  97         float winner_team = 0;
  98         if(redalive >= 1)
  99                 winner_team = COLOR_TEAM1;
 100         if(bluealive >= 1)
 101         {
 102                 if(winner_team) return 0;
 103                 winner_team = COLOR_TEAM2;
 104         }
 105         if(yellowalive >= 1)
 106         {
 107                 if(winner_team) return 0;
 108                 winner_team = COLOR_TEAM3;
 109         }
 110         if(pinkalive >= 1)
 111         {
 112                 if(winner_team) return 0;
 113                 winner_team = COLOR_TEAM4;
 114         }
 115         if(winner_team)
 116                 return winner_team;
 117         return -1; // no player left
 118 }
 119
 120 float freezetag_CheckWinner()
 121 {
 122         entity e;
 123         if(round_handler_GetTimeLeft() <= 0)
 124         {
 125                 FOR_EACH_REALCLIENT(e)
 126                         centerprint(e, "Round over, there's no winner");
 127                 bprint("Round over, there's no winner.\n");
 128                 FOR_EACH_PLAYER(e)
 129                         e.freezetag_frozen_timeout = 0;
 130                 return 1;
 131         }
 132
 133         if(FREEZETAG_ALIVE_TEAMS() > 1)
 134                 return 0;
 135
 136         float winner_team;
 137         string teamname;
 138         winner_team = freezetag_getWinnerTeam();
 139         if(winner_team > 0)
 140         {
 141                 teamname = ColoredTeamName(winner_team);
 142                 FOR_EACH_REALCLIENT(e)
 143                         centerprint(e, strcat(teamname, "^5 wins the round, all other teams were frozen."));
 144                 bprint(teamname, "^5 wins the round since all the other teams were frozen.\n");
 145                 TeamScore_AddToTeam(winner_team, ST_SCORE, +1);
 146         }
 147         else if(winner_team == -1)
 148         {
 149                 FOR_EACH_REALCLIENT(e)
 150                         centerprint(e, "^5Round tied! All teams were frozen.");
 151                 bprint("^5Round tied! All teams were frozen.\n");
 152         }
 153
 154         FOR_EACH_PLAYER(e)
 155                 e.freezetag_frozen_timeout = 0;
 156         return 1;
 157 }
 158
 159 // this is needed to allow the player to turn his view around (fixangle can't
 160 // be used to freeze his view, as that also changes the angles), while not
 161 // turning that ice object with the player
 162 void freezetag_Ice_Think()
 163 {
 164         setorigin(self, self.owner.origin - '0 0 16');
 165         self.nextthink = time;
 166 }
 167
 168 void freezetag_Add_Score(entity attacker)
 169 {
 170         if(attacker == self)
 171         {
 172                 // you froze your own dumb self
 173                 // counted as "suicide" already
 174                 PlayerScore_Add(self, SP_SCORE, -1);
 175         }
 176         else if(attacker.classname == "player")
 177         {
 178                 // got frozen by an enemy
 179                 // counted as "kill" and "death" already
 180                 PlayerScore_Add(self, SP_SCORE, -1);
 181                 PlayerScore_Add(attacker, SP_SCORE, +1);
 182         }
 183         // else nothing - got frozen by the game type rules themselves
 184 }
 185
 186 void freezetag_Freeze(entity attacker)
 187 {
 188         if(self.freezetag_frozen)
 189                 return;
 190         self.freezetag_frozen = 1;
 191         self.freezetag_frozen_time = time;
 192         self.freezetag_revive_progress = 0;
 193         self.health = 1;
 194         if(autocvar_g_freezetag_frozen_maxtime > 0)
 195                 self.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime;
 196
 197         freezetag_count_alive_players();
 198
 199         entity ice;
 200         ice = spawn();
 201         ice.owner = self;
 202         ice.classname = "freezetag_ice";
 203         ice.think = freezetag_Ice_Think;
 204         ice.nextthink = time;
 205         ice.frame = floor(random() * 21); // ice model has 20 different looking frames
 206         ice.alpha = ICE_MAX_ALPHA;
 207         setmodel(ice, "models/ice/ice.md3");
 208
 209         self.freezetag_ice = ice;
 210
 211         RemoveGrapplingHook(self);
 212
 213         // add waypoint
 214         WaypointSprite_Spawn("freezetag_frozen", 0, 0, self, '0 0 64', world, self.team, self, waypointsprite_attached, TRUE, RADARICON_WAYPOINT, '0.25 0.90 1');
 215
 216         freezetag_Add_Score(attacker);
 217 }
 218
 219 void freezetag_Unfreeze(entity attacker)
 220 {
 221         self.freezetag_frozen = 0;
 222         self.freezetag_frozen_time = 0;
 223         self.freezetag_frozen_timeout = 0;
 224         self.freezetag_revive_progress = 0;
 225
 226         remove(self.freezetag_ice);
 227         self.freezetag_ice = world;
 228
 229         if(self.waypointsprite_attached)
 230                 WaypointSprite_Kill(self.waypointsprite_attached);
 231 }
 232
 233
 234 // ================
 235 // Bot player logic
 236 // ================
 237
 238 void() havocbot_role_ft_freeing;
 239 void() havocbot_role_ft_offense;
 240
 241 void havocbot_goalrating_freeplayers(float ratingscale, vector org, float sradius)
 242 {
 243         entity head;
 244         float distance;
 245
 246         FOR_EACH_PLAYER(head)
 247         {
 248                 if ((head != self) && (head.team == self.team))
 249                 {
 250                         if (head.freezetag_frozen)
 251                         {
 252                                 distance = vlen(head.origin - org);
 253                                 if (distance > sradius)
 254                                         continue;
 255                                 navigation_routerating(head, ratingscale, 2000);
 256                         }
 257                         else
 258                         {
 259                                 // If teamate is not frozen still seek them out as fight better
 260                                 // in a group.
 261                                 navigation_routerating(head, ratingscale/3, 2000);
 262                         }
 263                 }
 264         }
 265 }
 266
 267 void havocbot_role_ft_offense()
 268 {
 269         entity head;
 270         float unfrozen;
 271
 272         if(self.deadflag != DEAD_NO)
 273                 return;
 274
 275         if (!self.havocbot_role_timeout)
 276                 self.havocbot_role_timeout = time + random() * 10 + 20;
 277
 278         // Count how many players on team are unfrozen.
 279         unfrozen = 0;
 280         FOR_EACH_PLAYER(head)
 281         {
 282                 if ((head.team == self.team) && (!head.freezetag_frozen))
 283                         unfrozen++;
 284         }
 285
 286         // If only one left on team or if role has timed out then start trying to free players.
 287         if (((unfrozen == 0) && (!self.freezetag_frozen)) || (time > self.havocbot_role_timeout))
 288         {
 289                 dprint("changing role to freeing\n");
 290                 self.havocbot_role = havocbot_role_ft_freeing;
 291                 self.havocbot_role_timeout = 0;
 292                 return;
 293         }
 294
 295         if (time > self.bot_strategytime)
 296         {
 297                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 298
 299                 navigation_goalrating_start();
 300                 havocbot_goalrating_items(10000, self.origin, 10000);
 301                 havocbot_goalrating_enemyplayers(20000, self.origin, 10000);
 302                 havocbot_goalrating_freeplayers(9000, self.origin, 10000);
 303                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 304                 navigation_goalrating_end();
 305         }
 306 }
 307
 308 void havocbot_role_ft_freeing()
 309 {
 310         if(self.deadflag != DEAD_NO)
 311                 return;
 312
 313         if (!self.havocbot_role_timeout)
 314                 self.havocbot_role_timeout = time + random() * 10 + 20;
 315
 316         if (time > self.havocbot_role_timeout)
 317         {
 318                 dprint("changing role to offense\n");
 319                 self.havocbot_role = havocbot_role_ft_offense;
 320                 self.havocbot_role_timeout = 0;
 321                 return;
 322         }
 323
 324         if (time > self.bot_strategytime)
 325         {
 326                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 327
 328                 navigation_goalrating_start();
 329                 havocbot_goalrating_items(8000, self.origin, 10000);
 330                 havocbot_goalrating_enemyplayers(10000, self.origin, 10000);
 331                 havocbot_goalrating_freeplayers(20000, self.origin, 10000);
 332                 //havocbot_goalrating_waypoints(1, self.origin, 1000);
 333                 navigation_goalrating_end();
 334         }
 335 }
 336
 337
 338 // ==============
 339 // Hook Functions
 340 // ==============
 341
 342 MUTATOR_HOOKFUNCTION(freezetag_RemovePlayer)
 343 {
 344         self.health = 0; // neccessary to update correctly alive stats
 345         freezetag_Unfreeze(world);
 346         freezetag_count_alive_players();
 347         return 1;
 348 }
 349
 350 MUTATOR_HOOKFUNCTION(freezetag_PlayerDies)
 351 {
 352         if(round_handler_IsActive())
 353         if(round_handler_CountdownRunning())
 354         {
 355                 if(self.freezetag_frozen)
 356                         freezetag_Unfreeze(world);
 357                 freezetag_count_alive_players();
 358                 return 1; // let the player die so that he can respawn whenever he wants
 359         }
 360
 361         // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
 362         // you succeed changing team through the menu: you both really die (gibbing) and get frozen
 363         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
 364                 || frag_deathtype == DEATH_TEAMCHANGE || frag_deathtype == DEATH_AUTOTEAMCHANGE)
 365         {
 366                 // let the player die, he will be automatically frozen when he respawns
 367                 if(!self.freezetag_frozen)
 368                 {
 369                         freezetag_Add_Score(frag_attacker);
 370                         freezetag_count_alive_players();
 371                 }
 372                 else
 373                         freezetag_Unfreeze(world); // remove ice
 374                 self.freezetag_frozen_timeout = -2; // freeze on respawn
 375                 return 1;
 376         }
 377
 378         if(self.freezetag_frozen)
 379                 return 1;
 380
 381         freezetag_Freeze(frag_attacker);
 382
 383         if(frag_attacker == frag_target || frag_attacker == world)
 384         {
 385                 if(frag_target.classname == STR_PLAYER)
 386                         centerprint(frag_target, "^1You froze yourself.\n");
 387                 bprint("^7", frag_target.netname, "^1 froze himself.\n");
 388         }
 389         else
 390         {
 391                 if(frag_target.classname == STR_PLAYER)
 392                         centerprint(frag_target, strcat("^1You were frozen by ^7", frag_attacker.netname, ".\n"));
 393                 if(frag_attacker.classname == STR_PLAYER)
 394                         centerprint(frag_attacker, strcat("^2You froze ^7", frag_target.netname, ".\n"));
 395                 bprint("^7", frag_target.netname, "^1 was frozen by ^7", frag_attacker.netname, ".\n");
 396         }
 397
 398         frag_target.health = 1; // "respawn" the player :P
 399
 400         return 1;
 401 }
 402
 403 MUTATOR_HOOKFUNCTION(freezetag_PlayerSpawn)
 404 {
 405         if(self.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 406                 return 1; // do nothing, round is starting right now
 407
 408         if(self.freezetag_frozen_timeout == -2) // player was dead
 409         {
 410                 freezetag_Freeze(world);
 411                 return 1;
 412         }
 413
 414         freezetag_count_alive_players();
 415
 416         if(round_handler_IsActive())
 417         if(round_handler_IsRoundStarted())
 418         {
 419                 centerprint(self, "^1Round already started, you spawn as frozen.");
 420                 freezetag_Freeze(world);
 421         }
 422
 423         return 1;
 424 }
 425
 426 MUTATOR_HOOKFUNCTION(freezetag_reset_map_players)
 427 {
 428         FOR_EACH_PLAYER(self)
 429         {
 430                 if (self.freezetag_frozen)
 431                         freezetag_Unfreeze(world);
 432                 self.freezetag_frozen_timeout = -1;
 433                 PutClientInServer();
 434                 self.freezetag_frozen_timeout = 0;
 435         }
 436         freezetag_count_alive_players();
 437         return 1;
 438 }
 439
 440 MUTATOR_HOOKFUNCTION(freezetag_GiveFragsForKill)
 441 {
 442         frag_score = 0; // no frags counted in Freeze Tag
 443         return 1;
 444 }
 445
 446 .float reviving; // temp var
 447 MUTATOR_HOOKFUNCTION(freezetag_PlayerPreThink)
 448 {
 449         float n;
 450
 451         if(gameover)
 452                 return 1;
 453
 454         if(self.freezetag_frozen)
 455         {
 456                 // keep health = 1
 457                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen;
 458         }
 459
 460         if(round_handler_IsActive())
 461         if(!round_handler_IsRoundStarted())
 462                 return 1;
 463
 464         entity o;
 465         o = world;
 466         if(self.freezetag_frozen_timeout > 0 && time < self.freezetag_frozen_timeout)
 467                 self.freezetag_ice.alpha = ICE_MIN_ALPHA + (ICE_MAX_ALPHA - ICE_MIN_ALPHA) * (self.freezetag_frozen_timeout - time) / (self.freezetag_frozen_timeout - self.freezetag_frozen_time);
 468
 469         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
 470                 n = -1;
 471         else
 472         {
 473                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 474                 n = 0;
 475                 FOR_EACH_PLAYER(other) if(self != other)
 476                 {
 477                         if(other.freezetag_frozen == 0)
 478                         {
 479                                 if(other.team == self.team)
 480                                 {
 481                                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
 482                                         {
 483                                                 if(!o)
 484                                                         o = other;
 485                                                 if(self.freezetag_frozen)
 486                                                         other.reviving = TRUE;
 487                                                 ++n;
 488                                         }
 489                                 }
 490                         }
 491                 }
 492         }
 493
 494         if(n && self.freezetag_frozen) // OK, there is at least one teammate reviving us
 495         {
 496                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress + frametime * autocvar_g_freezetag_revive_speed, 1);
 497                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 498
 499                 if(self.freezetag_revive_progress >= 1)
 500                 {
 501                         freezetag_Unfreeze(self);
 502                         freezetag_count_alive_players();
 503
 504                         if(n == -1)
 505                         {
 506                                 string s = ftos(autocvar_g_freezetag_frozen_maxtime);
 507                                 centerprint(self, strcat("^5You were automatically revived after ", s, " seconds^5.\n"));
 508                                 bprint("^7", self.netname, "^5 were automatically revived after ", s, " seconds^5.\n");
 509                                 return 1;
 510                         }
 511
 512                         // EVERY team mate nearby gets a point (even if multiple!)
 513                         FOR_EACH_PLAYER(other)
 514                         {
 515                                 if(other.reviving)
 516                                 {
 517                                         PlayerScore_Add(other, SP_FREEZETAG_REVIVALS, +1);
 518                                         PlayerScore_Add(other, SP_SCORE, +1);
 519                                 }
 520                         }
 521
 522                         if(n > 1)
 523                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5 et al.\n"));
 524                         else
 525                                 centerprint(self, strcat("^5You were revived by ^7", o.netname, "^5.\n"));
 526                         centerprint(o, strcat("^5You revived ^7", self.netname, "^5.\n"));
 527                         if(n > 1)
 528                                 bprint("^7", o.netname, "^5 et al revived ^7", self.netname, "^5.\n");
 529                         else
 530                                 bprint("^7", o.netname, "^5 revived ^7", self.netname, "^5.\n");
 531                 }
 532
 533                 FOR_EACH_PLAYER(other)
 534                 {
 535                         if(other.reviving)
 536                         {
 537                                 other.freezetag_revive_progress = self.freezetag_revive_progress;
 538                                 other.reviving = FALSE;
 539                         }
 540                 }
 541         }
 542         else if(!n && self.freezetag_frozen) // only if no teammate is nearby will we reset
 543         {
 544                 self.freezetag_revive_progress = bound(0, self.freezetag_revive_progress - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 545                 self.health = max(1, self.freezetag_revive_progress * autocvar_g_balance_health_start);
 546         }
 547         else if(!n)
 548         {
 549                 self.freezetag_revive_progress = 0; // thawing nobody
 550         }
 551
 552         return 1;
 553 }
 554
 555 MUTATOR_HOOKFUNCTION(freezetag_PlayerPhysics)
 556 {
 557         if(self.freezetag_frozen)
 558         {
 559                 self.movement = '0 0 0';
 560                 self.disableclientprediction = 1;
 561         }
 562         return 1;
 563 }
 564
 565 MUTATOR_HOOKFUNCTION(freezetag_PlayerDamage_Calculate)
 566 {
 567         if(frag_target.freezetag_frozen && frag_deathtype != DEATH_HURTTRIGGER)
 568         {
 569                 frag_damage = 0;
 570                 frag_force = frag_force * autocvar_g_freezetag_frozen_force;
 571         }
 572         return 1;
 573 }
 574
 575 MUTATOR_HOOKFUNCTION(freezetag_ForbidThrowCurrentWeapon)
 576 {
 577         if (self.freezetag_frozen)
 578                 return 1;
 579         return 0;
 580 }
 581
 582 MUTATOR_HOOKFUNCTION(freezetag_BotRoles)
 583 {
 584         if not(self.deadflag)
 585         {
 586                 if (random() < 0.5)
 587                         self.havocbot_role = havocbot_role_ft_freeing;
 588                 else
 589                         self.havocbot_role = havocbot_role_ft_offense;
 590         }
 591
 592         return TRUE;
 593 }
 594
 595 MUTATOR_HOOKFUNCTION(freezetag_SpectateCopy)
 596 {
 597         self.freezetag_frozen = other.freezetag_frozen;
 598         self.freezetag_revive_progress = other.freezetag_revive_progress;
 599         return 0;
 600 }
 601
 602 MUTATOR_HOOKFUNCTION(freezetag_GetTeamCount)
 603 {
 604         freezetag_teams = autocvar_g_freezetag_teams_override;
 605         if(freezetag_teams < 2)
 606                 freezetag_teams = autocvar_g_freezetag_teams;
 607         freezetag_teams = bound(2, freezetag_teams, 4);
 608         ret_float = freezetag_teams;
 609         return 0;
 610 }
 611
 612 MUTATOR_DEFINITION(gamemode_freezetag)
 613 {
 614         MUTATOR_HOOK(MakePlayerObserver, freezetag_RemovePlayer, CBC_ORDER_ANY);
 615         MUTATOR_HOOK(ClientDisconnect, freezetag_RemovePlayer, CBC_ORDER_ANY);
 616         MUTATOR_HOOK(PlayerDies, freezetag_PlayerDies, CBC_ORDER_ANY);
 617         MUTATOR_HOOK(PlayerSpawn, freezetag_PlayerSpawn, CBC_ORDER_ANY);
 618         MUTATOR_HOOK(reset_map_players, freezetag_reset_map_players, CBC_ORDER_ANY);
 619         MUTATOR_HOOK(GiveFragsForKill, freezetag_GiveFragsForKill, CBC_ORDER_FIRST);
 620         MUTATOR_HOOK(PlayerPreThink, freezetag_PlayerPreThink, CBC_ORDER_FIRST);
 621         MUTATOR_HOOK(PlayerPhysics, freezetag_PlayerPhysics, CBC_ORDER_FIRST);
 622         MUTATOR_HOOK(PlayerDamage_Calculate, freezetag_PlayerDamage_Calculate, CBC_ORDER_ANY);
 623         MUTATOR_HOOK(ForbidThrowCurrentWeapon, freezetag_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 624         MUTATOR_HOOK(HavocBot_ChooseRule, freezetag_BotRoles, CBC_ORDER_ANY);
 625         MUTATOR_HOOK(SpectateCopy, freezetag_SpectateCopy, CBC_ORDER_ANY);
 626         MUTATOR_HOOK(GetTeamCount, freezetag_GetTeamCount, CBC_ORDER_EXCLUSIVE);
 627
 628         MUTATOR_ONADD
 629         {
 630                 if(time > 1) // game loads at time 1
 631                         error("This is a game type and it cannot be added at runtime.");
 632                 freezetag_Initialize();
 633         }
 634
 635         MUTATOR_ONROLLBACK_OR_REMOVE
 636         {
 637                 // we actually cannot roll back freezetag_Initialize here
 638                 // BUT: we don't need to! If this gets called, adding always
 639                 // succeeds.
 640         }
 641
 642         MUTATOR_ONREMOVE
 643         {
 644                 print("This is a game type and it cannot be removed at runtime.");
 645                 return -1;
 646         }
 647
 648         return 0;
 649 }