qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28 #include "weapons/common.qh"
  29
  30 #include "bot/api.qh"
  31
  32 #include "../common/ent_cs.qh"
  33 #include "../common/wepent.qh"
  34 #include <common/state.qh>
  35
  36 #include "compat/quake3.qh"
  37
  38 #include <common/effects/qc/globalsound.qh>
  39
  40 #include "../common/mapobjects/func/conveyor.qh"
  41 #include "../common/mapobjects/teleporters.qh"
  42 #include "../common/mapobjects/target/spawnpoint.qh"
  43 #include <common/mapobjects/trigger/counter.qh>
  44 #include <common/mapobjects/trigger/swamp.qh>
  45
  46 #include "../common/vehicles/all.qh"
  47
  48 #include "weapons/hitplot.qh"
  49 #include "weapons/weaponsystem.qh"
  50
  51 #include "../common/net_notice.qh"
  52 #include "../common/net_linked.qh"
  53 #include "../common/physics/player.qh"
  54
  55 #include <common/vehicles/sv_vehicles.qh>
  56
  57 #include "../common/items/_mod.qh"
  58
  59 #include "../common/mutators/mutator/waypoints/all.qh"
  60 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  61 #include <common/gamemodes/_mod.qh>
  62
  63 #include "../common/mapobjects/subs.qh"
  64 #include "../common/mapobjects/triggers.qh"
  65 #include "../common/mapobjects/trigger/secret.qh"
  66
  67 #include "../common/minigames/sv_minigames.qh"
  68
  69 #include "../common/items/inventory.qh"
  70
  71 #include "../common/monsters/sv_monsters.qh"
  72
  73 #include "../lib/warpzone/server.qh"
  74
  75 #include <common/mutators/mutator/overkill/oknex.qh>
  76
  77 STATIC_METHOD(Client, Add, void(Client this, int _team))
  78 {
  79     ClientConnect(this);
  80     TRANSMUTE(Player, this);
  81     this.frame = 12; // 7
  82     this.team = _team;
  83     PutClientInServer(this);
  84 }
  85
  86 STATIC_METHOD(Client, Remove, void(Client this))
  87 {
  88     TRANSMUTE(Observer, this);
  89     PutClientInServer(this);
  90     ClientDisconnect(this);
  91 }
  92
  93 void send_CSQC_teamnagger() {
  94         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  95 }
  96
  97 int CountSpectators(entity player, entity to)
  98 {
  99         if(!player) { return 0; } // not sure how, but best to be safe
 100
 101         int spec_count = 0;
 102
 103         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 104         {
 105                 spec_count++;
 106         });
 107
 108         return spec_count;
 109 }
 110
 111 void WriteSpectators(entity player, entity to)
 112 {
 113         if(!player) { return; } // not sure how, but best to be safe
 114
 115         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 116         {
 117                 WriteByte(MSG_ENTITY, num_for_edict(it));
 118         });
 119 }
 120
 121 bool ClientData_Send(entity this, entity to, int sf)
 122 {
 123         assert(to == this.owner, return false);
 124
 125         entity e = to;
 126         if (IS_SPEC(e)) e = e.enemy;
 127
 128         sf = 0;
 129         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 130         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 131         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 132         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 133
 134         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 135         WriteByte(MSG_ENTITY, sf);
 136
 137         if (sf & BIT(1))
 138                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 139
 140         if(sf & BIT(4))
 141         {
 142                 float specs = CountSpectators(e, to);
 143                 WriteByte(MSG_ENTITY, specs);
 144                 WriteSpectators(e, to);
 145         }
 146
 147         return true;
 148 }
 149
 150 void ClientData_Attach(entity this)
 151 {
 152         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 153         CS(this).clientdata.drawonlytoclient = this;
 154         CS(this).clientdata.owner = this;
 155 }
 156
 157 void ClientData_Detach(entity this)
 158 {
 159         delete(CS(this).clientdata);
 160         CS(this).clientdata = NULL;
 161 }
 162
 163 void ClientData_Touch(entity e)
 164 {
 165         entity cd = CS(e).clientdata;
 166         if (cd) { cd.SendFlags = 1; }
 167
 168         // make it spectatable
 169         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 170         {
 171                 entity cd = CS(it).clientdata;
 172                 if (cd) { cd.SendFlags = 1; }
 173         });
 174 }
 175
 176
 177 /*
 178 =============
 179 CheckPlayerModel
 180
 181 Checks if the argument string can be a valid playermodel.
 182 Returns a valid one in doubt.
 183 =============
 184 */
 185 string FallbackPlayerModel;
 186 string CheckPlayerModel(string plyermodel) {
 187         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 188         {
 189                 // note: we cannot summon Don Strunzone here, some player may
 190                 // still have the model string set. In case anyone manages how
 191                 // to change a cvar default, we'll have a small leak here.
 192                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 193         }
 194         // only in right path
 195         if( substring(plyermodel,0,14) != "models/player/")
 196                 return FallbackPlayerModel;
 197         // only good file extensions
 198         if(substring(plyermodel,-4,4) != ".zym")
 199         if(substring(plyermodel,-4,4) != ".dpm")
 200         if(substring(plyermodel,-4,4) != ".iqm")
 201         if(substring(plyermodel,-4,4) != ".md3")
 202         if(substring(plyermodel,-4,4) != ".psk")
 203                 return FallbackPlayerModel;
 204         // forbid the LOD models
 205         if(substring(plyermodel, -9,5) == "_lod1")
 206                 return FallbackPlayerModel;
 207         if(substring(plyermodel, -9,5) == "_lod2")
 208                 return FallbackPlayerModel;
 209         if(plyermodel != strtolower(plyermodel))
 210                 return FallbackPlayerModel;
 211         // also, restrict to server models
 212         if(autocvar_sv_servermodelsonly)
 213         {
 214                 if(!fexists(plyermodel))
 215                         return FallbackPlayerModel;
 216         }
 217         return plyermodel;
 218 }
 219
 220 void setplayermodel(entity e, string modelname)
 221 {
 222         precache_model(modelname);
 223         _setmodel(e, modelname);
 224         player_setupanimsformodel(e);
 225         if(!autocvar_g_debug_globalsounds)
 226                 UpdatePlayerSounds(e);
 227 }
 228
 229 /** putting a client as observer in the server */
 230 void PutObserverInServer(entity this)
 231 {
 232     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 233         PlayerState_detach(this);
 234
 235         if (IS_PLAYER(this))
 236         {
 237                 if(GetResource(this, RES_HEALTH) >= 1)
 238                 {
 239                         // despawn effect
 240                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 241                 }
 242
 243                 // was a player, recount votes and ready status
 244                 if(IS_REAL_CLIENT(this))
 245                 {
 246                         if (vote_called) { VoteCount(false); }
 247                         ReadyCount();
 248                 }
 249     }
 250
 251     {
 252         entity spot = SelectSpawnPoint(this, true);
 253         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 254         this.angles = vec2(spot.angles);
 255         this.fixangle = true;
 256         // offset it so that the spectator spawns higher off the ground, looks better this way
 257         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 258         if (IS_REAL_CLIENT(this))
 259         {
 260             msg_entity = this;
 261             WriteByte(MSG_ONE, SVC_SETVIEW);
 262             WriteEntity(MSG_ONE, this);
 263         }
 264         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 265         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 266         if(!autocvar_g_debug_globalsounds)
 267         {
 268                 // needed for player sounds
 269                 this.model = "";
 270                 FixPlayermodel(this);
 271         }
 272         setmodel(this, MDL_Null);
 273         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 274         this.view_ofs = '0 0 0';
 275     }
 276
 277     RemoveGrapplingHooks(this);
 278         Portal_ClearAll(this);
 279         Unfreeze(this, false);
 280         SetSpectatee(this, NULL);
 281
 282         if (this.alivetime)
 283         {
 284                 if (!warmup_stage)
 285                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 286                 this.alivetime = 0;
 287         }
 288
 289         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 290
 291         WaypointSprite_PlayerDead(this);
 292
 293         if (CS(this).killcount != FRAGS_SPECTATOR)
 294         {
 295                 if(!game_stopped)
 296                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 297                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 298         }
 299
 300         accuracy_resend(this);
 301
 302         CS(this).spectatortime = time;
 303         if(this.bot_attack)
 304                 IL_REMOVE(g_bot_targets, this);
 305         this.bot_attack = false;
 306         if(this.monster_attack)
 307                 IL_REMOVE(g_monster_targets, this);
 308         this.monster_attack = false;
 309     STAT(HUD, this) = HUD_NORMAL;
 310         TRANSMUTE(Observer, this);
 311         this.iscreature = false;
 312         this.teleportable = TELEPORT_SIMPLE;
 313         if(this.damagedbycontents)
 314                 IL_REMOVE(g_damagedbycontents, this);
 315         this.damagedbycontents = false;
 316         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 317         SetSpectatee_status(this, etof(this));
 318         this.takedamage = DAMAGE_NO;
 319         this.solid = SOLID_NOT;
 320         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 321         this.flags = FL_CLIENT | FL_NOTARGET;
 322         this.effects = 0;
 323         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 324         this.pauserotarmor_finished = 0;
 325         this.pauserothealth_finished = 0;
 326         this.pauseregen_finished = 0;
 327         this.damageforcescale = 0;
 328         this.death_time = 0;
 329         this.respawn_flags = 0;
 330         this.respawn_time = 0;
 331         STAT(RESPAWN_TIME, this) = 0;
 332         this.alpha = 0;
 333         this.scale = 0;
 334         this.fade_time = 0;
 335         this.pain_frame = 0;
 336         this.pain_finished = 0;
 337         this.strength_finished = 0;
 338         this.invincible_finished = 0;
 339         this.superweapons_finished = 0;
 340         //this.dphitcontentsmask = 0;
 341         this.dphitcontentsmask = DPCONTENTS_SOLID;
 342         if (autocvar_g_playerclip_collisions)
 343                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 344         this.pushltime = 0;
 345         this.istypefrag = 0;
 346         setthink(this, func_null);
 347         this.nextthink = 0;
 348         this.deadflag = DEAD_NO;
 349         this.crouch = false;
 350         STAT(REVIVE_PROGRESS, this) = 0;
 351         this.revival_time = 0;
 352         this.draggable = drag_undraggable;
 353
 354         this.items = 0;
 355         STAT(WEAPONS, this) = '0 0 0';
 356         this.drawonlytoclient = this;
 357
 358         this.viewloc = NULL;
 359
 360         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 361
 362         this.weaponmodel = "";
 363         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 364         {
 365                 this.weaponentities[slot] = NULL;
 366         }
 367         this.exteriorweaponentity = NULL;
 368         CS(this).killcount = FRAGS_SPECTATOR;
 369         this.velocity = '0 0 0';
 370         this.avelocity = '0 0 0';
 371         this.punchangle = '0 0 0';
 372         this.punchvector = '0 0 0';
 373         this.oldvelocity = this.velocity;
 374         this.fire_endtime = -1;
 375         this.event_damage = func_null;
 376         this.event_heal = func_null;
 377
 378         for(int slot = 0; slot < MAX_AXH; ++slot)
 379         {
 380                 entity axh = this.(AuxiliaryXhair[slot]);
 381                 this.(AuxiliaryXhair[slot]) = NULL;
 382
 383                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 384                         delete(axh);
 385         }
 386
 387         if (mutator_returnvalue)
 388         {
 389                 // mutator prevents resetting teams+score
 390         }
 391         else
 392         {
 393                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 394                 this.frags = FRAGS_SPECTATOR;
 395         }
 396         if (CS(this).just_joined)
 397                 CS(this).just_joined = false;
 398 }
 399
 400 int player_getspecies(entity this)
 401 {
 402         get_model_parameters(this.model, this.skin);
 403         int s = get_model_parameters_species;
 404         get_model_parameters(string_null, 0);
 405         if (s < 0) return SPECIES_HUMAN;
 406         return s;
 407 }
 408
 409 .float model_randomizer;
 410 void FixPlayermodel(entity player)
 411 {
 412         string defaultmodel = "";
 413         int defaultskin = 0;
 414         if(autocvar_sv_defaultcharacter)
 415         {
 416                 if(teamplay)
 417                 {
 418                         switch(player.team)
 419                         {
 420                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 421                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 422                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 423                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 424                         }
 425                 }
 426
 427                 if(defaultmodel == "")
 428                 {
 429                         defaultmodel = autocvar_sv_defaultplayermodel;
 430                         defaultskin = autocvar_sv_defaultplayerskin;
 431                 }
 432
 433                 int n = tokenize_console(defaultmodel);
 434                 if(n > 0)
 435                 {
 436                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 437                         // However, do NOT randomize if the player-selected model is in the list.
 438                         for (int i = 0; i < n; ++i)
 439                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 440                                         defaultmodel = argv(i);
 441                 }
 442
 443                 int i = strstrofs(defaultmodel, ":", 0);
 444                 if(i >= 0)
 445                 {
 446                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 447                         defaultmodel = substring(defaultmodel, 0, i);
 448                 }
 449         }
 450         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 451         {
 452                 if(teamplay)
 453                 {
 454                         switch(player.team)
 455                         {
 456                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 457                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 458                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 459                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 460                         }
 461                 }
 462
 463                 if(!defaultskin)
 464                         defaultskin = autocvar_sv_defaultplayerskin;
 465         }
 466
 467         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 468         defaultmodel = M_ARGV(0, string);
 469         defaultskin = M_ARGV(1, int);
 470
 471         bool chmdl = false;
 472         int oldskin;
 473         if(defaultmodel != "")
 474         {
 475                 if (defaultmodel != player.model)
 476                 {
 477                         vector m1 = player.mins;
 478                         vector m2 = player.maxs;
 479                         setplayermodel (player, defaultmodel);
 480                         setsize (player, m1, m2);
 481                         chmdl = true;
 482                 }
 483
 484                 oldskin = player.skin;
 485                 player.skin = defaultskin;
 486         } else {
 487                 if (player.playermodel != player.model || player.playermodel == "")
 488                 {
 489                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 490                         vector m1 = player.mins;
 491                         vector m2 = player.maxs;
 492                         setplayermodel (player, player.playermodel);
 493                         setsize (player, m1, m2);
 494                         chmdl = true;
 495                 }
 496
 497                 if(!autocvar_sv_defaultcharacterskin)
 498                 {
 499                         oldskin = player.skin;
 500                         player.skin = stof(player.playerskin);
 501                 }
 502                 else
 503                 {
 504                         oldskin = player.skin;
 505                         player.skin = defaultskin;
 506                 }
 507         }
 508
 509         if(chmdl || oldskin != player.skin) // model or skin has changed
 510         {
 511                 player.species = player_getspecies(player); // update species
 512                 if(!autocvar_g_debug_globalsounds)
 513                         UpdatePlayerSounds(player); // update skin sounds
 514         }
 515
 516         if(!teamplay)
 517                 if(strlen(autocvar_sv_defaultplayercolors))
 518                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 519                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 520 }
 521
 522 void PutPlayerInServer(entity this)
 523 {
 524         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 525
 526         PlayerState_attach(this);
 527         accuracy_resend(this);
 528
 529         if (this.team < 0)
 530                 TeamBalance_JoinBestTeam(this);
 531
 532         entity spot = SelectSpawnPoint(this, false);
 533         if (!spot) {
 534                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 535                 return; // spawn failed
 536         }
 537
 538         TRANSMUTE(Player, this);
 539
 540         CS(this).wasplayer = true;
 541         this.iscreature = true;
 542         this.teleportable = TELEPORT_NORMAL;
 543         if(!this.damagedbycontents)
 544                 IL_PUSH(g_damagedbycontents, this);
 545         this.damagedbycontents = true;
 546         set_movetype(this, MOVETYPE_WALK);
 547         this.solid = SOLID_SLIDEBOX;
 548         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 549         if (autocvar_g_playerclip_collisions)
 550                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 551         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 552                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 553         this.frags = FRAGS_PLAYER;
 554         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 555         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 556         if (autocvar__notarget)
 557                 this.flags |= FL_NOTARGET;
 558         this.takedamage = DAMAGE_AIM;
 559         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 560
 561         if (warmup_stage) {
 562                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 563                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 564                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 565                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 566                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 567                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 568                 SetResource(this, RES_HEALTH, warmup_start_health);
 569                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 570                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 571         } else {
 572                 SetResource(this, RES_SHELLS, start_ammo_shells);
 573                 SetResource(this, RES_BULLETS, start_ammo_nails);
 574                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 575                 SetResource(this, RES_CELLS, start_ammo_cells);
 576                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 577                 SetResource(this, RES_FUEL, start_ammo_fuel);
 578                 SetResource(this, RES_HEALTH, start_health);
 579                 SetResource(this, RES_ARMOR, start_armorvalue);
 580                 STAT(WEAPONS, this) = start_weapons;
 581                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 582                 {
 583                         GiveRandomWeapons(this, random_start_weapons_count,
 584                                 autocvar_g_random_start_weapons, random_start_ammo);
 585                 }
 586         }
 587         SetSpectatee_status(this, 0);
 588
 589         PS(this).dual_weapons = '0 0 0';
 590
 591         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 592
 593         this.items = start_items;
 594
 595         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 596         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 597         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 598         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 599         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 600         if (!sv_ready_restart_after_countdown && time < game_starttime)
 601         {
 602                 float f = game_starttime - time;
 603                 this.spawnshieldtime += f;
 604                 this.pauserotarmor_finished += f;
 605                 this.pauserothealth_finished += f;
 606                 this.pauseregen_finished += f;
 607         }
 608
 609         this.damageforcescale = autocvar_g_player_damageforcescale;
 610         this.death_time = 0;
 611         this.respawn_flags = 0;
 612         this.respawn_time = 0;
 613         STAT(RESPAWN_TIME, this) = 0;
 614         this.scale = autocvar_sv_player_scale;
 615         this.fade_time = 0;
 616         this.pain_frame = 0;
 617         this.pain_finished = 0;
 618         this.pushltime = 0;
 619         setthink(this, func_null); // players have no think function
 620         this.nextthink = 0;
 621         this.dmg_team = 0;
 622         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 623
 624         this.deadflag = DEAD_NO;
 625
 626         this.angles = spot.angles;
 627         this.angles_z = 0; // never spawn tilted even if the spot says to
 628         if (IS_BOT_CLIENT(this))
 629         {
 630                 this.v_angle = this.angles;
 631                 bot_aim_reset(this);
 632         }
 633         this.fixangle = true; // turn this way immediately
 634         this.oldvelocity = this.velocity = '0 0 0';
 635         this.avelocity = '0 0 0';
 636         this.punchangle = '0 0 0';
 637         this.punchvector = '0 0 0';
 638
 639         this.strength_finished = 0;
 640         this.invincible_finished = 0;
 641         this.fire_endtime = -1;
 642         STAT(REVIVE_PROGRESS, this) = 0;
 643         this.revival_time = 0;
 644
 645         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 646         STAT(BUFFS, this) = 0;
 647         STAT(BUFF_TIME, this) = 0;
 648
 649         this.air_finished = time + 12;
 650         this.waterlevel = WATERLEVEL_NONE;
 651         this.watertype = CONTENT_EMPTY;
 652
 653         entity spawnevent = new_pure(spawnevent);
 654         spawnevent.owner = this;
 655         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 656
 657         // Cut off any still running player sounds.
 658         stopsound(this, CH_PLAYER_SINGLE);
 659
 660         this.model = "";
 661         FixPlayermodel(this);
 662         this.drawonlytoclient = NULL;
 663
 664         this.viewloc = NULL;
 665
 666         for(int slot = 0; slot < MAX_AXH; ++slot)
 667         {
 668                 entity axh = this.(AuxiliaryXhair[slot]);
 669                 this.(AuxiliaryXhair[slot]) = NULL;
 670
 671                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 672                         delete(axh);
 673         }
 674
 675         this.spawnpoint_targ = NULL;
 676
 677         this.crouch = false;
 678         this.view_ofs = STAT(PL_VIEW_OFS, this);
 679         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 680         this.spawnorigin = spot.origin;
 681         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 682         // don't reset back to last position, even if new position is stuck in solid
 683         this.oldorigin = this.origin;
 684         if(this.conveyor)
 685                 IL_REMOVE(g_conveyed, this);
 686         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 687         if(this.swampslug)
 688                 delete(this.swampslug);
 689         this.in_swamp = false;
 690         STAT(HUD, this) = HUD_NORMAL;
 691
 692         this.event_damage = PlayerDamage;
 693         this.event_heal = PlayerHeal;
 694
 695         this.draggable = func_null;
 696
 697         if(!this.bot_attack)
 698                 IL_PUSH(g_bot_targets, this);
 699         this.bot_attack = true;
 700         if(!this.monster_attack)
 701                 IL_PUSH(g_monster_targets, this);
 702         this.monster_attack = true;
 703         navigation_dynamicgoal_init(this, false);
 704
 705         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 706
 707         // player was spectator
 708         if (CS(this).killcount == FRAGS_SPECTATOR) {
 709                 PlayerScore_Clear(this);
 710                 CS(this).killcount = 0;
 711                 CS(this).startplaytime = time;
 712         }
 713
 714         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 715         {
 716                 .entity weaponentity = weaponentities[slot];
 717                 CL_SpawnWeaponentity(this, weaponentity);
 718         }
 719         this.alpha = default_player_alpha;
 720         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 721         this.exteriorweaponentity.alpha = default_weapon_alpha;
 722
 723         this.speedrunning = false;
 724
 725         this.counter_cnt = 0;
 726         this.fragsfilter_cnt = 0;
 727
 728         target_voicescript_clear(this);
 729
 730         // reset fields the weapons may use
 731         FOREACH(Weapons, true, {
 732                 it.wr_resetplayer(it, this);
 733                         // reload all reloadable weapons
 734                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 735                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 736                         {
 737                                 .entity weaponentity = weaponentities[slot];
 738                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 739                         }
 740                 }
 741         });
 742
 743         {
 744                 string s = spot.target;
 745                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 746                         spot.target = string_null;
 747                 SUB_UseTargets(spot, this, NULL);
 748                 if(g_assault || g_race)
 749                         spot.target = s;
 750         }
 751
 752         Unfreeze(this, false);
 753
 754         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 755
 756         if (autocvar_spawn_debug)
 757         {
 758                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 759                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 760         }
 761
 762         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 763         {
 764                 .entity weaponentity = weaponentities[slot];
 765                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 766                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 767                 else
 768                         this.(weaponentity).m_switchweapon = WEP_Null;
 769                 this.(weaponentity).m_weapon = WEP_Null;
 770                 this.(weaponentity).weaponname = "";
 771                 this.(weaponentity).m_switchingweapon = WEP_Null;
 772                 this.(weaponentity).cnt = -1;
 773         }
 774
 775         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 776
 777         if (CS(this).impulse) ImpulseCommands(this);
 778
 779         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 780         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 781         {
 782                 .entity weaponentity = weaponentities[slot];
 783                 W_WeaponFrame(this, weaponentity);
 784         }
 785
 786         if (!warmup_stage && !this.alivetime)
 787                 this.alivetime = time;
 788
 789         antilag_clear(this, CS(this));
 790 }
 791
 792 /** Called when a client spawns in the server */
 793 void PutClientInServer(entity this)
 794 {
 795         if (IS_BOT_CLIENT(this)) {
 796                 TRANSMUTE(Player, this);
 797         } else if (IS_REAL_CLIENT(this)) {
 798                 msg_entity = this;
 799                 WriteByte(MSG_ONE, SVC_SETVIEW);
 800                 WriteEntity(MSG_ONE, this);
 801         }
 802         if (game_stopped)
 803                 TRANSMUTE(Observer, this);
 804
 805         SetSpectatee(this, NULL);
 806
 807         // reset player keys
 808         if(PS(this))
 809                 PS(this).itemkeys = 0;
 810
 811         MUTATOR_CALLHOOK(PutClientInServer, this);
 812
 813         if (IS_OBSERVER(this)) {
 814                 PutObserverInServer(this);
 815         } else if (IS_PLAYER(this)) {
 816                 PutPlayerInServer(this);
 817         }
 818 }
 819
 820 // TODO do we need all these fields, or should we stop autodetecting runtime
 821 // changes and just have a console command to update this?
 822 bool ClientInit_SendEntity(entity this, entity to, int sf)
 823 {
 824         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 825         return = true;
 826         msg_entity = to;
 827         // MSG_INIT replacement
 828         // TODO: make easier to use
 829         Registry_send_all();
 830         W_PROP_reload(MSG_ONE, to);
 831         ClientInit_misc(this);
 832         MUTATOR_CALLHOOK(Ent_Init);
 833 }
 834 void ClientInit_misc(entity this)
 835 {
 836         int channel = MSG_ONE;
 837         WriteHeader(channel, ENT_CLIENT_INIT);
 838         WriteByte(channel, g_nexball_meter_period * 32);
 839         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 840         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 841         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 842         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 843         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 844         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 845         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 846         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 847
 848         if(sv_foginterval && world.fog != "")
 849                 WriteString(channel, world.fog);
 850         else
 851                 WriteString(channel, "");
 852         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 853         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 854         WriteByte(channel, serverflags);
 855         WriteCoord(channel, autocvar_g_trueaim_minrange);
 856 }
 857
 858 void ClientInit_CheckUpdate(entity this)
 859 {
 860         this.nextthink = time;
 861         if(this.count != autocvar_g_balance_armor_blockpercent)
 862         {
 863                 this.count = autocvar_g_balance_armor_blockpercent;
 864                 this.SendFlags |= 1;
 865         }
 866         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 867         {
 868                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 869                 this.SendFlags |= 1;
 870         }
 871 }
 872
 873 void ClientInit_Spawn()
 874 {
 875         entity e = new_pure(clientinit);
 876         setthink(e, ClientInit_CheckUpdate);
 877         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 878
 879         ClientInit_CheckUpdate(e);
 880 }
 881
 882 /*
 883 =============
 884 SetNewParms
 885 =============
 886 */
 887 void SetNewParms ()
 888 {
 889         // initialize parms for a new player
 890         parm1 = -(86400 * 366);
 891
 892         MUTATOR_CALLHOOK(SetNewParms);
 893 }
 894
 895 /*
 896 =============
 897 SetChangeParms
 898 =============
 899 */
 900 void SetChangeParms (entity this)
 901 {
 902         // save parms for level change
 903         parm1 = CS(this).parm_idlesince - time;
 904
 905         MUTATOR_CALLHOOK(SetChangeParms);
 906 }
 907
 908 /*
 909 =============
 910 DecodeLevelParms
 911 =============
 912 */
 913 void DecodeLevelParms(entity this)
 914 {
 915         // load parms
 916         CS(this).parm_idlesince = parm1;
 917         if (CS(this).parm_idlesince == -(86400 * 366))
 918                 CS(this).parm_idlesince = time;
 919
 920         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 921         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 922
 923         MUTATOR_CALLHOOK(DecodeLevelParms);
 924 }
 925
 926 void FixClientCvars(entity e)
 927 {
 928         // send prediction settings to the client
 929         stuffcmd(e, "\nin_bindmap 0 0\n");
 930         if(autocvar_g_antilag == 3) // client side hitscan
 931                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 932         if(autocvar_sv_gentle)
 933                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 934
 935         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 936         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 937
 938         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 939
 940         MUTATOR_CALLHOOK(FixClientCvars, e);
 941 }
 942
 943 bool findinlist_abbrev(string tofind, string list)
 944 {
 945         if(list == "" || tofind == "")
 946                 return false; // empty list or search, just return
 947
 948         // this function allows abbreviated strings!
 949         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 950         {
 951                 return true;
 952         });
 953
 954         return false;
 955 }
 956
 957 bool PlayerInIPList(entity p, string iplist)
 958 {
 959         // some safety checks (never allow local?)
 960         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 961                 return false;
 962
 963         return findinlist_abbrev(p.netaddress, iplist);
 964 }
 965
 966 bool PlayerInIDList(entity p, string idlist)
 967 {
 968         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 969         if(!p.crypto_idfp)
 970                 return false;
 971
 972         return findinlist_abbrev(p.crypto_idfp, idlist);
 973 }
 974
 975 bool PlayerInList(entity player, string list)
 976 {
 977         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 978 }
 979
 980 #ifdef DP_EXT_PRECONNECT
 981 /*
 982 =============
 983 ClientPreConnect
 984
 985 Called once (not at each match start) when a client begins a connection to the server
 986 =============
 987 */
 988 void ClientPreConnect(entity this)
 989 {
 990         if(autocvar_sv_eventlog)
 991         {
 992                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 993                         this.playerid,
 994                         etof(this),
 995                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
 996                 ));
 997         }
 998 }
 999 #endif
