qcsrc/server/command/sv_cmd.qc

   1 // =====================================================
   2 //  Server side game commands code, reworked by Samual
   3 //  Last updated: December 29th, 2011
   4 // =====================================================
   5
   6 //  used by GameCommand_make_mapinfo()
   7 void make_mapinfo_Think()
   8 {
   9         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
  10         {
  11                 print("Done rebuiling mapinfos.\n");
  12                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  13                 remove(self);
  14         }
  15         else
  16         {
  17                 self.think = make_mapinfo_Think;
  18                 self.nextthink = time;
  19         }
  20 }
  21
  22 //  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
  23 void changematchtime(float delta, float mi, float ma)
  24 {
  25         float cur;
  26         float new;
  27         float lim;
  28
  29         if(delta == 0)
  30                 return;
  31         if(autocvar_timelimit < 0)
  32                 return;
  33
  34         if(mi <= 10)
  35                 mi = 10; // at least ten sec in the future
  36         cur = time - game_starttime;
  37         if(cur > 0)
  38                 mi += cur; // from current time!
  39
  40         lim = autocvar_timelimit * 60;
  41
  42         if(delta > 0)
  43         {
  44                 if(lim == 0)
  45                         return; // cannot increase any further
  46                 else if(lim < ma)
  47                         new = min(ma, lim + delta);
  48                 else // already above maximum: FAIL
  49                         return;
  50         }
  51         else
  52         {
  53                 if(lim == 0) // infinite: try reducing to max, if we are allowed to
  54                         new = max(mi, ma);
  55                 else if(lim > mi) // above minimum: decrease
  56                         new = max(mi, lim + delta);
  57                 else // already below minimum: FAIL
  58                         return;
  59         }
  60
  61         cvar_set("timelimit", ftos(new / 60));
  62 }
  63
  64
  65 // =======================
  66 //  Command Sub-Functions
  67 // =======================
  68
  69 void GameCommand_adminmsg(float request, float argc)
  70 {
  71         switch(request)
  72         {
  73                 case CMD_REQUEST_COMMAND:
  74                 {
  75                         entity client;
  76                         float accepted;
  77
  78                         string targets = strreplace(",", " ", argv(1));
  79                         string original_targets = strreplace(" ", ", ", targets);
  80                         string admin_message = argv(2);
  81                         float infobartime = stof(argv(3));
  82
  83                         string successful, t;
  84                         successful = string_null;
  85
  86                         if((targets) && (admin_message))
  87                         {
  88                                 for(;targets;)
  89                                 {
  90                                         t = car(targets); targets = cdr(targets);
  91
  92                                         // Check to see if the player is a valid target
  93                                         client = GetFilteredEntity(t);
  94                                         accepted = VerifyClientEntity(client, TRUE, FALSE);
  95
  96                                         if not(accepted > 0)
  97                                         {
  98                                                 print("adminmsg: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
  99                                                 continue;
 100                                         }
 101
 102                                         // send the centerprint/console print or infomessage
 103                                         if(infobartime)
 104                                         {
 105                                                 stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", infobartime, MakeConsoleSafe(admin_message)));
 106                                         }
 107                                         else
 108                                         {
 109                                                 centerprint(client, strcat("^3", admin_name(), ":\n^7", admin_message));
 110                                                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", admin_message, "\n"));
 111                                         }
 112
 113                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
 114                                         dprint("Message sent to ", client.netname, "\n");
 115                                         continue;
 116                                 }
 117
 118                                 if(successful)
 119                                         bprint("Successfully sent message '", admin_message, "' to ", successful, ".\n");
 120                                 else
 121                                         print("No players given (", original_targets, ") could receive the message.\n");
 122
 123                                 return;
 124                         }
 125                 }
 126
 127                 default:
 128                         print("Incorrect parameters for ^2adminmsg^7\n");
 129                 case CMD_REQUEST_USAGE:
 130                 {
 131                         print("\nUsage:^3 sv_cmd adminmsg clients \"message\" [infobartime]\n");
 132                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
 133                         print("  If infobartime is provided, the message will be sent to infobar.\n");
 134                         print("  Otherwise, it will just be sent as a centerprint message.\n");
 135                         print("Examples: adminmsg 2,4 \"this infomessage will last for ten seconds\" 10\n");
 136                         print("          adminmsg 2,5 \"this message will be a centerprint\"\n");
 137                         return;
 138                 }
 139         }
 140 }
 141
 142 void GameCommand_allready(float request)
 143 {
 144         switch(request)
 145         {
 146                 case CMD_REQUEST_COMMAND:
 147                 {
 148                         ReadyRestart();
 149                         return;
 150                 }
 151
 152                 default:
 153                 case CMD_REQUEST_USAGE:
 154                 {
 155                         print("\nUsage:^3 sv_cmd allready\n");
 156                         print("  No arguments required.\n");
 157                         return;
 158                 }
 159         }
 160 }
 161
 162 void GameCommand_allspec(float request, float argc)
 163 {
 164         switch(request)
 165         {
 166                 case CMD_REQUEST_COMMAND:
 167                 {
 168                         entity client;
 169                         string reason = argv(1);
 170                         float i = 0;
 171
 172                         FOR_EACH_REALPLAYER(client)
 173                         {
 174                                 self = client;
 175                                 PutObserverInServer();
 176                                 ++i;
 177                         }
 178                         if(i) { bprint(strcat("Successfully forced all (", ftos(i), ") players to spectate", (reason ? strcat(" for reason: '", reason, "'") : ""), ".\n")); }
 179                         else { print("No players found to spectate.\n"); }
 180                         return;
 181                 }
 182
 183                 default:
 184                 case CMD_REQUEST_USAGE:
 185                 {
 186                         print("\nUsage:^3 sv_cmd allspec [reason]\n");
 187                         print("  Where 'reason' is an optional argument for explanation of allspec command.\n");
 188                         print("See also: ^2moveplayer, shuffleteams^7\n");
 189                         return;
 190                 }
 191         }
 192 }
 193
 194 void GameCommand_anticheat(float request, float argc)
 195 {
 196         switch(request)
 197         {
 198                 case CMD_REQUEST_COMMAND:
 199                 {
 200                         entity client = GetIndexedEntity(argc, 1);
 201                         float accepted = VerifyClientEntity(client, FALSE, FALSE);
 202
 203                         if(accepted > 0)
 204                         {
 205                                 self = client;
 206                                 anticheat_report();
 207                                 return;
 208                         }
 209                         else
 210                         {
 211                                 print("anticheat: ", GetClientErrorString(accepted, argv(1)), ".\n");
 212                         }
 213                 }
 214
 215                 default:
 216                         print("Incorrect parameters for ^2anticheat^7\n");
 217                 case CMD_REQUEST_USAGE:
 218                 {
 219                         print("\nUsage:^3 sv_cmd anticheat client\n");
 220                         print("  'client' is the entity number or name of the player.\n");
 221                         return;
 222                 }
 223         }
 224 }
 225
 226 void GameCommand_bbox(float request)
 227 {
 228         switch(request)
 229         {
 230                 case CMD_REQUEST_COMMAND:
 231                 {
 232                         print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
 233                         print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
 234                         print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
 235                         print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
 236                         print("Solid bounding box size:");
 237
 238                         tracebox('1 0 0' * world.absmin_x,
 239                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 240                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 241                                                         '1 0 0' * world.absmax_x,
 242                                         MOVE_WORLDONLY,
 243                                         world);
 244                         if(trace_startsolid)
 245                                 print(" ", ftos(world.absmin_x));
 246                         else
 247                                 print(" ", ftos(trace_endpos_x));
 248
 249                         tracebox('0 1 0' * world.absmin_y,
 250                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 251                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 252                                                         '0 1 0' * world.absmax_y,
 253                                         MOVE_WORLDONLY,
 254                                         world);
 255                         if(trace_startsolid)
 256                                 print(" ", ftos(world.absmin_y));
 257                         else
 258                                 print(" ", ftos(trace_endpos_y));
 259
 260                         tracebox('0 0 1' * world.absmin_z,
 261                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 262                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 263                                                         '0 0 1' * world.absmax_z,
 264                                         MOVE_WORLDONLY,
 265                                         world);
 266                         if(trace_startsolid)
 267                                 print(" ", ftos(world.absmin_z));
 268                         else
 269                                 print(" ", ftos(trace_endpos_z));
 270
 271                         tracebox('1 0 0' * world.absmax_x,
 272                                                         '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 273                                                         '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 274                                                         '1 0 0' * world.absmin_x,
 275                                         MOVE_WORLDONLY,
 276                                         world);
 277                         if(trace_startsolid)
 278                                 print(" ", ftos(world.absmax_x));
 279                         else
 280                                 print(" ", ftos(trace_endpos_x));
 281
 282                         tracebox('0 1 0' * world.absmax_y,
 283                                                         '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 284                                                         '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 285                                                         '0 1 0' * world.absmin_y,
 286                                         MOVE_WORLDONLY,
 287                                         world);
 288                         if(trace_startsolid)
 289                                 print(" ", ftos(world.absmax_y));
 290                         else
 291                                 print(" ", ftos(trace_endpos_y));
 292
 293                         tracebox('0 0 1' * world.absmax_z,
 294                                                         '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 295                                                         '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 296                                                         '0 0 1' * world.absmin_z,
 297                                         MOVE_WORLDONLY,
 298                                         world);
 299                         if(trace_startsolid)
 300                                 print(" ", ftos(world.absmax_z));
 301                         else
 302                                 print(" ", ftos(trace_endpos_z));
 303
 304                         print("\n");
 305                         return;
 306                 }
 307
 308                 default:
 309                 case CMD_REQUEST_USAGE:
 310                 {
 311                         print("\nUsage:^3 sv_cmd bbox\n");
 312                         print("  No arguments required.\n");
 313                         print("See also: ^2gettaginfo, trace^7\n");
 314                         return;
 315                 }
 316         }
 317 }
 318
 319 void GameCommand_bot_cmd(float request, float argc)
 320 {
 321         switch(request)
 322         {
 323                 case CMD_REQUEST_COMMAND:
 324                 {
 325                         entity bot;
 326
 327                         if(argv(1) == "reset")
 328                         {
 329                                 bot_resetqueues();
 330                                 return;
 331                         }
 332                         else if(argv(1) == "load" && argc == 3)
 333                         {
 334                                 float fh, i;
 335                                 string s;
 336                                 fh = fopen(argv(2), FILE_READ);
 337                                 if(fh < 0)
 338                                 {
 339                                         print("cannot open the file\n");
 340                                         return;
 341                                 }
 342
 343                                 i = 0;
 344                                 while((s = fgets(fh)))
 345                                 {
 346                                         argc = tokenize_console(s);
 347
 348                                         if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
 349                                         {
 350                                                 if(argv(2) == "reset")
 351                                                 {
 352                                                         bot_resetqueues();
 353                                                 }
 354                                                 else if(argv(2) == "setbots")
 355                                                 {
 356                                                         cvar_settemp("minplayers", "0");
 357                                                         cvar_settemp("bot_number", argv(3));
 358                                                         if(!bot_fixcount())
 359                                                                 print("Sorry, could not set requested bot count\n");
 360                                                 }
 361                                                 else
 362                                                 {
 363                                                         // let's start at token 2 so we can skip sv_cmd bot_cmd
 364                                                         bot = find_bot_by_number(stof(argv(2)));
 365                                                         if(bot == world)
 366                                                                 bot = find_bot_by_name(argv(2));
 367                                                         if(bot)
 368                                                                 bot_queuecommand(bot, strcat(argv(3), " ", argv(4)));
 369                                                 }
 370                                         }
 371                                         else
 372                                                 localcmd(strcat(s, "\n"));
 373
 374                                         ++i;
 375                                 }
 376                                 print(ftos(i), " commands read\n");
 377                                 fclose(fh);
 378                                 return;
 379                         }
 380                         else if(argv(1) == "help")
 381                         {
 382                                 if(argv(2))
 383                                         bot_cmdhelp(argv(2));
 384                                 else
 385                                         bot_list_commands();
 386                                 return;
 387                         }
 388                         else if(argc >= 3) // this comes last
 389                         {
 390                                 bot = find_bot_by_number(stof(argv(1)));
 391                                 if(bot == world)
 392                                         bot = find_bot_by_name(argv(1));
 393                                 if(bot)
 394                                 {
 395                                         print(strcat("Command '", strcat(argv(2), " ", argv(3)), "' sent to bot ", bot.netname, "\n"));
 396                                         bot_queuecommand(bot, strcat(argv(2), " ", argv(3)));
 397                                         return;
 398                                 }
 399                                 else
 400                                         print(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
 401                         }
 402                 }
 403
 404                 default:
 405                         print("Incorrect parameters for ^2bot_cmd^7\n");
 406                 case CMD_REQUEST_USAGE:
 407                 {
 408                         print("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
 409                         print("  'client' can be either the name or entity id of the bot\n");
 410                         print("  For full list of commands, see bot_cmd help [command].\n");
 411                         print("Examples: sv_cmd bot_cmd client cc \"say something\"\n");
 412                         print("          sv_cmd bot_cmd client presskey jump\n");
 413                         return;
 414                 }
 415         }
 416 }
 417
 418 void GameCommand_cointoss(float request, float argc)
 419 {
 420         switch(request)
 421         {
 422                 case CMD_REQUEST_COMMAND:
 423                 {
 424                         entity client;
 425                         string result1 = (argv(2) ? strcat("^7", argv(1), "^3!\n") : "^1HEADS^3!\n");
 426                         string result2 = (argv(2) ? strcat("^7", argv(2), "^3!\n") : "^4TAILS^3!\n");
 427                         string choice = ((random() > 0.5) ? result1 : result2);
 428
 429                         FOR_EACH_CLIENT(client)
 430                                 centerprint(client, strcat("^3Throwing coin... Result: ", choice));
 431                         bprint(strcat("^3Throwing coin... Result: ", choice));
 432                         return;
 433                 }
 434
 435                 default:
 436                 case CMD_REQUEST_USAGE:
 437                 {
 438                         print("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
 439                         print("  Where 'result1' and 'result2' are user created options.\n");
 440                         return;
 441                 }
 442         }
 443 }
 444
 445 void GameCommand_database(float request, float argc)
 446 {
 447         switch(request)
 448         {
 449                 case CMD_REQUEST_COMMAND:
 450                 {
 451                         if(argc == 3)
 452                         {
 453                                 if(argv(1) == "save")
 454                                 {
 455                                         db_save(ServerProgsDB, argv(2));
 456                                         print(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
 457                                         return;
 458                                 }
 459                                 else if(argv(1) == "dump")
 460                                 {
 461                                         db_dump(ServerProgsDB, argv(2));
 462                                         print("DB dumped.\n"); // wtf does this do?
 463                                         return;
 464                                 }
 465                                 else if(argv(1) == "load")
 466                                 {
 467                                         db_close(ServerProgsDB);
 468                                         ServerProgsDB = db_load(argv(2));
 469                                         print(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
 470                                         return;
 471                                 }
 472                         }
 473                 }
 474
 475                 default:
 476                         print("Incorrect parameters for ^2database^7\n");
 477                 case CMD_REQUEST_USAGE:
 478                 {
 479                         print("\nUsage:^3 sv_cmd database action filename\n");
 480                         print("  Where 'action' is the command to complete,\n");
 481                         print("  and 'filename' is what it acts upon.\n");
 482                         print("  Full list of commands here: \"save, dump, load.\"\n");
 483                         return;
 484                 }
 485         }
 486 }
 487
 488 void GameCommand_defer_clear(float request, float argc)
 489 {
 490         switch(request)
 491         {
 492                 case CMD_REQUEST_COMMAND:
 493                 {
 494                         entity client;
 495                         float accepted;
 496
 497                         if(argc >= 2)
 498                         {
 499                                 client = GetIndexedEntity(argc, 1);
 500                                 accepted = VerifyClientEntity(client, TRUE, FALSE);
 501
 502                                 if(accepted > 0)
 503                                 {
 504                                         stuffcmd(client, "defer clear\n");
 505                                         print("defer clear stuffed to ", client.netname, "\n");
 506                                 }
 507                                 else { print("defer_clear: ", GetClientErrorString(accepted, argv(1)), ".\n"); }
 508
 509                                 return;
 510                         }
 511                 }
 512
 513                 default:
 514                         print("Incorrect parameters for ^2defer_clear^7\n");
 515                 case CMD_REQUEST_USAGE:
 516                 {
 517                         print("\nUsage:^3 sv_cmd defer_clear client\n");
 518                         print("  'client' is the entity number or name of the player.\n");
 519                         print("See also: ^2defer_clear_all^7\n");
 520                         return;
 521                 }
 522         }
 523 }
 524
 525 void GameCommand_defer_clear_all(float request)
 526 {
 527         switch(request)
 528         {
 529                 case CMD_REQUEST_COMMAND:
 530                 {
 531                         entity client;
 532                         float i = 0;
 533                         float argc;
 534
 535                         FOR_EACH_CLIENT(client)
 536                         {
 537                                 argc = tokenize_console(strcat("defer_clear ", ftos(num_for_edict(client))));
 538                                 GameCommand_defer_clear(CMD_REQUEST_COMMAND, argc);
 539                                 ++i;
 540                         }
 541                         if(i) { print(strcat("Successfully stuffed defer clear to all clients (", ftos(i), ")\n")); } // should a message be added if no players were found?
 542                         return;
 543                 }
 544
 545                 default:
 546                 case CMD_REQUEST_USAGE:
 547                 {
 548                         print("\nUsage:^3 sv_cmd defer_clear_all\n");
 549                         print("  No arguments required.\n");
 550                         print("See also: ^2defer_clear^7\n");
 551                         return;
 552                 }
 553         }
 554 }
 555
 556 void GameCommand_delrec(float request, float argc)  // perhaps merge later with records and printstats and such?
 557 {
 558         switch(request)
 559         {
 560                 case CMD_REQUEST_COMMAND:
 561                 {
 562                         if(argv(1))
 563                         {
 564                                 if(argv(2))
 565                                         race_deleteTime(argv(2), stof(argv(1)));
 566                                 else
 567                                         race_deleteTime(GetMapname(), stof(argv(1)));
 568                                 return;
 569                         }
 570                 }
 571
 572                 default:
 573                         print("Incorrect parameters for ^2delrec^7\n");
 574                 case CMD_REQUEST_USAGE:
 575                 {
 576                         print("\nUsage:^3 sv_cmd delrec ranking [map]\n");
 577                         print("  'ranking' is which ranking level to clear up to, \n");
 578                         print("  it will clear all records up to nth place.\n");
 579                         print("  if 'map' is not provided it will use current map.\n");
 580                         return;
 581                 }
 582         }
 583 }
 584
 585 void GameCommand_effectindexdump(float request)
 586 {
 587         switch(request)
 588         {
 589                 case CMD_REQUEST_COMMAND:
 590                 {
 591                         float fh, d;
 592                         string s;
 593
 594                         d = db_create();
 595                         print("begin of effects list\n");
 596                         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 597                         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 598                         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 599                         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 600                         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 601                         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 602                         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 603                         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 604                         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 605                         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 606                         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 607                         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 608                         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 609                         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 610                         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 611                         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 612                         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 613                         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 614                         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 615                         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 616                         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 617                         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 618                         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 619                         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 620                         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 621                         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 622                         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 623                         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 624                         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 625                         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 626                         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 627                         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 628                         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 629                         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 630                         db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
 631                         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 632
 633                         fh = fopen("effectinfo.txt", FILE_READ);
 634                         while((s = fgets(fh)))
 635                         {
 636                                 tokenize_console(s);
 637                                 if(argv(0) == "effect")
 638                                 {
 639                                         if(db_get(d, argv(1)) != "1")
 640                                         {
 641                                                 if(particleeffectnum(argv(1)) >= 0)
 642                                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 643                                                 db_put(d, argv(1), "1");
 644                                         }
 645                                 }
 646                         }
 647                         print("end of effects list\n");
 648
 649                         db_close(d);
 650                         return;
 651                 }
 652
 653                 default:
 654                 case CMD_REQUEST_USAGE:
 655                 {
 656                         print("\nUsage:^3 sv_cmd effectindexdump\n");
 657                         print("  No arguments required.\n");
 658                         return;
 659                 }
 660         }
 661 }
 662
 663 void GameCommand_extendmatchtime(float request)
 664 {
 665         switch(request)
 666         {
 667                 case CMD_REQUEST_COMMAND:
 668                 {
 669                         changematchtime(autocvar_timelimit_increment * 60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
 670                         return;
 671                 }
 672
 673                 default:
 674                 case CMD_REQUEST_USAGE:
 675                 {
 676                         print("\nUsage:^3 sv_cmd extendmatchtime\n");
 677                         print("  No arguments required.\n");
 678                         print("See also: ^2reducematchtime^7\n");
 679                         return;
 680                 }
 681         }
 682 }
 683
 684 void GameCommand_find(float request, float argc)  // is this even needed? We have prvm_edicts command and such ANYWAY
 685 {
 686         switch(request)
 687         {
 688                 case CMD_REQUEST_COMMAND:
 689                 {
 690                         entity client;
 691
 692                         for(client = world; (client = find(client, classname, argv(1))); )
 693                                 print(etos(client), "\n");
 694
 695                         return;
 696                 }
 697
 698                 default:
 699                         print("Incorrect parameters for ^2find^7\n");
 700                 case CMD_REQUEST_USAGE:
 701                 {
 702                         print("\nUsage:^3 sv_cmd find classname\n");
 703                         print("  Where 'classname' is the classname to search for.\n");
 704                         return;
 705                 }
 706         }
 707 }
 708
 709 void GameCommand_gametype(float request, float argc)
 710 {
 711         switch(request)
 712         {
 713                 case CMD_REQUEST_COMMAND:
 714                 {
 715                         if(argv(1) != "")
 716                         {
 717                                 string s = argv(1);
 718                                 float t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
 719
 720                                 if(t)
 721                                 {
 722                                         MapInfo_SwitchGameType(t);
 723                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 724                                         if(MapInfo_count > 0)
 725                                                 bprint("Game type successfully switched to ", s, "\n");
 726                                         else
 727                                         {
 728                                                 bprint("Cannot use this game type: no map for it found\n");
 729                                                 MapInfo_SwitchGameType(tsave);
 730                                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 731                                         }
 732                                 }
 733                                 else
 734                                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 735
 736                                 return;
 737                         }
 738                 }
 739
 740                 default:
 741                         print("Incorrect parameters for ^2gametype^7\n");
 742                 case CMD_REQUEST_USAGE:
 743                 {
 744                         print("\nUsage:^3 sv_cmd gametype mode\n");
 745                         print("  Where 'mode' is the gametype mode to switch to.\n");
 746                         print("See also: ^2gotomap^7\n");
 747                         return;
 748                 }
 749         }
 750 }
 751
 752 void GameCommand_gettaginfo(float request, float argc)
 753 {
 754         switch(request)
 755         {
 756                 case CMD_REQUEST_COMMAND:
 757                 {
 758                         entity tmp_entity;
 759                         float i;
 760                         vector v;
 761
 762                         if(argc >= 4)
 763                         {
 764                                 tmp_entity = spawn();
 765                                 if(argv(1) == "w")
 766                                         setmodel(tmp_entity, (nextent(world)).weaponentity.model);
 767                                 else
 768                                 {
 769                                         precache_model(argv(1));
 770                                         setmodel(tmp_entity, argv(1));
 771                                 }
 772                                 tmp_entity.frame = stof(argv(2));
 773                                 if(substring(argv(3), 0, 1) == "#")
 774                                         i = stof(substring(argv(3), 1, -1));
 775                                 else
 776                                         i = gettagindex(tmp_entity, argv(3));
 777                                 if(i)
 778                                 {
 779                                         v = gettaginfo(tmp_entity, i);
 780                                         print("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
 781                                         print(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
 782                                         print(" vector = ", ftos(v_x), " ", ftos(v_y), " ", ftos(v_z), "\n");
 783                                         print(" offset = ", ftos(gettaginfo_offset_x), " ", ftos(gettaginfo_offset_y), " ", ftos(gettaginfo_offset_z), "\n");
 784                                         print(" forward = ", ftos(gettaginfo_forward_x), " ", ftos(gettaginfo_forward_y), " ", ftos(gettaginfo_forward_z), "\n");
 785                                         print(" right = ", ftos(gettaginfo_right_x), " ", ftos(gettaginfo_right_y), " ", ftos(gettaginfo_right_z), "\n");
 786                                         print(" up = ", ftos(gettaginfo_up_x), " ", ftos(gettaginfo_up_y), " ", ftos(gettaginfo_up_z), "\n");
 787                                         if(argc >= 6)
 788                                         {
 789                                                 v_y = -v_y;
 790                                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
 791                                         }
 792                                 }
 793                                 else
 794                                         print("bone not found\n");
 795
 796                                 remove(tmp_entity);
 797                                 return;
 798                         }
 799                 }
 800
 801                 default:
 802                         print("Incorrect parameters for ^2gettaginfo^7\n");
 803                 case CMD_REQUEST_USAGE:
 804                 {
 805                         print("\nUsage:^3 sv_cmd gettaginfo model frame index [command one] [command two]\n");
 806                         print("See also: ^2bbox, trace^7\n");
 807                         return;
 808                 }
 809         }
 810 }
 811
 812 void GameCommand_gotomap(float request, float argc)
 813 {
 814         switch(request)
 815         {
 816                 case CMD_REQUEST_COMMAND:
 817                 {
 818                         if(argv(1))
 819                         {
 820                                 print(GotoMap(argv(1)), "\n");
 821                                 return;
 822                         }
 823                 }
 824
 825                 default:
 826                         print("Incorrect parameters for ^2gotomap^7\n");
 827                 case CMD_REQUEST_USAGE:
 828                 {
 829                         print("\nUsage:^3 sv_cmd gotomap map\n");
 830                         print("  Where 'map' is the *.bsp file to change to.\n");
 831                         print("See also: ^2gametype^7\n");
 832                         return;
 833                 }
 834         }
 835 }
 836
 837 void GameCommand_lockteams(float request)
 838 {
 839         switch(request)
 840         {
 841                 case CMD_REQUEST_COMMAND:
 842                 {
 843                         if(teamplay)
 844                         {
 845                                 lockteams = 1;
 846                                 bprint("^1The teams are now locked.\n");
 847                         }
 848                         else
 849                         {
 850                                 bprint("lockteams command can only be used in a team-based gamemode.\n");
 851                         }
 852                         return;
 853                 }
 854
 855                 default:
 856                 case CMD_REQUEST_USAGE:
 857                 {
 858                         print("\nUsage:^3 sv_cmd lockteams\n");
 859                         print("  No arguments required.\n");
 860                         print("See also: ^2unlockteams^7\n");
 861                         return;
 862                 }
 863         }
 864 }
 865
 866 void GameCommand_make_mapinfo(float request)
 867 {
 868         switch(request)
 869         {
 870                 case CMD_REQUEST_COMMAND:
 871                 {
 872                         entity tmp_entity;
 873
 874                         tmp_entity = spawn();
 875                         tmp_entity.classname = "make_mapinfo";
 876                         tmp_entity.think = make_mapinfo_Think;
 877                         tmp_entity.nextthink = time;
 878                         MapInfo_Enumerate();
 879                         return;
 880                 }
 881
 882                 default:
 883                 case CMD_REQUEST_USAGE:
 884                 {
 885                         print("\nUsage:^3 sv_cmd make_mapinfo\n");
 886                         print("  No arguments required.\n");
 887                         print("See also: ^2radarmap^7\n");
 888                         return;
 889                 }
 890         }
 891 }
 892
 893 void GameCommand_moveplayer(float request, float argc)
 894 {
 895         switch(request)
 896         {
 897                 case CMD_REQUEST_COMMAND:
 898                 {
 899                         float accepted;
 900                         entity client;
 901
 902                         string targets = strreplace(",", " ", argv(1));
 903                         string original_targets = strreplace(" ", ", ", targets);
 904                         string destination = argv(2);
 905                         string notify = argv(3);
 906
 907                         string successful, t;
 908                         successful = string_null;
 909
 910                         // lets see if the target(s) even actually exist.
 911                         if((targets) && (destination))
 912                         {
 913                                 for(;targets;)
 914                                 {
 915                                         t = car(targets); targets = cdr(targets);
 916
 917                                         // Check to see if the player is a valid target
 918                                         client = GetFilteredEntity(t);
 919                                         accepted = VerifyClientEntity(client, FALSE, FALSE);
 920
 921                                         if not(accepted > 0)
 922                                         {
 923                                                 print("moveplayer: ", GetClientErrorString(accepted, t), (targets ? ", skipping to next player.\n" : ".\n"));
 924                                                 continue;
 925                                         }
 926
 927                                         // Where are we putting this player?
 928                                         if(destination == "spec" || destination == "spectator")
 929                                         {
 930                                                 if(client.classname != "spectator" && client.classname != "observer")
 931                                                 {
 932                                                         self = client;
 933                                                         PutObserverInServer();
 934
 935                                                         successful = strcat(successful, (successful ? ", " : ""), client.netname);
 936                                                 }
 937                                                 else
 938                                                 {
 939                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already spectating.\n");
 940                                                 }
 941                                                 continue;
 942                                         }
 943                                         else
 944                                         {
 945                                                 if(client.classname != "spectator" && client.classname != "observer")
 946                                                 {
 947                                                         if(teamplay)
 948                                                         {
 949                                                                 // set up
 950                                                                 float team_color;
 951                                                                 float save = client.team_forced;
 952                                                                 client.team_forced = 0;
 953
 954                                                                 // find the team to move the player to
 955                                                                 team_color = ColourToNumber(destination);
 956                                                                 if(team_color == client.team) // already on the destination team
 957                                                                 {
 958                                                                         // keep the forcing undone
 959                                                                         print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") is already on the ", ColoredTeamName(client.team), (targets ? ", skipping to next player.\n" : ".\n"));
 960                                                                         continue;
 961                                                                 }
 962                                                                 else if(team_color == 0)  // auto team
 963                                                                 {
 964                                                                         team_color = NumberToTeamNumber(FindSmallestTeam(client, FALSE));
 965                                                                 }
 966                                                                 else
 967                                                                 {
 968                                                                         CheckAllowedTeams(client);
 969                                                                 }
 970                                                                 client.team_forced = save;
 971
 972                                                                 // Check to see if the destination team is even available
 973                                                                 switch(team_color)
 974                                                                 {
 975                                                                         case COLOR_TEAM1: if(c1 == -1) { print("Sorry, can't move player to red team if it doesn't exist.\n"); return; } break;
 976                                                                         case COLOR_TEAM2: if(c2 == -1) { print("Sorry, can't move player to blue team if it doesn't exist.\n"); return; } break;
 977                                                                         case COLOR_TEAM3: if(c3 == -1) { print("Sorry, can't move player to yellow team if it doesn't exist.\n"); return; } break;
 978                                                                         case COLOR_TEAM4: if(c4 == -1) { print("Sorry, can't move player to pink team if it doesn't exist.\n"); return; } break;
 979
 980                                                                         default: print("Sorry, can't move player here if team ", destination, " doesn't exist.\n"); return;
 981                                                                 }
 982
 983                                                                 // If so, lets continue and finally move the player
 984                                                                 client.team_forced = 0;
 985                                                                 MoveToTeam(client, team_color, 6, stof(notify));
 986                                                                 successful = strcat(successful, (successful ? ", " : ""), client.netname);
 987                                                                 print("Player ", ftos(GetFilteredNumber(t)), " (", client.netname, ") has been moved to the ", ColoredTeamName(team_color), ".\n");
 988                                                                 continue;
 989                                                         }
 990                                                         else
 991                                                         {
 992                                                                 print("Can't change teams when currently not playing a team game.\n");
 993                                                                 return;
 994                                                         }
 995                                                 }
 996                                                 else
 997                                                 {
 998                                                         print("Can't change teams if the player isn't in the game.\n"); // well technically we could, but should we allow that? :P
 999                                                         return;
1000                                                 }
1001                                         }
1002                                 }
1003
1004                                 if(successful)
1005                                         bprint("Successfully moved players ", successful, " to destination ", destination, ".\n");
1006                                 else
1007                                         print("No players given (", original_targets, ") are able to move.\n");
1008
1009                                 return; // still correct parameters so return to avoid usage print
1010                         }
1011                 }
1012
1013                 default:
1014                         print("Incorrect parameters for ^2moveplayer^7\n");
1015                 case CMD_REQUEST_USAGE:
1016                 {
1017                         print("\nUsage:^3 sv_cmd moveplayer clients destination [notify]\n");
1018                         print("  'clients' is a list (separated by commas) of player entity ID's or nicknames\n");
1019                         print("  'destination' is what to send the player to, be it team or spectating\n");
1020                         print("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
1021                         print("  'notify' is whether or not to send messages notifying of the move. Detail below.\n");
1022                         print("    0 (00) automove centerprint, admin message; 1 (01) automove centerprint, no admin message\n");
1023                         print("    2 (10) no centerprint, admin message; 3 (11) no centerprint, no admin message\n");
1024                         print("Examples: sv_cmd moveplayer 1,3,5 red 3\n");
1025                         print("          sv_cmd moveplayer 2 spec \n");
1026                         print("See also: ^2allspec, shuffleteams^7\n");
1027                         return;
1028                 }
1029         }
1030 }
1031
1032 void GameCommand_nospectators(float request)
1033 {
1034         switch(request)
1035         {
1036                 case CMD_REQUEST_COMMAND:
1037                 {
1038                         blockSpectators = 1;
1039                         entity plr;
1040                         FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
1041                         {
1042                                 if(plr.classname == "spectator" || plr.classname == "observer")
1043                                 {
1044                                         plr.spectatortime = time;
1045                                         sprint(plr, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1046                                 }
1047                         }
1048                         bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
1049                         return;
1050                 }
1051
1052                 default:
1053                 case CMD_REQUEST_USAGE:
1054                 {
1055                         print("\nUsage:^3 sv_cmd nospectators\n");
1056                         print("  No arguments required.\n");
1057                         return;
1058                 }
1059         }
1060 }
1061
1062 void GameCommand_playerdemo(float request, float argc)
1063 {
1064         switch(request)
1065         {
1066                 case CMD_REQUEST_COMMAND:
1067                 {
1068                         if(argv(2) && argv(3))
1069                         {
1070                                 entity client;
1071                                 float i, n, accepted;
1072
1073                                 switch(argv(1))
1074                                 {
1075                                         case "read":
1076                                         {
1077                                                 client = GetIndexedEntity(argc, 2);
1078                                                 accepted = VerifyClientEntity(client, FALSE, TRUE);
1079
1080                                                 if not(accepted > 0)
1081                                                 {
1082                                                         print("playerdemo: read: ", GetClientErrorString(accepted, argv(2)), ".\n");
1083                                                         return;
1084                                                 }
1085
1086                                                 self = client;
1087                                                 playerdemo_open_read(argv(next_token));
1088                                                 return;
1089                                         }
1090
1091                                         case "write":
1092                                         {
1093                                                 client = GetIndexedEntity(argc, 2);
1094                                                 accepted = VerifyClientEntity(client, FALSE, FALSE);
1095
1096                                                 if not(accepted > 0)
1097                                                 {
1098                                                         print("playerdemo: write: ", GetClientErrorString(accepted, argv(2)), ".\n");
1099                                                         return;
1100                                                 }
1101
1102                                                 self = client;
1103                                                 playerdemo_open_write(argv(next_token));
1104                                                 return;
1105                                         }
1106
1107                                         case "auto_read_and_write":
1108                                         {
1109                                                 n = GetFilteredNumber(argv(3));
1110                                                 cvar_set("bot_number", ftos(n));
1111
1112                                                 localcmd("wait; wait; wait\n");
1113                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1114
1115                                                 localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
1116                                                 return;
1117                                         }
1118
1119                                         case "auto_read":
1120                                         {
1121                                                 n = GetFilteredNumber(argv(3));
1122                                                 cvar_set("bot_number", ftos(n));
1123
1124                                                 localcmd("wait; wait; wait\n");
1125                                                 for(i = 0; i < n; ++i) { localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", argv(2), ftos(i+1), "\n"); }
1126                                                 return;
1127                                         }
1128                                 }
1129                         }
1130                 }
1131
1132                 default:
1133                         print("Incorrect parameters for ^2playerdemo^7\n");
1134                 case CMD_REQUEST_USAGE:
1135                 {
1136                         print("\nUsage:^3 sv_cmd playerdemo command (entitynumber filename | entitynumber botnumber)\n");
1137                         print("  Full list of commands here: \"read, write, auto_read_and_write, auto_read.\"\n");
1138                         return;
1139                 }
1140         }
1141 }
1142
1143 void GameCommand_printstats(float request)
1144 {
1145         switch(request)
1146         {
1147                 case CMD_REQUEST_COMMAND:
1148                 {
1149                         DumpStats(FALSE);
1150                         print("stats dumped.\n");
1151                         return;
1152                 }
1153
1154                 default:
1155                 case CMD_REQUEST_USAGE:
1156                 {
1157                         print("\nUsage:^3 sv_cmd printstats\n");
1158                         print("  No arguments required.\n");
1159                         return;
1160                 }
1161         }
1162 }
1163
1164 void GameCommand_radarmap(float request, float argc)
1165 {
1166         switch(request)
1167         {
1168                 case CMD_REQUEST_COMMAND:
1169                 {
1170                         if(RadarMap_Make(argc))
1171                                 return;
1172                 }
1173
1174                 default:
1175                         print("Incorrect parameters for ^2radarmap^7\n");
1176                 case CMD_REQUEST_USAGE:
1177                 {
1178                         print("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
1179                         print("  The quality factor Q is roughly proportional to the time taken.\n");
1180                         print("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
1181                         print("See also: ^2make_mapinfo^7\n");
1182                         return;
1183                 }
1184         }
1185 }
1186
1187 void GameCommand_reducematchtime(float request)
1188 {
1189         switch(request)
1190         {
1191                 case CMD_REQUEST_COMMAND:
1192                 {
1193                         changematchtime(autocvar_timelimit_decrement *-60, autocvar_timelimit_min * 60, autocvar_timelimit_max * 60);
1194                         return;
1195                 }
1196
1197                 default:
1198                 case CMD_REQUEST_USAGE:
1199                 {
1200                         print("\nUsage:^3 sv_cmd reducematchtime\n");
1201                         print("  No arguments required.\n");
1202                         print("See also: ^2extendmatchtime^7\n");
1203                         return;
1204                 }
1205         }
1206 }
1207
1208 void GameCommand_setbots(float request, float argc)
1209 {
1210         switch(request)
1211         {
1212                 case CMD_REQUEST_COMMAND:
1213                 {
1214                         if(argc >= 2)
1215                         {
1216                                 cvar_settemp("minplayers", "0");
1217                                 cvar_settemp("bot_number", argv(1));
1218                                 bot_fixcount();
1219                                 return;
1220                         }
1221                 }
1222
1223                 default:
1224                         print("Incorrect parameters for ^2setbots^7\n");
1225                 case CMD_REQUEST_USAGE:
1226                 {
1227                         print("\nUsage:^3 sv_cmd setbots botnumber\n");
1228                         print("  Where 'botnumber' is the amount of bots to set bot_number cvar to.\n");
1229                         print("See also: ^2bot_cmd^7\n");
1230                         return;
1231                 }
1232         }
1233 }
1234
1235 void GameCommand_shuffleteams(float request)
1236 {
1237         switch(request)
1238         {
1239                 case CMD_REQUEST_COMMAND:
1240                 {
1241                         if(teamplay)
1242                         {
1243                                 entity tmp_player;
1244                                 float i, x, z, t_teams, t_players, team_color;
1245
1246                                 // count the total amount of players and total amount of teams
1247                                 t_players = 0;
1248                                 t_teams = 0;
1249                                 FOR_EACH_PLAYER(tmp_player)
1250                                 {
1251                                         CheckAllowedTeams(tmp_player);
1252
1253                                         if(c1 >= 0) t_teams = max(1, t_teams);
1254                                         if(c2 >= 0) t_teams = max(2, t_teams);
1255                                         if(c3 >= 0) t_teams = max(3, t_teams);
1256                                         if(c4 >= 0) t_teams = max(4, t_teams);
1257
1258                                         ++t_players;
1259                                 }
1260
1261                                 // build a list of the players in a random order
1262                                 FOR_EACH_PLAYER(tmp_player)
1263                                 {
1264                                         for(;;)
1265                                         {
1266                                                 i = bound(1, floor(random() * maxclients) + 1, maxclients);
1267
1268                                                 if(shuffleteams_players[i])
1269                                                 {
1270                                                         continue; // a player is already assigned to this slot
1271                                                 }
1272                                                 else
1273                                                 {
1274                                                         shuffleteams_players[i] = num_for_edict(tmp_player);
1275                                                         break;
1276                                                 }
1277                                         }
1278                                 }
1279
1280                                 // finally, from the list made earlier, re-join the players in different order.
1281                                 for(i = 1; i <= t_teams; ++i)
1282                                 {
1283                                         // find out how many players to assign to this team
1284                                         x = (t_players / t_teams);
1285                                         x = ((i == 1) ? ceil(x) : floor(x));
1286
1287                                         team_color = NumberToTeamNumber(i);
1288
1289                                         // sort through the random list of players made earlier
1290                                         for(z = 1; z <= maxclients; ++z)
1291                                         {
1292                                                 if not(shuffleteams_teams[i] >= x)
1293                                                 {
1294                                                         if not(shuffleteams_players[z])
1295                                                                 continue; // not a player, move on to next random slot
1296
1297                                                         if(VerifyClientNumber(shuffleteams_players[z]))
1298                                                                 self = edict_num(shuffleteams_players[z]);
1299
1300                                                         if(self.team != team_color)
1301                                                                 MoveToTeam(self, team_color, 6, 0);
1302
1303                                                         shuffleteams_players[z] = 0;
1304                                                         shuffleteams_teams[i] = shuffleteams_teams[i] + 1;
1305                                                 }
1306                                                 else
1307                                                 {
1308                                                         break; // move on to next team
1309                                                 }
1310                                         }
1311                                 }
1312
1313                                 bprint("Successfully shuffled the players around randomly.\n");
1314
1315                                 // clear the buffers now
1316                                 for (i=0; i<SHUFFLETEAMS_MAX_PLAYERS; ++i)
1317                                         shuffleteams_players[i] = 0;
1318
1319                                 for (i=0; i<SHUFFLETEAMS_MAX_TEAMS; ++i)
1320                                         shuffleteams_teams[i] = 0;
1321                         }
1322                         else
1323                         {
1324                                 print("Can't shuffle teams when currently not playing a team game.\n");
1325                         }
1326
1327                         return;
1328                 }
1329
1330                 default:
1331                 case CMD_REQUEST_USAGE:
1332                 {
1333                         print("\nUsage:^3 sv_cmd shuffleteams\n");
1334                         print("  No arguments required.\n");
1335                         print("See also: ^2moveplayer, allspec^7\n");
1336                         return;
1337                 }
1338         }
1339 }
1340
1341 void GameCommand_stuffto(float request, float argc)
1342 {
1343         // This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
1344         // Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
1345         // we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
1346
1347         #ifdef STUFFTO_ENABLED
1348         switch(request)
1349         {
1350                 case CMD_REQUEST_COMMAND:
1351                 {
1352                         if(argv(2))
1353                         {
1354                                 entity client = GetIndexedEntity(argc, 1);
1355                                 float accepted = VerifyClientEntity(client, TRUE, FALSE);
1356
1357                                 if(accepted > 0)
1358                                 {
1359                                         stuffcmd(client, strcat("\n", argv(next_token), "\n"));
1360                                         print(strcat("Command: \"", argv(next_token), "\" sent to ", GetCallerName(client), " (", argv(1) ,").\n"));
1361                                 }
1362                                 else
1363                                         print("stuffto: ", GetClientErrorString(accepted, argv(1)), ".\n");
1364
1365                                 return;
1366                         }
1367                 }
1368
1369                 default:
1370                         print("Incorrect parameters for ^2stuffto^7\n");
1371                 case CMD_REQUEST_USAGE:
1372                 {
1373                         print("\nUsage:^3 sv_cmd stuffto client \"command\"\n");
1374                         print("  'client' is the entity number or name of the player,\n");
1375                         print("  and 'command' is the command to be sent to that player.\n");
1376                         return;
1377                 }
1378         }
1379         #else
1380         if(request)
1381         {
1382                 print("stuffto command is not enabled on this server.\n");
1383                 return;
1384         }
1385         #endif
1386 }
1387
1388 void GameCommand_trace(float request, float argc)
1389 {
1390         switch(request)
1391         {
1392                 case CMD_REQUEST_COMMAND:
1393                 {
1394                         entity e;
1395                         vector org, delta, start, end, p, q, q0, pos, vv, dv;
1396                         float i, f, safe, unsafe, dq, dqf;
1397
1398                         switch(argv(1))
1399                         {
1400                                 case "debug":
1401                                 {
1402                                         print("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
1403                                         for(;;)
1404                                         {
1405                                                 org = world.mins;
1406                                                 delta = world.maxs - world.mins;
1407
1408                                                 start_x = org_x + random() * delta_x;
1409                                                 start_y = org_y + random() * delta_y;
1410                                                 start_z = org_z + random() * delta_z;
1411
1412                                                 end_x = org_x + random() * delta_x;
1413                                                 end_y = org_y + random() * delta_y;
1414                                                 end_z = org_z + random() * delta_z;
1415
1416                                                 start = stov(vtos(start));
1417                                                 end = stov(vtos(end));
1418
1419                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1420                                                 if(!trace_startsolid)
1421                                                 {
1422                                                         p = trace_endpos;
1423                                                         tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
1424                                                         if(trace_startsolid || trace_fraction == 1)
1425                                                         {
1426                                                                 rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
1427                                                                 tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
1428
1429                                                                 if(trace_startsolid)
1430                                                                 {
1431                                                                         // how much do we need to back off?
1432                                                                         safe = 1;
1433                                                                         unsafe = 0;
1434                                                                         for(;;)
1435                                                                         {
1436                                                                                 pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
1437                                                                                 tracebox(pos, PL_MIN, PL_MAX, pos, MOVE_NOMONSTERS, world);
1438                                                                                 if(trace_startsolid)
1439                                                                                 {
1440                                                                                         if((safe + unsafe) * 0.5 == unsafe)
1441                                                                                                 break;
1442                                                                                         unsafe = (safe + unsafe) * 0.5;
1443                                                                                 }
1444                                                                                 else
1445                                                                                 {
1446                                                                                         if((safe + unsafe) * 0.5 == safe)
1447                                                                                                 break;
1448                                                                                         safe = (safe + unsafe) * 0.5;
1449                                                                                 }
1450                                                                         }
1451
1452                                                                         print("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
1453                                                                         print("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");
1454
1455                                                                         tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
1456                                                                         if(trace_startsolid)
1457                                                                                 print("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1458                                                                         else
1459                                                                                 print("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1460                                                                         break;
1461                                                                 }
1462
1463                                                                 q0 = p;
1464                                                                 dq = 0;
1465                                                                 dqf = 1;
1466                                                                 for(;;)
1467                                                                 {
1468                                                                         q = p + normalize(end - p) * (dq + dqf);
1469                                                                         if(q == q0)
1470                                                                                 break;
1471                                                                         tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
1472                                                                         if(trace_startsolid)
1473                                                                                 error("THIS ONE cannot happen");
1474                                                                         if(trace_fraction > 0)
1475                                                                                 dq += dqf * trace_fraction;
1476                                                                         dqf *= 0.5;
1477                                                                         q0 = q;
1478                                                                 }
1479                                                                 if(dq > 0)
1480                                                                 {
1481                                                                         print("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
1482                                                                         print("could go ", ftos(dq), " units further to ", vtos(q), "\n");
1483                                                                         break;
1484                                                                 }
1485                                                         }
1486                                                 }
1487                                         }
1488                                         return;
1489                                 }
1490
1491                                 case "debug2":
1492                                 {
1493                                         e = nextent(world);
1494                                         tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
1495                                         vv = trace_endpos;
1496                                         if(trace_fraction == 1)
1497                                         {
1498                                                 print("not above ground, aborting\n");
1499                                                 return;
1500                                         }
1501                                         f = 0;
1502                                         for(i = 0; i < 100000; ++i)
1503                                         {
1504                                                 dv = randomvec();
1505                                                 if(dv_z > 0)
1506                                                         dv = -1 * dv;
1507                                                 tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
1508                                                 if(trace_startsolid)
1509                                                         print("bug 1\n");
1510                                                 if(trace_fraction == 1)
1511                                                 if(dv_z < f)
1512                                                 {
1513                                                         print("bug 2: ", ftos(dv_x), " ", ftos(dv_y), " ", ftos(dv_z));
1514                                                         print(" (", ftos(asin(dv_z / vlen(dv)) * 180 / M_PI), " degrees)\n");
1515                                                         f = dv_z;
1516                                                 }
1517                                         }
1518                                         print("highest possible dist: ", ftos(f), "\n");
1519                                         return;
1520                                 }
1521
1522                                 case "walk":
1523                                 {
1524                                         if(argc == 3)
1525                                         {
1526                                                 e = nextent(world);
1527                                                 if(tracewalk(e, stov(argv(1)), e.mins, e.maxs, stov(argv(2)), MOVE_NORMAL))
1528                                                         print("can walk\n");
1529                                                 else
1530                                                         print("cannot walk\n");
1531                                                 return;
1532                                         }
1533                                 }
1534
1535                                 case "showline":
1536                                 {
1537                                         if(argc == 3)
1538                                         {
1539                                                 vv = stov(argv(1));
1540                                                 dv = stov(argv(2));
1541                                                 traceline(vv, dv, MOVE_NORMAL, world);
1542                                                 trailparticles(world, particleeffectnum("TR_NEXUIZPLASMA"), vv, trace_endpos);
1543                                                 trailparticles(world, particleeffectnum("TR_CRYLINKPLASMA"), trace_endpos, dv);
1544                                                 return;
1545                                         }
1546                                 }
1547
1548                                 // no default case, just go straight to invalid
1549                         }
1550                 }
1551
1552                 default:
1553                         print("Incorrect parameters for ^2trace^7\n");
1554                 case CMD_REQUEST_USAGE:
1555                 {
1556                         print("\nUsage:^3 sv_cmd trace command (startpos endpos)\n");
1557                         print("  Full list of commands here: \"debug, debug2, walk, showline.\"\n");
1558                         print("See also: ^2bbox, gettaginfo^7\n");
1559                         return;
1560                 }
1561         }
1562 }
1563
1564 void GameCommand_unlockteams(float request)
1565 {
1566         switch(request)
1567         {
1568                 case CMD_REQUEST_COMMAND:
1569                 {
1570                         if(teamplay)
1571                         {
1572                                 lockteams = 0;
1573                                 bprint("^1The teams are now unlocked.\n");
1574                         }
1575                         else
1576                         {
1577                                 bprint("unlockteams command can only be used in a team-based gamemode.\n");
1578                         }
1579                         return;
1580                 }
1581
1582                 default:
1583                 case CMD_REQUEST_USAGE:
1584                 {
1585                         print("\nUsage:^3 sv_cmd unlockteams\n");
1586                         print("  No arguments required.\n");
1587                         print("See also: ^2lockteams^7\n");
1588                         return;
1589                 }
1590         }
1591 }
1592
1593 void GameCommand_warp(float request, float argc)
1594 {
1595         switch (request)
1596         {
1597                 case CMD_REQUEST_COMMAND:
1598                 {
1599                         if(autocvar_g_campaign)
1600                         {
1601                                 if(argc >= 2)
1602                                 {
1603                                         CampaignLevelWarp(stof(argv(1)));
1604                                         print("Successfully warped to campaign level ", stof(argv(1)), ".\n");
1605                                 }
1606                                 else
1607                                 {
1608                                         CampaignLevelWarp(-1);
1609                                         print("Successfully warped to next campaign level.\n");
1610                                 }
1611                         }
1612                         else
1613                                 print("Not in campaign, can't level warp\n");
1614                         return;
1615                 }
1616
1617                 default:
1618                 case CMD_REQUEST_USAGE:
1619                 {
1620                         print("\nUsage:^3 sv_cmd level\n");
1621                         print("  'level' is the level to change campaign mode to.\n");
1622                         return;
1623                 }
1624         }
1625 }
1626
1627 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1628 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1629 void GameCommand_(float request)
1630 {
1631         switch(request)
1632         {
1633                 case CMD_REQUEST_COMMAND:
1634                 {
1635
1636                         return;
1637                 }
1638
1639                 default:
1640                 case CMD_REQUEST_USAGE:
1641                 {
1642                         print("\nUsage:^3 sv_cmd \n");
1643                         print("  No arguments required.\n");
1644                         return;
1645                 }
1646         }
1647 }
1648 */
1649
1650
1651 // ==================================
1652 //  Macro system for server commands
1653 // ==================================
1654
1655 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1656 // Common commands have double indentation to separate them a bit.
1657 #define SERVER_COMMANDS(request,arguments,command) \
1658         SERVER_COMMAND("adminmsg", GameCommand_adminmsg(request, arguments), "Send an admin message to a client directly") \
1659         SERVER_COMMAND("allready", GameCommand_allready(request), "Restart the server and reset the players") \
1660         SERVER_COMMAND("allspec", GameCommand_allspec(request, arguments), "Force all players to spectate") \
1661         SERVER_COMMAND("anticheat", GameCommand_anticheat(request, arguments), "Create an anticheat report for a client") \
1662         SERVER_COMMAND("bbox", GameCommand_bbox(request), "Print detailed information about world size") \
1663         SERVER_COMMAND("bot_cmd", GameCommand_bot_cmd(request, arguments), "Control and send commands to bots") \
1664         SERVER_COMMAND("cointoss", GameCommand_cointoss(request, arguments), "Flip a virtual coin and give random result") \
1665         SERVER_COMMAND("database", GameCommand_database(request, arguments), "Extra controls of the serverprogs database") \
1666         SERVER_COMMAND("defer_clear", GameCommand_defer_clear(request, arguments), "Clear all queued defer commands for a specific client") \
1667         SERVER_COMMAND("defer_clear_all", GameCommand_defer_clear_all(request), "Clear all queued defer commands for all clients") \
1668         SERVER_COMMAND("delrec", GameCommand_delrec(request, arguments), "Delete race time record for a map") \
1669         SERVER_COMMAND("effectindexdump", GameCommand_effectindexdump(request), "Dump list of effects from code and effectinfo.txt") \
1670         SERVER_COMMAND("extendmatchtime", GameCommand_extendmatchtime(request), "Increase the timelimit value incrementally") \
1671         SERVER_COMMAND("find", GameCommand_find(request, arguments), "Search through entities for matching classname") \
1672         SERVER_COMMAND("gametype", GameCommand_gametype(request, arguments), "Simple command to change the active gametype") \
1673         SERVER_COMMAND("gettaginfo", GameCommand_gettaginfo(request, arguments), "Get specific information about a weapon model") \
1674         SERVER_COMMAND("gotomap", GameCommand_gotomap(request, arguments), "Simple command to switch to another map") \
1675         SERVER_COMMAND("lockteams", GameCommand_lockteams(request), "Disable the ability for players to switch or enter teams") \
1676         SERVER_COMMAND("make_mapinfo", GameCommand_make_mapinfo(request), "Automatically rebuild mapinfo files") \
1677         SERVER_COMMAND("moveplayer", GameCommand_moveplayer(request, arguments), "Change the team/status of a player") \
1678         SERVER_COMMAND("nospectators", GameCommand_nospectators(request), "Automatically remove spectators from a match") \
1679         SERVER_COMMAND("playerdemo", GameCommand_playerdemo(request, arguments), "Control the ability to save demos of players") \
1680         SERVER_COMMAND("printstats", GameCommand_printstats(request), "Dump eventlog player stats and other score information") \
1681         SERVER_COMMAND("radarmap", GameCommand_radarmap(request, arguments), "Generate a radar image of the map") \
1682         SERVER_COMMAND("reducematchtime", GameCommand_reducematchtime(request), "Decrease the timelimit value incrementally") \
1683         SERVER_COMMAND("setbots", GameCommand_setbots(request, arguments), "Adjust how many bots are in the match") \
1684         SERVER_COMMAND("shuffleteams", GameCommand_shuffleteams(request), "Randomly move players to different teams") \
1685         SERVER_COMMAND("stuffto", GameCommand_stuffto(request, arguments), "Send a command to be executed on a client") \
1686         SERVER_COMMAND("trace", GameCommand_trace(request, arguments), "Various debugging tools with tracing") \
1687         SERVER_COMMAND("unlockteams", GameCommand_unlockteams(request), "Enable the ability for players to switch or enter teams") \
1688         SERVER_COMMAND("warp", GameCommand_warp(request, arguments), "Choose different level in campaign") \
1689         /* nothing */
1690
1691 void GameCommand_macro_help()
1692 {
1693         #define SERVER_COMMAND(name,function,description) \
1694                 { print("  ^2", name, "^7: ", description, "\n"); }
1695
1696         SERVER_COMMANDS(0, 0, "")
1697         #undef SERVER_COMMAND
1698
1699         return;
1700 }
1701
1702 float GameCommand_macro_command(float argc, string command)
1703 {
1704         #define SERVER_COMMAND(name,function,description) \
1705                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
1706
1707         SERVER_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
1708         #undef SERVER_COMMAND
1709
1710         return FALSE;
1711 }
1712
1713 float GameCommand_macro_usage(float argc)
1714 {
1715         #define SERVER_COMMAND(name,function,description) \
1716                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
1717
1718         SERVER_COMMANDS(CMD_REQUEST_USAGE, argc, "")
1719         #undef SERVER_COMMAND
1720
1721         return FALSE;
1722 }
1723
1724 void GameCommand_macro_write_aliases(float fh)
1725 {
1726         #define SERVER_COMMAND(name,function,description) \
1727                 { CMD_Write_Alias("qc_cmd_sv", name, description); }
1728
1729         SERVER_COMMANDS(0, 0, "")
1730         #undef SERVER_COMMAND
1731
1732         return;
1733 }
1734
1735
1736 // =========================================
1737 //  Main Function Called By Engine (sv_cmd)
1738 // =========================================
1739 // If this function exists, game code handles gamecommand instead of the engine code.
1740
1741 void GameCommand(string command)
1742 {
1743         float argc = tokenize_console(command);
1744
1745         // Guide for working with argc arguments by example:
1746         // argc:   1    - 2      - 3     - 4
1747         // argv:   0    - 1      - 2     - 3
1748         // cmd     vote - master - login - password
1749
1750         if(strtolower(argv(0)) == "help")
1751         {
1752                 if(argc == 1)
1753                 {
1754                         print("\nServer console commands:\n");
1755                         GameCommand_macro_help();
1756
1757                         print("\nBanning commands:\n");
1758                         BanCommand_macro_help();
1759
1760                         print("\nCommon networked commands:\n");
1761                         CommonCommand_macro_help(world);
1762
1763                         print("\nGeneric commands shared by all programs:\n");
1764                         GenericCommand_macro_help();
1765
1766                         print("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are listed above.\n");
1767                         print("For help about a specific command, type sv_cmd help COMMAND\n");
1768
1769                         return;
1770                 }
1771                 else if(BanCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
1772                 {
1773                         return;
1774                 }
1775                 else if(CommonCommand_macro_usage(argc, world)) // same here, but for common commands instead
1776                 {
1777                         return;
1778                 }
1779                 else if(GenericCommand_macro_usage(argc)) // same here, but for generic commands instead
1780                 {
1781                         return;
1782                 }
1783                 else if(GameCommand_macro_usage(argc)) // finally try for normal commands too
1784                 {
1785                         return;
1786                 }
1787         }
1788         else if(BanCommand(command))
1789         {
1790                 return; // handled by server/command/ipban.qc
1791         }
1792         else if(CommonCommand_macro_command(argc, world, command))
1793         {
1794                 return; // handled by server/command/common.qc
1795         }
1796         else if(GenericCommand(command))
1797         {
1798                 return; // handled by common/command/generic.qc
1799         }
1800         else if(GameCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
1801         {
1802                 return; // handled by one of the above GameCommand_* functions
1803         }
1804
1805         // nothing above caught the command, must be invalid
1806         print(((command != "") ? strcat("Unknown server command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try sv_cmd help.\n");
1807
1808         return;
1809 }