qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ca_teams");
 260                 BADCVAR("g_ctf");
 261                 BADCVAR("g_cts");
 262                 BADCVAR("g_dm");
 263                 BADCVAR("g_domination");
 264                 BADCVAR("g_domination_default_teams");
 265                 BADCVAR("g_freezetag");
 266                 BADCVAR("g_freezetag_teams");
 267                 BADCVAR("g_keepaway");
 268                 BADCVAR("g_keyhunt");
 269                 BADCVAR("g_keyhunt_teams");
 270                 BADCVAR("g_lms");
 271                 BADCVAR("g_nexball");
 272                 BADCVAR("g_onslaught");
 273                 BADCVAR("g_race");
 274                 BADCVAR("g_race_qualifying_timelimit");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("leadlimit_and_fraglimit");
 319                 BADCVAR("leadlimit_override");
 320                 BADCVAR("pausable");
 321                 BADCVAR("sv_allow_fullbright");
 322                 BADCVAR("sv_checkforpacketsduringsleep");
 323                 BADCVAR("sv_fraginfo");
 324                 BADCVAR("sv_timeout");
 325                 BADPREFIX("sv_timeout_");
 326                 BADPREFIX("crypto_");
 327                 BADPREFIX("g_chat_");
 328                 BADPREFIX("g_ctf_captimerecord_");
 329                 BADPREFIX("g_maplist_votable_");
 330                 BADPREFIX("net_");
 331                 BADPREFIX("prvm_");
 332                 BADPREFIX("skill_");
 333                 BADPREFIX("sv_cullentities_");
 334                 BADPREFIX("sv_fraginfo_");
 335                 BADPREFIX("sv_maxidle_");
 336                 BADPREFIX("sv_vote_");
 337                 BADPREFIX("timelimit_");
 338                 BADCVAR("gameversion");
 339                 BADPREFIX("gameversion_");
 340                 BADCVAR("sv_namechangetimer");
 341
 342                 // allowed changes to server admins (please sync this to server.cfg)
 343                 // vi commands:
 344                 //   :/"impure"/,$d
 345                 //   :g!,^\/\/[^ /],d
 346                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 347                 //   :%!sort
 348                 // yes, this does contain some redundant stuff, don't really care
 349                 BADCVAR("bot_config_file");
 350                 BADCVAR("bot_number");
 351                 BADCVAR("bot_prefix");
 352                 BADCVAR("bot_suffix");
 353                 BADCVAR("capturelimit_override");
 354                 BADCVAR("fraglimit_override");
 355                 BADCVAR("gametype");
 356                 BADCVAR("g_antilag");
 357                 BADCVAR("g_balance_teams");
 358                 BADCVAR("g_balance_teams_prevent_imbalance");
 359                 BADCVAR("g_balance_teams_scorefactor");
 360                 BADCVAR("g_ban_sync_trusted_servers");
 361                 BADCVAR("g_ban_sync_uri");
 362                 BADCVAR("g_ca_teams_override");
 363                 BADCVAR("g_ctf_ignore_frags");
 364                 BADCVAR("g_domination_point_limit");
 365                 BADCVAR("g_freezetag_teams_override");
 366                 BADCVAR("g_friendlyfire");
 367                 BADCVAR("g_fullbrightitems");
 368                 BADCVAR("g_fullbrightplayers");
 369                 BADCVAR("g_keyhunt_point_limit");
 370                 BADCVAR("g_keyhunt_teams_override");
 371                 BADCVAR("g_lms_lives_override");
 372                 BADCVAR("g_maplist");
 373                 BADCVAR("g_maplist_check_waypoints");
 374                 BADCVAR("g_maplist_mostrecent_count");
 375                 BADCVAR("g_maplist_shuffle");
 376                 BADCVAR("g_maplist_votable");
 377                 BADCVAR("g_maplist_votable_abstain");
 378                 BADCVAR("g_maplist_votable_nodetail");
 379                 BADCVAR("g_maplist_votable_suggestions");
 380                 BADCVAR("g_maxplayers");
 381                 BADCVAR("g_mirrordamage");
 382                 BADCVAR("g_nexball_goallimit");
 383                 BADCVAR("g_powerups");
 384                 BADCVAR("g_start_delay");
 385                 BADCVAR("g_warmup");
 386                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 387                 BADCVAR("hostname");
 388                 BADCVAR("log_file");
 389                 BADCVAR("maxplayers");
 390                 BADCVAR("minplayers");
 391                 BADCVAR("net_address");
 392                 BADCVAR("port");
 393                 BADCVAR("rcon_password");
 394                 BADCVAR("rcon_restricted_commands");
 395                 BADCVAR("rcon_restricted_password");
 396                 BADCVAR("skill");
 397                 BADCVAR("sv_adminnick");
 398                 BADCVAR("sv_autoscreenshot");
 399                 BADCVAR("sv_autotaunt");
 400                 BADCVAR("sv_curl_defaulturl");
 401                 BADCVAR("sv_defaultcharacter");
 402                 BADCVAR("sv_defaultplayercolors");
 403                 BADCVAR("sv_defaultplayermodel");
 404                 BADCVAR("sv_defaultplayerskin");
 405                 BADCVAR("sv_maxidle");
 406                 BADCVAR("sv_maxrate");
 407                 BADCVAR("sv_motd");
 408                 BADCVAR("sv_public");
 409                 BADCVAR("sv_ready_restart");
 410                 BADCVAR("sv_status_privacy");
 411                 BADCVAR("sv_taunt");
 412                 BADCVAR("sv_vote_call");
 413                 BADCVAR("sv_vote_commands");
 414                 BADCVAR("sv_vote_majority_factor");
 415                 BADCVAR("sv_vote_master");
 416                 BADCVAR("sv_vote_master_commands");
 417                 BADCVAR("sv_vote_master_password");
 418                 BADCVAR("sv_vote_simple_majority_factor");
 419                 BADCVAR("teamplay_mode");
 420                 BADCVAR("timelimit_override");
 421                 BADCVAR("g_spawnshieldtime");
 422                 BADPREFIX("g_warmup_");
 423                 BADPREFIX("sv_ready_restart_");
 424
 425                 // mutators that announce themselves properly to the server browser
 426                 BADCVAR("g_minstagib");
 427                 BADCVAR("g_new_toys");
 428                 BADCVAR("g_nix");
 429                 BADCVAR("g_grappling_hook");
 430                 BADCVAR("g_jetpack");
 431
 432 #undef BADPREFIX
 433 #undef BADCVAR
 434
 435                 if(pureadding)
 436                 {
 437                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 438                         if(strlen(cvar_purechanges) > 16384)
 439                         {
 440                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 441                                 pureadding = 0;
 442                         }
 443                 }
 444                 ++cvar_purechanges_count;
 445                 // WARNING: this variable is used for the server list
 446                 // NEVER dare to skip this code!
 447                 // Hacks to intentionally appearing as "pure server" even though you DO have
 448                 // modified settings may be punished by removal from the server list.
 449                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 450                 // though.
 451         }
 452         buf_del(h);
 453         if(cvar_changes == "")
 454                 cvar_changes = "// this server runs at default server settings\n";
 455         else
 456                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 457         cvar_changes = strzone(cvar_changes);
 458         if(cvar_purechanges == "")
 459                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 460         else
 461                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 462         cvar_purechanges = strzone(cvar_purechanges);
 463 }
 464
 465 void detect_maptype()
 466 {
 467 #if 0
 468         vector o, v;
 469         float i;
 470
 471         for(;;)
 472         {
 473                 o = world.mins;
 474                 o_x += random() * (world.maxs_x - world.mins_x);
 475                 o_y += random() * (world.maxs_y - world.mins_y);
 476                 o_z += random() * (world.maxs_z - world.mins_z);
 477
 478                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 479                 if(trace_fraction == 1)
 480                         continue;
 481
 482                 v = trace_endpos;
 483
 484                 for(i = 0; i < 64; i += 4)
 485                 {
 486                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 487         if(trace_fraction == 1)
 488                 continue;
 489                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 490                 }
 491
 492                 break;
 493         }
 494 #endif
 495 }
 496
 497 entity randomseed;
 498 float RandomSeed_Send(entity to, float sf)
 499 {
 500         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 501         WriteShort(MSG_ENTITY, self.cnt);
 502         return TRUE;
 503 }
 504 void RandomSeed_Think()
 505 {
 506         self.cnt = bound(0, floor(random() * 65536), 65535);
 507         self.nextthink = time + 5;
 508
 509         self.SendFlags |= 1;
 510 }
 511 void RandomSeed_Spawn()
 512 {
 513         randomseed = spawn();
 514         randomseed.think = RandomSeed_Think;
 515         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 516
 517         entity oldself;
 518         oldself = self;
 519         self = randomseed;
 520         self.think(); // sets random seed and nextthink
 521         self = oldself;
 522 }
 523
 524 void spawnfunc___init_dedicated_server(void)
 525 {
 526         // handler for _init/_init map (only for dedicated server initialization)
 527
 528         world_initialized = -1; // don't complain
 529         cvar = cvar_normal;
 530         cvar_string = cvar_string_normal;
 531         cvar_set = cvar_set_normal;
 532
 533         remove = remove_unsafely;
 534
 535         entity e;
 536         e = spawn();
 537         e.think = GotoFirstMap;
 538         e.nextthink = time; // this is usually 1 at this point
 539
 540         e = spawn();
 541         e.classname = "info_player_deathmatch"; // safeguard against player joining
 542
 543         self.classname = "worldspawn"; // safeguard against various stuff ;)
 544
 545         // needs to be done so early because of the constants they create
 546         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 547         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 548         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 549         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 550         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 551
 552         MapInfo_Enumerate();
 553         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 554 }
 555
 556 void Map_MarkAsRecent(string m);
 557 float world_already_spawned;
 558 void Nagger_Init();
 559 void ClientInit_Spawn();
 560 void WeaponStats_Init();
 561 void WeaponStats_Shutdown();
 562 void spawnfunc_worldspawn (void)
 563 {
 564         float fd, l, i, j, n;
 565         string s;
 566
 567         cvar = cvar_normal;
 568         cvar_string = cvar_string_normal;
 569         cvar_set = cvar_set_normal;
 570
 571         if(world_already_spawned)
 572                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 573         world_already_spawned = TRUE;
 574
 575         remove = remove_safely; // during spawning, watch what you remove!
 576
 577         check_unacceptable_compiler_bugs();
 578
 579         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 580
 581         compressShortVector_init();
 582
 583         entity head;
 584         head = nextent(world);
 585         maxclients = 0;
 586         while(head)
 587         {
 588                 ++maxclients;
 589                 head = nextent(head);
 590         }
 591
 592         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 593
 594         // needs to be done so early because of the constants they create
 595         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 596         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 597         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 598         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 599         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 600
 601         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 602
 603         TemporaryDB = db_create();
 604
 605         // 0 normal
 606         lightstyle(0, "m");
 607
 608         // 1 FLICKER (first variety)
 609         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 610
 611         // 2 SLOW STRONG PULSE
 612         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 613
 614         // 3 CANDLE (first variety)
 615         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 616
 617         // 4 FAST STROBE
 618         lightstyle(4, "mamamamamama");
 619
 620         // 5 GENTLE PULSE 1
 621         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 622
 623         // 6 FLICKER (second variety)
 624         lightstyle(6, "nmonqnmomnmomomno");
 625
 626         // 7 CANDLE (second variety)
 627         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 628
 629         // 8 CANDLE (third variety)
 630         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 631
 632         // 9 SLOW STROBE (fourth variety)
 633         lightstyle(9, "aaaaaaaazzzzzzzz");
 634
 635         // 10 FLUORESCENT FLICKER
 636         lightstyle(10, "mmamammmmammamamaaamammma");
 637
 638         // 11 SLOW PULSE NOT FADE TO BLACK
 639         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 640
 641         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 642
 643         // 63 testing
 644         lightstyle(63, "a");
 645
 646         if(autocvar_g_campaign)
 647                 CampaignPreInit();
 648
 649         Map_MarkAsRecent(mapname);
 650
 651         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 652
 653         precache_model ("null"); // we need this one before InitGameplayMode
 654         InitGameplayMode();
 655         readlevelcvars();
 656         GrappleHookInit();
 657         ElectroInit();
 658         LaserInit();
 659
 660         player_count = 0;
 661         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 662         if(bot_waypoints_for_items == 1)
 663                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 664                         bot_waypoints_for_items = 0;
 665
 666         precache();
 667
 668         WaypointSprite_Init();
 669
 670         GameLogInit(); // prepare everything
 671         // NOTE for matchid:
 672         // changing the logic generating it is okay. But:
 673         // it HAS to stay <= 64 chars
 674         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 675         if(autocvar_sv_eventlog)
 676         {
 677                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 678                 matchid = strzone(s);
 679
 680                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 681                 s = ":gameinfo:mutators:LIST";
 682
 683                 ret_string = s;
 684                 MUTATOR_CALLHOOK(BuildMutatorsString);
 685                 s = ret_string;
 686
 687                 // simple, probably not good in the mutator system
 688                 if(autocvar_g_grappling_hook)
 689                         s = strcat(s, ":grappling_hook");
 690
 691                 // initialiation stuff, not good in the mutator system
 692                 if(!autocvar_g_use_ammunition)
 693                         s = strcat(s, ":no_use_ammunition");
 694
 695                 // initialiation stuff, not good in the mutator system
 696                 if(autocvar_g_pickup_items == 0)
 697                         s = strcat(s, ":no_pickup_items");
 698                 if(autocvar_g_pickup_items > 0)
 699                         s = strcat(s, ":pickup_items");
 700
 701                 // initialiation stuff, not good in the mutator system
 702                 if(autocvar_g_weaponarena != "0")
 703                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 704
 705                 // TODO to mutator system
 706                 if(autocvar_g_norecoil)
 707                         s = strcat(s, ":norecoil");
 708
 709                 // TODO to mutator system
 710                 if(autocvar_g_powerups == 0)
 711                         s = strcat(s, ":no_powerups");
 712                 if(autocvar_g_powerups > 0)
 713                         s = strcat(s, ":powerups");
 714
 715                 GameLogEcho(s);
 716                 GameLogEcho(":gameinfo:end");
 717         }
 718         else
 719                 matchid = strzone(ftos(random()));
 720
 721         cvar_set("nextmap", "");
 722
 723         SetDefaultAlpha();
 724
 725         if(autocvar_g_campaign)
 726                 CampaignPostInit();
 727
 728         fteqcc_testbugs();
 729
 730         Ban_LoadBans();
 731
 732         MapInfo_Enumerate();
 733         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 734
 735         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 736         {
 737                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 738                 if(fd != -1)
 739                 {
 740                         while((s = fgets(fd)))
 741                         {
 742                                 l = tokenize_console(s);
 743                                 if(l < 2)
 744                                         continue;
 745                                 if(argv(0) == "cd")
 746                                 {
 747                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 748                                         print("  cdtrack ", argv(2), "\n");
 749                                 }
 750                                 else if(argv(0) == "fog")
 751                                 {
 752                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 753                                         print("  \"fog\" \"", s, "\"\n");
 754                                 }
 755                                 else if(argv(0) == "set")
 756                                 {
 757                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 758                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 759                                 }
 760                                 else if(argv(0) != "//")
 761                                 {
 762                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 763                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 764                                 }
 765                         }
 766                         fclose(fd);
 767                 }
 768         }
 769
 770         WeaponStats_Init();
 771
 772         WepSet_AddStat();
 773         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 774         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 775         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 776         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 777         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 778         Nagger_Init();
 779
 780         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 781         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 782         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 783         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 784         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 785         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 786         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 787         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 788         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 789         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 790         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 791         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 792         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 793
 794         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 795         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 796
 797         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 798
 799         // freeze attacks
 800         addstat(STAT_FROZEN, AS_INT, frozen);
 801         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 802
 803         // g_movementspeed hack
 804         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 805         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 806         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 807         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 808
 809         // secrets
 810         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 811         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 812
 813         // monsters
 814         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 815         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 816
 817         // misc
 818         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 819
 820         next_pingtime = time + 5;
 821
 822         detect_maptype();
 823
 824         // set up information replies for clients and server to use
 825         maplist_reply = strzone(getmaplist());
 826         lsmaps_reply = strzone(getlsmaps());
 827         monsterlist_reply = strzone(getmonsterlist());
 828         for(i = 0; i < 10; ++i)
 829         {
 830                 s = getrecords(i);
 831                 if (s)
 832                         records_reply[i] = strzone(s);
 833         }
 834         ladder_reply = strzone(getladder());
 835         rankings_reply = strzone(getrankings());
 836
 837         // begin other init
 838         ClientInit_Spawn();
 839         RandomSeed_Spawn();
 840         PingPLReport_Spawn();
 841
 842         CheatInit();
 843
 844         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 845
 846         // fill sv_curl_serverpackages from .serverpackage files
 847         if(autocvar_sv_curl_serverpackages_auto)
 848         {
 849                 s = "";
 850                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 851                 for(i = 0; i < n; ++i)
 852                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 853                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 854                                 s = strcat(s, " ", argv(i));
 855                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 856                 if(fd >= 0)
 857                 {
 858                         j = search_getsize(fd);
 859                         for(i = 0; i < j; ++i)
 860                                 s = strcat(s, " ", search_getfilename(fd, i));
 861                         search_end(fd);
 862                 }
 863                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 864                 if(fd >= 0)
 865                 {
 866                         j = search_getsize(fd);
 867                         for(i = 0; i < j; ++i)
 868                                 s = strcat(s, " ", search_getfilename(fd, i));
 869                         search_end(fd);
 870                 }
 871                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 872         }
 873
 874         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 875         modname = "Xonotic";
 876         // physics/balance/config changes that count as mod
 877         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 878                 modname = cvar_string("g_mod_physics");
 879         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 880                 modname = cvar_string("g_mod_balance");
 881         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 882                 modname = cvar_string("g_mod_config");
 883         // extra mutators that deserve to count as mod
 884         MUTATOR_CALLHOOK(SetModname);
 885
 886         // save it for later
 887         modname = strzone(modname);
 888
 889         WinningConditionHelper(); // set worldstatus
 890
 891         world_initialized = 1;
 892 }
 893
 894 void spawnfunc_light (void)
 895 {
 896         //makestatic (self); // Who the f___ did that?
 897         remove(self);
 898 }
 899
 900 string GetGametype()
 901 {
 902         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 903 }
 904
 905 string getmapname_stored;
 906 string GetMapname()
 907 {
 908         return mapname;
 909 }
 910
 911 float Map_Count, Map_Current;
 912 string Map_Current_Name;
 913
 914 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 915 float GetMaplistPosition()
 916 {
 917         float pos, idx;
 918         string map;
 919
 920         map = GetMapname();
 921         idx = autocvar_g_maplist_index;
 922
 923         if(idx >= 0)
 924                 if(idx < Map_Count)
 925                         if(map == argv(idx))
 926                                 return idx;
 927
 928         for(pos = 0; pos < Map_Count; ++pos)
 929                 if(map == argv(pos))
 930                         return pos;
 931
 932         // resume normal maplist rotation if current map is not in g_maplist
 933         return idx;
 934 }
 935
 936 float MapHasRightSize(string map)
 937 {
 938         float fh;
 939         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 940         if(autocvar_g_maplist_check_waypoints)
 941         {
 942                 dprint("checkwp "); dprint(map);
 943                 if(!fexists(strcat("maps/", map, ".waypoints")))
 944                 {
 945                         dprint(": no waypoints\n");
 946                         return FALSE;
 947                 }
 948                 dprint(": has waypoints\n");
 949         }
 950
 951         // open map size restriction file
 952         dprint("opensize "); dprint(map);
 953         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 954         if(fh >= 0)
 955         {
 956                 float mapmin, mapmax;
 957                 dprint(": ok, ");
 958                 mapmin = stof(fgets(fh));
 959                 mapmax = stof(fgets(fh));
 960                 fclose(fh);
 961                 if(player_count < mapmin)
 962                 {
 963                         dprint("not enough\n");
 964                         return FALSE;
 965                 }
 966                 if(player_count > mapmax)
 967                 {
 968                         dprint("too many\n");
 969                         return FALSE;
 970                 }
 971                 dprint("right size\n");
 972                 return TRUE;
 973         }
 974         dprint(": not found\n");
 975         return TRUE;
 976 }
 977
 978 string Map_Filename(float position)
 979 {
 980         return strcat("maps/", argv(position), ".bsp");
 981 }
 982
 983 string strwords(string s, float w)
 984 {
 985         float endpos;
 986         for(endpos = 0; w && endpos >= 0; --w)
 987                 endpos = strstrofs(s, " ", endpos + 1);
 988         if(endpos < 0)
 989                 return s;
 990         else
 991                 return substring(s, 0, endpos);
 992 }
 993
 994 float strhasword(string s, string w)
 995 {
 996         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 997 }
 998
 999 void Map_MarkAsRecent(string m)
