qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
   7 void crosshair_trace(entity pl)
   8 {
   9         traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  10 }
  11 void crosshair_trace_plusvisibletriggers(entity pl)
  12 {
  13         entity first;
  14         entity e;
  15         first = findchainfloat(solid, SOLID_TRIGGER);
  16
  17         for (e = first; e; e = e.chain)
  18                 if (e.model != "")
  19                         e.solid = SOLID_BSP;
  20
  21         crosshair_trace(pl);
  22
  23         for (e = first; e; e = e.chain)
  24                 e.solid = SOLID_TRIGGER;
  25 }
  26 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag);
  27 void WarpZone_crosshair_trace(entity pl)
  28 {
  29         WarpZone_traceline_antilag(pl, pl.cursor_trace_start, pl.cursor_trace_start + normalize(pl.cursor_trace_endpos - pl.cursor_trace_start) * MAX_SHOT_DISTANCE, MOVE_NORMAL, pl, ANTILAG_LATENCY(pl));
  30 }
  31
  32 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
  33 void() spawnpoint_use;
  34 string GetMapname();
  35 string ColoredTeamName(float t);
  36
  37 string admin_name(void)
  38 {
  39         if(autocvar_sv_adminnick != "")
  40                 return autocvar_sv_adminnick;
  41         else
  42                 return "SERVER ADMIN";
  43 }
  44
  45 float DistributeEvenly_amount;
  46 float DistributeEvenly_totalweight;
  47 void DistributeEvenly_Init(float amount, float totalweight)
  48 {
  49     if (DistributeEvenly_amount)
  50     {
  51         dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  52         dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  53     }
  54     if (totalweight == 0)
  55         DistributeEvenly_amount = 0;
  56     else
  57         DistributeEvenly_amount = amount;
  58     DistributeEvenly_totalweight = totalweight;
  59 }
  60 float DistributeEvenly_Get(float weight)
  61 {
  62     float f;
  63     if (weight <= 0)
  64         return 0;
  65     f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  66     DistributeEvenly_totalweight -= weight;
  67     DistributeEvenly_amount -= f;
  68     return f;
  69 }
  70
  71 #define move_out_of_solid(e) WarpZoneLib_MoveOutOfSolid(e)
  72
  73
  74 string STR_PLAYER = "player";
  75 string STR_SPECTATOR = "spectator";
  76 string STR_OBSERVER = "observer";
  77
  78 #if 0
  79 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  80 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  81 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  82 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  83 #else
  84 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
  85 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
  86 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  87 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
  88 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
  89 #endif
  90
  91 // copies a string to a tempstring (so one can strunzone it)
  92 string strcat1(string s) = #115; // FRIK_FILE
  93
  94 float logfile_open;
  95 float logfile;
  96
  97 void bcenterprint(string s)
  98 {
  99     // TODO replace by MSG_ALL (would show it to spectators too, though)?
 100     entity head;
 101     FOR_EACH_PLAYER(head)
 102     if (clienttype(head) == CLIENTTYPE_REAL)
 103         centerprint(head, s);
 104 }
 105
 106 void GameLogEcho(string s)
 107 {
 108     string fn;
 109     float matches;
 110
 111     if (autocvar_sv_eventlog_files)
 112     {
 113         if (!logfile_open)
 114         {
 115             logfile_open = TRUE;
 116             matches = autocvar_sv_eventlog_files_counter + 1;
 117             cvar_set("sv_eventlog_files_counter", ftos(matches));
 118             fn = ftos(matches);
 119             if (strlen(fn) < 8)
 120                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 121             fn = strcat(autocvar_sv_eventlog_files_nameprefix, fn, autocvar_sv_eventlog_files_namesuffix);
 122             logfile = fopen(fn, FILE_APPEND);
 123             fputs(logfile, ":logversion:3\n");
 124         }
 125         if (logfile >= 0)
 126         {
 127             if (autocvar_sv_eventlog_files_timestamps)
 128                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 129             else
 130                 fputs(logfile, strcat(s, "\n"));
 131         }
 132     }
 133     if (autocvar_sv_eventlog_console)
 134     {
 135         print(s, "\n");
 136     }
 137 }
 138
 139 void GameLogInit()
 140 {
 141     logfile_open = 0;
 142     // will be opened later
 143 }
 144
 145 void GameLogClose()
 146 {
 147     if (logfile_open && logfile >= 0)
 148     {
 149         fclose(logfile);
 150         logfile = -1;
 151     }
 152 }
 153
 154 float spawnpoint_nag;
 155 void relocate_spawnpoint()
 156 {
 157     // nudge off the floor
 158     setorigin(self, self.origin + '0 0 1');
 159
 160     tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 161     if (trace_startsolid)
 162     {
 163         vector o;
 164         o = self.origin;
 165         self.mins = PL_MIN;
 166         self.maxs = PL_MAX;
 167         if (!move_out_of_solid(self))
 168             objerror("could not get out of solid at all!");
 169         print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 170         print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 171         print(" ", ftos(self.origin_y - o_y));
 172         print(" ", ftos(self.origin_z - o_z), "'\n");
 173         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
 174         {
 175             if (!spawnpoint_nag)
 176                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 177             spawnpoint_nag = 1;
 178         }
 179         else
 180         {
 181             setorigin(self, o);
 182             self.mins = self.maxs = '0 0 0';
 183             objerror("player spawn point in solid, mapper sucks!\n");
 184             return;
 185         }
 186     }
 187
 188     self.use = spawnpoint_use;
 189     self.team_saved = self.team;
 190     if (!self.cnt)
 191         self.cnt = 1;
 192
 193     if (have_team_spawns != 0)
 194         if (self.team)
 195             have_team_spawns = 1;
 196     have_team_spawns_forteam[self.team] = 1;
 197
 198     if (autocvar_r_showbboxes)
 199     {
 200         // show where spawnpoints point at too
 201         makevectors(self.angles);
 202         entity e;
 203         e = spawn();
 204         e.classname = "info_player_foo";
 205         setorigin(e, self.origin + v_forward * 24);
 206         setsize(e, '-8 -8 -8', '8 8 8');
 207         e.solid = SOLID_TRIGGER;
 208     }
 209 }
 210
 211 #define strstr strstrofs
 212 /*
 213 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 214 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 215 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 216 // BE CONSTANT OR strzoneD!
 217 float strstr(string haystack, string needle, float offset)
 218 {
 219         float len, endpos;
 220         string found;
 221         len = strlen(needle);
 222         endpos = strlen(haystack) - len;
 223         while(offset <= endpos)
 224         {
 225                 found = substring(haystack, offset, len);
 226                 if(found == needle)
 227                         return offset;
 228                 offset = offset + 1;
 229         }
 230         return -1;
 231 }
 232 */
 233
 234 float NUM_NEAREST_ENTITIES = 4;
 235 entity nearest_entity[NUM_NEAREST_ENTITIES];
 236 float nearest_length[NUM_NEAREST_ENTITIES];
 237 entity findnearest(vector point, .string field, string value, vector axismod)
 238 {
 239     entity localhead;
 240     float i;
 241     float j;
 242     float len;
 243     vector dist;
 244
 245     float num_nearest;
 246     num_nearest = 0;
 247
 248     localhead = find(world, field, value);
 249     while (localhead)
 250     {
 251         if ((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 252             dist = localhead.oldorigin;
 253         else
 254             dist = localhead.origin;
 255         dist = dist - point;
 256         dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 257         len = vlen(dist);
 258
 259         for (i = 0; i < num_nearest; ++i)
 260         {
 261             if (len < nearest_length[i])
 262                 break;
 263         }
 264
 265         // now i tells us where to insert at
 266         //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 267         if (i < NUM_NEAREST_ENTITIES)
 268         {
 269             for (j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 270             {
 271                 nearest_length[j + 1] = nearest_length[j];
 272                 nearest_entity[j + 1] = nearest_entity[j];
 273             }
 274             nearest_length[i] = len;
 275             nearest_entity[i] = localhead;
 276             if (num_nearest < NUM_NEAREST_ENTITIES)
 277                 num_nearest = num_nearest + 1;
 278         }
 279
 280         localhead = find(localhead, field, value);
 281     }
 282
 283     // now use the first one from our list that we can see
 284     for (i = 0; i < num_nearest; ++i)
 285     {
 286         traceline(point, nearest_entity[i].origin, TRUE, world);
 287         if (trace_fraction == 1)
 288         {
 289             if (i != 0)
 290             {
 291                 dprint("Nearest point (");
 292                 dprint(nearest_entity[0].netname);
 293                 dprint(") is not visible, using a visible one.\n");
 294             }
 295             return nearest_entity[i];
 296         }
 297     }
 298
 299     if (num_nearest == 0)
 300         return world;
 301
 302     dprint("Not seeing any location point, using nearest as fallback.\n");
 303     /* DEBUGGING CODE:
 304     dprint("Candidates were: ");
 305     for(j = 0; j < num_nearest; ++j)
 306     {
 307         if(j != 0)
 308                 dprint(", ");
 309         dprint(nearest_entity[j].netname);
 310     }
 311     dprint("\n");
 312     */
 313
 314     return nearest_entity[0];
 315 }
 316
 317 void spawnfunc_target_location()
 318 {
 319     self.classname = "target_location";
 320     // location name in netname
 321     // eventually support: count, teamgame selectors, line of sight?
 322 }
 323
 324 void spawnfunc_info_location()
 325 {
 326     self.classname = "target_location";
 327     self.message = self.netname;
 328 }
 329
 330 string NearestLocation(vector p)
 331 {
 332     entity loc;
 333     string ret;
 334     ret = "somewhere";
 335     loc = findnearest(p, classname, "target_location", '1 1 1');
 336     if (loc)
 337     {
 338         ret = loc.message;
 339     }
 340     else
 341     {
 342         loc = findnearest(p, target, "###item###", '1 1 4');
 343         if (loc)
 344             ret = loc.netname;
 345     }
 346     return ret;
 347 }
 348
 349 string formatmessage(string msg)
 350 {
 351         float p, p1, p2;
 352         float n;
 353         vector cursor;
 354         entity cursor_ent;
 355         string escape;
 356         string replacement;
 357         p = 0;
 358         n = 7;
 359
 360         WarpZone_crosshair_trace(self);
 361         cursor = trace_endpos;
 362         cursor_ent = trace_ent;
 363
 364         while (1) {
 365                 if (n < 1)
 366                         break; // too many replacements
 367
 368                 n = n - 1;
 369                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 370                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 371
 372                 if (p1 < 0)
 373                         p1 = p2;
 374
 375                 if (p2 < 0)
 376                         p2 = p1;
 377
 378                 p = min(p1, p2);
 379
 380                 if (p < 0)
 381                         break;
 382
 383                 replacement = substring(msg, p, 2);
 384                 escape = substring(msg, p + 1, 1);
 385
 386                 if (escape == "%")
 387                         replacement = "%";
 388                 else if (escape == "\\")
 389                         replacement = "\\";
 390                 else if (escape == "n")
 391                         replacement = "\n";
 392                 else if (escape == "a")
 393                         replacement = ftos(floor(self.armorvalue));
 394                 else if (escape == "h")
 395                         replacement = ftos(floor(self.health));
 396                 else if (escape == "l")
 397                         replacement = NearestLocation(self.origin);
 398                 else if (escape == "y")
 399                         replacement = NearestLocation(cursor);
 400                 else if (escape == "d")
 401                         replacement = NearestLocation(self.death_origin);
 402                 else if (escape == "w") {
 403                         float wep;
 404                         wep = self.weapon;
 405                         if (!wep)
 406                                 wep = self.switchweapon;
 407                         if (!wep)
 408                                 wep = self.cnt;
 409                         replacement = W_Name(wep);
 410                 } else if (escape == "W") {
 411                         if (self.items & IT_SHELLS) replacement = "shells";
 412                         else if (self.items & IT_NAILS) replacement = "bullets";
 413                         else if (self.items & IT_ROCKETS) replacement = "rockets";
 414                         else if (self.items & IT_CELLS) replacement = "cells";
 415                         else replacement = "batteries"; // ;)
 416                 } else if (escape == "x") {
 417                         replacement = cursor_ent.netname;
 418                         if (!replacement || !cursor_ent)
 419                                 replacement = "nothing";
 420                 } else if (escape == "s")
 421                         replacement = ftos(vlen(self.velocity - self.velocity_z * '0 0 1'));
 422                 else if (escape == "S")
 423                         replacement = ftos(vlen(self.velocity));
 424
 425                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 426                 p = p + strlen(replacement);
 427         }
 428         return msg;
 429 }
 430
 431 float boolean(float value) { // if value is 0 return FALSE (0), otherwise return TRUE (1)
 432         return (value == 0) ? FALSE : TRUE;
 433 }
 434
 435 /*
 436 =============
 437 GetCvars
 438 =============
 439 Called with:
 440   0:  sends the request
 441   >0: receives a cvar from name=argv(f) value=argv(f+1)
 442 */
 443 void GetCvars_handleString(string thisname, float f, .string field, string name)
 444 {
 445         if (f < 0)
 446         {
 447                 if (self.field)
 448                         strunzone(self.field);
 449                 self.field = string_null;
 450         }
 451         else if (f > 0)
 452         {
 453                 if (thisname == name)
 454                 {
 455                         if (self.field)
 456                                 strunzone(self.field);
 457                         self.field = strzone(argv(f + 1));
 458                 }
 459         }
 460         else
 461                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 462 }
 463 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 464 {
 465         GetCvars_handleString(thisname, f, field, name);
 466         if (f >= 0) // also initialize to the fitting value for "" when sending cvars out
 467                 if (thisname == name)
 468                 {
 469                         string s;
 470                         s = func(strcat1(self.field));
 471                         if (s != self.field)
 472                         {
 473                                 strunzone(self.field);
 474                                 self.field = strzone(s);
 475                         }
 476                 }
 477 }
 478 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 479 {
 480         if (f < 0)
 481         {
 482         }
 483         else if (f > 0)
 484         {
 485                 if (thisname == name)
 486                         self.field = stof(argv(f + 1));
 487         }
 488         else
 489                 stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 490 }
 491 void GetCvars_handleFloatOnce(string thisname, float f, .float field, string name)
 492 {
 493         if (f < 0)
 494         {
 495         }
 496         else if (f > 0)
 497         {
 498                 if (thisname == name)
 499                 {
 500                         if(!self.field)
 501                         {
 502                                 self.field = stof(argv(f + 1));
 503                                 if(!self.field)
 504                                         self.field = -1;
 505                         }
 506                 }
 507         }
 508         else
 509         {
 510                 if(!self.field)
 511                         stuffcmd(self, strcat("cl_cmd sendcvar ", name, "\n"));
 512         }
 513 }
 514 float w_getbestweapon(entity e);
 515 string W_FixWeaponOrder_ForceComplete_AndBuildImpulseList(string wo)
 516 {
 517         string o;
 518         o = W_FixWeaponOrder_ForceComplete(wo);
 519         if(self.weaponorder_byimpulse)
 520         {
 521                 strunzone(self.weaponorder_byimpulse);
 522                 self.weaponorder_byimpulse = string_null;
 523         }
 524         self.weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(o));
 525         return o;
 526 }
 527 void GetCvars(float f)
 528 {
 529         string s;
 530
 531         if (f > 0)
 532                 s = strcat1(argv(f));
 533
 534         get_cvars_f = f;
 535         get_cvars_s = s;
 536         MUTATOR_CALLHOOK(GetCvars);
 537         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 538         GetCvars_handleFloat(s, f, cvar_cl_autoscreenshot, "cl_autoscreenshot");
 539         GetCvars_handleString(s, f, cvar_g_xonoticversion, "g_xonoticversion");
 540         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 541         GetCvars_handleFloat(s, f, cvar_cl_clippedspectating, "cl_clippedspectating");
 542         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete_AndBuildImpulseList);
 543         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 544         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 553         GetCvars_handleFloat(s, f, cvar_cl_weaponimpulsemode, "cl_weaponimpulsemode");
 554         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 555         GetCvars_handleFloat(s, f, cvar_cl_noantilag, "cl_noantilag");
 556         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 557         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 558         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_share, "cl_accuracy_data_share");
 559         GetCvars_handleFloat(s, f, cvar_cl_accuracy_data_receive, "cl_accuracy_data_receive");
 560
 561         self.cvar_cl_accuracy_data_share = boolean(self.cvar_cl_accuracy_data_share);
 562         self.cvar_cl_accuracy_data_receive = boolean(self.cvar_cl_accuracy_data_receive);
 563
 564 #ifdef ALLOW_FORCEMODELS
 565         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodels, "cl_forceplayermodels");
 566         GetCvars_handleFloat(s, f, cvar_cl_forceplayermodelsfromxonotic, "cl_forceplayermodelsfromxonotic");
 567 #endif
 568         GetCvars_handleFloatOnce(s, f, cvar_cl_gunalign, "cl_gunalign");
 569         GetCvars_handleFloat(s, f, cvar_cl_allow_uid2name, "cl_allow_uid2name");
 570         GetCvars_handleFloat(s, f, cvar_cl_allow_uidtracking, "cl_allow_uidtracking");
 571         GetCvars_handleFloat(s, f, cvar_cl_movement_track_canjump, "cl_movement_track_canjump");
 572         GetCvars_handleFloat(s, f, cvar_cl_newusekeysupported, "cl_newusekeysupported");
 573
 574         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 575         if (f > 0)
 576         {
 577                 if (s == "cl_weaponpriority")
 578                         self.switchweapon = w_getbestweapon(self);
 579                 if (s == "cl_allow_uidtracking")
 580                         PlayerStats_AddPlayer(self);
 581         }
 582 }
 583
 584 void backtrace(string msg)
 585 {
 586     float dev, war;
 587     dev = autocvar_developer;
 588     war = autocvar_prvm_backtraceforwarnings;
 589     cvar_set("developer", "1");
 590     cvar_set("prvm_backtraceforwarnings", "1");
 591     print("\n");
 592     print("--- CUT HERE ---\nWARNING: ");
 593     print(msg);
 594     print("\n");
 595     remove(world); // isn't there any better way to cause a backtrace?
 596     print("\n--- CUT UNTIL HERE ---\n");
 597     cvar_set("developer", ftos(dev));
 598     cvar_set("prvm_backtraceforwarnings", ftos(war));
 599 }
 600
 601 string Team_ColorCode(float teamid)
 602 {
 603     if (teamid == COLOR_TEAM1)
 604         return "^1";
 605     else if (teamid == COLOR_TEAM2)
 606         return "^4";
 607     else if (teamid == COLOR_TEAM3)
 608         return "^3";
 609     else if (teamid == COLOR_TEAM4)
 610         return "^6";
 611     else
 612         return "^7";
 613 }
 614
 615 string Team_ColorName(float t)
 616 {
 617     // fixme: Search for team entities and get their .netname's!
 618     if (t == COLOR_TEAM1)
 619         return "Red";
 620     if (t == COLOR_TEAM2)
 621         return "Blue";
 622     if (t == COLOR_TEAM3)
 623         return "Yellow";
 624     if (t == COLOR_TEAM4)
 625         return "Pink";
 626     return "Neutral";
 627 }
 628
 629 string Team_ColorNameLowerCase(float t)
 630 {
 631     // fixme: Search for team entities and get their .netname's!
 632     if (t == COLOR_TEAM1)
 633         return "red";
 634     if (t == COLOR_TEAM2)
 635         return "blue";
 636     if (t == COLOR_TEAM3)
 637         return "yellow";
 638     if (t == COLOR_TEAM4)
 639         return "pink";
 640     return "neutral";
 641 }
 642
 643 float ColourToNumber(string team_colour)
 644 {
 645         if (team_colour == "red")
 646                 return COLOR_TEAM1;
 647
 648         if (team_colour == "blue")
 649                 return COLOR_TEAM2;
 650
 651         if (team_colour == "yellow")
 652                 return COLOR_TEAM3;
 653
 654         if (team_colour == "pink")
 655                 return COLOR_TEAM4;
 656
 657         if (team_colour == "auto")
 658                 return 0;
 659
 660         return -1;
 661 }
 662
 663 float NumberToTeamNumber(float number)
 664 {
 665         if (number == 1)
 666                 return COLOR_TEAM1;
 667
 668         if (number == 2)
 669                 return COLOR_TEAM2;
 670
 671         if (number == 3)
 672                 return COLOR_TEAM3;
 673
 674         if (number == 4)
 675                 return COLOR_TEAM4;
 676
 677         return -1;
 678 }
 679
 680 // decolorizes and team colors the player name when needed
 681 string playername(entity p)
 682 {
 683     string t;
 684     if (teamplay && !intermission_running && p.classname == "player")
 685     {
 686         t = Team_ColorCode(p.team);
 687         return strcat(t, strdecolorize(p.netname));
 688     }
 689     else
 690         return p.netname;
 691 }
 692
 693 vector randompos(vector m1, vector m2)
 694 {
 695     vector v;
 696     m2 = m2 - m1;
 697     v_x = m2_x * random() + m1_x;
 698     v_y = m2_y * random() + m1_y;
 699     v_z = m2_z * random() + m1_z;
 700     return  v;
 701 }
 702
 703 //#NO AUTOCVARS START
 704
 705 float g_pickup_shells;
 706 float g_pickup_shells_max;
 707 float g_pickup_nails;
 708 float g_pickup_nails_max;
 709 float g_pickup_rockets;
 710 float g_pickup_rockets_max;
 711 float g_pickup_cells;
 712 float g_pickup_cells_max;
 713 float g_pickup_fuel;
 714 float g_pickup_fuel_jetpack;
 715 float g_pickup_fuel_max;
 716 float g_pickup_armorsmall;
 717 float g_pickup_armorsmall_max;
 718 float g_pickup_armorsmall_anyway;
 719 float g_pickup_armormedium;
 720 float g_pickup_armormedium_max;
 721 float g_pickup_armormedium_anyway;
 722 float g_pickup_armorbig;
 723 float g_pickup_armorbig_max;
 724 float g_pickup_armorbig_anyway;
 725 float g_pickup_armorlarge;
 726 float g_pickup_armorlarge_max;
 727 float g_pickup_armorlarge_anyway;
 728 float g_pickup_healthsmall;
 729 float g_pickup_healthsmall_max;
 730 float g_pickup_healthsmall_anyway;
 731 float g_pickup_healthmedium;
 732 float g_pickup_healthmedium_max;
 733 float g_pickup_healthmedium_anyway;
 734 float g_pickup_healthlarge;
 735 float g_pickup_healthlarge_max;
 736 float g_pickup_healthlarge_anyway;
 737 float g_pickup_healthmega;
 738 float g_pickup_healthmega_max;
 739 float g_pickup_healthmega_anyway;
 740 float g_pickup_ammo_anyway;
 741 float g_pickup_weapons_anyway;
 742 float g_weaponarena;
 743 float g_weaponarena_random;
 744 float g_weaponarena_random_with_laser;
 745 string g_weaponarena_list;
 746 float g_weaponspeedfactor;
 747 float g_weaponratefactor;
 748 float g_weapondamagefactor;
 749 float g_weaponforcefactor;
 750 float g_weaponspreadfactor;
 751
 752 float start_weapons;
 753 float start_items;
 754 float start_ammo_shells;
 755 float start_ammo_nails;
 756 float start_ammo_rockets;
 757 float start_ammo_cells;
 758 float start_ammo_fuel;
 759 float start_health;
 760 float start_armorvalue;
 761 float warmup_start_weapons;
 762 float warmup_start_ammo_shells;
 763 float warmup_start_ammo_nails;
 764 float warmup_start_ammo_rockets;
 765 float warmup_start_ammo_cells;
 766 float warmup_start_ammo_fuel;
 767 float warmup_start_health;
 768 float warmup_start_armorvalue;
 769 float g_weapon_stay;
 770 float g_ghost_items;
 771
 772 entity get_weaponinfo(float w);
 773
 774 float want_weapon(string cvarprefix, entity weaponinfo, float allguns)
 775 {
 776         var float i = weaponinfo.weapon;
 777
 778         if (!i)
 779                 return 0;
 780
 781         var float t = cvar(strcat(cvarprefix, weaponinfo.netname));
 782
 783         if (t < 0) // "default" weapon selection
 784         {
 785                 if (g_lms || g_ca || allguns)
 786                         t = (weaponinfo.spawnflags & WEP_FLAG_NORMAL);
 787                 else if(t < -1)
 788                         t = 0;
 789                 else if (g_cts)
 790                         t = (i == WEP_SHOTGUN);
 791                 else if (g_nexball)
 792                         t = 0; // weapon is set a few lines later
 793                 else
 794                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 795                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 796                         t |= (i == WEP_HOOK);
 797         }
 798
 799         return t;
 800 }
 801
 802 void readplayerstartcvars()
 803 {
 804         entity e;
 805         float i, j, t;
 806         string s;
 807
 808         // initialize starting values for players
 809         start_weapons = 0;
 810         start_items = 0;
 811         start_ammo_shells = 0;
 812         start_ammo_nails = 0;
 813         start_ammo_rockets = 0;
 814         start_ammo_cells = 0;
 815         start_health = cvar("g_balance_health_start");
 816         start_armorvalue = cvar("g_balance_armor_start");
 817
 818         g_weaponarena = 0;
 819         s = cvar_string("g_weaponarena");
 820         if (s == "0" || s == "")
 821         {
 822                 if(g_lms || g_ca)
 823                         s = "most";
 824         }
 825
 826         if (s == "0" || s == "")
 827         {
 828                 // no arena
 829         }
 830         else if (s == "off")
 831         {
 832                 // forcibly turn off weaponarena
 833         }
 834         else if (s == "all")
 835         {
 836                 g_weaponarena_list = "All Weapons";
 837                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 838                 {
 839                         e = get_weaponinfo(j);
 840                         g_weaponarena |= e.weapons;
 841                         weapon_action(e.weapon, WR_PRECACHE);
 842                 }
 843         }
 844         else if (s == "most")
 845         {
 846                 g_weaponarena_list = "Most Weapons";
 847                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 848                 {
 849                         e = get_weaponinfo(j);
 850                         if (e.spawnflags & WEP_FLAG_NORMAL)
 851                         {
 852                                 g_weaponarena |= e.weapons;
 853                                 weapon_action(e.weapon, WR_PRECACHE);
 854                         }
 855                 }
 856         }
 857         else if (s == "none")
 858         {
 859                 g_weaponarena_list = "No Weapons";
 860                 g_weaponarena = WEPBIT_ALL + 1; // this supports no single weapon bit!
 861         }
 862         else
 863         {
 864                 t = tokenize_console(s);
 865                 g_weaponarena_list = "";
 866                 for (i = 0; i < t; ++i)
 867                 {
 868                         s = argv(i);
 869                         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 870                         {
 871                                 e = get_weaponinfo(j);
 872                                 if (e.netname == s)
 873                                 {
 874                                         g_weaponarena |= e.weapons;
 875                                         weapon_action(e.weapon, WR_PRECACHE);
 876                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 877                                         break;
 878                                 }
 879                         }
 880                         if (j > WEP_LAST)
 881                         {
 882                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 883                         }
 884                 }
 885                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 886         }
 887
 888         if(g_weaponarena)
 889                 g_weaponarena_random = cvar("g_weaponarena_random");
 890         else
 891                 g_weaponarena_random = 0;
 892         g_weaponarena_random_with_laser = cvar("g_weaponarena_random_with_laser");
 893
 894         if (g_weaponarena)
 895         {
 896                 start_weapons = g_weaponarena;
 897                 if(!(g_lms || g_ca))
 898                         start_items |= IT_UNLIMITED_AMMO;
 899         }
 900         else if (g_minstagib)
 901         {
 902                 start_health = 100;
 903                 start_armorvalue = 0;
 904                 start_weapons = WEPBIT_MINSTANEX;
 905                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 906                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 907                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
 908
 909                 if (g_minstagib_invis_alpha <= 0)
 910                         g_minstagib_invis_alpha = -1;
 911         }
 912         else
 913         {
 914                 for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 915                 {
 916                         e = get_weaponinfo(i);
 917                         if(want_weapon("g_start_weapon_", e, FALSE))
 918                                 start_weapons |= e.weapons;
 919                 }
 920         }
 921
 922         if(!cvar("g_use_ammunition"))
 923                 start_items |= IT_UNLIMITED_AMMO;
 924
 925         if(g_minstagib)
 926         {
 927                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 928                 start_ammo_fuel = cvar("g_start_ammo_fuel");
 929         }
 930         else if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 931         {
 932                 start_ammo_rockets = 999;
 933                 start_ammo_shells = 999;
 934                 start_ammo_cells = 999;
 935                 start_ammo_nails = 999;
 936                 start_ammo_fuel = 999;
 937         }
 938         else
 939         {
 940                 if(g_lms || g_ca)
 941                 {
 942                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 943                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 944                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 945                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 946                         start_ammo_fuel = cvar("g_lms_start_ammo_fuel");
 947                 }
 948                 else
 949                 {
 950                         start_ammo_shells = cvar("g_start_ammo_shells");
 951                         start_ammo_nails = cvar("g_start_ammo_nails");
 952                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 953                         start_ammo_cells = cvar("g_start_ammo_cells");
 954                         start_ammo_fuel = cvar("g_start_ammo_fuel");
 955                 }
 956         }
 957
 958         if (g_lms || g_ca)
 959         {
 960                 start_health = cvar("g_lms_start_health");
 961                 start_armorvalue = cvar("g_lms_start_armor");
 962         }
 963
 964         if (inWarmupStage)
 965         {
 966                 warmup_start_ammo_shells = start_ammo_shells;
 967                 warmup_start_ammo_nails = start_ammo_nails;
 968                 warmup_start_ammo_rockets = start_ammo_rockets;
 969                 warmup_start_ammo_cells = start_ammo_cells;
 970                 warmup_start_ammo_fuel = start_ammo_fuel;
 971                 warmup_start_health = start_health;
 972                 warmup_start_armorvalue = start_armorvalue;
 973                 warmup_start_weapons = start_weapons;
 974
 975                 if (!g_weaponarena && !g_minstagib && !g_ca)
 976                 {
 977                         warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 978                         warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 979                         warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 980                         warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 981                         warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
 982                         warmup_start_health = cvar("g_warmup_start_health");
 983                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 984                         warmup_start_weapons = 0;
 985                         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 986                         {
 987                                 e = get_weaponinfo(i);
 988                                 if(want_weapon("g_start_weapon_", e, cvar("g_warmup_allguns")))
 989                                         warmup_start_weapons |= e.weapons;
 990                         }
 991                 }
 992         }
 993
 994         if (g_jetpack || (g_grappling_hook && (start_weapons & WEPBIT_HOOK)))
 995         {
 996                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 997                 start_items |= IT_FUEL_REGEN;
 998                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
 999                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
1000         }
1001
1002         if (g_jetpack)
1003                 start_items |= IT_JETPACK;
1004
1005         MUTATOR_CALLHOOK(SetStartItems);
1006
1007         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
1008         {
1009                 e = get_weaponinfo(i);
1010                 if(e.weapons & (start_weapons | warmup_start_weapons))
1011                         weapon_action(e.weapon, WR_PRECACHE);
1012         }
1013
1014         start_ammo_shells = max(0, start_ammo_shells);
1015         start_ammo_nails = max(0, start_ammo_nails);
1016         start_ammo_cells = max(0, start_ammo_cells);
1017         start_ammo_rockets = max(0, start_ammo_rockets);
1018         start_ammo_fuel = max(0, start_ammo_fuel);
1019
1020         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
1021         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
1022         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
1023         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
1024         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
1025 }
1026
1027 float g_bugrigs;
1028 float g_bugrigs_planar_movement;
1029 float g_bugrigs_planar_movement_car_jumping;
1030 float g_bugrigs_reverse_spinning;
1031 float g_bugrigs_reverse_speeding;
1032 float g_bugrigs_reverse_stopping;
1033 float g_bugrigs_air_steering;
1034 float g_bugrigs_angle_smoothing;
1035 float g_bugrigs_friction_floor;
1036 float g_bugrigs_friction_brake;
1037 float g_bugrigs_friction_air;
1038 float g_bugrigs_accel;
1039 float g_bugrigs_speed_ref;
1040 float g_bugrigs_speed_pow;
1041 float g_bugrigs_steer;
1042
1043 float g_touchexplode;
1044 float g_touchexplode_radius;
1045 float g_touchexplode_damage;
1046 float g_touchexplode_edgedamage;
1047 float g_touchexplode_force;
1048
1049 float sv_autotaunt;
1050 float sv_taunt;
1051
1052 float sv_pitch_min;
1053 float sv_pitch_max;
1054 float sv_pitch_fixyaw;
1055
1056 string GetGametype(); // g_world.qc
1057 void readlevelcvars(void)
1058 {
1059         // first load all the mutators
1060         if(cvar("g_invincible_projectiles"))
1061                 MUTATOR_ADD(mutator_invincibleprojectiles);
1062         if(cvar("g_nix"))
1063                 MUTATOR_ADD(mutator_nix);
1064         if(cvar("g_dodging"))
1065                 MUTATOR_ADD(mutator_dodging);
1066         if(cvar("g_rocket_flying"))
1067                 MUTATOR_ADD(mutator_rocketflying);
1068         if(cvar("g_vampire"))
1069                 MUTATOR_ADD(mutator_vampire);
1070         if(cvar("g_spawn_near_teammate"))
1071                 MUTATOR_ADD(mutator_spawn_near_teammate);
1072
1073         // is this a mutator? is this a mode?
1074         if(cvar("g_sandbox"))
1075                 MUTATOR_ADD(sandbox);
1076
1077         if(cvar("sv_allow_fullbright"))
1078                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
1079
1080     g_bugrigs = cvar("g_bugrigs");
1081     g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1082     g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1083     g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1084     g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1085     g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1086     g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1087     g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1088     g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1089     g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1090     g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1091     g_bugrigs_accel = cvar("g_bugrigs_accel");
1092     g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1093     g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1094     g_bugrigs_steer = cvar("g_bugrigs_steer");
1095
1096     g_touchexplode = cvar("g_touchexplode");
1097     g_touchexplode_radius = cvar("g_touchexplode_radius");
1098     g_touchexplode_damage = cvar("g_touchexplode_damage");
1099     g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1100     g_touchexplode_force = cvar("g_touchexplode_force");
1101
1102 #ifdef ALLOW_FORCEMODELS
1103         sv_clforceplayermodels = cvar("sv_clforceplayermodels");
1104 #endif
1105
1106         sv_clones = cvar("sv_clones");
1107         sv_gentle = cvar("sv_gentle");
1108         sv_foginterval = cvar("sv_foginterval");
1109         g_cloaked = cvar("g_cloaked");
1110     if(g_cts)
1111         g_cloaked = 1; // always enable cloak in CTS
1112         g_jump_grunt = cvar("g_jump_grunt");
1113         g_footsteps = cvar("g_footsteps");
1114         g_grappling_hook = cvar("g_grappling_hook");
1115         g_jetpack = cvar("g_jetpack");
1116         g_midair = cvar("g_midair");
1117         g_minstagib = cvar("g_minstagib");
1118         g_norecoil = cvar("g_norecoil");
1119         g_bloodloss = cvar("g_bloodloss");
1120         sv_maxidle = cvar("sv_maxidle");
1121         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1122         g_ctf_reverse = cvar("g_ctf_reverse");
1123         sv_autotaunt = cvar("sv_autotaunt");
1124         sv_taunt = cvar("sv_taunt");
1125
1126         inWarmupStage = cvar("g_warmup");
1127         g_warmup_limit = cvar("g_warmup_limit");
1128         g_warmup_allguns = cvar("g_warmup_allguns");
1129         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1130
1131         if ((g_race && g_race_qualifying == 2) || g_runematch || g_arena || g_assault || cvar("g_campaign"))
1132                 inWarmupStage = 0; // these modes cannot work together, sorry
1133
1134         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1135         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
1136         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1137         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1138         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1139         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1140         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1141         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
1142         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
1143         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
1144         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
1145         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
1146         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
1147         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
1148
1149         g_weaponspeedfactor = cvar("g_weaponspeedfactor");
1150         g_weaponratefactor = cvar("g_weaponratefactor");
1151         g_weapondamagefactor = cvar("g_weapondamagefactor");
1152         g_weaponforcefactor = cvar("g_weaponforcefactor");
1153         g_weaponspreadfactor = cvar("g_weaponspreadfactor");
1154
1155         g_pickup_shells = cvar("g_pickup_shells");
1156         g_pickup_shells_max = cvar("g_pickup_shells_max");
1157         g_pickup_nails = cvar("g_pickup_nails");
1158         g_pickup_nails_max = cvar("g_pickup_nails_max");
1159         g_pickup_rockets = cvar("g_pickup_rockets");
1160         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
1161         g_pickup_cells = cvar("g_pickup_cells");
1162         g_pickup_cells_max = cvar("g_pickup_cells_max");
1163         g_pickup_fuel = cvar("g_pickup_fuel");
1164         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
1165         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
1166         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
1167         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
1168         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
1169         g_pickup_armormedium = cvar("g_pickup_armormedium");
1170         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
1171         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
1172         g_pickup_armorbig = cvar("g_pickup_armorbig");
1173         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
1174         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
1175         g_pickup_armorlarge = cvar("g_pickup_armorlarge");
1176         g_pickup_armorlarge_max = cvar("g_pickup_armorlarge_max");
1177         g_pickup_armorlarge_anyway = cvar("g_pickup_armorlarge_anyway");
1178         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
1179         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
1180         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
1181         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
1182         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
1183         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
1184         g_pickup_healthlarge = cvar("g_pickup_healthlarge");
1185         g_pickup_healthlarge_max = cvar("g_pickup_healthlarge_max");
1186         g_pickup_healthlarge_anyway = cvar("g_pickup_healthlarge_anyway");
1187         g_pickup_healthmega = cvar("g_pickup_healthmega");
1188         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
1189         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
1190
1191         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
1192         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
1193
1194         g_pinata = cvar("g_pinata");
1195
1196     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
1197     if(!g_weapon_stay)
1198         g_weapon_stay = cvar("g_weapon_stay");
1199
1200         g_ghost_items = cvar("g_ghost_items");
1201
1202         if(g_ghost_items >= 1)
1203                 g_ghost_items = 0.25; // default alpha value
1204
1205         if not(inWarmupStage && !g_ca)
1206                 game_starttime = cvar("g_start_delay");
1207
1208         sv_pitch_min = cvar("sv_pitch_min");
1209         sv_pitch_max = cvar("sv_pitch_max");
1210         sv_pitch_fixyaw = cvar("sv_pitch_fixyaw");
1211
1212         readplayerstartcvars();
1213 }
1214
1215 //#NO AUTOCVARS END
1216
1217 // Sound functions
1218 string precache_sound (string s) = #19;
1219 float precache_sound_index (string s) = #19;
1220
1221 #define SND_VOLUME      1
1222 #define SND_ATTENUATION 2
1223 #define SND_LARGEENTITY 8
1224 #define SND_LARGESOUND  16
1225
1226 float sound_allowed(float dest, entity e)
1227 {
1228     // sounds from world may always pass
1229     for (;;)
1230     {
1231         if (e.classname == "body")
1232             e = e.enemy;
1233         else if (e.realowner && e.realowner != e)
1234             e = e.realowner;
1235         else if (e.owner && e.owner != e)
1236             e = e.owner;
1237         else
1238             break;
1239     }
1240     // sounds to self may always pass
1241     if (dest == MSG_ONE)
1242         if (e == msg_entity)
1243             return TRUE;
1244     // sounds by players can be removed
1245     if (autocvar_bot_sound_monopoly)
1246         if (clienttype(e) == CLIENTTYPE_REAL)
1247             return FALSE;
1248     // anything else may pass
1249     return TRUE;
1250 }
1251
1252 #ifdef COMPAT_XON010_CHANNELS
1253 void(entity e, float chan, string samp, float vol, float atten) builtin_sound = #8;
1254 void sound(entity e, float chan, string samp, float vol, float atten)
1255 {
1256     if (!sound_allowed(MSG_BROADCAST, e))
1257         return;
1258     builtin_sound(e, chan, samp, vol, atten);
1259 }
1260 #else
1261 #undef sound
1262 void sound(entity e, float chan, string samp, float vol, float atten)
1263 {
1264     if (!sound_allowed(MSG_BROADCAST, e))
1265         return;
1266     sound7(e, chan, samp, vol, atten, 0, 0);
1267 }
1268 #endif
1269
1270 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1271 {
1272     float entno, idx;
1273
1274     if (!sound_allowed(dest, e))
1275         return;
1276
1277     entno = num_for_edict(e);
1278     idx = precache_sound_index(samp);
1279
1280     float sflags;
1281     sflags = 0;
1282
1283     atten = floor(atten * 64);
1284     vol = floor(vol * 255);
1285
1286     if (vol != 255)
1287         sflags |= SND_VOLUME;
1288     if (atten != 64)
1289         sflags |= SND_ATTENUATION;
1290     if (entno >= 8192 || chan < 0 || chan > 7)
1291         sflags |= SND_LARGEENTITY;
1292     if (idx >= 256)
1293         sflags |= SND_LARGESOUND;
1294
1295     WriteByte(dest, SVC_SOUND);
1296     WriteByte(dest, sflags);
1297     if (sflags & SND_VOLUME)
1298         WriteByte(dest, vol);
1299     if (sflags & SND_ATTENUATION)
1300         WriteByte(dest, atten);
1301     if (sflags & SND_LARGEENTITY)
1302     {
1303         WriteShort(dest, entno);
1304         WriteByte(dest, chan);
1305     }
1306     else
1307     {
1308         WriteShort(dest, entno * 8 + chan);
1309     }
1310     if (sflags & SND_LARGESOUND)
1311         WriteShort(dest, idx);
1312     else
1313         WriteByte(dest, idx);
1314
1315     WriteCoord(dest, o_x);
1316     WriteCoord(dest, o_y);
1317     WriteCoord(dest, o_z);
1318 }
1319 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1320 {
1321     vector o;
1322
1323     if (!sound_allowed(dest, e))
1324         return;
1325
1326     o = e.origin + 0.5 * (e.mins + e.maxs);
1327     soundtoat(dest, e, o, chan, samp, vol, atten);
1328 }
1329 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1330 {
1331     soundtoat(((chan & 8) ? MSG_ALL : MSG_BROADCAST), e, o, chan, samp, vol, atten);
1332 }
1333 void stopsoundto(float dest, entity e, float chan)
1334 {
1335     float entno;
1336
1337     if (!sound_allowed(dest, e))
1338         return;
1339
1340     entno = num_for_edict(e);
1341
1342     if (entno >= 8192 || chan < 0 || chan > 7)
1343     {
1344         float idx, sflags;
1345         idx = precache_sound_index("misc/null.wav");
1346         sflags = SND_LARGEENTITY;
1347         if (idx >= 256)
1348             sflags |= SND_LARGESOUND;
1349         WriteByte(dest, SVC_SOUND);
1350         WriteByte(dest, sflags);
1351         WriteShort(dest, entno);
1352         WriteByte(dest, chan);
1353         if (sflags & SND_LARGESOUND)
1354             WriteShort(dest, idx);
1355         else
1356             WriteByte(dest, idx);
1357         WriteCoord(dest, e.origin_x);
1358         WriteCoord(dest, e.origin_y);
1359         WriteCoord(dest, e.origin_z);
1360     }
1361     else
1362     {
1363         WriteByte(dest, SVC_STOPSOUND);
1364         WriteShort(dest, entno * 8 + chan);
1365     }
1366 }
1367 void stopsound(entity e, float chan)
1368 {
1369     if (!sound_allowed(MSG_BROADCAST, e))
1370         return;
1371
1372     stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1373     stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1374 }
1375
1376 void play2(entity e, string filename)
1377 {
1378     //stuffcmd(e, strcat("play2 ", filename, "\n"));
1379     msg_entity = e;
1380     soundtoat(MSG_ONE, world, '0 0 0', CH_INFO, filename, VOL_BASE, ATTN_NONE);
1381 }
1382
1383 // use this one if you might be causing spam (e.g. from touch functions that might get called more than once per frame)
1384 .float spamtime;
1385 float spamsound(entity e, float chan, string samp, float vol, float atten)
1386 {
1387     if (!sound_allowed(MSG_BROADCAST, e))
1388         return FALSE;
1389
1390     if (time > e.spamtime)
1391     {
1392         e.spamtime = time;
1393         sound(e, chan, samp, vol, atten);
1394         return TRUE;
1395     }
1396     return FALSE;
1397 }
1398
1399 void play2team(float t, string filename)
1400 {
1401     entity head;
1402
1403     if (autocvar_bot_sound_monopoly)
1404         return;
1405
1406     FOR_EACH_REALPLAYER(head)
1407     {
1408         if (head.team == t)
1409             play2(head, filename);
1410     }
1411 }
1412
1413 void play2all(string samp)
1414 {
1415     if (autocvar_bot_sound_monopoly)
1416         return;
1417
1418     sound(world, CH_INFO, samp, VOL_BASE, ATTN_NONE);
1419 }
1420
1421 void PrecachePlayerSounds(string f);
1422 void precache_playermodel(string m)
1423 {
1424         float globhandle, i, n;
1425         string f;
1426
1427         if(substring(m, -9,5) == "_lod1")
1428                 return;
1429         if(substring(m, -9,5) == "_lod2")
1430                 return;
1431         precache_model(m);
1432         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
1433         if(fexists(f))
1434                 precache_model(f);
1435         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
1436         if(fexists(f))
1437                 precache_model(f);
1438
1439         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
1440         if (globhandle < 0)
1441                 return;
1442         n = search_getsize(globhandle);
1443         for (i = 0; i < n; ++i)
1444         {
1445                 //print(search_getfilename(globhandle, i), "\n");
1446                 f = search_getfilename(globhandle, i);
1447                 PrecachePlayerSounds(f);
1448         }
1449         search_end(globhandle);
1450 }
1451 void precache_all_playermodels(string pattern)
1452 {
1453         float globhandle, i, n;
1454         string f;
1455
1456         globhandle = search_begin(pattern, TRUE, FALSE);
1457         if (globhandle < 0)
1458                 return;
1459         n = search_getsize(globhandle);
1460         for (i = 0; i < n; ++i)
1461         {
1462                 //print(search_getfilename(globhandle, i), "\n");
1463                 f = search_getfilename(globhandle, i);
1464                 precache_playermodel(f);
1465         }
1466         search_end(globhandle);
1467 }
1468
1469 void precache()
1470 {
1471     // gamemode related things
1472     precache_model ("models/misc/chatbubble.spr");
1473     if (g_runematch)
1474     {
1475         precache_model ("models/runematch/curse.mdl");
1476         precache_model ("models/runematch/rune.mdl");
1477     }
1478
1479 #ifdef TTURRETS_ENABLED
1480     if (autocvar_g_turrets)
1481         turrets_precash();
1482 #endif
1483
1484     // Precache all player models if desired
1485     if (autocvar_sv_precacheplayermodels)
1486     {
1487         PrecachePlayerSounds("sound/player/default.sounds");
1488         precache_all_playermodels("models/player/*.zym");
1489         precache_all_playermodels("models/player/*.dpm");
1490         precache_all_playermodels("models/player/*.md3");
1491         precache_all_playermodels("models/player/*.psk");
1492         precache_all_playermodels("models/player/*.iqm");
1493     }
1494
1495     if (autocvar_sv_defaultcharacter)
1496     {
1497         string s;
1498         s = autocvar_sv_defaultplayermodel_red;
1499         if (s != "")
1500             precache_playermodel(s);
1501         s = autocvar_sv_defaultplayermodel_blue;
1502         if (s != "")
1503             precache_playermodel(s);
1504         s = autocvar_sv_defaultplayermodel_yellow;
1505         if (s != "")
1506             precache_playermodel(s);
1507         s = autocvar_sv_defaultplayermodel_pink;
1508         if (s != "")
1509             precache_playermodel(s);
1510         s = autocvar_sv_defaultplayermodel;
1511         if (s != "")
1512             precache_playermodel(s);
1513     }
1514
1515     if (g_footsteps)
1516     {
1517         PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1518         PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1519     }
1520
1521     // gore and miscellaneous sounds
1522     //precache_sound ("misc/h2ohit.wav");
1523     precache_model ("models/hook.md3");
1524     precache_sound ("misc/armorimpact.wav");
1525     precache_sound ("misc/bodyimpact1.wav");
1526     precache_sound ("misc/bodyimpact2.wav");
1527     precache_sound ("misc/gib.wav");
1528     precache_sound ("misc/gib_splat01.wav");
1529     precache_sound ("misc/gib_splat02.wav");
1530     precache_sound ("misc/gib_splat03.wav");
1531     precache_sound ("misc/gib_splat04.wav");
1532     PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1533     PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1534     precache_sound ("misc/null.wav");
1535     precache_sound ("misc/spawn.wav");
1536     precache_sound ("misc/talk.wav");
1537     precache_sound ("misc/teleport.wav");
1538     precache_sound ("misc/poweroff.wav");
1539     precache_sound ("player/lava.wav");
1540     precache_sound ("player/slime.wav");
1541
1542     if (g_jetpack)
1543         precache_sound ("misc/jetpack_fly.wav");
1544
1545     precache_model ("models/sprites/0.spr32");
1546     precache_model ("models/sprites/1.spr32");
1547     precache_model ("models/sprites/2.spr32");
1548     precache_model ("models/sprites/3.spr32");
1549     precache_model ("models/sprites/4.spr32");
1550     precache_model ("models/sprites/5.spr32");
1551     precache_model ("models/sprites/6.spr32");
1552     precache_model ("models/sprites/7.spr32");
1553     precache_model ("models/sprites/8.spr32");
1554     precache_model ("models/sprites/9.spr32");
1555     precache_model ("models/sprites/10.spr32");
1556
1557     // common weapon precaches
1558         precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound here
1559     precache_sound ("weapons/weapon_switch.wav");
1560     precache_sound ("weapons/weaponpickup.wav");
1561     precache_sound ("weapons/unavailable.wav");
1562     precache_sound ("weapons/dryfire.wav");
1563     if (g_grappling_hook)
1564     {
1565         precache_sound ("weapons/hook_fire.wav"); // hook
1566         precache_sound ("weapons/hook_impact.wav"); // hook
1567     }
1568
1569     if(autocvar_sv_precacheweapons)
1570     {
1571         //precache weapon models/sounds
1572         float wep;
1573         wep = WEP_FIRST;
1574         while (wep <= WEP_LAST)
1575         {
1576             weapon_action(wep, WR_PRECACHE);
1577             wep = wep + 1;
1578         }
1579     }
1580
1581     precache_model("models/elaser.mdl");
1582     precache_model("models/laser.mdl");
1583     precache_model("models/ebomb.mdl");
1584
1585 #if 0
1586     // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1587
1588     if (!self.noise && self.music) // quake 3 uses the music field
1589         self.noise = self.music;
1590
1591     // plays music for the level if there is any
1592     if (self.noise)
1593     {
1594         precache_sound (self.noise);
1595         ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1596     }
1597 #endif
1598 }
1599
1600 // sorry, but using \ in macros breaks line numbers
1601 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1602 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1603 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1604
1605
1606 void Send_CSQC_Centerprint_Generic(entity e, float id, string s, float duration, float countdown_num)
1607 {
1608         if ((clienttype(e) == CLIENTTYPE_REAL) && (e.flags & FL_CLIENT))
1609         {
1610                 msg_entity = e;
1611                 WRITESPECTATABLE_MSG_ONE({
1612                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1613                         WriteByte(MSG_ONE, TE_CSQC_CENTERPRINT_GENERIC);
1614                         WriteByte(MSG_ONE, id);
1615                         WriteString(MSG_ONE, s);
1616                         if (id != 0 && s != "")
1617                         {
1618                                 WriteByte(MSG_ONE, duration);
1619                                 WriteByte(MSG_ONE, countdown_num);
1620                         }
1621                 });
1622         }
1623 }
1624 void Send_CSQC_Centerprint_Generic_Expire(entity e, float id)
1625 {
1626         Send_CSQC_Centerprint_Generic(e, id, "", 1, 0);
1627 }
1628 // WARNING: this kills the trace globals
1629 #define EXACTTRIGGER_TOUCH if(WarpZoneLib_ExactTrigger_Touch()) return
1630 #define EXACTTRIGGER_INIT  WarpZoneLib_ExactTrigger_Init()
1631
1632 #define INITPRIO_FIRST              0
1633 #define INITPRIO_GAMETYPE           0
1634 #define INITPRIO_GAMETYPE_FALLBACK  1
1635 #define INITPRIO_FINDTARGET        10
1636 #define INITPRIO_DROPTOFLOOR       20
1637 #define INITPRIO_SETLOCATION       90
1638 #define INITPRIO_LINKDOORS         91
1639 #define INITPRIO_LAST              99
1640
1641 .void(void) initialize_entity;
1642 .float initialize_entity_order;
1643 .entity initialize_entity_next;
1644 entity initialize_entity_first;
1645
1646 void make_safe_for_remove(entity e)
1647 {
1648     if (e.initialize_entity)
1649     {
1650         entity ent, prev;
1651         for (ent = initialize_entity_first; ent; )
1652         {
1653             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1654             {
1655                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1656                 // skip it in linked list
1657                 if (prev)
1658                 {
1659                     prev.initialize_entity_next = ent.initialize_entity_next;
1660                     ent = prev.initialize_entity_next;
1661                 }
1662                 else
1663                 {
1664                     initialize_entity_first = ent.initialize_entity_next;
1665                     ent = initialize_entity_first;
1666                 }
1667             }
1668             else
1669             {
1670                 prev = ent;
1671                 ent = ent.initialize_entity_next;
1672             }
1673         }
1674     }
1675 }
1676
1677 void objerror(string s)
1678 {
1679     make_safe_for_remove(self);
1680     builtin_objerror(s);
1681 }
1682
1683 .float remove_except_protected_forbidden;
1684 void remove_except_protected(entity e)
1685 {
1686         if(e.remove_except_protected_forbidden)
1687                 error("not allowed to remove this at this point");
1688         builtin_remove(e);
1689 }
1690
1691 void remove_unsafely(entity e)
1692 {
1693     if(e.classname == "spike")
1694         error("Removing spikes is forbidden (crylink bug), please report");
1695     builtin_remove(e);
1696 }
1697
1698 void remove_safely(entity e)
1699 {
1700     make_safe_for_remove(e);
1701     builtin_remove(e);
1702 }
1703
1704 void InitializeEntity(entity e, void(void) func, float order)
1705 {
1706     entity prev, cur;
1707
1708     if (!e || e.initialize_entity)
1709     {
1710         // make a proxy initializer entity
1711         entity e_old;
1712         e_old = e;
1713         e = spawn();
1714         e.classname = "initialize_entity";
1715         e.enemy = e_old;
1716     }
1717
1718     e.initialize_entity = func;
1719     e.initialize_entity_order = order;
1720
1721     cur = initialize_entity_first;
1722     for (;;)
1723     {
1724         if (!cur || cur.initialize_entity_order > order)
1725         {
1726             // insert between prev and cur
1727             if (prev)
1728                 prev.initialize_entity_next = e;
1729             else
1730                 initialize_entity_first = e;
1731             e.initialize_entity_next = cur;
1732             return;
1733         }
1734         prev = cur;
1735         cur = cur.initialize_entity_next;
1736     }
1737 }
1738 void InitializeEntitiesRun()
1739 {
1740     entity startoflist;
1741     startoflist = initialize_entity_first;
1742     initialize_entity_first = world;
1743     remove = remove_except_protected;
1744     for (self = startoflist; self; self = self.initialize_entity_next)
1745     {
1746         self.remove_except_protected_forbidden = 1;
1747     }
1748     for (self = startoflist; self; )
1749     {
1750         entity e;
1751         var void(void) func;
1752         e = self.initialize_entity_next;
1753         func = self.initialize_entity;
1754         self.initialize_entity_order = 0;
1755         self.initialize_entity = func_null;
1756         self.initialize_entity_next = world;
1757         self.remove_except_protected_forbidden = 0;
1758         if (self.classname == "initialize_entity")
1759         {
1760             entity e_old;
1761             e_old = self.enemy;
1762             builtin_remove(self);
1763             self = e_old;
1764         }
1765         //dprint("Delayed initialization: ", self.classname, "\n");
1766         if(func != func_null)
1767             func();
1768         else
1769         {
1770             eprint(self);
1771             backtrace(strcat("Null function in: ", self.classname, "\n"));
1772         }
1773         self = e;
1774     }
1775     remove = remove_unsafely;
1776 }
1777
1778 .float uncustomizeentityforclient_set;
1779 .void(void) uncustomizeentityforclient;
1780 void(void) SUB_Nullpointer = #0;
1781 void UncustomizeEntitiesRun()
1782 {
1783     entity oldself;
1784     oldself = self;
1785     for (self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1786         self.uncustomizeentityforclient();
1787     self = oldself;
1788 }
1789 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1790 {
1791     e.customizeentityforclient = customizer;
1792     e.uncustomizeentityforclient = uncustomizer;
1793     e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1794 }
1795
1796 .float nottargeted;
1797 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1798
1799 void() SUB_Remove;
1800 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1801 {
1802     vector mi, ma;
1803
1804     if (e.classname == "")
1805         e.classname = "net_linked";
1806
1807     if (e.model == "" || self.modelindex == 0)
1808     {
1809         mi = e.mins;
1810         ma = e.maxs;
1811         setmodel(e, "null");
1812         setsize(e, mi, ma);
1813     }
1814
1815     e.SendEntity = sendfunc;
1816     e.SendFlags = 0xFFFFFF;
1817
1818     if (!docull)
1819         e.effects |= EF_NODEPTHTEST;
1820
1821     if (dt)
1822     {
1823         e.nextthink = time + dt;
1824         e.think = SUB_Remove;
1825     }
1826 }
1827
1828 void adaptor_think2touch()
1829 {
1830     entity o;
1831     o = other;
1832     other = world;
1833     self.touch();
1834     other = o;
1835 }
1836
1837 void adaptor_think2use()
1838 {
1839     entity o, a;
1840     o = other;
1841     a = activator;
1842     activator = world;
1843     other = world;
1844     self.use();
1845     other = o;
1846     activator = a;
1847 }
1848
1849 void adaptor_think2use_hittype_splash() // for timed projectile detonation
1850 {
1851         if not(self.flags & FL_ONGROUND) // if onground, we ARE touching something, but HITTYPE_SPLASH is to be networked if the damage causing projectile is not touching ANYTHING
1852                 self.projectiledeathtype |= HITTYPE_SPLASH;
1853         adaptor_think2use();
1854 }
1855
1856 // deferred dropping
1857 void DropToFloor_Handler()
1858 {
1859     builtin_droptofloor();
1860     self.dropped_origin = self.origin;
1861 }
1862
1863 void droptofloor()
1864 {
1865     InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1866 }
1867
1868
1869
1870 float trace_hits_box_a0, trace_hits_box_a1;
1871
1872 float trace_hits_box_1d(float end, float thmi, float thma)
1873 {
1874     if (end == 0)
1875     {
1876         // just check if x is in range
1877         if (0 < thmi)
1878             return FALSE;
1879         if (0 > thma)
1880             return FALSE;
1881     }
1882     else
1883     {
1884         // do the trace with respect to x
1885         // 0 -> end has to stay in thmi -> thma
1886         trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1887         trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1888         if (trace_hits_box_a0 > trace_hits_box_a1)
1889             return FALSE;
1890     }
1891     return TRUE;
1892 }
1893
1894 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1895 {
1896     end -= start;
1897     thmi -= start;
1898     thma -= start;
1899     // now it is a trace from 0 to end
1900
1901     trace_hits_box_a0 = 0;
1902     trace_hits_box_a1 = 1;
1903
1904     if (!trace_hits_box_1d(end_x, thmi_x, thma_x))
1905         return FALSE;
1906     if (!trace_hits_box_1d(end_y, thmi_y, thma_y))
1907         return FALSE;
1908     if (!trace_hits_box_1d(end_z, thmi_z, thma_z))
1909         return FALSE;
1910
1911     return TRUE;
1912 }
1913
1914 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1915 {
1916     return trace_hits_box(start, end, thmi - ma, thma - mi);
1917 }
1918
1919 float SUB_NoImpactCheck()
1920 {
1921         // zero hitcontents = this is not the real impact, but either the
1922         // mirror-impact of something hitting the projectile instead of the
1923         // projectile hitting the something, or a touchareagrid one. Neither of
1924         // these stop the projectile from moving, so...
1925         if(trace_dphitcontents == 0)
1926         {
1927                 //dprint("A hit happened with zero hit contents... DEBUG THIS, this should never happen for projectiles! Projectile will self-destruct.\n");
1928                 dprint(sprintf(_("A hit from a projectile happened with no hit contents! DEBUG THIS, this should never happen for projectiles! Profectile will self-destruct. (edict: %d, classname: %s, origin: %s)\n"), num_for_edict(self), self.classname, vtos(self.origin)));
1929                 checkclient();
1930         }
1931     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1932         return 1;
1933     if (other == world && self.size != '0 0 0')
1934     {
1935         vector tic;
1936         tic = self.velocity * sys_frametime;
1937         tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1938         traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1939         if (trace_fraction >= 1)
1940         {
1941             dprint("Odd... did not hit...?\n");
1942         }
1943         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1944         {
1945             dprint("Detected and prevented the sky-grapple bug.\n");
1946             return 1;
1947         }
1948     }
1949
1950     return 0;
1951 }
1952
1953 #define SUB_OwnerCheck() (other && (other == self.owner))
1954
1955 void RemoveGrapplingHook(entity pl);
1956 void W_Crylink_Dequeue(entity e);
1957 float WarpZone_Projectile_Touch_ImpactFilter_Callback()
1958 {
1959         if(SUB_OwnerCheck())
1960                 return TRUE;
1961         if(SUB_NoImpactCheck())
1962         {
1963                 if(self.classname == "grapplinghook")
1964                         RemoveGrapplingHook(self.realowner);
1965                 else if(self.classname == "spike")
1966                 {
1967                         W_Crylink_Dequeue(self);
1968                         remove(self);
1969                 }
1970                 else
1971                         remove(self);
1972                 return TRUE;
1973         }
1974         if(trace_ent && trace_ent.solid > SOLID_TRIGGER)
1975                 UpdateCSQCProjectile(self);
1976         return FALSE;
1977 }
1978 #define PROJECTILE_TOUCH if(WarpZone_Projectile_Touch()) return
1979
1980 float MAX_IPBAN_URIS           = 16;
1981
1982 float URI_GET_DISCARD          = 0;
1983 float URI_GET_IPBAN            = 1;
1984 float URI_GET_IPBAN_END        = 16;
1985
1986 void URI_Get_Callback(float id, float status, string data)
1987 {
1988     dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is:\n");
1989     dprint(data);
1990     dprint("\nEnd of data.\n");
1991
1992     if(url_URI_Get_Callback(id, status, data))
1993     {
1994         // handled
1995     }
1996     else if (id == URI_GET_DISCARD)
1997     {
1998         // discard
1999     }
2000     else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
2001     {
2002         // online ban list
2003         OnlineBanList_URI_Get_Callback(id, status, data);
2004     }
2005     else
2006     {
2007         print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
2008     }
2009 }
2010
2011 string uid2name(string myuid) {
2012         string s;
2013         s = db_get(ServerProgsDB, strcat("/uid2name/", myuid));
2014
2015         // FIXME remove this later after 0.6 release
2016         // convert old style broken records to correct style
2017         if(s == "")
2018         {
2019                 s = db_get(ServerProgsDB, strcat("uid2name", myuid));
2020                 if(s != "")
2021                 {
2022                         db_put(ServerProgsDB, strcat("/uid2name/", myuid), s);
2023                         db_put(ServerProgsDB, strcat("uid2name", myuid), "");
2024                 }
2025         }
2026
2027         if(s == "")
2028                 s = "^1Unregistered Player";
2029         return s;
2030 }
2031
2032 float race_readTime(string map, float pos)
2033 {
2034         string rr;
2035         if(g_cts)
2036                 rr = CTS_RECORD;
2037         else
2038                 rr = RACE_RECORD;
2039
2040         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
2041 }
2042
2043 string race_readUID(string map, float pos)
2044 {
2045         string rr;
2046         if(g_cts)
2047                 rr = CTS_RECORD;
2048         else
2049                 rr = RACE_RECORD;
2050
2051         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
2052 }
2053
2054 float race_readPos(string map, float t) {
2055         float i;
2056         for (i = 1; i <= RANKINGS_CNT; ++i)
2057                 if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
2058                         return i;
2059
2060         return 0; // pos is zero if unranked
2061 }
2062
2063 void race_writeTime(string map, float t, string myuid)
2064 {
2065         string rr;
2066         if(g_cts)
2067                 rr = CTS_RECORD;
2068         else
2069                 rr = RACE_RECORD;
2070
2071         float newpos;
2072         newpos = race_readPos(map, t);
2073
2074         float i, prevpos;
2075         for(i = 1; i <= RANKINGS_CNT; ++i)
2076         {
2077                 if(race_readUID(map, i) == myuid)
2078                         prevpos = i;
2079         }
2080         if (prevpos) { // player improved his existing record, only have to iterate on ranks between new and old recs
2081                 for (i = prevpos; i > newpos; --i) {
2082                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2083                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2084                 }
2085         } else { // player has no ranked record yet
2086                 for (i = RANKINGS_CNT; i > newpos; --i) {
2087                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
2088                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
2089                 }
2090         }
2091
2092         // store new time itself
2093         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
2094         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
2095 }
2096
2097 string race_readName(string map, float pos)
2098 {
2099         string rr;
2100         if(g_cts)
2101                 rr = CTS_RECORD;
2102         else
2103                 rr = RACE_RECORD;
2104
2105         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
2106 }
2107
2108 string race_placeName(float pos) {
2109         if(floor((mod(pos, 100))/10) * 10 != 10) // examples: 12th, 111th, 213th will not execute this block
2110         {
2111                 if(mod(pos, 10) == 1)
2112                         return strcat(ftos(pos), "st");
2113                 else if(mod(pos, 10) == 2)
2114                         return strcat(ftos(pos), "nd");
2115                 else if(mod(pos, 10) == 3)
2116                         return strcat(ftos(pos), "rd");
2117                 else
2118                         return strcat(ftos(pos), "th");
2119         }
2120         else
2121                 return strcat(ftos(pos), "th");
2122 }
2123
2124 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
2125 {
2126     float m, i;
2127     vector start, org, delta, end, enddown, mstart;
2128     entity sp;
2129
2130     m = e.dphitcontentsmask;
2131     e.dphitcontentsmask = goodcontents | badcontents;
2132
2133     org = world.mins;
2134     delta = world.maxs - world.mins;
2135
2136     for (i = 0; i < attempts; ++i)
2137     {
2138         start_x = org_x + random() * delta_x;
2139         start_y = org_y + random() * delta_y;
2140         start_z = org_z + random() * delta_z;
2141
2142         // rule 1: start inside world bounds, and outside
2143         // solid, and don't start from somewhere where you can
2144         // fall down to evil
2145         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
2146         if (trace_fraction >= 1)
2147             continue;
2148         if (trace_startsolid)
2149             continue;
2150         if (trace_dphitcontents & badcontents)
2151             continue;
2152         if (trace_dphitq3surfaceflags & badsurfaceflags)
2153             continue;
2154
2155         // rule 2: if we are too high, lower the point
2156         if (trace_fraction * delta_z > maxaboveground)
2157             start = trace_endpos + '0 0 1' * maxaboveground;
2158         enddown = trace_endpos;
2159
2160         // rule 3: make sure we aren't outside the map. This only works
2161         // for somewhat well formed maps. A good rule of thumb is that
2162         // the map should have a convex outside hull.
2163         // these can be traceLINES as we already verified the starting box
2164         mstart = start + 0.5 * (e.mins + e.maxs);
2165         traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
2166         if (trace_fraction >= 1)
2167             continue;
2168         traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
2169         if (trace_fraction >= 1)
2170             continue;
2171         traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
2172         if (trace_fraction >= 1)
2173             continue;
2174         traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
2175         if (trace_fraction >= 1)
2176             continue;
2177         traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
2178         if (trace_fraction >= 1)
2179             continue;
2180
2181         // rule 4: we must "see" some spawnpoint
2182         for(sp = world; (sp = find(sp, classname, "info_player_deathmatch")); )
2183                 if(checkpvs(mstart, sp))
2184                         break;
2185         if(!sp)
2186         {
2187                 for(sp = world; (sp = findflags(sp, flags, FL_ITEM)); )
2188                         if(checkpvs(mstart, sp))
2189                                 break;
2190                 if(!sp)
2191                         continue;
2192         }
2193
2194         // find a random vector to "look at"
2195         end_x = org_x + random() * delta_x;
2196         end_y = org_y + random() * delta_y;
2197         end_z = org_z + random() * delta_z;
2198         end = start + normalize(end - start) * vlen(delta);
2199
2200         // rule 4: start TO end must not be too short
2201         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
2202         if (trace_startsolid)
2203             continue;
2204         if (trace_fraction < minviewdistance / vlen(delta))
2205             continue;
2206
2207         // rule 5: don't want to look at sky
2208         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
2209             continue;
2210
2211         // rule 6: we must not end up in trigger_hurt
2212         if (tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
2213             continue;
2214
2215         break;
2216     }
2217
2218     e.dphitcontentsmask = m;
2219
2220     if (i < attempts)
2221     {
2222         setorigin(e, start);
2223         e.angles = vectoangles(end - start);
2224         dprint("Needed ", ftos(i + 1), " attempts\n");
2225         return TRUE;
2226     }
2227     else
2228         return FALSE;
2229 }
2230
2231 float zcurveparticles_effectno;
2232 vector zcurveparticles_start;
2233 float zcurveparticles_spd;
2234
2235 void endzcurveparticles()
2236 {
2237         if(zcurveparticles_effectno)
2238         {
2239                 // terminator
2240                 WriteShort(MSG_BROADCAST, zcurveparticles_spd | 0x8000);
2241         }
2242         zcurveparticles_effectno = 0;
2243 }
2244
2245 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
2246 {
2247         spd = bound(0, floor(spd / 16), 32767);
2248         if(effectno != zcurveparticles_effectno || start != zcurveparticles_start)
2249         {
2250                 endzcurveparticles();
2251                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2252                 WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2253                 WriteShort(MSG_BROADCAST, effectno);
2254                 WriteCoord(MSG_BROADCAST, start_x);
2255                 WriteCoord(MSG_BROADCAST, start_y);
2256                 WriteCoord(MSG_BROADCAST, start_z);
2257                 zcurveparticles_effectno = effectno;
2258                 zcurveparticles_start = start;
2259         }
2260         else
2261                 WriteShort(MSG_BROADCAST, zcurveparticles_spd);
2262         WriteCoord(MSG_BROADCAST, end_x);
2263         WriteCoord(MSG_BROADCAST, end_y);
2264         WriteCoord(MSG_BROADCAST, end_z);
2265         WriteCoord(MSG_BROADCAST, end_dz);
2266         zcurveparticles_spd = spd;
2267 }
2268
2269 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2270 {
2271         float end_dz;
2272         vector vecxy, velxy;
2273
2274         vecxy = end - start;
2275         vecxy_z = 0;
2276         velxy = vel;
2277         velxy_z = 0;
2278
2279         if (vlen(velxy) < 0.000001 * fabs(vel_z))
2280         {
2281                 endzcurveparticles();
2282                 trailparticles(world, effectno, start, end);
2283                 return;
2284         }
2285
2286         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2287         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2288 }
2289
2290 void write_recordmarker(entity pl, float tstart, float dt)
2291 {
2292     GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt)));
2293
2294     // also write a marker into demo files for demotc-race-record-extractor to find
2295     stuffcmd(pl,
2296              strcat(
2297                  strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", TIME_ENCODED_TOSTRING(TIME_ENCODE(dt))),
2298                  " ", ftos(tstart), " ", ftos(dt), "\n"));
2299 }
2300
2301 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float allowcenter, float algn)
2302 {
2303         switch(algn)
2304         {
2305                 default:
2306                 case 3: // right
2307                         break;
2308
2309                 case 4: // left
2310                         vecs_y = -vecs_y;
2311                         break;
2312
2313                 case 1:
2314                         if(allowcenter) // 2: allow center handedness
2315                         {
2316                                 // center
2317                                 vecs_y = 0;
2318                                 vecs_z -= 2;
2319                         }
2320                         else
2321                         {
2322                                 // right
2323                         }
2324                         break;
2325
2326                 case 2:
2327                         if(allowcenter) // 2: allow center handedness
2328                         {
2329                                 // center
2330                                 vecs_y = 0;
2331                                 vecs_z -= 2;
2332                         }
2333                         else
2334                         {
2335                                 // left
2336                                 vecs_y = -vecs_y;
2337                         }
2338                         break;
2339         }
2340         return vecs;
2341 }
2342
2343 vector shotorg_adjust_values(vector vecs, float y_is_right, float visual, float algn)
2344 {
2345         string s;
2346         vector v;
2347
2348         if (autocvar_g_shootfromeye)
2349         {
2350                 if (visual)
2351                 {
2352                         vecs_y = 0;
2353                         vecs_z -= 2;
2354                 }
2355                 else
2356                 {
2357                         vecs_y = 0;
2358                         vecs_z = 0;
2359                 }
2360         }
2361         else if (autocvar_g_shootfromcenter)
2362         {
2363                 vecs_y = 0;
2364                 vecs_z -= 2;
2365         }
2366         else if ((s = autocvar_g_shootfromfixedorigin) != "")
2367         {
2368                 v = stov(s);
2369                 if (y_is_right)
2370                         v_y = -v_y;
2371                 if (v_x != 0)
2372                         vecs_x = v_x;
2373                 vecs_y = v_y;
2374                 vecs_z = v_z;
2375         }
2376         else if (autocvar_g_shootfromclient)
2377         {
2378                 vecs = shotorg_adjustfromclient(vecs, y_is_right, (autocvar_g_shootfromclient >= 2), algn);
2379         }
2380         return vecs;
2381 }
2382
2383 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2384 {
2385         return shotorg_adjust_values(vecs, y_is_right, visual, self.owner.cvar_cl_gunalign);
2386 }
2387
2388
2389 void attach_sameorigin(entity e, entity to, string tag)
2390 {
2391     vector org, t_forward, t_left, t_up, e_forward, e_up;
2392     vector org0, ang0;
2393     float tagscale;
2394
2395     ang0 = e.angles;
2396     org0 = e.origin;
2397
2398     org = e.origin - gettaginfo(to, gettagindex(to, tag));
2399     tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2400     t_forward = v_forward * tagscale;
2401     t_left = v_right * -tagscale;
2402     t_up = v_up * tagscale;
2403
2404     e.origin_x = org * t_forward;
2405     e.origin_y = org * t_left;
2406     e.origin_z = org * t_up;
2407
2408     // current forward and up directions
2409     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2410                 e.angles = AnglesTransform_FromVAngles(e.angles);
2411         else
2412                 e.angles = AnglesTransform_FromAngles(e.angles);
2413     fixedmakevectors(e.angles);
2414
2415     // untransform forward, up!
2416     e_forward_x = v_forward * t_forward;
2417     e_forward_y = v_forward * t_left;
2418     e_forward_z = v_forward * t_up;
2419     e_up_x = v_up * t_forward;
2420     e_up_y = v_up * t_left;
2421     e_up_z = v_up * t_up;
2422
2423     e.angles = fixedvectoangles2(e_forward, e_up);
2424     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2425                 e.angles = AnglesTransform_ToVAngles(e.angles);
2426         else
2427                 e.angles = AnglesTransform_ToAngles(e.angles);
2428
2429     setattachment(e, to, tag);
2430     setorigin(e, e.origin);
2431 }
2432
2433 void detach_sameorigin(entity e)
2434 {
2435     vector org;
2436     org = gettaginfo(e, 0);
2437     e.angles = fixedvectoangles2(v_forward, v_up);
2438     if (substring(e.model, 0, 1) == "*") // bmodels have their own rules
2439                 e.angles = AnglesTransform_ToVAngles(e.angles);
2440         else
2441                 e.angles = AnglesTransform_ToAngles(e.angles);
2442     setorigin(e, org);
2443     setattachment(e, world, "");
2444     setorigin(e, e.origin);
2445 }
2446
2447 void follow_sameorigin(entity e, entity to)
2448 {
2449     e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2450     e.aiment = to; // make the hole follow bmodel
2451     e.punchangle = to.angles; // the original angles of bmodel
2452     e.view_ofs = e.origin - to.origin; // relative origin
2453     e.v_angle = e.angles - to.angles; // relative angles
2454 }
2455
2456 void unfollow_sameorigin(entity e)
2457 {
2458     e.movetype = MOVETYPE_NONE;
2459 }
2460
2461 entity gettaginfo_relative_ent;
2462 vector gettaginfo_relative(entity e, float tag)
2463 {
2464     if (!gettaginfo_relative_ent)
2465     {
2466         gettaginfo_relative_ent = spawn();
2467         gettaginfo_relative_ent.effects = EF_NODRAW;
2468     }
2469     gettaginfo_relative_ent.model = e.model;
2470     gettaginfo_relative_ent.modelindex = e.modelindex;
2471     gettaginfo_relative_ent.frame = e.frame;
2472     return gettaginfo(gettaginfo_relative_ent, tag);
2473 }
2474
2475 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2476 {
2477     float p;
2478     p = pow(2, chan);
2479     if (pl.soundentity.cnt & p)
2480         return;
2481     soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2482     pl.soundentity.cnt |= p;
2483 }
2484
2485 void SoundEntity_StopSound(entity pl, float chan)
2486 {
2487     float p;
2488     p = pow(2, chan);
2489     if (pl.soundentity.cnt & p)
2490     {
2491         stopsoundto(MSG_ALL, pl.soundentity, chan);
2492         pl.soundentity.cnt &~= p;
2493     }
2494 }
2495
2496 void SoundEntity_Attach(entity pl)
2497 {
2498     pl.soundentity = spawn();
2499     pl.soundentity.classname = "soundentity";
2500     pl.soundentity.owner = pl;
2501     setattachment(pl.soundentity, pl, "");
2502     setmodel(pl.soundentity, "null");
2503 }
2504
2505 void SoundEntity_Detach(entity pl)
2506 {
2507     float i;
2508     for (i = 0; i <= 7; ++i)
2509         SoundEntity_StopSound(pl, i);
2510 }
2511
2512 .float scale2;
2513
2514 float modeleffect_SendEntity(entity to, float sf)
2515 {
2516         float f;
2517         WriteByte(MSG_ENTITY, ENT_CLIENT_MODELEFFECT);
2518
2519         f = 0;
2520         if(self.velocity != '0 0 0')
2521                 f |= 1;
2522         if(self.angles != '0 0 0')
2523                 f |= 2;
2524         if(self.avelocity != '0 0 0')
2525                 f |= 4;
2526
2527         WriteByte(MSG_ENTITY, f);
2528         WriteShort(MSG_ENTITY, self.modelindex);
2529         WriteByte(MSG_ENTITY, self.skin);
2530         WriteByte(MSG_ENTITY, self.frame);
2531         WriteCoord(MSG_ENTITY, self.origin_x);
2532         WriteCoord(MSG_ENTITY, self.origin_y);
2533         WriteCoord(MSG_ENTITY, self.origin_z);
2534         if(f & 1)
2535         {
2536                 WriteCoord(MSG_ENTITY, self.velocity_x);
2537                 WriteCoord(MSG_ENTITY, self.velocity_y);
2538                 WriteCoord(MSG_ENTITY, self.velocity_z);
2539         }
2540         if(f & 2)
2541         {
2542                 WriteCoord(MSG_ENTITY, self.angles_x);
2543                 WriteCoord(MSG_ENTITY, self.angles_y);
2544                 WriteCoord(MSG_ENTITY, self.angles_z);
2545         }
2546         if(f & 4)
2547         {
2548                 WriteCoord(MSG_ENTITY, self.avelocity_x);
2549                 WriteCoord(MSG_ENTITY, self.avelocity_y);
2550                 WriteCoord(MSG_ENTITY, self.avelocity_z);
2551         }
2552         WriteShort(MSG_ENTITY, self.scale * 256.0);
2553         WriteShort(MSG_ENTITY, self.scale2 * 256.0);
2554         WriteByte(MSG_ENTITY, self.teleport_time * 100.0);
2555         WriteByte(MSG_ENTITY, self.fade_time * 100.0);
2556         WriteByte(MSG_ENTITY, self.alpha * 255.0);
2557
2558         return TRUE;
2559 }
2560
2561 void modeleffect_spawn(string m, float s, float f, vector o, vector v, vector ang, vector angv, float s0, float s2, float a, float t1, float t2)
2562 {
2563         entity e;
2564         float sz;
2565         e = spawn();
2566         e.classname = "modeleffect";
2567         setmodel(e, m);
2568         e.frame = f;
2569         setorigin(e, o);
2570         e.velocity = v;
2571         e.angles = ang;
2572         e.avelocity = angv;
2573         e.alpha = a;
2574         e.teleport_time = t1;
2575         e.fade_time = t2;
2576         e.skin = s;
2577         if(s0 >= 0)
2578                 e.scale = s0 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2579         else
2580                 e.scale = -s0;
2581         if(s2 >= 0)
2582                 e.scale2 = s2 / max6(-e.mins_x, -e.mins_y, -e.mins_z, e.maxs_x, e.maxs_y, e.maxs_z);
2583         else
2584                 e.scale2 = -s2;
2585         sz = max(e.scale, e.scale2);
2586         setsize(e, e.mins * sz, e.maxs * sz);
2587         Net_LinkEntity(e, FALSE, 0.1, modeleffect_SendEntity);
2588 }
2589
2590 void shockwave_spawn(string m, vector org, float sz, float t1, float t2)
2591 {
2592         return modeleffect_spawn(m, 0, 0, org, '0 0 0', '0 0 0', '0 0 0', 0, sz, 1, t1, t2);
2593 }
2594
2595 float randombit(float bits)
2596 {
2597         if not(bits & (bits-1)) // this ONLY holds for powers of two!
2598                 return bits;
2599
2600         float n, f, b, r;
2601
2602         r = random();
2603         b = 0;
2604         n = 0;
2605
2606         for(f = 1; f <= bits; f *= 2)
2607         {
2608                 if(bits & f)
2609                 {
2610                         ++n;
2611                         r *= n;
2612                         if(r <= 1)
2613                                 b = f;
2614                         else
2615                                 r = (r - 1) / (n - 1);
2616                 }
2617         }
2618
2619         return b;
2620 }
2621
2622 float randombits(float bits, float k, float error_return)
2623 {
2624         float r;
2625         r = 0;
2626         while(k > 0 && bits != r)
2627         {
2628                 r += randombit(bits - r);
2629                 --k;
2630         }
2631         if(error_return)
2632                 if(k > 0)
2633                         return -1; // all
2634         return r;
2635 }
2636
2637 void randombit_test(float bits, float iter)
2638 {
2639         while(iter > 0)
2640         {
2641                 print(ftos(randombit(bits)), "\n");
2642                 --iter;
2643         }
2644 }
2645
2646 float ExponentialFalloff(float mindist, float maxdist, float halflifedist, float d)
2647 {
2648         if(halflifedist > 0)
2649                 return pow(0.5, (bound(mindist, d, maxdist) - mindist) / halflifedist);
2650         else if(halflifedist < 0)
2651                 return pow(0.5, (bound(mindist, d, maxdist) - maxdist) / halflifedist);
2652         else
2653                 return 1;
2654 }
2655
2656
2657
2658
2659 #ifdef RELEASE
2660 #define cvar_string_normal builtin_cvar_string
2661 #define cvar_normal builtin_cvar
2662 #else
2663 string cvar_string_normal(string n)
2664 {
2665         if not(cvar_type(n) & 1)
2666                 backtrace(strcat("Attempt to access undefined cvar: ", n));
2667         return builtin_cvar_string(n);
2668 }
2669
2670 float cvar_normal(string n)
2671 {
2672         return stof(cvar_string_normal(n));
2673 }
2674 #endif
2675 #define cvar_set_normal builtin_cvar_set
2676
2677 void defer_think()
2678 {
2679     entity oself;
2680
2681     oself           = self;
2682     self            = self.owner;
2683     oself.think     = SUB_Remove;
2684     oself.nextthink = time;
2685
2686     oself.use();
2687 }
2688
2689 /*
2690     Execute func() after time + fdelay.
2691     self when func is executed = self when defer is called
2692 */
2693 void defer(float fdelay, void() func)
2694 {
2695     entity e;
2696
2697     e           = spawn();
2698     e.owner     = self;
2699     e.use       = func;
2700     e.think     = defer_think;
2701     e.nextthink = time + fdelay;
2702 }
2703
2704 .string aiment_classname;
2705 .float aiment_deadflag;
2706 void SetMovetypeFollow(entity ent, entity e)
2707 {
2708         // FIXME this may not be warpzone aware
2709         ent.movetype = MOVETYPE_FOLLOW; // make the hole follow
2710         ent.solid = SOLID_NOT; // MOVETYPE_FOLLOW is always non-solid - this means this cannot be teleported by warpzones any more! Instead, we must notice when our owner gets teleported.
2711         ent.aiment = e; // make the hole follow bmodel
2712         ent.punchangle = e.angles; // the original angles of bmodel
2713         ent.view_ofs = ent.origin - e.origin; // relative origin
2714         ent.v_angle = ent.angles - e.angles; // relative angles
2715         ent.aiment_classname = strzone(e.classname);
2716         ent.aiment_deadflag = e.deadflag;
2717 }
2718 void UnsetMovetypeFollow(entity ent)
2719 {
2720         ent.movetype = MOVETYPE_FLY;
2721         PROJECTILE_MAKETRIGGER(ent);
2722         ent.aiment = world;
2723 }
2724 float LostMovetypeFollow(entity ent)
2725 {
2726 /*
2727         if(ent.movetype != MOVETYPE_FOLLOW)
2728                 if(ent.aiment)
2729                         error("???");
2730 */
2731         if(ent.aiment)
2732         {
2733                 if(ent.aiment.classname != ent.aiment_classname)
2734                         return 1;
2735                 if(ent.aiment.deadflag != ent.aiment_deadflag)
2736                         return 1;
2737         }
2738         return 0;
2739 }
2740
2741 float isPushable(entity e)
2742 {
2743         if(e.iscreature)
2744                 return TRUE;
2745         switch(e.classname)
2746         {
2747                 case "body":
2748                 case "droppedweapon":
2749                 case "keepawayball":
2750                 case "nexball_basketball":
2751                 case "nexball_football":
2752                         return TRUE;
2753                 case "bullet": // antilagged bullets can't hit this either
2754                         return FALSE;
2755         }
2756         if (e.projectiledeathtype)
2757                 return TRUE;
2758         return FALSE;
2759 }