qcsrc/server/command/cmd.qc

   1 #include "../../common/command/command.qh"
   2 #include "cmd.qh"
   3 #include "../_all.qh"
   4
   5 #include "common.qh"
   6 #include "vote.qh"
   7
   8 #include "../campaign.qh"
   9 #include "../cheats.qh"
  10 #include "../cl_player.qh"
  11 #include "../ipban.qh"
  12 #include "../mapvoting.qh"
  13 #include "../scores.qh"
  14 #include "../teamplay.qh"
  15
  16 #include "../mutators/mutators_include.qh"
  17
  18 #ifdef SVQC
  19         #include "../../common/vehicles/all.qh"
  20 #endif
  21
  22 #include "../../common/constants.qh"
  23 #include "../../common/deathtypes.qh"
  24 #include "../../common/mapinfo.qh"
  25 #include "../../common/notifications.qh"
  26 #include "../../common/teams.qh"
  27 #include "../../common/util.qh"
  28
  29 #include "../../common/monsters/all.qc"
  30 #include "../../common/monsters/spawn.qh"
  31 #include "../../common/monsters/sv_monsters.qh"
  32
  33 #include "../../warpzonelib/common.qh"
  34
  35 void ClientKill_TeamChange (float targetteam); // 0 = don't change, -1 = auto, -2 = spec
  36
  37 // =========================================================
  38 //  Server side networked commands code, reworked by Samual
  39 //  Last updated: December 28th, 2011
  40 // =========================================================
  41
  42 float SV_ParseClientCommand_floodcheck()
  43 {
  44         if (!timeout_status) // not while paused
  45         {
  46                 if(time <= (self.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  47                 {
  48                         self.cmd_floodcount += 1;
  49                         if(self.cmd_floodcount > autocvar_sv_clientcommand_antispam_count) { return false; } // too much spam, halt
  50                 }
  51                 else
  52                 {
  53                         self.cmd_floodtime = time;
  54                         self.cmd_floodcount = 1;
  55                 }
  56         }
  57         return true; // continue, as we're not flooding yet
  58 }
  59
  60
  61 // =======================
  62 //  Command Sub-Functions
  63 // =======================
  64
  65 void ClientCommand_autoswitch(float request, float argc)
  66 {
  67         switch(request)
  68         {
  69                 case CMD_REQUEST_COMMAND:
  70                 {
  71                         if(argv(1) != "")
  72                         {
  73                                 self.autoswitch = InterpretBoolean(argv(1));
  74                                 sprint(self, strcat("^1autoswitch is currently turned ", (self.autoswitch ? "on" : "off"), ".\n"));
  75                                 return;
  76                         }
  77                 }
  78
  79                 default:
  80                         sprint(self, "Incorrect parameters for ^2autoswitch^7\n");
  81                 case CMD_REQUEST_USAGE:
  82                 {
  83                         sprint(self, "\nUsage:^3 cmd autoswitch selection\n");
  84                         sprint(self, "  Where 'selection' controls if autoswitch is on or off.\n");
  85                         return;
  86                 }
  87         }
  88 }
  89
  90 void ClientCommand_checkfail(float request, string command) // internal command, used only by code
  91 {
  92         switch(request)
  93         {
  94                 case CMD_REQUEST_COMMAND:
  95                 {
  96                         LOG_INFOF("CHECKFAIL: %s (%s) epically failed check %s\n", self.netname, self.netaddress, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  97                         self.checkfail = 1;
  98                         return; // never fall through to usage
  99                 }
 100
 101                 default:
 102                         sprint(self, "Incorrect parameters for ^2checkfail^7\n");
 103                 case CMD_REQUEST_USAGE:
 104                 {
 105                         sprint(self, "\nUsage:^3 cmd checkfail <message>\n");
 106                         sprint(self, "  Where 'message' is the message reported by client about the fail.\n");
 107                         return;
 108                 }
 109         }
 110 }
 111
 112 void ClientCommand_clientversion(float request, float argc) // internal command, used only by code
 113 {
 114         switch(request)
 115         {
 116                 case CMD_REQUEST_COMMAND:
 117                 {
 118                         if(argv(1) != "")
 119                         {
 120                                 if(IS_CLIENT(self))
 121                                 {
 122                                         self.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 123
 124                                         if(self.version < autocvar_gameversion_min || self.version > autocvar_gameversion_max)
 125                                         {
 126                                                 self.version_mismatch = 1;
 127                                                 ClientKill_TeamChange(-2); // observe
 128                                         }
 129                                         else if(autocvar_g_campaign || autocvar_g_balance_teams)
 130                                         {
 131                                                 //JoinBestTeam(self, false, true);
 132                                         }
 133                                         else if(teamplay && !autocvar_sv_spectate && !(self.team_forced > 0))
 134                                         {
 135                                                 self.classname = "observer"; // really?
 136                                                 stuffcmd(self, "menu_showteamselect\n");
 137                                         }
 138                                 }
 139
 140                                 return;
 141                         }
 142                 }
 143
 144                 default:
 145                         sprint(self, "Incorrect parameters for ^2clientversion^7\n");
 146                 case CMD_REQUEST_USAGE:
 147                 {
 148                         sprint(self, "\nUsage:^3 cmd clientversion version\n");
 149                         sprint(self, "  Where 'version' is the game version reported by self.\n");
 150                         return;
 151                 }
 152         }
 153 }
 154
 155 void ClientCommand_mv_getpicture(float request, float argc) // internal command, used only by code
 156 {
 157         switch(request)
 158         {
 159                 case CMD_REQUEST_COMMAND:
 160                 {
 161                         if(argv(1) != "")
 162                         {
 163                                 if(intermission_running)
 164                                         MapVote_SendPicture(stof(argv(1)));
 165
 166                                 return;
 167                         }
 168                 }
 169
 170                 default:
 171                         sprint(self, "Incorrect parameters for ^2mv_getpicture^7\n");
 172                 case CMD_REQUEST_USAGE:
 173                 {
 174                         sprint(self, "\nUsage:^3 cmd mv_getpicture mapid\n");
 175                         sprint(self, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 176                         return;
 177                 }
 178         }
 179 }
 180
 181 void ClientCommand_join(float request)
 182 {
 183         switch(request)
 184         {
 185                 case CMD_REQUEST_COMMAND:
 186                 {
 187                         if(IS_CLIENT(self))
 188                         {
 189                                 if(!IS_PLAYER(self) && !lockteams && !gameover)
 190                                 {
 191                                         if(self.caplayer)
 192                                                 return;
 193                                         if(nJoinAllowed(self))
 194                                         {
 195                                                 if(autocvar_g_campaign) { campaign_bots_may_start = 1; }
 196
 197                                                 self.classname = "player";
 198                                                 PlayerScore_Clear(self);
 199                                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
 200                                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname);
 201                                                 PutClientInServer();
 202                                         }
 203                                         else
 204                                         {
 205                                                 //player may not join because of g_maxplayers is set
 206                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
 207                                         }
 208                                 }
 209                         }
 210                         return; // never fall through to usage
 211                 }
 212
 213                 default:
 214                 case CMD_REQUEST_USAGE:
 215                 {
 216                         sprint(self, "\nUsage:^3 cmd join\n");
 217                         sprint(self, "  No arguments required.\n");
 218                         return;
 219                 }
 220         }
 221 }
 222
 223 void ClientCommand_physics(float request, float argc)
 224 {
 225         switch(request)
 226         {
 227                 case CMD_REQUEST_COMMAND:
 228                 {
 229                         string command = strtolower(argv(1));
 230
 231                         if(!autocvar_g_physics_clientselect)
 232                         {
 233                                 sprint(self, "Client physics selection is currently disabled.\n");
 234                                 return;
 235                         }
 236
 237                         if(command == "list" || command == "help")
 238                         {
 239                                 sprint(self, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 240                                 return;
 241                         }
 242
 243                         if(Physics_Valid(command) || command == "default")
 244                         {
 245                                 stuffcmd(self, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 246                                 sprint(self, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 247                                 return;
 248                         }
 249                 }
 250
 251                 default:
 252                         sprint(self, strcat("Current physics set: ^3", self.cvar_cl_physics, "\n"));
 253                 case CMD_REQUEST_USAGE:
 254                 {
 255                         sprint(self, "\nUsage:^3 cmd physics <physics>\n");
 256                         sprint(self, "  See 'cmd physics list' for available physics sets.\n");
 257                         sprint(self, "  Argument 'default' resets to standard physics.\n");
 258                         return;
 259                 }
 260         }
 261 }
 262
 263 void ClientCommand_ready(float request) // todo: anti-spam for toggling readyness
 264 {
 265         switch(request)
 266         {
 267                 case CMD_REQUEST_COMMAND:
 268                 {
 269                         if(IS_CLIENT(self))
 270                         {
 271                                 if(warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 272                                 {
 273                                         if(!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 274                                         {
 275                                                 if(time < game_starttime) // game is already restarting
 276                                                         return;
 277                                                 if (self.ready) // toggle
 278                                                 {
 279                                                         self.ready = false;
 280                                                         bprint(self.netname, "^2 is ^1NOT^2 ready\n");
 281                                                 }
 282                                                 else
 283                                                 {
 284                                                         self.ready = true;
 285                                                         bprint(self.netname, "^2 is ready\n");
 286                                                 }
 287
 288                                                 // cannot reset the game while a timeout is active!
 289                                                 if (!timeout_status)
 290                                                         ReadyCount();
 291                                         } else {
 292                                                 sprint(self, "^1Game has already been restarted\n");
 293                                         }
 294                                 }
 295                         }
 296                         return; // never fall through to usage
 297                 }
 298
 299                 default:
 300                 case CMD_REQUEST_USAGE:
 301                 {
 302                         sprint(self, "\nUsage:^3 cmd ready\n");
 303                         sprint(self, "  No arguments required.\n");
 304                         return;
 305                 }
 306         }
 307 }
 308
 309 void ClientCommand_say(float request, float argc, string command)
 310 {
 311         switch(request)
 312         {
 313                 case CMD_REQUEST_COMMAND:
 314                 {
 315                         if(argc >= 2) { Say(self, false, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 316                         return; // never fall through to usage
 317                 }
 318
 319                 default:
 320                 case CMD_REQUEST_USAGE:
 321                 {
 322                         sprint(self, "\nUsage:^3 cmd say <message>\n");
 323                         sprint(self, "  Where 'message' is the string of text to say.\n");
 324                         return;
 325                 }
 326         }
 327 }
 328
 329 void ClientCommand_say_team(float request, float argc, string command)
 330 {
 331         switch(request)
 332         {
 333                 case CMD_REQUEST_COMMAND:
 334                 {
 335                         if(argc >= 2) { Say(self, true, world, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1); }
 336                         return; // never fall through to usage
 337                 }
 338
 339                 default:
 340                 case CMD_REQUEST_USAGE:
 341                 {
 342                         sprint(self, "\nUsage:^3 cmd say_team <message>\n");
 343                         sprint(self, "  Where 'message' is the string of text to say.\n");
 344                         return;
 345                 }
 346         }
 347 }
 348
 349 void ClientCommand_selectteam(float request, float argc)
 350 {
 351         switch(request)
 352         {
 353                 case CMD_REQUEST_COMMAND:
 354                 {
 355                         if(argv(1) != "")
 356                         {
 357                                 if(IS_CLIENT(self))
 358                                 {
 359                                         if(teamplay)
 360                                                 if(self.team_forced <= 0)
 361                                                         if (!lockteams)
 362                                                         {
 363                                                                 float selection;
 364
 365                                                                 switch(argv(1))
 366                                                                 {
 367                                                                         case "red": selection = NUM_TEAM_1; break;
 368                                                                         case "blue": selection = NUM_TEAM_2; break;
 369                                                                         case "yellow": selection = NUM_TEAM_3; break;
 370                                                                         case "pink": selection = NUM_TEAM_4; break;
 371                                                                         case "auto": selection = (-1); break;
 372
 373                                                                         default: selection = 0; break;
 374                                                                 }
 375
 376                                                                 if(selection)
 377                                                                 {
 378                                                                         if(self.team == selection && self.deadflag == DEAD_NO)
 379                                                                                 sprint(self, "^7You already are on that team.\n");
 380                                                                         else if(self.wasplayer && autocvar_g_changeteam_banned)
 381                                                                                 sprint(self, "^1You cannot change team, forbidden by the server.\n");
 382                                                                         else
 383                                                                         {
 384                                                                                 if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 385                                                                                 {
 386                                                                                         CheckAllowedTeams(self);
 387                                                                                         GetTeamCounts(self);
 388                                                                                         if(!TeamSmallerEqThanTeam(Team_TeamToNumber(selection), Team_TeamToNumber(self.team), self))
 389                                                                                         {
 390                                                                                                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 391                                                                                                 return;
 392                                                                                         }
 393                                                                                 }
 394                                                                                 ClientKill_TeamChange(selection);
 395                                                                         }
 396                                                                 }
 397                                                         }
 398                                                         else
 399                                                                 sprint(self, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 400                                                 else
 401                                                         sprint(self, "^7selectteam can not be used as your team is forced\n");
 402                                         else
 403                                                 sprint(self, "^7selectteam can only be used in teamgames\n");
 404                                 }
 405                                 return;
 406                         }
 407                 }
 408
 409                 default:
 410                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 411                 case CMD_REQUEST_USAGE:
 412                 {
 413                         sprint(self, "\nUsage:^3 cmd selectteam team\n");
 414                         sprint(self, "  Where 'team' is the prefered team to try and join.\n");
 415                         sprint(self, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 416                         return;
 417                 }
 418         }
 419 }
 420
 421 void ClientCommand_selfstuff(float request, string command)
 422 {
 423         switch(request)
 424         {
 425                 case CMD_REQUEST_COMMAND:
 426                 {
 427                         if(argv(1) != "")
 428                         {
 429                                 stuffcmd(self, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 430                                 return;
 431                         }
 432                 }
 433
 434                 default:
 435                         sprint(self, "Incorrect parameters for ^2selectteam^7\n");
 436                 case CMD_REQUEST_USAGE:
 437                 {
 438                         sprint(self, "\nUsage:^3 cmd selfstuff <command>\n");
 439                         sprint(self, "  Where 'command' is the string to be stuffed to your client.\n");
 440                         return;
 441                 }
 442         }
 443 }
 444
 445 void ClientCommand_sentcvar(float request, float argc, string command)
 446 {
 447         switch(request)
 448         {
 449                 case CMD_REQUEST_COMMAND:
 450                 {
 451                         if(argv(1) != "")
 452                         {
 453                                 //float tokens;
 454                                 string s;
 455
 456                                 if(argc == 2) // undefined cvar: use the default value on the server then
 457                                 {
 458                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 459                                         tokenize_console(s);
 460                                 }
 461
 462                                 GetCvars(1);
 463
 464                                 return;
 465                         }
 466                 }
 467
 468                 default:
 469                         sprint(self, "Incorrect parameters for ^2sentcvar^7\n");
 470                 case CMD_REQUEST_USAGE:
 471                 {
 472                         sprint(self, "\nUsage:^3 cmd sentcvar <cvar>\n");
 473                         sprint(self, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 474                         return;
 475                 }
 476         }
 477 }
 478
 479 void ClientCommand_spectate(float request)
 480 {
 481         switch(request)
 482         {
 483                 case CMD_REQUEST_COMMAND:
 484                 {
 485                         if(IS_CLIENT(self))
 486                         {
 487                                 if(g_lms)
 488                                 {
 489                                         if(self.lms_spectate_warning)
 490                                         {
 491                                                 // for the forfeit message...
 492                                                 self.lms_spectate_warning = 2;
 493                                                 // mark player as spectator
 494                                                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 495                                         }
 496                                         else
 497                                         {
 498                                                 self.lms_spectate_warning = 1;
 499                                                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 500                                                 return;
 501                                         }
 502                                 }
 503
 504                                 if((IS_PLAYER(self) || self.caplayer) && autocvar_sv_spectate == 1)
 505                                 {
 506                                         if(self.caplayer && (IS_SPEC(self) || IS_OBSERVER(self)))
 507                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CA_LEAVE);
 508                                         ClientKill_TeamChange(-2); // observe
 509                                 }
 510                         }
 511                         return; // never fall through to usage
 512                 }
 513
 514                 default:
 515                 case CMD_REQUEST_USAGE:
 516                 {
 517                         sprint(self, "\nUsage:^3 cmd spectate\n");
 518                         sprint(self, "  No arguments required.\n");
 519                         return;
 520                 }
 521         }
 522 }
 523
 524 void ClientCommand_suggestmap(float request, float argc)
 525 {
 526         switch(request)
 527         {
 528                 case CMD_REQUEST_COMMAND:
 529                 {
 530                         if(argv(1) != "")
 531                         {
 532                                 sprint(self, strcat(MapVote_Suggest(argv(1)), "\n"));
 533                                 return;
 534                         }
 535                 }
 536
 537                 default:
 538                         sprint(self, "Incorrect parameters for ^2suggestmap^7\n");
 539                 case CMD_REQUEST_USAGE:
 540                 {
 541                         sprint(self, "\nUsage:^3 cmd suggestmap map\n");
 542                         sprint(self, "  Where 'map' is the name of the map to suggest.\n");
 543                         return;
 544                 }
 545         }
 546 }
 547
 548 void ClientCommand_tell(float request, float argc, string command)
 549 {
 550         switch(request)
 551         {
 552                 case CMD_REQUEST_COMMAND:
 553                 {
 554                         if(argc >= 3)
 555                         {
 556                                 entity tell_to = GetIndexedEntity(argc, 1);
 557                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 558
 559                                 if(tell_accepted > 0) // the target is a real client
 560                                 {
 561                                         if(tell_to != self) // and we're allowed to send to them :D
 562                                         {
 563                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 564                                                 // In this case when the player name contains utf8 chars
 565                                                 // the message gets partially trimmed in the beginning.
 566                                                 // Potentially this bug affects any substring call that uses
 567                                                 // argv_start_index and argv_end_index.
 568
 569                                                 string utf8_enable_save = cvar_string("utf8_enable");
 570                                                 cvar_set("utf8_enable", "0");
 571                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 572                                                 cvar_set("utf8_enable", utf8_enable_save);
 573
 574                                                 Say(self, false, tell_to, msg, true);
 575                                                 return;
 576                                         }
 577                                         else { print_to(self, "You can't ^2tell^7 a message to yourself."); return; }
 578                                 }
 579                                 else if(argv(1) == "#0")
 580                                 {
 581                                         trigger_magicear_processmessage_forallears(self, -1, world, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 582                                         return;
 583                                 }
 584                                 else { print_to(self, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 585                         }
 586                 }
 587
 588                 default:
 589                         sprint(self, "Incorrect parameters for ^2tell^7\n");
 590                 case CMD_REQUEST_USAGE:
 591                 {
 592                         sprint(self, "\nUsage:^3 cmd tell client <message>\n");
 593                         sprint(self, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 594                         return;
 595                 }
 596         }
 597 }
 598
 599 void ClientCommand_voice(float request, float argc, string command)
 600 {
 601         switch(request)
 602         {
 603                 case CMD_REQUEST_COMMAND:
 604                 {
 605                         if(argv(1) != "")
 606                         {
 607                                 if(argc >= 3)
 608                                         VoiceMessage(argv(1), substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 609                                 else
 610                                         VoiceMessage(argv(1), "");
 611
 612                                 return;
 613                         }
 614                 }
 615
 616                 default:
 617                         sprint(self, "Incorrect parameters for ^2voice^7\n");
 618                 case CMD_REQUEST_USAGE:
 619                 {
 620                         sprint(self, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 621                         sprint(self, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 622                         sprint(self, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 623                         return;
 624                 }
 625         }
 626 }
 627
 628 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 629 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 630 void ClientCommand_(float request)
 631 {
 632         switch(request)
 633         {
 634                 case CMD_REQUEST_COMMAND:
 635                 {
 636
 637                         return; // never fall through to usage
 638                 }
 639
 640                 default:
 641                 case CMD_REQUEST_USAGE:
 642                 {
 643                         sprint(self, "\nUsage:^3 cmd \n");
 644                         sprint(self, "  No arguments required.\n");
 645                         return;
 646                 }
 647         }
 648 }
 649 */
 650
 651
 652 // =====================================
 653 //  Macro system for networked commands
 654 // =====================================
 655
 656 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 657 #define CLIENT_COMMANDS(request,arguments,command) \
 658         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 659         CLIENT_COMMAND("checkfail", ClientCommand_checkfail(request, command), "Report if a client-side check failed") \
 660         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(request, arguments), "Release version of the game") \
 661         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(request, arguments), "Retrieve mapshot picture from the server") \
 662         CLIENT_COMMAND("join", ClientCommand_join(request), "Become a player in the game") \
 663         CLIENT_COMMAND("physics", ClientCommand_physics(request, arguments), "Change physics set") \
 664         CLIENT_COMMAND("ready", ClientCommand_ready(request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 665         CLIENT_COMMAND("say", ClientCommand_say(request, arguments, command), "Print a message to chat to all players") \
 666         CLIENT_COMMAND("say_team", ClientCommand_say_team(request, arguments, command), "Print a message to chat to all team mates") \
 667         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(request, arguments), "Attempt to choose a team to join into") \
 668         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(request, command), "Stuffcmd a command to your own client") \
 669         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(request, arguments, command), "New system for sending a client cvar to the server") \
 670         CLIENT_COMMAND("spectate", ClientCommand_spectate(request), "Become an observer") \
 671         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(request, arguments), "Suggest a map to the mapvote at match end") \
 672         CLIENT_COMMAND("tell", ClientCommand_tell(request, arguments, command), "Send a message directly to a player") \
 673         CLIENT_COMMAND("voice", ClientCommand_voice(request, arguments, command), "Send voice message via sound") \
 674         CLIENT_COMMAND("minigame", ClientCommand_minigame(request, arguments, command), "Start a minigame") \
 675         /* nothing */
 676
 677 void ClientCommand_macro_help()
 678 {
 679         #define CLIENT_COMMAND(name,function,description) \
 680                 { sprint(self, "  ^2", name, "^7: ", description, "\n"); }
 681
 682         CLIENT_COMMANDS(0, 0, "");
 683         #undef CLIENT_COMMAND
 684
 685         return;
 686 }
 687
 688 float ClientCommand_macro_command(float argc, string command)
 689 {
 690         #define CLIENT_COMMAND(name,function,description) \
 691                 { if(name == strtolower(argv(0))) { function; return true; } }
 692
 693         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc, command);
 694         #undef CLIENT_COMMAND
 695
 696         return false;
 697 }
 698
 699 float ClientCommand_macro_usage(float argc)
 700 {
 701         #define CLIENT_COMMAND(name,function,description) \
 702                 { if(name == strtolower(argv(1))) { function; return true; } }
 703
 704         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc, "");
 705         #undef CLIENT_COMMAND
 706
 707         return false;
 708 }
 709
 710 void ClientCommand_macro_write_aliases(float fh)
 711 {
 712         #define CLIENT_COMMAND(name,function,description) \
 713                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 714
 715         CLIENT_COMMANDS(0, 0, "");
 716         #undef CLIENT_COMMAND
 717
 718         return;
 719 }
 720
 721 // ======================================
 722 //  Main Function Called By Engine (cmd)
 723 // ======================================
 724 // If this function exists, server game code parses clientcommand before the engine code gets it.
 725
 726 void SV_ParseClientCommand(string command)
 727 {
 728         // If invalid UTF-8, don't even parse it
 729         string command2 = "";
 730         float len = strlen(command);
 731         float i;
 732         for (i = 0; i < len; ++i)
 733                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 734         if (command != command2)
 735                 return;
 736
 737         // if we're banned, don't even parse the command
 738         if(Ban_MaybeEnforceBanOnce(self))
 739                 return;
 740
 741         float argc = tokenize_console(command);
 742
 743         // Guide for working with argc arguments by example:
 744         // argc:   1    - 2      - 3     - 4
 745         // argv:   0    - 1      - 2     - 3
 746         // cmd     vote - master - login - password
 747
 748         // for floodcheck
 749         switch(strtolower(argv(0)))
 750         {
 751                 // exempt commands which are not subject to floodcheck
 752                 case "begin": break; // handled by engine in host_cmd.c
 753                 case "download": break; // handled by engine in cl_parse.c
 754                 case "mv_getpicture": break; // handled by server in this file
 755                 case "pause": break; // handled by engine in host_cmd.c
 756                 case "prespawn": break; // handled by engine in host_cmd.c
 757                 case "sentcvar": break; // handled by server in this file
 758                 case "spawn": break; // handled by engine in host_cmd.c
 759
 760                 default:
 761                         if(SV_ParseClientCommand_floodcheck())
 762                                 break; // "true": continue, as we're not flooding yet
 763                         else
 764                                 return; // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 765         }
 766
 767         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 768         if(argv(0) == "help")
 769         {
 770                 if(argc == 1)
 771                 {
 772                         sprint(self, "\nClient networked commands:\n");
 773                         ClientCommand_macro_help();
 774
 775                         sprint(self, "\nCommon networked commands:\n");
 776                         CommonCommand_macro_help(self);
 777
 778                         sprint(self, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 779                         sprint(self, "For help about a specific command, type cmd help COMMAND\n");
 780                         return;
 781                 }
 782                 else if(CommonCommand_macro_usage(argc, self)) // Instead of trying to call a command, we're going to see detailed information about it
 783                 {
 784                         return;
 785                 }
 786                 else if(ClientCommand_macro_usage(argc)) // same, but for normal commands now
 787                 {
 788                         return;
 789                 }
 790         }
 791         else if(MUTATOR_CALLHOOK(SV_ParseClientCommand, strtolower(argv(0)), argc, command))
 792         {
 793                 return; // handled by a mutator
 794         }
 795         else if(CheatCommand(argc))
 796         {
 797                 return; // handled by server/cheats.qc
 798         }
 799         else if(CommonCommand_macro_command(argc, self, command))
 800         {
 801                 return; // handled by server/command/common.qc
 802         }
 803         else if(ClientCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 804         {
 805                 return; // handled by one of the above ClientCommand_* functions
 806         }
 807         else
 808                 clientcommand(self, command);
 809 }