1000
1001 string GetClientVersionMessage(entity this)
1002 {
1003         if (CS(this).version_mismatch) {
1004                 if(CS(this).version < autocvar_gameversion) {
1005                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1006                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1007                 } else {
1008                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1009                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1010                 }
1011         } else {
1012                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1013         }
1014 }
1015
1016 string getwelcomemessage(entity this)
1017 {
1018         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1019         string modifications = M_ARGV(0, string);
1020
1021         if(g_weaponarena)
1022         {
1023                 if(g_weaponarena_random)
1024                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1025                 else
1026                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1027         }
1028         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1029                 modifications = strcat(modifications, ", No start weapons");
1030         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1031                 modifications = strcat(modifications, ", Low gravity");
1032         if(g_weapon_stay && !g_cts)
1033                 modifications = strcat(modifications, ", Weapons stay");
1034         if(g_jetpack)
1035                 modifications = strcat(modifications, ", Jet pack");
1036         if(autocvar_g_powerups == 0)
1037                 modifications = strcat(modifications, ", No powerups");
1038         if(autocvar_g_powerups > 0)
1039                 modifications = strcat(modifications, ", Powerups");
1040         modifications = substring(modifications, 2, strlen(modifications) - 2);
1041
1042         string versionmessage = GetClientVersionMessage(this);
1043         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1044
1045         if(modifications != "")
1046                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1047
1048         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1049         {
1050                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1051                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1052         }
1053
1054         if (cache_mutatormsg != "") {
1055                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1056         }
1057
1058         string mutator_msg = "";
1059         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1060         mutator_msg = M_ARGV(0, string);
1061
1062         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1063
1064         string motd = autocvar_sv_motd;
1065         if (motd != "") {
1066                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1067         }
1068         return s;
1069 }
1070
1071 bool autocvar_sv_qcphysics = false; // TODO this is for testing - remove when qcphysics work
1072
1073 /**
1074 =============
1075 ClientConnect
1076
1077 Called when a client connects to the server
1078 =============
1079 */
1080 void ClientConnect(entity this)
1081 {
1082         if (Ban_MaybeEnforceBanOnce(this)) return;
1083         assert(!IS_CLIENT(this), return);
1084         this.flags |= FL_CLIENT;
1085         assert(player_count >= 0, player_count = 0);
1086
1087 #ifdef WATERMARK
1088         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1089 #endif
1090         TRANSMUTE(Client, this);
1091         CS(this).version_nagtime = time + 10 + random() * 10;
1092
1093         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1094
1095         bot_clientconnect(this);
1096
1097         Player_DetermineForcedTeam(this);
1098
1099         TRANSMUTE(Observer, this);
1100
1101         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1102
1103         // always track bots, don't ask for cl_allow_uidtracking
1104         if (IS_BOT_CLIENT(this))
1105                 PlayerStats_GameReport_AddPlayer(this);
1106         else
1107                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1108
1109         if (autocvar_sv_eventlog)
1110                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1111
1112         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1113
1114         stuffcmd(this, clientstuff, "\n");
1115         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1116
1117         FixClientCvars(this);
1118
1119         // get version info from player
1120         stuffcmd(this, "cmd clientversion $gameversion\n");
1121
1122         // notify about available teams
1123         if (teamplay)
1124         {
1125                 entity balance = TeamBalance_CheckAllowedTeams(this);
1126                 int t = TeamBalance_GetAllowedTeams(balance);
1127                 TeamBalance_Destroy(balance);
1128                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1129         }
1130         else
1131         {
1132                 stuffcmd(this, "set _teams_available 0\n");
1133         }
1134
1135         bot_relinkplayerlist();
1136
1137         CS(this).spectatortime = time;
1138         if (blockSpectators)
1139         {
1140                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1141         }
1142
1143         CS(this).jointime = time;
1144
1145         if (IS_REAL_CLIENT(this))
1146         {
1147                 if (g_weaponarena_weapons == WEPSET(TUBA))
1148                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1149         }
1150
1151         if (!sv_foginterval && world.fog != "")
1152                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1153
1154         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1155                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1156                         send_CSQC_teamnagger();
1157
1158         CSQCMODEL_AUTOINIT(this);
1159
1160         CS(this).model_randomizer = random();
1161
1162         if (IS_REAL_CLIENT(this))
1163                 sv_notice_join(this);
1164
1165         this.move_qcphysics = autocvar_sv_qcphysics;
1166
1167         // update physics stats (players can spawn before physics runs)
1168         Physics_UpdateStats(this);
1169
1170         IL_EACH(g_initforplayer, it.init_for_player, {
1171                 it.init_for_player(it, this);
1172         });
1173
1174         Handicap_Initialize(this);
1175
1176         MUTATOR_CALLHOOK(ClientConnect, this);
1177
1178         if (IS_REAL_CLIENT(this))
1179         {
1180                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1181                 {
1182                         CS(this).motd_actived_time = -1;
1183                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1184                 }
1185         }
1186 }
1187 /*
1188 =============
1189 ClientDisconnect
1190
1191 Called when a client disconnects from the server
1192 =============
1193 */
1194 .entity chatbubbleentity;
1195 void ClientDisconnect(entity this)
1196 {
1197         assert(IS_CLIENT(this), return);
1198
1199         PlayerStats_GameReport_FinalizePlayer(this);
1200         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1201         if (CS(this).active_minigame) part_minigame(this);
1202         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1203
1204         if (autocvar_sv_eventlog)
1205                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1206
1207         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1208
1209         if(IS_SPEC(this))
1210                 SetSpectatee(this, NULL);
1211
1212     MUTATOR_CALLHOOK(ClientDisconnect, this);
1213
1214         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1215         strfree(CS(this).weaponorder_byimpulse);
1216         ClientState_detach(this);
1217
1218         Portal_ClearAll(this);
1219
1220         Unfreeze(this, false);
1221
1222         RemoveGrapplingHooks(this);
1223
1224         // Here, everything has been done that requires this player to be a client.
1225
1226         this.flags &= ~FL_CLIENT;
1227
1228         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1229         if (this.killindicator) delete(this.killindicator);
1230
1231         WaypointSprite_PlayerGone(this);
1232
1233         bot_relinkplayerlist();
1234
1235         strfree(this.clientstatus);
1236         if (this.personal) delete(this.personal);
1237
1238         this.playerid = 0;
1239         ReadyCount();
1240         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1241
1242         ONREMOVE(this);
1243 }
1244
1245 void ChatBubbleThink(entity this)
1246 {
1247         this.nextthink = time;
1248         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1249         {
1250                 if(this.owner) // but why can that ever be NULL?
1251                         this.owner.chatbubbleentity = NULL;
1252                 delete(this);
1253                 return;
1254         }
1255
1256         this.mdl = "";
1257
1258         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1259         {
1260                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1261                         this.mdl = "models/sprites/minigame_busy.iqm";
1262                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1263                         this.mdl = "models/misc/chatbubble.spr";
1264         }
1265
1266         if ( this.model != this.mdl )
1267                 _setmodel(this, this.mdl);
1268
1269 }
1270
1271 void UpdateChatBubble(entity this)
1272 {
1273         if (this.alpha < 0)
1274                 return;
1275         // spawn a chatbubble entity if needed
1276         if (!this.chatbubbleentity)
1277         {
1278                 this.chatbubbleentity = new(chatbubbleentity);
1279                 this.chatbubbleentity.owner = this;
1280                 this.chatbubbleentity.exteriormodeltoclient = this;
1281                 setthink(this.chatbubbleentity, ChatBubbleThink);
1282                 this.chatbubbleentity.nextthink = time;
1283                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1284                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1285                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1286                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1287                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1288                 //this.chatbubbleentity.model = "";
1289                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1290         }
1291 }
1292
1293
1294 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1295 // added to the model skins
1296 /*void UpdateColorModHack()
1297 {
1298         float c;
1299         c = this.clientcolors & 15;
1300         // LordHavoc: only bothering to support white, green, red, yellow, blue
1301              if (!teamplay) this.colormod = '0 0 0';
1302         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1303         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1304         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1305         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1306         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1307         else this.colormod = '1 1 1';
1308 }*/
1309
1310 void respawn(entity this)
1311 {
1312         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1313         {
1314                 this.solid = SOLID_NOT;
1315                 this.takedamage = DAMAGE_NO;
1316                 set_movetype(this, MOVETYPE_FLY);
1317                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1318                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1319                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1320                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1321                 if(autocvar_g_respawn_ghosts_maxtime)
1322                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1323         }
1324
1325         CopyBody(this, 1);
1326
1327         this.effects |= EF_NODRAW; // prevent another CopyBody
1328         PutClientInServer(this);
1329 }
1330
1331 ERASEABLE
1332 void PrintToChat(entity client, string text)
1333 {
1334         text = strcat("\{1}^7", text, "\n");
1335         sprint(client, text);
1336 }
1337
1338 ERASEABLE
1339 void DebugPrintToChat(entity client, string text)
1340 {
1341         if (autocvar_developer > 0)
1342         {
1343                 PrintToChat(client, text);
1344         }
1345 }
1346
1347 ERASEABLE
1348 void PrintToChatAll(string text)
1349 {
1350         text = strcat("\{1}^7", text, "\n");
1351         bprint(text);
1352 }
1353
1354 ERASEABLE
1355 void DebugPrintToChatAll(string text)
1356 {
1357         if (autocvar_developer > 0)
1358         {
1359                 PrintToChatAll(text);
1360         }
1361 }
1362
1363 ERASEABLE
1364 void PrintToChatTeam(int team_num, string text)
1365 {
1366         text = strcat("\{1}^7", text, "\n");
1367         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1368         {
1369                 if (it.team == team_num)
1370                 {
1371                         sprint(it, text);
1372                 }
1373         });
1374 }
1375
1376 ERASEABLE
1377 void DebugPrintToChatTeam(int team_num, string text)
1378 {
1379         if (autocvar_developer > 0)
1380         {
1381                 PrintToChatTeam(team_num, text);
1382         }
1383 }
1384
1385 void play_countdown(entity this, float finished, Sound samp)
1386 {
1387         TC(Sound, samp);
1388         if(IS_REAL_CLIENT(this))
1389                 if(floor(finished - time - frametime) != floor(finished - time))
1390                         if(finished - time < 6)
1391                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1392 }
1393
1394 void player_powerups(entity this)
1395 {
1396         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1397         int items_prev = this.items;
1398
1399         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1400                 this.modelflags |= MF_ROCKET;
1401         else
1402                 this.modelflags &= ~MF_ROCKET;
1403
1404         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1405
1406         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1407                 return;
1408
1409         Fire_ApplyDamage(this);
1410         Fire_ApplyEffect(this);
1411
1412         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1413         {
1414                 if (this.items & ITEM_Strength.m_itemid)
1415                 {
1416                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1417                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1418                         if (time > this.strength_finished)
1419                         {
1420                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1421                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1422                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1423                         }
1424                 }
1425                 else
1426                 {
1427                         if (time < this.strength_finished)
1428                         {
1429                                 this.items = this.items | ITEM_Strength.m_itemid;
1430                                 if(!g_cts)
1431                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1432                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1433                         }
1434                 }
1435                 if (this.items & ITEM_Shield.m_itemid)
1436                 {
1437                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1438                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1439                         if (time > this.invincible_finished)
1440                         {
1441                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1442                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1443                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1444                         }
1445                 }
1446                 else
1447                 {
1448                         if (time < this.invincible_finished)
1449                         {
1450                                 this.items = this.items | ITEM_Shield.m_itemid;
1451                                 if(!g_cts)
1452                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1453                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1454                         }
1455                 }
1456                 if (this.items & IT_SUPERWEAPON)
1457                 {
1458                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1459                         {
1460                                 this.superweapons_finished = 0;
1461                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1462                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1463                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1464                         }
1465                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1466                         {
1467                                 // don't let them run out
1468                         }
1469                         else
1470                         {
1471                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1472                                 if (time > this.superweapons_finished)
1473                                 {
1474                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1475                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1476                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1477                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1478                                 }
1479                         }
1480                 }
1481                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1482                 {
1483                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1484                         {
1485                                 this.items = this.items | IT_SUPERWEAPON;
1486                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1487                                 {
1488                                         if(!g_cts)
1489                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1490                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1491                                 }
1492                         }
1493                         else
1494                         {
1495                                 this.superweapons_finished = 0;
1496                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1497                         }
1498                 }
1499                 else
1500                 {
1501                         this.superweapons_finished = 0;
1502                 }
1503         }
1504
1505         if(autocvar_g_nodepthtestplayers)
1506                 this.effects = this.effects | EF_NODEPTHTEST;
1507
1508         if(autocvar_g_fullbrightplayers)
1509                 this.effects = this.effects | EF_FULLBRIGHT;
1510
1511         if (time >= game_starttime)
1512         if (time < this.spawnshieldtime)
1513                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1514
1515         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1516 }
1517
1518 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1519 {
1520         if(current > stable)
1521                 return current;
1522         else if(current > stable - 0.25) // when close enough, "snap"
1523                 return stable;
1524         else
1525                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1526 }
1527
1528 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1529 {
1530         if(current < stable)
1531                 return current;
1532         else if(current < stable + 0.25) // when close enough, "snap"
1533                 return stable;
1534         else
1535                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1536 }
1537
1538 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1539 {
1540         if(current > rotstable)
1541         {
1542                 if(rotframetime > 0)
1543                 {
1544                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1545                         current = max(rotstable, current - rotlinear * rotframetime);
1546                 }
1547         }
1548         else if(current < regenstable)
1549         {
1550                 if(regenframetime > 0)
1551                 {
1552                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1553                         current = min(regenstable, current + regenlinear * regenframetime);
1554                 }
1555         }
1556
1557         if(current > limit)
1558                 current = limit;
1559
1560         return current;
1561 }
1562
1563 void player_regen(entity this)
1564 {
1565         float max_mod, regen_mod, rot_mod, limit_mod;
1566         max_mod = regen_mod = rot_mod = limit_mod = 1;
1567
1568         float regen_health = autocvar_g_balance_health_regen;
1569         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1570         float regen_health_rot = autocvar_g_balance_health_rot;
1571         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1572         float regen_health_stable = autocvar_g_balance_health_regenstable;
1573         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1574         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1575                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1576         max_mod = M_ARGV(1, float);
1577         regen_mod = M_ARGV(2, float);
1578         rot_mod = M_ARGV(3, float);
1579         limit_mod = M_ARGV(4, float);
1580         regen_health = M_ARGV(5, float);
1581         regen_health_linear = M_ARGV(6, float);
1582         regen_health_rot = M_ARGV(7, float);
1583         regen_health_rotlinear = M_ARGV(8, float);
1584         regen_health_stable = M_ARGV(9, float);
1585         regen_health_rotstable = M_ARGV(10, float);
1586
1587         if(!mutator_returnvalue)
1588         if(!STAT(FROZEN, this))
1589         {
1590                 float mina, maxa, limith, limita;
1591                 maxa = autocvar_g_balance_armor_rotstable;
1592                 mina = autocvar_g_balance_armor_regenstable;
1593                 limith = GetResourceLimit(this, RES_HEALTH);
1594                 limita = GetResourceLimit(this, RES_ARMOR);
1595
1596                 regen_health_rotstable = regen_health_rotstable * max_mod;
1597                 regen_health_stable = regen_health_stable * max_mod;
1598                 limith = limith * limit_mod;
1599                 limita = limita * limit_mod;
1600
1601                 SetResource(this, RES_ARMOR, CalcRotRegen(GetResource(this, RES_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1602                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1603                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1604                 SetResource(this, RES_HEALTH, CalcRotRegen(GetResource(this, RES_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1605                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1606                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1607         }
1608
1609         // if player rotted to death...  die!
1610         // check this outside above checks, as player may still be able to rot to death
1611         if(GetResource(this, RES_HEALTH) < 1)
1612         {
1613                 if(this.vehicle)
1614                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1615                 if(this.event_damage)
1616                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1617         }
1618
1619         if (!(this.items & IT_UNLIMITED_AMMO))
1620         {
1621                 float minf, maxf, limitf;
1622
1623                 maxf = autocvar_g_balance_fuel_rotstable;
1624                 minf = autocvar_g_balance_fuel_regenstable;
1625                 limitf = GetResourceLimit(this, RES_FUEL);
1626
1627                 SetResource(this, RES_FUEL, CalcRotRegen(GetResource(this, RES_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1628                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1629                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1630         }
1631 }
1632
1633 bool zoomstate_set;
1634 void SetZoomState(entity this, float newzoom)
1635 {
1636         if(newzoom != CS(this).zoomstate)
1637         {
1638                 CS(this).zoomstate = newzoom;
1639                 ClientData_Touch(this);
1640         }
1641         zoomstate_set = true;
1642 }
1643
1644 void GetPressedKeys(entity this)
1645 {
1646         MUTATOR_CALLHOOK(GetPressedKeys, this);
1647         int keys = STAT(PRESSED_KEYS, this);
1648         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1649         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1650         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1651         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1652
1653         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1654         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1655         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1656         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1657         CS(this).pressedkeys = keys; // store for other users
1658
1659         STAT(PRESSED_KEYS, this) = keys;
1660 }
1661
1662 /*
1663 ======================
1664 spectate mode routines
1665 ======================
1666 */
1667
1668 void SpectateCopy(entity this, entity spectatee)
1669 {
1670         TC(Client, this); TC(Client, spectatee);
1671
1672         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1673         PS(this) = PS(spectatee);
1674         this.armortype = spectatee.armortype;
1675         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1676         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1677         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1678         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1679         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1680         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1681         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1682         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1683         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1684         CS(this).impulse = 0;
1685         this.disableclientprediction = 1; // no need to run prediction on a spectator
1686         this.items = spectatee.items;
1687         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1688         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1689         this.strength_finished = spectatee.strength_finished;
1690         this.invincible_finished = spectatee.invincible_finished;
1691         this.superweapons_finished = spectatee.superweapons_finished;
1692         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1693         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1694         this.punchangle = spectatee.punchangle;
1695         this.view_ofs = spectatee.view_ofs;
1696         this.velocity = spectatee.velocity;
1697         this.dmg_take = spectatee.dmg_take;
1698         this.dmg_save = spectatee.dmg_save;
1699         this.dmg_inflictor = spectatee.dmg_inflictor;
1700         this.v_angle = spectatee.v_angle;
1701         this.angles = spectatee.v_angle;
1702         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1703         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1704         this.viewloc = spectatee.viewloc;
1705         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1706                 this.fixangle = true;
1707         setorigin(this, spectatee.origin);
1708         setsize(this, spectatee.mins, spectatee.maxs);
1709         SetZoomState(this, CS(spectatee).zoomstate);
1710
1711     anticheat_spectatecopy(this, spectatee);
1712         STAT(HUD, this) = STAT(HUD, spectatee);
1713         if(spectatee.vehicle)
1714     {
1715         this.angles = spectatee.v_angle;
1716
1717         //this.fixangle = false;
1718         //this.velocity = spectatee.vehicle.velocity;
1719         this.vehicle_health = spectatee.vehicle_health;
1720         this.vehicle_shield = spectatee.vehicle_shield;
1721         this.vehicle_energy = spectatee.vehicle_energy;
1722         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1723         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1724         this.vehicle_reload1 = spectatee.vehicle_reload1;
1725         this.vehicle_reload2 = spectatee.vehicle_reload2;
1726
1727         //msg_entity = this;
1728
1729        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1730             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1731            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1732            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1733
1734         //WriteByte (MSG_ONE, SVC_SETVIEW);
1735         //    WriteEntity(MSG_ONE, this);
1736         //makevectors(spectatee.v_angle);
1737         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1738     }
1739 }
1740
1741 bool SpectateUpdate(entity this)
1742 {
1743         if(!this.enemy)
1744                 return false;
1745
1746         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1747         {
1748                 SetSpectatee(this, NULL);
1749                 return false;
1750         }
1751
1752         SpectateCopy(this, this.enemy);
1753
1754         return true;
1755 }
1756
1757 bool SpectateSet(entity this)
1758 {
1759         if(!IS_PLAYER(this.enemy))
1760                 return false;
1761
1762         ClientData_Touch(this.enemy);
1763
1764         msg_entity = this;
1765         WriteByte(MSG_ONE, SVC_SETVIEW);
1766         WriteEntity(MSG_ONE, this.enemy);
1767         set_movetype(this, MOVETYPE_NONE);
1768         accuracy_resend(this);
1769
1770         if(!SpectateUpdate(this))
1771                 PutObserverInServer(this);
1772
1773         return true;
1774 }
1775
1776 void SetSpectatee_status(entity this, int spectatee_num)
1777 {
1778         int oldspectatee_status = CS(this).spectatee_status;
1779         CS(this).spectatee_status = spectatee_num;
1780
1781         if (CS(this).spectatee_status != oldspectatee_status)
1782         {
1783                 ClientData_Touch(this);
1784                 if (g_race || g_cts) race_InitSpectator();
1785         }
1786 }
1787
1788 void SetSpectatee(entity this, entity spectatee)
1789 {
1790         if(IS_BOT_CLIENT(this))
1791                 return; // bots abuse .enemy, this code is useless to them
1792
1793         entity old_spectatee = this.enemy;
1794
1795         this.enemy = spectatee;
1796
1797         // WEAPONTODO
1798         // these are required to fix the spectator bug with arc
1799         if(old_spectatee)
1800         {
1801                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1802                 {
1803                         .entity weaponentity = weaponentities[slot];
1804                         if(old_spectatee.(weaponentity).arc_beam)
1805                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1806                 }
1807         }
1808         if(this.enemy)
1809         {
1810                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1811                 {
1812                         .entity weaponentity = weaponentities[slot];
1813                         if(this.enemy.(weaponentity).arc_beam)
1814                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1815                 }
1816         }
1817
1818         if (this.enemy)
1819                 SetSpectatee_status(this, etof(this.enemy));
1820
1821         // needed to update spectator list
1822         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1823 }
1824
1825 bool Spectate(entity this, entity pl)
1826 {
1827         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1828                 return false;
1829         pl = M_ARGV(1, entity);
1830
1831         SetSpectatee(this, pl);
1832         return SpectateSet(this);
1833 }
1834
1835 bool SpectateNext(entity this)
1836 {
1837         entity ent = find(this.enemy, classname, STR_PLAYER);
1838
1839         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1840                 ent = M_ARGV(1, entity);
1841         else if (!ent)
1842                 ent = find(ent, classname, STR_PLAYER);
1843
1844         if(ent) { SetSpectatee(this, ent); }
1845
1846         return SpectateSet(this);
1847 }
1848
1849 bool SpectatePrev(entity this)
1850 {
1851         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1852         entity ent = findchain(classname, STR_PLAYER);
1853         if (!ent) // no player
1854                 return false;
1855
1856         entity first = ent;
1857         // skip players until current spectated player
1858         if(this.enemy)
1859         while(ent && ent != this.enemy)
1860                 ent = ent.chain;
1861
1862         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1863         {
1864                 case MUT_SPECPREV_FOUND:
1865                     ent = M_ARGV(1, entity);
1866                     break;
1867                 case MUT_SPECPREV_RETURN:
1868                     return true;
1869                 case MUT_SPECPREV_CONTINUE:
1870                 default:
1871                 {
1872                         if(ent.chain)
1873                                 ent = ent.chain;
1874                         else
1875                                 ent = first;
1876                         break;
1877                 }
1878         }
1879
1880         SetSpectatee(this, ent);
1881         return SpectateSet(this);
1882 }
1883
1884 /*
1885 =============
1886 ShowRespawnCountdown()
1887
1888 Update a respawn countdown display.
1889 =============
1890 */
1891 void ShowRespawnCountdown(entity this)
1892 {
1893         float number;
1894         if(!IS_DEAD(this)) // just respawned?
1895                 return;
1896         else
1897         {
1898                 number = ceil(this.respawn_time - time);
1899                 if(number <= 0)
1900                         return;
1901                 if(number <= this.respawn_countdown)
1902                 {
1903                         this.respawn_countdown = number - 1;
1904                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1905                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1906                 }
1907         }
1908 }
1909
1910 .bool team_selected;
1911 bool ShowTeamSelection(entity this)
1912 {
1913         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1914                 return false;
1915         stuffcmd(this, "menu_showteamselect\n");
1916         return true;
1917 }
1918 void Join(entity this)
1919 {
1920         TRANSMUTE(Player, this);
1921
1922         if(!this.team_selected)
1923         if(autocvar_g_campaign || autocvar_g_balance_teams)
1924                 TeamBalance_JoinBestTeam(this);
1925
1926         if(autocvar_g_campaign)
1927                 campaign_bots_may_start = true;
1928
1929         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1930
1931         PutClientInServer(this);
1932
1933         if(IS_PLAYER(this))
1934         if(teamplay && this.team != -1)
1935         {
1936         }
1937         else
1938                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1939         this.team_selected = false;
1940 }
1941
1942 int GetPlayerLimit()
1943 {
1944         int player_limit = autocvar_g_maxplayers;
1945         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1946         player_limit = M_ARGV(0, int);
1947         return player_limit;
1948 }
1949
1950 /**
1951  * Determines whether the player is allowed to join. This depends on cvar
1952  * g_maxplayers, if it isn't used this function always return true, otherwise
1953  * it checks whether the number of currently playing players exceeds g_maxplayers.
1954  * @return int number of free slots for players, 0 if none
1955  */
1956 int nJoinAllowed(entity this, entity ignore)
1957 {
1958         if(!ignore)
1959         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1960         // so report 0 free slots if restricted
1961         {
1962                 if(autocvar_g_forced_team_otherwise == "spectate")
1963                         return 0;
1964                 if(autocvar_g_forced_team_otherwise == "spectator")
1965                         return 0;
1966         }
1967
1968         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1969                 return 0; // forced spectators can never join
1970
1971         // TODO simplify this
1972         int totalClients = 0;
1973         int currentlyPlaying = 0;
1974         FOREACH_CLIENT(true, {
1975                 if(it != ignore)
1976                         ++totalClients;
1977                 if(IS_REAL_CLIENT(it))
1978                 if(IS_PLAYER(it) || it.caplayer)
1979                         ++currentlyPlaying;
1980         });
1981
1982         int player_limit = GetPlayerLimit();
1983
1984         float free_slots = 0;
1985         if (!player_limit)
1986                 free_slots = maxclients - totalClients;
1987         else if(currentlyPlaying < player_limit)
1988                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
1989
1990         static float join_prevent_msg_time = 0;
1991         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1992         {
1993                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1994                 join_prevent_msg_time = time + 3;
1995         }
1996
1997         return free_slots;
1998 }
1999
2000 /**
2001  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2002  * g_maxplayers_spectator_blocktime seconds
2003  */
2004 void checkSpectatorBlock(entity this)
2005 {
2006         if(IS_SPEC(this) || IS_OBSERVER(this))
2007         if(!this.caplayer)
2008         if(IS_REAL_CLIENT(this))
2009         {
2010                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2011                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2012                         dropclient(this);
2013                 }
2014         }
2015 }
2016
2017 void PrintWelcomeMessage(entity this)
2018 {
2019         if(CS(this).motd_actived_time == 0)
2020         {
2021                 if (autocvar_g_campaign) {
2022                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2023                                 CS(this).motd_actived_time = time;
2024                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2025                         }
2026                 } else {
2027                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2028                                 CS(this).motd_actived_time = time;
2029                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2030                         }
2031                 }
2032         }
2033         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2034         {
2035                 if (autocvar_g_campaign) {
2036                         if (PHYS_INPUT_BUTTON_INFO(this))
2037                                 CS(this).motd_actived_time = time;
2038                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2039                                 CS(this).motd_actived_time = 0;
2040                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2041                         }
2042                 } else {
2043                         if (PHYS_INPUT_BUTTON_INFO(this))
2044                                 CS(this).motd_actived_time = time;
2045                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2046                                 CS(this).motd_actived_time = 0;
2047                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2048                         }
2049                 }
2050         }
2051         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2052         {
2053                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2054                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2055                 else if (CS(this).motd_actived_time == -2)
2056                 {
2057                         // instantly hide MOTD
2058                         CS(this).motd_actived_time = 0;
2059                         if (autocvar_g_campaign)
2060                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2061                         else
2062                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2063                 }
2064                 else if (IS_PLAYER(this) || IS_SPEC(this))
2065                 {
2066                         // FIXME occasionally for some reason MOTD never goes away
2067                         // delay MOTD removal a little bit in the hope it fixes this bug
2068                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2069                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2070                         else //if (CS(this).motd_actived_time < -2)
2071                                 CS(this).motd_actived_time++;
2072                 }
2073         }
2074 }
2075
2076 const int MIN_SPEC_TIME = 1;
2077 bool joinAllowed(entity this)
2078 {
2079         if (CS(this).version_mismatch) return false;
2080         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2081         if (!nJoinAllowed(this, this)) return false;
2082         if (teamplay && lockteams) return false;
2083         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2084         if (ShowTeamSelection(this)) return false;
2085         return true;
2086 }
2087
2088 .int items_added;
2089 .string shootfromfixedorigin;
2090 .bool dualwielding_prev;
2091 bool PlayerThink(entity this)
2092 {
2093         if (game_stopped || intermission_running) {
2094                 this.modelflags &= ~MF_ROCKET;
2095                 if(intermission_running)
2096                         IntermissionThink(this);
2097                 return false;
2098         }
2099
2100         if (timeout_status == TIMEOUT_ACTIVE) {
2101         // don't allow the player to turn around while game is paused
2102                 // FIXME turn this into CSQC stuff
2103                 this.v_angle = this.lastV_angle;
2104                 this.angles = this.lastV_angle;
2105                 this.fixangle = true;
2106         }
2107
2108         if (frametime) player_powerups(this);
2109
2110         if (IS_DEAD(this)) {
2111                 if (this.personal && g_race_qualifying) {
2112                         if (time > this.respawn_time) {
2113                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2114                                 respawn(this);
2115                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2116                         }
2117                 } else {
2118                         if (frametime) player_anim(this);
2119
2120                         if (this.respawn_flags & RESPAWN_DENY)
2121                         {
2122                                 STAT(RESPAWN_TIME, this) = 0;
2123                                 return false;
2124                         }
2125
2126                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2127
2128                         switch(this.deadflag)
2129                         {
2130                                 case DEAD_DYING:
2131                                 {
2132                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2133                                                 this.deadflag = DEAD_RESPAWNING;
2134                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2135                                                 this.deadflag = DEAD_DEAD;
2136                                         break;
2137                                 }
2138                                 case DEAD_DEAD:
2139                                 {
2140                                         if (button_pressed)
2141                                                 this.deadflag = DEAD_RESPAWNABLE;
2142                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2143                                                 this.deadflag = DEAD_RESPAWNING;
2144                                         break;
2145                                 }
2146                                 case DEAD_RESPAWNABLE:
2147                                 {
2148                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2149                                                 this.deadflag = DEAD_RESPAWNING;
2150                                         break;
2151                                 }
2152                                 case DEAD_RESPAWNING:
2153                                 {
2154                                         if (time > this.respawn_time)
2155                                         {
2156                                                 this.respawn_time = time + 1; // only retry once a second
2157                                                 this.respawn_time_max = this.respawn_time;
2158                                                 respawn(this);
2159                                         }
2160                                         break;
2161                                 }
2162                         }
2163
2164                         ShowRespawnCountdown(this);
2165
2166                         if (this.respawn_flags & RESPAWN_SILENT)
2167                                 STAT(RESPAWN_TIME, this) = 0;
2168                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2169                         {
2170                                 if (time < this.respawn_time)
2171                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2172                                 else if (this.deadflag != DEAD_RESPAWNING)
2173                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2174                         }
2175                         else
2176                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2177                 }
2178
2179                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2180                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2181                         STAT(RESPAWN_TIME, this) *= -1;
2182
2183                 return false;
2184         }
2185
2186         FixPlayermodel(this);
2187
2188         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2189                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2190                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2191         }
2192
2193         // reset gun alignment when dual wielding status changes
2194         // to ensure guns are always aligned right and left
2195         bool dualwielding = W_DualWielding(this);
2196         if(this.dualwielding_prev != dualwielding)
2197         {
2198                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2199                 this.dualwielding_prev = dualwielding;
2200         }
2201
2202         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2203         //if(frametime)
2204         {
2205                 this.items &= ~this.items_added;
2206
2207                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2208                 {
2209                         .entity weaponentity = weaponentities[slot];
2210                         if(WEP_CVAR(vortex, charge_always))
2211                                 W_Vortex_Charge(this, weaponentity, frametime);
2212                         W_WeaponFrame(this, weaponentity);
2213                 }
2214
2215                 this.items_added = 0;
2216                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResource(this, RES_FUEL) >= 0.01))
2217             this.items_added |= IT_FUEL;
2218
2219                 this.items |= this.items_added;
2220         }
2221
2222         if (frametime)
2223         {
2224                 // WEAPONTODO: Add a weapon request for this
2225                 // rot vortex charge to the charge limit
2226                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2227                 {
2228                         .entity weaponentity = weaponentities[slot];
2229                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2230                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2231                 }
2232
2233                 player_regen(this);
2234                 player_anim(this);
2235                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2236         }
2237
2238         secrets_setstatus(this);
2239         monsters_setstatus(this);
2240
2241         return true;
2242 }
2243
2244 .bool would_spectate;
2245 void ObserverThink(entity this)
2246 {
2247         if ( CS(this).impulse )
2248         {
2249                 MinigameImpulse(this, CS(this).impulse);
2250                 CS(this).impulse = 0;
2251         }
2252
2253         if (this.flags & FL_JUMPRELEASED) {
2254                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2255                         this.flags &= ~FL_JUMPRELEASED;
2256                         this.flags |= FL_SPAWNING;
2257                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2258                         this.flags &= ~FL_JUMPRELEASED;
2259                         if(SpectateNext(this)) {
2260                                 TRANSMUTE(Spectator, this);
2261                         }
2262                 } else {
2263                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2264                         set_movetype(this, preferred_movetype);
2265                 }
2266         } else {
2267                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2268                         this.flags |= FL_JUMPRELEASED;
2269                         if(this.flags & FL_SPAWNING)
2270                         {
2271                                 this.flags &= ~FL_SPAWNING;
2272                                 Join(this);
2273                                 return;
2274                         }
2275                 }
2276         }
2277 }
2278
2279 void SpectatorThink(entity this)
2280 {
2281         if ( CS(this).impulse )
2282         {
2283                 if(MinigameImpulse(this, CS(this).impulse))
2284                         CS(this).impulse = 0;
2285
2286                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2287                 {
2288                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2289                         CS(this).impulse = 0;
2290                         return;
2291                 }
2292         }
2293
2294         if (this.flags & FL_JUMPRELEASED) {
2295                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2296                         this.flags &= ~FL_JUMPRELEASED;
2297                         this.flags |= FL_SPAWNING;
2298                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2299                         this.flags &= ~FL_JUMPRELEASED;
2300                         if(SpectateNext(this)) {
2301                                 TRANSMUTE(Spectator, this);
2302                         } else {
2303                                 TRANSMUTE(Observer, this);
2304                                 PutClientInServer(this);
2305                         }
2306                         CS(this).impulse = 0;
2307                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2308                         this.flags &= ~FL_JUMPRELEASED;
2309                         if(SpectatePrev(this)) {
2310                                 TRANSMUTE(Spectator, this);
2311                         } else {
2312                                 TRANSMUTE(Observer, this);
2313                                 PutClientInServer(this);
2314                         }
2315                         CS(this).impulse = 0;
2316                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2317                         this.would_spectate = false;
2318                         this.flags &= ~FL_JUMPRELEASED;
2319                         TRANSMUTE(Observer, this);
2320                         PutClientInServer(this);
2321                 } else {
2322                         if(!SpectateUpdate(this))
2323                         {
2324                                 if(!SpectateNext(this))
2325                                 {
2326                                         PutObserverInServer(this);
2327                                         this.would_spectate = true;
2328                                 }
2329                         }
2330                 }
2331         } else {
2332                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2333                         this.flags |= FL_JUMPRELEASED;
2334                         if(this.flags & FL_SPAWNING)
2335                         {
2336                                 this.flags &= ~FL_SPAWNING;
2337                                 Join(this);
2338                                 return;
2339                         }
2340                 }
2341                 if(!SpectateUpdate(this))
2342                         PutObserverInServer(this);
2343         }
2344
2345         this.flags |= FL_CLIENT | FL_NOTARGET;
2346 }
2347
2348 void PlayerUseKey(entity this)
2349 {
2350         if (!IS_PLAYER(this))
2351                 return;
2352
2353         if(this.vehicle)
2354         {
2355                 if(!game_stopped)
2356                 {
2357                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2358                         return;
2359                 }
2360         }
2361         else if(autocvar_g_vehicles_enter)
2362         {
2363                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2364                 {
2365                         entity head, closest_target = NULL;
2366                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2367
2368                         while(head) // find the closest acceptable target to enter
2369                         {
2370                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2371                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2372                                 {
2373                                         if(closest_target)
2374                                         {
2375                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2376                                                 { closest_target = head; }
2377                                         }
2378                                         else { closest_target = head; }
2379                                 }
2380
2381                                 head = head.chain;
2382                         }
2383
2384                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2385                 }
2386         }
2387
2388         // a use key was pressed; call handlers
2389         MUTATOR_CALLHOOK(PlayerUseKey, this);
2390 }
2391
2392
2393 /*
2394 =============
2395 PlayerPreThink
2396
2397 Called every frame for each client before the physics are run
2398 =============
2399 */
2400 .float last_vehiclecheck;
2401 void PlayerPreThink (entity this)
2402 {
2403         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2404         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2405
2406         WarpZone_PlayerPhysics_FixVAngle(this);
2407
2408         if (frametime) {
2409                 // physics frames: update anticheat stuff
2410                 anticheat_prethink(this);
2411         }
2412
2413         if (blockSpectators && frametime) {
2414                 // WORKAROUND: only use dropclient in server frames (frametime set).
2415                 // Never use it in cl_movement frames (frametime zero).
2416                 checkSpectatorBlock(this);
2417         }
2418
2419         zoomstate_set = false;
2420
2421         // Check for nameless players
2422         if (this.netname == "" || this.netname != CS(this).netname_previous)
2423         {
2424                 bool assume_unchanged = (CS(this).netname_previous == "");
2425                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2426                 {
2427                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2428                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2429                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2430                         assume_unchanged = false;
2431                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2432                 }
2433                 if (isInvisibleString(this.netname))
2434                 {
2435                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2436                         sprint(this, "Warning: invisible names are not allowed.\n");
2437                         assume_unchanged = false;
2438                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2439                 }
2440                 if (!assume_unchanged && autocvar_sv_eventlog)
2441                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2442                 strcpy(CS(this).netname_previous, this.netname);
2443         }
2444
2445         // version nagging
2446         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2447         CS(this).version_nagtime = 0;
2448         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2449             // git client
2450         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2451             // git server
2452             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2453         } else {
2454             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2455             if (r < 0) { // old client
2456                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2457             } else if (r > 0) { // old server
2458                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2459             }
2460         }
2461     }
2462
2463         // GOD MODE info
2464         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2465         {
2466                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2467                 this.max_armorvalue = 0;
2468         }
2469
2470         if (frametime && IS_PLAYER(this))
2471         {
2472                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2473                 {
2474                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2475                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2476                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2477
2478                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2479                                 Unfreeze(this, false);
2480                 }
2481                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2482                 {
2483                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2484                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2485
2486                         if (GetResource(this, RES_HEALTH) < 1)
2487                         {
2488                                 if (this.vehicle)
2489                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2490                                 if(this.event_damage)
2491                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2492                         }
2493                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2494                                 Unfreeze(this, false);
2495                 }
2496         }
2497
2498         MUTATOR_CALLHOOK(PlayerPreThink, this);
2499
2500         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2501         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2502         {
2503                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2504                 {
2505                         if(!it.owner)
2506                         {
2507                                 if(!it.team || SAME_TEAM(this, it))
2508                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2509                                 else if(autocvar_g_vehicles_steal)
2510                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2511                         }
2512                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2513                         {
2514                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2515                         }
2516                 });
2517
2518                 this.last_vehiclecheck = time + 1;
2519         }
2520
2521         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2522         {
2523                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2524                         PlayerUseKey(this);
2525                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2526         }
2527
2528         if (IS_REAL_CLIENT(this))
2529                 PrintWelcomeMessage(this);
2530
2531         if (IS_PLAYER(this)) {
2532                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2533                         error("Client can't be spawned as player on connection!");
2534                 if(!PlayerThink(this))
2535                         return;
2536         }
2537         else if (game_stopped || intermission_running) {
2538                 if(intermission_running)
2539                         IntermissionThink(this);
2540                 return;
2541         }
2542         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2543         {
2544                 CS(this).autojoin_checked = true;
2545                 // don't do this in ClientConnect
2546                 // many things can go wrong if a client is spawned as player on connection
2547                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2548                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2549                                 && (!teamplay || autocvar_g_balance_teams)))
2550                 {
2551                         campaign_bots_may_start = true;
2552                         Join(this);
2553                         return;
2554                 }
2555         }
2556         else if (IS_OBSERVER(this)) {
2557                 ObserverThink(this);
2558         }
2559         else if (IS_SPEC(this)) {
2560                 SpectatorThink(this);
2561         }
2562
2563         // WEAPONTODO: Add weapon request for this
2564         if (!zoomstate_set) {
2565                 bool wep_zoomed = false;
2566                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2567                 {
2568                         .entity weaponentity = weaponentities[slot];
2569                         Weapon thiswep = this.(weaponentity).m_weapon;
2570                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2571                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2572                 }
2573                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2574     }
2575
2576         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2577         {
2578                 CS(this).teamkill_soundtime = 0;
2579
2580                 entity e = CS(this).teamkill_soundsource;
2581                 entity oldpusher = e.pusher;
2582                 e.pusher = this;
2583                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2584                 e.pusher = oldpusher;
2585         }
2586
2587         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2588                 CS(this).taunt_soundtime = 0;
2589                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2590         }
2591
2592         target_voicescript_next(this);
2593
2594         // WEAPONTODO: Move into weaponsystem somehow
2595         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2596         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2597         {
2598                 .entity weaponentity = weaponentities[slot];
2599                 if(this.(weaponentity).m_weapon == WEP_Null)
2600                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2601         }
2602 }
2603
2604 void DrownPlayer(entity this)
2605 {
2606         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2607                 return;
2608
2609         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2610         {
2611                 if(this.air_finished < time)
2612                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2613                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2614         }
2615         else if (this.air_finished < time)
2616         {       // drown!
2617                 if (this.pain_finished < time)
2618                 {
2619                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2620                         this.pain_finished = time + 0.5;
2621                 }
2622         }
2623 }
2624
2625 .bool move_qcphysics;
2626
2627 void Player_Physics(entity this)
2628 {
2629         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2630
2631         if(!this.move_qcphysics)
2632                 return;
2633
2634         if(!frametime && !CS(this).pm_frametime)
2635                 return;
2636
2637         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2638
2639         CS(this).pm_frametime = 0;
2640 }
2641
2642 /*
2643 =============
2644 PlayerPostThink
2645
2646 Called every frame for each client after the physics are run
2647 =============
2648 */
2649 void PlayerPostThink (entity this)
2650 {
2651         Player_Physics(this);
2652
2653         if (sv_maxidle > 0)
2654         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2655         if (IS_REAL_CLIENT(this))
2656         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2657         {
2658                 int totalClients = 0;
2659                 if(sv_maxidle_slots > 0)
2660                 {
2661                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2662                         {
2663                                 ++totalClients;
2664                         });
2665                 }
2666
2667                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2668                 { /* do nothing */ }
2669                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2670                 {
2671                         if (CS(this).idlekick_lasttimeleft)
2672                         {
2673                                 CS(this).idlekick_lasttimeleft = 0;
2674                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2675                         }
2676                 }
2677                 else
2678                 {
2679                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2680                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2681                                 if (!CS(this).idlekick_lasttimeleft)
2682                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2683                         }
2684                         if (timeleft <= 0) {
2685                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2686                                 dropclient(this);
2687                                 return;
2688                         }
2689                         else if (timeleft <= 10) {
2690                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2691                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2692                 }
2693                                 CS(this).idlekick_lasttimeleft = timeleft;
2694                         }
2695                 }
2696         }
2697
2698         CheatFrame(this);
2699
2700         if (game_stopped)
2701         {
2702                 this.solid = SOLID_NOT;
2703                 this.takedamage = DAMAGE_NO;
2704                 set_movetype(this, MOVETYPE_NONE);
2705         }
2706
2707         if (IS_PLAYER(this)) {
2708                 if(this.death_time == time && IS_DEAD(this))
2709                 {
2710                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2711                         // once all the damage events of this frame have been processed with normal size
2712                         this.maxs.z = 5;
2713                         setsize(this, this.mins, this.maxs);
2714                 }
2715                 DrownPlayer(this);
2716                 UpdateChatBubble(this);
2717                 if (CS(this).impulse) ImpulseCommands(this);
2718                 if (game_stopped)
2719                 {
2720                         CSQCMODEL_AUTOUPDATE(this);
2721                         return;
2722                 }
2723                 GetPressedKeys(this);
2724         }
2725
2726         if (this.waypointsprite_attachedforcarrier) {
2727                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2728                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2729         }
2730
2731         CSQCMODEL_AUTOUPDATE(this);
2732 }
2733
2734 /**
2735  * message "": do not say, just test flood control
2736  * return value:
2737  *   1 = accept
2738  *   0 = reject
2739  *  -1 = fake accept
2740  */
2741 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2742 {
2743         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2744                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2745
2746         if (source)
2747                 msgin = formatmessage(source, msgin);
2748
2749         string colorstr;
2750         if (!(IS_PLAYER(source) || source.caplayer))
2751                 colorstr = "^0"; // black for spectators
2752         else if(teamplay)
2753                 colorstr = Team_ColorCode(source.team);
2754         else
2755         {
2756                 colorstr = "";
2757                 teamsay = false;
2758         }
2759
2760         if (!source) {
2761                 colorstr = "";
2762                 teamsay = false;
2763         }
2764
2765         if(msgin != "")
2766                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2767
2768         /*
2769          * using bprint solves this... me stupid
2770         // how can we prevent the message from appearing in a listen server?
2771         // for now, just give "say" back and only handle say_team
2772         if(!teamsay)
2773         {
2774                 clientcommand(source, strcat("say ", msgin));
2775                 return;
2776         }
2777         */
2778
2779         string namestr = "";
2780         if (source)
2781                 namestr = playername(source, autocvar_g_chat_teamcolors);
2782
2783         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2784
2785         string msgstr = "", cmsgstr = "";
2786         string privatemsgprefix = string_null;
2787         int privatemsgprefixlen = 0;
2788         if (msgin != "")
2789         {
2790                 bool found_me = false;
2791                 if(strstrofs(msgin, "/me", 0) >= 0)
2792                 {
2793                         string newmsgin = "";
2794                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2795                         FOREACH_WORD(msgin, true,
2796                         {
2797                                 if(strdecolorize(it) == "/me")
2798                                 {
2799                                         found_me = true;
2800                                         newmsgin = cons(newmsgin, newnamestr);
2801                                 }
2802                                 else
2803                                         newmsgin = cons(newmsgin, it);
2804                         });
2805                         msgin = newmsgin;
2806                 }
2807
2808                 if(privatesay)
2809                 {
2810                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2811                         privatemsgprefixlen = strlen(msgstr);
2812                         msgstr = strcat(msgstr, msgin);
2813                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2814                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2815                 }
2816                 else if(teamsay)
2817                 {
2818                         if(found_me)
2819                         {
2820                                 //msgin = strreplace("/me", "", msgin);
2821                                 //msgin = substring(msgin, 3, strlen(msgin));
2822                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2823                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2824                         }
2825                         else
2826                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2827                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2828                 }
2829                 else
2830                 {
2831                         if(found_me)
2832                         {
2833                                 //msgin = strreplace("/me", "", msgin);
2834                                 //msgin = substring(msgin, 3, strlen(msgin));
2835                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2836                                 msgstr = strcat("\{1}^4* ^7", msgin);
2837                         }
2838                         else {
2839                                 msgstr = "\{1}";
2840                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2841                                 msgstr = strcat(msgstr, msgin);
2842                         }
2843                         cmsgstr = "";
2844                 }
2845                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2846         }
2847
2848         string fullmsgstr = msgstr;
2849         string fullcmsgstr = cmsgstr;
2850
2851         // FLOOD CONTROL
2852         int flood = 0;
2853         var .float flood_field = floodcontrol_chat;
2854         if(floodcontrol && source)
2855         {
2856                 float flood_spl;
2857                 float flood_burst;
2858                 float flood_lmax;
2859                 float lines;
2860                 if(privatesay)
2861                 {
2862                         flood_spl = autocvar_g_chat_flood_spl_tell;
2863                         flood_burst = autocvar_g_chat_flood_burst_tell;
2864                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2865                         flood_field = floodcontrol_chattell;
2866                 }
2867                 else if(teamsay)
2868                 {
2869                         flood_spl = autocvar_g_chat_flood_spl_team;
2870                         flood_burst = autocvar_g_chat_flood_burst_team;
2871                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2872                         flood_field = floodcontrol_chatteam;
2873                 }
2874                 else
2875                 {
2876                         flood_spl = autocvar_g_chat_flood_spl;
2877                         flood_burst = autocvar_g_chat_flood_burst;
2878                         flood_lmax = autocvar_g_chat_flood_lmax;
2879                         flood_field = floodcontrol_chat;
2880                 }
2881                 flood_burst = max(0, flood_burst - 1);
2882                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2883
2884                 // do flood control for the default line size
2885                 if(msgstr != "")
2886                 {
2887                         getWrappedLine_remaining = msgstr;
2888                         msgstr = "";
2889                         lines = 0;
2890                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2891                         {
2892                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2893                                 ++lines;
2894                         }
2895                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2896
2897                         if(getWrappedLine_remaining != "")
2898                         {
2899                                 msgstr = strcat(msgstr, "\n");
2900                                 flood = 2;
2901                         }
2902
2903                         if (time >= source.(flood_field))
2904                         {
2905                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2906                         }
2907                         else
2908                         {
2909                                 flood = 1;
2910                                 msgstr = fullmsgstr;
2911                         }
2912                 }
2913                 else
2914                 {
2915                         if (time >= source.(flood_field))
2916                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2917                         else
2918                                 flood = 1;
2919                 }
2920
2921                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2922                         source.(flood_field) = flood = 0;
2923         }
2924
2925         string sourcemsgstr, sourcecmsgstr;
2926         if(flood == 2) // cannot happen for empty msgstr
2927         {
2928                 if(autocvar_g_chat_flood_notify_flooder)
2929                 {
2930                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2931                         sourcecmsgstr = "";
2932                 }
2933                 else
2934                 {
2935                         sourcemsgstr = fullmsgstr;
2936                         sourcecmsgstr = fullcmsgstr;
2937                 }
2938                 cmsgstr = "";
2939         }
2940         else
2941         {
2942                 sourcemsgstr = msgstr;
2943                 sourcecmsgstr = cmsgstr;
2944         }
2945
2946         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2947         {
2948                 if (!game_stopped)
2949                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2950                         teamsay = -1; // spectators
2951         }
2952
2953         if(flood)
2954                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2955
2956         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2957         if(privatesay)
2958                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2959
2960         int ret;
2961         if(source && CS(source).muted)
2962         {
2963                 // always fake the message
2964                 ret = -1;
2965         }
2966         else if(flood == 1)
2967         {
2968                 if (autocvar_g_chat_flood_notify_flooder)
2969                 {
2970                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
2971                         ret = 0;
2972                 }
2973                 else
2974                         ret = -1;
2975         }
2976         else
2977         {
2978                 ret = 1;
2979         }
2980
2981         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2982         {
2983                 if (!game_stopped)
2984                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
2985                         ret = -1; // just hide the message completely
2986         }
2987
2988         MUTATOR_CALLHOOK(ChatMessage, source, ret);
2989         ret = M_ARGV(1, int);
2990
2991         string event_log_msg = "";
2992
2993         if(sourcemsgstr != "" && ret != 0)
2994         {
2995                 if(ret < 0) // faked message, because the player is muted
2996                 {
2997                         sprint(source, sourcemsgstr);
2998                         if(sourcecmsgstr != "" && !privatesay)
2999                                 centerprint(source, sourcecmsgstr);
3000                 }
3001                 else if(privatesay) // private message, between 2 people only
3002                 {
3003                         sprint(source, sourcemsgstr);
3004                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
3005                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
3006                         {
3007                                 sprint(privatesay, msgstr);
3008                                 if(cmsgstr != "")
3009                                         centerprint(privatesay, cmsgstr);
3010                         }
3011                 }
3012                 else if ( teamsay && CS(source).active_minigame )
3013                 {
3014                         sprint(source, sourcemsgstr);
3015                         dedicated_print(msgstr); // send to server console too
3016                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3017                                 sprint(it, msgstr);
3018                         });
3019                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3020
3021                 }
3022                 else if(teamsay > 0) // team message, only sent to team mates
3023                 {
3024                         sprint(source, sourcemsgstr);
3025                         dedicated_print(msgstr); // send to server console too
3026                         if(sourcecmsgstr != "")
3027                                 centerprint(source, sourcecmsgstr);
3028                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3029                                 sprint(it, msgstr);
3030                                 if(cmsgstr != "")
3031                                         centerprint(it, cmsgstr);
3032                         });
3033                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3034                 }
3035                 else if(teamsay < 0) // spectator message, only sent to spectators
3036                 {
3037                         sprint(source, sourcemsgstr);
3038                         dedicated_print(msgstr); // send to server console too
3039                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3040                                 sprint(it, msgstr);
3041                         });
3042                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3043                 }
3044                 else
3045                 {
3046                         if (source) {
3047                                 sprint(source, sourcemsgstr);
3048                                 dedicated_print(msgstr); // send to server console too
3049                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3050                         }
3051                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3052                                 sprint(it, msgstr);
3053                         });
3054                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3055                 }
3056         }
3057
3058         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3059                 GameLogEcho(event_log_msg);
3060         }
3061
3062         return ret;
3063 }
3064
3065 // hack to copy the button fields from the client entity to the Client State
3066 void PM_UpdateButtons(entity this, entity store)
3067 {
3068         if(this.impulse)
3069                 store.impulse = this.impulse;
3070         this.impulse = 0;
3071
3072         bool typing = this.buttonchat || this.button12;
3073
3074         store.button0 = (typing) ? 0 : this.button0;
3075         //button1?!
3076         store.button2 = (typing) ? 0 : this.button2;
3077         store.button3 = (typing) ? 0 : this.button3;
3078         store.button4 = this.button4;
3079         store.button5 = (typing) ? 0 : this.button5;
3080         store.button6 = this.button6;
3081         store.button7 = this.button7;
3082         store.button8 = this.button8;
3083         store.button9 = this.button9;
3084         store.button10 = this.button10;
3085         store.button11 = this.button11;
3086         store.button12 = this.button12;
3087         store.button13 = this.button13;
3088         store.button14 = this.button14;
3089         store.button15 = this.button15;
3090         store.button16 = this.button16;
3091         store.buttonuse = this.buttonuse;
3092         store.buttonchat = this.buttonchat;
3093
3094         store.cursor_active = this.cursor_active;
3095         store.cursor_screen = this.cursor_screen;
3096         store.cursor_trace_start = this.cursor_trace_start;
3097         store.cursor_trace_endpos = this.cursor_trace_endpos;
3098         store.cursor_trace_ent = this.cursor_trace_ent;
3099
3100         store.ping = this.ping;
3101         store.ping_packetloss = this.ping_packetloss;
3102         store.ping_movementloss = this.ping_movementloss;
3103
3104         store.v_angle = this.v_angle;
3105         store.movement = (typing) ? '0 0 0' : this.movement;
3106 }
3107
3108 NET_HANDLE(fpsreport, bool)
3109 {
3110         int fps = ReadShort();
3111         PlayerScore_Set(sender, SP_FPS, fps);
3112         return true;
3113 }