qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_runematch");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("g_runematch_point_leadlimit");
 319                 BADCVAR("leadlimit_and_fraglimit");
 320                 BADCVAR("leadlimit_override");
 321                 BADCVAR("pausable");
 322                 BADCVAR("sv_allow_fullbright");
 323                 BADCVAR("sv_checkforpacketsduringsleep");
 324                 BADCVAR("sv_fraginfo");
 325                 BADCVAR("sv_timeout");
 326                 BADPREFIX("sv_timeout_");
 327                 BADCVAR("welcome_message_time");
 328                 BADPREFIX("crypto_");
 329                 BADPREFIX("g_chat_");
 330                 BADPREFIX("g_ctf_captimerecord_");
 331                 BADPREFIX("g_maplist_votable_");
 332                 BADPREFIX("net_");
 333                 BADPREFIX("prvm_");
 334                 BADPREFIX("skill_");
 335                 BADPREFIX("sv_cullentities_");
 336                 BADPREFIX("sv_fraginfo_");
 337                 BADPREFIX("sv_maxidle_");
 338                 BADPREFIX("sv_vote_");
 339                 BADPREFIX("timelimit_");
 340                 BADCVAR("gameversion");
 341                 BADPREFIX("gameversion_");
 342                 BADCVAR("sv_namechangetimer");
 343 #ifndef NO_LEGACY_NETWORKING
 344                 BADCVAR("sv_use_csqc_players"); // transition
 345 #endif
 346
 347                 // allowed changes to server admins (please sync this to server.cfg)
 348                 // vi commands:
 349                 //   :/"impure"/,$d
 350                 //   :g!,^\/\/[^ /],d
 351                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 352                 //   :%!sort
 353                 // yes, this does contain some redundant stuff, don't really care
 354                 BADCVAR("bot_config_file");
 355                 BADCVAR("bot_number");
 356                 BADCVAR("bot_prefix");
 357                 BADCVAR("bot_suffix");
 358                 BADCVAR("capturelimit_override");
 359                 BADCVAR("fraglimit_override");
 360                 BADCVAR("gametype");
 361                 BADCVAR("g_antilag");
 362                 BADCVAR("g_balance_teams");
 363                 BADCVAR("g_balance_teams_prevent_imbalance");
 364                 BADCVAR("g_balance_teams_scorefactor");
 365                 BADCVAR("g_ban_sync_trusted_servers");
 366                 BADCVAR("g_ban_sync_uri");
 367                 BADCVAR("g_ctf_ignore_frags");
 368                 BADCVAR("g_domination_point_limit");
 369                 BADCVAR("g_friendlyfire");
 370                 BADCVAR("g_fullbrightitems");
 371                 BADCVAR("g_fullbrightplayers");
 372                 BADCVAR("g_keyhunt_point_limit");
 373                 BADCVAR("g_keyhunt_teams_override");
 374                 BADCVAR("g_lms_lives_override");
 375                 BADCVAR("g_maplist");
 376                 BADCVAR("g_maplist_check_waypoints");
 377                 BADCVAR("g_maplist_mostrecent_count");
 378                 BADCVAR("g_maplist_shuffle");
 379                 BADCVAR("g_maplist_votable");
 380                 BADCVAR("g_maplist_votable_abstain");
 381                 BADCVAR("g_maplist_votable_nodetail");
 382                 BADCVAR("g_maplist_votable_suggestions");
 383                 BADCVAR("g_maxplayers");
 384                 BADCVAR("g_mirrordamage");
 385                 BADCVAR("g_nexball_goallimit");
 386                 BADCVAR("g_powerups");
 387                 BADCVAR("g_runematch_point_limit");
 388                 BADCVAR("g_start_delay");
 389                 BADCVAR("g_warmup");
 390                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 391                 BADCVAR("hostname");
 392                 BADCVAR("log_file");
 393                 BADCVAR("maxplayers");
 394                 BADCVAR("minplayers");
 395                 BADCVAR("net_address");
 396                 BADCVAR("port");
 397                 BADCVAR("rcon_password");
 398                 BADCVAR("rcon_restricted_commands");
 399                 BADCVAR("rcon_restricted_password");
 400                 BADCVAR("skill");
 401                 BADCVAR("sv_adminnick");
 402                 BADCVAR("sv_autoscreenshot");
 403                 BADCVAR("sv_autotaunt");
 404                 BADCVAR("sv_curl_defaulturl");
 405                 BADCVAR("sv_defaultcharacter");
 406                 BADCVAR("sv_defaultplayercolors");
 407                 BADCVAR("sv_defaultplayermodel");
 408                 BADCVAR("sv_defaultplayerskin");
 409                 BADCVAR("sv_maxidle");
 410                 BADCVAR("sv_maxrate");
 411                 BADCVAR("sv_motd");
 412                 BADCVAR("sv_public");
 413                 BADCVAR("sv_ready_restart");
 414                 BADCVAR("sv_status_privacy");
 415                 BADCVAR("sv_taunt");
 416                 BADCVAR("sv_vote_call");
 417                 BADCVAR("sv_vote_commands");
 418                 BADCVAR("sv_vote_majority_factor");
 419                 BADCVAR("sv_vote_master");
 420                 BADCVAR("sv_vote_master_commands");
 421                 BADCVAR("sv_vote_master_password");
 422                 BADCVAR("sv_vote_simple_majority_factor");
 423                 BADCVAR("sys_ticrate");
 424                 BADCVAR("teamplay_mode");
 425                 BADCVAR("timelimit_override");
 426                 BADCVAR("g_spawnshieldtime");
 427                 BADPREFIX("g_warmup_");
 428                 BADPREFIX("sv_ready_restart_");
 429
 430                 // mutators that announce themselves properly to the server browser
 431                 BADCVAR("g_minstagib");
 432                 BADCVAR("g_new_toys");
 433                 BADCVAR("g_nix");
 434
 435                 if(autocvar_g_minstagib)
 436                 {
 437                         BADCVAR("g_grappling_hook");
 438                         BADCVAR("g_jetpack");
 439                 }
 440 #undef BADPREFIX
 441 #undef BADCVAR
 442
 443                 if(pureadding)
 444                 {
 445                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 446                         if(strlen(cvar_purechanges) > 16384)
 447                         {
 448                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 449                                 pureadding = 0;
 450                         }
 451                 }
 452                 ++cvar_purechanges_count;
 453                 // WARNING: this variable is used for the server list
 454                 // NEVER dare to skip this code!
 455                 // Hacks to intentionally appearing as "pure server" even though you DO have
 456                 // modified settings may be punished by removal from the server list.
 457                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 458                 // though.
 459         }
 460         buf_del(h);
 461         if(cvar_changes == "")
 462                 cvar_changes = "// this server runs at default server settings\n";
 463         else
 464                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 465         cvar_changes = strzone(cvar_changes);
 466         if(cvar_purechanges == "")
 467                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 468         else
 469                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 470         cvar_purechanges = strzone(cvar_purechanges);
 471 }
 472
 473 void detect_maptype()
 474 {
 475 #if 0
 476         vector o, v;
 477         float i;
 478
 479         for(;;)
 480         {
 481                 o = world.mins;
 482                 o_x += random() * (world.maxs_x - world.mins_x);
 483                 o_y += random() * (world.maxs_y - world.mins_y);
 484                 o_z += random() * (world.maxs_z - world.mins_z);
 485
 486                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 487                 if(trace_fraction == 1)
 488                         continue;
 489
 490                 v = trace_endpos;
 491
 492                 for(i = 0; i < 64; i += 4)
 493                 {
 494                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 495         if(trace_fraction == 1)
 496                 continue;
 497                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 498                 }
 499
 500                 break;
 501         }
 502 #endif
 503 }
 504
 505 entity randomseed;
 506 float RandomSeed_Send(entity to, float sf)
 507 {
 508         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 509         WriteShort(MSG_ENTITY, self.cnt);
 510         return TRUE;
 511 }
 512 void RandomSeed_Think()
 513 {
 514         self.cnt = bound(0, floor(random() * 65536), 65535);
 515         self.nextthink = time + 5;
 516
 517         self.SendFlags |= 1;
 518 }
 519 void RandomSeed_Spawn()
 520 {
 521         randomseed = spawn();
 522         randomseed.think = RandomSeed_Think;
 523         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 524
 525         entity oldself;
 526         oldself = self;
 527         self = randomseed;
 528         self.think(); // sets random seed and nextthink
 529         self = oldself;
 530 }
 531
 532 void spawnfunc___init_dedicated_server(void)
 533 {
 534         // handler for _init/_init map (only for dedicated server initialization)
 535
 536         world_initialized = -1; // don't complain
 537         cvar = cvar_normal;
 538         cvar_string = cvar_string_normal;
 539         cvar_set = cvar_set_normal;
 540
 541         remove = remove_unsafely;
 542
 543         entity e;
 544         e = spawn();
 545         e.think = GotoFirstMap;
 546         e.nextthink = time; // this is usually 1 at this point
 547
 548         e = spawn();
 549         e.classname = "info_player_deathmatch"; // safeguard against player joining
 550
 551         self.classname = "worldspawn"; // safeguard against various stuff ;)
 552
 553         // needs to be done so early because of the constants they create
 554         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 555         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 556         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 557         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 558
 559         MapInfo_Enumerate();
 560         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 561 }
 562
 563 void Map_MarkAsRecent(string m);
 564 float world_already_spawned;
 565 void Nagger_Init();
 566 void ClientInit_Spawn();
 567 void WeaponStats_Init();
 568 void WeaponStats_Shutdown();
 569 void spawnfunc_worldspawn (void)
 570 {
 571         float fd, l, i, j, n;
 572         string s, col;
 573
 574         cvar = cvar_normal;
 575         cvar_string = cvar_string_normal;
 576         cvar_set = cvar_set_normal;
 577
 578         if(world_already_spawned)
 579                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 580         world_already_spawned = TRUE;
 581
 582         remove = remove_safely; // during spawning, watch what you remove!
 583
 584         check_unacceptable_compiler_bugs();
 585
 586         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 587
 588         compressShortVector_init();
 589
 590         allowed_to_spawn = TRUE;
 591
 592         entity head;
 593         head = nextent(world);
 594         maxclients = 0;
 595         while(head)
 596         {
 597                 ++maxclients;
 598                 head = nextent(head);
 599         }
 600
 601         // needs to be done so early because of the constants they create
 602         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 603         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 604         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 605         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 606
 607         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 608
 609         TemporaryDB = db_create();
 610
 611         // 0 normal
 612         lightstyle(0, "m");
 613
 614         // 1 FLICKER (first variety)
 615         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 616
 617         // 2 SLOW STRONG PULSE
 618         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 619
 620         // 3 CANDLE (first variety)
 621         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 622
 623         // 4 FAST STROBE
 624         lightstyle(4, "mamamamamama");
 625
 626         // 5 GENTLE PULSE 1
 627         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 628
 629         // 6 FLICKER (second variety)
 630         lightstyle(6, "nmonqnmomnmomomno");
 631
 632         // 7 CANDLE (second variety)
 633         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 634
 635         // 8 CANDLE (third variety)
 636         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 637
 638         // 9 SLOW STROBE (fourth variety)
 639         lightstyle(9, "aaaaaaaazzzzzzzz");
 640
 641         // 10 FLUORESCENT FLICKER
 642         lightstyle(10, "mmamammmmammamamaaamammma");
 643
 644         // 11 SLOW PULSE NOT FADE TO BLACK
 645         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 646
 647         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 648
 649         // 63 testing
 650         lightstyle(63, "a");
 651
 652         if(autocvar_g_campaign)
 653                 CampaignPreInit();
 654
 655         Map_MarkAsRecent(mapname);
 656
 657         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 658
 659         precache_model ("null"); // we need this one before InitGameplayMode
 660         InitGameplayMode();
 661         readlevelcvars();
 662         GrappleHookInit();
 663         ElectroInit();
 664         LaserInit();
 665
 666         player_count = 0;
 667         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 668         if(bot_waypoints_for_items == 1)
 669                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 670                         bot_waypoints_for_items = 0;
 671
 672         precache();
 673
 674         WaypointSprite_Init();
 675
 676         //if (g_domination)
 677         //      dom_init();
 678
 679         GameLogInit(); // prepare everything
 680         // NOTE for matchid:
 681         // changing the logic generating it is okay. But:
 682         // it HAS to stay <= 64 chars
 683         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 684         if(autocvar_sv_eventlog)
 685         {
 686                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 687                 matchid = strzone(s);
 688
 689                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 690                 s = ":gameinfo:mutators:LIST";
 691
 692                 ret_string = s;
 693                 MUTATOR_CALLHOOK(BuildMutatorsString);
 694                 s = ret_string;
 695
 696                 // simple, probably not good in the mutator system
 697                 if(autocvar_g_grappling_hook)
 698                         s = strcat(s, ":grappling_hook");
 699
 700                 // initialiation stuff, not good in the mutator system
 701                 if(!autocvar_g_use_ammunition)
 702                         s = strcat(s, ":no_use_ammunition");
 703
 704                 // initialiation stuff, not good in the mutator system
 705                 if(autocvar_g_pickup_items == 0)
 706                         s = strcat(s, ":no_pickup_items");
 707                 if(autocvar_g_pickup_items > 0)
 708                         s = strcat(s, ":pickup_items");
 709
 710                 // initialiation stuff, not good in the mutator system
 711                 if(autocvar_g_weaponarena != "0")
 712                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 713
 714                 // TODO to mutator system
 715                 if(autocvar_g_norecoil)
 716                         s = strcat(s, ":norecoil");
 717
 718                 // TODO to mutator system
 719                 if(autocvar_g_midair)
 720                         s = strcat(s, ":midair");
 721
 722                 // TODO to mutator system
 723                 if(autocvar_g_minstagib)
 724                         s = strcat(s, ":minstagib");
 725
 726                 // TODO to mutator system
 727                 if(autocvar_g_powerups == 0)
 728                         s = strcat(s, ":no_powerups");
 729                 if(autocvar_g_powerups > 0)
 730                         s = strcat(s, ":powerups");
 731
 732                 GameLogEcho(s);
 733                 GameLogEcho(":gameinfo:end");
 734         }
 735         else
 736                 matchid = strzone(ftos(random()));
 737
 738         cvar_set("nextmap", "");
 739
 740         SetDefaultAlpha();
 741
 742         if(autocvar_g_campaign)
 743                 CampaignPostInit();
 744
 745         fteqcc_testbugs();
 746
 747         Ban_LoadBans();
 748
 749         MapInfo_Enumerate();
 750         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 751
 752         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 753         {
 754                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 755                 if(fd != -1)
 756                 {
 757                         while((s = fgets(fd)))
 758                         {
 759                                 l = tokenize_console(s);
 760                                 if(l < 2)
 761                                         continue;
 762                                 if(argv(0) == "cd")
 763                                 {
 764                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 765                                         print("  cdtrack ", argv(2), "\n");
 766                                 }
 767                                 else if(argv(0) == "fog")
 768                                 {
 769                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 770                                         print("  \"fog\" \"", s, "\"\n");
 771                                 }
 772                                 else if(argv(0) == "set")
 773                                 {
 774                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 775                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 776                                 }
 777                                 else if(argv(0) != "//")
 778                                 {
 779                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 780                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 781                                 }
 782                         }
 783                         fclose(fd);
 784                 }
 785         }
 786
 787         WeaponStats_Init();
 788
 789         WEPSET_ADDSTAT();
 790         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 791         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 792         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 793         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 794         Nagger_Init();
 795
 796         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 797         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 798         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 799         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 800         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 801         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 802         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 803         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 804         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 805         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 806         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 807         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 808         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 809
 810         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 811         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 812
 813         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 814
 815         if(g_ca || g_freezetag)
 816         {
 817                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 818                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 819                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 820                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 821         }
 822         if(g_freezetag)
 823         {
 824                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 825                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 826         }
 827
 828         // g_movementspeed hack
 829         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 830         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 831         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 832         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 833
 834         // secrets
 835         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 836         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 837
 838         // misc
 839         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 840
 841         next_pingtime = time + 5;
 842
 843         detect_maptype();
 844
 845         // set up information replies for clients and server to use
 846         lsmaps_reply = "^7Maps available: ";
 847         lsnewmaps_reply = "^7Maps without a record set: ";
 848         for(i = 0, j = 0; i < MapInfo_count; ++i)
 849         {
 850                 if(MapInfo_Get_ByID(i))
 851                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 852                         {
 853                                 if(mod(i, 2))
 854                                         col = "^2";
 855                                 else
 856                                         col = "^3";
 857
 858                                 ++j;
 859
 860                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 861
 862                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 863                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 864                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 865                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 866                         }
 867         }
 868
 869         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 870         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 871
 872         maplist_reply = "^7Maps in list: ";
 873         n = tokenize_console(autocvar_g_maplist);
 874         for(i = 0, j = 0; i < n; ++i)
 875         {
 876                 if(MapInfo_CheckMap(argv(i)))
 877                 {
 878                         if(mod(j, 2))
 879                                 col = "^2";
 880                         else
 881                                 col = "^3";
 882                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 883                         ++j;
 884                 }
 885         }
 886         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 887         MapInfo_ClearTemps();
 888
 889         for(i = 0; i < 10; ++i)
 890         {
 891                 s = getrecords(i);
 892                 if (s)
 893                         records_reply[i] = strzone(s);
 894         }
 895
 896         ladder_reply = strzone(getladder());
 897
 898         rankings_reply = strzone(getrankings());
 899
 900         // begin other init
 901         ClientInit_Spawn();
 902         RandomSeed_Spawn();
 903         PingPLReport_Spawn();
 904
 905         CheatInit();
 906
 907         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 908
 909         // fill sv_curl_serverpackages from .serverpackage files
 910         if(autocvar_sv_curl_serverpackages_auto)
 911         {
 912                 s = "";
 913                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 914                 for(i = 0; i < n; ++i)
 915                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 916                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 917                                 s = strcat(s, " ", argv(i));
 918                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 919                 if(fd >= 0)
 920                 {
 921                         j = search_getsize(fd);
 922                         for(i = 0; i < j; ++i)
 923                                 s = strcat(s, " ", search_getfilename(fd, i));
 924                         search_end(fd);
 925                 }
 926                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 927                 if(fd >= 0)
 928                 {
 929                         j = search_getsize(fd);
 930                         for(i = 0; i < j; ++i)
 931                                 s = strcat(s, " ", search_getfilename(fd, i));
 932                         search_end(fd);
 933                 }
 934                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 935         }
 936
 937         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 938         modname = "Xonotic";
 939         // physics/balance/config changes that count as mod
 940         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 941                 modname = cvar_string("g_mod_physics");
 942         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 943                 modname = cvar_string("g_mod_balance");
 944         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 945                 modname = cvar_string("g_mod_config");
 946         // weird mutators that deserve to count as mod
 947         if(autocvar_g_minstagib)
 948                 modname = "MinstaGib";
 949         // extra mutators that deserve to count as mod
 950         MUTATOR_CALLHOOK(SetModname);
 951         // weird game types that deserve to count as mod
 952         if(g_cts)
 953                 modname = "CTS";
 954         // save it for later
 955         modname = strzone(modname);
 956
 957         WinningConditionHelper(); // set worldstatus
 958
 959         world_initialized = 1;
 960 }
 961
 962 void spawnfunc_light (void)
 963 {
 964         //makestatic (self); // Who the f___ did that?
 965         remove(self);
 966 }
 967
 968 string GetGametype()
 969 {
 970         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 971 }
 972
 973 string getmapname_stored;
 974 string GetMapname()
 975 {
 976         return mapname;
 977 }
 978
 979 float Map_Count, Map_Current;
 980 string Map_Current_Name;
 981
 982 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 983 float GetMaplistPosition()
 984 {
 985         float pos, idx;
 986         string map;
 987
 988         map = GetMapname();
 989         idx = autocvar_g_maplist_index;
 990
 991         if(idx >= 0)
 992                 if(idx < Map_Count)
 993                         if(map == argv(idx))
 994                                 return idx;
 995
 996         for(pos = 0; pos < Map_Count; ++pos)
 997                 if(map == argv(pos))
 998                         return pos;
 999
1000         // resume normal maplist rotation if current map is not in g_maplist
1001         return idx;
1002 }
1003
1004 float MapHasRightSize(string map)
1005 {
1006         float fh;
1007         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1008         if(autocvar_g_maplist_check_waypoints)
1009         {
1010                 dprint("checkwp "); dprint(map);
1011                 if(!fexists(strcat("maps/", map, ".waypoints")))
1012                 {
1013                         dprint(": no waypoints\n");
1014                         return FALSE;
1015                 }
1016                 dprint(": has waypoints\n");
1017         }
1018
1019         // open map size restriction file
1020         dprint("opensize "); dprint(map);
1021         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1022         if(fh >= 0)
1023         {
1024                 float mapmin, mapmax;
1025                 dprint(": ok, ");
1026                 mapmin = stof(fgets(fh));
1027                 mapmax = stof(fgets(fh));
1028                 fclose(fh);
1029                 if(player_count < mapmin)
1030                 {
1031                         dprint("not enough\n");
1032                         return FALSE;
1033                 }
1034                 if(player_count > mapmax)
1035                 {
1036                         dprint("too many\n");
1037                         return FALSE;
1038                 }
1039                 dprint("right size\n");
1040                 return TRUE;
1041         }
1042         dprint(": not found\n");
1043         return TRUE;
1044 }
1045
1046 string Map_Filename(float position)
1047 {
1048         return strcat("maps/", argv(position), ".bsp");
1049 }
1050
1051 string strwords(string s, float w)
1052 {
1053         float endpos;
1054         for(endpos = 0; w && endpos >= 0; --w)
1055                 endpos = strstrofs(s, " ", endpos + 1);
1056         if(endpos < 0)
1057                 return s;
1058         else
1059                 return substring(s, 0, endpos);
1060 }
1061
1062 float strhasword(string s, string w)
1063 {
1064         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1065 }
1066
1067 void Map_MarkAsRecent(string m)
1068 {
1069         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1070 }
1071
1072 float Map_IsRecent(string m)
1073 {
1074         return strhasword(autocvar_g_maplist_mostrecent, m);
1075 }
1076
1077 float Map_Check(float position, float pass)
1078 {
1079         string filename;
1080         string map_next;
1081         map_next = argv(position);
1082         if(pass <= 1)
1083         {
1084                 if(Map_IsRecent(map_next))
1085                         return 0;
1086         }
1087         filename = Map_Filename(position);
1088         if(MapInfo_CheckMap(map_next))
1089         {
1090                 if(pass == 2)
1091                         return 1;
1092                 if(MapHasRightSize(map_next))
1093                         return 1;
1094                 return 0;
1095         }
1096         else
1097                 dprint( "Couldn't select '", filename, "'..\n" );
1098
1099         return 0;
1100 }
1101
1102 void Map_Goto_SetStr(string nextmapname)
1103 {
1104         if(getmapname_stored != "")
1105                 strunzone(getmapname_stored);
1106         if(nextmapname == "")
1107                 getmapname_stored = "";
1108         else
1109                 getmapname_stored = strzone(nextmapname);
1110 }
1111
1112 void Map_Goto_SetFloat(float position)
1113 {
1114         cvar_set("g_maplist_index", ftos(position));
1115         Map_Goto_SetStr(argv(position));
1116 }
1117
1118 void Map_Goto(float reinit)
1119 {
1120         MapInfo_LoadMap(getmapname_stored, reinit);
1121 }
1122
1123 // return codes of map selectors:
1124 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1125 //   -2 = permanent failure
1126 float() MaplistMethod_Iterate = // usual method
1127 {
1128         float pass, i;
1129
1130         for(pass = 1; pass <= 2; ++pass)
1131         {
1132                 for(i = 1; i < Map_Count; ++i)
1133                 {
1134                         float mapindex;
1135                         mapindex = mod(i + Map_Current, Map_Count);
1136                         if(Map_Check(mapindex, pass))
1137                                 return mapindex;
1138                 }
1139         }
1140         return -1;
1141 }
1142
1143 float() MaplistMethod_Repeat = // fallback method
1144 {
1145         if(Map_Check(Map_Current, 2))
1146                 return Map_Current;
1147         return -2;
1148 }
1149
1150 float() MaplistMethod_Random = // random map selection
1151 {
1152         float i, imax;
1153
1154         imax = 42;
1155
1156         for(i = 0; i <= imax; ++i)
1157         {
1158                 float mapindex;
1159                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1160                 if(Map_Check(mapindex, 1))
1161                         return mapindex;
1162         }
1163         return -1;
1164 }
1165
1166 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1167 // the exponent sets a bias on the map selection:
1168 // the higher the exponent, the less likely "shortly repeated" same maps are
1169 {
1170         float i, j, imax, insertpos;
1171
1172         imax = 42;
1173
1174         for(i = 0; i <= imax; ++i)
1175         {
1176                 string newlist;
1177
1178                 // now reinsert this at another position
1179                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1180                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1181                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1182                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1183
1184                 // insert the current map there
1185                 newlist = "";
1186                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1187                         newlist = strcat(newlist, " ", argv(j));
1188                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1189                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1190                         newlist = strcat(newlist, " ", argv(j));
1191                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1192                 cvar_set("g_maplist", newlist);
1193                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1194
1195                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1196                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1197                 if(Map_Check(Map_Current, 1))
1198                         return Map_Current;
1199         }
1200         return -1;
1201 }
1202
1203 void Maplist_Init()
1204 {
1205         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1206         if(Map_Count == 0)
1207         {
1208                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1209                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1210                 if(autocvar_g_maplist_shuffle)
1211                         ShuffleMaplist();
1212                 localcmd("\nmenu_cmd sync\n");
1213                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1214         }
1215         if(Map_Count == 0)
1216                 error("empty maplist, cannot select a new map");
1217         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1218
1219         if(Map_Current_Name)
1220                 strunzone(Map_Current_Name);
1221         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1222         // this may or may not be correct, but who cares, in the worst case a map
1223         // isn't chosen in the first pass that should have been
1224 }
1225
1226 string GetNextMap()
1227 {
1228         float nextMap;
1229
1230         Maplist_Init();
1231         nextMap = -1;
1232
1233         if(nextMap == -1)
1234                 if(autocvar_g_maplist_shuffle > 0)
1235                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1236
1237         if(nextMap == -1)
1238                 if(autocvar_g_maplist_selectrandom)
1239                         nextMap = MaplistMethod_Random();
1240
1241         if(nextMap == -1)
1242                 nextMap = MaplistMethod_Iterate();
1243
1244         if(nextMap == -1)
1245                 nextMap = MaplistMethod_Repeat();
1246
1247         if(nextMap >= 0)
1248         {
1249                 Map_Goto_SetFloat(nextMap);
1250                 return getmapname_stored;
1251         }
1252
1253         return "";
1254 }
1255
1256 float DoNextMapOverride(float reinit)
1257 {
1258         if(autocvar_g_campaign)
1259         {
1260                 CampaignPostIntermission();
1261                 alreadychangedlevel = TRUE;
1262                 return TRUE;
1263         }
1264         if(autocvar_quit_when_empty)
1265         {
1266                 if(player_count <= currentbots)
1267                 {
1268                         localcmd("quit\n");
1269                         alreadychangedlevel = TRUE;
1270                         return TRUE;
1271                 }
1272         }
1273         if(autocvar_quit_and_redirect != "")
1274         {
1275                 redirection_target = strzone(autocvar_quit_and_redirect);
1276                 alreadychangedlevel = TRUE;
1277                 return TRUE;
1278         }
1279         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1280         {
1281                 localcmd("restart\n");
1282                 alreadychangedlevel = TRUE;
1283                 return TRUE;
1284         }
1285         if(autocvar_nextmap != "")
1286                 if(MapInfo_CheckMap(autocvar_nextmap))
1287                 {
1288                         Map_Goto_SetStr(autocvar_nextmap);
1289                         Map_Goto(reinit);
1290                         alreadychangedlevel = TRUE;
1291                         return TRUE;
1292                 }
1293         if(!reinit && autocvar_lastlevel)
1294         {
1295                 cvar_settemp_restore();
1296                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1297                 alreadychangedlevel = TRUE;
1298                 return TRUE;
1299         }
1300         return FALSE;
1301 }
1302
1303 void GotoNextMap(float reinit)
1304 {
1305         //string nextmap;
1306         //float n, nummaps;
1307         //string s;
1308         if (alreadychangedlevel)
1309                 return;
1310         alreadychangedlevel = TRUE;
1311
1312         {
1313                 string nextMap;
1314                 float allowReset;
1315
1316                 for(allowReset = 1; allowReset >= 0; --allowReset)
1317                 {
1318                         nextMap = GetNextMap();
1319                         if(nextMap != "")
1320                                 break;
1321
1322                         if(allowReset)
1323                         {
1324                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1325                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1326                                 if(autocvar_g_maplist_shuffle)
1327                                         ShuffleMaplist();
1328                                 localcmd("\nmenu_cmd sync\n");
1329                         }
1330                         else
1331                         {
1332                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1333                         }
1334                 }
1335                 Map_Goto(reinit);
1336         }
1337 }
1338
1339
1340 /*
1341 ============
1342 IntermissionThink
1343
1344 When the player presses attack or jump, change to the next level
1345 ============
1346 */
1347 .float autoscreenshot;
1348 void() MapVote_Start;
1349 void() MapVote_Think;
1350 float mapvote_initialized;
1351 void IntermissionThink()
1352 {
1353         FixIntermissionClient(self);
1354
1355         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1356         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1357
1358         if( (server_screenshot || client_screenshot)
1359                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1360         {
1361                 self.autoscreenshot = -1;
1362                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1363                 return;
1364         }
1365
1366         if (time < intermission_exittime)
1367                 return;
1368
1369         if(!mapvote_initialized)
1370                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1371                         return;
1372
1373         MapVote_Start();
1374 }
1375
1376 /*
1377 ============
1378 FindIntermission
1379
1380 Returns the entity to view from
1381 ============
1382 */
1383 /*
1384 entity FindIntermission()
1385 {
1386         local   entity spot;
1387         local   float cyc;
1388
1389 // look for info_intermission first
1390         spot = find (world, classname, "info_intermission");
1391         if (spot)
1392         {       // pick a random one
1393                 cyc = random() * 4;
1394                 while (cyc > 1)
1395                 {
1396                         spot = find (spot, classname, "info_intermission");
1397                         if (!spot)
1398                                 spot = find (spot, classname, "info_intermission");
1399                         cyc = cyc - 1;
1400                 }
1401                 return spot;
1402         }
1403
1404 // then look for the start position
1405         spot = find (world, classname, "info_player_start");
1406         if (spot)
1407                 return spot;
1408
1409 // testinfo_player_start is only found in regioned levels
1410         spot = find (world, classname, "testplayerstart");
1411         if (spot)
1412                 return spot;
1413
1414 // then look for the start position
1415         spot = find (world, classname, "info_player_deathmatch");
1416         if (spot)
1417                 return spot;
1418
1419         //objerror ("FindIntermission: no spot");
1420         return world;
1421 }
1422 */
1423
1424 /*
1425 ===============================================================================
1426
1427 RULES
1428
1429 ===============================================================================
1430 */
1431
1432 void DumpStats(float final)
1433 {
1434         float file;
1435         string s;
1436         float to_console;
1437         float to_eventlog;
1438         float to_file;
1439         float i;
1440
1441         to_console = autocvar_sv_logscores_console;
1442         to_eventlog = autocvar_sv_eventlog;
1443         to_file = autocvar_sv_logscores_file;
1444
1445         if(!final)
1446         {
1447                 to_console = TRUE; // always print printstats replies
1448                 to_eventlog = FALSE; // but never print them to the event log
1449         }
1450
1451         if(to_eventlog)
1452                 if(autocvar_sv_eventlog_console)
1453                         to_console = FALSE; // otherwise we get the output twice
1454
1455         if(final)
1456                 s = ":scores:";
1457         else
1458                 s = ":status:";
1459         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1460
1461         if(to_console)
1462                 print(s, "\n");
1463         if(to_eventlog)
1464                 GameLogEcho(s);
1465
1466         file = -1;
1467         if(to_file)
1468         {
1469                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1470                 if(file == -1)
1471                         to_file = FALSE;
1472                 else
1473                         fputs(file, strcat(s, "\n"));
1474         }
1475
1476         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1477         if(to_console)
1478                 print(s, "\n");
1479         if(to_eventlog)
1480                 GameLogEcho(s);
1481         if(to_file)
1482                 fputs(file, strcat(s, "\n"));
1483
1484         FOR_EACH_CLIENT(other)
1485         {
1486                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1487                 {
1488                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1489                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1490                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1491                                 s = strcat(s, ftos(other.team), ":");
1492                         else
1493                                 s = strcat(s, "spectator:");
1494
1495                         if(to_console)
1496                                 print(s, other.netname, "\n");
1497                         if(to_eventlog)
1498                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1499                         if(to_file)
1500                                 fputs(file, strcat(s, other.netname, "\n"));
1501                 }
1502         }
1503
1504         if(teamplay)
1505         {
1506                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1507                 if(to_console)
1508                         print(s, "\n");
1509                 if(to_eventlog)
1510                         GameLogEcho(s);
1511                 if(to_file)
1512                         fputs(file, strcat(s, "\n"));
1513
1514                 for(i = 1; i < 16; ++i)
1515                 {
1516                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1517                         s = strcat(s, ":", ftos(i));
1518                         if(to_console)
1519                                 print(s, "\n");
1520                         if(to_eventlog)
1521                                 GameLogEcho(s);
1522                         if(to_file)
1523                                 fputs(file, strcat(s, "\n"));
1524                 }
1525         }
1526
1527         if(to_console)
1528                 print(":end\n");
1529         if(to_eventlog)
1530                 GameLogEcho(":end");
1531         if(to_file)
1532         {
1533                 fputs(file, ":end\n");
1534                 fclose(file);
1535         }
1536 }
1537
1538 void FixIntermissionClient(entity e)
1539 {
1540         string s;
1541         if(!e.autoscreenshot) // initial call
1542         {
1543                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1544                 e.health = -2342;
1545                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1546                 e.solid = SOLID_NOT;
1547                 e.movetype = MOVETYPE_NONE;
1548                 e.takedamage = DAMAGE_NO;
1549                 if(e.weaponentity)
1550                 {
1551                         e.weaponentity.effects = EF_NODRAW;
1552                         if (e.weaponentity.weaponentity)
1553                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1554                 }
1555                 if(clienttype(e) == CLIENTTYPE_REAL)
1556                 {
1557                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1558                         s = autocvar_sv_intermission_cdtrack;
1559                         if(s != "")
1560                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1561                         msg_entity = e;
1562                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1563                 }
1564         }
1565 }
1566
1567 void minstagib_stop_countdown(entity e);
1568 /*
1569 go to the next level for deathmatch
1570 only called if a time or frag limit has expired
1571 */
1572 void NextLevel()
1573 {
1574         gameover = TRUE;
1575
1576         intermission_running = 1;
1577
1578 // enforce a wait time before allowing changelevel
1579         if(player_count > 0)
1580                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1581         else
1582                 intermission_exittime = -1;
1583
1584         /*
1585         WriteByte (MSG_ALL, SVC_CDTRACK);
1586         WriteByte (MSG_ALL, 3);
1587         WriteByte (MSG_ALL, 3);
1588         // done in FixIntermission
1589         */
1590
1591         //pos = FindIntermission ();
1592
1593         VoteReset();
1594
1595         DumpStats(TRUE);
1596
1597         // send statistics
1598         entity e;
1599         PlayerStats_EndMatch(1);
1600         FOR_EACH_CLIENT(e)
1601                 PlayerStats_AddGlobalInfo(e);
1602         PlayerStats_Shutdown();
1603         WeaponStats_Shutdown();
1604
1605         if(autocvar_sv_eventlog)
1606                 GameLogEcho(":gameover");
1607
1608         GameLogClose();
1609
1610         FOR_EACH_PLAYER(other) {
1611                 minstagib_stop_countdown(other);
1612                 FixIntermissionClient(other);
1613                 if(other.winning)
1614                         bprint(other.netname, " ^7wins.\n");
1615         }
1616
1617         if(autocvar_g_campaign)
1618                 CampaignPreIntermission();
1619
1620         MUTATOR_CALLHOOK(MatchEnd);
1621
1622         localcmd("\nsv_hook_gameend\n");
1623 }
1624
1625 /*
1626 ============
1627 CheckRules_Player
1628
1629 Exit deathmatch games upon conditions
1630 ============
1631 */
1632 void CheckRules_Player()
1633 {
1634         if (gameover)   // someone else quit the game already
1635                 return;
1636
1637         if(self.deadflag == DEAD_NO)
1638                 self.play_time += frametime;
1639
1640         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1641         //   (div0: and that in CheckRules_World please)
1642 }
1643
1644 float checkrules_equality;
1645 float checkrules_suddendeathwarning;
1646 float checkrules_suddendeathend;
1647 float checkrules_overtimesadded; //how many overtimes have been already added
1648
1649 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1650 float WINNING_YES = 1; // winner found
1651 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1652 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1653
1654 float InitiateSuddenDeath()
1655 {
1656         // Check first whether normal overtimes could be added before initiating suddendeath mode
1657         // - for this timelimit_overtime needs to be >0 of course
1658         // - also check the winning condition calculated in the previous frame and only add normal overtime
1659         //   again, if at the point at which timelimit would be extended again, still no winner was found
1660         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1661         {
1662                 return 1; // need to call InitiateOvertime later
1663         }
1664         else
1665         {
1666                 if(!checkrules_suddendeathend)
1667                 {
1668                         if(autocvar_g_campaign)
1669                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1670                         else
1671                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1672                         if(g_race && !g_race_qualifying)
1673                                 race_StartCompleting();
1674                 }
1675                 return 0;
1676         }
1677 }
1678
1679 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1680 {
1681         ++checkrules_overtimesadded;
1682         //add one more overtime by simply extending the timelimit
1683         float tl;
1684         tl = autocvar_timelimit;
1685         tl += autocvar_timelimit_overtime;
1686         cvar_set("timelimit", ftos(tl));
1687         string minutesPlural;
1688         if (autocvar_timelimit_overtime == 1)
1689                 minutesPlural = " ^3minute";
1690         else
1691                 minutesPlural = " ^3minutes";
1692
1693         bcenterprint(
1694                 strcat(
1695                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1696                         ftos(autocvar_timelimit_overtime),
1697                         minutesPlural,
1698                         " to the game!"
1699                 )
1700         );
1701 }
1702
1703 float GetWinningCode(float fraglimitreached, float equality)
1704 {
1705         if(autocvar_g_campaign == 1)
1706                 if(fraglimitreached)
1707                         return WINNING_YES;
1708                 else
1709                         return WINNING_NO;
1710
1711         else
1712                 if(equality)
1713                         if(fraglimitreached)
1714                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1715                         else
1716                                 return WINNING_NEVER;
1717                 else
1718                         if(fraglimitreached)
1719                                 return WINNING_YES;
1720                         else
1721                                 return WINNING_NO;
1722 }
1723
1724 // set the .winning flag for exactly those players with a given field value
1725 void SetWinners(.float field, float value)
1726 {
1727         entity head;
1728         FOR_EACH_PLAYER(head)
1729                 head.winning = (head.field == value);
1730 }
1731
1732 // set the .winning flag for those players with a given field value
1733 void AddWinners(.float field, float value)
1734 {
1735         entity head;
1736         FOR_EACH_PLAYER(head)
1737                 if(head.field == value)
1738                         head.winning = 1;
1739 }
1740
1741 // clear the .winning flags
1742 void ClearWinners(void)
1743 {
1744         entity head;
1745         FOR_EACH_PLAYER(head)
1746                 head.winning = 0;
1747 }
1748
1749 // Onslaught winning condition:
1750 // game terminates if only one team has a working generator (or none)
1751 float WinningCondition_Onslaught()
1752 {
1753         entity head;
1754         float t1, t2, t3, t4;
1755
1756         WinningConditionHelper(); // set worldstatus
1757
1758         if(inWarmupStage)
1759                 return WINNING_NO;
1760
1761         // first check if the game has ended
1762         t1 = t2 = t3 = t4 = 0;
1763         head = find(world, classname, "onslaught_generator");
1764         while (head)
1765         {
1766                 if (head.health > 0)
1767                 {
1768                         if (head.team == FL_TEAM_1) t1 = 1;
1769                         if (head.team == FL_TEAM_2) t2 = 1;
1770                         if (head.team == FL_TEAM_3) t3 = 1;
1771                         if (head.team == FL_TEAM_4) t4 = 1;
1772                 }
1773                 head = find(head, classname, "onslaught_generator");
1774         }
1775         if (t1 + t2 + t3 + t4 < 2)
1776         {
1777                 // game over, only one team remains (or none)
1778                 ClearWinners();
1779                 if (t1) SetWinners(team, FL_TEAM_1);
1780                 if (t2) SetWinners(team, FL_TEAM_2);
1781                 if (t3) SetWinners(team, FL_TEAM_3);
1782                 if (t4) SetWinners(team, FL_TEAM_4);
1783                 dprint("Have a winner, ending game.\n");
1784                 return WINNING_YES;
1785         }
1786
1787         // Two or more teams remain
1788         return WINNING_NO;
1789 }
1790
1791 float LMS_NewPlayerLives()
1792 {
1793         float fl;
1794         fl = autocvar_fraglimit;
1795         if(fl == 0)
1796                 fl = 999;
1797
1798         // first player has left the game for dying too much? Nobody else can get in.
1799         if(lms_lowest_lives < 1)
1800                 return 0;
1801
1802         if(!autocvar_g_lms_join_anytime)
1803                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1804                         return 0;
1805
1806         return bound(1, lms_lowest_lives, fl);
1807 }
1808
1809 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1810 // they win. Otherwise the defending team wins once the timelimit passes.
1811 void assault_new_round();
1812 float WinningCondition_Assault()
1813 {
1814         float status;
1815
1816         WinningConditionHelper(); // set worldstatus
1817
1818         status = WINNING_NO;
1819         // as the timelimit has not yet passed just assume the defending team will win
1820         if(assault_attacker_team == FL_TEAM_1)
1821         {
1822                 SetWinners(team, FL_TEAM_2);
1823         }
1824         else
1825         {
1826                 SetWinners(team, FL_TEAM_1);
1827         }
1828
1829         entity ent;
1830         ent = find(world, classname, "target_assault_roundend");
1831         if(ent)
1832         {
1833                 if(ent.winning) // round end has been triggered by attacking team
1834                 {
1835                         bprint("ASSAULT: round completed...\n");
1836                         SetWinners(team, assault_attacker_team);
1837
1838                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1839
1840                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1841                         {
1842                                 status = WINNING_YES;
1843                         }
1844                         else
1845                         {
1846                                 entity oldself;
1847                                 oldself = self;
1848                                 self = ent;
1849                                 assault_new_round();
1850                                 self = oldself;
1851                         }
1852                 }
1853         }
1854
1855         return status;
1856 }
1857
1858 // LMS winning condition: game terminates if and only if there's at most one
1859 // one player who's living lives. Top two scores being equal cancels the time
1860 // limit.
1861 float WinningCondition_LMS()
1862 {
1863         entity head, head2;
1864         float have_player;
1865         float have_players;
1866         float l;
1867
1868         have_player = FALSE;
1869         have_players = FALSE;
1870         l = LMS_NewPlayerLives();
1871
1872         head = find(world, classname, "player");
1873         if(head)
1874                 have_player = TRUE;
1875         head2 = find(head, classname, "player");
1876         if(head2)
1877                 have_players = TRUE;
1878
1879         if(have_player)
1880         {
1881                 // we have at least one player
1882                 if(have_players)
1883                 {
1884                         // two or more active players - continue with the game
1885                 }
1886                 else
1887                 {
1888                         // exactly one player?
1889
1890                         ClearWinners();
1891                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1892
1893                         if(l)
1894                         {
1895                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1896                                 return WINNING_NO;
1897                         }
1898                         else
1899                         {
1900                                 // a winner!
1901                                 // and assign him his first place
1902                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1903                                 return WINNING_YES;
1904                         }
1905                 }
1906         }
1907         else
1908         {
1909                 // nobody is playing at all...
1910                 if(l)
1911                 {
1912                         // wait for players...
1913                 }
1914                 else
1915                 {
1916                         // SNAFU (maybe a draw game?)
1917                         ClearWinners();
1918                         dprint("No players, ending game.\n");
1919                         return WINNING_YES;
1920                 }
1921         }
1922
1923         // When we get here, we have at least two players who are actually LIVING,
1924         // now check if the top two players have equal score.
1925         WinningConditionHelper();
1926
1927         ClearWinners();
1928         if(WinningConditionHelper_winner)
1929                 WinningConditionHelper_winner.winning = TRUE;
1930         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1931                 return WINNING_NEVER;
1932
1933         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1934         return WINNING_NO;
1935 }
1936
1937 void ShuffleMaplist()
1938 {
1939         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1940 }
1941
1942 float leaderfrags;
1943 float WinningCondition_Scores(float limit, float leadlimit)
1944 {
1945         float limitreached;
1946
1947         // TODO make everything use THIS winning condition (except LMS)
1948         WinningConditionHelper();
1949
1950         if(teamplay)
1951         {
1952                 team1_score = TeamScore_GetCompareValue(FL_TEAM_1);
1953                 team2_score = TeamScore_GetCompareValue(FL_TEAM_2);
1954                 team3_score = TeamScore_GetCompareValue(FL_TEAM_3);
1955                 team4_score = TeamScore_GetCompareValue(FL_TEAM_4);
1956         }
1957
1958         ClearWinners();
1959         if(WinningConditionHelper_winner)
1960                 WinningConditionHelper_winner.winning = 1;
1961         if(WinningConditionHelper_winnerteam >= 0)
1962                 SetWinners(team, WinningConditionHelper_winnerteam);
1963
1964         if(WinningConditionHelper_lowerisbetter)
1965         {
1966                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1967                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1968                 limit = -limit;
1969         }
1970
1971         if(WinningConditionHelper_zeroisworst)
1972                 leadlimit = 0; // not supported in this mode
1973
1974         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1975         // these modes always score in increments of 1, thus this makes sense
1976         {
1977                 if(leaderfrags != WinningConditionHelper_topscore)
1978                 {
1979                         leaderfrags = WinningConditionHelper_topscore;
1980
1981                         if (limit)
1982                         if (leaderfrags == limit - 1)
1983                                 Announce("1fragleft");
1984                         else if (leaderfrags == limit - 2)
1985                                 Announce("2fragsleft");
1986                         else if (leaderfrags == limit - 3)
1987                                 Announce("3fragsleft");
1988                 }
1989         }
1990
1991         limitreached = FALSE;
1992         if(limit)
1993                 if(WinningConditionHelper_topscore >= limit)
1994                         limitreached = TRUE;
1995         if(leadlimit)
1996         {
1997                 float leadlimitreached;
1998                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1999                 if(autocvar_leadlimit_and_fraglimit)
2000                         limitreached = (limitreached && leadlimitreached);
2001                 else
2002                         limitreached = (limitreached || leadlimitreached);
2003         }
2004
2005         if(limit)
2006                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
2007
2008         return GetWinningCode(
2009                 WinningConditionHelper_topscore && limitreached,
2010                 WinningConditionHelper_equality
2011         );
2012 }
2013
2014 float WinningCondition_Race(float fraglimit)
2015 {
2016         float wc;
2017         entity p;
2018         float n, c;
2019
2020         n = 0;
2021         c = 0;
2022         FOR_EACH_PLAYER(p)
2023         {
2024                 ++n;
2025                 if(p.race_completed)
2026                         ++c;
2027         }
2028         if(n && (n == c))
2029                 return WINNING_YES;
2030         wc = WinningCondition_Scores(fraglimit, 0);
2031
2032         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2033         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2034         // do NOT support equality when the laps are all raced!
2035                 return WINNING_STARTSUDDENDEATHOVERTIME;
2036         else
2037                 return WINNING_NEVER;
2038 }
2039
2040 float WinningCondition_QualifyingThenRace(float limit)
2041 {
2042         float wc;
2043         wc = WinningCondition_Scores(limit, 0);
2044
2045         // NEVER initiate overtime
2046         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2047         {
2048                 return WINNING_YES;
2049         }
2050
2051         return wc;
2052 }
2053
2054 float WinningCondition_RanOutOfSpawns()
2055 {
2056         entity head;
2057
2058         if(have_team_spawns <= 0)
2059                 return WINNING_NO;
2060
2061         if(autocvar_g_spawn_useallspawns <= 0)
2062                 return WINNING_NO;
2063
2064         if(!some_spawn_has_been_used)
2065                 return WINNING_NO;
2066
2067         team1_score = team2_score = team3_score = team4_score = 0;
2068
2069         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2070         {
2071                 if(head.team == FL_TEAM_1)
2072                         team1_score = 1;
2073                 else if(head.team == FL_TEAM_2)
2074                         team2_score = 1;
2075                 else if(head.team == FL_TEAM_3)
2076                         team3_score = 1;
2077                 else if(head.team == FL_TEAM_4)
2078                         team4_score = 1;
2079         }
2080
2081         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2082         {
2083                 if(head.team == FL_TEAM_1)
2084                         team1_score = 1;
2085                 else if(head.team == FL_TEAM_2)
2086                         team2_score = 1;
2087                 else if(head.team == FL_TEAM_3)
2088                         team3_score = 1;
2089                 else if(head.team == FL_TEAM_4)
2090                         team4_score = 1;
2091         }
2092
2093         ClearWinners();
2094         if(team1_score + team2_score + team3_score + team4_score == 0)
2095         {
2096                 checkrules_equality = TRUE;
2097                 return WINNING_YES;
2098         }
2099         else if(team1_score + team2_score + team3_score + team4_score == 1)
2100         {
2101                 float t, i;
2102                 if(team1_score)
2103                         t = FL_TEAM_1;
2104                 else if(team2_score)
2105                         t = FL_TEAM_2;
2106                 else if(team3_score)
2107                         t = FL_TEAM_3;
2108                 else // if(team4_score)
2109                         t = FL_TEAM_4;
2110                 CheckAllowedTeams(world);
2111                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2112                 {
2113                         if(t != FL_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(FL_TEAM_1, i, -1000);
2114                         if(t != FL_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(FL_TEAM_2, i, -1000);
2115                         if(t != FL_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(FL_TEAM_3, i, -1000);
2116                         if(t != FL_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(FL_TEAM_4, i, -1000);
2117                 }
2118
2119                 AddWinners(team, t);
2120                 return WINNING_YES;
2121         }
2122         else
2123                 return WINNING_NO;
2124 }
2125
2126 /*
2127 ============
2128 CheckRules_World
2129
2130 Exit deathmatch games upon conditions
2131 ============
2132 */
2133 void ReadyRestart();
2134 void CheckRules_World()
2135 {
2136         float timelimit;
2137         float fraglimit;
2138         float leadlimit;
2139
2140         VoteThink();
2141         MapVote_Think();
2142
2143         SetDefaultAlpha();
2144
2145         /*
2146         MapVote_Think should now do that part
2147         if (intermission_running)
2148                 if (time >= intermission_exittime + 60)
2149                 {
2150                         if(!DoNextMapOverride())
2151                                 GotoNextMap();
2152                         return;
2153                 }
2154         */
2155
2156         if (gameover)   // someone else quit the game already
2157         {
2158                 if(player_count == 0) // Nobody there? Then let's go to the next map
2159                         MapVote_Start();
2160                         // this will actually check the player count in the next frame
2161                         // again, but this shouldn't hurt
2162                 return;
2163         }
2164
2165         timelimit = autocvar_timelimit * 60;
2166         fraglimit = autocvar_fraglimit;
2167         leadlimit = autocvar_leadlimit;
2168
2169         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2170         {
2171                 if(timelimit > 0)
2172                         timelimit = 0; // timelimit is not made for warmup
2173                 if(fraglimit > 0)
2174                         fraglimit = 0; // no fraglimit for now
2175                 leadlimit = 0; // no leadlimit for now
2176         }
2177
2178         if(timelimit > 0)
2179         {
2180                 timelimit += game_starttime;
2181         }
2182         else if (timelimit < 0)
2183         {
2184                 // endmatch
2185                 NextLevel();
2186                 return;
2187         }
2188
2189         if(g_onslaught)
2190                 timelimit = 0; // ONS has its own overtime rule
2191
2192         float wantovertime;
2193         wantovertime = 0;
2194
2195         if(timelimit > game_starttime)
2196                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2197         else
2198                 game_completion_ratio = 0;
2199
2200         if(checkrules_suddendeathend)
2201         {
2202                 if(!checkrules_suddendeathwarning)
2203                 {
2204                         checkrules_suddendeathwarning = TRUE;
2205                         if(g_race && !g_race_qualifying)
2206                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2207                         else
2208                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2209                 }
2210         }
2211         else
2212         {
2213                 if (timelimit && time >= timelimit)
2214                 {
2215                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2216                         {
2217                                 float totalplayers;
2218                                 float playerswithlaps;
2219                                 float readyplayers;
2220                                 entity head;
2221                                 totalplayers = playerswithlaps = readyplayers = 0;
2222                                 FOR_EACH_PLAYER(head)
2223                                 {
2224                                         ++totalplayers;
2225                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2226                                                 ++playerswithlaps;
2227                                         if(head.ready)
2228                                                 ++readyplayers;
2229                                 }
2230
2231                                 // at least 2 of the players have completed a lap: start the RACE
2232                                 // otherwise, the players should end the qualifying on their own
2233                                 if(readyplayers || playerswithlaps >= 2)
2234                                 {
2235                                         checkrules_suddendeathend = 0;
2236                                         ReadyRestart(); // go to race
2237                                         return;
2238                                 }
2239                                 else
2240                                         wantovertime |= InitiateSuddenDeath();
2241                         }
2242                         else
2243                                 wantovertime |= InitiateSuddenDeath();
2244                 }
2245         }
2246
2247         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2248         {
2249                 NextLevel();
2250                 return;
2251         }
2252
2253         float checkrules_status;
2254         checkrules_status = WinningCondition_RanOutOfSpawns();
2255         if(checkrules_status == WINNING_YES)
2256         {
2257                 bprint("Hey! Someone ran out of spawns!\n");
2258         }
2259         else if(g_race && !g_race_qualifying && timelimit >= 0)
2260         {
2261                 checkrules_status = WinningCondition_Race(fraglimit);
2262                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2263         }
2264         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2265         {
2266                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2267                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2268         }
2269         else if(g_assault)
2270         {
2271                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2272         }
2273         else if(g_lms)
2274         {
2275                 checkrules_status = WinningCondition_LMS();
2276         }
2277         else if (g_onslaught)
2278         {
2279                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2280         }
2281         else
2282         {
2283                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2284                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2285         }
2286
2287         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2288         {
2289                 checkrules_status = WINNING_NEVER;
2290                 checkrules_overtimesadded = -1;
2291                 wantovertime |= InitiateSuddenDeath();
2292         }
2293
2294         if(checkrules_status == WINNING_NEVER)
2295                 // equality cases! Nobody wins if the overtime ends in a draw.
2296                 ClearWinners();
2297
2298         if(wantovertime)
2299         {
2300                 if(checkrules_status == WINNING_NEVER)
2301                         InitiateOvertime();
2302                 else
2303                         checkrules_status = WINNING_YES;
2304         }
2305
2306         if(checkrules_suddendeathend)
2307                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2308                         checkrules_status = WINNING_YES;
2309
2310         if(checkrules_status == WINNING_YES)
2311         {
2312                 //print("WINNING\n");
2313                 NextLevel();
2314         }
2315 }
2316
2317 float mapvote_nextthink;
2318 float mapvote_initialized;
2319 float mapvote_keeptwotime;
2320 float mapvote_timeout;
2321 string mapvote_message;
2322 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2323 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2324 float mapvote_screenshot_dirs_count;
2325
2326 float mapvote_count;
2327 float mapvote_count_real;
2328 string mapvote_maps[MAPVOTE_COUNT];
2329 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2330 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2331 float mapvote_maps_suggested[MAPVOTE_COUNT];
2332 string mapvote_suggestions[MAPVOTE_COUNT];
2333 float mapvote_suggestion_ptr;
2334 float mapvote_voters;
2335 float mapvote_selections[MAPVOTE_COUNT];
2336 float mapvote_run;
2337 float mapvote_detail;
2338 float mapvote_abstain;
2339 .float mapvote;
2340
2341 void MapVote_ClearAllVotes()
2342 {
2343         FOR_EACH_CLIENT(other)
2344                 other.mapvote = 0;
2345 }
2346
2347 string MapVote_Suggest(string m)
2348 {
2349         float i;
2350         if(m == "")
2351                 return "That's not how to use this command.";
2352         if(!autocvar_g_maplist_votable_suggestions)
2353                 return "Suggestions are not accepted on this server.";
2354         if(mapvote_initialized)
2355                 return "Can't suggest - voting is already in progress!";
2356         m = MapInfo_FixName(m);
2357         if not(m)
2358                 return "The map you suggested is not available on this server.";
2359         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2360                 if(Map_IsRecent(m))
2361                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2362
2363         if(!MapInfo_CheckMap(m))
2364                 return "The map you suggested does not support the current game mode.";
2365         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2366                 if(mapvote_suggestions[i] == m)
2367                         return "This map was already suggested.";
2368         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2369         {
2370                 i = floor(random() * mapvote_suggestion_ptr);
2371         }
2372         else
2373         {
2374                 i = mapvote_suggestion_ptr;
2375                 mapvote_suggestion_ptr += 1;
2376         }
2377         if(mapvote_suggestions[i] != "")
2378                 strunzone(mapvote_suggestions[i]);
2379         mapvote_suggestions[i] = strzone(m);
2380         if(autocvar_sv_eventlog)
2381                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2382         return strcat("Suggestion of ", m, " accepted.");
2383 }
2384
2385 void MapVote_AddVotable(string nextMap, float isSuggestion)
2386 {
2387         float j, i, o;
2388         string pakfile, mapfile;
2389
2390         if(nextMap == "")
2391                 return;
2392         for(j = 0; j < mapvote_count; ++j)
2393                 if(mapvote_maps[j] == nextMap)
2394                         return;
2395         // suggestions might be no longer valid/allowed after gametype switch!
2396         if(isSuggestion)
2397                 if(!MapInfo_CheckMap(nextMap))
2398                         return;
2399         mapvote_maps[mapvote_count] = strzone(nextMap);
2400         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2401
2402         pakfile = string_null;
2403         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2404         {
2405                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2406                 pakfile = whichpack(strcat(mapfile, ".tga"));
2407                 if(pakfile == "")
2408                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2409                 if(pakfile == "")
2410                         pakfile = whichpack(strcat(mapfile, ".png"));
2411                 if(pakfile != "")
2412                         break;
2413         }
2414         if(i >= mapvote_screenshot_dirs_count)
2415                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2416         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2417                 pakfile = substring(pakfile, o, -1);
2418
2419         mapvote_maps_screenshot_dir[mapvote_count] = i;
2420         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2421
2422         mapvote_count += 1;
2423 }
2424
2425 void MapVote_Spawn();
2426 void MapVote_Init()
2427 {
2428         float i;
2429         float nmax, smax;
2430
2431         MapVote_ClearAllVotes();
2432
2433         mapvote_count = 0;
2434         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2435         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2436
2437         if(mapvote_abstain)
2438                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2439         else
2440                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2441         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2442
2443         // we need this for AddVotable, as that cycles through the screenshot dirs
2444         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2445         if(mapvote_screenshot_dirs_count == 0)
2446                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2447         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2448         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2449                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2450
2451         if(mapvote_suggestion_ptr)
2452                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2453                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2454
2455         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2456                 MapVote_AddVotable(GetNextMap(), FALSE);
2457
2458         if(mapvote_count == 0)
2459         {
2460                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2461                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2462                 if(autocvar_g_maplist_shuffle)
2463                         ShuffleMaplist();
2464                 localcmd("\nmenu_cmd sync\n");
2465                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2466                         MapVote_AddVotable(GetNextMap(), FALSE);
2467         }
2468
2469         mapvote_count_real = mapvote_count;
2470         if(mapvote_abstain)
2471                 MapVote_AddVotable("don't care", 0);
2472
2473         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2474
2475         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2476         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2477         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2478                 mapvote_keeptwotime = 0;
2479         mapvote_message = "Choose a map and press its key!";
2480
2481         MapVote_Spawn();
2482 }
2483
2484 void MapVote_SendPicture(float id)
2485 {
2486         msg_entity = self;
2487         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2488         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2489         WriteByte(MSG_ONE, id);
2490         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2491 }
2492
2493 float MapVote_GetMapMask()
2494 {
2495         float mask, i, power;
2496         mask = 0;
2497         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2498                 if(mapvote_maps[i] != "")
2499                         mask |= power;
2500         return mask;
2501 }
2502
2503 entity mapvote_ent;
2504 float MapVote_SendEntity(entity to, float sf)
2505 {
2506         float i;
2507
2508         if(sf & 1)
2509                 sf &~= 2; // if we send 1, we don't need to also send 2
2510
2511         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2512         WriteByte(MSG_ENTITY, sf);
2513
2514         if(sf & 1)
2515         {
2516                 // flag 1 == initialization
2517                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2518                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2519                 WriteString(MSG_ENTITY, "");
2520                 WriteByte(MSG_ENTITY, mapvote_count);
2521                 WriteByte(MSG_ENTITY, mapvote_abstain);
2522                 WriteByte(MSG_ENTITY, mapvote_detail);
2523                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2524                 if(mapvote_count <= 8)
2525                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2526                 else
2527                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2528                 for(i = 0; i < mapvote_count; ++i)
2529                         if(mapvote_maps[i] != "")
2530                         {
2531                                 if(mapvote_abstain && i == mapvote_count - 1)
2532                                 {
2533                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2534                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2535                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2536                                 }
2537                                 else
2538                                 {
2539                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2540                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2541                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2542                                 }
2543                         }
2544         }
2545
2546         if(sf & 2)
2547         {
2548                 // flag 2 == update of mask
2549                 if(mapvote_count <= 8)
2550                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2551                 else
2552                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2553         }
2554
2555         if(sf & 4)
2556         {
2557                 if(mapvote_detail)
2558                         for(i = 0; i < mapvote_count; ++i)
2559                                 if(mapvote_maps[i] != "")
2560                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2561
2562                 WriteByte(MSG_ENTITY, to.mapvote);
2563         }
2564
2565         return TRUE;
2566 }
2567
2568 void MapVote_Spawn()
2569 {
2570         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2571 }
2572
2573 void MapVote_TouchMask()
2574 {
2575         mapvote_ent.SendFlags |= 2;
2576 }
2577
2578 void MapVote_TouchVotes(entity voter)
2579 {
2580         mapvote_ent.SendFlags |= 4;
2581 }
2582
2583 float MapVote_Finished(float mappos)
2584 {
2585         string result;
2586         float i;
2587         float didntvote;
2588
2589         if(autocvar_sv_eventlog)
2590         {
2591                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2592                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2593                 didntvote = mapvote_voters;
2594                 for(i = 0; i < mapvote_count; ++i)
2595                         if(mapvote_maps[i] != "")
2596                         {
2597                                 didntvote -= mapvote_selections[i];
2598                                 if(i != mappos)
2599                                 {
2600                                         result = strcat(result, ":", mapvote_maps[i]);
2601                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2602                                 }
2603                         }
2604                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2605
2606                 GameLogEcho(result);
2607                 if(mapvote_maps_suggested[mappos])
2608                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2609         }
2610
2611         FOR_EACH_REALCLIENT(other)
2612                 FixClientCvars(other);
2613
2614         Map_Goto_SetStr(mapvote_maps[mappos]);
2615         Map_Goto(0);
2616         alreadychangedlevel = TRUE;
2617         return TRUE;
2618 }
2619 void MapVote_CheckRules_1()
2620 {
2621         float i;
2622
2623         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2624         {
2625                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2626                 mapvote_selections[i] = 0;
2627         }
2628
2629         mapvote_voters = 0;
2630         FOR_EACH_REALCLIENT(other)
2631         {
2632                 ++mapvote_voters;
2633                 if(other.mapvote)
2634                 {
2635                         i = other.mapvote - 1;
2636                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2637                         mapvote_selections[i] = mapvote_selections[i] + 1;
2638                 }
2639         }
2640 }
2641
2642 float MapVote_CheckRules_2()
2643 {
2644         float i;
2645         float firstPlace, secondPlace;
2646         float firstPlaceVotes, secondPlaceVotes;
2647         float mapvote_voters_real;
2648         string result;
2649
2650         if(mapvote_count_real == 1)
2651                 return MapVote_Finished(0);
2652
2653         mapvote_voters_real = mapvote_voters;
2654         if(mapvote_abstain)
2655                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2656
2657         RandomSelection_Init();
2658         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2659                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2660         firstPlace = RandomSelection_chosen_float;
2661         firstPlaceVotes = RandomSelection_best_priority;
2662         //dprint("First place: ", ftos(firstPlace), "\n");
2663         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2664
2665         RandomSelection_Init();
2666         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2667                 if(i != firstPlace)
2668                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2669         secondPlace = RandomSelection_chosen_float;
2670         secondPlaceVotes = RandomSelection_best_priority;
2671         //dprint("Second place: ", ftos(secondPlace), "\n");
2672         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2673
2674         if(firstPlace == -1)
2675                 error("No first place in map vote... WTF?");
2676
2677         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2678                 return MapVote_Finished(firstPlace);
2679
2680         if(mapvote_keeptwotime)
2681                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2682                 {
2683                         float didntvote;
2684                         MapVote_TouchMask();
2685                         mapvote_message = "Now decide between the TOP TWO!";
2686                         mapvote_keeptwotime = 0;
2687                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2688                         result = strcat(result, ":", ftos(firstPlaceVotes));
2689                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2690                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2691                         didntvote = mapvote_voters;
2692                         for(i = 0; i < mapvote_count; ++i)
2693                                 if(mapvote_maps[i] != "")
2694                                 {
2695                                         didntvote -= mapvote_selections[i];
2696                                         if(i != firstPlace)
2697                                                 if(i != secondPlace)
2698                                                 {
2699                                                         result = strcat(result, ":", mapvote_maps[i]);
2700                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2701                                                         if(i < mapvote_count_real)
2702                                                         {
2703                                                                 strunzone(mapvote_maps[i]);
2704                                                                 mapvote_maps[i] = "";
2705                                                                 strunzone(mapvote_maps_pakfile[i]);
2706                                                                 mapvote_maps_pakfile[i] = "";
2707                                                         }
2708                                                 }
2709                                 }
2710                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2711                         if(autocvar_sv_eventlog)
2712                                 GameLogEcho(result);
2713                 }
2714
2715         return FALSE;
2716 }
2717 void MapVote_Tick()
2718 {
2719         float keeptwo;
2720         float totalvotes;
2721
2722         keeptwo = mapvote_keeptwotime;
2723         MapVote_CheckRules_1(); // count
2724         if(MapVote_CheckRules_2()) // decide
2725                 return;
2726
2727         totalvotes = 0;
2728         FOR_EACH_REALCLIENT(other)
2729         {
2730                 // hide scoreboard again
2731                 if(other.health != 2342)
2732                 {
2733                         other.health = 2342;
2734                         other.impulse = 0;
2735                         if(clienttype(other) == CLIENTTYPE_REAL)
2736                         {
2737                                 msg_entity = other;
2738                                 WriteByte(MSG_ONE, SVC_FINALE);
2739                                 WriteString(MSG_ONE, "");
2740                         }
2741                 }
2742
2743                 // clear possibly invalid votes
2744                 if(mapvote_maps[other.mapvote - 1] == "")
2745                         other.mapvote = 0;
2746                 // use impulses as new vote
2747                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2748                         if(mapvote_maps[other.impulse - 1] != "")
2749                         {
2750                                 other.mapvote = other.impulse;
2751                                 MapVote_TouchVotes(other);
2752                         }
2753                 other.impulse = 0;
2754
2755                 if(other.mapvote)
2756                         ++totalvotes;
2757         }
2758
2759         MapVote_CheckRules_1(); // just count
2760 }
2761 void MapVote_Start()
2762 {
2763         if(mapvote_run)
2764                 return;
2765
2766         // wait for stats to be sent first
2767         if(!playerstats_waitforme)
2768                 return;
2769
2770         MapInfo_Enumerate();
2771         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2772                 mapvote_run = TRUE;
2773 }
2774 void MapVote_Think()
2775 {
2776         if(!mapvote_run)
2777                 return;
2778
2779         if(alreadychangedlevel)
2780                 return;
2781
2782         if(time < mapvote_nextthink)
2783                 return;
2784         //dprint("tick\n");
2785
2786         mapvote_nextthink = time + 0.5;
2787
2788         if(!mapvote_initialized)
2789         {
2790                 if(autocvar_rescan_pending == 1)
2791                 {
2792                         cvar_set("rescan_pending", "2");
2793                         localcmd("fs_rescan\nrescan_pending 3\n");
2794                         return;
2795                 }
2796                 else if(autocvar_rescan_pending == 2)
2797                 {
2798                         return;
2799                 }
2800                 else if(autocvar_rescan_pending == 3)
2801                 {
2802                         // now build missing mapinfo files
2803                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2804                                 return;
2805
2806                         // we're done, start the timer
2807                         cvar_set("rescan_pending", "0");
2808                 }
2809
2810                 mapvote_initialized = TRUE;
2811                 if(DoNextMapOverride(0))
2812                         return;
2813                 if(!autocvar_g_maplist_votable || player_count <= 0)
2814                 {
2815                         GotoNextMap(0);
2816                         return;
2817                 }
2818                 MapVote_Init();
2819         }
2820
2821         MapVote_Tick();
2822 }
2823
2824 string GotoMap(string m)
2825 {
2826         if(!MapInfo_CheckMap(m))
2827                 return "The map you chose is not available on this server.";
2828         cvar_set("nextmap", m);
2829         cvar_set("timelimit", "-1");
2830         if(mapvote_initialized || alreadychangedlevel)
2831         {
2832                 if(DoNextMapOverride(0))
2833                         return "Map switch initiated.";
2834                 else
2835                         return "Hm... no. For some reason I like THIS map more.";
2836         }
2837         else
2838                 return "Map switch will happen after scoreboard.";
2839 }
2840
2841
2842 void EndFrame()
2843 {
2844         float altime;
2845         FOR_EACH_REALCLIENT(self)
2846         {
2847                 if(self.classname == "spectator")
2848                 {
2849                         if(self.enemy.typehitsound)
2850                                 self.typehit_time = time;
2851                         else if(self.enemy.hitsound)
2852                                 self.hit_time = time;
2853                 }
2854                 else
2855                 {
2856                         if(self.typehitsound)
2857                                 self.typehit_time = time;
2858                         else if(self.hitsound)
2859                                 self.hit_time = time;
2860                 }
2861         }
2862         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2863         // add 1 frametime because after this, engine SV_Physics
2864         // increases time by a frametime and then networks the frame
2865         // add another frametime because client shows everything with
2866         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2867         // needed!
2868         FOR_EACH_CLIENT(self)
2869         {
2870                 self.hitsound = FALSE;
2871                 self.typehitsound = FALSE;
2872                 antilag_record(self, altime);
2873         }
2874 }
2875
2876
2877 /*
2878  * RedirectionThink:
2879  * returns TRUE if redirecting
2880  */
2881 float redirection_timeout;
2882 float redirection_nextthink;
2883 float RedirectionThink()
2884 {
2885         float clients_found;
2886
2887         if(redirection_target == "")
2888                 return FALSE;
2889
2890         if(!redirection_timeout)
2891         {
2892                 cvar_set("sv_public", "-2");
2893                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2894                 if(redirection_target == "self")
2895                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2896                 else
2897                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2898         }
2899
2900         if(time < redirection_nextthink)
2901                 return TRUE;
2902
2903         redirection_nextthink = time + 1;
2904
2905         clients_found = 0;
2906         FOR_EACH_REALCLIENT(self)
2907         {
2908                 // TODO add timer
2909                 print("Redirecting: sending connect command to ", self.netname, "\n");
2910                 if(redirection_target == "self")
2911                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2912                 else
2913                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2914                 ++clients_found;
2915         }
2916
2917         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2918
2919         if(time > redirection_timeout || clients_found == 0)
2920                 localcmd("\nwait; wait; wait; quit\n");
2921
2922         return TRUE;
2923 }
2924
2925 void TargetMusic_RestoreGame();
2926 void RestoreGame()
2927 {
2928         // Loaded from a save game
2929         // some things then break, so let's work around them...
2930
2931         // Progs DB (capture records)
2932         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2933
2934         // Mapinfo
2935         MapInfo_Shutdown();
2936         MapInfo_Enumerate();
2937         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2938         WeaponStats_Init();
2939
2940         TargetMusic_RestoreGame();
2941 }
2942
2943 void Shutdown()
2944 {
2945         entity e;
2946
2947         gameover = 2;
2948
2949         if(world_initialized > 0)
2950         {
2951                 world_initialized = 0;
2952                 print("Saving persistent data...\n");
2953                 Ban_SaveBans();
2954
2955                 PlayerStats_EndMatch(0);
2956                 FOR_EACH_CLIENT(e)
2957                         PlayerStats_AddGlobalInfo(e);
2958                 PlayerStats_Shutdown();
2959
2960                 if(!cheatcount_total)
2961                 {
2962                         if(autocvar_sv_db_saveasdump)
2963                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2964                         else
2965                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2966                 }
2967                 if(autocvar_developer)
2968                 {
2969                         if(autocvar_sv_db_saveasdump)
2970                                 db_dump(TemporaryDB, "server-temp.db");
2971                         else
2972                                 db_save(TemporaryDB, "server-temp.db");
2973                 }
2974                 CheatShutdown(); // must be after cheatcount check
2975                 db_close(ServerProgsDB);
2976                 db_close(TemporaryDB);
2977                 print("done!\n");
2978                 // tell the bot system the game is ending now
2979                 bot_endgame();
2980
2981                 WeaponStats_Shutdown();
2982                 MapInfo_Shutdown();
2983         }
2984         else if(world_initialized == 0)
2985         {
2986                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2987         }
2988 }