qcsrc/server/main.qc

   1 #include "main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "hook.qh"
   5 #include "damage.qh"
   6 #include "world.qh"
   7 #include "spawnpoints.qh"
   8 #include <server/gamelog.qh>
   9
  10 #include "bot/api.qh"
  11
  12 #include "command/common.qh"
  13
  14 #include <server/mutators/_mod.qh>
  15 #include "weapons/csqcprojectile.qh"
  16 #include <server/weapons/common.qh>
  17 #include <server/compat/quake3.qh>
  18
  19 #include "../common/constants.qh"
  20 #include "../common/deathtypes/all.qh"
  21 #include "../common/debug.qh"
  22 #include "../common/mapinfo.qh"
  23 #include "../common/util.qh"
  24
  25 #include "../common/vehicles/all.qh"
  26 #include <common/monsters/sv_monsters.qh>
  27 #include <common/weapons/_all.qh>
  28
  29 #include "../lib/csqcmodel/sv_model.qh"
  30
  31 #include "../lib/warpzone/common.qh"
  32 #include "../lib/warpzone/server.qh"
  33
  34 void CreatureFrame_hotliquids(entity this)
  35 {
  36         if (this.contents_damagetime >= time)
  37         {
  38                 return;
  39         }
  40
  41         this.contents_damagetime = time + autocvar_g_balance_contents_damagerate;
  42
  43         if (this.flags & FL_PROJECTILE)
  44         {
  45                 if (this.watertype == CONTENT_LAVA)
  46                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  47                 else if (this.watertype == CONTENT_SLIME)
  48                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  49         }
  50         else
  51         {
  52                 if (STAT(FROZEN, this))
  53                 {
  54                         if (this.watertype == CONTENT_LAVA)
  55                                 Damage(this, NULL, NULL, 10000, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  56                         else if (this.watertype == CONTENT_SLIME)
  57                                 Damage(this, NULL, NULL, 10000, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  58                 }
  59                 else if (this.watertype == CONTENT_LAVA)
  60                 {
  61                         if (this.watersound_finished < time)
  62                         {
  63                                 this.watersound_finished = time + 0.5;
  64                                 sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  65                         }
  66                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  67                         if(autocvar_g_balance_contents_playerdamage_lava_burn)
  68                                 Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  69                 }
  70                 else if (this.watertype == CONTENT_SLIME)
  71                 {
  72                         if (this.watersound_finished < time)
  73                         {
  74                                 this.watersound_finished = time + 0.5;
  75                                 sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  76                         }
  77                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  78                 }
  79         }
  80 }
  81
  82 void CreatureFrame_Liquids(entity this)
  83 {
  84         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  85         {
  86                 if (!(this.flags & FL_INWATER))
  87                 {
  88                         this.flags |= FL_INWATER;
  89                         this.contents_damagetime = 0;
  90                 }
  91
  92                 CreatureFrame_hotliquids(this);
  93         }
  94         else
  95         {
  96                 if (this.flags & FL_INWATER)
  97                 {
  98                         // play leave water sound
  99                         this.flags &= ~FL_INWATER;
 100                         this.contents_damagetime = 0;
 101                 }
 102         }
 103 }
 104
 105 void CreatureFrame_FallDamage(entity this)
 106 {
 107         if(IS_VEHICLE(this) || (this.flags & FL_PROJECTILE))
 108                 return; // vehicles and projectiles don't receive fall damage
 109         if(!(this.velocity || this.oldvelocity))
 110                 return; // if the entity hasn't moved and isn't moving, then don't do anything
 111
 112         // check for falling damage
 113         bool have_hook = false;
 114         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 115         {
 116             .entity weaponentity = weaponentities[slot];
 117             if(this.(weaponentity).hook && this.(weaponentity).hook.state)
 118             {
 119                 have_hook = true;
 120                 break;
 121             }
 122         }
 123         if(!have_hook)
 124         {
 125                 float dm; // dm is the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 126                 if(autocvar_g_balance_falldamage_onlyvertical)
 127                         dm = fabs(this.oldvelocity.z) - vlen(this.velocity);
 128                 else
 129                         dm = vlen(this.oldvelocity) - vlen(this.velocity);
 130                 if (IS_DEAD(this))
 131                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 132                 else
 133                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 134                 if (dm > 0)
 135                 {
 136                         tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 137                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODAMAGE))
 138                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 139                 }
 140         }
 141
 142         if(autocvar_g_maxspeed > 0 && vdist(this.velocity, >, autocvar_g_maxspeed))
 143                 Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, DMG_NOWEP, this.origin, '0 0 0');
 144 }
 145
 146 void CreatureFrame_All()
 147 {
 148         if(game_stopped || time < game_starttime)
 149                 return;
 150
 151         IL_EACH(g_damagedbycontents, it.damagedbycontents,
 152         {
 153                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 154                 CreatureFrame_Liquids(it);
 155                 CreatureFrame_FallDamage(it);
 156                 it.oldvelocity = it.velocity;
 157         });
 158 }
 159
 160 void Pause_TryPause(bool ispaused)
 161 {
 162         int n = 0;
 163         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 164                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 165                 ++n;
 166         });
 167         if (!n) return;
 168         setpause(ispaused);
 169 }
 170
 171 void SV_PausedTic(float elapsedtime)
 172 {
 173         if (!server_is_dedicated) Pause_TryPause(false);
 174 }
 175
 176 void dedicated_print(string input)
 177 {
 178         if (server_is_dedicated) print(input);
 179 }
 180
 181 void make_safe_for_remove(entity e)
 182 {
 183     if (e.initialize_entity)
 184     {
 185         entity ent, prev = NULL;
 186         for (ent = initialize_entity_first; ent; )
 187         {
 188             if ((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
 189             {
 190                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
 191                 // skip it in linked list
 192                 if (prev)
 193                 {
 194                     prev.initialize_entity_next = ent.initialize_entity_next;
 195                     ent = prev.initialize_entity_next;
 196                 }
 197                 else
 198                 {
 199                     initialize_entity_first = ent.initialize_entity_next;
 200                     ent = initialize_entity_first;
 201                 }
 202             }
 203             else
 204             {
 205                 prev = ent;
 206                 ent = ent.initialize_entity_next;
 207             }
 208         }
 209     }
 210 }
 211
 212 .float remove_except_protected_forbidden;
 213 void remove_except_protected(entity e)
 214 {
 215         if(e.remove_except_protected_forbidden)
 216                 error("not allowed to remove this at this point");
 217         builtin_remove(e);
 218 }
 219
 220 void remove_unsafely(entity e)
 221 {
 222     if(e.classname == "spike")
 223         error("Removing spikes is forbidden (crylink bug), please report");
 224     builtin_remove(e);
 225 }
 226
 227 void remove_safely(entity e)
 228 {
 229     make_safe_for_remove(e);
 230     builtin_remove(e);
 231 }
 232
 233 /*
 234 =============
 235 StartFrame
 236
 237 Called before each frame by the server
 238 =============
 239 */
 240
 241 bool game_delay_last;
 242
 243 bool autocvar_sv_autopause = false;
 244 void systems_update();
 245 void sys_phys_update(entity this, float dt);
 246 void StartFrame()
 247 {
 248     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 249     IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 250     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 251
 252         execute_next_frame();
 253         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 254
 255         delete_fn = remove_unsafely; // not during spawning!
 256         serverprevtime = servertime;
 257         servertime = time;
 258         serverframetime = frametime;
 259
 260 #ifdef PROFILING
 261         if(time > client_cefc_accumulatortime + 1)
 262         {
 263                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 264                 int c_seeing = 0;
 265                 int c_seen = 0;
 266                 FOREACH_CLIENT(true, {
 267                         if(IS_REAL_CLIENT(it))
 268                                 ++c_seeing;
 269                         if(IS_PLAYER(it))
 270                                 ++c_seen;
 271                 });
 272                 LOG_INFO(
 273                     "CEFC time: ", ftos(t * 1000), "ms; ",
 274             "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
 275             "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
 276         );
 277                 client_cefc_accumulatortime = time;
 278                 client_cefc_accumulator = 0;
 279         }
 280 #endif
 281
 282         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
 283
 284         if (RedirectionThink()) return;
 285
 286         UncustomizeEntitiesRun();
 287         InitializeEntitiesRun();
 288
 289         WarpZone_StartFrame();
 290
 291         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 292         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 293
 294         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 295                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 296
 297         // detect when the pre-game countdown (if any) has ended and the game has started
 298         bool game_delay = (time < game_starttime);
 299         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 300                 GameLogEcho(":startdelay_ended");
 301         game_delay_last = game_delay;
 302
 303         CreatureFrame_All();
 304         CheckRules_World();
 305
 306         if (warmup_stage && !game_stopped && warmup_limit > 0 && time >= warmup_limit) {
 307                 ReadyRestart();
 308                 return;
 309         }
 310
 311         bot_serverframe();
 312         anticheat_startframe();
 313         MUTATOR_CALLHOOK(SV_StartFrame);
 314
 315         GlobalStats_updateglobal();
 316     FOREACH_CLIENT(true, GlobalStats_update(it));
 317     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 318 }
 319
 320 .vector originjitter;
 321 .vector anglesjitter;
 322 .float anglejitter;
 323 .string gametypefilter;
 324 .string cvarfilter;
 325
 326 void SV_OnEntityPreSpawnFunction(entity this)
 327 {
 328         if (this)
 329         if (this.gametypefilter != "")
 330         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 331         {
 332                 delete(this);
 333                 return;
 334         }
 335         if (this.cvarfilter != "" && !expr_evaluate(this.cvarfilter)) {
 336                 delete(this);
 337                 return;
 338         }
 339
 340         if (DoesQ3ARemoveThisEntity(this)) {
 341                 delete(this);
 342                 return;
 343         }
 344
 345         set_movetype(this, this.movetype);
 346
 347         if (this.monster_attack) {
 348                 IL_PUSH(g_monster_targets, this);
 349     }
 350
 351         // support special -1 and -2 angle from radiant
 352         if (this.angles == '0 -1 0') {
 353                 this.angles = '-90 0 0';
 354         } else if (this.angles == '0 -2 0') {
 355                 this.angles = '+90 0 0';
 356     }
 357
 358     #define X(out, in) MACRO_BEGIN \
 359         if (in != 0) { out = out + (random() * 2 - 1) * in; } \
 360     MACRO_END
 361     X(this.origin.x, this.originjitter.x); X(this.origin.y, this.originjitter.y); X(this.origin.z, this.originjitter.z);
 362     X(this.angles.x, this.anglesjitter.x); X(this.angles.y, this.anglesjitter.y); X(this.angles.z, this.anglesjitter.z);
 363     X(this.angles.y, this.anglejitter);
 364     #undef X
 365
 366         if (MUTATOR_CALLHOOK(OnEntityPreSpawn, this)) {
 367                 delete(this);
 368                 return;
 369         }
 370 }
 371
 372 void WarpZone_PostInitialize_Callback()
 373 {
 374         // create waypoint links for warpzones
 375         entity tracetest_ent = spawn();
 376         setsize(tracetest_ent, PL_MIN_CONST, PL_MAX_CONST);
 377         tracetest_ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 378         //for(entity e = warpzone_first; e; e = e.warpzone_next)
 379         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 380                 waypoint_spawnforteleporter_wz(e, tracetest_ent);
 381         delete(tracetest_ent);
 382 }
 383
 384 /*
 385 ==================
 386 main
 387
 388 unused but required by the engine
 389 ==================
 390 */
 391 void main ()
 392 {
 393
 394 }