1000 {
1001         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1002 }
1003
1004 float Map_IsRecent(string m)
1005 {
1006         return strhasword(autocvar_g_maplist_mostrecent, m);
1007 }
1008
1009 float Map_Check(float position, float pass)
1010 {
1011         string filename;
1012         string map_next;
1013         map_next = argv(position);
1014         if(pass <= 1)
1015         {
1016                 if(Map_IsRecent(map_next))
1017                         return 0;
1018         }
1019         filename = Map_Filename(position);
1020         if(MapInfo_CheckMap(map_next))
1021         {
1022                 if(pass == 2)
1023                         return 1;
1024                 if(MapHasRightSize(map_next))
1025                         return 1;
1026                 return 0;
1027         }
1028         else
1029                 dprint( "Couldn't select '", filename, "'..\n" );
1030
1031         return 0;
1032 }
1033
1034 void Map_Goto_SetStr(string nextmapname)
1035 {
1036         if(getmapname_stored != "")
1037                 strunzone(getmapname_stored);
1038         if(nextmapname == "")
1039                 getmapname_stored = "";
1040         else
1041                 getmapname_stored = strzone(nextmapname);
1042 }
1043
1044 void Map_Goto_SetFloat(float position)
1045 {
1046         cvar_set("g_maplist_index", ftos(position));
1047         Map_Goto_SetStr(argv(position));
1048 }
1049
1050 void Map_Goto(float reinit)
1051 {
1052         MapInfo_LoadMap(getmapname_stored, reinit);
1053 }
1054
1055 // return codes of map selectors:
1056 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1057 //   -2 = permanent failure
1058 float() MaplistMethod_Iterate = // usual method
1059 {
1060         float pass, i;
1061
1062         dprint("Trying MaplistMethod_Iterate\n");
1063
1064         for(pass = 1; pass <= 2; ++pass)
1065         {
1066                 for(i = 1; i < Map_Count; ++i)
1067                 {
1068                         float mapindex;
1069                         mapindex = mod(i + Map_Current, Map_Count);
1070                         if(Map_Check(mapindex, pass))
1071                                 return mapindex;
1072                 }
1073         }
1074         return -1;
1075 }
1076
1077 float() MaplistMethod_Repeat = // fallback method
1078 {
1079         dprint("Trying MaplistMethod_Repeat\n");
1080
1081         if(Map_Check(Map_Current, 2))
1082                 return Map_Current;
1083         return -2;
1084 }
1085
1086 float() MaplistMethod_Random = // random map selection
1087 {
1088         float i, imax;
1089
1090         dprint("Trying MaplistMethod_Random\n");
1091
1092         imax = 42;
1093
1094         for(i = 0; i <= imax; ++i)
1095         {
1096                 float mapindex;
1097                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1098                 if(Map_Check(mapindex, 1))
1099                         return mapindex;
1100         }
1101         return -1;
1102 }
1103
1104 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1105 // the exponent sets a bias on the map selection:
1106 // the higher the exponent, the less likely "shortly repeated" same maps are
1107 {
1108         float i, j, imax, insertpos;
1109
1110         dprint("Trying MaplistMethod_Shuffle\n");
1111
1112         imax = 42;
1113
1114         for(i = 0; i <= imax; ++i)
1115         {
1116                 string newlist;
1117
1118                 // now reinsert this at another position
1119                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1120                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1121                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1122                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1123
1124                 // insert the current map there
1125                 newlist = "";
1126                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1127                         newlist = strcat(newlist, " ", argv(j));
1128                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1129                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1130                         newlist = strcat(newlist, " ", argv(j));
1131                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1132                 cvar_set("g_maplist", newlist);
1133                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1134
1135                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1136                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1137                 if(Map_Check(Map_Current, 1))
1138                         return Map_Current;
1139         }
1140         return -1;
1141 }
1142
1143 void Maplist_Init()
1144 {
1145         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1146         float i;
1147         for (i = 0; i < Map_Count; ++i)
1148                 if (Map_Check(i, 2))
1149                         break;
1150         if (i == Map_Count)
1151         {
1152                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1153                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1154                 if(autocvar_g_maplist_shuffle)
1155                         ShuffleMaplist();
1156                 localcmd("\nmenu_cmd sync\n");
1157                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1158         }
1159         if(Map_Count == 0)
1160                 error("empty maplist, cannot select a new map");
1161         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1162
1163         if(Map_Current_Name)
1164                 strunzone(Map_Current_Name);
1165         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1166         // this may or may not be correct, but who cares, in the worst case a map
1167         // isn't chosen in the first pass that should have been
1168 }
1169
1170 string GetNextMap()
1171 {
1172         float nextMap;
1173
1174         Maplist_Init();
1175         nextMap = -1;
1176
1177         if(nextMap == -1)
1178                 if(autocvar_g_maplist_shuffle > 0)
1179                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1180
1181         if(nextMap == -1)
1182                 if(autocvar_g_maplist_selectrandom)
1183                         nextMap = MaplistMethod_Random();
1184
1185         if(nextMap == -1)
1186                 nextMap = MaplistMethod_Iterate();
1187
1188         if(nextMap == -1)
1189                 nextMap = MaplistMethod_Repeat();
1190
1191         if(nextMap >= 0)
1192         {
1193                 Map_Goto_SetFloat(nextMap);
1194                 return getmapname_stored;
1195         }
1196
1197         return "";
1198 }
1199
1200 float DoNextMapOverride(float reinit)
1201 {
1202         if(autocvar_g_campaign)
1203         {
1204                 CampaignPostIntermission();
1205                 alreadychangedlevel = TRUE;
1206                 return TRUE;
1207         }
1208         if(autocvar_quit_when_empty)
1209         {
1210                 if(player_count <= currentbots)
1211                 {
1212                         localcmd("quit\n");
1213                         alreadychangedlevel = TRUE;
1214                         return TRUE;
1215                 }
1216         }
1217         if(autocvar_quit_and_redirect != "")
1218         {
1219                 redirection_target = strzone(autocvar_quit_and_redirect);
1220                 alreadychangedlevel = TRUE;
1221                 return TRUE;
1222         }
1223         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1224         {
1225                 localcmd("restart\n");
1226                 alreadychangedlevel = TRUE;
1227                 return TRUE;
1228         }
1229         if(autocvar_nextmap != "")
1230                 if(MapInfo_CheckMap(autocvar_nextmap))
1231                 {
1232                         Map_Goto_SetStr(autocvar_nextmap);
1233                         Map_Goto(reinit);
1234                         alreadychangedlevel = TRUE;
1235                         return TRUE;
1236                 }
1237         if(!reinit && autocvar_lastlevel)
1238         {
1239                 cvar_settemp_restore();
1240                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1241                 alreadychangedlevel = TRUE;
1242                 return TRUE;
1243         }
1244         return FALSE;
1245 }
1246
1247 void GotoNextMap(float reinit)
1248 {
1249         //string nextmap;
1250         //float n, nummaps;
1251         //string s;
1252         if (alreadychangedlevel)
1253                 return;
1254         alreadychangedlevel = TRUE;
1255
1256         string nextMap;
1257
1258         nextMap = GetNextMap();
1259         if(nextMap == "")
1260                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1261         Map_Goto(reinit);
1262 }
1263
1264
1265 /*
1266 ============
1267 IntermissionThink
1268
1269 When the player presses attack or jump, change to the next level
1270 ============
1271 */
1272 .float autoscreenshot;
1273 void() MapVote_Start;
1274 void() MapVote_Think;
1275 float mapvote_initialized;
1276 void IntermissionThink()
1277 {
1278         FixIntermissionClient(self);
1279
1280         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1281         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1282
1283         if( (server_screenshot || client_screenshot)
1284                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1285         {
1286                 self.autoscreenshot = -1;
1287                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1288                 return;
1289         }
1290
1291         if (time < intermission_exittime)
1292                 return;
1293
1294         if(!mapvote_initialized)
1295                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1296                         return;
1297
1298         MapVote_Start();
1299 }
1300
1301 /*
1302 ============
1303 FindIntermission
1304
1305 Returns the entity to view from
1306 ============
1307 */
1308 /*
1309 entity FindIntermission()
1310 {
1311         local   entity spot;
1312         local   float cyc;
1313
1314 // look for info_intermission first
1315         spot = find (world, classname, "info_intermission");
1316         if (spot)
1317         {       // pick a random one
1318                 cyc = random() * 4;
1319                 while (cyc > 1)
1320                 {
1321                         spot = find (spot, classname, "info_intermission");
1322                         if (!spot)
1323                                 spot = find (spot, classname, "info_intermission");
1324                         cyc = cyc - 1;
1325                 }
1326                 return spot;
1327         }
1328
1329 // then look for the start position
1330         spot = find (world, classname, "info_player_start");
1331         if (spot)
1332                 return spot;
1333
1334 // testinfo_player_start is only found in regioned levels
1335         spot = find (world, classname, "testplayerstart");
1336         if (spot)
1337                 return spot;
1338
1339 // then look for the start position
1340         spot = find (world, classname, "info_player_deathmatch");
1341         if (spot)
1342                 return spot;
1343
1344         //objerror ("FindIntermission: no spot");
1345         return world;
1346 }
1347 */
1348
1349 /*
1350 ===============================================================================
1351
1352 RULES
1353
1354 ===============================================================================
1355 */
1356
1357 void DumpStats(float final)
1358 {
1359         float file;
1360         string s;
1361         float to_console;
1362         float to_eventlog;
1363         float to_file;
1364         float i;
1365
1366         to_console = autocvar_sv_logscores_console;
1367         to_eventlog = autocvar_sv_eventlog;
1368         to_file = autocvar_sv_logscores_file;
1369
1370         if(!final)
1371         {
1372                 to_console = TRUE; // always print printstats replies
1373                 to_eventlog = FALSE; // but never print them to the event log
1374         }
1375
1376         if(to_eventlog)
1377                 if(autocvar_sv_eventlog_console)
1378                         to_console = FALSE; // otherwise we get the output twice
1379
1380         if(final)
1381                 s = ":scores:";
1382         else
1383                 s = ":status:";
1384         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1385
1386         if(to_console)
1387                 print(s, "\n");
1388         if(to_eventlog)
1389                 GameLogEcho(s);
1390
1391         file = -1;
1392         if(to_file)
1393         {
1394                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1395                 if(file == -1)
1396                         to_file = FALSE;
1397                 else
1398                         fputs(file, strcat(s, "\n"));
1399         }
1400
1401         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1402         if(to_console)
1403                 print(s, "\n");
1404         if(to_eventlog)
1405                 GameLogEcho(s);
1406         if(to_file)
1407                 fputs(file, strcat(s, "\n"));
1408
1409         FOR_EACH_CLIENT(other)
1410         {
1411                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1412                 {
1413                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1414                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1415                         if(IS_PLAYER(other) || g_arena || other.caplayer == 1 || g_lms)
1416                                 s = strcat(s, ftos(other.team), ":");
1417                         else
1418                                 s = strcat(s, "spectator:");
1419
1420                         if(to_console)
1421                                 print(s, other.netname, "\n");
1422                         if(to_eventlog)
1423                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1424                         if(to_file)
1425                                 fputs(file, strcat(s, other.netname, "\n"));
1426                 }
1427         }
1428
1429         if(teamplay)
1430         {
1431                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1432                 if(to_console)
1433                         print(s, "\n");
1434                 if(to_eventlog)
1435                         GameLogEcho(s);
1436                 if(to_file)
1437                         fputs(file, strcat(s, "\n"));
1438
1439                 for(i = 1; i < 16; ++i)
1440                 {
1441                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1442                         s = strcat(s, ":", ftos(i));
1443                         if(to_console)
1444                                 print(s, "\n");
1445                         if(to_eventlog)
1446                                 GameLogEcho(s);
1447                         if(to_file)
1448                                 fputs(file, strcat(s, "\n"));
1449                 }
1450         }
1451
1452         if(to_console)
1453                 print(":end\n");
1454         if(to_eventlog)
1455                 GameLogEcho(":end");
1456         if(to_file)
1457         {
1458                 fputs(file, ":end\n");
1459                 fclose(file);
1460         }
1461 }
1462
1463 void FixIntermissionClient(entity e)
1464 {
1465         string s;
1466         if(!e.autoscreenshot) // initial call
1467         {
1468                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1469                 e.health = -2342;
1470                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1471                 e.solid = SOLID_NOT;
1472                 e.movetype = MOVETYPE_NONE;
1473                 e.takedamage = DAMAGE_NO;
1474                 if(e.weaponentity)
1475                 {
1476                         e.weaponentity.effects = EF_NODRAW;
1477                         if (e.weaponentity.weaponentity)
1478                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1479                 }
1480                 if(IS_REAL_CLIENT(e))
1481                 {
1482                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1483                         s = autocvar_sv_intermission_cdtrack;
1484                         if(s != "")
1485                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1486                         msg_entity = e;
1487                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1488                 }
1489         }
1490 }
1491
1492 /*
1493 go to the next level for deathmatch
1494 only called if a time or frag limit has expired
1495 */
1496 void NextLevel()
1497 {
1498         gameover = TRUE;
1499
1500         intermission_running = 1;
1501
1502 // enforce a wait time before allowing changelevel
1503         if(player_count > 0)
1504                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1505         else
1506                 intermission_exittime = -1;
1507
1508         /*
1509         WriteByte (MSG_ALL, SVC_CDTRACK);
1510         WriteByte (MSG_ALL, 3);
1511         WriteByte (MSG_ALL, 3);
1512         // done in FixIntermission
1513         */
1514
1515         //pos = FindIntermission ();
1516
1517         VoteReset();
1518
1519         DumpStats(TRUE);
1520
1521         // send statistics
1522         entity e;
1523         PlayerStats_EndMatch(1);
1524         FOR_EACH_CLIENT(e)
1525                 PlayerStats_AddGlobalInfo(e);
1526         PlayerStats_Shutdown();
1527         WeaponStats_Shutdown();
1528
1529         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1530
1531         if(autocvar_sv_eventlog)
1532                 GameLogEcho(":gameover");
1533
1534         GameLogClose();
1535
1536         FOR_EACH_PLAYER(other) {
1537                 FixIntermissionClient(other);
1538                 if(other.winning)
1539                         bprint(other.netname, " ^7wins.\n");
1540         }
1541
1542         if(autocvar_g_campaign)
1543                 CampaignPreIntermission();
1544
1545         MUTATOR_CALLHOOK(MatchEnd);
1546
1547         localcmd("\nsv_hook_gameend\n");
1548 }
1549
1550 /*
1551 ============
1552 CheckRules_Player
1553
1554 Exit deathmatch games upon conditions
1555 ============
1556 */
1557 void CheckRules_Player()
1558 {
1559         if (gameover)   // someone else quit the game already
1560                 return;
1561
1562         if(self.deadflag == DEAD_NO)
1563                 self.play_time += frametime;
1564
1565         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1566         //   (div0: and that in CheckRules_World please)
1567 }
1568
1569 float checkrules_equality;
1570 float checkrules_suddendeathwarning;
1571 float checkrules_suddendeathend;
1572 float checkrules_overtimesadded; //how many overtimes have been already added
1573
1574 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1575 const float WINNING_YES = 1; // winner found
1576 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1577 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1578
1579 float InitiateSuddenDeath()
1580 {
1581         // Check first whether normal overtimes could be added before initiating suddendeath mode
1582         // - for this timelimit_overtime needs to be >0 of course
1583         // - also check the winning condition calculated in the previous frame and only add normal overtime
1584         //   again, if at the point at which timelimit would be extended again, still no winner was found
1585         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1586         {
1587                 return 1; // need to call InitiateOvertime later
1588         }
1589         else
1590         {
1591                 if(!checkrules_suddendeathend)
1592                 {
1593                         if(autocvar_g_campaign)
1594                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1595                         else
1596                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1597                         if(g_race && !g_race_qualifying)
1598                                 race_StartCompleting();
1599                 }
1600                 return 0;
1601         }
1602 }
1603
1604 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1605 {
1606         ++checkrules_overtimesadded;
1607         //add one more overtime by simply extending the timelimit
1608         float tl;
1609         tl = autocvar_timelimit;
1610         tl += autocvar_timelimit_overtime;
1611         cvar_set("timelimit", ftos(tl));
1612
1613         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1614 }
1615
1616 float GetWinningCode(float fraglimitreached, float equality)
1617 {
1618         if(autocvar_g_campaign == 1)
1619                 if(fraglimitreached)
1620                         return WINNING_YES;
1621                 else
1622                         return WINNING_NO;
1623
1624         else
1625                 if(equality)
1626                         if(fraglimitreached)
1627                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1628                         else
1629                                 return WINNING_NEVER;
1630                 else
1631                         if(fraglimitreached)
1632                                 return WINNING_YES;
1633                         else
1634                                 return WINNING_NO;
1635 }
1636
1637 // set the .winning flag for exactly those players with a given field value
1638 void SetWinners(.float field, float value)
1639 {
1640         entity head;
1641         FOR_EACH_PLAYER(head)
1642                 head.winning = (head.field == value);
1643 }
1644
1645 // set the .winning flag for those players with a given field value
1646 void AddWinners(.float field, float value)
1647 {
1648         entity head;
1649         FOR_EACH_PLAYER(head)
1650                 if(head.field == value)
1651                         head.winning = 1;
1652 }
1653
1654 // clear the .winning flags
1655 void ClearWinners(void)
1656 {
1657         entity head;
1658         FOR_EACH_PLAYER(head)
1659                 head.winning = 0;
1660 }
1661
1662 // Onslaught winning condition:
1663 // game terminates if only one team has a working generator (or none)
1664 float WinningCondition_Onslaught()
1665 {
1666         entity head;
1667         float t1, t2, t3, t4;
1668
1669         WinningConditionHelper(); // set worldstatus
1670
1671         if(warmup_stage)
1672                 return WINNING_NO;
1673
1674         // first check if the game has ended
1675         t1 = t2 = t3 = t4 = 0;
1676         head = find(world, classname, "onslaught_generator");
1677         while (head)
1678         {
1679                 if (head.health > 0)
1680                 {
1681                         if (head.team == NUM_TEAM_1) t1 = 1;
1682                         if (head.team == NUM_TEAM_2) t2 = 1;
1683                         if (head.team == NUM_TEAM_3) t3 = 1;
1684                         if (head.team == NUM_TEAM_4) t4 = 1;
1685                 }
1686                 head = find(head, classname, "onslaught_generator");
1687         }
1688         if (t1 + t2 + t3 + t4 < 2)
1689         {
1690                 // game over, only one team remains (or none)
1691                 ClearWinners();
1692                 if (t1) SetWinners(team, NUM_TEAM_1);
1693                 if (t2) SetWinners(team, NUM_TEAM_2);
1694                 if (t3) SetWinners(team, NUM_TEAM_3);
1695                 if (t4) SetWinners(team, NUM_TEAM_4);
1696                 dprint("Have a winner, ending game.\n");
1697                 return WINNING_YES;
1698         }
1699
1700         // Two or more teams remain
1701         return WINNING_NO;
1702 }
1703
1704 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1705 // they win. Otherwise the defending team wins once the timelimit passes.
1706 void assault_new_round();
1707 float WinningCondition_Assault()
1708 {
1709         float status;
1710
1711         WinningConditionHelper(); // set worldstatus
1712
1713         status = WINNING_NO;
1714         // as the timelimit has not yet passed just assume the defending team will win
1715         if(assault_attacker_team == NUM_TEAM_1)
1716         {
1717                 SetWinners(team, NUM_TEAM_2);
1718         }
1719         else
1720         {
1721                 SetWinners(team, NUM_TEAM_1);
1722         }
1723
1724         entity ent;
1725         ent = find(world, classname, "target_assault_roundend");
1726         if(ent)
1727         {
1728                 if(ent.winning) // round end has been triggered by attacking team
1729                 {
1730                         bprint("ASSAULT: round completed...\n");
1731                         SetWinners(team, assault_attacker_team);
1732
1733                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1734
1735                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1736                         {
1737                                 status = WINNING_YES;
1738                         }
1739                         else
1740                         {
1741                                 entity oldself;
1742                                 oldself = self;
1743                                 self = ent;
1744                                 assault_new_round();
1745                                 self = oldself;
1746                         }
1747                 }
1748         }
1749
1750         return status;
1751 }
1752
1753 // LMS winning condition: game terminates if and only if there's at most one
1754 // one player who's living lives. Top two scores being equal cancels the time
1755 // limit.
1756 float WinningCondition_LMS()
1757 {
1758         entity head, head2;
1759         float have_player;
1760         float have_players;
1761         float l;
1762
1763         have_player = FALSE;
1764         have_players = FALSE;
1765         l = LMS_NewPlayerLives();
1766
1767         head = find(world, classname, "player");
1768         if(head)
1769                 have_player = TRUE;
1770         head2 = find(head, classname, "player");
1771         if(head2)
1772                 have_players = TRUE;
1773
1774         if(have_player)
1775         {
1776                 // we have at least one player
1777                 if(have_players)
1778                 {
1779                         // two or more active players - continue with the game
1780                 }
1781                 else
1782                 {
1783                         // exactly one player?
1784
1785                         ClearWinners();
1786                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1787
1788                         if(l)
1789                         {
1790                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1791                                 return WINNING_NO;
1792                         }
1793                         else
1794                         {
1795                                 // a winner!
1796                                 // and assign him his first place
1797                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1798                                 return WINNING_YES;
1799                         }
1800                 }
1801         }
1802         else
1803         {
1804                 // nobody is playing at all...
1805                 if(l)
1806                 {
1807                         // wait for players...
1808                 }
1809                 else
1810                 {
1811                         // SNAFU (maybe a draw game?)
1812                         ClearWinners();
1813                         dprint("No players, ending game.\n");
1814                         return WINNING_YES;
1815                 }
1816         }
1817
1818         // When we get here, we have at least two players who are actually LIVING,
1819         // now check if the top two players have equal score.
1820         WinningConditionHelper();
1821
1822         ClearWinners();
1823         if(WinningConditionHelper_winner)
1824                 WinningConditionHelper_winner.winning = TRUE;
1825         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1826                 return WINNING_NEVER;
1827
1828         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1829         return WINNING_NO;
1830 }
1831
1832 void ShuffleMaplist()
1833 {
1834         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1835 }
1836
1837 float leaderfrags;
1838 float WinningCondition_Scores(float limit, float leadlimit)
1839 {
1840         float limitreached;
1841
1842         // TODO make everything use THIS winning condition (except LMS)
1843         WinningConditionHelper();
1844
1845         if(teamplay)
1846         {
1847                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1848                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1849                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1850                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1851         }
1852
1853         ClearWinners();
1854         if(WinningConditionHelper_winner)
1855                 WinningConditionHelper_winner.winning = 1;
1856         if(WinningConditionHelper_winnerteam >= 0)
1857                 SetWinners(team, WinningConditionHelper_winnerteam);
1858
1859         if(WinningConditionHelper_lowerisbetter)
1860         {
1861                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1862                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1863                 limit = -limit;
1864         }
1865
1866         if(WinningConditionHelper_zeroisworst)
1867                 leadlimit = 0; // not supported in this mode
1868
1869         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1870         // these modes always score in increments of 1, thus this makes sense
1871         {
1872                 if(leaderfrags != WinningConditionHelper_topscore)
1873                 {
1874                         leaderfrags = WinningConditionHelper_topscore;
1875
1876                         if (limit)
1877                         if (leaderfrags == limit - 1)
1878                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1879                         else if (leaderfrags == limit - 2)
1880                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1881                         else if (leaderfrags == limit - 3)
1882                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1883                 }
1884         }
1885
1886         limitreached = FALSE;
1887         if(limit)
1888                 if(WinningConditionHelper_topscore >= limit)
1889                         limitreached = TRUE;
1890         if(leadlimit)
1891         {
1892                 float leadlimitreached;
1893                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1894                 if(autocvar_leadlimit_and_fraglimit)
1895                         limitreached = (limitreached && leadlimitreached);
1896                 else
1897                         limitreached = (limitreached || leadlimitreached);
1898         }
1899
1900         if(limit)
1901                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1902
1903         return GetWinningCode(
1904                 WinningConditionHelper_topscore && limitreached,
1905                 WinningConditionHelper_equality
1906         );
1907 }
1908
1909 float WinningCondition_Race(float fraglimit)
1910 {
1911         float wc;
1912         entity p;
1913         float n, c;
1914
1915         n = 0;
1916         c = 0;
1917         FOR_EACH_PLAYER(p)
1918         {
1919                 ++n;
1920                 if(p.race_completed)
1921                         ++c;
1922         }
1923         if(n && (n == c))
1924                 return WINNING_YES;
1925         wc = WinningCondition_Scores(fraglimit, 0);
1926
1927         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1928         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1929         // do NOT support equality when the laps are all raced!
1930                 return WINNING_STARTSUDDENDEATHOVERTIME;
1931         else
1932                 return WINNING_NEVER;
1933 }
1934
1935 float WinningCondition_QualifyingThenRace(float limit)
1936 {
1937         float wc;
1938         wc = WinningCondition_Scores(limit, 0);
1939
1940         // NEVER initiate overtime
1941         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1942         {
1943                 return WINNING_YES;
1944         }
1945
1946         return wc;
1947 }
1948
1949 float WinningCondition_RanOutOfSpawns()
1950 {
1951         entity head;
1952
1953         if(have_team_spawns <= 0)
1954                 return WINNING_NO;
1955
1956         if(autocvar_g_spawn_useallspawns <= 0)
1957                 return WINNING_NO;
1958
1959         if(!some_spawn_has_been_used)
1960                 return WINNING_NO;
1961
1962         team1_score = team2_score = team3_score = team4_score = 0;
1963
1964         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1965         {
1966                 if(head.team == NUM_TEAM_1)
1967                         team1_score = 1;
1968                 else if(head.team == NUM_TEAM_2)
1969                         team2_score = 1;
1970                 else if(head.team == NUM_TEAM_3)
1971                         team3_score = 1;
1972                 else if(head.team == NUM_TEAM_4)
1973                         team4_score = 1;
1974         }
1975
1976         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1977         {
1978                 if(head.team == NUM_TEAM_1)
1979                         team1_score = 1;
1980                 else if(head.team == NUM_TEAM_2)
1981                         team2_score = 1;
1982                 else if(head.team == NUM_TEAM_3)
1983                         team3_score = 1;
1984                 else if(head.team == NUM_TEAM_4)
1985                         team4_score = 1;
1986         }
1987
1988         ClearWinners();
1989         if(team1_score + team2_score + team3_score + team4_score == 0)
1990         {
1991                 checkrules_equality = TRUE;
1992                 return WINNING_YES;
1993         }
1994         else if(team1_score + team2_score + team3_score + team4_score == 1)
1995         {
1996                 float t, i;
1997                 if(team1_score)
1998                         t = NUM_TEAM_1;
1999                 else if(team2_score)
2000                         t = NUM_TEAM_2;
2001                 else if(team3_score)
2002                         t = NUM_TEAM_3;
2003                 else // if(team4_score)
2004                         t = NUM_TEAM_4;
2005                 CheckAllowedTeams(world);
2006                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2007                 {
2008                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2009                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2010                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2011                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2012                 }
2013
2014                 AddWinners(team, t);
2015                 return WINNING_YES;
2016         }
2017         else
2018                 return WINNING_NO;
2019 }
2020
2021 /*
2022 ============
2023 CheckRules_World
2024
2025 Exit deathmatch games upon conditions
2026 ============
2027 */
2028 void ReadyRestart();
2029 void CheckRules_World()
2030 {
2031         float timelimit;
2032         float fraglimit;
2033         float leadlimit;
2034
2035         VoteThink();
2036         MapVote_Think();
2037
2038         SetDefaultAlpha();
2039
2040         /*
2041         MapVote_Think should now do that part
2042         if (intermission_running)
2043                 if (time >= intermission_exittime + 60)
2044                 {
2045                         if(!DoNextMapOverride())
2046                                 GotoNextMap();
2047                         return;
2048                 }
2049         */
2050
2051         if (gameover)   // someone else quit the game already
2052         {
2053                 if(player_count == 0) // Nobody there? Then let's go to the next map
2054                         MapVote_Start();
2055                         // this will actually check the player count in the next frame
2056                         // again, but this shouldn't hurt
2057                 return;
2058         }
2059
2060         timelimit = autocvar_timelimit * 60;
2061         fraglimit = autocvar_fraglimit;
2062         leadlimit = autocvar_leadlimit;
2063
2064         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2065         {
2066                 if(timelimit > 0)
2067                         timelimit = 0; // timelimit is not made for warmup
2068                 if(fraglimit > 0)
2069                         fraglimit = 0; // no fraglimit for now
2070                 leadlimit = 0; // no leadlimit for now
2071         }
2072
2073         if(timelimit > 0)
2074         {
2075                 timelimit += game_starttime;
2076         }
2077         else if (timelimit < 0)
2078         {
2079                 // endmatch
2080                 NextLevel();
2081                 return;
2082         }
2083
2084         if(g_onslaught)
2085                 timelimit = 0; // ONS has its own overtime rule
2086
2087         float wantovertime;
2088         wantovertime = 0;
2089
2090         if(timelimit > game_starttime)
2091                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2092         else
2093                 game_completion_ratio = 0;
2094
2095         if(checkrules_suddendeathend)
2096         {
2097                 if(!checkrules_suddendeathwarning)
2098                 {
2099                         checkrules_suddendeathwarning = TRUE;
2100                         if(g_race && !g_race_qualifying)
2101                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2102                         else
2103                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2104                 }
2105         }
2106         else
2107         {
2108                 if (timelimit && time >= timelimit)
2109                 {
2110                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2111                         {
2112                                 float totalplayers;
2113                                 float playerswithlaps;
2114                                 float readyplayers;
2115                                 entity head;
2116                                 totalplayers = playerswithlaps = readyplayers = 0;
2117                                 FOR_EACH_PLAYER(head)
2118                                 {
2119                                         ++totalplayers;
2120                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2121                                                 ++playerswithlaps;
2122                                         if(head.ready)
2123                                                 ++readyplayers;
2124                                 }
2125
2126                                 // at least 2 of the players have completed a lap: start the RACE
2127                                 // otherwise, the players should end the qualifying on their own
2128                                 if(readyplayers || playerswithlaps >= 2)
2129                                 {
2130                                         checkrules_suddendeathend = 0;
2131                                         ReadyRestart(); // go to race
2132                                         return;
2133                                 }
2134                                 else
2135                                         wantovertime |= InitiateSuddenDeath();
2136                         }
2137                         else
2138                                 wantovertime |= InitiateSuddenDeath();
2139                 }
2140         }
2141
2142         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2143         {
2144                 NextLevel();
2145                 return;
2146         }
2147
2148         float checkrules_status;
2149         checkrules_status = WinningCondition_RanOutOfSpawns();
2150         if(checkrules_status == WINNING_YES)
2151         {
2152                 bprint("Hey! Someone ran out of spawns!\n");
2153         }
2154         else if(g_race && !g_race_qualifying && timelimit >= 0)
2155         {
2156                 checkrules_status = WinningCondition_Race(fraglimit);
2157                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2158         }
2159         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2160         {
2161                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2162                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2163         }
2164         else if(g_assault)
2165         {
2166                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2167         }
2168         else if(g_lms)
2169         {
2170                 checkrules_status = WinningCondition_LMS();
2171         }
2172         else if (g_onslaught)
2173         {
2174                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2175         }
2176         else
2177         {
2178                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2179                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2180         }
2181
2182         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2183         {
2184                 checkrules_status = WINNING_NEVER;
2185                 checkrules_overtimesadded = -1;
2186                 wantovertime |= InitiateSuddenDeath();
2187         }
2188
2189         if(checkrules_status == WINNING_NEVER)
2190                 // equality cases! Nobody wins if the overtime ends in a draw.
2191                 ClearWinners();
2192
2193         if(wantovertime)
2194         {
2195                 if(checkrules_status == WINNING_NEVER)
2196                         InitiateOvertime();
2197                 else
2198                         checkrules_status = WINNING_YES;
2199         }
2200
2201         if(checkrules_suddendeathend)
2202                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2203                         checkrules_status = WINNING_YES;
2204
2205         if(checkrules_status == WINNING_YES)
2206         {
2207                 //print("WINNING\n");
2208                 NextLevel();
2209         }
2210 }
2211
2212 float mapvote_nextthink;
2213 float mapvote_initialized;
2214 float mapvote_keeptwotime;
2215 float mapvote_timeout;
2216 string mapvote_message;
2217 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2218 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2219 float mapvote_screenshot_dirs_count;
2220
2221 float mapvote_count;
2222 float mapvote_count_real;
2223 string mapvote_maps[MAPVOTE_COUNT];
2224 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2225 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2226 float mapvote_maps_suggested[MAPVOTE_COUNT];
2227 string mapvote_suggestions[MAPVOTE_COUNT];
2228 float mapvote_suggestion_ptr;
2229 float mapvote_voters;
2230 float mapvote_selections[MAPVOTE_COUNT];
2231 float mapvote_run;
2232 float mapvote_detail;
2233 float mapvote_abstain;
2234 .float mapvote;
2235
2236 void MapVote_ClearAllVotes()
2237 {
2238         FOR_EACH_CLIENT(other)
2239                 other.mapvote = 0;
2240 }
2241
2242 string MapVote_Suggest(string m)
2243 {
2244         float i;
2245         if(m == "")
2246                 return "That's not how to use this command.";
2247         if(!autocvar_g_maplist_votable_suggestions)
2248                 return "Suggestions are not accepted on this server.";
2249         if(mapvote_initialized)
2250                 return "Can't suggest - voting is already in progress!";
2251         m = MapInfo_FixName(m);
2252         if (!m)
2253                 return "The map you suggested is not available on this server.";
2254         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2255                 if(Map_IsRecent(m))
2256                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2257
2258         if(!MapInfo_CheckMap(m))
2259                 return "The map you suggested does not support the current game mode.";
2260         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2261                 if(mapvote_suggestions[i] == m)
2262                         return "This map was already suggested.";
2263         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2264         {
2265                 i = floor(random() * mapvote_suggestion_ptr);
2266         }
2267         else
2268         {
2269                 i = mapvote_suggestion_ptr;
2270                 mapvote_suggestion_ptr += 1;
2271         }
2272         if(mapvote_suggestions[i] != "")
2273                 strunzone(mapvote_suggestions[i]);
2274         mapvote_suggestions[i] = strzone(m);
2275         if(autocvar_sv_eventlog)
2276                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2277         return strcat("Suggestion of ", m, " accepted.");
2278 }
2279
2280 void MapVote_AddVotable(string nextMap, float isSuggestion)
2281 {
2282         float j, i, o;
2283         string pakfile, mapfile;
2284
2285         if(nextMap == "")
2286                 return;
2287         for(j = 0; j < mapvote_count; ++j)
2288                 if(mapvote_maps[j] == nextMap)
2289                         return;
2290         // suggestions might be no longer valid/allowed after gametype switch!
2291         if(isSuggestion)
2292                 if(!MapInfo_CheckMap(nextMap))
2293                         return;
2294         mapvote_maps[mapvote_count] = strzone(nextMap);
2295         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2296
2297         pakfile = string_null;
2298         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2299         {
2300                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2301                 pakfile = whichpack(strcat(mapfile, ".tga"));
2302                 if(pakfile == "")
2303                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2304                 if(pakfile == "")
2305                         pakfile = whichpack(strcat(mapfile, ".png"));
2306                 if(pakfile != "")
2307                         break;
2308         }
2309         if(i >= mapvote_screenshot_dirs_count)
2310                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2311         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2312                 pakfile = substring(pakfile, o, -1);
2313
2314         mapvote_maps_screenshot_dir[mapvote_count] = i;
2315         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2316
2317         mapvote_count += 1;
2318 }
2319
2320 void MapVote_Spawn();
2321 void MapVote_Init()
2322 {
2323         float i;
2324         float nmax, smax;
2325
2326         MapVote_ClearAllVotes();
2327
2328         mapvote_count = 0;
2329         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2330         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2331
2332         if(mapvote_abstain)
2333                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2334         else
2335                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2336         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2337
2338         // we need this for AddVotable, as that cycles through the screenshot dirs
2339         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2340         if(mapvote_screenshot_dirs_count == 0)
2341                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2342         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2343         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2344                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2345
2346         if(mapvote_suggestion_ptr)
2347                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2348                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2349
2350         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2351                 MapVote_AddVotable(GetNextMap(), FALSE);
2352
2353         if(mapvote_count == 0)
2354         {
2355                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2356                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2357                 if(autocvar_g_maplist_shuffle)
2358                         ShuffleMaplist();
2359                 localcmd("\nmenu_cmd sync\n");
2360                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2361                         MapVote_AddVotable(GetNextMap(), FALSE);
2362         }
2363
2364         mapvote_count_real = mapvote_count;
2365         if(mapvote_abstain)
2366                 MapVote_AddVotable("don't care", 0);
2367
2368         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2369
2370         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2371         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2372         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2373                 mapvote_keeptwotime = 0;
2374         mapvote_message = "Choose a map and press its key!";
2375
2376         MapVote_Spawn();
2377 }
2378
2379 void MapVote_SendPicture(float id)
2380 {
2381         msg_entity = self;
2382         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2383         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2384         WriteByte(MSG_ONE, id);
2385         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2386 }
2387
2388 float MapVote_GetMapMask()
2389 {
2390         float mask, i, power;
2391         mask = 0;
2392         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2393                 if(mapvote_maps[i] != "")
2394                         mask |= power;
2395         return mask;
2396 }
2397
2398 entity mapvote_ent;
2399 float MapVote_SendEntity(entity to, float sf)
2400 {
2401         float i;
2402
2403         if(sf & 1)
2404                 sf &= ~2; // if we send 1, we don't need to also send 2
2405
2406         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2407         WriteByte(MSG_ENTITY, sf);
2408
2409         if(sf & 1)
2410         {
2411                 // flag 1 == initialization
2412                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2413                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2414                 WriteString(MSG_ENTITY, "");
2415                 WriteByte(MSG_ENTITY, mapvote_count);
2416                 WriteByte(MSG_ENTITY, mapvote_abstain);
2417                 WriteByte(MSG_ENTITY, mapvote_detail);
2418                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2419                 if(mapvote_count <= 8)
2420                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2421                 else
2422                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2423                 for(i = 0; i < mapvote_count; ++i)
2424                         if(mapvote_maps[i] != "")
2425                         {
2426                                 if(mapvote_abstain && i == mapvote_count - 1)
2427                                 {
2428                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2429                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2430                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2431                                 }
2432                                 else
2433                                 {
2434                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2435                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2436                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2437                                 }
2438                         }
2439         }
2440
2441         if(sf & 2)
2442         {
2443                 // flag 2 == update of mask
2444                 if(mapvote_count <= 8)
2445                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2446                 else
2447                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2448         }
2449
2450         if(sf & 4)
2451         {
2452                 if(mapvote_detail)
2453                         for(i = 0; i < mapvote_count; ++i)
2454                                 if(mapvote_maps[i] != "")
2455                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2456
2457                 WriteByte(MSG_ENTITY, to.mapvote);
2458         }
2459
2460         return TRUE;
2461 }
2462
2463 void MapVote_Spawn()
2464 {
2465         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2466 }
2467
2468 void MapVote_TouchMask()
2469 {
2470         mapvote_ent.SendFlags |= 2;
2471 }
2472
2473 void MapVote_TouchVotes(entity voter)
2474 {
2475         mapvote_ent.SendFlags |= 4;
2476 }
2477
2478 float MapVote_Finished(float mappos)
2479 {
2480         string result;
2481         float i;
2482         float didntvote;
2483
2484         if(autocvar_sv_eventlog)
2485         {
2486                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2487                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2488                 didntvote = mapvote_voters;
2489                 for(i = 0; i < mapvote_count; ++i)
2490                         if(mapvote_maps[i] != "")
2491                         {
2492                                 didntvote -= mapvote_selections[i];
2493                                 if(i != mappos)
2494                                 {
2495                                         result = strcat(result, ":", mapvote_maps[i]);
2496                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2497                                 }
2498                         }
2499                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2500
2501                 GameLogEcho(result);
2502                 if(mapvote_maps_suggested[mappos])
2503                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2504         }
2505
2506         FOR_EACH_REALCLIENT(other)
2507                 FixClientCvars(other);
2508
2509         Map_Goto_SetStr(mapvote_maps[mappos]);
2510         Map_Goto(0);
2511         alreadychangedlevel = TRUE;
2512         return TRUE;
2513 }
2514 void MapVote_CheckRules_1()
2515 {
2516         float i;
2517
2518         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2519         {
2520                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2521                 mapvote_selections[i] = 0;
2522         }
2523
2524         mapvote_voters = 0;
2525         FOR_EACH_REALCLIENT(other)
2526         {
2527                 ++mapvote_voters;
2528                 if(other.mapvote)
2529                 {
2530                         i = other.mapvote - 1;
2531                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2532                         mapvote_selections[i] = mapvote_selections[i] + 1;
2533                 }
2534         }
2535 }
2536
2537 float MapVote_CheckRules_2()
2538 {
2539         float i;
2540         float firstPlace, secondPlace;
2541         float firstPlaceVotes, secondPlaceVotes;
2542         float mapvote_voters_real;
2543         string result;
2544
2545         if(mapvote_count_real == 1)
2546                 return MapVote_Finished(0);
2547
2548         mapvote_voters_real = mapvote_voters;
2549         if(mapvote_abstain)
2550                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2551
2552         RandomSelection_Init();
2553         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2554                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2555         firstPlace = RandomSelection_chosen_float;
2556         firstPlaceVotes = RandomSelection_best_priority;
2557         //dprint("First place: ", ftos(firstPlace), "\n");
2558         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2559
2560         RandomSelection_Init();
2561         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2562                 if(i != firstPlace)
2563                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2564         secondPlace = RandomSelection_chosen_float;
2565         secondPlaceVotes = RandomSelection_best_priority;
2566         //dprint("Second place: ", ftos(secondPlace), "\n");
2567         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2568
2569         if(firstPlace == -1)
2570                 error("No first place in map vote... WTF?");
2571
2572         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2573                 return MapVote_Finished(firstPlace);
2574
2575         if(mapvote_keeptwotime)
2576                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2577                 {
2578                         float didntvote;
2579                         MapVote_TouchMask();
2580                         mapvote_message = "Now decide between the TOP TWO!";
2581                         mapvote_keeptwotime = 0;
2582                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2583                         result = strcat(result, ":", ftos(firstPlaceVotes));
2584                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2585                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2586                         didntvote = mapvote_voters;
2587                         for(i = 0; i < mapvote_count; ++i)
2588                                 if(mapvote_maps[i] != "")
2589                                 {
2590                                         didntvote -= mapvote_selections[i];
2591                                         if(i != firstPlace)
2592                                                 if(i != secondPlace)
2593                                                 {
2594                                                         result = strcat(result, ":", mapvote_maps[i]);
2595                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2596                                                         if(i < mapvote_count_real)
2597                                                         {
2598                                                                 strunzone(mapvote_maps[i]);
2599                                                                 mapvote_maps[i] = "";
2600                                                                 strunzone(mapvote_maps_pakfile[i]);
2601                                                                 mapvote_maps_pakfile[i] = "";
2602                                                         }
2603                                                 }
2604                                 }
2605                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2606                         if(autocvar_sv_eventlog)
2607                                 GameLogEcho(result);
2608                 }
2609
2610         return FALSE;
2611 }
2612 void MapVote_Tick()
2613 {
2614         float keeptwo;
2615         float totalvotes;
2616
2617         keeptwo = mapvote_keeptwotime;
2618         MapVote_CheckRules_1(); // count
2619         if(MapVote_CheckRules_2()) // decide
2620                 return;
2621
2622         totalvotes = 0;
2623         FOR_EACH_REALCLIENT(other)
2624         {
2625                 // hide scoreboard again
2626                 if(other.health != 2342)
2627                 {
2628                         other.health = 2342;
2629                         other.impulse = 0;
2630                         if(IS_REAL_CLIENT(other))
2631                         {
2632                                 msg_entity = other;
2633                                 WriteByte(MSG_ONE, SVC_FINALE);
2634                                 WriteString(MSG_ONE, "");
2635                         }
2636                 }
2637
2638                 // clear possibly invalid votes
2639                 if(mapvote_maps[other.mapvote - 1] == "")
2640                         other.mapvote = 0;
2641                 // use impulses as new vote
2642                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2643                         if(mapvote_maps[other.impulse - 1] != "")
2644                         {
2645                                 other.mapvote = other.impulse;
2646                                 MapVote_TouchVotes(other);
2647                         }
2648                 other.impulse = 0;
2649
2650                 if(other.mapvote)
2651                         ++totalvotes;
2652         }
2653
2654         MapVote_CheckRules_1(); // just count
2655 }
2656 void MapVote_Start()
2657 {
2658         if(mapvote_run)
2659                 return;
2660
2661         // wait for stats to be sent first
2662         if(!playerstats_waitforme)
2663                 return;
2664
2665         MapInfo_Enumerate();
2666         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2667                 mapvote_run = TRUE;
2668 }
2669 void MapVote_Think()
2670 {
2671         if(!mapvote_run)
2672                 return;
2673
2674         if(alreadychangedlevel)
2675                 return;
2676
2677         if(time < mapvote_nextthink)
2678                 return;
2679         //dprint("tick\n");
2680
2681         mapvote_nextthink = time + 0.5;
2682
2683         if(!mapvote_initialized)
2684         {
2685                 if(autocvar_rescan_pending == 1)
2686                 {
2687                         cvar_set("rescan_pending", "2");
2688                         localcmd("fs_rescan\nrescan_pending 3\n");
2689                         return;
2690                 }
2691                 else if(autocvar_rescan_pending == 2)
2692                 {
2693                         return;
2694                 }
2695                 else if(autocvar_rescan_pending == 3)
2696                 {
2697                         // now build missing mapinfo files
2698                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2699                                 return;
2700
2701                         // we're done, start the timer
2702                         cvar_set("rescan_pending", "0");
2703                 }
2704
2705                 mapvote_initialized = TRUE;
2706                 if(DoNextMapOverride(0))
2707                         return;
2708                 if(!autocvar_g_maplist_votable || player_count <= 0)
2709                 {
2710                         GotoNextMap(0);
2711                         return;
2712                 }
2713                 MapVote_Init();
2714         }
2715
2716         MapVote_Tick();
2717 }
2718
2719 string GotoMap(string m)
2720 {
2721         if(!MapInfo_CheckMap(m))
2722                 return "The map you chose is not available on this server.";
2723         cvar_set("nextmap", m);
2724         cvar_set("timelimit", "-1");
2725         if(mapvote_initialized || alreadychangedlevel)
2726         {
2727                 if(DoNextMapOverride(0))
2728                         return "Map switch initiated.";
2729                 else
2730                         return "Hm... no. For some reason I like THIS map more.";
2731         }
2732         else
2733                 return "Map switch will happen after scoreboard.";
2734 }
2735
2736
2737 void EndFrame()
2738 {
2739         float altime;
2740         FOR_EACH_REALCLIENT(self)
2741         {
2742                 if(IS_SPEC(self))
2743                 {
2744                         if(self.enemy.typehitsound)
2745                                 self.typehit_time = time;
2746                         else if(self.enemy.hitsound)
2747                                 self.hit_time = time;
2748                 }
2749                 else
2750                 {
2751                         if(self.typehitsound)
2752                                 self.typehit_time = time;
2753                         else if(self.hitsound)
2754                                 self.hit_time = time;
2755                 }
2756         }
2757         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2758         // add 1 frametime because after this, engine SV_Physics
2759         // increases time by a frametime and then networks the frame
2760         // add another frametime because client shows everything with
2761         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2762         // needed!
2763         FOR_EACH_CLIENT(self)
2764         {
2765                 self.hitsound = FALSE;
2766                 self.typehitsound = FALSE;
2767                 antilag_record(self, altime);
2768         }
2769 }
2770
2771
2772 /*
2773  * RedirectionThink:
2774  * returns TRUE if redirecting
2775  */
2776 float redirection_timeout;
2777 float redirection_nextthink;
2778 float RedirectionThink()
2779 {
2780         float clients_found;
2781
2782         if(redirection_target == "")
2783                 return FALSE;
2784
2785         if(!redirection_timeout)
2786         {
2787                 cvar_set("sv_public", "-2");
2788                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2789                 if(redirection_target == "self")
2790                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2791                 else
2792                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2793         }
2794
2795         if(time < redirection_nextthink)
2796                 return TRUE;
2797
2798         redirection_nextthink = time + 1;
2799
2800         clients_found = 0;
2801         FOR_EACH_REALCLIENT(self)
2802         {
2803                 // TODO add timer
2804                 print("Redirecting: sending connect command to ", self.netname, "\n");
2805                 if(redirection_target == "self")
2806                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2807                 else
2808                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2809                 ++clients_found;
2810         }
2811
2812         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2813
2814         if(time > redirection_timeout || clients_found == 0)
2815                 localcmd("\nwait; wait; wait; quit\n");
2816
2817         return TRUE;
2818 }
2819
2820 void TargetMusic_RestoreGame();
2821 void RestoreGame()
2822 {
2823         // Loaded from a save game
2824         // some things then break, so let's work around them...
2825
2826         // Progs DB (capture records)
2827         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2828
2829         // Mapinfo
2830         MapInfo_Shutdown();
2831         MapInfo_Enumerate();
2832         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2833         WeaponStats_Init();
2834
2835         TargetMusic_RestoreGame();
2836 }
2837
2838 void Shutdown()
2839 {
2840         entity e;
2841
2842         gameover = 2;
2843
2844         if(world_initialized > 0)
2845         {
2846                 world_initialized = 0;
2847                 print("Saving persistent data...\n");
2848                 Ban_SaveBans();
2849
2850                 PlayerStats_EndMatch(0);
2851                 FOR_EACH_CLIENT(e)
2852                         PlayerStats_AddGlobalInfo(e);
2853                 PlayerStats_Shutdown();
2854
2855                 if(!cheatcount_total)
2856                 {
2857                         if(autocvar_sv_db_saveasdump)
2858                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2859                         else
2860                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2861                 }
2862                 if(autocvar_developer)
2863                 {
2864                         if(autocvar_sv_db_saveasdump)
2865                                 db_dump(TemporaryDB, "server-temp.db");
2866                         else
2867                                 db_save(TemporaryDB, "server-temp.db");
2868                 }
2869                 CheatShutdown(); // must be after cheatcount check
2870                 db_close(ServerProgsDB);
2871                 db_close(TemporaryDB);
2872                 print("done!\n");
2873                 // tell the bot system the game is ending now
2874                 bot_endgame();
2875
2876                 WeaponStats_Shutdown();
2877                 MapInfo_Shutdown();
2878         }
2879         else if(world_initialized == 0)
2880         {
2881                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2882         }
2883 }