qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2 #include <common/command/_mod.qh>
   3
   4 #include "common.qh"
   5 #include "vote.qh"
   6
   7 #include "../campaign.qh"
   8 #include "../cheats.qh"
   9 #include "../player.qh"
  10 #include "../ipban.qh"
  11 #include "../mapvoting.qh"
  12 #include "../scores.qh"
  13 #include "../teamplay.qh"
  14
  15 #include "../mutators/_mod.qh"
  16
  17 #ifdef SVQC
  18         #include <common/vehicles/all.qh>
  19 #endif
  20
  21 #include <common/constants.qh>
  22 #include <common/deathtypes/all.qh>
  23 #include <common/effects/all.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/notifications/all.qh>
  26 #include <common/physics/player.qh>
  27 #include <common/teams.qh>
  28 #include <common/util.qh>
  29 #include <common/triggers/triggers.qh>
  30
  31 #include <common/minigames/sv_minigames.qh>
  32
  33 #include <common/monsters/_mod.qh>
  34 #include <common/monsters/sv_spawn.qh>
  35 #include <common/monsters/sv_monsters.qh>
  36
  37 #include <lib/warpzone/common.qh>
  38
  39 void ClientKill_TeamChange(entity this, float targetteam);  // 0 = don't change, -1 = auto, -2 = spec
  40
  41 // =========================================================
  42 //  Server side networked commands code, reworked by Samual
  43 //  Last updated: December 28th, 2011
  44 // =========================================================
  45
  46 bool SV_ParseClientCommand_floodcheck(entity this)
  47 {
  48         if (!timeout_status)  // not while paused
  49         {
  50                 if (time <= (this.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  51                 {
  52                         this.cmd_floodcount += 1;
  53                         if (this.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  54                 }
  55                 else
  56                 {
  57                         this.cmd_floodtime = time;
  58                         this.cmd_floodcount = 1;
  59                 }
  60         }
  61         return true;  // continue, as we're not flooding yet
  62 }
  63
  64
  65 // =======================
  66 //  Command Sub-Functions
  67 // =======================
  68
  69 void ClientCommand_autoswitch(entity caller, float request, float argc)
  70 {
  71         switch (request)
  72         {
  73                 case CMD_REQUEST_COMMAND:
  74                 {
  75                         if (argv(1) != "")
  76                         {
  77                                 caller.autoswitch = InterpretBoolean(argv(1));
  78                                 sprint(caller, strcat("^1autoswitch is currently turned ", (caller.autoswitch ? "on" : "off"), ".\n"));
  79                                 return;
  80                         }
  81                 }
  82
  83                 default:
  84                         sprint(caller, "Incorrect parameters for ^2autoswitch^7\n");
  85                 case CMD_REQUEST_USAGE:
  86                 {
  87                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  88                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  89                         return;
  90                 }
  91         }
  92 }
  93
  94 void ClientCommand_clientversion(entity caller, float request, float argc)  // internal command, used only by code
  95 {
  96         switch (request)
  97         {
  98                 case CMD_REQUEST_COMMAND:
  99                 {
 100                         if (argv(1) != "")
 101                         {
 102                                 if (IS_CLIENT(caller))
 103                                 {
 104                                         caller.version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 105
 106                                         if (caller.version < autocvar_gameversion_min || caller.version > autocvar_gameversion_max)
 107                                         {
 108                                                 caller.version_mismatch = 1;
 109                                                 ClientKill_TeamChange(caller, -2);  // observe
 110                                         }
 111                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 112                                         {
 113                                                 // JoinBestTeam(caller, false, true);
 114                                         }
 115                                         else if (teamplay && !autocvar_sv_spectate && !(caller.team_forced > 0))
 116                                         {
 117                                                 TRANSMUTE(Observer, caller);  // really?
 118                                                 stuffcmd(caller, "menu_showteamselect\n");
 119                                         }
 120                                 }
 121
 122                                 return;
 123                         }
 124                 }
 125
 126                 default:
 127                         sprint(caller, "Incorrect parameters for ^2clientversion^7\n");
 128                 case CMD_REQUEST_USAGE:
 129                 {
 130                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 131                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 132                         return;
 133                 }
 134         }
 135 }
 136
 137 void ClientCommand_getserverpic(entity caller, float request) // internal command, used only by code
 138 {
 139         switch(request)
 140         {
 141                 case CMD_REQUEST_COMMAND:
 142                 {
 143                         serverinfo_pic_send(caller);
 144                         return;
 145                 }
 146
 147                 default:
 148                 case CMD_REQUEST_USAGE:
 149                 {
 150                         sprint(caller, "\nUsage:^3 cmd getserverpic\n");
 151                         sprint(caller, "  No arguments required.\n");
 152                         return;
 153                 }
 154         }
 155 }
 156
 157 void ClientCommand_mv_getpicture(entity caller, float request, float argc)  // internal command, used only by code
 158 {
 159         switch (request)
 160         {
 161                 case CMD_REQUEST_COMMAND:
 162                 {
 163                         if (argv(1) != "")
 164                         {
 165                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 166
 167                                 return;
 168                         }
 169                 }
 170
 171                 default:
 172                         sprint(caller, "Incorrect parameters for ^2mv_getpicture^7\n");
 173                 case CMD_REQUEST_USAGE:
 174                 {
 175                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 176                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 177                         return;
 178                 }
 179         }
 180 }
 181
 182 bool joinAllowed(entity this);
 183 void Join(entity this);
 184 void ClientCommand_join(entity caller, float request)
 185 {
 186         switch (request)
 187         {
 188                 case CMD_REQUEST_COMMAND:
 189                 {
 190                         if (!gameover)
 191                         if (IS_CLIENT(caller) && !IS_PLAYER(caller))
 192                         if (joinAllowed(caller))
 193                                 Join(caller);
 194
 195                         return;  // never fall through to usage
 196                 }
 197
 198                 default:
 199                 case CMD_REQUEST_USAGE:
 200                 {
 201                         sprint(caller, "\nUsage:^3 cmd join\n");
 202                         sprint(caller, "  No arguments required.\n");
 203                         return;
 204                 }
 205         }
 206 }
 207
 208 void ClientCommand_physics(entity caller, float request, float argc)
 209 {
 210         switch (request)
 211         {
 212                 case CMD_REQUEST_COMMAND:
 213                 {
 214                         string command = strtolower(argv(1));
 215
 216                         if (!autocvar_g_physics_clientselect)
 217                         {
 218                                 sprint(caller, "Client physics selection is currently disabled.\n");
 219                                 return;
 220                         }
 221
 222                         if (command == "list" || command == "help")
 223                         {
 224                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 225                                 return;
 226                         }
 227
 228                         if (Physics_Valid(command) || command == "default")
 229                         {
 230                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 231                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 232                                 return;
 233                         }
 234                 }
 235
 236                 default:
 237                         sprint(caller, strcat("Current physics set: ^3", caller.cvar_cl_physics, "\n"));
 238                 case CMD_REQUEST_USAGE:
 239                 {
 240                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 241                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 242                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 243                         return;
 244                 }
 245         }
 246 }
 247
 248 void ClientCommand_ready(entity caller, float request)  // todo: anti-spam for toggling readyness
 249 {
 250         switch (request)
 251         {
 252                 case CMD_REQUEST_COMMAND:
 253                 {
 254                         if (IS_CLIENT(caller))
 255                         {
 256                                 if (warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 257                                 {
 258                                         if (!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 259                                         {
 260                                                 if (time < game_starttime) // game is already restarting
 261                                                         return;
 262                                                 if (caller.ready)            // toggle
 263                                                 {
 264                                                         caller.ready = false;
 265                                                         bprint(caller.netname, "^2 is ^1NOT^2 ready\n");
 266                                                 }
 267                                                 else
 268                                                 {
 269                                                         caller.ready = true;
 270                                                         bprint(caller.netname, "^2 is ready\n");
 271                                                 }
 272
 273                                                 // cannot reset the game while a timeout is active!
 274                                                 if (!timeout_status) ReadyCount();
 275                                         }
 276                                         else
 277                                         {
 278                                                 sprint(caller, "^1Game has already been restarted\n");
 279                                         }
 280                                 }
 281                         }
 282                         return;  // never fall through to usage
 283                 }
 284
 285                 default:
 286                 case CMD_REQUEST_USAGE:
 287                 {
 288                         sprint(caller, "\nUsage:^3 cmd ready\n");
 289                         sprint(caller, "  No arguments required.\n");
 290                         return;
 291                 }
 292         }
 293 }
 294
 295 void ClientCommand_say(entity caller, float request, float argc, string command)
 296 {
 297         switch (request)
 298         {
 299                 case CMD_REQUEST_COMMAND:
 300                 {
 301                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 302                         return;  // never fall through to usage
 303                 }
 304
 305                 default:
 306                 case CMD_REQUEST_USAGE:
 307                 {
 308                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 309                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 310                         return;
 311                 }
 312         }
 313 }
 314
 315 void ClientCommand_say_team(entity caller, float request, float argc, string command)
 316 {
 317         switch (request)
 318         {
 319                 case CMD_REQUEST_COMMAND:
 320                 {
 321                         if (argc >= 2)   Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 322                         return;  // never fall through to usage
 323                 }
 324
 325                 default:
 326                 case CMD_REQUEST_USAGE:
 327                 {
 328                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 329                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 330                         return;
 331                 }
 332         }
 333 }
 334
 335 .bool team_selected;
 336 void ClientCommand_selectteam(entity caller, float request, float argc)
 337 {
 338         switch (request)
 339         {
 340                 case CMD_REQUEST_COMMAND:
 341                 {
 342                         if (argv(1) != "")
 343                         {
 344                                 if (IS_CLIENT(caller))
 345                                 {
 346                                         if (teamplay)
 347                                         {
 348                                                 if (caller.team_forced <= 0)
 349                                                 {
 350                                                         if (!lockteams)
 351                                                         {
 352                                                                 float selection;
 353
 354                                                                 switch (argv(1))
 355                                                                 {
 356                                                                         case "red": selection = NUM_TEAM_1;
 357                                                                                 break;
 358                                                                         case "blue": selection = NUM_TEAM_2;
 359                                                                                 break;
 360                                                                         case "yellow": selection = NUM_TEAM_3;
 361                                                                                 break;
 362                                                                         case "pink": selection = NUM_TEAM_4;
 363                                                                                 break;
 364                                                                         case "auto": selection = (-1);
 365                                                                                 break;
 366
 367                                                                         default: selection = 0;
 368                                                                                 break;
 369                                                                 }
 370
 371                                                                 if (selection)
 372                                                                 {
 373                                                                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 374                                                                         {
 375                                                                                 sprint(caller, "^7You already are on that team.\n");
 376                                                                         }
 377                                                                         else if (caller.wasplayer && autocvar_g_changeteam_banned)
 378                                                                         {
 379                                                                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 380                                                                         }
 381                                                                         else
 382                                                                         {
 383                                                                                 if (autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 384                                                                                 {
 385                                                                                         CheckAllowedTeams(caller);
 386                                                                                         GetTeamCounts(caller);
 387                                                                                         if (!TeamSmallerEqThanTeam(Team_TeamToNumber(selection), Team_TeamToNumber(caller.team), caller))
 388                                                                                         {
 389                                                                                                 Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 390                                                                                                 return;
 391                                                                                         }
 392                                                                                 }
 393                                                                                 ClientKill_TeamChange(caller, selection);
 394                                                                         }
 395                                                                         if(!IS_PLAYER(caller))
 396                                                                                 caller.team_selected = true; // avoids asking again for team selection on join
 397                                                                 }
 398                                                         }
 399                                                         else
 400                                                         {
 401                                                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 402                                                         }
 403                                                 }
 404                                                 else
 405                                                 {
 406                                                         sprint(caller, "^7selectteam can not be used as your team is forced\n");
 407                                                 }
 408                                         }
 409                                         else
 410                                         {
 411                                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 412                                         }
 413                                 }
 414                                 return;
 415                         }
 416                 }
 417
 418                 default:
 419                         sprint(caller, "Incorrect parameters for ^2selectteam^7\n");
 420                 case CMD_REQUEST_USAGE:
 421                 {
 422                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 423                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 424                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 425                         return;
 426                 }
 427         }
 428 }
 429
 430 void ClientCommand_selfstuff(entity caller, float request, string command)
 431 {
 432         switch (request)
 433         {
 434                 case CMD_REQUEST_COMMAND:
 435                 {
 436                         if (argv(1) != "")
 437                         {
 438                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 439                                 return;
 440                         }
 441                 }
 442
 443                 default:
 444                         sprint(caller, "Incorrect parameters for ^2selfstuff^7\n");
 445                 case CMD_REQUEST_USAGE:
 446                 {
 447                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 448                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 449                         return;
 450                 }
 451         }
 452 }
 453
 454 void ClientCommand_sentcvar(entity caller, float request, float argc, string command)
 455 {
 456         switch (request)
 457         {
 458                 case CMD_REQUEST_COMMAND:
 459                 {
 460                         if (argv(1) != "")
 461                         {
 462                                 // float tokens;
 463                                 string s;
 464
 465                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 466                                 {
 467                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 468                                         tokenize_console(s);
 469                                 }
 470
 471                                 GetCvars(caller, 1);
 472
 473                                 return;
 474                         }
 475                 }
 476
 477                 default:
 478                         sprint(caller, "Incorrect parameters for ^2sentcvar^7\n");
 479                 case CMD_REQUEST_USAGE:
 480                 {
 481                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 482                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 483                         return;
 484                 }
 485         }
 486 }
 487
 488 void ClientCommand_spectate(entity caller, float request)
 489 {
 490         switch (request)
 491         {
 492                 case CMD_REQUEST_COMMAND:
 493                 {
 494                         if (IS_CLIENT(caller))
 495                         {
 496                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 497
 498                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 499
 500                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 501                                 if (autocvar_sv_spectate == 1)
 502                                         ClientKill_TeamChange(caller, -2); // observe
 503                         }
 504                         return; // never fall through to usage
 505                 }
 506
 507                 default:
 508                 case CMD_REQUEST_USAGE:
 509                 {
 510                         sprint(caller, "\nUsage:^3 cmd spectate\n");
 511                         sprint(caller, "  No arguments required.\n");
 512                         return;
 513                 }
 514         }
 515 }
 516
 517 void ClientCommand_suggestmap(entity caller, float request, float argc)
 518 {
 519         switch (request)
 520         {
 521                 case CMD_REQUEST_COMMAND:
 522                 {
 523                         if (argv(1) != "")
 524                         {
 525                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 526                                 return;
 527                         }
 528                 }
 529
 530                 default:
 531                         sprint(caller, "Incorrect parameters for ^2suggestmap^7\n");
 532                 case CMD_REQUEST_USAGE:
 533                 {
 534                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 535                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 536                         return;
 537                 }
 538         }
 539 }
 540
 541 void ClientCommand_tell(entity caller, float request, float argc, string command)
 542 {
 543         switch (request)
 544         {
 545                 case CMD_REQUEST_COMMAND:
 546                 {
 547                         if (argc >= 3)
 548                         {
 549                                 entity tell_to = GetIndexedEntity(argc, 1);
 550                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 551
 552                                 if (tell_accepted > 0)   // the target is a real client
 553                                 {
 554                                         if (tell_to != caller) // and we're allowed to send to them :D
 555                                         {
 556                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 557                                                 // In this case when the player name contains utf8 chars
 558                                                 // the message gets partially trimmed in the beginning.
 559                                                 // Potentially this bug affects any substring call that uses
 560                                                 // argv_start_index and argv_end_index.
 561
 562                                                 string utf8_enable_save = cvar_string("utf8_enable");
 563                                                 cvar_set("utf8_enable", "0");
 564                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 565                                                 cvar_set("utf8_enable", utf8_enable_save);
 566
 567                                                 Say(caller, false, tell_to, msg, true);
 568                                                 return;
 569                                         }
 570                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 571                                 }
 572                                 else if (argv(1) == "#0")
 573                                 {
 574                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 575                                         return;
 576                                 }
 577                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 578                         }
 579                 }
 580
 581                 default:
 582                         sprint(caller, "Incorrect parameters for ^2tell^7\n");
 583                 case CMD_REQUEST_USAGE:
 584                 {
 585                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 586                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 587                         return;
 588                 }
 589         }
 590 }
 591
 592 void ClientCommand_voice(entity caller, float request, float argc, string command)
 593 {
 594         switch (request)
 595         {
 596                 case CMD_REQUEST_COMMAND:
 597                 {
 598                         if (argv(1) != "")
 599                         {
 600                                 entity e = GetVoiceMessage(argv(1));
 601                                 if (!e)
 602                                 {
 603                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 604                                         return;
 605                                 }
 606                                 if (argc >= 3) VoiceMessage(caller, e, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 607                                 else VoiceMessage(caller, e, "");
 608
 609                                 return;
 610                         }
 611                 }
 612
 613                 default:
 614                         sprint(caller, "Incorrect parameters for ^2voice^7\n");
 615                 case CMD_REQUEST_USAGE:
 616                 {
 617                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 618                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 619                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 620                         return;
 621                 }
 622         }
 623 }
 624
 625 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 626 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 627 void ClientCommand_(entity caller, float request)
 628 {
 629     switch(request)
 630     {
 631         case CMD_REQUEST_COMMAND:
 632         {
 633
 634             return; // never fall through to usage
 635         }
 636
 637         default:
 638         case CMD_REQUEST_USAGE:
 639         {
 640             sprint(caller, "\nUsage:^3 cmd \n");
 641             sprint(caller, "  No arguments required.\n");
 642             return;
 643         }
 644     }
 645 }
 646 */
 647
 648
 649 // =====================================
 650 //  Macro system for networked commands
 651 // =====================================
 652
 653 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 654 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 655         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 656         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 657         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 658         CLIENT_COMMAND("getserverpic", ClientCommand_getserverpic(ent, request), "Retrieve server banner from the server") \
 659         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 660         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 661         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 662         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 663         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 664         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 665         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 666         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 667         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 668         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 669         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 670         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 671         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 672         /* nothing */
 673
 674 void ClientCommand_macro_help(entity caller)
 675 {
 676         #define CLIENT_COMMAND(name, function, description) \
 677                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 678
 679         CLIENT_COMMANDS(NULL, 0, 0, "");
 680 #undef CLIENT_COMMAND
 681 }
 682
 683 float ClientCommand_macro_command(float argc, entity caller, string command)
 684 {
 685         #define CLIENT_COMMAND(name, function, description) \
 686                 { if (name == strtolower(argv(0))) { function; return true; } }
 687
 688         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 689 #undef CLIENT_COMMAND
 690
 691         return false;
 692 }
 693
 694 float ClientCommand_macro_usage(float argc, entity caller)
 695 {
 696         #define CLIENT_COMMAND(name, function, description) \
 697                 { if (name == strtolower(argv(1))) { function; return true; } }
 698
 699         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 700 #undef CLIENT_COMMAND
 701
 702         return false;
 703 }
 704
 705 void ClientCommand_macro_write_aliases(float fh)
 706 {
 707         #define CLIENT_COMMAND(name, function, description) \
 708                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 709
 710         CLIENT_COMMANDS(NULL, 0, 0, "");
 711 #undef CLIENT_COMMAND
 712 }
 713
 714 // ======================================
 715 //  Main Function Called By Engine (cmd)
 716 // ======================================
 717 // If this function exists, server game code parses clientcommand before the engine code gets it.
 718
 719 void SV_ParseClientCommand(entity this, string command)
 720 {
 721         // If invalid UTF-8, don't even parse it
 722         string command2 = "";
 723         float len = strlen(command);
 724         float i;
 725         for (i = 0; i < len; ++i)
 726                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 727         if (command != command2) return;
 728
 729         // if we're banned, don't even parse the command
 730         if (Ban_MaybeEnforceBanOnce(this)) return;
 731
 732         float argc = tokenize_console(command);
 733
 734         // Guide for working with argc arguments by example:
 735         // argc:   1    - 2      - 3     - 4
 736         // argv:   0    - 1      - 2     - 3
 737         // cmd     vote - master - login - password
 738
 739         // for floodcheck
 740         switch (strtolower(argv(0)))
 741         {
 742                 // exempt commands which are not subject to floodcheck
 743                 case "begin": break;                               // handled by engine in host_cmd.c
 744                 case "download": break;                            // handled by engine in cl_parse.c
 745                 case "getserverpic": break; // handled by server in this file
 746                 case "mv_getpicture": break;                       // handled by server in this file
 747                 case "pause": break;                               // handled by engine in host_cmd.c
 748                 case "prespawn": break;                            // handled by engine in host_cmd.c
 749                 case "sentcvar": break;                            // handled by server in this file
 750                 case "spawn": break;                               // handled by engine in host_cmd.c
 751                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 752
 753                 default:
 754                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 755                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 756         }
 757
 758         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 759         if (argv(0) == "help")
 760         {
 761                 if (argc == 1)
 762                 {
 763                         sprint(this, "\nClient networked commands:\n");
 764                         ClientCommand_macro_help(this);
 765
 766                         sprint(this, "\nCommon networked commands:\n");
 767                         CommonCommand_macro_help(this);
 768
 769                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 770                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 771                         return;
 772                 }
 773                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 774                 {
 775                         return;
 776                 }
 777                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 778                 {
 779                         return;
 780                 }
 781         }
 782         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 783         {
 784                 return;  // handled by a mutator
 785         }
 786         else if (CheatCommand(this, argc))
 787         {
 788                 return;  // handled by server/cheats.qc
 789         }
 790         else if (CommonCommand_macro_command(argc, this, command))
 791         {
 792                 return;                                          // handled by server/command/common.qc
 793         }
 794         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 795         {
 796                 return;                                          // handled by one of the above ClientCommand_* functions
 797         }
 798         else
 799         {
 800                 clientcommand(this, command);
 801         }
 802 }