qcsrc/server/main.qc

   1 #include "main.qh"
   2
   3 #include <common/command/generic.qh>
   4 #include <common/constants.qh>
   5 #include <common/deathtypes/all.qh>
   6 #include <common/debug.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/mapobjects/_mod.qh>
   9 #include <common/monsters/sv_monsters.qh>
  10 #include <common/util.qh>
  11 #include <common/vehicles/all.qh>
  12 #include <common/weapons/_all.qh>
  13 #include <lib/csqcmodel/sv_model.qh>
  14 #include <lib/warpzone/common.qh>
  15 #include <lib/warpzone/server.qh>
  16 #include <server/anticheat.qh>
  17 #include <server/bot/api.qh>
  18 #include <server/command/common.qh>
  19 #include <server/compat/quake3.qh>
  20 #include <server/damage.qh>
  21 #include <server/gamelog.qh>
  22 #include <server/hook.qh>
  23 #include <server/ipban.qh>
  24 #include <server/mutators/_mod.qh>
  25 #include <server/spawnpoints.qh>
  26 #include <server/weapons/common.qh>
  27 #include <server/weapons/csqcprojectile.qh>
  28 #include <server/world.qh>
  29
  30 void dropclient_do(entity this)
  31 {
  32         if (this.owner)
  33                 dropclient(this.owner);
  34         delete(this);
  35 }
  36
  37 /**
  38  * Schedules dropclient for a player and returns true;
  39  * if dropclient is already scheduled (for that player) it does nothing and returns false.
  40  *
  41  * NOTE: this function exists only to allow sending a message to the kicked player with
  42  * Send_Notification, which doesn't work if called together with dropclient
  43  */
  44 bool dropclient_schedule(entity this)
  45 {
  46         bool scheduled = false;
  47         FOREACH_ENTITY_CLASS("dropclient_handler", true,
  48         {
  49                 if(it.owner == this)
  50                 {
  51                         scheduled = true;
  52                         break; // can't use return here, compiler shows a warning
  53                 }
  54         });
  55         if (scheduled)
  56                 return false;
  57
  58         entity e = new_pure(dropclient_handler);
  59         setthink(e, dropclient_do);
  60         e.owner = this;
  61         e.nextthink = time + 0.1;
  62         return true;
  63 }
  64
  65 void CreatureFrame_hotliquids(entity this)
  66 {
  67         if (this.contents_damagetime >= time)
  68         {
  69                 return;
  70         }
  71
  72         this.contents_damagetime = time + autocvar_g_balance_contents_damagerate;
  73
  74         if (this.flags & FL_PROJECTILE)
  75         {
  76                 if (this.watertype == CONTENT_LAVA)
  77                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  78                 else if (this.watertype == CONTENT_SLIME)
  79                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  80         }
  81         else
  82         {
  83                 if (STAT(FROZEN, this))
  84                 {
  85                         if (this.watertype == CONTENT_LAVA)
  86                                 Damage(this, NULL, NULL, 10000, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  87                         else if (this.watertype == CONTENT_SLIME)
  88                                 Damage(this, NULL, NULL, 10000, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  89                 }
  90                 else if (this.watertype == CONTENT_LAVA)
  91                 {
  92                         if (this.watersound_finished < time)
  93                         {
  94                                 this.watersound_finished = time + 0.5;
  95                                 sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  96                         }
  97                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  98                         if(autocvar_g_balance_contents_playerdamage_lava_burn)
  99                                 Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
 100                 }
 101                 else if (this.watertype == CONTENT_SLIME)
 102                 {
 103                         if (this.watersound_finished < time)
 104                         {
 105                                 this.watersound_finished = time + 0.5;
 106                                 sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
 107                         }
 108                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
 109                 }
 110         }
 111 }
 112
 113 void CreatureFrame_Liquids(entity this)
 114 {
 115         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
 116         {
 117                 if (!(this.flags & FL_INWATER))
 118                 {
 119                         this.flags |= FL_INWATER;
 120                         this.contents_damagetime = 0;
 121                 }
 122
 123                 CreatureFrame_hotliquids(this);
 124         }
 125         else
 126         {
 127                 if (this.flags & FL_INWATER)
 128                 {
 129                         // play leave water sound
 130                         this.flags &= ~FL_INWATER;
 131                         this.contents_damagetime = 0;
 132                 }
 133         }
 134 }
 135
 136 void CreatureFrame_FallDamage(entity this)
 137 {
 138         if(IS_VEHICLE(this) || (this.flags & FL_PROJECTILE))
 139                 return; // vehicles and projectiles don't receive fall damage
 140         if(!(this.velocity || this.oldvelocity))
 141                 return; // if the entity hasn't moved and isn't moving, then don't do anything
 142
 143         // check for falling damage
 144         bool have_hook = false;
 145         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 146         {
 147                 .entity weaponentity = weaponentities[slot];
 148                 if(this.(weaponentity).hook && this.(weaponentity).hook.state)
 149                 {
 150                         have_hook = true;
 151                         break;
 152                 }
 153         }
 154         if(!have_hook)
 155         {
 156                 float dm; // dm is the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 157                 if(autocvar_g_balance_falldamage_onlyvertical)
 158                         dm = fabs(this.oldvelocity.z) - vlen(this.velocity);
 159                 else
 160                         dm = vlen(this.oldvelocity) - vlen(this.velocity);
 161                 if (IS_DEAD(this))
 162                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 163                 else
 164                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 165                 if (dm > 0)
 166                 {
 167                         tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 168                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODAMAGE))
 169                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 170                 }
 171         }
 172
 173         if(autocvar_g_maxspeed > 0 && vdist(this.velocity, >, autocvar_g_maxspeed))
 174                 Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, DMG_NOWEP, this.origin, '0 0 0');
 175 }
 176
 177 void CreatureFrame_All()
 178 {
 179         if(game_stopped || time < game_starttime)
 180                 return;
 181
 182         IL_EACH(g_damagedbycontents, it.damagedbycontents,
 183         {
 184                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 185                 CreatureFrame_Liquids(it);
 186                 CreatureFrame_FallDamage(it);
 187                 it.oldvelocity = it.velocity;
 188         });
 189 }
 190
 191 // called shortly after map change in dedicated
 192 void Pause_TryPause_Dedicated(entity this)
 193 {
 194         if (player_count == 0 && !intermission_running && !autocvar__endmatch)
 195                 setpause(1);
 196 }
 197
 198 // called every normal frame in singleplayer/listen
 199 void Pause_TryPause()
 200 {
 201         int n = 0, p = 0;
 202         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 203                 if (PHYS_INPUT_BUTTON_CHAT(it)) ++p;
 204                 ++n;
 205         });
 206         if (!n) return;
 207         if (n == p)
 208                 setpause(1);
 209         else
 210                 setpause(0);
 211 }
 212
 213 // called every paused frame by DP
 214 void SV_PausedTic(float elapsedtime)
 215 {
 216         if (autocvar__endmatch) // `endmatch` while paused
 217                 setpause(0); // proceed to intermission
 218         else if (!server_is_dedicated)
 219         {
 220                 if (autocvar_sv_autopause)
 221                         Pause_TryPause();
 222                 else
 223                         setpause(0);
 224         }
 225 }
 226
 227 void dedicated_print(string input)
 228 {
 229         if (server_is_dedicated) print(input);
 230 }
 231
 232 void make_safe_for_remove(entity e)
 233 {
 234         if (e.initialize_entity)
 235         {
 236                 entity ent, prev = NULL;
 237                 for (ent = initialize_entity_first; ent; )
 238                 {
 239                         if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 240                         {
 241                                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 242                                 // skip it in linked list
 243                                 if (prev)
 244                                 {
 245                                         prev.initialize_entity_next = ent.initialize_entity_next;
 246                                         ent = prev.initialize_entity_next;
 247                                 }
 248                                 else
 249                                 {
 250                                         initialize_entity_first = ent.initialize_entity_next;
 251                                         ent = initialize_entity_first;
 252                                 }
 253                         }
 254                         else
 255                         {
 256                                 prev = ent;
 257                                 ent = ent.initialize_entity_next;
 258                         }
 259                 }
 260         }
 261 }
 262
 263 void remove_except_protected(entity e)
 264 {
 265         if(e.remove_except_protected_forbidden)
 266                 error("not allowed to remove this at this point");
 267         builtin_remove(e);
 268 }
 269
 270 void remove_unsafely(entity e)
 271 {
 272         if(e.classname == "spike")
 273                 error("Removing spikes is forbidden (crylink bug), please report");
 274         builtin_remove(e);
 275 }
 276
 277 void remove_safely(entity e)
 278 {
 279         make_safe_for_remove(e);
 280         builtin_remove(e);
 281 }
 282
 283 /*
 284 =============
 285 StartFrame
 286
 287 Called before each frame by the server
 288 =============
 289 */
 290
 291 bool game_delay_last;
 292
 293 void systems_update();
 294 void sys_phys_update(entity this, float dt);
 295 void StartFrame()
 296 {
 297         // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 298         IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 299         IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 300
 301         execute_next_frame();
 302
 303         delete_fn = remove_unsafely; // not during spawning!
 304         serverprevtime = servertime;
 305         servertime = time;
 306         serverframetime = frametime;
 307
 308 #ifdef PROFILING
 309         if(time > client_cefc_accumulatortime + 1)
 310         {
 311                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 312                 int c_seeing = 0;
 313                 int c_seen = 0;
 314                 FOREACH_CLIENT(true, {
 315                         if(IS_REAL_CLIENT(it))
 316                                 ++c_seeing;
 317                         if(IS_PLAYER(it))
 318                                 ++c_seen;
 319                 });
 320                 LOG_INFO(
 321                         "CEFC time: ", ftos(t * 1000), "ms; ",
 322                         "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
 323                         "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
 324                 );
 325                 client_cefc_accumulatortime = time;
 326                 client_cefc_accumulator = 0;
 327         }
 328 #endif
 329
 330         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
 331
 332         if (RedirectionThink()) return;
 333
 334         UncustomizeEntitiesRun();
 335         InitializeEntitiesRun();
 336
 337         WarpZone_StartFrame();
 338
 339         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 340         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 341
 342         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 343                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 344
 345         // detect when the pre-game countdown (if any) has ended and the game has started
 346         bool game_delay = (time < game_starttime);
 347         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 348                 GameLogEcho(":startdelay_ended");
 349         game_delay_last = game_delay;
 350
 351         CreatureFrame_All();
 352         CheckRules_World();
 353
 354         // after CheckRules_World() as it may set intermission_running, and after RedirectionThink() in case listen server is closing
 355         if (autocvar_sv_autopause && !server_is_dedicated && !intermission_running)
 356                 Pause_TryPause();
 357
 358         if (warmup_stage && !game_stopped && warmup_limit > 0 && time - game_starttime >= warmup_limit) {
 359                 ReadyRestart(true);
 360                 return;
 361         }
 362
 363         bot_serverframe();
 364         anticheat_startframe();
 365         MUTATOR_CALLHOOK(SV_StartFrame);
 366
 367         GlobalStats_updateglobal();
 368         FOREACH_CLIENT(true, GlobalStats_update(it));
 369         IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 370 }
 371
 372 .vector originjitter;
 373 .vector anglesjitter;
 374 .float anglejitter;
 375 .string gametypefilter;
 376 .string cvarfilter;
 377
 378 void SV_OnEntityPreSpawnFunction(entity this)
 379 {
 380         if (this)
 381         if (this.gametypefilter != "")
 382         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 383         {
 384                 delete(this);
 385                 return;
 386         }
 387         if (this.cvarfilter != "" && !expr_evaluate(this.cvarfilter)) {
 388                 delete(this);
 389                 return;
 390         }
 391
 392         if (q3compat && DoesQ3ARemoveThisEntity(this)) {
 393                 delete(this);
 394                 return;
 395         }
 396
 397         set_movetype(this, this.movetype);
 398
 399         if (this.monster_attack) {
 400                 IL_PUSH(g_monster_targets, this);
 401         }
 402
 403         // support special -1 and -2 angle from radiant
 404         if (this.angles == '0 -1 0') {
 405                 this.angles = '-90 0 0';
 406         } else if (this.angles == '0 -2 0') {
 407                 this.angles = '+90 0 0';
 408         }
 409
 410         #define X(out, in) MACRO_BEGIN \
 411                 if (in != 0) { out = out + (random() * 2 - 1) * in; } \
 412         MACRO_END
 413         X(this.origin.x, this.originjitter.x); X(this.origin.y, this.originjitter.y); X(this.origin.z, this.originjitter.z);
 414         X(this.angles.x, this.anglesjitter.x); X(this.angles.y, this.anglesjitter.y); X(this.angles.z, this.anglesjitter.z);
 415         X(this.angles.y, this.anglejitter);
 416         #undef X
 417
 418         if (MUTATOR_CALLHOOK(OnEntityPreSpawn, this)) {
 419                 delete(this);
 420                 return;
 421         }
 422 }
 423
 424 string GetField_fullspawndata(entity e, string f, ...)
 425 /* Retrieves the value of a map entity field from fullspawndata
 426  * This bypasses field value changes made by the engine,
 427  * eg string-to-float and escape sequence substitution.
 428  *
 429  * Avoids the need to declare fields just to read them once :)
 430  *
 431  * Returns the last instance of the field to match DarkPlaces behaviour.
 432  * Path support: converts \ to / and tests the file if a third (bool, true) arg is passed.
 433  * Returns string_null if the entity does not have the field, or the file is not in the VFS.
 434  *
 435  * FIXME: entities with //comments are not supported.
 436  */
 437 {
 438         string v = string_null;
 439
 440         if (!e.fullspawndata)
 441         {
 442                 //LOG_WARNF("^1EDICT %s (classname %s) has no fullspawndata, engine lacks support?", ftos(num_for_edict(e)), e.classname);
 443                 return v;
 444         }
 445
 446         if (strstrofs(e.fullspawndata, "//", 0) >= 0)
 447         {
 448                 // tokenize and tokenize_console return early if "//" is reached,
 449                 // which can leave an odd number of tokens and break key:value pairing.
 450                 LOG_WARNF("^1EDICT %s fullspawndata contains unsupported //comment^7%s", ftos(num_for_edict(e)), e.fullspawndata);
 451                 return v;
 452         }
 453
 454         //print(sprintf("%s(EDICT %s, FIELD %s)\n", __FUNC__, ftos(num_for_edict(e)), f));
 455         //print(strcat("FULLSPAWNDATA:", e.fullspawndata, "\n"));
 456
 457         // tokenize treats \ as an escape, but tokenize_console returns the required literal
 458         for (int t = tokenize_console(e.fullspawndata) - 3; t > 0; t -= 2)
 459         {
 460                 //print(sprintf("\tTOKEN %s:%s\t%s:%s\n", ftos(t), ftos(t + 1), argv(t), argv(t + 1)));
 461                 if (argv(t) == f)
 462                 {
 463                         v = argv(t + 1);
 464                         break;
 465                 }
 466         }
 467
 468         //print(strcat("RESULT: ", v, "\n\n"));
 469
 470         if (v && ...(0, bool) == true)
 471         {
 472                 v = strreplace("\\", "/", v);
 473                 if (whichpack(v) == "")
 474                         return string_null;
 475         }
 476
 477         return v;
 478 }
 479
 480 /*
 481 =============
 482 FindFileInMapPack
 483
 484 Returns the first matching VFS file path that exists in the current map's pack.
 485 Returns string_null if no files match or the map isn't packaged.
 486 =============
 487 */
 488 string FindFileInMapPack(string pattern)
 489 {
 490         if (!checkextension("DP_QC_FS_SEARCH_PACKFILE"))
 491                 return string_null;
 492
 493         string base_pack = whichpack(strcat("maps/", mapname, ".bsp"));
 494         if (base_pack == "" || !base_pack) // this map isn't packaged or there was an error
 495                 return string_null;
 496
 497         int glob = search_packfile_begin(pattern, true, true, base_pack);
 498         if (glob < 0)
 499                 return string_null;
 500
 501         string file = search_getfilename(glob, 0);
 502         search_end(glob);
 503         return file;
 504 }
 505
 506 void WarpZone_PostInitialize_Callback()
 507 {
 508         // create waypoint links for warpzones
 509         entity tracetest_ent = spawn();
 510         setsize(tracetest_ent, PL_MIN_CONST, PL_MAX_CONST);
 511         tracetest_ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 512         //for(entity e = warpzone_first; e; e = e.warpzone_next)
 513         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 514                 waypoint_spawnforteleporter_wz(e, tracetest_ent);
 515         delete(tracetest_ent);
 516 }
 517
 518 /** engine callback */
 519 void URI_Get_Callback(float id, float status, string data)
 520 {
 521         if(url_URI_Get_Callback(id, status, data))
 522         {
 523                 // handled
 524         }
 525         else if (id == URI_GET_DISCARD)
 526         {
 527                 // discard
 528         }
 529         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 530         {
 531                 // sv_cmd curl
 532                 Curl_URI_Get_Callback(id, status, data);
 533         }
 534         else if (id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
 535         {
 536                 // online ban list
 537                 OnlineBanList_URI_Get_Callback(id, status, data);
 538         }
 539         else if (MUTATOR_CALLHOOK(URI_GetCallback, id, status, data))
 540         {
 541                 // handled by a mutator
 542         }
 543         else
 544         {
 545                 LOG_INFO("Received HTTP request data for an invalid id ", ftos(id), ".");
 546         }
 547 }
 548
 549 /*
 550 ==================
 551 main
 552
 553 unused but required by the engine
 554 ==================
 555 */
 556 void main ()
 557 {
 558
 559 }