qcsrc/server/g_subs.qc

   1 void SUB_Null() {};
   2 float SUB_True() { return 1; }
   3 float SUB_False() { return 0; }
   4
   5 void(vector destangle, float tspeed, void() func) SUB_CalcAngleMove;
   6 void()  SUB_CalcMoveDone;
   7 void() SUB_CalcAngleMoveDone;
   8 //void() SUB_UseTargets;
   9 void() SUB_Remove;
  10
  11 void spawnfunc_info_null (void)
  12 {
  13         remove(self);
  14         // if anything breaks, tell the mapper to fix his map! info_null is meant to remove itself immediately.
  15 }
  16
  17 void setanim(entity e, vector anim, float looping, float override, float restart)
  18 {
  19         if (!anim)
  20                 return; // no animation was given to us! We can't use this.
  21
  22         if (anim_x == e.animstate_startframe)
  23         if (anim_y == e.animstate_numframes)
  24         if (anim_z == e.animstate_framerate)
  25         {
  26                 if(restart)
  27                 {
  28                         if(restart > 0)
  29                         if(anim_y == 1) // ZYM animation
  30                                 BITXOR_ASSIGN(e.effects, EF_RESTARTANIM_BIT);
  31                 }
  32                 else
  33                         return;
  34         }
  35         e.animstate_startframe = anim_x;
  36         e.animstate_numframes = anim_y;
  37         e.animstate_framerate = anim_z;
  38         e.animstate_starttime = servertime - 0.1 * serverframetime; // shift it a little bit into the past to prevent float inaccuracy hiccups
  39         e.animstate_endtime = e.animstate_starttime + e.animstate_numframes / e.animstate_framerate;
  40         e.animstate_looping = looping;
  41         e.animstate_override = override;
  42         e.frame = e.animstate_startframe;
  43         e.frame1time = servertime;
  44 };
  45
  46 void updateanim(entity e)
  47 {
  48         if (time >= e.animstate_endtime)
  49         {
  50                 if (e.animstate_looping)
  51                 {
  52                         e.animstate_starttime = e.animstate_endtime;
  53                         e.animstate_endtime = e.animstate_starttime + e.animstate_numframes / e.animstate_framerate;
  54                 }
  55                 e.animstate_override = FALSE;
  56         }
  57         e.frame = e.animstate_startframe + bound(0, (time - e.animstate_starttime) * e.animstate_framerate, e.animstate_numframes - 1);
  58         //print(ftos(time), " -> ", ftos(e.frame), "\n");
  59 };
  60
  61 vector animfixfps(entity e, vector a)
  62 {
  63         // multi-frame anim: keep as-is
  64         if(a_y == 1)
  65         {
  66                 float dur;
  67                 dur = frameduration(e.modelindex, a_x);
  68                 if(dur > 0)
  69                         a_z = 1.0 / dur;
  70         }
  71         return a;
  72 }
  73
  74 /*
  75 ==================
  76 SUB_Remove
  77
  78 Remove self
  79 ==================
  80 */
  81 void SUB_Remove (void)
  82 {
  83         remove (self);
  84 }
  85
  86 /*
  87 ==================
  88 SUB_Friction
  89
  90 Applies some friction to self
  91 ==================
  92 */
  93 .float friction;
  94 void SUB_Friction (void)
  95 {
  96         self.nextthink = time;
  97         if(self.flags & FL_ONGROUND)
  98                 self.velocity = self.velocity * (1 - frametime * self.friction);
  99 }
 100
 101 /*
 102 ==================
 103 SUB_VanishOrRemove
 104
 105 Makes client invisible or removes non-client
 106 ==================
 107 */
 108 void SUB_VanishOrRemove (entity ent)
 109 {
 110         if (ent.flags & FL_CLIENT)
 111         {
 112                 // vanish
 113                 ent.model = "";
 114                 ent.effects = 0;
 115                 ent.glow_size = 0;
 116                 ent.pflags = 0;
 117         }
 118         else
 119         {
 120                 // remove
 121                 remove (ent);
 122         }
 123 }
 124
 125 void SUB_SetFade_Think (void)
 126 {
 127         self.think = SUB_SetFade_Think;
 128         self.nextthink = self.fade_time;
 129         self.alpha = 1 - (time - self.fade_time) * self.fade_rate;
 130         if (self.alpha < 0.01)
 131                 SUB_VanishOrRemove(self);
 132         self.alpha = bound(0.01, self.alpha, 1);
 133 }
 134
 135 /*
 136 ==================
 137 SUB_SetFade
 138
 139 Fade 'ent' out when time >= 'when'
 140 ==================
 141 */
 142 void SUB_SetFade (entity ent, float when, float fadetime)
 143 {
 144         //if (ent.flags & FL_CLIENT) // && ent.deadflag != DEAD_NO)
 145         //      return;
 146         //ent.alpha = 1;
 147         ent.fade_rate = 1/fadetime;
 148         ent.fade_time = when;
 149         ent.think = SUB_SetFade_Think;
 150         ent.nextthink = when;
 151 }
 152
 153 /*
 154 =============
 155 SUB_CalcMove
 156
 157 calculate self.velocity and self.nextthink to reach dest from
 158 self.origin traveling at speed
 159 ===============
 160 */
 161 void SUB_CalcMoveDone (void)
 162 {
 163         // After moving, set origin to exact final destination
 164
 165         setorigin (self, self.finaldest);
 166         self.velocity = '0 0 0';
 167         self.nextthink = -1;
 168         if (self.think1)
 169                 self.think1 ();
 170 }
 171
 172 void SUB_CalcMove_controller_think (void)
 173 {
 174         entity oldself;
 175         float traveltime;
 176         float phasepos;
 177         float nexttick;
 178         vector delta;
 179         vector veloc;
 180         vector nextpos;
 181         if(time < self.animstate_endtime) {
 182                 delta = self.destvec;
 183                 nexttick = time + sys_frametime;
 184
 185                 if(nexttick < self.animstate_endtime) {
 186                         traveltime = self.animstate_endtime - self.animstate_starttime;
 187                         phasepos = (nexttick - self.animstate_starttime) / traveltime; // range: [0, 1]
 188                         phasepos = 3.14159265 + (phasepos * 3.14159265); // range: [pi, 2pi]
 189                         phasepos = cos(phasepos); // cos [pi, 2pi] is in [-1, 1]
 190                         phasepos = phasepos + 1; // correct range to [0, 2]
 191                         phasepos = phasepos / 2; // correct range to [0, 1]
 192                         nextpos = self.origin + (delta * phasepos);
 193
 194                         veloc = nextpos - self.owner.origin;
 195                         veloc = veloc * (1 / sys_frametime); // so it arrives for the next frame
 196
 197                 } else {
 198                         veloc = self.finaldest - self.owner.origin;
 199                         veloc = veloc * (1 / sys_frametime); // so it arrives for the next frame
 200                 }
 201                 self.owner.velocity = veloc;
 202                 self.nextthink = nexttick;
 203         } else {
 204                 oldself = self;
 205                 self.owner.think = self.think1;
 206                 self = self.owner;
 207                 remove(oldself);
 208                 self.think();
 209         }
 210 }
 211
 212 void SUB_CalcMove (vector tdest, float tspeed, void() func)
 213 {
 214         vector  delta;
 215         float   traveltime;
 216         entity controller;
 217
 218         if (!tspeed)
 219                 objerror ("No speed is defined!");
 220
 221         self.think1 = func;
 222         self.finaldest = tdest;
 223         self.think = SUB_CalcMoveDone;
 224
 225         if (tdest == self.origin)
 226         {
 227                 self.velocity = '0 0 0';
 228                 self.nextthink = self.ltime + 0.1;
 229                 return;
 230         }
 231
 232         delta = tdest - self.origin;
 233         traveltime = vlen (delta) / tspeed;
 234
 235         if (traveltime < 0.1)
 236         {
 237                 self.velocity = '0 0 0';
 238                 self.nextthink = self.ltime + 0.1;
 239                 return;
 240         }
 241
 242         // Very short animations don't really show off the effect
 243         // of controlled animation, so let's just use linear movement.
 244         // Alternatively entities can choose to specify non-controlled movement.
 245         // The only currently implemented alternative movement is linear (value 1)
 246         if (traveltime < 0.15 || self.platmovetype == 1)
 247         {
 248                 self.velocity = delta * (1/traveltime); // QuakeC doesn't allow vector/float division
 249                 self.nextthink = self.ltime + traveltime;
 250                 return;
 251         }
 252
 253         controller = spawn();
 254         controller.classname = "SUB_CalcMove_controller";
 255         controller.owner = self;
 256         controller.origin = self.origin; // starting point
 257         controller.finaldest = (tdest + '0 0 0.125'); // where do we want to end? Offset to overshoot a bit.
 258         controller.destvec = delta;
 259         controller.animstate_starttime = time;
 260         controller.animstate_endtime = time + traveltime;
 261         controller.think = SUB_CalcMove_controller_think;
 262         controller.think1 = self.think;
 263
 264         // the thinking is now done by the controller
 265         self.think = SUB_Null;
 266         self.nextthink = self.ltime + traveltime;
 267
 268         // invoke controller
 269         self = controller;
 270         self.think();
 271         self = self.owner;
 272 }
 273
 274 void SUB_CalcMoveEnt (entity ent, vector tdest, float tspeed, void() func)
 275 {
 276         entity  oldself;
 277
 278         oldself = self;
 279         self = ent;
 280
 281         SUB_CalcMove (tdest, tspeed, func);
 282
 283         self = oldself;
 284 }
 285
 286 /*
 287 =============
 288 SUB_CalcAngleMove
 289
 290 calculate self.avelocity and self.nextthink to reach destangle from
 291 self.angles rotating
 292
 293 The calling function should make sure self.think is valid
 294 ===============
 295 */
 296 void SUB_CalcAngleMoveDone (void)
 297 {
 298         // After rotating, set angle to exact final angle
 299         self.angles = self.finalangle;
 300         self.avelocity = '0 0 0';
 301         self.nextthink = -1;
 302         if (self.think1)
 303                 self.think1 ();
 304 }
 305
 306 // FIXME: I fixed this function only for rotation around the main axes
 307 void SUB_CalcAngleMove (vector destangle, float tspeed, void() func)
 308 {
 309         vector  delta;
 310         float   traveltime;
 311
 312         if (!tspeed)
 313                 objerror ("No speed is defined!");
 314
 315         // take the shortest distance for the angles
 316         self.angles_x -= 360 * floor((self.angles_x - destangle_x) / 360 + 0.5);
 317         self.angles_y -= 360 * floor((self.angles_y - destangle_y) / 360 + 0.5);
 318         self.angles_z -= 360 * floor((self.angles_z - destangle_z) / 360 + 0.5);
 319         delta = destangle - self.angles;
 320         traveltime = vlen (delta) / tspeed;
 321
 322         self.think1 = func;
 323         self.finalangle = destangle;
 324         self.think = SUB_CalcAngleMoveDone;
 325
 326         if (traveltime < 0.1)
 327         {
 328                 self.avelocity = '0 0 0';
 329                 self.nextthink = self.ltime + 0.1;
 330                 return;
 331         }
 332
 333         self.avelocity = delta * (1 / traveltime);
 334         self.nextthink = self.ltime + traveltime;
 335 }
 336
 337 void SUB_CalcAngleMoveEnt (entity ent, vector destangle, float tspeed, void() func)
 338 {
 339         entity  oldself;
 340
 341         oldself = self;
 342         self = ent;
 343
 344         SUB_CalcAngleMove (destangle, tspeed, func);
 345
 346         self = oldself;
 347 }
 348
 349 /*
 350 ==================
 351 main
 352
 353 unused but required by the engine
 354 ==================
 355 */
 356 void main (void)
 357 {
 358
 359 }
 360
 361 // Misc
 362
 363 /*
 364 ==================
 365 traceline_antilag
 366
 367 A version of traceline that must be used by SOLID_SLIDEBOX things that want to hit SOLID_CORPSE things with a trace attack
 368 Additionally it moves players back into the past before the trace and restores them afterward.
 369 ==================
 370 */
 371 void tracebox_antilag_force_wz (entity source, vector v1, vector mi, vector ma, vector v2, float nomonst, entity forent, float lag, float wz)
 372 {
 373         local entity player;
 374         local float oldsolid;
 375
 376         // check whether antilagged traces are enabled
 377         if (lag < 0.001)
 378                 lag = 0;
 379         if (clienttype(forent) != CLIENTTYPE_REAL)
 380                 lag = 0; // only antilag for clients
 381
 382         // change shooter to SOLID_BBOX so the shot can hit corpses
 383         if(source)
 384         {
 385                 oldsolid = source.dphitcontentsmask;
 386                 source.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 387         }
 388
 389         if (lag)
 390         {
 391                 // take players back into the past
 392                 player = player_list;
 393                 while (player)
 394                 {
 395                         antilag_takeback(player, time - lag);
 396                         player = player.nextplayer;
 397                 }
 398         }
 399
 400         // do the trace
 401         if(wz)
 402                 WarpZone_TraceBox (v1, mi, ma, v2, nomonst, forent);
 403         else
 404                 tracebox (v1, mi, ma, v2, nomonst, forent);
 405
 406         // restore players to current positions
 407         if (lag)
 408         {
 409                 player = player_list;
 410                 while (player)
 411                 {
 412                         antilag_restore(player);
 413                         player = player.nextplayer;
 414                 }
 415         }
 416
 417         // restore shooter solid type
 418         if(source)
 419                 source.dphitcontentsmask = oldsolid;
 420 }
 421 void traceline_antilag_force (entity source, vector v1, vector v2, float nomonst, entity forent, float lag)
 422 {
 423         tracebox_antilag_force_wz(source, v1, '0 0 0', '0 0 0', v2, nomonst, forent, lag, FALSE);
 424 }
 425 void traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag)
 426 {
 427         if (autocvar_g_antilag != 2 || source.cvar_cl_noantilag)
 428                 lag = 0;
 429         traceline_antilag_force(source, v1, v2, nomonst, forent, lag);
 430 }
 431 void tracebox_antilag (entity source, vector v1, vector mi, vector ma, vector v2, float nomonst, entity forent, float lag)
 432 {
 433         if (autocvar_g_antilag != 2 || source.cvar_cl_noantilag)
 434                 lag = 0;
 435         tracebox_antilag_force_wz(source, v1, mi, ma, v2, nomonst, forent, lag, FALSE);
 436 }
 437 void WarpZone_traceline_antilag_force (entity source, vector v1, vector v2, float nomonst, entity forent, float lag)
 438 {
 439         tracebox_antilag_force_wz(source, v1, '0 0 0', '0 0 0', v2, nomonst, forent, lag, TRUE);
 440 }
 441 void WarpZone_traceline_antilag (entity source, vector v1, vector v2, float nomonst, entity forent, float lag)
 442 {
 443         if (autocvar_g_antilag != 2 || source.cvar_cl_noantilag)
 444                 lag = 0;
 445         WarpZone_traceline_antilag_force(source, v1, v2, nomonst, forent, lag);
 446 }
 447 void WarpZone_tracebox_antilag (entity source, vector v1, vector mi, vector ma, vector v2, float nomonst, entity forent, float lag)
 448 {
 449         if (autocvar_g_antilag != 2 || source.cvar_cl_noantilag)
 450                 lag = 0;
 451         tracebox_antilag_force_wz(source, v1, mi, ma, v2, nomonst, forent, lag, TRUE);
 452 }
 453
 454 float tracebox_inverted (vector v1, vector mi, vector ma, vector v2, float nomonsters, entity forent) // returns the number of traces done, for benchmarking
 455 {
 456         vector pos, dir, t;
 457         float nudge;
 458
 459         //nudge = 2 * cvar("collision_impactnudge"); // why not?
 460         nudge = 0.5;
 461
 462         dir = normalize(v2 - v1);
 463
 464         pos = v1 + dir * nudge;
 465
 466         float c;
 467         c = 0;
 468
 469         for(;;)
 470         {
 471                 if((pos - v1) * dir >= (v2 - v1) * dir)
 472                 {
 473                         // went too far
 474                         trace_fraction = 1;
 475                         trace_endpos = v2;
 476                         return c;
 477                 }
 478
 479                 tracebox(pos, mi, ma, v2, nomonsters, forent);
 480                 ++c;
 481
 482                 if(c == 50)
 483                 {
 484                         dprint("HOLY SHIT! When tracing from ", vtos(v1), " to ", vtos(v2), "\n");
 485                         dprint("  Nudging gets us nowhere at ", vtos(pos), "\n");
 486                         dprint("  trace_endpos is ", vtos(trace_endpos), "\n");
 487                         dprint("  trace distance is ", ftos(vlen(pos - trace_endpos)), "\n");
 488                 }
 489
 490                 if(trace_startsolid)
 491                 {
 492                         // we started inside solid.
 493                         // then trace from endpos to pos
 494                         t = trace_endpos;
 495                         tracebox(t, mi, ma, pos, nomonsters, forent);
 496                         ++c;
 497                         if(trace_startsolid)
 498                         {
 499                                 // t is still inside solid? bad
 500                                 // force advance, then, and retry
 501                                 pos = t + dir * nudge;
 502                         }
 503                         else
 504                         {
 505                                 // we actually LEFT solid!
 506                                 trace_fraction = ((trace_endpos - v1) * dir) / ((v2 - v1) * dir);
 507                                 return c;
 508                         }
 509                 }
 510                 else
 511                 {
 512                         // pos is outside solid?!? but why?!? never mind, just return it.
 513                         trace_endpos = pos;
 514                         trace_fraction = ((trace_endpos - v1) * dir) / ((v2 - v1) * dir);
 515                         return c;
 516                 }
 517         }
 518 }
 519
 520 void traceline_inverted (vector v1, vector v2, float nomonsters, entity forent)
 521 {
 522 #if 0
 523         vector pos, dir, t;
 524         float nudge;
 525
 526         //nudge = 2 * cvar("collision_impactnudge"); // why not?
 527         nudge = 0.5;
 528
 529         dir = normalize(v2 - v1);
 530
 531         pos = v1 + dir * nudge;
 532
 533         for(;;)
 534         {
 535                 if((pos - v1) * dir >= (v2 - v1) * dir)
 536                 {
 537                         // went too far
 538                         trace_fraction = 1;
 539                         return;
 540                 }
 541
 542                 traceline(pos, v2, nomonsters, forent);
 543
 544                 if(trace_startsolid)
 545                 {
 546                         // we started inside solid.
 547                         // then trace from endpos to pos
 548                         t = trace_endpos;
 549                         traceline(t, pos, nomonsters, forent);
 550                         if(trace_startsolid)
 551                         {
 552                                 // t is inside solid? bad
 553                                 // force advance, then
 554                                 pos = pos + dir * nudge;
 555                         }
 556                         else
 557                         {
 558                                 // we actually LEFT solid!
 559                                 trace_fraction = ((trace_endpos - v1) * dir) / ((v2 - v1) * dir);
 560                                 return;
 561                         }
 562                 }
 563                 else
 564                 {
 565                         // pos is outside solid?!? but why?!? never mind, just return it.
 566                         trace_endpos = pos;
 567                         trace_fraction = ((trace_endpos - v1) * dir) / ((v2 - v1) * dir);
 568                         return;
 569                 }
 570         }
 571 #else
 572         tracebox_inverted(v1, '0 0 0', '0 0 0', v2, nomonsters, forent);
 573 }
 574
 575 /*
 576 ==================
 577 findbetterlocation
 578
 579 Returns a point at least 12 units away from walls
 580 (useful for explosion animations, although the blast is performed where it really happened)
 581 Ripped from DPMod
 582 ==================
 583 */
 584 vector findbetterlocation (vector org, float mindist)
 585 {
 586         vector  loc;
 587         vector vec;
 588         float c, h;
 589
 590         vec = mindist * '1 0 0';
 591         c = 0;
 592         while (c < 6)
 593         {
 594                 traceline (org, org + vec, TRUE, world);
 595                 vec = vec * -1;
 596                 if (trace_fraction < 1)
 597                 {
 598                         loc = trace_endpos;
 599                         traceline (loc, loc + vec, TRUE, world);
 600                         if (trace_fraction >= 1)
 601                                 org = loc + vec;
 602                 }
 603                 if (c & 1)
 604                 {
 605                         h = vec_y;
 606                         vec_y = vec_x;
 607                         vec_x = vec_z;
 608                         vec_z = h;
 609                 }
 610                 c = c + 1;
 611         }
 612
 613         return org;
 614 }
 615
 616 /*
 617 ==================
 618 crandom
 619
 620 Returns a random number between -1.0 and 1.0
 621 ==================
 622 */
 623 float crandom (void)
 624 {
 625         return 2 * (random () - 0.5);
 626 }
 627
 628 /*
 629 ==================
 630 Angc used for animations
 631 ==================
 632 */
 633
 634
 635 float angc (float a1, float a2)
 636 {
 637         float   a;
 638
 639         while (a1 > 180)
 640                 a1 = a1 - 360;
 641         while (a1 < -179)
 642                 a1 = a1 + 360;
 643
 644         while (a2 > 180)
 645                 a2 = a2 - 360;
 646         while (a2 < -179)
 647                 a2 = a2 + 360;
 648
 649         a = a1 - a2;
 650         while (a > 180)
 651                 a = a - 360;
 652         while (a < -179)
 653                 a = a + 360;
 654
 655         return a;
 656 }
 657
 658 .string lodtarget1;
 659 .string lodtarget2;
 660 .string lodmodel1;
 661 .string lodmodel2;
 662 .float lodmodelindex0;
 663 .float lodmodelindex1;
 664 .float lodmodelindex2;
 665 .float loddistance1;
 666 .float loddistance2;
 667
 668 float LOD_customize()
 669 {
 670         float d;
 671
 672         if(autocvar_loddebug)
 673         {
 674                 d = autocvar_loddebug;
 675                 if(d == 1)
 676                         self.modelindex = self.lodmodelindex0;
 677                 else if(d == 2 || !self.lodmodelindex2)
 678                         self.modelindex = self.lodmodelindex1;
 679                 else // if(d == 3)
 680                         self.modelindex = self.lodmodelindex2;
 681                 return TRUE;
 682         }
 683
 684         // TODO csqc network this so it only gets sent once
 685         d = vlen(NearestPointOnBox(self, other.origin) - other.origin);
 686         if(d < self.loddistance1)
 687                 self.modelindex = self.lodmodelindex0;
 688         else if(!self.lodmodelindex2 || d < self.loddistance2)
 689                 self.modelindex = self.lodmodelindex1;
 690         else
 691                 self.modelindex = self.lodmodelindex2;
 692
 693         return TRUE;
 694 }
 695
 696 void LOD_uncustomize()
 697 {
 698         self.modelindex = self.lodmodelindex0;
 699 }
 700
 701 void LODmodel_attach()
 702 {
 703         entity e;
 704
 705         if(!self.loddistance1)
 706                 self.loddistance1 = 1000;
 707         if(!self.loddistance2)
 708                 self.loddistance2 = 2000;
 709         self.lodmodelindex0 = self.modelindex;
 710
 711         if(self.lodtarget1 != "")
 712         {
 713                 e = find(world, targetname, self.lodtarget1);
 714                 if(e)
 715                 {
 716                         self.lodmodel1 = e.model;
 717                         remove(e);
 718                 }
 719         }
 720         if(self.lodtarget2 != "")
 721         {
 722                 e = find(world, targetname, self.lodtarget2);
 723                 if(e)
 724                 {
 725                         self.lodmodel2 = e.model;
 726                         remove(e);
 727                 }
 728         }
 729
 730         if(autocvar_loddebug < 0)
 731         {
 732                 self.lodmodel1 = self.lodmodel2 = ""; // don't even initialize
 733         }
 734
 735         if(self.lodmodel1 != "")
 736         {
 737                 vector mi, ma;
 738                 mi = self.mins;
 739                 ma = self.maxs;
 740
 741                 precache_model(self.lodmodel1);
 742                 setmodel(self, self.lodmodel1);
 743                 self.lodmodelindex1 = self.modelindex;
 744
 745                 if(self.lodmodel2 != "")
 746                 {
 747                         precache_model(self.lodmodel2);
 748                         setmodel(self, self.lodmodel2);
 749                         self.lodmodelindex2 = self.modelindex;
 750                 }
 751
 752                 self.modelindex = self.lodmodelindex0;
 753                 setsize(self, mi, ma);
 754         }
 755
 756         if(self.lodmodelindex1)
 757                 if not(self.SendEntity)
 758                         SetCustomizer(self, LOD_customize, LOD_uncustomize);
 759 }
 760
 761 void ApplyMinMaxScaleAngles(entity e)
 762 {
 763         if(e.angles_x != 0 || e.angles_z != 0 || self.avelocity_x != 0 || self.avelocity_z != 0) // "weird" rotation
 764         {
 765                 e.maxs = '1 1 1' * vlen(
 766                         '1 0 0' * max(-e.mins_x, e.maxs_x) +
 767                         '0 1 0' * max(-e.mins_y, e.maxs_y) +
 768                         '0 0 1' * max(-e.mins_z, e.maxs_z)
 769                 );
 770                 e.mins = -e.maxs;
 771         }
 772         else if(e.angles_y != 0 || self.avelocity_y != 0) // yaw only is a bit better
 773         {
 774                 e.maxs_x = vlen(
 775                         '1 0 0' * max(-e.mins_x, e.maxs_x) +
 776                         '0 1 0' * max(-e.mins_y, e.maxs_y)
 777                 );
 778                 e.maxs_y = e.maxs_x;
 779                 e.mins_x = -e.maxs_x;
 780                 e.mins_y = -e.maxs_x;
 781         }
 782         if(e.scale)
 783                 setsize(e, e.mins * e.scale, e.maxs * e.scale);
 784         else
 785                 setsize(e, e.mins, e.maxs);
 786 }
 787
 788 void SetBrushEntityModel()
 789 {
 790         if(self.model != "")
 791         {
 792                 precache_model(self.model);
 793                 setmodel(self, self.model); // no precision needed
 794                 InitializeEntity(self, LODmodel_attach, INITPRIO_FINDTARGET);
 795         }
 796         setorigin(self, self.origin);
 797         ApplyMinMaxScaleAngles(self);
 798 }
 799
 800 void SetBrushEntityModelNoLOD()
 801 {
 802         if(self.model != "")
 803         {
 804                 precache_model(self.model);
 805                 setmodel(self, self.model); // no precision needed
 806         }
 807         setorigin(self, self.origin);
 808         ApplyMinMaxScaleAngles(self);
 809 }
 810
 811 /*
 812 ================
 813 InitTrigger
 814 ================
 815 */
 816
 817 void SetMovedir()
 818 {
 819         if (self.movedir != '0 0 0')
 820                 self.movedir = normalize(self.movedir);
 821         else
 822         {
 823                 makevectors (self.angles);
 824                 self.movedir = v_forward;
 825         }
 826
 827         self.angles = '0 0 0';
 828 };
 829
 830 void InitTrigger()
 831 {
 832 // trigger angles are used for one-way touches.  An angle of 0 is assumed
 833 // to mean no restrictions, so use a yaw of 360 instead.
 834         SetMovedir ();
 835         self.solid = SOLID_TRIGGER;
 836         SetBrushEntityModel();
 837         self.movetype = MOVETYPE_NONE;
 838         self.modelindex = 0;
 839         self.model = "";
 840 };
 841
 842 void InitSolidBSPTrigger()
 843 {
 844 // trigger angles are used for one-way touches.  An angle of 0 is assumed
 845 // to mean no restrictions, so use a yaw of 360 instead.
 846         SetMovedir ();
 847         self.solid = SOLID_BSP;
 848         SetBrushEntityModel();
 849         self.movetype = MOVETYPE_NONE; // why was this PUSH? -div0
 850 //      self.modelindex = 0;
 851         self.model = "";
 852 };
 853
 854 float InitMovingBrushTrigger()
 855 {
 856 // trigger angles are used for one-way touches.  An angle of 0 is assumed
 857 // to mean no restrictions, so use a yaw of 360 instead.
 858         self.solid = SOLID_BSP;
 859         SetBrushEntityModel();
 860         self.movetype = MOVETYPE_PUSH;
 861         if(self.modelindex == 0)
 862         {
 863                 objerror("InitMovingBrushTrigger: no brushes found!");
 864                 return 0;
 865         }
 866         return 1;
 867 };