qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(g_arena || g_ca)
 124                 if(autocvar_g_arena_roundbased)
 125                         return;
 126
 127         if(targ != attacker) // not for suicides
 128         if(g_weaponarena_random)
 129         {
 130                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 131                 float culprit;
 132                 culprit = DEATH_WEAPONOF(deathtype);
 133                 if(!culprit)
 134                         culprit = attacker.weapon;
 135                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 136                         culprit = attacker.weapon;
 137
 138                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 139                 {
 140                         // no exchange
 141                 }
 142                 else
 143                 {
 144                         if(!GiveFrags_randomweapons)
 145                         {
 146                                 GiveFrags_randomweapons = spawn();
 147                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 148                         }
 149
 150                         if(inWarmupStage)
 151                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 152                         else
 153                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 154
 155                         // all others (including the culprit): remove
 156                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 157                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 158
 159                         // among the remaining ones, choose one by random
 160                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 161
 162                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 163                         {
 164                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 165                                 WEPSET_ANDNOT_EW(attacker, culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189                 if(g_runematch)
 190                 {
 191                         f = RunematchHandleFrags(attacker, targ, f);
 192                 }
 193                 else if(g_lms)
 194                 {
 195                         // remove a life
 196                         float tl;
 197                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 198                         if(tl < lms_lowest_lives)
 199                                 lms_lowest_lives = tl;
 200                         if(tl <= 0)
 201                         {
 202                                 if(!lms_next_place)
 203                                         lms_next_place = player_count;
 204                                 else
 205                                         lms_next_place = min(lms_next_place, player_count);
 206                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 207                                 --lms_next_place;
 208                         }
 209                         f = 0;
 210                 }
 211         }
 212
 213         attacker.totalfrags += f;
 214
 215         if(f)
 216                 UpdateFrags(attacker, f);
 217 }
 218
 219 string AppendItemcodes(string s, entity player)
 220 {
 221         float w;
 222         w = player.weapon;
 223         //if(w == 0)
 224         //      w = player.switchweapon;
 225         if(w == 0)
 226                 w = player.cnt; // previous weapon!
 227         s = strcat(s, ftos(w));
 228         if(time < player.strength_finished)
 229                 s = strcat(s, "S");
 230         if(time < player.invincible_finished)
 231                 s = strcat(s, "I");
 232         if(player.flagcarried != world)
 233                 s = strcat(s, "F");
 234         if(player.BUTTON_CHAT)
 235                 s = strcat(s, "T");
 236         if(player.kh_next)
 237                 s = strcat(s, "K");
 238         if(player.runes)
 239                 s = strcat(s, "|", ftos(player.runes));
 240         return s;
 241 }
 242
 243 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 244 {
 245         string s;
 246         if(!autocvar_sv_eventlog)
 247                 return;
 248         s = strcat(":kill:", mode);
 249         s = strcat(s, ":", ftos(killer.playerid));
 250         s = strcat(s, ":", ftos(killed.playerid));
 251         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 252         s = strcat(s, ":items=");
 253         s = AppendItemcodes(s, killer);
 254         if(killed != killer)
 255         {
 256                 s = strcat(s, ":victimitems=");
 257                 s = AppendItemcodes(s, killed);
 258         }
 259         GameLogEcho(s);
 260 }
 261
 262 #define INFO_NO_MSG 0 // so that compilation works with the INFO_##msg_death stuff
 263 void Obituary_SpecialDeath(entity notif_target, float murder, float deathtype, string s1, string s2, string s3, float f1, float f2, float f3)
 264 {
 265         float handled = 0, hits = 0;
 266         if(DEATH_ISSPECIAL(deathtype))
 267         {
 268                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 269                         { if(deathtype == max(0, name)) \
 270                         { \
 271                                 #if msg_death != NO_MSG \
 272                                         if not(murder) \
 273                                         { \
 274                                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_MULTI, msg_death, s1, s2, s3, "", f1, f2, f3, 0); \
 275                                                 Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death, s1, s2, s3, "", f1, f2, f3, 0); \
 276                                                 ++handled; \
 277                                         } \
 278                                 #endif \
 279                                 #if msg_death_by != NO_MSG \
 280                                         if(murder) \
 281                                         { \
 282                                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_MULTI, msg_death_by, s1, s2, s3, "", f1, f2, f3, 0); \
 283                                                 Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death_by, s1, s2, s3, "", f1, f2, f3, 0); \
 284                                                 ++handled; \
 285                                         } \
 286                                 #endif \
 287                                 ++hits; \
 288                         } }
 289
 290                 DEATHTYPES
 291                 #undef DEATHTYPE
 292
 293                 if not(hits)
 294                 {
 295                         backtrace("Obituary_SpecialDeath(): Unhandled deathtype- Please notify Samual!\n");
 296                 }
 297                 if not(handled)
 298                 {
 299                         dprint(sprintf(
 300                                 "Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n",
 301                                 Deathtype_Name(deathtype),
 302                                 deathtype
 303                         ));
 304                         return;
 305                 }
 306         }
 307 }
 308
 309 float w_deathtype;
 310 float Obituary_WeaponDeath(entity notif_target, float murder, float deathtype, string s1, string s2, string s3, float f1, float f2)
 311 {
 312         float death_weapon = DEATH_WEAPONOF(deathtype);
 313         if(death_weapon)
 314         {
 315                 w_deathtype = deathtype;
 316                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 317                 w_deathtype = FALSE;
 318
 319                 if(death_message)
 320                 {
 321                         Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_MULTI, death_message, s1, s2, s3, "", f1, f2, 0, 0);
 322                         Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, msg_multi_notifs[death_message - 1].nent_msginfo.nent_id, s1, s2, s3, "", f1, f2, 0, 0);
 323                 }
 324                 else
 325                 {
 326                         dprint(sprintf(
 327                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification for weapon %d!\n",
 328                                 Deathtype_Name(deathtype),
 329                                 deathtype,
 330                                 death_weapon
 331                         ));
 332                 }
 333
 334                 return TRUE;
 335         }
 336         return FALSE;
 337 }
 338
 339 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 340 {
 341         // Sanity check
 342         if not(targ.classname == STR_PLAYER) { backtrace("Obituary called on non-player?!\n"); return; }
 343
 344         // Declarations
 345         float notif_firstblood = FALSE;
 346         float kill_count_to_attacker, kill_count_to_target;
 347
 348         // Set final information for the death
 349         targ.death_origin = targ.origin;
 350         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 351         string deathlocation = NearestLocation(targ.death_origin);
 352
 353         #ifdef NOTIFICATIONS_DEBUG
 354         dprint(
 355                 sprintf(
 356                         "Obituary(%s, %s, %s, %s = %d);\n",
 357                         attacker.netname,
 358                         inflictor.netname,
 359                         targ.netname,
 360                         Deathtype_Name(deathtype),
 361                         deathtype
 362                 )
 363         );
 364         #endif
 365
 366         // =======
 367         // SUICIDE
 368         // =======
 369         if(targ == attacker)
 370         {
 371                 if(DEATH_ISSPECIAL(deathtype))
 372                 {
 373                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 374                         {
 375                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 376                         }
 377                         else
 378                         {
 379                                 switch(deathtype)
 380                                 {
 381                                         case DEATH_MIRRORDAMAGE:
 382                                         {
 383                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 384                                                 break;
 385                                         }
 386
 387                                         default:
 388                                         {
 389                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 390                                                 break;
 391                                         }
 392                                 }
 393                                 LogDeath("suicide", deathtype, targ, targ);
 394                                 GiveFrags(attacker, targ, -1, deathtype);
 395                         }
 396                 }
 397                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 398                 {
 399                         backtrace("SUICIDE: what the hell happened here?\n");
 400                 }
 401         }
 402
 403         // ======
 404         // MURDER
 405         // ======
 406         else if(attacker.classname == "player")
 407         {
 408                 if(!IsDifferentTeam(attacker, targ))
 409                 {
 410                         LogDeath("tk", deathtype, attacker, targ);
 411                         GiveFrags(attacker, targ, -1, deathtype);
 412
 413                         attacker.killcount = 0;
 414
 415                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 416                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 417                         Send_Notification(NOTIF_ANY, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, targ.killcount);
 418
 419                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 420                         // No need for specific death/weapon messages...
 421                 }
 422                 else
 423                 {
 424                         LogDeath("frag", deathtype, attacker, targ);
 425                         GiveFrags(attacker, targ, 1, deathtype);
 426
 427                         attacker.taunt_soundtime = time + 1;
 428                         attacker.killcount = attacker.killcount + 1;
 429
 430                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 431                                 case counta: \
 432                                 { \
 433                                         AnnounceTo(attacker, strcat(#countb, "kills")); \
 434                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 435                                         break; \
 436                                 }
 437                         switch(attacker.killcount)
 438                         {
 439                                 KILL_SPREE_LIST
 440                                 default: break;
 441                         }
 442                         #undef SPREE_ITEM
 443
 444                         if(!checkrules_firstblood)
 445                         {
 446                                 checkrules_firstblood = TRUE;
 447                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 448                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 449                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 450
 451                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 452                                 kill_count_to_attacker = -1;
 453                                 kill_count_to_target = -2;
 454                         }
 455                         else
 456                         {
 457                                 kill_count_to_attacker = attacker.killcount;
 458                                 kill_count_to_target = 0;
 459                         }
 460
 461                         if(targ.istypefrag)
 462                         {
 463                                 if(attacker.FRAG_VERBOSE)
 464                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 465                                 else
 466                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 467
 468                                 if(targ.FRAG_VERBOSE)
 469                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 470                                 else
 471                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 472                         }
 473                         else
 474                         {
 475                                 if(attacker.FRAG_VERBOSE)
 476                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 477                                 else
 478                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 479
 480                                 if(targ.FRAG_VERBOSE)
 481                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 482                                 else
 483                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 484                         }
 485
 486                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 487                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 488                 }
 489         }
 490
 491         // =============
 492         // ACCIDENT/TRAP
 493         // =============
 494         else
 495         {
 496                 switch(deathtype)
 497                 {
 498                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 499                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 500                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 501                         /*case DEATH_HURTTRIGGER:
 502                         {
 503                                 s1 = targ.netname;
 504                                 s2 = inflictor.message;
 505                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 506                                 break;
 507                         }*/
 508
 509                         case DEATH_CUSTOM:
 510                         {
 511                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 512                                         targ.netname,
 513                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 514                                         deathlocation,
 515                                         targ.killcount,
 516                                         0,
 517                                         0);
 518                                 break;
 519                         }
 520
 521                         default:
 522                         {
 523                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 524                                 break;
 525                         }
 526                 }
 527
 528                 LogDeath("accident", deathtype, targ, targ);
 529                 GiveFrags(targ, targ, -1, deathtype);
 530
 531                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 532                 {
 533                         AnnounceTo(targ, "botlike");
 534                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 535                 }
 536         }
 537
 538         // reset target kill count
 539         if(targ.killcount) { targ.killcount = 0; }
 540 }
 541
 542 // these are updated by each Damage call for use in button triggering and such
 543 entity damage_targ;
 544 entity damage_inflictor;
 545 entity damage_attacker;
 546
 547 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 548 {
 549         float mirrordamage;
 550         float mirrorforce;
 551         float complainteamdamage = 0;
 552         entity attacker_save;
 553         mirrordamage = 0;
 554         mirrorforce = 0;
 555
 556         if (gameover || targ.killcount == -666)
 557                 return;
 558
 559         entity oldself;
 560         oldself = self;
 561         self = targ;
 562         damage_targ = targ;
 563         damage_inflictor = inflictor;
 564         damage_attacker = attacker;
 565                 attacker_save = attacker;
 566
 567         if(targ.classname == "player")
 568                 if(targ.hook)
 569                         if(targ.hook.aiment)
 570                                 if(targ.hook.aiment == attacker)
 571                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 572
 573         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 574         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 575         {
 576                 if(targ.classname == "player")
 577                         if not(IsDifferentTeam(targ, attacker))
 578                         {
 579                                 self = oldself;
 580                                 return;
 581                         }
 582         }
 583
 584         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 585         {
 586                 // These are ALWAYS lethal
 587                 // No damage modification here
 588                 // Instead, prepare the victim for his death...
 589                 targ.armorvalue = 0;
 590                 targ.spawnshieldtime = 0;
 591                 targ.health = 0.9; // this is < 1
 592                 targ.flags -= targ.flags & FL_GODMODE;
 593                 damage = 100000;
 594         }
 595         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 596         {
 597                 // no processing
 598         }
 599         else
 600         {
 601                 /*
 602                 skill based bot damage? gtfo. (tZork)
 603                 if (targ.classname == "player")
 604                 if (attacker.classname == "player")
 605                 if (!targ.isbot)
 606                 if (attacker.isbot)
 607                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 608         */
 609
 610                 // nullify damage if teamplay is on
 611                 if(deathtype != DEATH_TELEFRAG)
 612                 if(attacker.classname == "player")
 613                 {
 614                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 615                         {
 616                                 damage = 0;
 617                                 force = '0 0 0';
 618                         }
 619                         else if(!IsDifferentTeam(attacker, targ))
 620                         {
 621                                 if(autocvar_teamplay_mode == 1)
 622                                         damage = 0;
 623                                 else if(attacker != targ)
 624                                 {
 625                                         if(autocvar_teamplay_mode == 3)
 626                                                 damage = 0;
 627                                         else if(autocvar_teamplay_mode == 4)
 628                                         {
 629                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 630                                                 {
 631                                                         attacker.dmg_team = attacker.dmg_team + damage;
 632                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 633                                                         if(complainteamdamage > 0 && !g_ca) // FIXME why is g_ca ruled out here? Why not just g_mirrordamage 0 on CA servers?
 634                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 635                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 636                                                         if(g_minstagib)
 637                                                         {
 638                                                                 if(autocvar_g_friendlyfire == 0)
 639                                                                         damage = 0;
 640                                                         }
 641                                                         else if(g_ca)
 642                                                                 damage = 0;
 643                                                         else
 644                                                                 damage = autocvar_g_friendlyfire * damage;
 645                                                         // mirrordamage will be used LATER
 646
 647                                                         if(autocvar_g_mirrordamage_virtual)
 648                                                         {
 649                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 650                                                                 attacker.dmg_take += v_x;
 651                                                                 attacker.dmg_save += v_y;
 652                                                                 attacker.dmg_inflictor = inflictor;
 653                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 654                                                                 mirrorforce = 0;
 655                                                         }
 656
 657                                                         if(autocvar_g_friendlyfire_virtual)
 658                                                         {
 659                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 660                                                                 targ.dmg_take += v_x;
 661                                                                 targ.dmg_save += v_y;
 662                                                                 targ.dmg_inflictor = inflictor;
 663                                                                 damage = 0;
 664                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 665                                                                         force = '0 0 0';
 666                                                         }
 667                                                 }
 668                                                 else
 669                                                         damage = 0;
 670                                         }
 671                                 }
 672                         }
 673                 }
 674
 675                 if(targ.classname == "player")
 676                 if(attacker.classname == "player")
 677                 if(attacker != targ)
 678                 {
 679                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 680                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 681                 }
 682
 683                 if(targ.classname == "player")
 684                 if (g_minstagib)
 685                 {
 686                         if ((deathtype == DEATH_FALL)  ||
 687                                 (deathtype == DEATH_DROWN) ||
 688                                 (deathtype == DEATH_SLIME) ||
 689                                 (deathtype == DEATH_LAVA)  ||
 690                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 691                         {
 692                                 self = oldself;
 693                                 return;
 694                         }
 695                         if(damage > 0)
 696                             damage = 10000;
 697                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 698                         {
 699                                 targ.armorvalue -= 1;
 700                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 701                                 damage = 0;
 702                                 targ.hitsound += 1;
 703                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 704                         }
 705                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 706                         {
 707                                 damage = 0;
 708                                 mirrordamage = 0;
 709                                 complainteamdamage = 0;
 710                                 if (targ != attacker)
 711                                 {
 712                                         if ((targ.health >= 1) && (targ.classname == "player"))
 713                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 714                                         force = '0 0 0';
 715                                         // keep mirrorforce
 716                                         attacker = targ;
 717                                 }
 718                         }
 719                 }
 720
 721                 if not(DEATH_ISSPECIAL(deathtype))
 722                 {
 723                         damage *= g_weapondamagefactor;
 724                         mirrordamage *= g_weapondamagefactor;
 725                         complainteamdamage *= g_weapondamagefactor;
 726                         force = force * g_weaponforcefactor;
 727                         mirrorforce *= g_weaponforcefactor;
 728                 }
 729
 730                 // should this be changed at all? If so, in what way?
 731                 frag_attacker = attacker;
 732                 frag_target = targ;
 733                 frag_damage = damage;
 734                 frag_force = force;
 735         frag_deathtype = deathtype;
 736                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 737                 damage = frag_damage;
 738                 force = frag_force;
 739
 740                 // apply strength multiplier
 741                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 742                 {
 743                         if(targ == attacker)
 744                         {
 745                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 746                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 747                         }
 748                         else
 749                         {
 750                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 751                                 force = force * autocvar_g_balance_powerup_strength_force;
 752                         }
 753                 }
 754
 755                 // apply invincibility multiplier
 756                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 757                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 758
 759                 if (targ == attacker)
 760                 {
 761                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 762                                 damage = 0;
 763                         else
 764                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 765                 }
 766
 767                 if(g_runematch)
 768                 {
 769                         // apply strength rune
 770                         if (attacker.runes & RUNE_STRENGTH)
 771                         {
 772                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 773                                 {
 774                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 775                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 776                                 }
 777                                 else
 778                                 {
 779                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 780                                         force = force * autocvar_g_balance_rune_strength_force;
 781                                 }
 782                         }
 783                         else if (attacker.runes & CURSE_WEAK)
 784                         {
 785                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 786                                 force = force * autocvar_g_balance_curse_weak_force;
 787                         }
 788
 789                         // apply defense rune
 790                         if (targ.runes & RUNE_DEFENSE)
 791                         {
 792                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 793                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 794                                 else
 795                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 796                         }
 797                         else if (targ.runes & CURSE_VULNER)
 798                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 799                 }
 800
 801                 // count the damage
 802                 if(attacker)
 803                 if(!targ.deadflag)
 804                 if(targ.takedamage == DAMAGE_AIM)
 805                 if(targ != attacker)
 806                 {
 807                         entity victim;
 808                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 809                                 victim = targ.owner;
 810                         else
 811                                 victim = targ;
 812
 813                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 814                         {
 815                                 if(IsDifferentTeam(victim, attacker))
 816                                 {
 817                                         if(damage > 0)
 818                                         {
 819                                                 if(deathtype != DEATH_FIRE)
 820                                                 {
 821                                                         if(victim.BUTTON_CHAT)
 822                                                                 attacker.typehitsound += 1;
 823                                                         else
 824                                                                 attacker.hitsound += 1;
 825                                                 }
 826
 827                                                 damage_goodhits += 1;
 828                                                 damage_gooddamage += damage;
 829
 830                                                 if not(DEATH_ISSPECIAL(deathtype))
 831                                                 {
 832                                                         if(targ.classname == "player") // don't do this for vehicles
 833                                                         if(!g_minstagib)
 834                                                         if(IsFlying(victim))
 835                                                                 yoda = 1;
 836
 837                                                         if(g_minstagib)
 838                                                         if(victim.items & IT_STRENGTH)
 839                                                                 yoda = 1;
 840                                                 }
 841                                         }
 842                                 }
 843                                 else
 844                                 {
 845                                         if(deathtype != DEATH_FIRE)
 846                                         {
 847                                                 attacker.typehitsound += 1;
 848                                         }
 849                                         if(complainteamdamage > 0)
 850                                                 if(time > attacker.teamkill_complain)
 851                                                 {
 852                                                         attacker.teamkill_complain = time + 5;
 853                                                         attacker.teamkill_soundtime = time + 0.4;
 854                                                         attacker.teamkill_soundsource = targ;
 855                                                 }
 856                                 }
 857                         }
 858                 }
 859         }
 860
 861         // apply push
 862         if (self.damageforcescale)
 863         if (vlen(force))
 864         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 865         {
 866                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 867                 if(self.movetype == MOVETYPE_PHYSICS)
 868                 {
 869                         entity farcent;
 870                         farcent = spawn();
 871                         farcent.classname = "farce";
 872                         farcent.enemy = self;
 873                         farcent.movedir = farce * 10;
 874                         if(self.mass)
 875                                 farcent.movedir = farcent.movedir * self.mass;
 876                         farcent.origin = hitloc;
 877                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 878                         farcent.nextthink = time + 0.1;
 879                         farcent.think = SUB_Remove;
 880                 }
 881                 else
 882                         self.velocity = self.velocity + farce;
 883                 self.flags &~= FL_ONGROUND;
 884                 UpdateCSQCProjectile(self);
 885         }
 886         // apply damage
 887         if (damage != 0 || (self.damageforcescale && vlen(force)))
 888         if (self.event_damage)
 889                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 890         self = oldself;
 891
 892         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 893         {
 894                 if(g_runematch)
 895                 {
 896                         if (attacker.runes & RUNE_VAMPIRE)
 897                         {
 898                         // apply vampire rune
 899                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 900                                 {
 901                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 902                                         attacker.health = bound(
 903                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 904                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 905                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 906                                 }
 907                                 else
 908                                 {
 909                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 910                                         attacker.health = bound(
 911                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 912                                                                                         // empathy won't let you gain health in the same way...
 913                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 914                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 915                                         }
 916                         }
 917                         // apply empathy curse
 918                         else if (attacker.runes & CURSE_EMPATHY)
 919                         {
 920                                 attacker.health = bound(
 921                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 922                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 923                                         attacker.health);
 924                         }
 925                 }
 926         }
 927
 928         // apply mirror damage if any
 929         if(mirrordamage > 0 || mirrorforce > 0)
 930         {
 931                 attacker = attacker_save;
 932                 if(g_minstagib)
 933                 if(mirrordamage > 0)
 934                 {
 935                         // just lose extra LIVES, don't kill the player for mirror damage
 936                         if(attacker.armorvalue > 0)
 937                         {
 938                                 attacker.armorvalue = attacker.armorvalue - 1;
 939                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 940                                 attacker.hitsound += 1;
 941                         }
 942                         mirrordamage = 0;
 943                 }
 944
 945                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 946                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 947         }
 948 }
 949
 950 float RadiusDamage_running;
 951 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 952         // Returns total damage applies to creatures
 953 {
 954         entity  targ;
 955         vector  blastorigin;
 956         vector  force;
 957         float   total_damage_to_creatures;
 958         entity  next;
 959         float   tfloordmg;
 960         float   tfloorforce;
 961
 962         float stat_damagedone;
 963
 964         if(RadiusDamage_running)
 965         {
 966                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 967                 return 0;
 968         }
 969
 970         RadiusDamage_running = 1;
 971
 972         tfloordmg = autocvar_g_throughfloor_damage;
 973         tfloorforce = autocvar_g_throughfloor_force;
 974
 975         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 976         total_damage_to_creatures = 0;
 977
 978         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 979                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 980                 {
 981                         force = inflictor.velocity;
 982                         if(vlen(force) == 0)
 983                                 force = '0 0 -1';
 984                         else
 985                                 force = normalize(force);
 986                         if(forceintensity >= 0)
 987                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 988                         else
 989                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 990                 }
 991
 992         stat_damagedone = 0;
 993
 994         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 995         while (targ)
 996         {
 997                 next = targ.chain;
 998                 if (targ != inflictor)
 999                         if (ignore != targ) if(targ.takedamage)
1000                         {
1001                                 vector nearest;
1002                                 vector diff;
1003                                 float power;
1004
1005                                 // LordHavoc: measure distance to nearest point on target (not origin)
1006                                 // (this guarentees 100% damage on a touch impact)
1007                                 nearest = targ.WarpZone_findradius_nearest;
1008                                 diff = targ.WarpZone_findradius_dist;
1009                                 // round up a little on the damage to ensure full damage on impacts
1010                                 // and turn the distance into a fraction of the radius
1011                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1012                                 //bprint(" ");
1013                                 //bprint(ftos(power));
1014                                 //if (targ == attacker)
1015                                 //      print(ftos(power), "\n");
1016                                 if (power > 0)
1017                                 {
1018                                         float finaldmg;
1019                                         if (power > 1)
1020                                                 power = 1;
1021                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1022                                         if (finaldmg > 0)
1023                                         {
1024                                                 float a;
1025                                                 float c;
1026                                                 vector hitloc;
1027                                                 vector myblastorigin;
1028                                                 vector center;
1029
1030                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1031
1032                                                 // if it's a player, use the view origin as reference
1033                                                 center = CENTER_OR_VIEWOFS(targ);
1034
1035                                                 force = normalize(center - myblastorigin);
1036                                                 force = force * (finaldmg / coredamage) * forceintensity;
1037                                                 hitloc = nearest;
1038
1039                                                 if(targ != directhitentity)
1040                                                 {
1041                                                         float hits;
1042                                                         float total;
1043                                                         float hitratio;
1044                                                         float mininv_f, mininv_d;
1045
1046                                                         // test line of sight to multiple positions on box,
1047                                                         // and do damage if any of them hit
1048                                                         hits = 0;
1049
1050                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1051                                                         // so for a given max stddev:
1052                                                         // n = (1 / (2 * max stddev of hitratio))^2
1053
1054                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1055                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1056
1057                                                         if(autocvar_g_throughfloor_debug)
1058                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1059
1060                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1061
1062                                                         if(autocvar_g_throughfloor_debug)
1063                                                                 print(sprintf(" steps=%f", total));
1064
1065                                                         if (targ.classname == "player")
1066                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1067                                                         else
1068                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1069
1070                                                         if(autocvar_g_throughfloor_debug)
1071                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1072
1073                                                         for(c = 0; c < total; ++c)
1074                                                         {
1075                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1076                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1077                                                                 if (trace_fraction == 1 || trace_ent == targ)
1078                                                                 {
1079                                                                         ++hits;
1080                                                                         if (hits > 1)
1081                                                                                 hitloc = hitloc + nearest;
1082                                                                         else
1083                                                                                 hitloc = nearest;
1084                                                                 }
1085                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1086                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1087                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1088                                                         }
1089
1090                                                         nearest = hitloc * (1 / max(1, hits));
1091                                                         hitratio = (hits / total);
1092                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1093                                                         finaldmg = finaldmg * a;
1094                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1095                                                         force = force * a;
1096
1097                                                         if(autocvar_g_throughfloor_debug)
1098                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1099                                                 }
1100
1101                                                 // laser force adjustments :P
1102                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1103                                                 {
1104                                                         if (targ == attacker)
1105                                                         {
1106                                                                 vector vel;
1107
1108                                                                 float force_zscale;
1109                                                                 float force_velocitybiasramp;
1110                                                                 float force_velocitybias;
1111
1112                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1113                                                                 if(deathtype & HITTYPE_SECONDARY)
1114                                                                 {
1115                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1116                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1117                                                                 }
1118                                                                 else
1119                                                                 {
1120                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1121                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1122                                                                 }
1123
1124                                                                 vel = targ.velocity;
1125                                                                 vel_z = 0;
1126                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1127                                                                 force =
1128                                                                         vlen(force)
1129                                                                         *
1130                                                                         normalize(normalize(force) + vel);
1131
1132                                                                 force_z *= force_zscale;
1133                                                         }
1134                                                         else
1135                                                         {
1136                                                                 if(deathtype & HITTYPE_SECONDARY)
1137                                                                 {
1138                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1139                                                                 }
1140                                                                 else
1141                                                                 {
1142                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1143                                                                 }
1144                                                         }
1145                                                 }
1146
1147                                                 //if (targ == attacker)
1148                                                 //{
1149                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1150                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1151                                                 //      print(" (", ftos(a), ")\n");
1152                                                 //}
1153                                                 if(finaldmg || vlen(force))
1154                                                 {
1155                                                         if(targ.iscreature)
1156                                                         {
1157                                                                 total_damage_to_creatures += finaldmg;
1158
1159                                                                 if(accuracy_isgooddamage(attacker, targ))
1160                                                                         stat_damagedone += finaldmg;
1161                                                         }
1162
1163                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1164                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1165                                                         else
1166                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1167                                                 }
1168                                         }
1169                                 }
1170                         }
1171                 targ = next;
1172         }
1173
1174         RadiusDamage_running = 0;
1175
1176         if(!DEATH_ISSPECIAL(deathtype))
1177                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1178
1179         return total_damage_to_creatures;
1180 }
1181
1182 .float fire_damagepersec;
1183 .float fire_endtime;
1184 .float fire_deathtype;
1185 .entity fire_owner;
1186 .float fire_hitsound;
1187 .entity fire_burner;
1188
1189 void fireburner_think();
1190
1191 float Fire_IsBurning(entity e)
1192 {
1193         return (time < e.fire_endtime);
1194 }
1195
1196 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1197 {
1198         float dps;
1199         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1200
1201         if(e.classname == "player")
1202         {
1203                 if(e.deadflag)
1204                         return -1;
1205         }
1206         else
1207         {
1208                 if(!e.fire_burner)
1209                 {
1210                         // print("adding a fire burner to ", e.classname, "\n");
1211                         e.fire_burner = spawn();
1212                         e.fire_burner.classname = "fireburner";
1213                         e.fire_burner.think = fireburner_think;
1214                         e.fire_burner.nextthink = time;
1215                         e.fire_burner.owner = e;
1216                 }
1217         }
1218
1219         t = max(t, 0.1);
1220         dps = d / t;
1221         if(Fire_IsBurning(e))
1222         {
1223                 mintime = e.fire_endtime - time;
1224                 maxtime = max(mintime, t);
1225
1226                 mindps = e.fire_damagepersec;
1227                 maxdps = max(mindps, dps);
1228
1229                 if(maxtime > mintime || maxdps > mindps)
1230                 {
1231                         // Constraints:
1232
1233                         // damage we have right now
1234                         mindamage = mindps * mintime;
1235
1236                         // damage we want to get
1237                         maxdamage = mindamage + d;
1238
1239                         // but we can't exceed maxtime * maxdps!
1240                         totaldamage = min(maxdamage, maxtime * maxdps);
1241
1242                         // LEMMA:
1243                         // Look at:
1244                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1245                         // We see:
1246                         // totaldamage <= maxtime * maxdps
1247                         // ==> totaldamage / maxdps <= maxtime.
1248                         // We also see:
1249                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1250                         //                     >= min(mintime, maxtime)
1251                         // ==> totaldamage / maxdps >= mintime.
1252
1253                         /*
1254                         // how long do we damage then?
1255                         // at least as long as before
1256                         // but, never exceed maxdps
1257                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1258                         */
1259
1260                         // alternate:
1261                         // at most as long as maximum allowed
1262                         // but, never below mindps
1263                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1264
1265                         // assuming t > mintime, dps > mindps:
1266                         // we get d = t * dps = maxtime * maxdps
1267                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1268                         // totaldamage / maxdps = maxtime
1269                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1270                         // FROM THIS:
1271                         // a) totaltime = max(mintime, maxtime) = maxtime
1272                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1273
1274                         // assuming t <= mintime:
1275                         // we get maxtime = mintime
1276                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1277                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1278
1279                         // assuming dps <= mindps:
1280                         // we get mindps = maxdps.
1281                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1282                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1283                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1284
1285                         e.fire_damagepersec = totaldamage / totaltime;
1286                         e.fire_endtime = time + totaltime;
1287                         if(totaldamage > 1.2 * mindamage)
1288                         {
1289                                 e.fire_deathtype = dt;
1290                                 if(e.fire_owner != o)
1291                                 {
1292                                         e.fire_owner = o;
1293                                         e.fire_hitsound = FALSE;
1294                                 }
1295                         }
1296                         if(accuracy_isgooddamage(o, e))
1297                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1298                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1299                 }
1300                 else
1301                         return 0;
1302         }
1303         else
1304         {
1305                 e.fire_damagepersec = dps;
1306                 e.fire_endtime = time + t;
1307                 e.fire_deathtype = dt;
1308                 e.fire_owner = o;
1309                 e.fire_hitsound = FALSE;
1310                 if(accuracy_isgooddamage(o, e))
1311                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1312                 return d;
1313         }
1314 }
1315
1316 void Fire_ApplyDamage(entity e)
1317 {
1318         float t, d, hi, ty;
1319         entity o;
1320
1321         if not(Fire_IsBurning(e))
1322                 return;
1323
1324         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1325         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1326                 o = e.fire_owner;
1327
1328         // water and slime stop fire
1329         if(e.waterlevel)
1330         if(e.watertype != CONTENT_LAVA)
1331                 e.fire_endtime = 0;
1332
1333         // ice stops fire
1334         if(e.freezetag_frozen)
1335                 e.fire_endtime = 0;
1336
1337         t = min(frametime, e.fire_endtime - time);
1338         d = e.fire_damagepersec * t;
1339
1340         hi = e.fire_owner.hitsound;
1341         ty = e.fire_owner.typehitsound;
1342         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1343         if(e.fire_hitsound && e.fire_owner)
1344         {
1345                 e.fire_owner.hitsound = hi;
1346                 e.fire_owner.typehitsound = ty;
1347         }
1348         e.fire_hitsound = TRUE;
1349
1350         if not(IS_INDEPENDENT_PLAYER(e))
1351         FOR_EACH_PLAYER(other) if(e != other)
1352         {
1353                 if(other.classname == "player")
1354                 if(other.deadflag == DEAD_NO)
1355                 if not(IS_INDEPENDENT_PLAYER(other))
1356                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1357                 {
1358                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1359                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1360                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1361                 }
1362         }
1363 }
1364
1365 void Fire_ApplyEffect(entity e)
1366 {
1367         if(Fire_IsBurning(e))
1368                 e.effects |= EF_FLAME;
1369         else
1370                 e.effects &~= EF_FLAME;
1371 }
1372
1373 void fireburner_think()
1374 {
1375         // for players, this is done in the regular loop
1376         if(wasfreed(self.owner))
1377         {
1378                 remove(self);
1379                 return;
1380         }
1381         Fire_ApplyEffect(self.owner);
1382         if(!Fire_IsBurning(self.owner))
1383         {
1384                 self.owner.fire_burner = world;
1385                 remove(self);
1386                 return;
1387         }
1388         Fire_ApplyDamage(self.owner);
1389         self.nextthink = time;
1390 }