qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50 float headshot;
  51 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  52
  53 .float dmg_team;
  54 .float teamkill_complain;
  55 .float teamkill_soundtime;
  56 .entity teamkill_soundsource;
  57 .entity pusher;
  58 .float istypefrag;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teamplay)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 entity GiveFrags_randomweapons;
 106 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
 107 {
 108         // TODO route through PlayerScores instead
 109         if(gameover) return;
 110
 111         if(f < 0)
 112         {
 113                 if(targ == attacker)
 114                 {
 115                         // suicide
 116                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 117                 }
 118                 else
 119                 {
 120                         // teamkill
 121                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 122                 }
 123         }
 124         else
 125         {
 126                 // regular frag
 127                 PlayerScore_Add(attacker, SP_KILLS, 1);
 128                 if(targ.playerid)
 129                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 130         }
 131
 132         PlayerScore_Add(targ, SP_DEATHS, 1);
 133
 134         if(g_arena || g_ca)
 135                 if(autocvar_g_arena_roundbased)
 136                         return;
 137
 138         if(targ != attacker) // not for suicides
 139         if(g_weaponarena_random)
 140         {
 141                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 142                 float culprit;
 143                 culprit = DEATH_WEAPONOF(deathtype);
 144                 if(!culprit)
 145                         culprit = attacker.weapon;
 146                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 147                         culprit = attacker.weapon;
 148
 149                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 150                 {
 151                         // no exchange
 152                 }
 153                 else
 154                 {
 155                         if(!GiveFrags_randomweapons)
 156                         {
 157                                 GiveFrags_randomweapons = spawn();
 158                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 159                         }
 160
 161                         if(inWarmupStage)
 162                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 163                         else
 164                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 165
 166                         // all others (including the culprit): remove
 167                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 168                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 169
 170                         // among the remaining ones, choose one by random
 171                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 172
 173                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 174                         {
 175                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 176                                 WEPSET_ANDNOT_EW(attacker, culprit);
 177                         }
 178                 }
 179
 180                 // after a frag, choose another random weapon set
 181                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 182                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 183         }
 184
 185         // FIXME fix the mess this is (we have REAL points now!)
 186         entity oldself;
 187         oldself = self;
 188         self = attacker;
 189         frag_attacker = attacker;
 190         frag_target = targ;
 191         frag_score = f;
 192         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 193         {
 194                 f = frag_score;
 195                 self = oldself;
 196         }
 197         else
 198         {
 199                 self = oldself;
 200                 if(g_runematch)
 201                 {
 202                         f = RunematchHandleFrags(attacker, targ, f);
 203                 }
 204                 else if(g_lms)
 205                 {
 206                         // remove a life
 207                         float tl;
 208                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 209                         if(tl < lms_lowest_lives)
 210                                 lms_lowest_lives = tl;
 211                         if(tl <= 0)
 212                         {
 213                                 if(!lms_next_place)
 214                                         lms_next_place = player_count;
 215                                 else
 216                                         lms_next_place = min(lms_next_place, player_count);
 217                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 218                                 --lms_next_place;
 219                         }
 220                         f = 0;
 221                 }
 222         }
 223
 224         attacker.totalfrags += f;
 225
 226         if(f)
 227                 UpdateFrags(attacker, f);
 228 }
 229
 230 string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 231 {
 232         string health_output = string_null;
 233         string ping_output = string_null;
 234         string handicap_output = string_null;
 235         string output = string_null;
 236
 237         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 238         {
 239                 // health/armor of attacker (person who killed you)
 240                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 241                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 242
 243                 // ping display
 244                 if(autocvar_sv_fraginfo_ping)
 245                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 246
 247                 // handicap display
 248                 if(autocvar_sv_fraginfo_handicap)
 249                 {
 250                         if(autocvar_sv_fraginfo_handicap == 2)
 251                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 252                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 253                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 254                 }
 255
 256                 // format the string
 257                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 258                         ping_output, (handicap_output ? "^7 / " : ""),
 259                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 260
 261                 // add new line to the beginning if there is a message
 262                 if(output) { output = strcat("\n", output); }
 263         }
 264
 265         return output;
 266 }
 267
 268 string AppendItemcodes(string s, entity player)
 269 {
 270         float w;
 271         w = player.weapon;
 272         //if(w == 0)
 273         //      w = player.switchweapon;
 274         if(w == 0)
 275                 w = player.cnt; // previous weapon!
 276         s = strcat(s, ftos(w));
 277         if(time < player.strength_finished)
 278                 s = strcat(s, "S");
 279         if(time < player.invincible_finished)
 280                 s = strcat(s, "I");
 281         if(player.flagcarried != world)
 282                 s = strcat(s, "F");
 283         if(player.BUTTON_CHAT)
 284                 s = strcat(s, "T");
 285         if(player.kh_next)
 286                 s = strcat(s, "K");
 287         if(player.runes)
 288                 s = strcat(s, "|", ftos(player.runes));
 289         return s;
 290 }
 291
 292 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 293 {
 294         string s;
 295         if(!autocvar_sv_eventlog)
 296                 return;
 297         s = strcat(":kill:", mode);
 298         s = strcat(s, ":", ftos(killer.playerid));
 299         s = strcat(s, ":", ftos(killed.playerid));
 300         s = strcat(s, ":type=", ftos(deathtype));
 301         s = strcat(s, ":items=");
 302         s = AppendItemcodes(s, killer);
 303         if(killed != killer)
 304         {
 305                 s = strcat(s, ":victimitems=");
 306                 s = AppendItemcodes(s, killed);
 307         }
 308         GameLogEcho(s);
 309 }
 310
 311 void Send_KillNotification (string s1, string s2, string s3, float msg, float type)
 312 {
 313         WriteByte(MSG_ALL, SVC_TEMPENTITY);
 314         WriteByte(MSG_ALL, TE_CSQC_KILLNOTIFY);
 315         WriteString(MSG_ALL, s1);
 316         WriteString(MSG_ALL, s2);
 317         WriteString(MSG_ALL, s3);
 318         WriteShort(MSG_ALL, msg);
 319         WriteByte(MSG_ALL, type);
 320 }
 321
 322 // Function is used to send a generic centerprint whose content CSQC gets to decide (gentle version or not in the below cases)
 323 void Send_CSQC_KillCenterprint(entity e, string s1, string s2, float msg, float type)
 324 {
 325         if (clienttype(e) == CLIENTTYPE_REAL)
 326         {
 327                 msg_entity = e;
 328                 WRITESPECTATABLE_MSG_ONE({
 329                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 330                         WriteByte(MSG_ONE, TE_CSQC_KILLCENTERPRINT);
 331                         WriteString(MSG_ONE, s1);
 332                         WriteString(MSG_ONE, s2);
 333                         WriteShort(MSG_ONE, msg);
 334                         WriteByte(MSG_ONE, type);
 335                 });
 336         }
 337 }
 338
 339 void Obituary (entity attacker, entity inflictor, entity targ, float deathtype)
 340 {
 341         string  s, a, msg;
 342         float w, type;
 343
 344         if (targ.classname == "player")
 345         {
 346                 s = targ.netname;
 347                 a = attacker.netname;
 348
 349                 if (targ == attacker) // suicides
 350                 {
 351                         if (deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 352                                 msg = ColoredTeamName(targ.team); // TODO: check if needed?
 353                         else
 354                                 msg = "";
 355             if(!g_cts) // no "killed your own dumb self" message in CTS
 356                 Send_CSQC_KillCenterprint(targ, msg, "", deathtype, MSG_SUICIDE);
 357
 358                         if(deathtype != DEATH_TEAMCHANGE && deathtype != DEATH_QUIET)
 359                         {
 360                                 LogDeath("suicide", deathtype, targ, targ);
 361                                 GiveFrags(attacker, targ, -1, deathtype);
 362                         }
 363
 364                         if (targ.killcount > 2)
 365                                 msg = ftos(targ.killcount);
 366                         else
 367                                 msg = "";
 368                         if(teamplay && deathtype == DEATH_MIRRORDAMAGE)
 369                         {
 370                                 if(attacker.team == COLOR_TEAM1)
 371                                         deathtype = KILL_TEAM_RED;
 372                                 else
 373                                         deathtype = KILL_TEAM_BLUE;
 374                         }
 375
 376                         Send_KillNotification(s, msg, ftos(w), deathtype, MSG_SUICIDE);
 377                 }
 378                 else if (attacker.classname == "player")
 379                 {
 380                         if(!IsDifferentTeam(attacker, targ))
 381                         {
 382                                 if(attacker.team == COLOR_TEAM1)
 383                                         type = KILL_TEAM_RED;
 384                                 else
 385                                         type = KILL_TEAM_BLUE;
 386
 387                                 GiveFrags(attacker, targ, -1, deathtype);
 388
 389                                 Send_CSQC_KillCenterprint(attacker, s, "", type, MSG_KILL);
 390
 391                                 if (targ.killcount > 2)
 392                                         msg = ftos(targ.killcount);
 393                                 else
 394                                         msg = "";
 395
 396                                 if (attacker.killcount > 2) {
 397                                         msg = ftos(attacker.killcount);
 398                                         type = KILL_TEAM_SPREE;
 399                                 }
 400                                 Send_KillNotification(a, s, msg, type, MSG_KILL);
 401
 402                                 attacker.killcount = 0;
 403
 404                                 LogDeath("tk", deathtype, attacker, targ);
 405                         }
 406                         else
 407                         {
 408                                 if (!checkrules_firstblood)
 409                                 {
 410                                         checkrules_firstblood = TRUE;
 411                                         Send_KillNotification(a, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 412                                         // TODO: make these print a newline if they dont
 413                                         Send_CSQC_KillCenterprint(attacker, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 414                                         Send_CSQC_KillCenterprint(targ, "", "", KILL_FIRST_VICTIM, MSG_KILL);
 415                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 416                                         PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 417                                 }
 418
 419                                 if(targ.istypefrag) {
 420                                         Send_CSQC_KillCenterprint(attacker, s, Obituary_ExtraFragInfo(targ), KILL_TYPEFRAG, MSG_KILL);
 421                                         Send_CSQC_KillCenterprint(targ, a, Obituary_ExtraFragInfo(attacker), KILL_TYPEFRAGGED, MSG_KILL);
 422                                 } else {
 423                                         Send_CSQC_KillCenterprint(attacker, s, Obituary_ExtraFragInfo(targ), KILL_FRAG, MSG_KILL);
 424                                         Send_CSQC_KillCenterprint(targ, a, Obituary_ExtraFragInfo(attacker), KILL_FRAGGED, MSG_KILL);
 425                                 }
 426
 427                                 attacker.taunt_soundtime = time + 1;
 428
 429                                 if (deathtype == DEATH_HURTTRIGGER && inflictor.message2 != "")
 430                                         msg = inflictor.message2;
 431                                 else if (deathtype == DEATH_CUSTOM)
 432                                         msg = deathmessage;
 433                                 else
 434                                         msg = "";
 435
 436                                 if(strstrofs(msg, "%", 0) < 0)
 437                                         msg = strcat("%s ", msg, " by %s");
 438
 439                                 Send_KillNotification(a, s, msg, deathtype, MSG_KILL);
 440
 441                                 GiveFrags(attacker, targ, 1, deathtype);
 442
 443                                 if (targ.killcount > 2) {
 444                                         Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE);
 445                                 }
 446
 447                                 attacker.killcount = attacker.killcount + 1;
 448
 449                                 if (attacker.killcount == 3)
 450                                 {
 451                                         Send_KillNotification(a, "", "", KILL_SPREE_3, MSG_SPREE);
 452                                         AnnounceTo(attacker, "03kills");
 453                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_3, 1);
 454                                 }
 455                                 else if (attacker.killcount == 5)
 456                                 {
 457                                         Send_KillNotification(a, "", "", KILL_SPREE_5, MSG_SPREE);
 458                                         AnnounceTo(attacker, "05kills");
 459                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_5, 1);
 460                                 }
 461                                 else if (attacker.killcount == 10)
 462                                 {
 463                                         Send_KillNotification(a, "", "", KILL_SPREE_10, MSG_SPREE);
 464                                         AnnounceTo(attacker, "10kills");
 465                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_10, 1);
 466                                 }
 467                                 else if (attacker.killcount == 15)
 468                                 {
 469                                         Send_KillNotification(a, "", "", KILL_SPREE_15, MSG_SPREE);
 470                                         AnnounceTo(attacker, "15kills");
 471                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_15, 1);
 472                                 }
 473                                 else if (attacker.killcount == 20)
 474                                 {
 475                                         Send_KillNotification(a, "", "", KILL_SPREE_20, MSG_SPREE);
 476                                         AnnounceTo(attacker, "20kills");
 477                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_20, 1);
 478                                 }
 479                                 else if (attacker.killcount == 25)
 480                                 {
 481                                         Send_KillNotification(a, "", "", KILL_SPREE_25, MSG_SPREE);
 482                                         AnnounceTo(attacker, "25kills");
 483                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_25, 1);
 484                                 }
 485                                 else if (attacker.killcount == 30)
 486                                 {
 487                                         Send_KillNotification(a, "", "", KILL_SPREE_30, MSG_SPREE);
 488                                         AnnounceTo(attacker, "30kills");
 489                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_30, 1);
 490                                 }
 491                                 else if (attacker.killcount > 2) {
 492                                         Send_KillNotification(a, ftos(attacker.killcount), "", KILL_SPREE, MSG_SPREE);
 493                                 }
 494                                 LogDeath("frag", deathtype, attacker, targ);
 495                         }
 496                 }
 497                 else
 498                 {
 499                         Send_CSQC_KillCenterprint(targ, "", "", deathtype, MSG_KILL_ACTION);
 500                         if (deathtype == DEATH_HURTTRIGGER && inflictor.message != "")
 501                                 msg = inflictor.message;
 502                         else if (deathtype == DEATH_CUSTOM)
 503                                 msg = deathmessage;
 504                         else
 505                                 msg = "";
 506                         if(strstrofs(msg, "%", 0) < 0)
 507                                 msg = strcat("%s ", msg);
 508
 509                         GiveFrags(targ, targ, -1, deathtype);
 510                         if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
 511                                 AnnounceTo(targ, "botlike");
 512                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 513                         }
 514                         Send_KillNotification(s, msg, "", deathtype, MSG_KILL_ACTION);
 515
 516                         if (targ.killcount > 2)
 517                                 Send_KillNotification(s, ftos(targ.killcount), "", 0, MSG_KILL_ACTION_SPREE);
 518
 519                         LogDeath("accident", deathtype, targ, targ);
 520                 }
 521
 522                 targ.death_origin = targ.origin;
 523                 if(targ != attacker)
 524                         targ.killer_origin = attacker.origin;
 525
 526                 // FIXME: this should go in PutClientInServer
 527                 if (targ.killcount)
 528                         targ.killcount = 0;
 529         }
 530 }
 531
 532 // these are updated by each Damage call for use in button triggering and such
 533 entity damage_targ;
 534 entity damage_inflictor;
 535 entity damage_attacker;
 536
 537 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 538 {
 539         float mirrordamage;
 540         float mirrorforce;
 541         float teamdamage0;
 542         entity attacker_save;
 543         mirrordamage = 0;
 544         mirrorforce = 0;
 545
 546         if (gameover || targ.killcount == -666)
 547                 return;
 548
 549         entity oldself;
 550         oldself = self;
 551         self = targ;
 552         damage_targ = targ;
 553         damage_inflictor = inflictor;
 554         damage_attacker = attacker;
 555                 attacker_save = attacker;
 556
 557         if(targ.classname == "player")
 558                 if(targ.hook)
 559                         if(targ.hook.aiment)
 560                                 if(targ.hook.aiment == attacker)
 561                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 562
 563         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 564         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 565         {
 566                 if(targ.classname == "player")
 567                         if not(IsDifferentTeam(targ, attacker))
 568                         {
 569                                 self = oldself;
 570                                 return;
 571                         }
 572         }
 573
 574         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE || deathtype == DEATH_QUIET)
 575         {
 576                 // These are ALWAYS lethal
 577                 // No damage modification here
 578                 // Instead, prepare the victim for his death...
 579                 targ.armorvalue = 0;
 580                 targ.spawnshieldtime = 0;
 581                 targ.health = 0.9; // this is < 1
 582                 targ.flags -= targ.flags & FL_GODMODE;
 583                 damage = 100000;
 584         }
 585         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 586         {
 587                 // no processing
 588         }
 589         else
 590         {
 591                 /*
 592                 skill based bot damage? gtfo. (tZork)
 593                 if (targ.classname == "player")
 594                 if (attacker.classname == "player")
 595                 if (!targ.isbot)
 596                 if (attacker.isbot)
 597                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 598         */
 599
 600                 // nullify damage if teamplay is on
 601                 if(deathtype != DEATH_TELEFRAG)
 602                 if(attacker.classname == "player")
 603                 {
 604                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 605                         {
 606                                 damage = 0;
 607                                 force = '0 0 0';
 608                         }
 609                         else if(!IsDifferentTeam(attacker, targ))
 610                         {
 611                                 if(autocvar_teamplay_mode == 1)
 612                                         damage = 0;
 613                                 else if(attacker != targ)
 614                                 {
 615                                         if(autocvar_teamplay_mode == 3)
 616                                                 damage = 0;
 617                                         else if(autocvar_teamplay_mode == 4)
 618                                         {
 619                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 620                                                 {
 621                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 622                                                         attacker.dmg_team = attacker.dmg_team + damage;
 623                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 624                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 625                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 626                                                         if(g_minstagib)
 627                                                         {
 628                                                                 if(autocvar_g_friendlyfire == 0)
 629                                                                         damage = 0;
 630                                                         }
 631                                                         else if(g_ca)
 632                                                                 damage = 0;
 633                                                         else
 634                                                                 damage = autocvar_g_friendlyfire * damage;
 635                                                         // mirrordamage will be used LATER
 636
 637                                                         if(autocvar_g_mirrordamage_virtual)
 638                                                         {
 639                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 640                                                                 attacker.dmg_take += v_x;
 641                                                                 attacker.dmg_save += v_y;
 642                                                                 attacker.dmg_inflictor = inflictor;
 643                                                                 mirrordamage = 0;
 644                                                                 mirrorforce = 0;
 645                                                         }
 646
 647                                                         if(autocvar_g_friendlyfire_virtual)
 648                                                         {
 649                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 650                                                                 targ.dmg_take += v_x;
 651                                                                 targ.dmg_save += v_y;
 652                                                                 targ.dmg_inflictor = inflictor;
 653                                                                 damage = 0;
 654                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 655                                                                         force = '0 0 0';
 656                                                         }
 657                                                 }
 658                                                 else
 659                                                         damage = 0;
 660                                         }
 661                                 }
 662                         }
 663                 }
 664
 665                 if(targ.classname == "player")
 666                 if(attacker.classname == "player")
 667                 if(attacker != targ)
 668                 {
 669                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 670                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 671                 }
 672
 673                 if(targ.classname == "player")
 674                 if (g_minstagib)
 675                 {
 676                         if ((deathtype == DEATH_FALL)  ||
 677                                 (deathtype == DEATH_DROWN) ||
 678                                 (deathtype == DEATH_SLIME) ||
 679                                 (deathtype == DEATH_LAVA)  ||
 680                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 681                         {
 682                                 self = oldself;
 683                                 return;
 684                         }
 685                         if(damage > 0)
 686                             damage = 10000;
 687                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 688                         {
 689                                 targ.armorvalue -= 1;
 690                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 691                                 damage = 0;
 692                                 targ.hitsound += 1;
 693                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 694                         }
 695                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 696                         {
 697                                 damage = 0;
 698                                 mirrordamage = 0;
 699                                 if (targ != attacker)
 700                                 {
 701                                         if ((targ.health >= 1) && (targ.classname == "player"))
 702                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 703                                         force = '0 0 0';
 704                                         // keep mirrorforce
 705                                         attacker = targ;
 706                                 }
 707                         }
 708                 }
 709
 710                 if not(DEATH_ISSPECIAL(deathtype))
 711                 {
 712                         damage *= g_weapondamagefactor;
 713                         mirrordamage *= g_weapondamagefactor;
 714                         force = force * g_weaponforcefactor;
 715                         mirrorforce *= g_weaponforcefactor;
 716                 }
 717
 718                 // should this be changed at all? If so, in what way?
 719                 frag_attacker = attacker;
 720                 frag_target = targ;
 721                 frag_damage = damage;
 722                 frag_force = force;
 723         frag_deathtype = deathtype;
 724                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 725                 damage = frag_damage;
 726                 force = frag_force;
 727
 728                 // apply strength multiplier
 729                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 730                 {
 731                         if(targ == attacker)
 732                         {
 733                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 734                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 735                         }
 736                         else
 737                         {
 738                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 739                                 force = force * autocvar_g_balance_powerup_strength_force;
 740                         }
 741                 }
 742
 743                 // apply invincibility multiplier
 744                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 745                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 746
 747                 if (targ == attacker)
 748                 {
 749                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 750                                 damage = 0;
 751                         else
 752                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 753                 }
 754
 755                 if(g_runematch)
 756                 {
 757                         // apply strength rune
 758                         if (attacker.runes & RUNE_STRENGTH)
 759                         {
 760                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 761                                 {
 762                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 763                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 764                                 }
 765                                 else
 766                                 {
 767                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 768                                         force = force * autocvar_g_balance_rune_strength_force;
 769                                 }
 770                         }
 771                         else if (attacker.runes & CURSE_WEAK)
 772                         {
 773                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 774                                 force = force * autocvar_g_balance_curse_weak_force;
 775                         }
 776
 777                         // apply defense rune
 778                         if (targ.runes & RUNE_DEFENSE)
 779                         {
 780                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 781                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 782                                 else
 783                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 784                         }
 785                         else if (targ.runes & CURSE_VULNER)
 786                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 787                 }
 788
 789                 // count the damage
 790                 if(attacker)
 791                 if(!targ.deadflag)
 792                 if(targ.takedamage == DAMAGE_AIM)
 793                 if(targ != attacker)
 794                 {
 795                         if(damage_headshotbonus)
 796                         {
 797                                 if(targ.classname == "player")
 798                                 {
 799                                         // HEAD SHOT:
 800                                         // find height of hit on player axis
 801                                         // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 802                                         vector headmins, headmaxs, org;
 803                                         org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 804                                         headmins = org + GetHeadshotMins(targ);
 805                                         headmaxs = org + GetHeadshotMaxs(targ);
 806                                         if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 807                                         {
 808                                                 deathtype |= HITTYPE_HEADSHOT;
 809                                         }
 810                                 }
 811                                 else if(targ.classname == "turret_head")
 812                                 {
 813                                         deathtype |= HITTYPE_HEADSHOT;
 814                                 }
 815                                 if(deathtype & HITTYPE_HEADSHOT)
 816                                         if(damage_headshotbonus > 0)
 817                                                 damage *= 1 + damage_headshotbonus;
 818                         }
 819
 820                         entity victim;
 821                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 822                                 victim = targ.owner;
 823                         else
 824                                 victim = targ;
 825
 826                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 827                         {
 828                                 if(IsDifferentTeam(victim, attacker))
 829                                 {
 830                                         if(damage > 0)
 831                                         {
 832                                                 if(deathtype != DEATH_FIRE)
 833                                                 {
 834                                                         if(victim.BUTTON_CHAT)
 835                                                                 attacker.typehitsound += 1;
 836                                                         else
 837                                                                 attacker.hitsound += 1;
 838                                                 }
 839
 840                                                 damage_goodhits += 1;
 841                                                 damage_gooddamage += damage;
 842
 843                                                 if not(DEATH_ISSPECIAL(deathtype))
 844                                                 {
 845                                                         if(targ.classname == "player") // don't do this for vehicles
 846                                                         if(!g_minstagib)
 847                                                         if(IsFlying(victim))
 848                                                                 yoda = 1;
 849
 850                                                         if(g_minstagib)
 851                                                         if(victim.items & IT_STRENGTH)
 852                                                                 yoda = 1;
 853
 854                                                         if(deathtype & HITTYPE_HEADSHOT)
 855                                                                 headshot = 1;
 856                                                 }
 857                                                 if(g_ca)
 858                                                         PlayerScore_Add(attacker, SP_SCORE, damage * autocvar_g_ca_damage2score_multiplier);
 859                                         }
 860                                 }
 861                                 else
 862                                 {
 863                                         if(deathtype != DEATH_FIRE)
 864                                         {
 865                                                 attacker.typehitsound += 1;
 866                                         }
 867                                         if(mirrordamage > 0)
 868                                                 if(time > attacker.teamkill_complain)
 869                                                 {
 870                                                         attacker.teamkill_complain = time + 5;
 871                                                         attacker.teamkill_soundtime = time + 0.4;
 872                                                         attacker.teamkill_soundsource = targ;
 873                                                 }
 874                                 }
 875                         }
 876                 }
 877         }
 878
 879         // apply push
 880         if (self.damageforcescale)
 881         if (vlen(force))
 882         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 883         {
 884                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 885                 if(self.movetype == MOVETYPE_PHYSICS)
 886                 {
 887                         entity farcent;
 888                         farcent = spawn();
 889                         farcent.classname = "farce";
 890                         farcent.enemy = self;
 891                         farcent.movedir = farce * 10;
 892                         if(self.mass)
 893                                 farcent.movedir = farcent.movedir * self.mass;
 894                         farcent.origin = hitloc;
 895                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 896                         farcent.nextthink = time + 0.1;
 897                         farcent.think = SUB_Remove;
 898                 }
 899                 else
 900                         self.velocity = self.velocity + farce;
 901                 self.flags &~= FL_ONGROUND;
 902                 UpdateCSQCProjectile(self);
 903         }
 904         // apply damage
 905         if (damage != 0 || (self.damageforcescale && vlen(force)))
 906         if (self.event_damage)
 907                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 908         self = oldself;
 909
 910         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 911         {
 912                 if(g_runematch)
 913                 {
 914                         if (attacker.runes & RUNE_VAMPIRE)
 915                         {
 916                         // apply vampire rune
 917                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 918                                 {
 919                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 920                                         attacker.health = bound(
 921                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 922                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 923                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 924                                 }
 925                                 else
 926                                 {
 927                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 928                                         attacker.health = bound(
 929                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 930                                                                                         // empathy won't let you gain health in the same way...
 931                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 932                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 933                                         }
 934                         }
 935                         // apply empathy curse
 936                         else if (attacker.runes & CURSE_EMPATHY)
 937                         {
 938                                 attacker.health = bound(
 939                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 940                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 941                                         attacker.health);
 942                         }
 943                 }
 944         }
 945
 946         // apply mirror damage if any
 947         if(mirrordamage > 0 || mirrorforce > 0)
 948         {
 949                 attacker = attacker_save;
 950                 if(g_minstagib)
 951                 if(mirrordamage > 0)
 952                 {
 953                         // just lose extra LIVES, don't kill the player for mirror damage
 954                         if(attacker.armorvalue > 0)
 955                         {
 956                                 attacker.armorvalue = attacker.armorvalue - 1;
 957                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 958                                 attacker.hitsound += 1;
 959                         }
 960                         mirrordamage = 0;
 961                 }
 962
 963                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 964                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 965         }
 966 }
 967
 968 float RadiusDamage_running;
 969 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 970         // Returns total damage applies to creatures
 971 {
 972         entity  targ;
 973         vector  blastorigin;
 974         vector  force;
 975         float   total_damage_to_creatures;
 976         entity  next;
 977         float   tfloordmg;
 978         float   tfloorforce;
 979
 980         float stat_damagedone;
 981
 982         if(RadiusDamage_running)
 983         {
 984                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 985                 return 0;
 986         }
 987
 988         RadiusDamage_running = 1;
 989
 990         tfloordmg = autocvar_g_throughfloor_damage;
 991         tfloorforce = autocvar_g_throughfloor_force;
 992
 993         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 994         total_damage_to_creatures = 0;
 995
 996         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 997                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 998                 {
 999                         force = inflictor.velocity;
1000                         if(vlen(force) == 0)
1001                                 force = '0 0 -1';
1002                         else
1003                                 force = normalize(force);
1004                         if(forceintensity >= 0)
1005                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
1006                         else
1007                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
1008                 }
1009
1010         stat_damagedone = 0;
1011
1012         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
1013         while (targ)
1014         {
1015                 next = targ.chain;
1016                 if (targ != inflictor)
1017                         if (ignore != targ) if(targ.takedamage)
1018                         {
1019                                 vector nearest;
1020                                 vector diff;
1021                                 float power;
1022
1023                                 // LordHavoc: measure distance to nearest point on target (not origin)
1024                                 // (this guarentees 100% damage on a touch impact)
1025                                 nearest = targ.WarpZone_findradius_nearest;
1026                                 diff = targ.WarpZone_findradius_dist;
1027                                 // round up a little on the damage to ensure full damage on impacts
1028                                 // and turn the distance into a fraction of the radius
1029                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1030                                 //bprint(" ");
1031                                 //bprint(ftos(power));
1032                                 //if (targ == attacker)
1033                                 //      print(ftos(power), "\n");
1034                                 if (power > 0)
1035                                 {
1036                                         float finaldmg;
1037                                         if (power > 1)
1038                                                 power = 1;
1039                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1040                                         if (finaldmg > 0)
1041                                         {
1042                                                 float a;
1043                                                 float c;
1044                                                 vector hitloc;
1045                                                 vector myblastorigin;
1046                                                 vector center;
1047
1048                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1049
1050                                                 // if it's a player, use the view origin as reference
1051                                                 if (targ.classname == "player")
1052                                                         center = targ.origin + targ.view_ofs;
1053                                                 else
1054                                                         center = targ.origin + (targ.mins + targ.maxs) * 0.5;
1055
1056                                                 force = normalize(center - myblastorigin);
1057                                                 force = force * (finaldmg / coredamage) * forceintensity;
1058                                                 hitloc = nearest;
1059
1060                                                 if(targ != directhitentity)
1061                                                 {
1062                                                         float hits;
1063                                                         float total;
1064                                                         float hitratio;
1065                                                         float mininv_f, mininv_d;
1066
1067                                                         // test line of sight to multiple positions on box,
1068                                                         // and do damage if any of them hit
1069                                                         hits = 0;
1070
1071                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1072                                                         // so for a given max stddev:
1073                                                         // n = (1 / (2 * max stddev of hitratio))^2
1074
1075                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1076                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1077
1078                                                         if(autocvar_g_throughfloor_debug)
1079                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1080
1081                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1082
1083                                                         if(autocvar_g_throughfloor_debug)
1084                                                                 print(sprintf(" steps=%f", total));
1085
1086                                                         if (targ.classname == "player")
1087                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1088                                                         else
1089                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1090
1091                                                         if(autocvar_g_throughfloor_debug)
1092                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1093
1094                                                         for(c = 0; c < total; ++c)
1095                                                         {
1096                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1097                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1098                                                                 if (trace_fraction == 1 || trace_ent == targ)
1099                                                                 {
1100                                                                         ++hits;
1101                                                                         if (hits > 1)
1102                                                                                 hitloc = hitloc + nearest;
1103                                                                         else
1104                                                                                 hitloc = nearest;
1105                                                                 }
1106                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1107                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1108                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1109                                                         }
1110
1111                                                         nearest = hitloc * (1 / max(1, hits));
1112                                                         hitratio = (hits / total);
1113                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1114                                                         finaldmg = finaldmg * a;
1115                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1116                                                         force = force * a;
1117
1118                                                         if(autocvar_g_throughfloor_debug)
1119                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1120                                                 }
1121
1122                                                 // laser force adjustments :P
1123                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1124                                                 {
1125                                                         if (targ == attacker)
1126                                                         {
1127                                                                 vector vel;
1128
1129                                                                 float force_zscale;
1130                                                                 float force_velocitybiasramp;
1131                                                                 float force_velocitybias;
1132
1133                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1134                                                                 if(deathtype & HITTYPE_SECONDARY)
1135                                                                 {
1136                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1137                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1138                                                                 }
1139                                                                 else
1140                                                                 {
1141                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1142                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1143                                                                 }
1144
1145                                                                 vel = targ.velocity;
1146                                                                 vel_z = 0;
1147                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1148                                                                 force =
1149                                                                         vlen(force)
1150                                                                         *
1151                                                                         normalize(normalize(force) + vel);
1152
1153                                                                 force_z *= force_zscale;
1154                                                         }
1155                                                         else
1156                                                         {
1157                                                                 if(deathtype & HITTYPE_SECONDARY)
1158                                                                 {
1159                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1160                                                                 }
1161                                                                 else
1162                                                                 {
1163                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1164                                                                 }
1165                                                         }
1166                                                 }
1167
1168                                                 //if (targ == attacker)
1169                                                 //{
1170                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1171                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1172                                                 //      print(" (", ftos(a), ")\n");
1173                                                 //}
1174                                                 if(finaldmg || vlen(force))
1175                                                 {
1176                                                         if(targ.iscreature)
1177                                                         {
1178                                                                 total_damage_to_creatures += finaldmg;
1179
1180                                                                 if(accuracy_isgooddamage(attacker, targ))
1181                                                                         stat_damagedone += finaldmg;
1182                                                         }
1183
1184                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1185                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1186                                                         else
1187                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1188                                                 }
1189                                         }
1190                                 }
1191                         }
1192                 targ = next;
1193         }
1194
1195         RadiusDamage_running = 0;
1196
1197         if(!DEATH_ISSPECIAL(deathtype))
1198                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1199
1200         return total_damage_to_creatures;
1201 }
1202
1203 .float fire_damagepersec;
1204 .float fire_endtime;
1205 .float fire_deathtype;
1206 .entity fire_owner;
1207 .float fire_hitsound;
1208 .entity fire_burner;
1209
1210 void fireburner_think();
1211
1212 float Fire_IsBurning(entity e)
1213 {
1214         return (time < e.fire_endtime);
1215 }
1216
1217 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1218 {
1219         float dps;
1220         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1221
1222         if(e.classname == "player")
1223         {
1224                 if(e.deadflag)
1225                         return -1;
1226         }
1227         else
1228         {
1229                 if(!e.fire_burner)
1230                 {
1231                         // print("adding a fire burner to ", e.classname, "\n");
1232                         e.fire_burner = spawn();
1233                         e.fire_burner.classname = "fireburner";
1234                         e.fire_burner.think = fireburner_think;
1235                         e.fire_burner.nextthink = time;
1236                         e.fire_burner.owner = e;
1237                 }
1238         }
1239
1240         t = max(t, 0.1);
1241         dps = d / t;
1242         if(Fire_IsBurning(e))
1243         {
1244                 mintime = e.fire_endtime - time;
1245                 maxtime = max(mintime, t);
1246
1247                 mindps = e.fire_damagepersec;
1248                 maxdps = max(mindps, dps);
1249
1250                 if(maxtime > mintime || maxdps > mindps)
1251                 {
1252                         // Constraints:
1253
1254                         // damage we have right now
1255                         mindamage = mindps * mintime;
1256
1257                         // damage we want to get
1258                         maxdamage = mindamage + d;
1259
1260                         // but we can't exceed maxtime * maxdps!
1261                         totaldamage = min(maxdamage, maxtime * maxdps);
1262
1263                         // LEMMA:
1264                         // Look at:
1265                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1266                         // We see:
1267                         // totaldamage <= maxtime * maxdps
1268                         // ==> totaldamage / maxdps <= maxtime.
1269                         // We also see:
1270                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1271                         //                     >= min(mintime, maxtime)
1272                         // ==> totaldamage / maxdps >= mintime.
1273
1274                         /*
1275                         // how long do we damage then?
1276                         // at least as long as before
1277                         // but, never exceed maxdps
1278                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1279                         */
1280
1281                         // alternate:
1282                         // at most as long as maximum allowed
1283                         // but, never below mindps
1284                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1285
1286                         // assuming t > mintime, dps > mindps:
1287                         // we get d = t * dps = maxtime * maxdps
1288                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1289                         // totaldamage / maxdps = maxtime
1290                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1291                         // FROM THIS:
1292                         // a) totaltime = max(mintime, maxtime) = maxtime
1293                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1294
1295                         // assuming t <= mintime:
1296                         // we get maxtime = mintime
1297                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1298                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1299
1300                         // assuming dps <= mindps:
1301                         // we get mindps = maxdps.
1302                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1303                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1304                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1305
1306                         e.fire_damagepersec = totaldamage / totaltime;
1307                         e.fire_endtime = time + totaltime;
1308                         if(totaldamage > 1.2 * mindamage)
1309                         {
1310                                 e.fire_deathtype = dt;
1311                                 if(e.fire_owner != o)
1312                                 {
1313                                         e.fire_owner = o;
1314                                         e.fire_hitsound = FALSE;
1315                                 }
1316                         }
1317                         if(accuracy_isgooddamage(o, e))
1318                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1319                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1320                 }
1321                 else
1322                         return 0;
1323         }
1324         else
1325         {
1326                 e.fire_damagepersec = dps;
1327                 e.fire_endtime = time + t;
1328                 e.fire_deathtype = dt;
1329                 e.fire_owner = o;
1330                 e.fire_hitsound = FALSE;
1331                 if(accuracy_isgooddamage(o, e))
1332                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1333                 return d;
1334         }
1335 }
1336
1337 void Fire_ApplyDamage(entity e)
1338 {
1339         float t, d, hi, ty;
1340         entity o;
1341
1342         if not(Fire_IsBurning(e))
1343                 return;
1344
1345         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1346         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1347                 o = e.fire_owner;
1348
1349         // water and slime stop fire
1350         if(e.waterlevel)
1351         if(e.watertype != CONTENT_LAVA)
1352                 e.fire_endtime = 0;
1353
1354         // ice stops fire
1355         if(e.freezetag_frozen)
1356                 e.fire_endtime = 0;
1357
1358         t = min(frametime, e.fire_endtime - time);
1359         d = e.fire_damagepersec * t;
1360
1361         hi = e.fire_owner.hitsound;
1362         ty = e.fire_owner.typehitsound;
1363         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1364         if(e.fire_hitsound && e.fire_owner)
1365         {
1366                 e.fire_owner.hitsound = hi;
1367                 e.fire_owner.typehitsound = ty;
1368         }
1369         e.fire_hitsound = TRUE;
1370
1371         if not(IS_INDEPENDENT_PLAYER(e))
1372         FOR_EACH_PLAYER(other) if(e != other)
1373         {
1374                 if(other.classname == "player")
1375                 if(other.deadflag == DEAD_NO)
1376                 if not(IS_INDEPENDENT_PLAYER(other))
1377                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1378                 {
1379                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1380                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1381                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1382                 }
1383         }
1384 }
1385
1386 void Fire_ApplyEffect(entity e)
1387 {
1388         if(Fire_IsBurning(e))
1389                 e.effects |= EF_FLAME;
1390         else
1391                 e.effects &~= EF_FLAME;
1392 }
1393
1394 void fireburner_think()
1395 {
1396         // for players, this is done in the regular loop
1397         if(wasfreed(self.owner))
1398         {
1399                 remove(self);
1400                 return;
1401         }
1402         Fire_ApplyEffect(self.owner);
1403         if(!Fire_IsBurning(self.owner))
1404         {
1405                 self.owner.fire_burner = world;
1406                 remove(self);
1407                 return;
1408         }
1409         Fire_ApplyDamage(self.owner);
1410         self.nextthink = time;
1411 }