qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2 #include "../_.qh"
   3
   4 #include "common.qh"
   5
   6 #include "../g_damage.qh"
   7 #include "../g_world.qh"
   8 #include "../race.qh"
   9 #include "../round_handler.qh"
  10 #include "../scores.qh"
  11
  12 #include "../mutators/mutators_include.qh"
  13
  14 #include "../../common/constants.qh"
  15 #include "../../common/mapinfo.qh"
  16 #include "../../common/notifications.qh"
  17 #include "../../common/playerstats.qh"
  18 #include "../../common/util.qh"
  19
  20 #include "../../common/command/shared_defs.qh"
  21
  22 // =============================================
  23 //  Server side voting code, reworked by Samual
  24 //  Last updated: December 27th, 2011
  25 // =============================================
  26
  27 //  Nagger for players to know status of voting
  28 float Nagger_SendEntity(entity to, float sendflags)
  29 {
  30         int nags, i, f, b;
  31         entity e;
  32         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
  33
  34         // bits:
  35         //   1 = ready
  36         //   2 = player needs to ready up
  37         //   4 = vote
  38         //   8 = player needs to vote
  39         //  16 = warmup
  40         // sendflags:
  41         //  64 = vote counts
  42         // 128 = vote string
  43
  44         nags = 0;
  45         if(readycount)
  46         {
  47                 nags |= 1;
  48                 if(to.ready == 0)
  49                         nags |= 2;
  50         }
  51         if(vote_called)
  52         {
  53                 nags |= 4;
  54                 if(to.vote_selection == 0)
  55                         nags |= 8;
  56         }
  57         if(warmup_stage)
  58                 nags |= 16;
  59
  60         if(sendflags & 64)
  61                 nags |= 64;
  62
  63         if(sendflags & 128)
  64                 nags |= 128;
  65
  66         if(!(nags & 4)) // no vote called? send no string
  67                 nags &= ~(64 | 128);
  68
  69         WriteByte(MSG_ENTITY, nags);
  70
  71         if(nags & 64)
  72         {
  73                 WriteByte(MSG_ENTITY, vote_accept_count);
  74                 WriteByte(MSG_ENTITY, vote_reject_count);
  75                 WriteByte(MSG_ENTITY, vote_needed_overall);
  76                 WriteChar(MSG_ENTITY, to.vote_selection);
  77         }
  78
  79         if(nags & 128)
  80                 WriteString(MSG_ENTITY, vote_called_display);
  81
  82         if(nags & 1)
  83         {
  84                 for(i = 1; i <= maxclients; i += 8)
  85                 {
  86                         for(f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  87                                 if(!IS_REAL_CLIENT(e) || e.ready)
  88                                         f |= b;
  89                         WriteByte(MSG_ENTITY, f);
  90                 }
  91         }
  92
  93         return true;
  94 }
  95
  96 void Nagger_Init()
  97 {
  98         Net_LinkEntity(nagger = spawn(), false, 0, Nagger_SendEntity);
  99 }
 100
 101 void Nagger_VoteChanged()
 102 {
 103         if(nagger)
 104                 nagger.SendFlags |= 128;
 105 }
 106
 107 void Nagger_VoteCountChanged()
 108 {
 109         if(nagger)
 110                 nagger.SendFlags |= 64;
 111 }
 112
 113 void Nagger_ReadyCounted()
 114 {
 115         if(nagger)
 116                 nagger.SendFlags |= 1;
 117 }
 118
 119
 120 // =======================
 121 //  Game logic for voting
 122 // =======================
 123
 124 void VoteReset()
 125 {
 126         entity tmp_player;
 127
 128         FOR_EACH_CLIENT(tmp_player) { tmp_player.vote_selection = 0; }
 129
 130         if(vote_called)
 131         {
 132                 strunzone(vote_called_command);
 133                 strunzone(vote_called_display);
 134         }
 135
 136         vote_called = VOTE_NULL;
 137         vote_caller = world;
 138         vote_endtime = 0;
 139
 140         vote_called_command = string_null;
 141         vote_called_display = string_null;
 142
 143         vote_parsed_command = string_null;
 144         vote_parsed_display = string_null;
 145
 146         Nagger_VoteChanged();
 147 }
 148
 149 void VoteStop(entity stopper)
 150 {
 151         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", GetCallerName(vote_caller), "^2's vote\n");
 152         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid))); }
 153
 154         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 155         if((vote_caller) && (stopper == vote_caller)) { vote_caller.vote_waittime = time + autocvar_sv_vote_stop; }
 156
 157         VoteReset();
 158 }
 159
 160 void VoteAccept()
 161 {
 162         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 163
 164         if((vote_called == VOTE_MASTER) && vote_caller)
 165                 vote_caller.vote_master = 1;
 166         else
 167                 localcmd(strcat(vote_called_command, "\n"));
 168
 169         if(vote_caller) { vote_caller.vote_waittime = 0; } // people like your votes, you don't need to wait to vote again
 170
 171         VoteReset();
 172         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 173 }
 174
 175 void VoteReject()
 176 {
 177         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 178         VoteReset();
 179         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 180 }
 181
 182 void VoteTimeout()
 183 {
 184         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2's vote for ", vote_called_display, "^2 timed out\n");
 185         VoteReset();
 186         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 187 }
 188
 189 void VoteSpam(float notvoters, float mincount, string result)
 190 {
 191         bprint(strcat(
 192                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 193                 strcat("^2:^1", ftos(vote_reject_count)),
 194                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 195                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 196                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 197
 198         if(autocvar_sv_eventlog)
 199         {
 200                 GameLogEcho(strcat(
 201                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 202                         strcat(":", ftos(vote_reject_count)),
 203                         strcat(":", ftos(vote_abstain_count)),
 204                         strcat(":", ftos(notvoters)),
 205                         strcat(":", ftos(mincount))));
 206         }
 207 }
 208
 209 void VoteCount(float first_count)
 210 {
 211         // declarations
 212         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 213
 214         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 215                                 || ((autocvar_sv_vote_nospectators == 1) && (warmup_stage || gameover))
 216                                 || (autocvar_sv_vote_nospectators == 0));
 217
 218         float vote_player_count = 0, notvoters = 0;
 219         float vote_real_player_count = 0, vote_real_accept_count = 0;
 220         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 221         float vote_needed_of_voted, final_needed_votes;
 222         float vote_factor_overall, vote_factor_of_voted;
 223
 224         entity tmp_player;
 225
 226         Nagger_VoteCountChanged();
 227
 228         // add up all the votes from each connected client
 229         FOR_EACH_REALCLIENT(tmp_player)
 230         {
 231                 ++vote_player_count;
 232                 if(IS_PLAYER(tmp_player)) { ++vote_real_player_count; }
 233
 234                 switch(tmp_player.vote_selection)
 235                 {
 236                         case VOTE_SELECT_REJECT: { ++vote_reject_count; { if(IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break; }
 237                         case VOTE_SELECT_ACCEPT: { ++vote_accept_count; { if(IS_PLAYER(tmp_player)) ++vote_real_accept_count; } break; }
 238                         case VOTE_SELECT_ABSTAIN: { ++vote_abstain_count; { if(IS_PLAYER(tmp_player)) ++vote_real_abstain_count; } break; }
 239                         default: break;
 240                 }
 241         }
 242
 243         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 244         if((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 245         {
 246                 if(vote_caller) { vote_caller.vote_waittime = 0; }
 247                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 248                 VoteReset();
 249                 return;
 250         }
 251
 252         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 253         if(!spectators_allowed && (vote_real_player_count > 0))
 254         {
 255                 vote_accept_count = vote_real_accept_count;
 256                 vote_reject_count = vote_real_reject_count;
 257                 vote_abstain_count = vote_real_abstain_count;
 258                 vote_player_count = vote_real_player_count;
 259         }
 260
 261         // people who have no opinion in any way :D
 262         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 263
 264         // determine the goal for the vote to be passed or rejected normally
 265         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 266         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 267
 268         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 269         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 270         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 271
 272         // are there any players at all on the server? it could be an admin vote
 273         if(vote_player_count == 0 && first_count)
 274         {
 275                 VoteSpam(0, -1, "yes"); // no players at all, just accept it
 276                 VoteAccept();
 277                 return;
 278         }
 279
 280         // since there ARE players, finally calculate the result of the vote
 281         if(vote_accept_count >= vote_needed_overall)
 282         {
 283                 VoteSpam(notvoters, -1, "yes"); // there is enough acceptions to pass the vote
 284                 VoteAccept();
 285                 return;
 286         }
 287
 288         if(vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 289         {
 290                 VoteSpam(notvoters, -1, "no"); // there is enough rejections to deny the vote
 291                 VoteReject();
 292                 return;
 293         }
 294
 295         // there is not enough votes in either direction, now lets just calculate what the voters have said
 296         if(time > vote_endtime)
 297         {
 298                 final_needed_votes = vote_needed_overall;
 299
 300                 if(autocvar_sv_vote_majority_factor_of_voted)
 301                 {
 302                         if(vote_accept_count >= vote_needed_of_voted)
 303                         {
 304                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 305                                 VoteAccept();
 306                                 return;
 307                         }
 308
 309                         if(vote_accept_count + vote_reject_count > 0)
 310                         {
 311                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 312                                 VoteReject();
 313                                 return;
 314                         }
 315
 316                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 317                 }
 318
 319                 // it didn't pass or fail, so not enough votes to even make a decision.
 320                 VoteSpam(notvoters, final_needed_votes, "timeout");
 321                 VoteTimeout();
 322         }
 323 }
 324
 325 void VoteThink()
 326 {
 327         if(vote_endtime > 0) // a vote was called
 328         if(time > vote_endtime) // time is up
 329         {
 330                 VoteCount(false);
 331         }
 332
 333         return;
 334 }
 335
 336
 337 // =======================
 338 //  Game logic for warmup
 339 // =======================
 340
 341 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 342 void reset_map(float dorespawn)
 343 {
 344         entity oldself;
 345         oldself = self;
 346
 347         if(time <= game_starttime && round_handler_IsActive())
 348                 round_handler_Reset(game_starttime);
 349
 350         MUTATOR_CALLHOOK(reset_map_global);
 351
 352         for(self = world; (self = nextent(self)); )
 353         if(IS_NOT_A_CLIENT(self))
 354         {
 355                 if(self.reset)
 356                 {
 357                         self.reset();
 358                         continue;
 359                 }
 360
 361                 if(self.team_saved)
 362                         self.team = self.team_saved;
 363
 364                 if(self.flags & FL_PROJECTILE) // remove any projectiles left
 365                         remove(self);
 366         }
 367
 368         // Waypoints and assault start come LAST
 369         for(self = world; (self = nextent(self)); )
 370         if(IS_NOT_A_CLIENT(self))
 371         {
 372                 if(self.reset2)
 373                 {
 374                         self.reset2();
 375                         continue;
 376                 }
 377         }
 378
 379         FOR_EACH_PLAYER(self)
 380         if(self.frozen)
 381                 Unfreeze(self);
 382
 383         // Moving the player reset code here since the player-reset depends
 384         // on spawnpoint entities which have to be reset first --blub
 385         if(dorespawn)
 386         if(!MUTATOR_CALLHOOK(reset_map_players))
 387         FOR_EACH_CLIENT(self) // reset all players
 388         {
 389                 /*
 390                 only reset players if a restart countdown is active
 391                 this can either be due to cvar sv_ready_restart_after_countdown having set
 392                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 393                 sv_ready_restart_after_countdown is not used and countdown is still running
 394                 */
 395                 if (restart_mapalreadyrestarted || (time < game_starttime))
 396                 {
 397                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 398                         if (IS_PLAYER(self)) {
 399                                 //PlayerScore_Clear(self);
 400                                 self.killcount = 0;
 401                                 //stop the player from moving so that he stands still once he gets respawned
 402                                 self.velocity = '0 0 0';
 403                                 self.avelocity = '0 0 0';
 404                                 self.movement = '0 0 0';
 405                                 PutClientInServer();
 406                         }
 407                 }
 408         }
 409
 410         if(g_keyhunt)
 411                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round + (game_starttime - time), kh_StartRound);
 412
 413         self = oldself;
 414 }
 415
 416 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 417 void ReadyRestart_think()
 418 {
 419         restart_mapalreadyrestarted = 1;
 420         reset_map(true);
 421         Score_ClearAll();
 422         remove(self);
 423
 424         return;
 425 }
 426
 427 // Forces a restart of the game without actually reloading the map // this is a mess...
 428 void ReadyRestart_force()
 429 {
 430         entity tmp_player, restart_timer;
 431
 432         bprint("^1Server is restarting...\n");
 433
 434         VoteReset();
 435
 436         // clear overtime, we have to decrease timelimit to its original value again.
 437         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2) { cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime))); }
 438
 439         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 440
 441         readyrestart_happened = 1;
 442         game_starttime = time + RESTART_COUNTDOWN;
 443
 444         // clear player attributes
 445         FOR_EACH_CLIENT(tmp_player)
 446         {
 447                 tmp_player.alivetime = 0;
 448                 tmp_player.killcount = 0;
 449                 PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, 0));
 450         }
 451
 452         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 453
 454         // disable the warmup global for the server
 455         warmup_stage = 0; // once the game is restarted the game is in match stage
 456
 457         // reset the .ready status of all players (also spectators)
 458         FOR_EACH_REALCLIENT(tmp_player) { tmp_player.ready = 0; }
 459         readycount = 0;
 460         Nagger_ReadyCounted(); // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 461
 462         // lock teams with lockonrestart
 463         if(autocvar_teamplay_lockonrestart && teamplay)
 464         {
 465                 lockteams = 1;
 466                 bprint("^1The teams are now locked.\n");
 467         }
 468
 469         //initiate the restart-countdown-announcer entity
 470         if(autocvar_sv_ready_restart_after_countdown)
 471         {
 472                 restart_timer = spawn();
 473                 restart_timer.think = ReadyRestart_think;
 474                 restart_timer.nextthink = game_starttime;
 475         }
 476
 477         // after a restart every players number of allowed timeouts gets reset, too
 478         if(autocvar_sv_timeout) { FOR_EACH_REALPLAYER(tmp_player) { tmp_player.allowed_timeouts = autocvar_sv_timeout_number; } }
 479
 480         //reset map immediately if this cvar is not set
 481         if (!autocvar_sv_ready_restart_after_countdown) { reset_map(true); }
 482
 483         if(autocvar_sv_eventlog) { GameLogEcho(":restart"); }
 484 }
 485
 486 void ReadyRestart()
 487 {
 488         // no arena, assault support yet...
 489         if(g_assault | gameover | intermission_running | race_completing)
 490                 localcmd("restart\n");
 491         else
 492                 localcmd("\nsv_hook_gamerestart\n");
 493
 494         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 495         // Otherwise scores could be manipulated during the countdown.
 496         if (!autocvar_sv_ready_restart_after_countdown) { Score_ClearAll(); }
 497
 498         ReadyRestart_force();
 499
 500         return;
 501 }
 502
 503 // Count the players who are ready and determine whether or not to restart the match
 504 void ReadyCount()
 505 {
 506         entity tmp_player;
 507         float ready_needed_factor, ready_needed_count;
 508         float t_ready = 0, t_players = 0;
 509
 510         FOR_EACH_REALCLIENT(tmp_player)
 511         {
 512                 if(IS_PLAYER(tmp_player) || tmp_player.caplayer == 1)
 513                 {
 514                         ++t_players;
 515                         if(tmp_player.ready) { ++t_ready; }
 516                 }
 517         }
 518
 519         readycount = t_ready;
 520
 521         Nagger_ReadyCounted();
 522
 523         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 524         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 525
 526         if(readycount >= ready_needed_count)
 527         {
 528                 ReadyRestart();
 529         }
 530
 531         return;
 532 }
 533
 534
 535 // ======================================
 536 //  Supporting functions for VoteCommand
 537 // ======================================
 538
 539 float Votecommand_check_assignment(entity caller, float assignment)
 540 {
 541         float from_server = (!caller);
 542
 543         if((assignment == VC_ASGNMNT_BOTH)
 544                 || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 545                 || (from_server && assignment == VC_ASGNMNT_SERVERONLY)))
 546         {
 547                 return true;
 548         }
 549
 550         return false;
 551 }
 552
 553 string VoteCommand_extractcommand(string input, float startpos, float argc)
 554 {
 555         string output;
 556
 557         if((argc - 1) < startpos)
 558                 output = "";
 559         else
 560                 output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 561
 562         return output;
 563 }
 564
 565 float VoteCommand_checknasty(string vote_command)
 566 {
 567         if((strstrofs(vote_command, ";", 0) >= 0)
 568                 || (strstrofs(vote_command, "\n", 0) >= 0)
 569                 || (strstrofs(vote_command, "\r", 0) >= 0)
 570                 || (strstrofs(vote_command, "$", 0) >= 0))
 571                 return false;
 572
 573         return true;
 574 }
 575
 576 float VoteCommand_checkinlist(string vote_command, string list)
 577 {
 578         string l = strcat(" ", list, " ");
 579
 580         if(strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0)
 581                 return true;
 582
 583         return false;
 584 }
 585
 586 string ValidateMap(string validated_map, entity caller)
 587 {
 588         validated_map = MapInfo_FixName(validated_map);
 589
 590         if (!validated_map)
 591         {
 592                 print_to(caller, "This map is not available on this server.");
 593                 return string_null;
 594         }
 595
 596         if(!autocvar_sv_vote_override_mostrecent && caller)
 597         {
 598                 if(Map_IsRecent(validated_map))
 599                 {
 600                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 601                         return string_null;
 602                 }
 603         }
 604
 605         if(!MapInfo_CheckMap(validated_map))
 606         {
 607                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 608                 return string_null;
 609         }
 610
 611         return validated_map;
 612 }
 613
 614 float VoteCommand_checkargs(float startpos, float argc)
 615 {
 616         float p, q, check, minargs;
 617         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 618         string cmdrestriction = cvar_string(cvarname); // note: this warns on undefined cvar. We want that.
 619         string charlist, arg;
 620         float checkmate;
 621
 622         if(cmdrestriction == "")
 623                 return true;
 624
 625         ++startpos; // skip command name
 626
 627         // check minimum arg count
 628
 629         // 0 args: argc == startpos
 630         // 1 args: argc == startpos + 1
 631         // ...
 632
 633         minargs = stof(cmdrestriction);
 634         if(argc - startpos < minargs)
 635                 return false;
 636
 637         p = strstrofs(cmdrestriction, ";", 0); // find first semicolon
 638
 639         for (;;)
 640         {
 641                 // we know that at any time, startpos <= argc - minargs
 642                 // so this means: argc-minargs >= startpos >= argc, thus
 643                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 644                 // have been seen already
 645
 646                 if(startpos >= argc) // all args checked? GOOD
 647                         break;
 648
 649                 if(p < 0) // no more args? FAIL
 650                 {
 651                         // exception: exactly minargs left, this one included
 652                         if(argc - startpos == minargs)
 653                                 break;
 654
 655                         // otherwise fail
 656                         return false;
 657                 }
 658
 659                 // cut to next semicolon
 660                 q = strstrofs(cmdrestriction, ";", p+1); // find next semicolon
 661                 if(q < 0)
 662                         charlist = substring(cmdrestriction, p+1, -1);
 663                 else
 664                         charlist = substring(cmdrestriction, p+1, q - (p+1));
 665
 666                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 667                 // charlist = strreplace("^^", ";", charlist);
 668
 669                 if(charlist != "")
 670                 {
 671                         // verify the arg only contains allowed chars
 672                         arg = argv(startpos);
 673                         checkmate = strlen(arg);
 674                         for(check = 0; check < checkmate; ++check)
 675                                 if(strstrofs(charlist, substring(arg, check, 1), 0) < 0)
 676                                         return false; // not allowed character
 677                         // all characters are allowed. FINE.
 678                 }
 679
 680                 ++startpos;
 681                 --minargs;
 682                 p = q;
 683         }
 684
 685         return true;
 686 }
 687
 688 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 689 {
 690         string first_command;
 691
 692         first_command = argv(startpos);
 693
 694         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 695                 substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 696                 strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 697         );*/
 698
 699         if(
 700                 (autocvar_sv_vote_limit > 0)
 701                 &&
 702                 (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 703         )
 704                 return false;
 705
 706         if (!VoteCommand_checkinlist(first_command, vote_list))
 707                 return false;
 708
 709         if (!VoteCommand_checkargs(startpos, argc))
 710                 return false;
 711
 712         switch(first_command) // now go through and parse the proper commands to adjust as needed.
 713         {
 714                 case "kick":
 715                 case "kickban": // catch all kick/kickban commands
 716                 {
 717                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 718                         float accepted = VerifyClientEntity(victim, true, false);
 719
 720                         if(accepted > 0)
 721                         {
 722                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 723                                 string command_arguments;
 724
 725                                 if(first_command == "kickban")
 726                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 727                                 else
 728                                         command_arguments = reason;
 729
 730                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 731                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 732                         }
 733                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
 734
 735                         break;
 736                 }
 737
 738                 case "map":
 739                 case "chmap":
 740                 case "gotomap": // re-direct all map selection commands to gotomap
 741                 {
 742                         vote_command = ValidateMap(argv(startpos + 1), caller);
 743                         if (!vote_command) { return false; }
 744                         vote_parsed_command = strcat("gotomap ", vote_command);
 745                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 746
 747                         break;
 748                 }
 749
 750                 default:
 751                 {
 752                         vote_parsed_command = vote_command;
 753                         vote_parsed_display = strzone(strcat("^1", vote_command));
 754
 755                         break;
 756                 }
 757         }
 758
 759         return true;
 760 }
 761
 762
 763 // =======================
 764 //  Command Sub-Functions
 765 // =======================
 766
 767 void VoteCommand_abstain(float request, entity caller) // CLIENT ONLY
 768 {
 769         switch(request)
 770         {
 771                 case CMD_REQUEST_COMMAND:
 772                 {
 773                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 774                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 775
 776                         else // everything went okay, continue changing vote
 777                         {
 778                                 print_to(caller, "^1You abstained from your vote.");
 779                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 780                                 msg_entity = caller;
 781                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
 782                         }
 783
 784                         return;
 785                 }
 786
 787                 default:
 788                 case CMD_REQUEST_USAGE:
 789                 {
 790                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 791                         print_to(caller, "  No arguments required.");
 792                         return;
 793                 }
 794         }
 795 }
 796
 797 void VoteCommand_call(float request, entity caller, float argc, string vote_command) // BOTH
 798 {
 799         switch(request)
 800         {
 801                 case CMD_REQUEST_COMMAND:
 802                 {
 803                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 804                                 || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 805                                 || (autocvar_sv_vote_nospectators == 0));
 806
 807                         float tmp_playercount = 0;
 808                         entity tmp_player;
 809
 810                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 811
 812                         if(!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 813                         else if(!autocvar_sv_vote_gamestart && time < game_starttime) { print_to(caller, "^1Vote calling is not allowed before the match has started."); }
 814                         else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 815                         else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
 816                         else if(caller && !IS_CLIENT(caller)) { print_to(caller, "^1Only connected clients can vote."); }
 817                         else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 818                         else if(caller && (time < caller.vote_waittime)) { print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote.")); }
 819                         else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 820                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 821
 822                         else // everything went okay, continue with calling the vote
 823                         {
 824                                 vote_caller = caller; // remember who called the vote
 825                                 vote_called = VOTE_NORMAL;
 826                                 vote_called_command = strzone(vote_parsed_command);
 827                                 vote_called_display = strzone(vote_parsed_display);
 828                                 vote_endtime = time + autocvar_sv_vote_timeout;
 829
 830                                 if(caller)
 831                                 {
 832                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 833                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 834                                         msg_entity = caller;
 835                                 }
 836
 837                                 FOR_EACH_REALCLIENT(tmp_player) { ++tmp_playercount; }
 838                                 if(tmp_playercount > 1) { Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL); } // don't announce a "vote now" sound if player is alone
 839
 840                                 bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote for ", vote_called_display, "\n");
 841                                 if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 842                                 Nagger_VoteChanged();
 843                                 VoteCount(true); // needed if you are the only one
 844                         }
 845
 846                         return;
 847                 }
 848
 849                 default:
 850                 case CMD_REQUEST_USAGE:
 851                 {
 852                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 853                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 854                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 855                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 856                         return;
 857                 }
 858         }
 859 }
 860
 861 void VoteCommand_master(float request, entity caller, float argc, string vote_command) // CLIENT ONLY
 862 {
 863         switch(request)
 864         {
 865                 case CMD_REQUEST_COMMAND:
 866                 {
 867                         if(autocvar_sv_vote_master)
 868                         {
 869                                 switch(strtolower(argv(2)))
 870                                 {
 871                                         case "do":
 872                                         {
 873                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 874
 875                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 876                                                 else if (!VoteCommand_checknasty(vote_command)) { print_to(caller, "^1Syntax error in command, see 'vhelp' for more info."); }
 877                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) { print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info."); }
 878
 879                                                 else // everything went okay, proceed with command
 880                                                 {
 881                                                         localcmd(strcat(vote_parsed_command, "\n"));
 882                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 883                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 884                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 885                                                 }
 886
 887                                                 return;
 888                                         }
 889
 890                                         case "login":
 891                                         {
 892                                                 if(autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 893                                                 else if(caller.vote_master) { print_to(caller, "^1You are already logged in as vote master."); }
 894                                                 else if(autocvar_sv_vote_master_password != argv(3)) { print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller))); }
 895
 896                                                 else // everything went okay, proceed with giving this player master privilages
 897                                                 {
 898                                                         caller.vote_master = true;
 899                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 900                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 901                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 902                                                 }
 903
 904                                                 return;
 905                                         }
 906
 907                                         default: // calling a vote for master
 908                                         {
 909                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 910                                                         || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 911                                                         || (autocvar_sv_vote_nospectators == 0));
 912
 913                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 914                                                 else if(vote_called) { print_to(caller, "^1There is already a vote called."); }
 915                                                 else if(!spectators_allowed && (caller && !IS_PLAYER(caller))) { print_to(caller, "^1Only players can call a vote."); }
 916                                                 else if(timeout_status) { print_to(caller, "^1You can not call a vote while a timeout is active."); }
 917
 918                                                 else // everything went okay, continue with creating vote
 919                                                 {
 920                                                         vote_caller = caller;
 921                                                         vote_called = VOTE_MASTER;
 922                                                         vote_called_command = strzone("XXX");
 923                                                         vote_called_display = strzone("^3master");
 924                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 925
 926                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 927                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 928
 929                                                         bprint("\{1}^2* ^3", GetCallerName(vote_caller), "^2 calls a vote to become ^3master^2.\n");
 930                                                         if(autocvar_sv_eventlog) { GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display)); }
 931                                                         Nagger_VoteChanged();
 932                                                         VoteCount(true); // needed if you are the only one
 933                                                 }
 934
 935                                                 return;
 936                                         }
 937                                 }
 938                         }
 939                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 940
 941                         return;
 942                 }
 943
 944                 default:
 945                 case CMD_REQUEST_USAGE:
 946                 {
 947                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 948                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 949                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 950                         return;
 951                 }
 952         }
 953 }
 954
 955 void VoteCommand_no(float request, entity caller) // CLIENT ONLY
 956 {
 957         switch(request)
 958         {
 959                 case CMD_REQUEST_COMMAND:
 960                 {
 961                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 962                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
 963                         else if(((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote) { VoteStop(caller); }
 964
 965                         else // everything went okay, continue changing vote
 966                         {
 967                                 print_to(caller, "^1You rejected the vote.");
 968                                 caller.vote_selection = VOTE_SELECT_REJECT;
 969                                 msg_entity = caller;
 970                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
 971                         }
 972
 973                         return;
 974                 }
 975
 976                 default:
 977                 case CMD_REQUEST_USAGE:
 978                 {
 979                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 980                         print_to(caller, "  No arguments required.");
 981                         return;
 982                 }
 983         }
 984 }
 985
 986 void VoteCommand_status(float request, entity caller) // BOTH
 987 {
 988         switch(request)
 989         {
 990                 case CMD_REQUEST_COMMAND:
 991                 {
 992                         if(vote_called)
 993                                 print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", GetCallerName(vote_caller), "^7."));
 994                         else
 995                                 print_to(caller, "^1No vote called.");
 996
 997                         return;
 998                 }
 999
1000                 default:
1001                 case CMD_REQUEST_USAGE:
1002                 {
1003                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1004                         print_to(caller, "  No arguments required.");
1005                         return;
1006                 }
1007         }
1008 }
1009
1010 void VoteCommand_stop(float request, entity caller) // BOTH
1011 {
1012         switch(request)
1013         {
1014                 case CMD_REQUEST_COMMAND:
1015                 {
1016                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1017                         else if((caller == vote_caller) || !caller || caller.vote_master) { VoteStop(caller); }
1018                         else { print_to(caller, "^1You are not allowed to stop that vote."); }
1019
1020                         return;
1021                 }
1022
1023                 default:
1024                 case CMD_REQUEST_USAGE:
1025                 {
1026                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1027                         print_to(caller, "  No arguments required.");
1028                         return;
1029                 }
1030         }
1031 }
1032
1033 void VoteCommand_yes(float request, entity caller) // CLIENT ONLY
1034 {
1035         switch(request)
1036         {
1037                 case CMD_REQUEST_COMMAND:
1038                 {
1039                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1040                         else if(caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change) { print_to(caller, "^1You have already voted."); }
1041
1042                         else // everything went okay, continue changing vote
1043                         {
1044                                 print_to(caller, "^1You accepted the vote.");
1045                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1046                                 msg_entity = caller;
1047                                 if(!autocvar_sv_vote_singlecount) { VoteCount(false); }
1048                         }
1049
1050                         return;
1051                 }
1052
1053                 default:
1054                 case CMD_REQUEST_USAGE:
1055                 {
1056                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1057                         print_to(caller, "  No arguments required.");
1058                         return;
1059                 }
1060         }
1061 }
1062
1063 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1064 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1065 void VoteCommand_(float request)
1066 {
1067         switch(request)
1068         {
1069                 case CMD_REQUEST_COMMAND:
1070                 {
1071
1072                         return;
1073                 }
1074
1075                 default:
1076                 case CMD_REQUEST_USAGE:
1077                 {
1078                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1079                         print_to(caller, "  No arguments required.");
1080                         return;
1081                 }
1082         }
1083 }
1084 */
1085
1086
1087 // ================================
1088 //  Macro system for vote commands
1089 // ================================
1090
1091 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1092 #define VOTE_COMMANDS(request,caller,arguments,command) \
1093         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1094         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1095         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1096         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1097         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1098         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1099         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1100         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1101         /* nothing */
1102
1103 void VoteCommand_macro_help(entity caller, float argc)
1104 {
1105         string command_origin = GetCommandPrefix(caller);
1106
1107         if(argc == 2 || argv(2) == "help") // help display listing all commands
1108         {
1109                 print_to(caller, "\nVoting commands:\n");
1110                 #define VOTE_COMMAND(name,function,description,assignment) \
1111                         { if(Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1112
1113                 VOTE_COMMANDS(0, caller, 0, "");
1114                 #undef VOTE_COMMAND
1115
1116                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1117                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1118                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1119         }
1120         else // usage for individual command
1121         {
1122                 #define VOTE_COMMAND(name,function,description,assignment) \
1123                         { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(2))) { function; return; } } }
1124
1125                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1126                 #undef VOTE_COMMAND
1127         }
1128
1129         return;
1130 }
1131
1132 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1133 {
1134         #define VOTE_COMMAND(name,function,description,assignment) \
1135                 { if(Votecommand_check_assignment(caller, assignment)) { if(name == strtolower(argv(1))) { function; return true; } } }
1136
1137         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1138         #undef VOTE_COMMAND
1139
1140         return false;
1141 }
1142
1143
1144 // ======================================
1145 //  Main function handling vote commands
1146 // ======================================
1147
1148 void VoteCommand(float request, entity caller, float argc, string vote_command)
1149 {
1150         // Guide for working with argc arguments by example:
1151         // argc:   1    - 2      - 3     - 4
1152         // argv:   0    - 1      - 2     - 3
1153         // cmd     vote - master - login - password
1154
1155         switch(request)
1156         {
1157                 case CMD_REQUEST_COMMAND:
1158                 {
1159                         if(VoteCommand_macro_command(caller, argc, vote_command))
1160                                 return;
1161                 }
1162
1163                 default:
1164                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1165                 case CMD_REQUEST_USAGE:
1166                 {
1167                         VoteCommand_macro_help(caller, argc);
1168                         return;
1169                 }
1170         }
1171 }