qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50 float headshot;
  51 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  52
  53 .float dmg_team;
  54 .float teamkill_complain;
  55 .float teamkill_soundtime;
  56 .entity teamkill_soundsource;
  57 .entity pusher;
  58 .float istypefrag;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teamplay)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 entity GiveFrags_randomweapons;
 106 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
 107 {
 108         // TODO route through PlayerScores instead
 109         if(gameover) return;
 110
 111         if(f < 0)
 112         {
 113                 if(targ == attacker)
 114                 {
 115                         // suicide
 116                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 117                 }
 118                 else
 119                 {
 120                         // teamkill
 121                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 122                 }
 123         }
 124         else
 125         {
 126                 // regular frag
 127                 PlayerScore_Add(attacker, SP_KILLS, 1);
 128                 if(targ.playerid)
 129                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 130         }
 131
 132         PlayerScore_Add(targ, SP_DEATHS, 1);
 133
 134         if(g_arena && arena_roundbased)
 135                 return;
 136
 137         if(targ != attacker) // not for suicides
 138         if(g_weaponarena_random)
 139         {
 140                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 141                 float culprit;
 142                 culprit = DEATH_WEAPONOF(deathtype);
 143                 if(!culprit)
 144                         culprit = attacker.weapon;
 145                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 146                         culprit = attacker.weapon;
 147
 148                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 149                 {
 150                         // no exchange
 151                 }
 152                 else
 153                 {
 154                         if(!GiveFrags_randomweapons)
 155                         {
 156                                 GiveFrags_randomweapons = spawn();
 157                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 158                         }
 159
 160                         if(inWarmupStage)
 161                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 162                         else
 163                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 164
 165                         // all others (including the culprit): remove
 166                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 167                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 168
 169                         // among the remaining ones, choose one by random
 170                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 171
 172                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 173                         {
 174                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 175                                 WEPSET_ANDNOT_EW(attacker, culprit);
 176                         }
 177                 }
 178
 179                 // after a frag, choose another random weapon set
 180                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 181                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 182         }
 183
 184         // FIXME fix the mess this is (we have REAL points now!)
 185         entity oldself;
 186         oldself = self;
 187         self = attacker;
 188         frag_attacker = attacker;
 189         frag_target = targ;
 190         frag_score = f;
 191         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 192         {
 193                 f = frag_score;
 194                 self = oldself;
 195         }
 196         else
 197         {
 198                 self = oldself;
 199                 if(g_runematch)
 200                 {
 201                         f = RunematchHandleFrags(attacker, targ, f);
 202                 }
 203                 else if(g_lms)
 204                 {
 205                         // remove a life
 206                         float tl;
 207                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 208                         if(tl < lms_lowest_lives)
 209                                 lms_lowest_lives = tl;
 210                         if(tl <= 0)
 211                         {
 212                                 if(!lms_next_place)
 213                                         lms_next_place = player_count;
 214                                 else
 215                                         lms_next_place = min(lms_next_place, player_count);
 216                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 217                                 --lms_next_place;
 218                         }
 219                         f = 0;
 220                 }
 221         }
 222
 223         attacker.totalfrags += f;
 224
 225         if(f)
 226                 UpdateFrags(attacker, f);
 227 }
 228
 229 string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 230 {
 231         string health_output = string_null;
 232         string ping_output = string_null;
 233         string handicap_output = string_null;
 234         string output = string_null;
 235
 236         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 237         {
 238                 // health/armor of attacker (person who killed you)
 239                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 240                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 241
 242                 // ping display
 243                 if(autocvar_sv_fraginfo_ping)
 244                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 245
 246                 // handicap display
 247                 if(autocvar_sv_fraginfo_handicap)
 248                 {
 249                         if(autocvar_sv_fraginfo_handicap == 2)
 250                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 251                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 252                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 253                 }
 254
 255                 // format the string
 256                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 257                         ping_output, (handicap_output ? "^7 / " : ""),
 258                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 259
 260                 // add new line to the beginning if there is a message
 261                 if(output) { output = strcat("\n", output); }
 262         }
 263
 264         return output;
 265 }
 266
 267 string AppendItemcodes(string s, entity player)
 268 {
 269         float w;
 270         w = player.weapon;
 271         //if(w == 0)
 272         //      w = player.switchweapon;
 273         if(w == 0)
 274                 w = player.cnt; // previous weapon!
 275         s = strcat(s, ftos(w));
 276         if(time < player.strength_finished)
 277                 s = strcat(s, "S");
 278         if(time < player.invincible_finished)
 279                 s = strcat(s, "I");
 280         if(player.flagcarried != world)
 281                 s = strcat(s, "F");
 282         if(player.BUTTON_CHAT)
 283                 s = strcat(s, "T");
 284         if(player.kh_next)
 285                 s = strcat(s, "K");
 286         if(player.runes)
 287                 s = strcat(s, "|", ftos(player.runes));
 288         return s;
 289 }
 290
 291 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 292 {
 293         string s;
 294         if(!autocvar_sv_eventlog)
 295                 return;
 296         s = strcat(":kill:", mode);
 297         s = strcat(s, ":", ftos(killer.playerid));
 298         s = strcat(s, ":", ftos(killed.playerid));
 299         s = strcat(s, ":type=", ftos(deathtype));
 300         s = strcat(s, ":items=");
 301         s = AppendItemcodes(s, killer);
 302         if(killed != killer)
 303         {
 304                 s = strcat(s, ":victimitems=");
 305                 s = AppendItemcodes(s, killed);
 306         }
 307         GameLogEcho(s);
 308 }
 309
 310 void Send_KillNotification (string s1, string s2, string s3, float msg, float type)
 311 {
 312         WriteByte(MSG_ALL, SVC_TEMPENTITY);
 313         WriteByte(MSG_ALL, TE_CSQC_KILLNOTIFY);
 314         WriteString(MSG_ALL, s1);
 315         WriteString(MSG_ALL, s2);
 316         WriteString(MSG_ALL, s3);
 317         WriteShort(MSG_ALL, msg);
 318         WriteByte(MSG_ALL, type);
 319 }
 320
 321 // Function is used to send a generic centerprint whose content CSQC gets to decide (gentle version or not in the below cases)
 322 void Send_CSQC_KillCenterprint(entity e, string s1, string s2, float msg, float type)
 323 {
 324         if (clienttype(e) == CLIENTTYPE_REAL)
 325         {
 326                 msg_entity = e;
 327                 WRITESPECTATABLE_MSG_ONE({
 328                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 329                         WriteByte(MSG_ONE, TE_CSQC_KILLCENTERPRINT);
 330                         WriteString(MSG_ONE, s1);
 331                         WriteString(MSG_ONE, s2);
 332                         WriteShort(MSG_ONE, msg);
 333                         WriteByte(MSG_ONE, type);
 334                 });
 335         }
 336 }
 337
 338 void Obituary (entity attacker, entity inflictor, entity targ, float deathtype)
 339 {
 340         string  s, a, msg;
 341         float w, type;
 342
 343         if (targ.classname == "player")
 344         {
 345                 s = targ.netname;
 346                 a = attacker.netname;
 347
 348                 if (targ == attacker) // suicides
 349                 {
 350                         if (deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 351                                 msg = ColoredTeamName(targ.team); // TODO: check if needed?
 352                         else
 353                                 msg = "";
 354             if(!g_cts) // no "killed your own dumb self" message in CTS
 355                 Send_CSQC_KillCenterprint(targ, msg, "", deathtype, MSG_SUICIDE);
 356
 357                         if(deathtype != DEATH_TEAMCHANGE && deathtype != DEATH_QUIET)
 358                         {
 359                                 LogDeath("suicide", deathtype, targ, targ);
 360                                 GiveFrags(attacker, targ, -1, deathtype);
 361                         }
 362
 363                         if (targ.killcount > 2)
 364                                 msg = ftos(targ.killcount);
 365                         else
 366                                 msg = "";
 367                         if(teamplay && deathtype == DEATH_MIRRORDAMAGE)
 368                         {
 369                                 if(attacker.team == COLOR_TEAM1)
 370                                         deathtype = KILL_TEAM_RED;
 371                                 else
 372                                         deathtype = KILL_TEAM_BLUE;
 373                         }
 374
 375                         Send_KillNotification(s, msg, ftos(w), deathtype, MSG_SUICIDE);
 376                 }
 377                 else if (attacker.classname == "player")
 378                 {
 379                         if(!IsDifferentTeam(attacker, targ))
 380                         {
 381                                 if(attacker.team == COLOR_TEAM1)
 382                                         type = KILL_TEAM_RED;
 383                                 else
 384                                         type = KILL_TEAM_BLUE;
 385
 386                                 GiveFrags(attacker, targ, -1, deathtype);
 387
 388                                 Send_CSQC_KillCenterprint(attacker, s, "", type, MSG_KILL);
 389
 390                                 if (targ.killcount > 2)
 391                                         msg = ftos(targ.killcount);
 392                                 else
 393                                         msg = "";
 394
 395                                 if (attacker.killcount > 2) {
 396                                         msg = ftos(attacker.killcount);
 397                                         type = KILL_TEAM_SPREE;
 398                                 }
 399                                 Send_KillNotification(a, s, msg, type, MSG_KILL);
 400
 401                                 attacker.killcount = 0;
 402
 403                                 LogDeath("tk", deathtype, attacker, targ);
 404                         }
 405                         else
 406                         {
 407                                 if (!checkrules_firstblood)
 408                                 {
 409                                         checkrules_firstblood = TRUE;
 410                                         Send_KillNotification(a, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 411                                         // TODO: make these print a newline if they dont
 412                                         Send_CSQC_KillCenterprint(attacker, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 413                                         Send_CSQC_KillCenterprint(targ, "", "", KILL_FIRST_VICTIM, MSG_KILL);
 414                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 415                                         PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 416                                 }
 417
 418                                 if(targ.istypefrag) {
 419                                         Send_CSQC_KillCenterprint(attacker, s, Obituary_ExtraFragInfo(targ), KILL_TYPEFRAG, MSG_KILL);
 420                                         Send_CSQC_KillCenterprint(targ, a, Obituary_ExtraFragInfo(attacker), KILL_TYPEFRAGGED, MSG_KILL);
 421                                 } else {
 422                                         Send_CSQC_KillCenterprint(attacker, s, Obituary_ExtraFragInfo(targ), KILL_FRAG, MSG_KILL);
 423                                         Send_CSQC_KillCenterprint(targ, a, Obituary_ExtraFragInfo(attacker), KILL_FRAGGED, MSG_KILL);
 424                                 }
 425
 426                                 attacker.taunt_soundtime = time + 1;
 427
 428                                 if (deathtype == DEATH_HURTTRIGGER && inflictor.message2 != "")
 429                                         msg = inflictor.message2;
 430                                 else if (deathtype == DEATH_CUSTOM)
 431                                         msg = deathmessage;
 432                                 else
 433                                         msg = "";
 434
 435                                 if(strstrofs(msg, "%", 0) < 0)
 436                                         msg = strcat("%s ", msg, " by %s");
 437
 438                                 Send_KillNotification(a, s, msg, deathtype, MSG_KILL);
 439
 440                                 GiveFrags(attacker, targ, 1, deathtype);
 441
 442                                 if (targ.killcount > 2) {
 443                                         Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE);
 444                                 }
 445
 446                                 attacker.killcount = attacker.killcount + 1;
 447
 448                                 if (attacker.killcount == 3)
 449                                 {
 450                                         Send_KillNotification(a, "", "", KILL_SPREE_3, MSG_SPREE);
 451                                         AnnounceTo(attacker, "03kills");
 452                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_3, 1);
 453                                 }
 454                                 else if (attacker.killcount == 5)
 455                                 {
 456                                         Send_KillNotification(a, "", "", KILL_SPREE_5, MSG_SPREE);
 457                                         AnnounceTo(attacker, "05kills");
 458                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_5, 1);
 459                                 }
 460                                 else if (attacker.killcount == 10)
 461                                 {
 462                                         Send_KillNotification(a, "", "", KILL_SPREE_10, MSG_SPREE);
 463                                         AnnounceTo(attacker, "10kills");
 464                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_10, 1);
 465                                 }
 466                                 else if (attacker.killcount == 15)
 467                                 {
 468                                         Send_KillNotification(a, "", "", KILL_SPREE_15, MSG_SPREE);
 469                                         AnnounceTo(attacker, "15kills");
 470                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_15, 1);
 471                                 }
 472                                 else if (attacker.killcount == 20)
 473                                 {
 474                                         Send_KillNotification(a, "", "", KILL_SPREE_20, MSG_SPREE);
 475                                         AnnounceTo(attacker, "20kills");
 476                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_20, 1);
 477                                 }
 478                                 else if (attacker.killcount == 25)
 479                                 {
 480                                         Send_KillNotification(a, "", "", KILL_SPREE_25, MSG_SPREE);
 481                                         AnnounceTo(attacker, "25kills");
 482                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_25, 1);
 483                                 }
 484                                 else if (attacker.killcount == 30)
 485                                 {
 486                                         Send_KillNotification(a, "", "", KILL_SPREE_30, MSG_SPREE);
 487                                         AnnounceTo(attacker, "30kills");
 488                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_30, 1);
 489                                 }
 490                                 else if (attacker.killcount > 2) {
 491                                         Send_KillNotification(a, ftos(attacker.killcount), "", KILL_SPREE, MSG_SPREE);
 492                                 }
 493                                 LogDeath("frag", deathtype, attacker, targ);
 494                         }
 495                 }
 496                 else
 497                 {
 498                         Send_CSQC_KillCenterprint(targ, "", "", deathtype, MSG_KILL_ACTION);
 499                         if (deathtype == DEATH_HURTTRIGGER && inflictor.message != "")
 500                                 msg = inflictor.message;
 501                         else if (deathtype == DEATH_CUSTOM)
 502                                 msg = deathmessage;
 503                         else
 504                                 msg = "";
 505                         if(strstrofs(msg, "%", 0) < 0)
 506                                 msg = strcat("%s ", msg);
 507
 508                         GiveFrags(targ, targ, -1, deathtype);
 509                         if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
 510                                 AnnounceTo(targ, "botlike");
 511                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 512                         }
 513                         Send_KillNotification(s, msg, "", deathtype, MSG_KILL_ACTION);
 514
 515                         if (targ.killcount > 2)
 516                                 Send_KillNotification(s, ftos(targ.killcount), "", 0, MSG_KILL_ACTION_SPREE);
 517
 518                         LogDeath("accident", deathtype, targ, targ);
 519                 }
 520
 521                 targ.death_origin = targ.origin;
 522                 if(targ != attacker)
 523                         targ.killer_origin = attacker.origin;
 524
 525                 // FIXME: this should go in PutClientInServer
 526                 if (targ.killcount)
 527                         targ.killcount = 0;
 528         }
 529 }
 530
 531 // these are updated by each Damage call for use in button triggering and such
 532 entity damage_targ;
 533 entity damage_inflictor;
 534 entity damage_attacker;
 535
 536 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 537 {
 538         float mirrordamage;
 539         float mirrorforce;
 540         float teamdamage0;
 541         entity attacker_save;
 542         mirrordamage = 0;
 543         mirrorforce = 0;
 544
 545         if (gameover || targ.killcount == -666)
 546                 return;
 547
 548         entity oldself;
 549         oldself = self;
 550         self = targ;
 551         damage_targ = targ;
 552         damage_inflictor = inflictor;
 553         damage_attacker = attacker;
 554                 attacker_save = attacker;
 555
 556         if(targ.classname == "player")
 557                 if(targ.hook)
 558                         if(targ.hook.aiment)
 559                                 if(targ.hook.aiment == attacker)
 560                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 561
 562         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 563         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 564         {
 565                 if(targ.classname == "player")
 566                         if not(IsDifferentTeam(targ, attacker))
 567                         {
 568                                 self = oldself;
 569                                 return;
 570                         }
 571         }
 572
 573         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE || deathtype == DEATH_QUIET)
 574         {
 575                 // These are ALWAYS lethal
 576                 // No damage modification here
 577                 // Instead, prepare the victim for his death...
 578                 targ.armorvalue = 0;
 579                 targ.spawnshieldtime = 0;
 580                 targ.health = 0.9; // this is < 1
 581                 targ.flags -= targ.flags & FL_GODMODE;
 582                 damage = 100000;
 583         }
 584         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 585         {
 586                 // no processing
 587         }
 588         else
 589         {
 590                 /*
 591                 skill based bot damage? gtfo. (tZork)
 592                 if (targ.classname == "player")
 593                 if (attacker.classname == "player")
 594                 if (!targ.isbot)
 595                 if (attacker.isbot)
 596                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 597         */
 598
 599                 // nullify damage if teamplay is on
 600                 if(deathtype != DEATH_TELEFRAG)
 601                 if(attacker.classname == "player")
 602                 {
 603                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 604                         {
 605                                 damage = 0;
 606                                 force = '0 0 0';
 607                         }
 608                         else if(!IsDifferentTeam(attacker, targ))
 609                         {
 610                                 if(autocvar_teamplay_mode == 1)
 611                                         damage = 0;
 612                                 else if(attacker != targ)
 613                                 {
 614                                         if(autocvar_teamplay_mode == 3)
 615                                                 damage = 0;
 616                                         else if(autocvar_teamplay_mode == 4)
 617                                         {
 618                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 619                                                 {
 620                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 621                                                         attacker.dmg_team = attacker.dmg_team + damage;
 622                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 623                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 624                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 625                                                         if(g_minstagib)
 626                                                         {
 627                                                                 if(autocvar_g_friendlyfire == 0)
 628                                                                         damage = 0;
 629                                                         }
 630                                                         else if(g_ca)
 631                                                                 damage = 0;
 632                                                         else
 633                                                                 damage = autocvar_g_friendlyfire * damage;
 634                                                         // mirrordamage will be used LATER
 635
 636                                                         if(autocvar_g_mirrordamage_virtual)
 637                                                         {
 638                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 639                                                                 attacker.dmg_take += v_x;
 640                                                                 attacker.dmg_save += v_y;
 641                                                                 attacker.dmg_inflictor = inflictor;
 642                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 643                                                                 mirrorforce = 0;
 644                                                         }
 645
 646                                                         if(autocvar_g_friendlyfire_virtual)
 647                                                         {
 648                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 649                                                                 targ.dmg_take += v_x;
 650                                                                 targ.dmg_save += v_y;
 651                                                                 targ.dmg_inflictor = inflictor;
 652                                                                 damage = 0;
 653                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 654                                                                         force = '0 0 0';
 655                                                         }
 656                                                 }
 657                                                 else
 658                                                         damage = 0;
 659                                         }
 660                                 }
 661                         }
 662                 }
 663
 664                 if(targ.classname == "player")
 665                 if(attacker.classname == "player")
 666                 if(attacker != targ)
 667                 {
 668                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 669                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 670                 }
 671
 672                 if(targ.classname == "player")
 673                 if (g_minstagib)
 674                 {
 675                         if ((deathtype == DEATH_FALL)  ||
 676                                 (deathtype == DEATH_DROWN) ||
 677                                 (deathtype == DEATH_SLIME) ||
 678                                 (deathtype == DEATH_LAVA)  ||
 679                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 680                         {
 681                                 self = oldself;
 682                                 return;
 683                         }
 684                         if(damage > 0)
 685                             damage = 10000;
 686                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 687                         {
 688                                 targ.armorvalue -= 1;
 689                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 690                                 damage = 0;
 691                                 targ.hitsound += 1;
 692                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 693                         }
 694                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 695                         {
 696                                 damage = 0;
 697                                 mirrordamage = 0;
 698                                 if (targ != attacker)
 699                                 {
 700                                         if ((targ.health >= 1) && (targ.classname == "player"))
 701                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 702                                         force = '0 0 0';
 703                                         // keep mirrorforce
 704                                         attacker = targ;
 705                                 }
 706                         }
 707                 }
 708
 709                 if not(DEATH_ISSPECIAL(deathtype))
 710                 {
 711                         damage *= g_weapondamagefactor;
 712                         mirrordamage *= g_weapondamagefactor;
 713                         force = force * g_weaponforcefactor;
 714                         mirrorforce *= g_weaponforcefactor;
 715                 }
 716
 717                 // should this be changed at all? If so, in what way?
 718                 frag_attacker = attacker;
 719                 frag_target = targ;
 720                 frag_damage = damage;
 721                 frag_force = force;
 722         frag_deathtype = deathtype;
 723                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 724                 damage = frag_damage;
 725                 force = frag_force;
 726
 727                 // apply strength multiplier
 728                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 729                 {
 730                         if(targ == attacker)
 731                         {
 732                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 733                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 734                         }
 735                         else
 736                         {
 737                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 738                                 force = force * autocvar_g_balance_powerup_strength_force;
 739                         }
 740                 }
 741
 742                 // apply invincibility multiplier
 743                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 744                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 745
 746                 if (targ == attacker)
 747                 {
 748                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 749                                 damage = 0;
 750                         else
 751                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 752                 }
 753
 754                 if(g_runematch)
 755                 {
 756                         // apply strength rune
 757                         if (attacker.runes & RUNE_STRENGTH)
 758                         {
 759                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 760                                 {
 761                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 762                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 763                                 }
 764                                 else
 765                                 {
 766                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 767                                         force = force * autocvar_g_balance_rune_strength_force;
 768                                 }
 769                         }
 770                         else if (attacker.runes & CURSE_WEAK)
 771                         {
 772                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 773                                 force = force * autocvar_g_balance_curse_weak_force;
 774                         }
 775
 776                         // apply defense rune
 777                         if (targ.runes & RUNE_DEFENSE)
 778                         {
 779                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 780                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 781                                 else
 782                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 783                         }
 784                         else if (targ.runes & CURSE_VULNER)
 785                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 786                 }
 787
 788                 // count the damage
 789                 if(attacker)
 790                 if(!targ.deadflag)
 791                 if(targ.takedamage == DAMAGE_AIM)
 792                 if(targ != attacker)
 793                 {
 794                         if(damage_headshotbonus)
 795                         {
 796                                 if(targ.classname == "player")
 797                                 {
 798                                         // HEAD SHOT:
 799                                         // find height of hit on player axis
 800                                         // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 801                                         vector headmins, headmaxs, org;
 802                                         org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 803                                         headmins = org + GetHeadshotMins(targ);
 804                                         headmaxs = org + GetHeadshotMaxs(targ);
 805                                         if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 806                                         {
 807                                                 deathtype |= HITTYPE_HEADSHOT;
 808                                         }
 809                                 }
 810                                 else if(targ.classname == "turret_head")
 811                                 {
 812                                         deathtype |= HITTYPE_HEADSHOT;
 813                                 }
 814                                 if(deathtype & HITTYPE_HEADSHOT)
 815                                         if(damage_headshotbonus > 0)
 816                                                 damage *= 1 + damage_headshotbonus;
 817                         }
 818
 819                         entity victim;
 820                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 821                                 victim = targ.owner;
 822                         else
 823                                 victim = targ;
 824
 825                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 826                         {
 827                                 if(IsDifferentTeam(victim, attacker))
 828                                 {
 829                                         if(damage > 0)
 830                                         {
 831                                                 if(deathtype != DEATH_FIRE)
 832                                                 {
 833                                                         if(victim.BUTTON_CHAT)
 834                                                                 attacker.typehitsound += 1;
 835                                                         else
 836                                                                 attacker.hitsound += 1;
 837                                                 }
 838
 839                                                 damage_goodhits += 1;
 840                                                 damage_gooddamage += damage;
 841
 842                                                 if not(DEATH_ISSPECIAL(deathtype))
 843                                                 {
 844                                                         if(targ.classname == "player") // don't do this for vehicles
 845                                                         if(!g_minstagib)
 846                                                         if(IsFlying(victim))
 847                                                                 yoda = 1;
 848
 849                                                         if(g_minstagib)
 850                                                         if(victim.items & IT_STRENGTH)
 851                                                                 yoda = 1;
 852
 853                                                         if(deathtype & HITTYPE_HEADSHOT)
 854                                                                 headshot = 1;
 855                                                 }
 856                                         }
 857                                 }
 858                                 else
 859                                 {
 860                                         if(deathtype != DEATH_FIRE)
 861                                         {
 862                                                 attacker.typehitsound += 1;
 863                                         }
 864                                         if(mirrordamage > 0)
 865                                                 if(time > attacker.teamkill_complain)
 866                                                 {
 867                                                         attacker.teamkill_complain = time + 5;
 868                                                         attacker.teamkill_soundtime = time + 0.4;
 869                                                         attacker.teamkill_soundsource = targ;
 870                                                 }
 871                                 }
 872                         }
 873                 }
 874         }
 875
 876         // apply push
 877         if (self.damageforcescale)
 878         if (vlen(force))
 879         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 880         {
 881                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 882                 if(self.movetype == MOVETYPE_PHYSICS)
 883                 {
 884                         entity farcent;
 885                         farcent = spawn();
 886                         farcent.classname = "farce";
 887                         farcent.enemy = self;
 888                         farcent.movedir = farce * 10;
 889                         if(self.mass)
 890                                 farcent.movedir = farcent.movedir * self.mass;
 891                         farcent.origin = hitloc;
 892                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 893                         farcent.nextthink = time + 0.1;
 894                         farcent.think = SUB_Remove;
 895                 }
 896                 else
 897                         self.velocity = self.velocity + farce;
 898                 self.flags &~= FL_ONGROUND;
 899                 UpdateCSQCProjectile(self);
 900         }
 901         // apply damage
 902         if (damage != 0 || (self.damageforcescale && vlen(force)))
 903         if (self.event_damage)
 904                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 905         self = oldself;
 906
 907         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 908         {
 909                 if(g_runematch)
 910                 {
 911                         if (attacker.runes & RUNE_VAMPIRE)
 912                         {
 913                         // apply vampire rune
 914                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 915                                 {
 916                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 917                                         attacker.health = bound(
 918                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 919                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 920                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 921                                 }
 922                                 else
 923                                 {
 924                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 925                                         attacker.health = bound(
 926                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 927                                                                                         // empathy won't let you gain health in the same way...
 928                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 929                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 930                                         }
 931                         }
 932                         // apply empathy curse
 933                         else if (attacker.runes & CURSE_EMPATHY)
 934                         {
 935                                 attacker.health = bound(
 936                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 937                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 938                                         attacker.health);
 939                         }
 940                 }
 941         }
 942
 943         // apply mirror damage if any
 944         if(mirrordamage > 0 || mirrorforce > 0)
 945         {
 946                 attacker = attacker_save;
 947                 if(g_minstagib)
 948                 if(mirrordamage > 0)
 949                 {
 950                         // just lose extra LIVES, don't kill the player for mirror damage
 951                         if(attacker.armorvalue > 0)
 952                         {
 953                                 attacker.armorvalue = attacker.armorvalue - 1;
 954                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 955                                 attacker.hitsound += 1;
 956                         }
 957                         mirrordamage = 0;
 958                 }
 959
 960                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 961                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 962         }
 963 }
 964
 965 float RadiusDamage_running;
 966 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 967         // Returns total damage applies to creatures
 968 {
 969         entity  targ;
 970         vector  blastorigin;
 971         vector  force;
 972         float   total_damage_to_creatures;
 973         entity  next;
 974         float   tfloordmg;
 975         float   tfloorforce;
 976
 977         float stat_damagedone;
 978
 979         if(RadiusDamage_running)
 980         {
 981                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 982                 return 0;
 983         }
 984
 985         RadiusDamage_running = 1;
 986
 987         tfloordmg = autocvar_g_throughfloor_damage;
 988         tfloorforce = autocvar_g_throughfloor_force;
 989
 990         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 991         total_damage_to_creatures = 0;
 992
 993         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 994                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 995                 {
 996                         force = inflictor.velocity;
 997                         if(vlen(force) == 0)
 998                                 force = '0 0 -1';
 999                         else
1000                                 force = normalize(force);
1001                         if(forceintensity >= 0)
1002                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
1003                         else
1004                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
1005                 }
1006
1007         stat_damagedone = 0;
1008
1009         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
1010         while (targ)
1011         {
1012                 next = targ.chain;
1013                 if (targ != inflictor)
1014                         if (ignore != targ) if(targ.takedamage)
1015                         {
1016                                 vector nearest;
1017                                 vector diff;
1018                                 float power;
1019
1020                                 // LordHavoc: measure distance to nearest point on target (not origin)
1021                                 // (this guarentees 100% damage on a touch impact)
1022                                 nearest = targ.WarpZone_findradius_nearest;
1023                                 diff = targ.WarpZone_findradius_dist;
1024                                 // round up a little on the damage to ensure full damage on impacts
1025                                 // and turn the distance into a fraction of the radius
1026                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1027                                 //bprint(" ");
1028                                 //bprint(ftos(power));
1029                                 //if (targ == attacker)
1030                                 //      print(ftos(power), "\n");
1031                                 if (power > 0)
1032                                 {
1033                                         float finaldmg;
1034                                         if (power > 1)
1035                                                 power = 1;
1036                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1037                                         if (finaldmg > 0)
1038                                         {
1039                                                 float a;
1040                                                 float c;
1041                                                 vector hitloc;
1042                                                 vector myblastorigin;
1043                                                 vector center;
1044
1045                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1046
1047                                                 // if it's a player, use the view origin as reference
1048                                                 center = CENTER_OR_VIEWOFS(targ);
1049
1050                                                 force = normalize(center - myblastorigin);
1051                                                 force = force * (finaldmg / coredamage) * forceintensity;
1052                                                 hitloc = nearest;
1053
1054                                                 if(targ != directhitentity)
1055                                                 {
1056                                                         float hits;
1057                                                         float total;
1058                                                         float hitratio;
1059                                                         float mininv_f, mininv_d;
1060
1061                                                         // test line of sight to multiple positions on box,
1062                                                         // and do damage if any of them hit
1063                                                         hits = 0;
1064
1065                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1066                                                         // so for a given max stddev:
1067                                                         // n = (1 / (2 * max stddev of hitratio))^2
1068
1069                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1070                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1071
1072                                                         if(autocvar_g_throughfloor_debug)
1073                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1074
1075                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1076
1077                                                         if(autocvar_g_throughfloor_debug)
1078                                                                 print(sprintf(" steps=%f", total));
1079
1080                                                         if (targ.classname == "player")
1081                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1082                                                         else
1083                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1084
1085                                                         if(autocvar_g_throughfloor_debug)
1086                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1087
1088                                                         for(c = 0; c < total; ++c)
1089                                                         {
1090                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1091                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1092                                                                 if (trace_fraction == 1 || trace_ent == targ)
1093                                                                 {
1094                                                                         ++hits;
1095                                                                         if (hits > 1)
1096                                                                                 hitloc = hitloc + nearest;
1097                                                                         else
1098                                                                                 hitloc = nearest;
1099                                                                 }
1100                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1101                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1102                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1103                                                         }
1104
1105                                                         nearest = hitloc * (1 / max(1, hits));
1106                                                         hitratio = (hits / total);
1107                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1108                                                         finaldmg = finaldmg * a;
1109                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1110                                                         force = force * a;
1111
1112                                                         if(autocvar_g_throughfloor_debug)
1113                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1114                                                 }
1115
1116                                                 // laser force adjustments :P
1117                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1118                                                 {
1119                                                         if (targ == attacker)
1120                                                         {
1121                                                                 vector vel;
1122
1123                                                                 float force_zscale;
1124                                                                 float force_velocitybiasramp;
1125                                                                 float force_velocitybias;
1126
1127                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1128                                                                 if(deathtype & HITTYPE_SECONDARY)
1129                                                                 {
1130                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1131                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1132                                                                 }
1133                                                                 else
1134                                                                 {
1135                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1136                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1137                                                                 }
1138
1139                                                                 vel = targ.velocity;
1140                                                                 vel_z = 0;
1141                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1142                                                                 force =
1143                                                                         vlen(force)
1144                                                                         *
1145                                                                         normalize(normalize(force) + vel);
1146
1147                                                                 force_z *= force_zscale;
1148                                                         }
1149                                                         else
1150                                                         {
1151                                                                 if(deathtype & HITTYPE_SECONDARY)
1152                                                                 {
1153                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1154                                                                 }
1155                                                                 else
1156                                                                 {
1157                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1158                                                                 }
1159                                                         }
1160                                                 }
1161
1162                                                 //if (targ == attacker)
1163                                                 //{
1164                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1165                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1166                                                 //      print(" (", ftos(a), ")\n");
1167                                                 //}
1168                                                 if(finaldmg || vlen(force))
1169                                                 {
1170                                                         if(targ.iscreature)
1171                                                         {
1172                                                                 total_damage_to_creatures += finaldmg;
1173
1174                                                                 if(accuracy_isgooddamage(attacker, targ))
1175                                                                         stat_damagedone += finaldmg;
1176                                                         }
1177
1178                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1179                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1180                                                         else
1181                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1182                                                 }
1183                                         }
1184                                 }
1185                         }
1186                 targ = next;
1187         }
1188
1189         RadiusDamage_running = 0;
1190
1191         if(!DEATH_ISSPECIAL(deathtype))
1192                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1193
1194         return total_damage_to_creatures;
1195 }
1196
1197 .float fire_damagepersec;
1198 .float fire_endtime;
1199 .float fire_deathtype;
1200 .entity fire_owner;
1201 .float fire_hitsound;
1202 .entity fire_burner;
1203
1204 void fireburner_think();
1205
1206 float Fire_IsBurning(entity e)
1207 {
1208         return (time < e.fire_endtime);
1209 }
1210
1211 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1212 {
1213         float dps;
1214         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1215
1216         if(e.classname == "player")
1217         {
1218                 if(e.deadflag)
1219                         return -1;
1220         }
1221         else
1222         {
1223                 if(!e.fire_burner)
1224                 {
1225                         // print("adding a fire burner to ", e.classname, "\n");
1226                         e.fire_burner = spawn();
1227                         e.fire_burner.classname = "fireburner";
1228                         e.fire_burner.think = fireburner_think;
1229                         e.fire_burner.nextthink = time;
1230                         e.fire_burner.owner = e;
1231                 }
1232         }
1233
1234         t = max(t, 0.1);
1235         dps = d / t;
1236         if(Fire_IsBurning(e))
1237         {
1238                 mintime = e.fire_endtime - time;
1239                 maxtime = max(mintime, t);
1240
1241                 mindps = e.fire_damagepersec;
1242                 maxdps = max(mindps, dps);
1243
1244                 if(maxtime > mintime || maxdps > mindps)
1245                 {
1246                         // Constraints:
1247
1248                         // damage we have right now
1249                         mindamage = mindps * mintime;
1250
1251                         // damage we want to get
1252                         maxdamage = mindamage + d;
1253
1254                         // but we can't exceed maxtime * maxdps!
1255                         totaldamage = min(maxdamage, maxtime * maxdps);
1256
1257                         // LEMMA:
1258                         // Look at:
1259                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1260                         // We see:
1261                         // totaldamage <= maxtime * maxdps
1262                         // ==> totaldamage / maxdps <= maxtime.
1263                         // We also see:
1264                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1265                         //                     >= min(mintime, maxtime)
1266                         // ==> totaldamage / maxdps >= mintime.
1267
1268                         /*
1269                         // how long do we damage then?
1270                         // at least as long as before
1271                         // but, never exceed maxdps
1272                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1273                         */
1274
1275                         // alternate:
1276                         // at most as long as maximum allowed
1277                         // but, never below mindps
1278                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1279
1280                         // assuming t > mintime, dps > mindps:
1281                         // we get d = t * dps = maxtime * maxdps
1282                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1283                         // totaldamage / maxdps = maxtime
1284                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1285                         // FROM THIS:
1286                         // a) totaltime = max(mintime, maxtime) = maxtime
1287                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1288
1289                         // assuming t <= mintime:
1290                         // we get maxtime = mintime
1291                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1292                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1293
1294                         // assuming dps <= mindps:
1295                         // we get mindps = maxdps.
1296                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1297                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1298                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1299
1300                         e.fire_damagepersec = totaldamage / totaltime;
1301                         e.fire_endtime = time + totaltime;
1302                         if(totaldamage > 1.2 * mindamage)
1303                         {
1304                                 e.fire_deathtype = dt;
1305                                 if(e.fire_owner != o)
1306                                 {
1307                                         e.fire_owner = o;
1308                                         e.fire_hitsound = FALSE;
1309                                 }
1310                         }
1311                         if(accuracy_isgooddamage(o, e))
1312                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1313                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1314                 }
1315                 else
1316                         return 0;
1317         }
1318         else
1319         {
1320                 e.fire_damagepersec = dps;
1321                 e.fire_endtime = time + t;
1322                 e.fire_deathtype = dt;
1323                 e.fire_owner = o;
1324                 e.fire_hitsound = FALSE;
1325                 if(accuracy_isgooddamage(o, e))
1326                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1327                 return d;
1328         }
1329 }
1330
1331 void Fire_ApplyDamage(entity e)
1332 {
1333         float t, d, hi, ty;
1334         entity o;
1335
1336         if not(Fire_IsBurning(e))
1337                 return;
1338
1339         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1340         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1341                 o = e.fire_owner;
1342
1343         // water and slime stop fire
1344         if(e.waterlevel)
1345         if(e.watertype != CONTENT_LAVA)
1346                 e.fire_endtime = 0;
1347
1348         // ice stops fire
1349         if(e.freezetag_frozen)
1350                 e.fire_endtime = 0;
1351
1352         t = min(frametime, e.fire_endtime - time);
1353         d = e.fire_damagepersec * t;
1354
1355         hi = e.fire_owner.hitsound;
1356         ty = e.fire_owner.typehitsound;
1357         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1358         if(e.fire_hitsound && e.fire_owner)
1359         {
1360                 e.fire_owner.hitsound = hi;
1361                 e.fire_owner.typehitsound = ty;
1362         }
1363         e.fire_hitsound = TRUE;
1364
1365         if not(IS_INDEPENDENT_PLAYER(e))
1366         FOR_EACH_PLAYER(other) if(e != other)
1367         {
1368                 if(other.classname == "player")
1369                 if(other.deadflag == DEAD_NO)
1370                 if not(IS_INDEPENDENT_PLAYER(other))
1371                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1372                 {
1373                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1374                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1375                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1376                 }
1377         }
1378 }
1379
1380 void Fire_ApplyEffect(entity e)
1381 {
1382         if(Fire_IsBurning(e))
1383                 e.effects |= EF_FLAME;
1384         else
1385                 e.effects &~= EF_FLAME;
1386 }
1387
1388 void fireburner_think()
1389 {
1390         // for players, this is done in the regular loop
1391         if(wasfreed(self.owner))
1392         {
1393                 remove(self);
1394                 return;
1395         }
1396         Fire_ApplyEffect(self.owner);
1397         if(!Fire_IsBurning(self.owner))
1398         {
1399                 self.owner.fire_burner = world;
1400                 remove(self);
1401                 return;
1402         }
1403         Fire_ApplyDamage(self.owner);
1404         self.nextthink = time;
1405 }