qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(g_arena || g_ca)
 124                 if(autocvar_g_arena_roundbased)
 125                         return;
 126
 127         if(targ != attacker) // not for suicides
 128         if(g_weaponarena_random)
 129         {
 130                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 131                 float culprit;
 132                 culprit = DEATH_WEAPONOF(deathtype);
 133                 if(!culprit)
 134                         culprit = attacker.weapon;
 135                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 136                         culprit = attacker.weapon;
 137
 138                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 139                 {
 140                         // no exchange
 141                 }
 142                 else
 143                 {
 144                         if(!GiveFrags_randomweapons)
 145                         {
 146                                 GiveFrags_randomweapons = spawn();
 147                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 148                         }
 149
 150                         if(inWarmupStage)
 151                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 152                         else
 153                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 154
 155                         // all others (including the culprit): remove
 156                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 157                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 158
 159                         // among the remaining ones, choose one by random
 160                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 161
 162                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 163                         {
 164                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 165                                 WEPSET_ANDNOT_EW(attacker, culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189                 if(g_lms)
 190                 {
 191                         // remove a life
 192                         float tl;
 193                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 194                         if(tl < lms_lowest_lives)
 195                                 lms_lowest_lives = tl;
 196                         if(tl <= 0)
 197                         {
 198                                 if(!lms_next_place)
 199                                         lms_next_place = player_count;
 200                                 else
 201                                         lms_next_place = min(lms_next_place, player_count);
 202                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 203                                 --lms_next_place;
 204                         }
 205                         f = 0;
 206                 }
 207         }
 208
 209         attacker.totalfrags += f;
 210
 211         if(f)
 212                 UpdateFrags(attacker, f);
 213 }
 214
 215 string AppendItemcodes(string s, entity player)
 216 {
 217         float w;
 218         w = player.weapon;
 219         //if(w == 0)
 220         //      w = player.switchweapon;
 221         if(w == 0)
 222                 w = player.cnt; // previous weapon!
 223         s = strcat(s, ftos(w));
 224         if(time < player.strength_finished)
 225                 s = strcat(s, "S");
 226         if(time < player.invincible_finished)
 227                 s = strcat(s, "I");
 228         if(player.flagcarried != world)
 229                 s = strcat(s, "F");
 230         if(player.BUTTON_CHAT)
 231                 s = strcat(s, "T");
 232         if(player.kh_next)
 233                 s = strcat(s, "K");
 234         return s;
 235 }
 236
 237 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 238 {
 239         string s;
 240         if(!autocvar_sv_eventlog)
 241                 return;
 242         s = strcat(":kill:", mode);
 243         s = strcat(s, ":", ftos(killer.playerid));
 244         s = strcat(s, ":", ftos(killed.playerid));
 245         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 246         s = strcat(s, ":items=");
 247         s = AppendItemcodes(s, killer);
 248         if(killed != killer)
 249         {
 250                 s = strcat(s, ":victimitems=");
 251                 s = AppendItemcodes(s, killed);
 252         }
 253         GameLogEcho(s);
 254 }
 255
 256 void Obituary_SpecialDeath(
 257         entity notif_target,
 258         float murder,
 259         float deathtype,
 260         string s1, string s2, string s3,
 261         float f1, float f2, float f3)
 262 {
 263         if(DEATH_ISSPECIAL(deathtype))
 264         {
 265                 entity deathent = deathtypes[(deathtype - DT_FIRST) - 1];
 266                 if not(deathent) { backtrace("Obituary_SpecialDeath: Could not find deathtype entity!\n"); return; }
 267
 268                 if(murder)
 269                 {
 270                         if(deathent.death_msgmurder)
 271                         {
 272                                 Send_Notification_WOVA(
 273                                         NOTIF_ONE,
 274                                         notif_target,
 275                                         MSG_MULTI,
 276                                         deathent.death_msgmurder.nent_id,
 277                                         s1, s2, s3, "",
 278                                         f1, f2, f3, 0
 279                                 );
 280                                 Send_Notification_WOVA(
 281                                         NOTIF_ALL_EXCEPT,
 282                                         notif_target,
 283                                         MSG_INFO,
 284                                         deathent.death_msgmurder.nent_msginfo.nent_id,
 285                                         s1, s2, s3, "",
 286                                         f1, f2, f3, 0
 287                                 );
 288                         }
 289                 }
 290                 else
 291                 {
 292                         if(deathent.death_msgself)
 293                         {
 294                                 Send_Notification_WOVA(
 295                                         NOTIF_ONE,
 296                                         notif_target,
 297                                         MSG_MULTI,
 298                                         deathent.death_msgself.nent_id,
 299                                         s1, s2, s3, "",
 300                                         f1, f2, f3, 0
 301                                 );
 302                                 Send_Notification_WOVA(
 303                                         NOTIF_ALL_EXCEPT,
 304                                         notif_target,
 305                                         MSG_INFO,
 306                                         deathent.death_msgself.nent_msginfo.nent_id,
 307                                         s1, s2, s3, "",
 308                                         f1, f2, f3, 0
 309                                 );
 310                         }
 311                 }
 312         }
 313         else { backtrace("Obituary_SpecialDeath called without a special deathtype?\n"); return; }
 314 }
 315
 316 float w_deathtype;
 317 float Obituary_WeaponDeath(
 318         entity notif_target,
 319         float murder,
 320         float deathtype,
 321         string s1, string s2, string s3,
 322         float f1, float f2)
 323 {
 324         float death_weapon = DEATH_WEAPONOF(deathtype);
 325         if(death_weapon)
 326         {
 327                 w_deathtype = deathtype;
 328                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 329                 w_deathtype = FALSE;
 330
 331                 if(death_message)
 332                 {
 333                         Send_Notification_WOVA(
 334                                 NOTIF_ONE,
 335                                 notif_target,
 336                                 MSG_MULTI,
 337                                 death_message,
 338                                 s1, s2, s3, "",
 339                                 f1, f2, 0, 0
 340                         );
 341                         Send_Notification_WOVA(
 342                                 NOTIF_ALL_EXCEPT,
 343                                 notif_target,
 344                                 MSG_INFO,
 345                                 msg_multi_notifs[death_message - 1].nent_msginfo.nent_id,
 346                                 s1, s2, s3, "",
 347                                 f1, f2, 0, 0
 348                         );
 349                 }
 350                 else
 351                 {
 352                         dprint(sprintf(
 353                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%d)^1 has no notification for weapon %d!\n",
 354                                 deathtype,
 355                                 death_weapon
 356                         ));
 357                 }
 358
 359                 return TRUE;
 360         }
 361         return FALSE;
 362 }
 363
 364 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 365 {
 366         // Sanity check
 367         if not(IS_PLAYER(targ)) { backtrace("Obituary called on non-player?!\n"); return; }
 368
 369         // Declarations
 370         float notif_firstblood = FALSE;
 371         float kill_count_to_attacker, kill_count_to_target;
 372
 373         // Set final information for the death
 374         targ.death_origin = targ.origin;
 375         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 376         string deathlocation = (autocvar_notification_server_allows_location ? NearestLocation(targ.death_origin) : "");
 377
 378         #ifdef NOTIFICATIONS_DEBUG
 379         dprint(
 380                 sprintf(
 381                         "Obituary(%s, %s, %s, %s = %d);\n",
 382                         attacker.netname,
 383                         inflictor.netname,
 384                         targ.netname,
 385                         Deathtype_Name(deathtype),
 386                         deathtype
 387                 )
 388         );
 389         #endif
 390
 391         // =======
 392         // SUICIDE
 393         // =======
 394         if(targ == attacker)
 395         {
 396                 if(DEATH_ISSPECIAL(deathtype))
 397                 {
 398                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 399                         {
 400                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 401                         }
 402                         else
 403                         {
 404                                 switch(deathtype)
 405                                 {
 406                                         case DEATH_MIRRORDAMAGE:
 407                                         {
 408                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 409                                                 break;
 410                                         }
 411
 412                                         default:
 413                                         {
 414                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 415                                                 break;
 416                                         }
 417                                 }
 418                         }
 419                 }
 420                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 421                 {
 422                         backtrace("SUICIDE: what the hell happened here?\n");
 423                         return;
 424                 }
 425                 LogDeath("suicide", deathtype, targ, targ);
 426                 GiveFrags(attacker, targ, -1, deathtype);
 427         }
 428
 429         // ======
 430         // MURDER
 431         // ======
 432         else if(IS_PLAYER(attacker))
 433         {
 434                 if(!IsDifferentTeam(attacker, targ))
 435                 {
 436                         LogDeath("tk", deathtype, attacker, targ);
 437                         GiveFrags(attacker, targ, -1, deathtype);
 438
 439                         attacker.killcount = 0;
 440
 441                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 442                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 443                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, targ.killcount);
 444
 445                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 446                         // No need for specific death/weapon messages...
 447                 }
 448                 else
 449                 {
 450                         LogDeath("frag", deathtype, attacker, targ);
 451                         GiveFrags(attacker, targ, 1, deathtype);
 452
 453                         attacker.taunt_soundtime = time + 1;
 454                         attacker.killcount = attacker.killcount + 1;
 455
 456                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 457                                 case counta: \
 458                                 { \
 459                                         AnnounceTo(attacker, strcat(#countb, "kills")); \
 460                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 461                                         break; \
 462                                 }
 463                         switch(attacker.killcount)
 464                         {
 465                                 KILL_SPREE_LIST
 466                                 default: break;
 467                         }
 468                         #undef SPREE_ITEM
 469
 470                         if(!checkrules_firstblood)
 471                         {
 472                                 checkrules_firstblood = TRUE;
 473                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 474                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 475                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 476
 477                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 478                                 kill_count_to_attacker = -1;
 479                                 kill_count_to_target = -2;
 480                         }
 481                         else
 482                         {
 483                                 kill_count_to_attacker = attacker.killcount;
 484                                 kill_count_to_target = 0;
 485                         }
 486
 487                         float verbose_allowed = (autocvar_notification_server_allows_frag_verbose && ((autocvar_notification_server_allows_frag_verbose == 2) || inWarmupStage));
 488                         if(targ.istypefrag)
 489                         {
 490                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
 491                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 492                                 else
 493                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 494
 495                                 if(targ.FRAG_VERBOSE && verbose_allowed)
 496                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 497                                 else
 498                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 499                         }
 500                         else
 501                         {
 502                                 if(attacker.FRAG_VERBOSE && verbose_allowed)
 503                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 504                                 else
 505                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 506
 507                                 if(targ.FRAG_VERBOSE && verbose_allowed)
 508                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 509                                 else
 510                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 511                         }
 512
 513                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 514                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 515                 }
 516         }
 517
 518         // =============
 519         // ACCIDENT/TRAP
 520         // =============
 521         else
 522         {
 523                 switch(deathtype)
 524                 {
 525                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 526                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 527                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 528                         /*case DEATH_HURTTRIGGER:
 529                         {
 530                                 s1 = targ.netname;
 531                                 s2 = inflictor.message;
 532                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 533                                 break;
 534                         }*/
 535
 536                         case DEATH_CUSTOM:
 537                         {
 538                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 539                                         targ.netname,
 540                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 541                                         deathlocation,
 542                                         targ.killcount,
 543                                         0,
 544                                         0);
 545                                 break;
 546                         }
 547
 548                         default:
 549                         {
 550                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 551                                 break;
 552                         }
 553                 }
 554
 555                 LogDeath("accident", deathtype, targ, targ);
 556                 GiveFrags(targ, targ, -1, deathtype);
 557
 558                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 559                 {
 560                         AnnounceTo(targ, "botlike");
 561                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 562                 }
 563         }
 564
 565         // reset target kill count
 566         if(targ.killcount) { targ.killcount = 0; }
 567 }
 568
 569 // these are updated by each Damage call for use in button triggering and such
 570 entity damage_targ;
 571 entity damage_inflictor;
 572 entity damage_attacker;
 573
 574 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 575 {
 576         float mirrordamage;
 577         float mirrorforce;
 578         float complainteamdamage = 0;
 579         entity attacker_save;
 580         mirrordamage = 0;
 581         mirrorforce = 0;
 582
 583         if (gameover || targ.killcount == -666)
 584                 return;
 585
 586         entity oldself;
 587         oldself = self;
 588         self = targ;
 589         damage_targ = targ;
 590         damage_inflictor = inflictor;
 591         damage_attacker = attacker;
 592                 attacker_save = attacker;
 593
 594         if(targ.classname == "player")
 595                 if(targ.hook)
 596                         if(targ.hook.aiment)
 597                                 if(targ.hook.aiment == attacker)
 598                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 599
 600         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 601         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 602         {
 603                 if(targ.classname == "player")
 604                         if not(IsDifferentTeam(targ, attacker))
 605                         {
 606                                 self = oldself;
 607                                 return;
 608                         }
 609         }
 610
 611         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 612         {
 613                 // These are ALWAYS lethal
 614                 // No damage modification here
 615                 // Instead, prepare the victim for his death...
 616                 targ.armorvalue = 0;
 617                 targ.spawnshieldtime = 0;
 618                 targ.health = 0.9; // this is < 1
 619                 targ.flags -= targ.flags & FL_GODMODE;
 620                 damage = 100000;
 621         }
 622         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 623         {
 624                 // no processing
 625         }
 626         else
 627         {
 628                 /*
 629                 skill based bot damage? gtfo. (tZork)
 630                 if (targ.classname == "player")
 631                 if (attacker.classname == "player")
 632                 if (!targ.isbot)
 633                 if (attacker.isbot)
 634                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 635         */
 636
 637                 // nullify damage if teamplay is on
 638                 if(deathtype != DEATH_TELEFRAG)
 639                 if(attacker.classname == "player")
 640                 {
 641                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 642                         {
 643                                 damage = 0;
 644                                 force = '0 0 0';
 645                         }
 646                         else if(!IsDifferentTeam(attacker, targ))
 647                         {
 648                                 if(autocvar_teamplay_mode == 1)
 649                                         damage = 0;
 650                                 else if(attacker != targ)
 651                                 {
 652                                         if(autocvar_teamplay_mode == 3)
 653                                                 damage = 0;
 654                                         else if(autocvar_teamplay_mode == 4)
 655                                         {
 656                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 657                                                 {
 658                                                         attacker.dmg_team = attacker.dmg_team + damage;
 659                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 660                                                         if(complainteamdamage > 0 && !g_ca) // FIXME why is g_ca ruled out here? Why not just g_mirrordamage 0 on CA servers?
 661                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 662                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 663                                                         if(g_ca)
 664                                                                 damage = 0;
 665                                                         else
 666                                                                 damage = autocvar_g_friendlyfire * damage;
 667                                                         // mirrordamage will be used LATER
 668
 669                                                         if(autocvar_g_mirrordamage_virtual)
 670                                                         {
 671                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 672                                                                 attacker.dmg_take += v_x;
 673                                                                 attacker.dmg_save += v_y;
 674                                                                 attacker.dmg_inflictor = inflictor;
 675                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 676                                                                 mirrorforce = 0;
 677                                                         }
 678
 679                                                         if(autocvar_g_friendlyfire_virtual)
 680                                                         {
 681                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 682                                                                 targ.dmg_take += v_x;
 683                                                                 targ.dmg_save += v_y;
 684                                                                 targ.dmg_inflictor = inflictor;
 685                                                                 damage = 0;
 686                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 687                                                                         force = '0 0 0';
 688                                                         }
 689                                                 }
 690                                                 else
 691                                                         damage = 0;
 692                                         }
 693                                 }
 694                         }
 695                 }
 696
 697                 if(targ.classname == "player")
 698                 if(attacker.classname == "player")
 699                 if(attacker != targ)
 700                 {
 701                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 702                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 703                 }
 704
 705                 if not(DEATH_ISSPECIAL(deathtype))
 706                 {
 707                         damage *= g_weapondamagefactor;
 708                         mirrordamage *= g_weapondamagefactor;
 709                         complainteamdamage *= g_weapondamagefactor;
 710                         force = force * g_weaponforcefactor;
 711                         mirrorforce *= g_weaponforcefactor;
 712                 }
 713
 714                 // should this be changed at all? If so, in what way?
 715                 frag_attacker = attacker;
 716                 frag_target = targ;
 717                 frag_damage = damage;
 718                 frag_force = force;
 719         frag_deathtype = deathtype;
 720                 frag_mirrordamage = mirrordamage;
 721                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 722                 damage = frag_damage;
 723                 mirrordamage = frag_mirrordamage;
 724                 force = frag_force;
 725
 726                 if not(g_minstagib)
 727                 {
 728                         // apply strength multiplier
 729                         if (attacker.items & IT_STRENGTH)
 730                         {
 731                                 if(targ == attacker)
 732                                 {
 733                                         damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 734                                         force = force * autocvar_g_balance_powerup_strength_selfforce;
 735                                 }
 736                                 else
 737                                 {
 738                                         damage = damage * autocvar_g_balance_powerup_strength_damage;
 739                                         force = force * autocvar_g_balance_powerup_strength_force;
 740                                 }
 741                         }
 742
 743                         // apply invincibility multiplier
 744                         if (targ.items & IT_INVINCIBLE)
 745                                 damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 746                 }
 747
 748                 if (targ == attacker)
 749                 {
 750                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 751                                 damage = 0;
 752                         else
 753                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 754                 }
 755
 756                 // count the damage
 757                 if(attacker)
 758                 if(!targ.deadflag)
 759                 if(targ.takedamage == DAMAGE_AIM)
 760                 if(targ != attacker)
 761                 {
 762                         entity victim;
 763                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 764                                 victim = targ.owner;
 765                         else
 766                                 victim = targ;
 767
 768                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 769                         {
 770                                 if(IsDifferentTeam(victim, attacker))
 771                                 {
 772                                         if(damage > 0)
 773                                         {
 774                                                 if(deathtype != DEATH_FIRE)
 775                                                 {
 776                                                         if(victim.BUTTON_CHAT)
 777                                                                 attacker.typehitsound += 1;
 778                                                         else
 779                                                                 attacker.hitsound += 1;
 780                                                 }
 781
 782                                                 damage_goodhits += 1;
 783                                                 damage_gooddamage += damage;
 784
 785                                                 if not(DEATH_ISSPECIAL(deathtype))
 786                                                 {
 787                                                         if(targ.classname == "player") // don't do this for vehicles
 788                                                         if(IsFlying(victim))
 789                                                                 yoda = 1;
 790                                                 }
 791                                         }
 792                                 }
 793                                 else
 794                                 {
 795                                         if(deathtype != DEATH_FIRE)
 796                                         {
 797                                                 attacker.typehitsound += 1;
 798                                         }
 799                                         if(complainteamdamage > 0)
 800                                                 if(time > attacker.teamkill_complain)
 801                                                 {
 802                                                         attacker.teamkill_complain = time + 5;
 803                                                         attacker.teamkill_soundtime = time + 0.4;
 804                                                         attacker.teamkill_soundsource = targ;
 805                                                 }
 806                                 }
 807                         }
 808                 }
 809         }
 810
 811         // apply push
 812         if (self.damageforcescale)
 813         if (vlen(force))
 814         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 815         {
 816                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 817                 if(self.movetype == MOVETYPE_PHYSICS)
 818                 {
 819                         entity farcent;
 820                         farcent = spawn();
 821                         farcent.classname = "farce";
 822                         farcent.enemy = self;
 823                         farcent.movedir = farce * 10;
 824                         if(self.mass)
 825                                 farcent.movedir = farcent.movedir * self.mass;
 826                         farcent.origin = hitloc;
 827                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 828                         farcent.nextthink = time + 0.1;
 829                         farcent.think = SUB_Remove;
 830                 }
 831                 else
 832                         self.velocity = self.velocity + farce;
 833                 self.flags &~= FL_ONGROUND;
 834                 UpdateCSQCProjectile(self);
 835         }
 836         // apply damage
 837         if (damage != 0 || (self.damageforcescale && vlen(force)))
 838         if (self.event_damage)
 839                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 840         self = oldself;
 841
 842         // apply mirror damage if any
 843         if(mirrordamage > 0 || mirrorforce > 0)
 844         {
 845                 attacker = attacker_save;
 846
 847                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 848                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 849         }
 850 }
 851
 852 float RadiusDamage_running;
 853 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 854         // Returns total damage applies to creatures
 855 {
 856         entity  targ;
 857         vector  blastorigin;
 858         vector  force;
 859         float   total_damage_to_creatures;
 860         entity  next;
 861         float   tfloordmg;
 862         float   tfloorforce;
 863
 864         float stat_damagedone;
 865
 866         if(RadiusDamage_running)
 867         {
 868                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 869                 return 0;
 870         }
 871
 872         RadiusDamage_running = 1;
 873
 874         tfloordmg = autocvar_g_throughfloor_damage;
 875         tfloorforce = autocvar_g_throughfloor_force;
 876
 877         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 878         total_damage_to_creatures = 0;
 879
 880         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 881                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 882                 {
 883                         force = inflictor.velocity;
 884                         if(vlen(force) == 0)
 885                                 force = '0 0 -1';
 886                         else
 887                                 force = normalize(force);
 888                         if(forceintensity >= 0)
 889                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 890                         else
 891                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 892                 }
 893
 894         stat_damagedone = 0;
 895
 896         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 897         while (targ)
 898         {
 899                 next = targ.chain;
 900                 if (targ != inflictor)
 901                         if (ignore != targ) if(targ.takedamage)
 902                         {
 903                                 vector nearest;
 904                                 vector diff;
 905                                 float power;
 906
 907                                 // LordHavoc: measure distance to nearest point on target (not origin)
 908                                 // (this guarentees 100% damage on a touch impact)
 909                                 nearest = targ.WarpZone_findradius_nearest;
 910                                 diff = targ.WarpZone_findradius_dist;
 911                                 // round up a little on the damage to ensure full damage on impacts
 912                                 // and turn the distance into a fraction of the radius
 913                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
 914                                 //bprint(" ");
 915                                 //bprint(ftos(power));
 916                                 //if (targ == attacker)
 917                                 //      print(ftos(power), "\n");
 918                                 if (power > 0)
 919                                 {
 920                                         float finaldmg;
 921                                         if (power > 1)
 922                                                 power = 1;
 923                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 924                                         if (finaldmg > 0)
 925                                         {
 926                                                 float a;
 927                                                 float c;
 928                                                 vector hitloc;
 929                                                 vector myblastorigin;
 930                                                 vector center;
 931
 932                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
 933
 934                                                 // if it's a player, use the view origin as reference
 935                                                 center = CENTER_OR_VIEWOFS(targ);
 936
 937                                                 force = normalize(center - myblastorigin);
 938                                                 force = force * (finaldmg / coredamage) * forceintensity;
 939                                                 hitloc = nearest;
 940
 941                                                 if(targ != directhitentity)
 942                                                 {
 943                                                         float hits;
 944                                                         float total;
 945                                                         float hitratio;
 946                                                         float mininv_f, mininv_d;
 947
 948                                                         // test line of sight to multiple positions on box,
 949                                                         // and do damage if any of them hit
 950                                                         hits = 0;
 951
 952                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
 953                                                         // so for a given max stddev:
 954                                                         // n = (1 / (2 * max stddev of hitratio))^2
 955
 956                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
 957                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
 958
 959                                                         if(autocvar_g_throughfloor_debug)
 960                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
 961
 962                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
 963
 964                                                         if(autocvar_g_throughfloor_debug)
 965                                                                 print(sprintf(" steps=%f", total));
 966
 967                                                         if (targ.classname == "player")
 968                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
 969                                                         else
 970                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
 971
 972                                                         if(autocvar_g_throughfloor_debug)
 973                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
 974
 975                                                         for(c = 0; c < total; ++c)
 976                                                         {
 977                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
 978                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
 979                                                                 if (trace_fraction == 1 || trace_ent == targ)
 980                                                                 {
 981                                                                         ++hits;
 982                                                                         if (hits > 1)
 983                                                                                 hitloc = hitloc + nearest;
 984                                                                         else
 985                                                                                 hitloc = nearest;
 986                                                                 }
 987                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
 988                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
 989                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
 990                                                         }
 991
 992                                                         nearest = hitloc * (1 / max(1, hits));
 993                                                         hitratio = (hits / total);
 994                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
 995                                                         finaldmg = finaldmg * a;
 996                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
 997                                                         force = force * a;
 998
 999                                                         if(autocvar_g_throughfloor_debug)
1000                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1001                                                 }
1002
1003                                                 // laser force adjustments :P
1004                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1005                                                 {
1006                                                         if (targ == attacker)
1007                                                         {
1008                                                                 vector vel;
1009
1010                                                                 float force_zscale;
1011                                                                 float force_velocitybiasramp;
1012                                                                 float force_velocitybias;
1013
1014                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1015                                                                 if(deathtype & HITTYPE_SECONDARY)
1016                                                                 {
1017                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1018                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1019                                                                 }
1020                                                                 else
1021                                                                 {
1022                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1023                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1024                                                                 }
1025
1026                                                                 vel = targ.velocity;
1027                                                                 vel_z = 0;
1028                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1029                                                                 force =
1030                                                                         vlen(force)
1031                                                                         *
1032                                                                         normalize(normalize(force) + vel);
1033
1034                                                                 force_z *= force_zscale;
1035                                                         }
1036                                                         else
1037                                                         {
1038                                                                 if(deathtype & HITTYPE_SECONDARY)
1039                                                                 {
1040                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1041                                                                 }
1042                                                                 else
1043                                                                 {
1044                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1045                                                                 }
1046                                                         }
1047                                                 }
1048
1049                                                 //if (targ == attacker)
1050                                                 //{
1051                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1052                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1053                                                 //      print(" (", ftos(a), ")\n");
1054                                                 //}
1055                                                 if(finaldmg || vlen(force))
1056                                                 {
1057                                                         if(targ.iscreature)
1058                                                         {
1059                                                                 total_damage_to_creatures += finaldmg;
1060
1061                                                                 if(accuracy_isgooddamage(attacker, targ))
1062                                                                         stat_damagedone += finaldmg;
1063                                                         }
1064
1065                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1066                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1067                                                         else
1068                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1069                                                 }
1070                                         }
1071                                 }
1072                         }
1073                 targ = next;
1074         }
1075
1076         RadiusDamage_running = 0;
1077
1078         if(!DEATH_ISSPECIAL(deathtype))
1079                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1080
1081         return total_damage_to_creatures;
1082 }
1083
1084 .float fire_damagepersec;
1085 .float fire_endtime;
1086 .float fire_deathtype;
1087 .entity fire_owner;
1088 .float fire_hitsound;
1089 .entity fire_burner;
1090
1091 void fireburner_think();
1092
1093 float Fire_IsBurning(entity e)
1094 {
1095         return (time < e.fire_endtime);
1096 }
1097
1098 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1099 {
1100         float dps;
1101         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1102
1103         if(e.classname == "player")
1104         {
1105                 if(e.deadflag)
1106                         return -1;
1107         }
1108         else
1109         {
1110                 if(!e.fire_burner)
1111                 {
1112                         // print("adding a fire burner to ", e.classname, "\n");
1113                         e.fire_burner = spawn();
1114                         e.fire_burner.classname = "fireburner";
1115                         e.fire_burner.think = fireburner_think;
1116                         e.fire_burner.nextthink = time;
1117                         e.fire_burner.owner = e;
1118                 }
1119         }
1120
1121         t = max(t, 0.1);
1122         dps = d / t;
1123         if(Fire_IsBurning(e))
1124         {
1125                 mintime = e.fire_endtime - time;
1126                 maxtime = max(mintime, t);
1127
1128                 mindps = e.fire_damagepersec;
1129                 maxdps = max(mindps, dps);
1130
1131                 if(maxtime > mintime || maxdps > mindps)
1132                 {
1133                         // Constraints:
1134
1135                         // damage we have right now
1136                         mindamage = mindps * mintime;
1137
1138                         // damage we want to get
1139                         maxdamage = mindamage + d;
1140
1141                         // but we can't exceed maxtime * maxdps!
1142                         totaldamage = min(maxdamage, maxtime * maxdps);
1143
1144                         // LEMMA:
1145                         // Look at:
1146                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1147                         // We see:
1148                         // totaldamage <= maxtime * maxdps
1149                         // ==> totaldamage / maxdps <= maxtime.
1150                         // We also see:
1151                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1152                         //                     >= min(mintime, maxtime)
1153                         // ==> totaldamage / maxdps >= mintime.
1154
1155                         /*
1156                         // how long do we damage then?
1157                         // at least as long as before
1158                         // but, never exceed maxdps
1159                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1160                         */
1161
1162                         // alternate:
1163                         // at most as long as maximum allowed
1164                         // but, never below mindps
1165                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1166
1167                         // assuming t > mintime, dps > mindps:
1168                         // we get d = t * dps = maxtime * maxdps
1169                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1170                         // totaldamage / maxdps = maxtime
1171                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1172                         // FROM THIS:
1173                         // a) totaltime = max(mintime, maxtime) = maxtime
1174                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1175
1176                         // assuming t <= mintime:
1177                         // we get maxtime = mintime
1178                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1179                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1180
1181                         // assuming dps <= mindps:
1182                         // we get mindps = maxdps.
1183                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1184                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1185                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1186
1187                         e.fire_damagepersec = totaldamage / totaltime;
1188                         e.fire_endtime = time + totaltime;
1189                         if(totaldamage > 1.2 * mindamage)
1190                         {
1191                                 e.fire_deathtype = dt;
1192                                 if(e.fire_owner != o)
1193                                 {
1194                                         e.fire_owner = o;
1195                                         e.fire_hitsound = FALSE;
1196                                 }
1197                         }
1198                         if(accuracy_isgooddamage(o, e))
1199                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1200                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1201                 }
1202                 else
1203                         return 0;
1204         }
1205         else
1206         {
1207                 e.fire_damagepersec = dps;
1208                 e.fire_endtime = time + t;
1209                 e.fire_deathtype = dt;
1210                 e.fire_owner = o;
1211                 e.fire_hitsound = FALSE;
1212                 if(accuracy_isgooddamage(o, e))
1213                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1214                 return d;
1215         }
1216 }
1217
1218 void Fire_ApplyDamage(entity e)
1219 {
1220         float t, d, hi, ty;
1221         entity o;
1222
1223         if not(Fire_IsBurning(e))
1224                 return;
1225
1226         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1227         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1228                 o = e.fire_owner;
1229
1230         // water and slime stop fire
1231         if(e.waterlevel)
1232         if(e.watertype != CONTENT_LAVA)
1233                 e.fire_endtime = 0;
1234
1235         // ice stops fire
1236         if(e.freezetag_frozen)
1237                 e.fire_endtime = 0;
1238
1239         t = min(frametime, e.fire_endtime - time);
1240         d = e.fire_damagepersec * t;
1241
1242         hi = e.fire_owner.hitsound;
1243         ty = e.fire_owner.typehitsound;
1244         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1245         if(e.fire_hitsound && e.fire_owner)
1246         {
1247                 e.fire_owner.hitsound = hi;
1248                 e.fire_owner.typehitsound = ty;
1249         }
1250         e.fire_hitsound = TRUE;
1251
1252         if not(IS_INDEPENDENT_PLAYER(e))
1253         FOR_EACH_PLAYER(other) if(e != other)
1254         {
1255                 if(other.classname == "player")
1256                 if(other.deadflag == DEAD_NO)
1257                 if not(IS_INDEPENDENT_PLAYER(other))
1258                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1259                 {
1260                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1261                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1262                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1263                 }
1264         }
1265 }
1266
1267 void Fire_ApplyEffect(entity e)
1268 {
1269         if(Fire_IsBurning(e))
1270                 e.effects |= EF_FLAME;
1271         else
1272                 e.effects &~= EF_FLAME;
1273 }
1274
1275 void fireburner_think()
1276 {
1277         // for players, this is done in the regular loop
1278         if(wasfreed(self.owner))
1279         {
1280                 remove(self);
1281                 return;
1282         }
1283         Fire_ApplyEffect(self.owner);
1284         if(!Fire_IsBurning(self.owner))
1285         {
1286                 self.owner.fire_burner = world;
1287                 remove(self);
1288                 return;
1289         }
1290         Fire_ApplyDamage(self.owner);
1291         self.nextthink = time;
1292 }