qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/weapons/_all.qh>
   4 #include <common/stats.qh>
   5 #include <server/miscfunctions.qh>
   6 #include <common/effects/all.qh>
   7 #include "anticheat.qh"
   8 #include "impulse.qh"
   9 #include "player.qh"
  10 #include "ipban.qh"
  11 #include "miscfunctions.qh"
  12 #include "portals.qh"
  13 #include "teamplay.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "damage.qh"
  17 #include "handicap.qh"
  18 #include "hook.qh"
  19 #include <server/intermission.qh>
  20 #include "command/common.qh"
  21 #include "command/vote.qh"
  22 #include "clientkill.qh"
  23 #include "cheats.qh"
  24 #include "world.qh"
  25 #include <server/gamelog.qh>
  26 #include "race.qh"
  27 #include <server/main.qh>
  28 #include "antilag.qh"
  29 #include "campaign.qh"
  30 #include "command/common.qh"
  31 #include "scores_rules.qh"
  32 #include "weapons/common.qh"
  33
  34 #include "bot/api.qh"
  35
  36 #include "../common/ent_cs.qh"
  37 #include "../common/wepent.qh"
  38 #include <common/state.qh>
  39
  40 #include "compat/quake3.qh"
  41
  42 #include <common/effects/qc/globalsound.qh>
  43
  44 #include "../common/mapobjects/func/conveyor.qh"
  45 #include <common/mapobjects/func/ladder.qh>
  46 #include "../common/mapobjects/teleporters.qh"
  47 #include "../common/mapobjects/target/spawnpoint.qh"
  48 #include <common/mapobjects/trigger/counter.qh>
  49 #include <common/mapobjects/trigger/swamp.qh>
  50
  51 #include "../common/vehicles/all.qh"
  52
  53 #include "weapons/hitplot.qh"
  54 #include "weapons/selection.qh"
  55 #include "weapons/weaponsystem.qh"
  56
  57 #include "../common/net_notice.qh"
  58 #include "../common/net_linked.qh"
  59 #include "../common/physics/player.qh"
  60
  61 #include <common/vehicles/sv_vehicles.qh>
  62
  63 #include "../common/items/_mod.qh"
  64
  65 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  66
  67 #include "../common/mutators/mutator/waypoints/all.qh"
  68 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  69 #include <common/gamemodes/_mod.qh>
  70
  71 #include "../common/mapobjects/subs.qh"
  72 #include "../common/mapobjects/triggers.qh"
  73 #include "../common/mapobjects/trigger/secret.qh"
  74
  75 #include "../common/minigames/sv_minigames.qh"
  76
  77 #include "../common/items/inventory.qh"
  78
  79 #include "../common/monsters/sv_monsters.qh"
  80
  81 #include "../lib/warpzone/server.qh"
  82
  83 #include <common/mutators/mutator/overkill/oknex.qh>
  84
  85 #include <common/weapons/weapon/vortex.qh>
  86
  87 #define CHAT_NOSPECTATORS() ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
  88
  89 STATIC_METHOD(Client, Add, void(Client this, int _team))
  90 {
  91     ClientConnect(this);
  92     TRANSMUTE(Player, this);
  93     this.frame = 12; // 7
  94     this.team = _team;
  95     PutClientInServer(this);
  96 }
  97
  98 STATIC_METHOD(Client, Remove, void(Client this))
  99 {
 100     TRANSMUTE(Observer, this);
 101     PutClientInServer(this);
 102     ClientDisconnect(this);
 103 }
 104
 105 void send_CSQC_teamnagger() {
 106         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 107 }
 108
 109 int CountSpectators(entity player, entity to)
 110 {
 111         if(!player) { return 0; } // not sure how, but best to be safe
 112
 113         int spec_count = 0;
 114
 115         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 116         {
 117                 spec_count++;
 118         });
 119
 120         return spec_count;
 121 }
 122
 123 void WriteSpectators(entity player, entity to)
 124 {
 125         if(!player) { return; } // not sure how, but best to be safe
 126
 127         int spec_count = 0;
 128         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 129         {
 130                 if(spec_count >= MAX_SPECTATORS)
 131                         break;
 132                 WriteByte(MSG_ENTITY, num_for_edict(it));
 133                 ++spec_count;
 134         });
 135 }
 136
 137 bool ClientData_Send(entity this, entity to, int sf)
 138 {
 139         assert(to == this.owner, return false);
 140
 141         entity e = to;
 142         if (IS_SPEC(e)) e = e.enemy;
 143
 144         sf = 0;
 145         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 146         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 147         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 148         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 149
 150         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 151         WriteByte(MSG_ENTITY, sf);
 152
 153         if (sf & BIT(1))
 154                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 155
 156         if(sf & BIT(4))
 157         {
 158                 float specs = CountSpectators(e, to);
 159                 WriteByte(MSG_ENTITY, specs);
 160                 WriteSpectators(e, to);
 161         }
 162
 163         return true;
 164 }
 165
 166 void ClientData_Attach(entity this)
 167 {
 168         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 169         CS(this).clientdata.drawonlytoclient = this;
 170         CS(this).clientdata.owner = this;
 171 }
 172
 173 void ClientData_Detach(entity this)
 174 {
 175         delete(CS(this).clientdata);
 176         CS(this).clientdata = NULL;
 177 }
 178
 179 void ClientData_Touch(entity e)
 180 {
 181         entity cd = CS(e).clientdata;
 182         if (cd) { cd.SendFlags = 1; }
 183
 184         // make it spectatable
 185         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 186         {
 187                 entity cd = CS(it).clientdata;
 188                 if (cd) { cd.SendFlags = 1; }
 189         });
 190 }
 191
 192
 193 /*
 194 =============
 195 CheckPlayerModel
 196
 197 Checks if the argument string can be a valid playermodel.
 198 Returns a valid one in doubt.
 199 =============
 200 */
 201 string FallbackPlayerModel;
 202 string CheckPlayerModel(string plyermodel) {
 203         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 204         {
 205                 // note: we cannot summon Don Strunzone here, some player may
 206                 // still have the model string set. In case anyone manages how
 207                 // to change a cvar default, we'll have a small leak here.
 208                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 209         }
 210         // only in right path
 211         if( substring(plyermodel,0,14) != "models/player/")
 212                 return FallbackPlayerModel;
 213         // only good file extensions
 214         if(substring(plyermodel,-4,4) != ".zym")
 215         if(substring(plyermodel,-4,4) != ".dpm")
 216         if(substring(plyermodel,-4,4) != ".iqm")
 217         if(substring(plyermodel,-4,4) != ".md3")
 218         if(substring(plyermodel,-4,4) != ".psk")
 219                 return FallbackPlayerModel;
 220         // forbid the LOD models
 221         if(substring(plyermodel, -9,5) == "_lod1")
 222                 return FallbackPlayerModel;
 223         if(substring(plyermodel, -9,5) == "_lod2")
 224                 return FallbackPlayerModel;
 225         if(plyermodel != strtolower(plyermodel))
 226                 return FallbackPlayerModel;
 227         // also, restrict to server models
 228         if(autocvar_sv_servermodelsonly)
 229         {
 230                 if(!fexists(plyermodel))
 231                         return FallbackPlayerModel;
 232         }
 233         return plyermodel;
 234 }
 235
 236 void setplayermodel(entity e, string modelname)
 237 {
 238         precache_model(modelname);
 239         _setmodel(e, modelname);
 240         player_setupanimsformodel(e);
 241         if(!autocvar_g_debug_globalsounds)
 242                 UpdatePlayerSounds(e);
 243 }
 244
 245 /** putting a client as observer in the server */
 246 void PutObserverInServer(entity this)
 247 {
 248         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 249         PlayerState_detach(this);
 250
 251         if (IS_PLAYER(this))
 252         {
 253                 if(GetResource(this, RES_HEALTH) >= 1)
 254                 {
 255                         // despawn effect
 256                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 257                 }
 258
 259                 // was a player, recount votes and ready status
 260                 if(IS_REAL_CLIENT(this))
 261                 {
 262                         if (vote_called) { VoteCount(false); }
 263                         ReadyCount();
 264                 }
 265         }
 266
 267         entity spot = SelectSpawnPoint(this, true);
 268         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 269         this.angles = vec2(spot.angles);
 270         this.fixangle = true;
 271         // offset it so that the spectator spawns higher off the ground, looks better this way
 272         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 273         if (IS_REAL_CLIENT(this))
 274         {
 275                 msg_entity = this;
 276                 WriteByte(MSG_ONE, SVC_SETVIEW);
 277                 WriteEntity(MSG_ONE, this);
 278         }
 279         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 280         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 281         if(!autocvar_g_debug_globalsounds)
 282         {
 283                 // needed for player sounds
 284                 this.model = "";
 285                 FixPlayermodel(this);
 286         }
 287         setmodel(this, MDL_Null);
 288         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 289         this.view_ofs = '0 0 0';
 290
 291         RemoveGrapplingHooks(this);
 292         Portal_ClearAll(this);
 293         Unfreeze(this, false);
 294         SetSpectatee(this, NULL);
 295
 296         if (this.alivetime)
 297         {
 298                 if (!warmup_stage)
 299                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 300                 this.alivetime = 0;
 301         }
 302
 303         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 304
 305         WaypointSprite_PlayerDead(this);
 306
 307         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 308                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 309
 310         accuracy_resend(this);
 311
 312         CS(this).spectatortime = time;
 313         if(this.bot_attack)
 314                 IL_REMOVE(g_bot_targets, this);
 315         this.bot_attack = false;
 316         if(this.monster_attack)
 317                 IL_REMOVE(g_monster_targets, this);
 318         this.monster_attack = false;
 319         STAT(HUD, this) = HUD_NORMAL;
 320         TRANSMUTE(Observer, this);
 321         this.iscreature = false;
 322         this.teleportable = TELEPORT_SIMPLE;
 323         if(this.damagedbycontents)
 324                 IL_REMOVE(g_damagedbycontents, this);
 325         this.damagedbycontents = false;
 326         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 327         SetSpectatee_status(this, etof(this));
 328         this.takedamage = DAMAGE_NO;
 329         this.solid = SOLID_NOT;
 330         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 331         this.flags = FL_CLIENT | FL_NOTARGET;
 332         this.effects = 0;
 333         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 334         this.pauserotarmor_finished = 0;
 335         this.pauserothealth_finished = 0;
 336         this.pauseregen_finished = 0;
 337         this.damageforcescale = 0;
 338         this.death_time = 0;
 339         this.respawn_flags = 0;
 340         this.respawn_time = 0;
 341         STAT(RESPAWN_TIME, this) = 0;
 342         this.alpha = 0;
 343         this.scale = 0;
 344         this.fade_time = 0;
 345         this.pain_finished = 0;
 346         STAT(STRENGTH_FINISHED, this) = 0;
 347         STAT(INVINCIBLE_FINISHED, this) = 0;
 348         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 349         STAT(AIR_FINISHED, this) = 0;
 350         //this.dphitcontentsmask = 0;
 351         this.dphitcontentsmask = DPCONTENTS_SOLID;
 352         if (autocvar_g_playerclip_collisions)
 353                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 354         this.pushltime = 0;
 355         this.istypefrag = 0;
 356         setthink(this, func_null);
 357         this.nextthink = 0;
 358         this.deadflag = DEAD_NO;
 359         UNSET_DUCKED(this);
 360         STAT(REVIVE_PROGRESS, this) = 0;
 361         this.revival_time = 0;
 362         this.draggable = drag_undraggable;
 363
 364         this.items = 0;
 365         STAT(WEAPONS, this) = '0 0 0';
 366         this.drawonlytoclient = this;
 367
 368         this.viewloc = NULL;
 369
 370         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 371
 372         this.weaponmodel = "";
 373         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 374         {
 375                 this.weaponentities[slot] = NULL;
 376         }
 377         this.exteriorweaponentity = NULL;
 378         CS(this).killcount = FRAGS_SPECTATOR;
 379         this.velocity = '0 0 0';
 380         this.avelocity = '0 0 0';
 381         this.punchangle = '0 0 0';
 382         this.punchvector = '0 0 0';
 383         this.oldvelocity = this.velocity;
 384         this.fire_endtime = -1;
 385         this.event_damage = func_null;
 386         this.event_heal = func_null;
 387
 388         for(int slot = 0; slot < MAX_AXH; ++slot)
 389         {
 390                 entity axh = this.(AuxiliaryXhair[slot]);
 391                 this.(AuxiliaryXhair[slot]) = NULL;
 392
 393                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 394                         delete(axh);
 395         }
 396
 397         if (mutator_returnvalue)
 398         {
 399                 // mutator prevents resetting teams+score
 400         }
 401         else
 402         {
 403                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 404                 this.frags = FRAGS_SPECTATOR;
 405         }
 406         if (CS(this).just_joined)
 407                 CS(this).just_joined = false;
 408 }
 409
 410 int player_getspecies(entity this)
 411 {
 412         get_model_parameters(this.model, this.skin);
 413         int s = get_model_parameters_species;
 414         get_model_parameters(string_null, 0);
 415         if (s < 0) return SPECIES_HUMAN;
 416         return s;
 417 }
 418
 419 .float model_randomizer;
 420 void FixPlayermodel(entity player)
 421 {
 422         string defaultmodel = "";
 423         int defaultskin = 0;
 424         if(autocvar_sv_defaultcharacter)
 425         {
 426                 if(teamplay)
 427                 {
 428                         switch(player.team)
 429                         {
 430                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 431                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 432                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 433                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 434                         }
 435                 }
 436
 437                 if(defaultmodel == "")
 438                 {
 439                         defaultmodel = autocvar_sv_defaultplayermodel;
 440                         defaultskin = autocvar_sv_defaultplayerskin;
 441                 }
 442
 443                 int n = tokenize_console(defaultmodel);
 444                 if(n > 0)
 445                 {
 446                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 447                         // However, do NOT randomize if the player-selected model is in the list.
 448                         for (int i = 0; i < n; ++i)
 449                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 450                                         defaultmodel = argv(i);
 451                 }
 452
 453                 int i = strstrofs(defaultmodel, ":", 0);
 454                 if(i >= 0)
 455                 {
 456                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 457                         defaultmodel = substring(defaultmodel, 0, i);
 458                 }
 459         }
 460         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 461         {
 462                 if(teamplay)
 463                 {
 464                         switch(player.team)
 465                         {
 466                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 467                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 468                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 469                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 470                         }
 471                 }
 472
 473                 if(!defaultskin)
 474                         defaultskin = autocvar_sv_defaultplayerskin;
 475         }
 476
 477         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 478         defaultmodel = M_ARGV(0, string);
 479         defaultskin = M_ARGV(1, int);
 480
 481         bool chmdl = false;
 482         int oldskin;
 483         if(defaultmodel != "")
 484         {
 485                 if (defaultmodel != player.model)
 486                 {
 487                         vector m1 = player.mins;
 488                         vector m2 = player.maxs;
 489                         setplayermodel (player, defaultmodel);
 490                         setsize (player, m1, m2);
 491                         chmdl = true;
 492                 }
 493
 494                 oldskin = player.skin;
 495                 player.skin = defaultskin;
 496         } else {
 497                 if (player.playermodel != player.model || player.playermodel == "")
 498                 {
 499                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 500                         vector m1 = player.mins;
 501                         vector m2 = player.maxs;
 502                         setplayermodel (player, player.playermodel);
 503                         setsize (player, m1, m2);
 504                         chmdl = true;
 505                 }
 506
 507                 if(!autocvar_sv_defaultcharacterskin)
 508                 {
 509                         oldskin = player.skin;
 510                         player.skin = stof(player.playerskin);
 511                 }
 512                 else
 513                 {
 514                         oldskin = player.skin;
 515                         player.skin = defaultskin;
 516                 }
 517         }
 518
 519         if(chmdl || oldskin != player.skin) // model or skin has changed
 520         {
 521                 player.species = player_getspecies(player); // update species
 522                 if(!autocvar_g_debug_globalsounds)
 523                         UpdatePlayerSounds(player); // update skin sounds
 524         }
 525
 526         if(!teamplay)
 527                 if(strlen(autocvar_sv_defaultplayercolors))
 528                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 529                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 530 }
 531
 532 void PutPlayerInServer(entity this)
 533 {
 534         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 535
 536         PlayerState_attach(this);
 537         accuracy_resend(this);
 538
 539         if (this.team < 0)
 540                 TeamBalance_JoinBestTeam(this);
 541
 542         entity spot = SelectSpawnPoint(this, false);
 543         if (!spot) {
 544                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 545                 return; // spawn failed
 546         }
 547
 548         TRANSMUTE(Player, this);
 549
 550         CS(this).wasplayer = true;
 551         this.iscreature = true;
 552         this.teleportable = TELEPORT_NORMAL;
 553         if(!this.damagedbycontents)
 554                 IL_PUSH(g_damagedbycontents, this);
 555         this.damagedbycontents = true;
 556         set_movetype(this, MOVETYPE_WALK);
 557         this.solid = SOLID_SLIDEBOX;
 558         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 559         if (autocvar_g_playerclip_collisions)
 560                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 561         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 562                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 563         this.frags = FRAGS_PLAYER;
 564         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 565         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 566         if (autocvar__notarget)
 567                 this.flags |= FL_NOTARGET;
 568         this.takedamage = DAMAGE_AIM;
 569         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 570
 571         if (warmup_stage) {
 572                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 573                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 574                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 575                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 576                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 577                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 578                 SetResource(this, RES_HEALTH, warmup_start_health);
 579                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 580                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 581         } else {
 582                 SetResource(this, RES_SHELLS, start_ammo_shells);
 583                 SetResource(this, RES_BULLETS, start_ammo_nails);
 584                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 585                 SetResource(this, RES_CELLS, start_ammo_cells);
 586                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 587                 SetResource(this, RES_FUEL, start_ammo_fuel);
 588                 SetResource(this, RES_HEALTH, start_health);
 589                 SetResource(this, RES_ARMOR, start_armorvalue);
 590                 STAT(WEAPONS, this) = start_weapons;
 591                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 592                 {
 593                         GiveRandomWeapons(this, random_start_weapons_count,
 594                                 autocvar_g_random_start_weapons, random_start_ammo);
 595                 }
 596         }
 597         SetSpectatee_status(this, 0);
 598
 599         PS(this).dual_weapons = '0 0 0';
 600
 601         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 602
 603         this.items = start_items;
 604
 605         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 606         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 607         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 608         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 609         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 610         if (!sv_ready_restart_after_countdown && time < game_starttime)
 611         {
 612                 float f = game_starttime - time;
 613                 this.spawnshieldtime += f;
 614                 this.pauserotarmor_finished += f;
 615                 this.pauserothealth_finished += f;
 616                 this.pauseregen_finished += f;
 617         }
 618
 619         this.damageforcescale = autocvar_g_player_damageforcescale;
 620         this.death_time = 0;
 621         this.respawn_flags = 0;
 622         this.respawn_time = 0;
 623         STAT(RESPAWN_TIME, this) = 0;
 624         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 625         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 626         this.fade_time = 0;
 627         this.pain_finished = 0;
 628         this.pushltime = 0;
 629         setthink(this, func_null); // players have no think function
 630         this.nextthink = 0;
 631         this.dmg_team = 0;
 632         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 633
 634         this.deadflag = DEAD_NO;
 635
 636         this.angles = spot.angles;
 637         this.angles_z = 0; // never spawn tilted even if the spot says to
 638         if (IS_BOT_CLIENT(this))
 639         {
 640                 this.v_angle = this.angles;
 641                 bot_aim_reset(this);
 642         }
 643         this.fixangle = true; // turn this way immediately
 644         this.oldvelocity = this.velocity = '0 0 0';
 645         this.avelocity = '0 0 0';
 646         this.punchangle = '0 0 0';
 647         this.punchvector = '0 0 0';
 648
 649         STAT(STRENGTH_FINISHED, this) = 0;
 650         STAT(INVINCIBLE_FINISHED, this) = 0;
 651         this.fire_endtime = -1;
 652         STAT(REVIVE_PROGRESS, this) = 0;
 653         this.revival_time = 0;
 654
 655         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 656         STAT(BUFFS, this) = 0;
 657         STAT(BUFF_TIME, this) = 0;
 658
 659         STAT(AIR_FINISHED, this) = 0;
 660         this.waterlevel = WATERLEVEL_NONE;
 661         this.watertype = CONTENT_EMPTY;
 662
 663         entity spawnevent = new_pure(spawnevent);
 664         spawnevent.owner = this;
 665         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 666
 667         // Cut off any still running player sounds.
 668         stopsound(this, CH_PLAYER_SINGLE);
 669
 670         this.model = "";
 671         FixPlayermodel(this);
 672         this.drawonlytoclient = NULL;
 673
 674         this.viewloc = NULL;
 675
 676         for(int slot = 0; slot < MAX_AXH; ++slot)
 677         {
 678                 entity axh = this.(AuxiliaryXhair[slot]);
 679                 this.(AuxiliaryXhair[slot]) = NULL;
 680
 681                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 682                         delete(axh);
 683         }
 684
 685         this.spawnpoint_targ = NULL;
 686
 687         UNSET_DUCKED(this);
 688         this.view_ofs = STAT(PL_VIEW_OFS, this);
 689         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 690         this.spawnorigin = spot.origin;
 691         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 692         // don't reset back to last position, even if new position is stuck in solid
 693         this.oldorigin = this.origin;
 694         if(this.conveyor)
 695                 IL_REMOVE(g_conveyed, this);
 696         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 697         if(this.swampslug)
 698                 IL_REMOVE(g_swamped, this);
 699         this.swampslug = NULL;
 700         this.swamp_interval = 0;
 701         if(this.ladder_entity)
 702                 IL_REMOVE(g_ladderents, this);
 703         this.ladder_entity = NULL;
 704         IL_EACH(g_counters, it.realowner == this,
 705         {
 706                 delete(it);
 707         });
 708         STAT(HUD, this) = HUD_NORMAL;
 709
 710         this.event_damage = PlayerDamage;
 711         this.event_heal = PlayerHeal;
 712
 713         this.draggable = func_null;
 714
 715         if(!this.bot_attack)
 716                 IL_PUSH(g_bot_targets, this);
 717         this.bot_attack = true;
 718         if(!this.monster_attack)
 719                 IL_PUSH(g_monster_targets, this);
 720         this.monster_attack = true;
 721         navigation_dynamicgoal_init(this, false);
 722
 723         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 724
 725         // player was spectator
 726         if (CS(this).killcount == FRAGS_SPECTATOR) {
 727                 PlayerScore_Clear(this);
 728                 CS(this).killcount = 0;
 729                 CS(this).startplaytime = time;
 730         }
 731
 732         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 733         {
 734                 .entity weaponentity = weaponentities[slot];
 735                 CL_SpawnWeaponentity(this, weaponentity);
 736         }
 737         this.alpha = default_player_alpha;
 738         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 739         this.exteriorweaponentity.alpha = default_weapon_alpha;
 740
 741         this.speedrunning = false;
 742
 743         this.counter_cnt = 0;
 744         this.fragsfilter_cnt = 0;
 745
 746         target_voicescript_clear(this);
 747
 748         // reset fields the weapons may use
 749         FOREACH(Weapons, true, {
 750                 it.wr_resetplayer(it, this);
 751                         // reload all reloadable weapons
 752                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 753                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 754                         {
 755                                 .entity weaponentity = weaponentities[slot];
 756                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 757                         }
 758                 }
 759         });
 760
 761         {
 762                 string s = spot.target;
 763                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 764                         spot.target = string_null;
 765                 SUB_UseTargets(spot, this, NULL);
 766                 if(g_assault || g_race)
 767                         spot.target = s;
 768         }
 769
 770         Unfreeze(this, false);
 771
 772         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 773
 774         if (autocvar_spawn_debug)
 775         {
 776                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 777                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 778         }
 779
 780         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 781         {
 782                 .entity weaponentity = weaponentities[slot];
 783                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 784                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 785                 else
 786                         this.(weaponentity).m_switchweapon = WEP_Null;
 787                 this.(weaponentity).m_weapon = WEP_Null;
 788                 this.(weaponentity).weaponname = "";
 789                 this.(weaponentity).m_switchingweapon = WEP_Null;
 790                 this.(weaponentity).cnt = -1;
 791         }
 792
 793         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 794
 795         if (CS(this).impulse) ImpulseCommands(this);
 796
 797         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 798         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 799         {
 800                 .entity weaponentity = weaponentities[slot];
 801                 W_WeaponFrame(this, weaponentity);
 802         }
 803
 804         if (!warmup_stage && !this.alivetime)
 805                 this.alivetime = time;
 806
 807         antilag_clear(this, CS(this));
 808 }
 809
 810 /** Called when a client spawns in the server */
 811 void PutClientInServer(entity this)
 812 {
 813         if (IS_BOT_CLIENT(this)) {
 814                 TRANSMUTE(Player, this);
 815         } else if (IS_REAL_CLIENT(this)) {
 816                 msg_entity = this;
 817                 WriteByte(MSG_ONE, SVC_SETVIEW);
 818                 WriteEntity(MSG_ONE, this);
 819         }
 820         if (game_stopped)
 821                 TRANSMUTE(Observer, this);
 822
 823         SetSpectatee(this, NULL);
 824
 825         // reset player keys
 826         if(PS(this))
 827                 PS(this).itemkeys = 0;
 828
 829         MUTATOR_CALLHOOK(PutClientInServer, this);
 830
 831         if (IS_OBSERVER(this)) {
 832                 PutObserverInServer(this);
 833         } else if (IS_PLAYER(this)) {
 834                 PutPlayerInServer(this);
 835         }
 836 }
 837
 838 // TODO do we need all these fields, or should we stop autodetecting runtime
 839 // changes and just have a console command to update this?
 840 bool ClientInit_SendEntity(entity this, entity to, int sf)
 841 {
 842         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 843         return = true;
 844         msg_entity = to;
 845         // MSG_INIT replacement
 846         // TODO: make easier to use
 847         Registry_send_all();
 848         W_PROP_reload(MSG_ONE, to);
 849         ClientInit_misc(this);
 850         MUTATOR_CALLHOOK(Ent_Init);
 851 }
 852 void ClientInit_misc(entity this)
 853 {
 854         int channel = MSG_ONE;
 855         WriteHeader(channel, ENT_CLIENT_INIT);
 856         WriteByte(channel, g_nexball_meter_period * 32);
 857         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 858         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 859         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 860         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 861         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 862         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 863         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 864         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 865
 866         if(autocvar_sv_foginterval && world.fog != "")
 867                 WriteString(channel, world.fog);
 868         else
 869                 WriteString(channel, "");
 870         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 871         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 872         WriteByte(channel, serverflags);
 873         WriteCoord(channel, autocvar_g_trueaim_minrange);
 874 }
 875
 876 void ClientInit_CheckUpdate(entity this)
 877 {
 878         this.nextthink = time;
 879         if(this.count != autocvar_g_balance_armor_blockpercent)
 880         {
 881                 this.count = autocvar_g_balance_armor_blockpercent;
 882                 this.SendFlags |= 1;
 883         }
 884         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 885         {
 886                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 887                 this.SendFlags |= 1;
 888         }
 889 }
 890
 891 void ClientInit_Spawn()
 892 {
 893         entity e = new_pure(clientinit);
 894         setthink(e, ClientInit_CheckUpdate);
 895         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 896
 897         ClientInit_CheckUpdate(e);
 898 }
 899
 900 /*
 901 =============
 902 SetNewParms
 903 =============
 904 */
 905 void SetNewParms ()
 906 {
 907         // initialize parms for a new player
 908         parm1 = -(86400 * 366);
 909
 910         MUTATOR_CALLHOOK(SetNewParms);
 911 }
 912
 913 /*
 914 =============
 915 SetChangeParms
 916 =============
 917 */
 918 void SetChangeParms (entity this)
 919 {
 920         // save parms for level change
 921         parm1 = CS(this).parm_idlesince - time;
 922
 923         MUTATOR_CALLHOOK(SetChangeParms);
 924 }
 925
 926 /*
 927 =============
 928 DecodeLevelParms
 929 =============
 930 */
 931 void DecodeLevelParms(entity this)
 932 {
 933         // load parms
 934         CS(this).parm_idlesince = parm1;
 935         if (CS(this).parm_idlesince == -(86400 * 366))
 936                 CS(this).parm_idlesince = time;
 937
 938         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 939         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 940
 941         MUTATOR_CALLHOOK(DecodeLevelParms);
 942 }
 943
 944 void FixClientCvars(entity e)
 945 {
 946         // send prediction settings to the client
 947         stuffcmd(e, "\nin_bindmap 0 0\n");
 948         if(autocvar_g_antilag == 3) // client side hitscan
 949                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 950         if(autocvar_sv_gentle)
 951                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 952
 953         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 954         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 955
 956         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 957
 958         MUTATOR_CALLHOOK(FixClientCvars, e);
 959 }
 960
 961 bool findinlist_abbrev(string tofind, string list)
 962 {
 963         if(list == "" || tofind == "")
 964                 return false; // empty list or search, just return
 965
 966         // this function allows abbreviated strings!
 967         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 968         {
 969                 return true;
 970         });
 971
 972         return false;
 973 }
 974
 975 bool PlayerInIPList(entity p, string iplist)
 976 {
 977         // some safety checks (never allow local?)
 978         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 979                 return false;
 980
 981         return findinlist_abbrev(p.netaddress, iplist);
 982 }
 983
 984 bool PlayerInIDList(entity p, string idlist)
 985 {
 986         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 987         if(!p.crypto_idfp)
 988                 return false;
 989
 990         return findinlist_abbrev(p.crypto_idfp, idlist);
 991 }
 992
 993 bool PlayerInList(entity player, string list)
 994 {
 995         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 996 }
 997
 998 #ifdef DP_EXT_PRECONNECT
 999 /*
1000 =============
1001 ClientPreConnect
1002
1003 Called once (not at each match start) when a client begins a connection to the server
1004 =============
1005 */
1006 void ClientPreConnect(entity this)
1007 {
1008         if(autocvar_sv_eventlog)
1009         {
1010                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1011                         this.playerid,
1012                         etof(this),
1013                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1014                 ));
1015         }
1016 }
1017 #endif
1018
1019 string GetClientVersionMessage(entity this)
1020 {
1021         if (CS(this).version_mismatch) {
1022                 if(CS(this).version < autocvar_gameversion) {
1023                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1024                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1025                 } else {
1026                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1027                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1028                 }
1029         } else {
1030                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1031         }
1032 }
1033
1034 string getwelcomemessage(entity this)
1035 {
1036         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1037         string modifications = M_ARGV(0, string);
1038
1039         if(g_weaponarena)
1040         {
1041                 if(g_weaponarena_random)
1042                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1043                 else
1044                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1045         }
1046         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1047                 modifications = strcat(modifications, ", No start weapons");
1048         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1049                 modifications = strcat(modifications, ", Low gravity");
1050         if(g_weapon_stay && !g_cts)
1051                 modifications = strcat(modifications, ", Weapons stay");
1052         if(autocvar_g_jetpack)
1053                 modifications = strcat(modifications, ", Jet pack");
1054         if(autocvar_g_powerups == 0)
1055                 modifications = strcat(modifications, ", No powerups");
1056         if(autocvar_g_powerups > 0)
1057                 modifications = strcat(modifications, ", Powerups");
1058         modifications = substring(modifications, 2, strlen(modifications) - 2);
1059
1060         string versionmessage = GetClientVersionMessage(this);
1061         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1062
1063         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1064
1065         if(modifications != "")
1066                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1067
1068         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1069         {
1070                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1071                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1072         }
1073
1074         if (cache_mutatormsg != "") {
1075                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1076         }
1077
1078         string mutator_msg = "";
1079         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1080         mutator_msg = M_ARGV(0, string);
1081
1082         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1083
1084         string motd = autocvar_sv_motd;
1085         if (motd != "") {
1086                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1087         }
1088         return s;
1089 }
1090
1091 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1092
1093 /**
1094 =============
1095 ClientConnect
1096
1097 Called when a client connects to the server
1098 =============
1099 */
1100 void ClientConnect(entity this)
1101 {
1102         if (Ban_MaybeEnforceBanOnce(this)) return;
1103         assert(!IS_CLIENT(this), return);
1104         this.flags |= FL_CLIENT;
1105         assert(player_count >= 0, player_count = 0);
1106
1107         TRANSMUTE(Client, this);
1108         CS(this).version_nagtime = time + 10 + random() * 10;
1109
1110         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1111
1112         bot_clientconnect(this);
1113
1114         Player_DetermineForcedTeam(this);
1115
1116         TRANSMUTE(Observer, this);
1117
1118         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1119
1120         // always track bots, don't ask for cl_allow_uidtracking
1121         if (IS_BOT_CLIENT(this))
1122                 PlayerStats_GameReport_AddPlayer(this);
1123         else
1124                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1125
1126         if (autocvar_sv_eventlog)
1127                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1128
1129         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1130
1131         stuffcmd(this, clientstuff, "\n");
1132         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1133
1134         FixClientCvars(this);
1135
1136         // get version info from player
1137         stuffcmd(this, "cmd clientversion $gameversion\n");
1138
1139         // notify about available teams
1140         if (teamplay)
1141         {
1142                 entity balance = TeamBalance_CheckAllowedTeams(this);
1143                 int t = TeamBalance_GetAllowedTeams(balance);
1144                 TeamBalance_Destroy(balance);
1145                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1146         }
1147         else
1148         {
1149                 stuffcmd(this, "set _teams_available 0\n");
1150         }
1151
1152         bot_relinkplayerlist();
1153
1154         CS(this).spectatortime = time;
1155         if (blockSpectators)
1156         {
1157                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1158         }
1159
1160         CS(this).jointime = time;
1161
1162         if (IS_REAL_CLIENT(this))
1163         {
1164                 if (g_weaponarena_weapons == WEPSET(TUBA))
1165                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1166         }
1167
1168         if (!autocvar_sv_foginterval && world.fog != "")
1169                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1170
1171         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1172                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1173                         send_CSQC_teamnagger();
1174
1175         CSQCMODEL_AUTOINIT(this);
1176
1177         CS(this).model_randomizer = random();
1178
1179         if (IS_REAL_CLIENT(this))
1180                 sv_notice_join(this);
1181
1182         this.move_qcphysics = autocvar_sv_qcphysics;
1183
1184         // update physics stats (players can spawn before physics runs)
1185         Physics_UpdateStats(this);
1186
1187         IL_EACH(g_initforplayer, it.init_for_player, {
1188                 it.init_for_player(it, this);
1189         });
1190
1191         Handicap_Initialize(this);
1192
1193         MUTATOR_CALLHOOK(ClientConnect, this);
1194
1195         if (IS_REAL_CLIENT(this))
1196         {
1197                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1198                 {
1199                         CS(this).motd_actived_time = -1;
1200                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1201                 }
1202         }
1203 }
1204 /*
1205 =============
1206 ClientDisconnect
1207
1208 Called when a client disconnects from the server
1209 =============
1210 */
1211 .entity chatbubbleentity;
1212 void ClientDisconnect(entity this)
1213 {
1214         assert(IS_CLIENT(this), return);
1215
1216         PlayerStats_GameReport_FinalizePlayer(this);
1217         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1218         if (CS(this).active_minigame) part_minigame(this);
1219         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1220
1221         if (autocvar_sv_eventlog)
1222                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1223
1224         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1225
1226         if(IS_SPEC(this))
1227                 SetSpectatee(this, NULL);
1228
1229         MUTATOR_CALLHOOK(ClientDisconnect, this);
1230
1231         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1232         strfree(CS(this).weaponorder_byimpulse);
1233         ClientState_detach(this);
1234
1235         Portal_ClearAll(this);
1236
1237         Unfreeze(this, false);
1238
1239         RemoveGrapplingHooks(this);
1240
1241         // Here, everything has been done that requires this player to be a client.
1242
1243         this.flags &= ~FL_CLIENT;
1244
1245         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1246         if (this.killindicator) delete(this.killindicator);
1247
1248         IL_EACH(g_counters, it.realowner == this,
1249         {
1250                 delete(it);
1251         });
1252
1253         WaypointSprite_PlayerGone(this);
1254
1255         bot_relinkplayerlist();
1256
1257         strfree(this.clientstatus);
1258         if (this.personal) delete(this.personal);
1259
1260         this.playerid = 0;
1261         ReadyCount();
1262         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1263
1264         ONREMOVE(this);
1265 }
1266
1267 void ChatBubbleThink(entity this)
1268 {
1269         this.nextthink = time;
1270         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1271         {
1272                 if(this.owner) // but why can that ever be NULL?
1273                         this.owner.chatbubbleentity = NULL;
1274                 delete(this);
1275                 return;
1276         }
1277
1278         this.mdl = "";
1279
1280         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1281         {
1282                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1283                         this.mdl = "models/sprites/minigame_busy.iqm";
1284                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1285                         this.mdl = "models/misc/chatbubble.spr";
1286         }
1287
1288         if ( this.model != this.mdl )
1289                 _setmodel(this, this.mdl);
1290
1291 }
1292
1293 void UpdateChatBubble(entity this)
1294 {
1295         if (this.alpha < 0)
1296                 return;
1297         // spawn a chatbubble entity if needed
1298         if (!this.chatbubbleentity)
1299         {
1300                 this.chatbubbleentity = new(chatbubbleentity);
1301                 this.chatbubbleentity.owner = this;
1302                 this.chatbubbleentity.exteriormodeltoclient = this;
1303                 setthink(this.chatbubbleentity, ChatBubbleThink);
1304                 this.chatbubbleentity.nextthink = time;
1305                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1306                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1307                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1308                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1309                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1310                 //this.chatbubbleentity.model = "";
1311                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1312         }
1313 }
1314
1315 void calculate_player_respawn_time(entity this)
1316 {
1317         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1318                 return;
1319
1320         float gametype_setting_tmp;
1321         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1322         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1323         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1324         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1325         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1326         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1327
1328         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1329         if (teamplay)
1330         {
1331                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1332                         if(it.team == this.team)
1333                                 ++pcount;
1334                 });
1335                 if (sdelay_small_count == 0)
1336                         sdelay_small_count = 1;
1337                 if (sdelay_large_count == 0)
1338                         sdelay_large_count = 1;
1339         }
1340         else
1341         {
1342                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1343                         ++pcount;
1344                 });
1345                 if (sdelay_small_count == 0)
1346                 {
1347                         if (IS_INDEPENDENT_PLAYER(this))
1348                         {
1349                                 // Players play independently. No point in requiring enemies.
1350                                 sdelay_small_count = 1;
1351                         }
1352                         else
1353                         {
1354                                 // Players play AGAINST each other. Enemies required.
1355                                 sdelay_small_count = 2;
1356                         }
1357                 }
1358                 if (sdelay_large_count == 0)
1359                 {
1360                         if (IS_INDEPENDENT_PLAYER(this))
1361                         {
1362                                 // Players play independently. No point in requiring enemies.
1363                                 sdelay_large_count = 1;
1364                         }
1365                         else
1366                         {
1367                                 // Players play AGAINST each other. Enemies required.
1368                                 sdelay_large_count = 2;
1369                         }
1370                 }
1371         }
1372
1373         float sdelay;
1374
1375         if (pcount <= sdelay_small_count)
1376                 sdelay = sdelay_small;
1377         else if (pcount >= sdelay_large_count)
1378                 sdelay = sdelay_large;
1379         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1380                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1381
1382         if(waves)
1383                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1384         else
1385                 this.respawn_time = time + sdelay;
1386
1387         if(sdelay < sdelay_max)
1388                 this.respawn_time_max = time + sdelay_max;
1389         else
1390                 this.respawn_time_max = this.respawn_time;
1391
1392         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1393                 this.respawn_countdown = 10; // first number to count down from is 10
1394         else
1395                 this.respawn_countdown = -1; // do not count down
1396
1397         if(autocvar_g_forced_respawn)
1398                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1399 }
1400
1401 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1402 // added to the model skins
1403 /*void UpdateColorModHack()
1404 {
1405         float c;
1406         c = this.clientcolors & 15;
1407         // LordHavoc: only bothering to support white, green, red, yellow, blue
1408              if (!teamplay) this.colormod = '0 0 0';
1409         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1410         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1411         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1412         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1413         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1414         else this.colormod = '1 1 1';
1415 }*/
1416
1417 void respawn(entity this)
1418 {
1419         bool damagedbycontents_prev = this.damagedbycontents;
1420         if(this.alpha >= 0)
1421         {
1422                 if(autocvar_g_respawn_ghosts)
1423                 {
1424                         this.solid = SOLID_NOT;
1425                         this.takedamage = DAMAGE_NO;
1426                         this.damagedbycontents = false;
1427                         set_movetype(this, MOVETYPE_FLY);
1428                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1429                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1430                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1431                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1432                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1433                         if(autocvar_g_respawn_ghosts_time > 0)
1434                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1435                 }
1436                 else
1437                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1438         }
1439
1440         CopyBody(this, 1);
1441         this.damagedbycontents = damagedbycontents_prev;
1442
1443         this.effects |= EF_NODRAW; // prevent another CopyBody
1444         PutClientInServer(this);
1445 }
1446
1447 ERASEABLE
1448 void PrintToChat(entity client, string text)
1449 {
1450         text = strcat("\{1}^7", text, "\n");
1451         sprint(client, text);
1452 }
1453
1454 ERASEABLE
1455 void DebugPrintToChat(entity client, string text)
1456 {
1457         if (autocvar_developer > 0)
1458         {
1459                 PrintToChat(client, text);
1460         }
1461 }
1462
1463 ERASEABLE
1464 void PrintToChatAll(string text)
1465 {
1466         text = strcat("\{1}^7", text, "\n");
1467         bprint(text);
1468 }
1469
1470 ERASEABLE
1471 void DebugPrintToChatAll(string text)
1472 {
1473         if (autocvar_developer > 0)
1474         {
1475                 PrintToChatAll(text);
1476         }
1477 }
1478
1479 ERASEABLE
1480 void PrintToChatTeam(int team_num, string text)
1481 {
1482         text = strcat("\{1}^7", text, "\n");
1483         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1484         {
1485                 if (it.team == team_num)
1486                 {
1487                         sprint(it, text);
1488                 }
1489         });
1490 }
1491
1492 ERASEABLE
1493 void DebugPrintToChatTeam(int team_num, string text)
1494 {
1495         if (autocvar_developer > 0)
1496         {
1497                 PrintToChatTeam(team_num, text);
1498         }
1499 }
1500
1501 void play_countdown(entity this, float finished, Sound samp)
1502 {
1503         TC(Sound, samp);
1504         if(IS_REAL_CLIENT(this))
1505                 if(floor(finished - time - frametime) != floor(finished - time))
1506                         if(finished - time < 6)
1507                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1508 }
1509
1510 void player_powerups(entity this)
1511 {
1512         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1513                 this.modelflags |= MF_ROCKET;
1514         else
1515                 this.modelflags &= ~MF_ROCKET;
1516
1517         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1518
1519         if (IS_DEAD(this))
1520         {
1521                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1522                 {
1523                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1524                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1525                         this.items &= ~ITEM_Strength.m_itemid;
1526                         this.items &= ~ITEM_Shield.m_itemid;
1527                         this.items -= (this.items & IT_SUPERWEAPON);
1528                 }
1529         }
1530
1531         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1532                 return;
1533
1534         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1535         int items_prev = this.items;
1536
1537         Fire_ApplyDamage(this);
1538         Fire_ApplyEffect(this);
1539
1540         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1541         {
1542                 if (this.items & ITEM_Strength.m_itemid)
1543                 {
1544                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1545                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1546                         if (time > STAT(STRENGTH_FINISHED, this))
1547                         {
1548                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1549                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1550                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1551                         }
1552                 }
1553                 else
1554                 {
1555                         if (time < STAT(STRENGTH_FINISHED, this))
1556                         {
1557                                 this.items = this.items | ITEM_Strength.m_itemid;
1558                                 if(!g_cts)
1559                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1560                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1561                         }
1562                 }
1563                 if (this.items & ITEM_Shield.m_itemid)
1564                 {
1565                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1566                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1567                         if (time > STAT(INVINCIBLE_FINISHED, this))
1568                         {
1569                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1570                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1571                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1572                         }
1573                 }
1574                 else
1575                 {
1576                         if (time < STAT(INVINCIBLE_FINISHED, this))
1577                         {
1578                                 this.items = this.items | ITEM_Shield.m_itemid;
1579                                 if(!g_cts)
1580                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1581                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1582                         }
1583                 }
1584                 if (this.items & IT_SUPERWEAPON)
1585                 {
1586                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1587                         {
1588                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1589                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1590                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1591                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1592                         }
1593                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1594                         {
1595                                 // don't let them run out
1596                         }
1597                         else
1598                         {
1599                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1600                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1601                                 {
1602                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1603                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1604                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1605                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1606                                 }
1607                         }
1608                 }
1609                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1610                 {
1611                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1612                         {
1613                                 this.items = this.items | IT_SUPERWEAPON;
1614                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1615                                 {
1616                                         if(!g_cts)
1617                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1618                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1619                                 }
1620                         }
1621                         else
1622                         {
1623                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1624                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1625                         }
1626                 }
1627                 else
1628                 {
1629                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1630                 }
1631         }
1632
1633         if(autocvar_g_nodepthtestplayers)
1634                 this.effects = this.effects | EF_NODEPTHTEST;
1635
1636         if(autocvar_g_fullbrightplayers)
1637                 this.effects = this.effects | EF_FULLBRIGHT;
1638
1639         if (time >= game_starttime)
1640         if (time < this.spawnshieldtime)
1641                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1642
1643         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1644 }
1645
1646 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1647 {
1648         if(current > stable)
1649                 return current;
1650         else if(current > stable - 0.25) // when close enough, "snap"
1651                 return stable;
1652         else
1653                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1654 }
1655
1656 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1657 {
1658         if(current < stable)
1659                 return current;
1660         else if(current < stable + 0.25) // when close enough, "snap"
1661                 return stable;
1662         else
1663                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1664 }
1665
1666 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1667 {
1668         float old = GetResource(this, res);
1669         float current = old;
1670         if(current > rotstable)
1671         {
1672                 if(rotframetime > 0)
1673                 {
1674                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1675                         current = max(rotstable, current - rotlinear * rotframetime);
1676                 }
1677         }
1678         else if(current < regenstable)
1679         {
1680                 if(regenframetime > 0)
1681                 {
1682                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1683                         current = min(regenstable, current + regenlinear * regenframetime);
1684                 }
1685         }
1686
1687         float limit = GetResourceLimit(this, res) * limit_mod;
1688         if(current > limit)
1689                 current = limit;
1690
1691         if (current != old)
1692                 SetResource(this, res, current);
1693 }
1694
1695 void player_regen(entity this)
1696 {
1697         float max_mod, regen_mod, rot_mod, limit_mod;
1698         max_mod = regen_mod = rot_mod = limit_mod = 1;
1699
1700         float regen_health = autocvar_g_balance_health_regen;
1701         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1702         float regen_health_rot = autocvar_g_balance_health_rot;
1703         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1704         float regen_health_stable = autocvar_g_balance_health_regenstable;
1705         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1706         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1707                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1708         max_mod = M_ARGV(1, float);
1709         regen_mod = M_ARGV(2, float);
1710         rot_mod = M_ARGV(3, float);
1711         limit_mod = M_ARGV(4, float);
1712         regen_health = M_ARGV(5, float);
1713         regen_health_linear = M_ARGV(6, float);
1714         regen_health_rot = M_ARGV(7, float);
1715         regen_health_rotlinear = M_ARGV(8, float);
1716         regen_health_stable = M_ARGV(9, float);
1717         regen_health_rotstable = M_ARGV(10, float);
1718
1719         if(!mutator_returnvalue)
1720         if(!STAT(FROZEN, this))
1721         {
1722                 float maxa = autocvar_g_balance_armor_rotstable;
1723                 float mina = autocvar_g_balance_armor_regenstable;
1724
1725                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1726                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1727                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1728
1729                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1730                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1731                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1732         }
1733
1734         // if player rotted to death...  die!
1735         // check this outside above checks, as player may still be able to rot to death
1736         if(GetResource(this, RES_HEALTH) < 1)
1737         {
1738                 if(this.vehicle)
1739                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1740                 if(this.event_damage)
1741                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1742         }
1743
1744         if (!(this.items & IT_UNLIMITED_AMMO))
1745         {
1746                 float maxf = autocvar_g_balance_fuel_rotstable;
1747                 float minf = autocvar_g_balance_fuel_regenstable;
1748
1749                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1750                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1751                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1752         }
1753 }
1754
1755 bool zoomstate_set;
1756 void SetZoomState(entity this, float newzoom)
1757 {
1758         if(newzoom != CS(this).zoomstate)
1759         {
1760                 CS(this).zoomstate = newzoom;
1761                 ClientData_Touch(this);
1762         }
1763         zoomstate_set = true;
1764 }
1765
1766 void GetPressedKeys(entity this)
1767 {
1768         MUTATOR_CALLHOOK(GetPressedKeys, this);
1769         int keys = STAT(PRESSED_KEYS, this);
1770         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1771         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1772         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1773         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1774
1775         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1776         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1777         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1778         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1779         CS(this).pressedkeys = keys; // store for other users
1780
1781         STAT(PRESSED_KEYS, this) = keys;
1782 }
1783
1784 /*
1785 ======================
1786 spectate mode routines
1787 ======================
1788 */
1789
1790 void SpectateCopy(entity this, entity spectatee)
1791 {
1792         TC(Client, this); TC(Client, spectatee);
1793
1794         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1795         PS(this) = PS(spectatee);
1796         this.armortype = spectatee.armortype;
1797         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1798         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1799         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1800         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1801         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1802         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1803         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1804         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1805         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1806         CS(this).impulse = 0;
1807         this.disableclientprediction = 1; // no need to run prediction on a spectator
1808         this.items = spectatee.items;
1809         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1810         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1811         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1812         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1813         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1814         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1815         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1816         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1817         this.punchangle = spectatee.punchangle;
1818         this.view_ofs = spectatee.view_ofs;
1819         this.velocity = spectatee.velocity;
1820         this.dmg_take = spectatee.dmg_take;
1821         this.dmg_save = spectatee.dmg_save;
1822         this.dmg_inflictor = spectatee.dmg_inflictor;
1823         this.v_angle = spectatee.v_angle;
1824         this.angles = spectatee.v_angle;
1825         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1826         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1827         this.viewloc = spectatee.viewloc;
1828         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1829                 this.fixangle = true;
1830         setorigin(this, spectatee.origin);
1831         setsize(this, spectatee.mins, spectatee.maxs);
1832         SetZoomState(this, CS(spectatee).zoomstate);
1833
1834     anticheat_spectatecopy(this, spectatee);
1835         STAT(HUD, this) = STAT(HUD, spectatee);
1836         if(spectatee.vehicle)
1837     {
1838         this.angles = spectatee.v_angle;
1839
1840         //this.fixangle = false;
1841         //this.velocity = spectatee.vehicle.velocity;
1842         this.vehicle_health = spectatee.vehicle_health;
1843         this.vehicle_shield = spectatee.vehicle_shield;
1844         this.vehicle_energy = spectatee.vehicle_energy;
1845         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1846         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1847         this.vehicle_reload1 = spectatee.vehicle_reload1;
1848         this.vehicle_reload2 = spectatee.vehicle_reload2;
1849
1850         //msg_entity = this;
1851
1852        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1853             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1854            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1855            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1856
1857         //WriteByte (MSG_ONE, SVC_SETVIEW);
1858         //    WriteEntity(MSG_ONE, this);
1859         //makevectors(spectatee.v_angle);
1860         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1861     }
1862 }
1863
1864 bool SpectateUpdate(entity this)
1865 {
1866         if(!this.enemy)
1867                 return false;
1868
1869         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1870         {
1871                 SetSpectatee(this, NULL);
1872                 return false;
1873         }
1874
1875         SpectateCopy(this, this.enemy);
1876
1877         return true;
1878 }
1879
1880 bool SpectateSet(entity this)
1881 {
1882         if(!IS_PLAYER(this.enemy))
1883                 return false;
1884
1885         ClientData_Touch(this.enemy);
1886
1887         msg_entity = this;
1888         WriteByte(MSG_ONE, SVC_SETVIEW);
1889         WriteEntity(MSG_ONE, this.enemy);
1890         set_movetype(this, MOVETYPE_NONE);
1891         accuracy_resend(this);
1892
1893         if(!SpectateUpdate(this))
1894                 PutObserverInServer(this);
1895
1896         return true;
1897 }
1898
1899 void SetSpectatee_status(entity this, int spectatee_num)
1900 {
1901         int oldspectatee_status = CS(this).spectatee_status;
1902         CS(this).spectatee_status = spectatee_num;
1903
1904         if (CS(this).spectatee_status != oldspectatee_status)
1905         {
1906                 if (STAT(PRESSED_KEYS, this))
1907                 {
1908                         CS(this).pressedkeys = 0;
1909                         STAT(PRESSED_KEYS, this) = 0;
1910                 }
1911                 ClientData_Touch(this);
1912                 if (g_race || g_cts) race_InitSpectator();
1913         }
1914 }
1915
1916 void SetSpectatee(entity this, entity spectatee)
1917 {
1918         if(IS_BOT_CLIENT(this))
1919                 return; // bots abuse .enemy, this code is useless to them
1920
1921         entity old_spectatee = this.enemy;
1922
1923         this.enemy = spectatee;
1924
1925         // WEAPONTODO
1926         // these are required to fix the spectator bug with arc
1927         if(old_spectatee)
1928         {
1929                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1930                 {
1931                         .entity weaponentity = weaponentities[slot];
1932                         if(old_spectatee.(weaponentity).arc_beam)
1933                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1934                 }
1935         }
1936         if(this.enemy)
1937         {
1938                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1939                 {
1940                         .entity weaponentity = weaponentities[slot];
1941                         if(this.enemy.(weaponentity).arc_beam)
1942                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1943                 }
1944         }
1945
1946         if (this.enemy)
1947                 SetSpectatee_status(this, etof(this.enemy));
1948
1949         // needed to update spectator list
1950         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1951 }
1952
1953 bool Spectate(entity this, entity pl)
1954 {
1955         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1956                 return false;
1957         pl = M_ARGV(1, entity);
1958
1959         SetSpectatee(this, pl);
1960         return SpectateSet(this);
1961 }
1962
1963 bool SpectateNext(entity this)
1964 {
1965         entity ent = find(this.enemy, classname, STR_PLAYER);
1966
1967         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1968                 ent = M_ARGV(1, entity);
1969         else if (!ent)
1970                 ent = find(ent, classname, STR_PLAYER);
1971
1972         if(ent) { SetSpectatee(this, ent); }
1973
1974         return SpectateSet(this);
1975 }
1976
1977 bool SpectatePrev(entity this)
1978 {
1979         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1980         entity ent = findchain(classname, STR_PLAYER);
1981         if (!ent) // no player
1982                 return false;
1983
1984         entity first = ent;
1985         // skip players until current spectated player
1986         if(this.enemy)
1987         while(ent && ent != this.enemy)
1988                 ent = ent.chain;
1989
1990         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1991         {
1992                 case MUT_SPECPREV_FOUND:
1993                         ent = M_ARGV(1, entity);
1994                         break;
1995                 case MUT_SPECPREV_RETURN:
1996                         return true;
1997                 case MUT_SPECPREV_CONTINUE:
1998                 default:
1999                 {
2000                         if(ent.chain)
2001                                 ent = ent.chain;
2002                         else
2003                                 ent = first;
2004                         break;
2005                 }
2006         }
2007
2008         SetSpectatee(this, ent);
2009         return SpectateSet(this);
2010 }
2011
2012 /*
2013 =============
2014 ShowRespawnCountdown()
2015
2016 Update a respawn countdown display.
2017 =============
2018 */
2019 void ShowRespawnCountdown(entity this)
2020 {
2021         float number;
2022         if(!IS_DEAD(this)) // just respawned?
2023                 return;
2024         else
2025         {
2026                 number = ceil(this.respawn_time - time);
2027                 if(number <= 0)
2028                         return;
2029                 if(number <= this.respawn_countdown)
2030                 {
2031                         this.respawn_countdown = number - 1;
2032                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2033                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2034                 }
2035         }
2036 }
2037
2038 .bool team_selected;
2039 bool ShowTeamSelection(entity this)
2040 {
2041         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2042                 return false;
2043         stuffcmd(this, "menu_showteamselect\n");
2044         return true;
2045 }
2046 void Join(entity this)
2047 {
2048         TRANSMUTE(Player, this);
2049
2050         if(!this.team_selected)
2051         if(autocvar_g_campaign || autocvar_g_balance_teams)
2052                 TeamBalance_JoinBestTeam(this);
2053
2054         if(autocvar_g_campaign)
2055                 campaign_bots_may_start = true;
2056
2057         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2058
2059         PutClientInServer(this);
2060
2061         if(IS_PLAYER(this))
2062         if(teamplay && this.team != -1)
2063         {
2064         }
2065         else
2066                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2067         this.team_selected = false;
2068 }
2069
2070 int GetPlayerLimit()
2071 {
2072         if(g_duel)
2073                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2074         int player_limit = autocvar_g_maxplayers;
2075         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2076         player_limit = M_ARGV(0, int);
2077         return player_limit;
2078 }
2079
2080 /**
2081  * Determines whether the player is allowed to join. This depends on cvar
2082  * g_maxplayers, if it isn't used this function always return true, otherwise
2083  * it checks whether the number of currently playing players exceeds g_maxplayers.
2084  * @return int number of free slots for players, 0 if none
2085  */
2086 int nJoinAllowed(entity this, entity ignore)
2087 {
2088         if(!ignore)
2089         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2090         // so report 0 free slots if restricted
2091         {
2092                 if(autocvar_g_forced_team_otherwise == "spectate")
2093                         return 0;
2094                 if(autocvar_g_forced_team_otherwise == "spectator")
2095                         return 0;
2096         }
2097
2098         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2099                 return 0; // forced spectators can never join
2100
2101         // TODO simplify this
2102         int totalClients = 0;
2103         int currentlyPlaying = 0;
2104         FOREACH_CLIENT(true, {
2105                 if(it != ignore)
2106                         ++totalClients;
2107                 if(IS_REAL_CLIENT(it))
2108                 if(IS_PLAYER(it) || it.caplayer)
2109                         ++currentlyPlaying;
2110         });
2111
2112         int player_limit = GetPlayerLimit();
2113
2114         int free_slots = 0;
2115         if (!player_limit)
2116                 free_slots = maxclients - totalClients;
2117         else if(player_limit > 0 && currentlyPlaying < player_limit)
2118                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2119
2120         static float msg_time = 0;
2121         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2122         {
2123                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2124                 msg_time = time + 0.5;
2125         }
2126
2127         return free_slots;
2128 }
2129
2130 /**
2131  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2132  * g_maxplayers_spectator_blocktime seconds
2133  */
2134 void checkSpectatorBlock(entity this)
2135 {
2136         if(IS_SPEC(this) || IS_OBSERVER(this))
2137         if(!this.caplayer)
2138         if(IS_REAL_CLIENT(this))
2139         {
2140                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2141                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2142                         dropclient(this);
2143                 }
2144         }
2145 }
2146
2147 void PrintWelcomeMessage(entity this)
2148 {
2149         if(CS(this).motd_actived_time == 0)
2150         {
2151                 if (autocvar_g_campaign) {
2152                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2153                                 CS(this).motd_actived_time = time;
2154                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2155                         }
2156                 } else {
2157                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2158                                 CS(this).motd_actived_time = time;
2159                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2160                         }
2161                 }
2162         }
2163         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2164         {
2165                 if (autocvar_g_campaign) {
2166                         if (PHYS_INPUT_BUTTON_INFO(this))
2167                                 CS(this).motd_actived_time = time;
2168                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2169                                 CS(this).motd_actived_time = 0;
2170                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2171                         }
2172                 } else {
2173                         if (PHYS_INPUT_BUTTON_INFO(this))
2174                                 CS(this).motd_actived_time = time;
2175                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2176                                 CS(this).motd_actived_time = 0;
2177                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2178                         }
2179                 }
2180         }
2181         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2182         {
2183                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2184                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2185                 else if (CS(this).motd_actived_time == -2)
2186                 {
2187                         // instantly hide MOTD
2188                         CS(this).motd_actived_time = 0;
2189                         if (autocvar_g_campaign)
2190                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2191                         else
2192                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2193                 }
2194                 else if (IS_PLAYER(this) || IS_SPEC(this))
2195                 {
2196                         // FIXME occasionally for some reason MOTD never goes away
2197                         // delay MOTD removal a little bit in the hope it fixes this bug
2198                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2199                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2200                         else //if (CS(this).motd_actived_time < -2)
2201                                 CS(this).motd_actived_time++;
2202                 }
2203         }
2204 }
2205
2206 bool joinAllowed(entity this)
2207 {
2208         if (CS(this).version_mismatch) return false;
2209         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2210         if (!nJoinAllowed(this, this)) return false;
2211         if (teamplay && lockteams) return false;
2212         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2213         if (ShowTeamSelection(this)) return false;
2214         return true;
2215 }
2216
2217 .string shootfromfixedorigin;
2218 .bool dualwielding_prev;
2219 bool PlayerThink(entity this)
2220 {
2221         if (game_stopped || intermission_running) {
2222                 this.modelflags &= ~MF_ROCKET;
2223                 if(intermission_running)
2224                         IntermissionThink(this);
2225                 return false;
2226         }
2227
2228         if (timeout_status == TIMEOUT_ACTIVE) {
2229                 // don't allow the player to turn around while game is paused
2230                 // FIXME turn this into CSQC stuff
2231                 this.v_angle = this.lastV_angle;
2232                 this.angles = this.lastV_angle;
2233                 this.fixangle = true;
2234         }
2235
2236         if (frametime) player_powerups(this);
2237
2238         if (IS_DEAD(this)) {
2239                 if (this.personal && g_race_qualifying) {
2240                         if (time > this.respawn_time) {
2241                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2242                                 respawn(this);
2243                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2244                         }
2245                 } else {
2246                         if (frametime) player_anim(this);
2247
2248                         if (this.respawn_flags & RESPAWN_DENY)
2249                         {
2250                                 STAT(RESPAWN_TIME, this) = 0;
2251                                 return false;
2252                         }
2253
2254                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2255
2256                         switch(this.deadflag)
2257                         {
2258                                 case DEAD_DYING:
2259                                 {
2260                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2261                                                 this.deadflag = DEAD_RESPAWNING;
2262                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2263                                                 this.deadflag = DEAD_DEAD;
2264                                         break;
2265                                 }
2266                                 case DEAD_DEAD:
2267                                 {
2268                                         if (button_pressed)
2269                                                 this.deadflag = DEAD_RESPAWNABLE;
2270                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2271                                                 this.deadflag = DEAD_RESPAWNING;
2272                                         break;
2273                                 }
2274                                 case DEAD_RESPAWNABLE:
2275                                 {
2276                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2277                                                 this.deadflag = DEAD_RESPAWNING;
2278                                         break;
2279                                 }
2280                                 case DEAD_RESPAWNING:
2281                                 {
2282                                         if (time > this.respawn_time)
2283                                         {
2284                                                 this.respawn_time = time + 1; // only retry once a second
2285                                                 this.respawn_time_max = this.respawn_time;
2286                                                 respawn(this);
2287                                         }
2288                                         break;
2289                                 }
2290                         }
2291
2292                         ShowRespawnCountdown(this);
2293
2294                         if (this.respawn_flags & RESPAWN_SILENT)
2295                                 STAT(RESPAWN_TIME, this) = 0;
2296                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2297                         {
2298                                 if (time < this.respawn_time)
2299                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2300                                 else if (this.deadflag != DEAD_RESPAWNING)
2301                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2302                         }
2303                         else
2304                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2305                 }
2306
2307                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2308                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2309                         STAT(RESPAWN_TIME, this) *= -1;
2310
2311                 return false;
2312         }
2313
2314         FixPlayermodel(this);
2315
2316         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2317                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2318                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2319         }
2320
2321         // reset gun alignment when dual wielding status changes
2322         // to ensure guns are always aligned right and left
2323         bool dualwielding = W_DualWielding(this);
2324         if(this.dualwielding_prev != dualwielding)
2325         {
2326                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2327                 this.dualwielding_prev = dualwielding;
2328         }
2329
2330         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2331         //if(frametime)
2332         {
2333                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2334                 {
2335                         .entity weaponentity = weaponentities[slot];
2336                         if(WEP_CVAR(vortex, charge_always))
2337                                 W_Vortex_Charge(this, weaponentity, frametime);
2338                         W_WeaponFrame(this, weaponentity);
2339                 }
2340         }
2341
2342         if (frametime)
2343         {
2344                 // WEAPONTODO: Add a weapon request for this
2345                 // rot vortex charge to the charge limit
2346                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2347                 {
2348                         .entity weaponentity = weaponentities[slot];
2349                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2350                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2351                 }
2352
2353                 player_regen(this);
2354                 player_anim(this);
2355                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2356         }
2357
2358         monsters_setstatus(this);
2359
2360         return true;
2361 }
2362
2363 .bool would_spectate;
2364 void ObserverOrSpectatorThink(entity this)
2365 {
2366         bool is_spec = IS_SPEC(this);
2367         if ( CS(this).impulse )
2368         {
2369                 int r = MinigameImpulse(this, CS(this).impulse);
2370                 if (!is_spec || r)
2371                         CS(this).impulse = 0;
2372
2373                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2374                 {
2375                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2376                         CS(this).impulse = 0;
2377                         return;
2378                 }
2379         }
2380
2381         if (this.flags & FL_JUMPRELEASED) {
2382                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2383                         this.flags &= ~FL_JUMPRELEASED;
2384                         this.flags |= FL_SPAWNING;
2385                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2386                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2387                         this.flags &= ~FL_JUMPRELEASED;
2388                         if(SpectateNext(this)) {
2389                                 TRANSMUTE(Spectator, this);
2390                         } else if (is_spec) {
2391                                 TRANSMUTE(Observer, this);
2392                                 PutClientInServer(this);
2393                         }
2394                         if (is_spec)
2395                                 CS(this).impulse = 0;
2396                 } else if (is_spec) {
2397                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2398                                 this.flags &= ~FL_JUMPRELEASED;
2399                                 if(SpectatePrev(this)) {
2400                                         TRANSMUTE(Spectator, this);
2401                                 } else {
2402                                         TRANSMUTE(Observer, this);
2403                                         PutClientInServer(this);
2404                                 }
2405                                 CS(this).impulse = 0;
2406                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2407                                 this.would_spectate = false;
2408                                 this.flags &= ~FL_JUMPRELEASED;
2409                                 TRANSMUTE(Observer, this);
2410                                 PutClientInServer(this);
2411                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2412                                 PutObserverInServer(this);
2413                                 this.would_spectate = true;
2414                         }
2415                 }
2416                 else {
2417                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2418                         set_movetype(this, preferred_movetype);
2419                 }
2420         } else {
2421                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2422                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2423                         this.flags |= FL_JUMPRELEASED;
2424                         if(this.flags & FL_SPAWNING)
2425                         {
2426                                 this.flags &= ~FL_SPAWNING;
2427                                 if(joinAllowed(this))
2428                                         Join(this);
2429                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2430                                         CS(this).autojoin_checked = -1;
2431                                 return;
2432                         }
2433                 }
2434                 if(is_spec && !SpectateUpdate(this))
2435                         PutObserverInServer(this);
2436         }
2437         if (is_spec)
2438                 this.flags |= FL_CLIENT | FL_NOTARGET;
2439 }
2440
2441 void PlayerUseKey(entity this)
2442 {
2443         if (!IS_PLAYER(this))
2444                 return;
2445
2446         if(this.vehicle)
2447         {
2448                 if(!game_stopped)
2449                 {
2450                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2451                         return;
2452                 }
2453         }
2454         else if(autocvar_g_vehicles_enter)
2455         {
2456                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2457                 {
2458                         entity head, closest_target = NULL;
2459                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2460
2461                         while(head) // find the closest acceptable target to enter
2462                         {
2463                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2464                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2465                                 {
2466                                         if(closest_target)
2467                                         {
2468                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2469                                                 { closest_target = head; }
2470                                         }
2471                                         else { closest_target = head; }
2472                                 }
2473
2474                                 head = head.chain;
2475                         }
2476
2477                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2478                 }
2479         }
2480
2481         // a use key was pressed; call handlers
2482         MUTATOR_CALLHOOK(PlayerUseKey, this);
2483 }
2484
2485
2486 /*
2487 =============
2488 PlayerPreThink
2489
2490 Called every frame for each client before the physics are run
2491 =============
2492 */
2493 .float last_vehiclecheck;
2494 void PlayerPreThink (entity this)
2495 {
2496         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2497         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2498
2499         WarpZone_PlayerPhysics_FixVAngle(this);
2500
2501         if (frametime) {
2502                 // physics frames: update anticheat stuff
2503                 anticheat_prethink(this);
2504         }
2505
2506         if (blockSpectators && frametime) {
2507                 // WORKAROUND: only use dropclient in server frames (frametime set).
2508                 // Never use it in cl_movement frames (frametime zero).
2509                 checkSpectatorBlock(this);
2510         }
2511
2512         zoomstate_set = false;
2513
2514         // Check for nameless players
2515         if (this.netname == "" || this.netname != CS(this).netname_previous)
2516         {
2517                 bool assume_unchanged = (CS(this).netname_previous == "");
2518                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2519                 {
2520                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2521                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2522                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2523                         assume_unchanged = false;
2524                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2525                 }
2526                 if (isInvisibleString(this.netname))
2527                 {
2528                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2529                         sprint(this, "Warning: invisible names are not allowed.\n");
2530                         assume_unchanged = false;
2531                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2532                 }
2533                 if (!assume_unchanged && autocvar_sv_eventlog)
2534                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2535                 strcpy(CS(this).netname_previous, this.netname);
2536         }
2537
2538         // version nagging
2539         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2540         CS(this).version_nagtime = 0;
2541         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2542             // git client
2543         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2544             // git server
2545             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2546         } else {
2547             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2548             if (r < 0) { // old client
2549                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2550             } else if (r > 0) { // old server
2551                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2552             }
2553         }
2554     }
2555
2556         // GOD MODE info
2557         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2558         {
2559                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2560                 this.max_armorvalue = 0;
2561         }
2562
2563         if (frametime && IS_PLAYER(this))
2564         {
2565                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2566                 {
2567                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2568                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2569                         if (this.iceblock)
2570                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2571
2572                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2573                                 Unfreeze(this, false);
2574                 }
2575                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2576                 {
2577                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2578                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2579
2580                         if (GetResource(this, RES_HEALTH) < 1)
2581                         {
2582                                 if (this.vehicle)
2583                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2584                                 if(this.event_damage)
2585                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2586                         }
2587                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2588                                 Unfreeze(this, false);
2589                 }
2590         }
2591
2592         MUTATOR_CALLHOOK(PlayerPreThink, this);
2593
2594         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2595         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2596         {
2597                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2598                 {
2599                         if(!it.owner)
2600                         {
2601                                 if(!it.team || SAME_TEAM(this, it))
2602                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2603                                 else if(autocvar_g_vehicles_steal)
2604                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2605                         }
2606                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2607                         {
2608                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2609                         }
2610                 });
2611
2612                 this.last_vehiclecheck = time + 1;
2613         }
2614
2615         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2616         {
2617                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2618                         PlayerUseKey(this);
2619                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2620         }
2621
2622         if (IS_REAL_CLIENT(this))
2623                 PrintWelcomeMessage(this);
2624
2625         if (IS_PLAYER(this)) {
2626                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2627                         error("Client can't be spawned as player on connection!");
2628                 if(!PlayerThink(this))
2629                         return;
2630         }
2631         else if (game_stopped || intermission_running) {
2632                 if(intermission_running)
2633                         IntermissionThink(this);
2634                 return;
2635         }
2636         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2637         {
2638                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2639                 CS(this).autojoin_checked = 1;
2640                 // don't do this in ClientConnect
2641                 // many things can go wrong if a client is spawned as player on connection
2642                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2643                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2644                                 && (!teamplay || autocvar_g_balance_teams)))
2645                 {
2646                         campaign_bots_may_start = true;
2647                         if(joinAllowed(this))
2648                                 Join(this);
2649                         return;
2650                 }
2651         }
2652         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2653                 ObserverOrSpectatorThink(this);
2654         }
2655
2656         // WEAPONTODO: Add weapon request for this
2657         if (!zoomstate_set) {
2658                 bool wep_zoomed = false;
2659                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2660                 {
2661                         .entity weaponentity = weaponentities[slot];
2662                         Weapon thiswep = this.(weaponentity).m_weapon;
2663                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2664                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2665                 }
2666                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2667         }
2668
2669         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2670         {
2671                 CS(this).teamkill_soundtime = 0;
2672
2673                 entity e = CS(this).teamkill_soundsource;
2674                 entity oldpusher = e.pusher;
2675                 e.pusher = this;
2676                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2677                 e.pusher = oldpusher;
2678         }
2679
2680         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2681                 CS(this).taunt_soundtime = 0;
2682                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2683         }
2684
2685         target_voicescript_next(this);
2686
2687         // WEAPONTODO: Move into weaponsystem somehow
2688         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2689         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2690         {
2691                 .entity weaponentity = weaponentities[slot];
2692                 if(this.(weaponentity).m_weapon == WEP_Null)
2693                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2694         }
2695 }
2696
2697 void DrownPlayer(entity this)
2698 {
2699         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2700                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2701         {
2702                 STAT(AIR_FINISHED, this) = 0;
2703                 return;
2704         }
2705
2706         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2707         {
2708                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2709                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2710                 STAT(AIR_FINISHED, this) = 0;
2711         }
2712         else
2713         {
2714                 if (!STAT(AIR_FINISHED, this))
2715                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2716                 if (STAT(AIR_FINISHED, this) < time)
2717                 {       // drown!
2718                         if (this.pain_finished < time)
2719                         {
2720                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2721                                 this.pain_finished = time + 0.5;
2722                         }
2723                 }
2724         }
2725 }
2726
2727 .bool move_qcphysics;
2728
2729 void Player_Physics(entity this)
2730 {
2731         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2732
2733         if(!this.move_qcphysics)
2734                 return;
2735
2736         if(!frametime && !CS(this).pm_frametime)
2737                 return;
2738
2739         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2740
2741         CS(this).pm_frametime = 0;
2742 }
2743
2744 /*
2745 =============
2746 PlayerPostThink
2747
2748 Called every frame for each client after the physics are run
2749 =============
2750 */
2751 void PlayerPostThink (entity this)
2752 {
2753         Player_Physics(this);
2754
2755         if (autocvar_sv_maxidle > 0)
2756         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2757         if (IS_REAL_CLIENT(this))
2758         if (IS_PLAYER(this) || autocvar_sv_maxidle_spectatorsareidle)
2759         {
2760                 int totalClients = 0;
2761                 if(autocvar_sv_maxidle_slots > 0)
2762                 {
2763                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2764                         {
2765                                 ++totalClients;
2766                         });
2767                 }
2768
2769                 if (autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2770                 { /* do nothing */ }
2771                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2772                 {
2773                         if (CS(this).idlekick_lasttimeleft)
2774                         {
2775                                 CS(this).idlekick_lasttimeleft = 0;
2776                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2777                         }
2778                 }
2779                 else
2780                 {
2781                         float timeleft = ceil(autocvar_sv_maxidle - (time - CS(this).parm_idlesince));
2782                         if (timeleft == min(10, autocvar_sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2783                                 if (!CS(this).idlekick_lasttimeleft)
2784                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2785                         }
2786                         if (timeleft <= 0) {
2787                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2788                                 dropclient(this);
2789                                 return;
2790                         }
2791                         else if (timeleft <= 10) {
2792                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2793                                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2794                                 CS(this).idlekick_lasttimeleft = timeleft;
2795                         }
2796                 }
2797         }
2798
2799         CheatFrame(this);
2800
2801         if (game_stopped)
2802         {
2803                 this.solid = SOLID_NOT;
2804                 this.takedamage = DAMAGE_NO;
2805                 set_movetype(this, MOVETYPE_NONE);
2806                 CS(this).teamkill_complain = 0;
2807                 CS(this).teamkill_soundtime = 0;
2808                 CS(this).teamkill_soundsource = NULL;
2809         }
2810
2811         if (IS_PLAYER(this)) {
2812                 if(this.death_time == time && IS_DEAD(this))
2813                 {
2814                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2815                         // once all the damage events of this frame have been processed with normal size
2816                         this.maxs.z = 5;
2817                         setsize(this, this.mins, this.maxs);
2818                 }
2819                 DrownPlayer(this);
2820                 UpdateChatBubble(this);
2821                 if (CS(this).impulse) ImpulseCommands(this);
2822                 if (game_stopped)
2823                 {
2824                         CSQCMODEL_AUTOUPDATE(this);
2825                         return;
2826                 }
2827                 GetPressedKeys(this);
2828         }
2829         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2830         {
2831                 CS(this).pressedkeys = 0;
2832                 STAT(PRESSED_KEYS, this) = 0;
2833         }
2834
2835         if (this.waypointsprite_attachedforcarrier) {
2836                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2837                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2838         }
2839
2840         CSQCMODEL_AUTOUPDATE(this);
2841 }
2842
2843 /**
2844  * message "": do not say, just test flood control
2845  * return value:
2846  *   1 = accept
2847  *   0 = reject
2848  *  -1 = fake accept
2849  */
2850 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2851 {
2852         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2853                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2854
2855         if (source)
2856                 msgin = formatmessage(source, msgin);
2857
2858         string colorstr;
2859         if (!(IS_PLAYER(source) || source.caplayer))
2860                 colorstr = "^0"; // black for spectators
2861         else if(teamplay)
2862                 colorstr = Team_ColorCode(source.team);
2863         else
2864         {
2865                 colorstr = "";
2866                 teamsay = false;
2867         }
2868
2869         if (!source) {
2870                 colorstr = "";
2871                 teamsay = false;
2872         }
2873
2874         if(msgin != "")
2875                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2876
2877         /*
2878          * using bprint solves this... me stupid
2879         // how can we prevent the message from appearing in a listen server?
2880         // for now, just give "say" back and only handle say_team
2881         if(!teamsay)
2882         {
2883                 clientcommand(source, strcat("say ", msgin));
2884                 return;
2885         }
2886         */
2887
2888         string namestr = "";
2889         if (source)
2890                 namestr = playername(source, autocvar_g_chat_teamcolors);
2891
2892         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2893
2894         string msgstr = "", cmsgstr = "";
2895         string privatemsgprefix = string_null;
2896         int privatemsgprefixlen = 0;
2897         if (msgin != "")
2898         {
2899                 bool found_me = false;
2900                 if(strstrofs(msgin, "/me", 0) >= 0)
2901                 {
2902                         string newmsgin = "";
2903                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2904                         FOREACH_WORD(msgin, true,
2905                         {
2906                                 if(strdecolorize(it) == "/me")
2907                                 {
2908                                         found_me = true;
2909                                         newmsgin = cons(newmsgin, newnamestr);
2910                                 }
2911                                 else
2912                                         newmsgin = cons(newmsgin, it);
2913                         });
2914                         msgin = newmsgin;
2915                 }
2916
2917                 if(privatesay)
2918                 {
2919                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2920                         privatemsgprefixlen = strlen(msgstr);
2921                         msgstr = strcat(msgstr, msgin);
2922                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2923                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2924                 }
2925                 else if(teamsay)
2926                 {
2927                         if(found_me)
2928                         {
2929                                 //msgin = strreplace("/me", "", msgin);
2930                                 //msgin = substring(msgin, 3, strlen(msgin));
2931                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2932                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2933                         }
2934                         else
2935                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2936                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2937                 }
2938                 else
2939                 {
2940                         if(found_me)
2941                         {
2942                                 //msgin = strreplace("/me", "", msgin);
2943                                 //msgin = substring(msgin, 3, strlen(msgin));
2944                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2945                                 msgstr = strcat("\{1}^4* ^7", msgin);
2946                         }
2947                         else {
2948                                 msgstr = "\{1}";
2949                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2950                                 msgstr = strcat(msgstr, msgin);
2951                         }
2952                         cmsgstr = "";
2953                 }
2954                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2955         }
2956
2957         string fullmsgstr = msgstr;
2958         string fullcmsgstr = cmsgstr;
2959
2960         // FLOOD CONTROL
2961         int flood = 0;
2962         var .float flood_field = floodcontrol_chat;
2963         if(floodcontrol && source)
2964         {
2965                 float flood_spl, flood_burst, flood_lmax;
2966                 if(privatesay)
2967                 {
2968                         flood_spl = autocvar_g_chat_flood_spl_tell;
2969                         flood_burst = autocvar_g_chat_flood_burst_tell;
2970                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2971                         flood_field = floodcontrol_chattell;
2972                 }
2973                 else if(teamsay)
2974                 {
2975                         flood_spl = autocvar_g_chat_flood_spl_team;
2976                         flood_burst = autocvar_g_chat_flood_burst_team;
2977                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2978                         flood_field = floodcontrol_chatteam;
2979                 }
2980                 else
2981                 {
2982                         flood_spl = autocvar_g_chat_flood_spl;
2983                         flood_burst = autocvar_g_chat_flood_burst;
2984                         flood_lmax = autocvar_g_chat_flood_lmax;
2985                         flood_field = floodcontrol_chat;
2986                 }
2987                 flood_burst = max(0, flood_burst - 1);
2988                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2989
2990                 // do flood control for the default line size
2991                 if(msgstr != "")
2992                 {
2993                         getWrappedLine_remaining = msgstr;
2994                         msgstr = "";
2995                         int lines = 0;
2996                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2997                         {
2998                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2999                                 ++lines;
3000                         }
3001                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
3002
3003                         if(getWrappedLine_remaining != "")
3004                         {
3005                                 msgstr = strcat(msgstr, "\n");
3006                                 flood = 2;
3007                         }
3008
3009                         if (time >= source.(flood_field))
3010                         {
3011                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
3012                         }
3013                         else
3014                         {
3015                                 flood = 1;
3016                                 msgstr = fullmsgstr;
3017                         }
3018                 }
3019                 else
3020                 {
3021                         if (time >= source.(flood_field))
3022                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
3023                         else
3024                                 flood = 1;
3025                 }
3026
3027                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
3028                         source.(flood_field) = flood = 0;
3029         }
3030
3031         string sourcemsgstr, sourcecmsgstr;
3032         if(flood == 2) // cannot happen for empty msgstr
3033         {
3034                 if(autocvar_g_chat_flood_notify_flooder)
3035                 {
3036                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
3037                         sourcecmsgstr = "";
3038                 }
3039                 else
3040                 {
3041                         sourcemsgstr = fullmsgstr;
3042                         sourcecmsgstr = fullcmsgstr;
3043                 }
3044                 cmsgstr = "";
3045         }
3046         else
3047         {
3048                 sourcemsgstr = msgstr;
3049                 sourcecmsgstr = cmsgstr;
3050         }
3051
3052         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer) && !game_stopped
3053                 && (teamsay || CHAT_NOSPECTATORS()))
3054         {
3055                 teamsay = -1; // spectators
3056         }
3057
3058         if(flood)
3059                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
3060
3061         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
3062         if(privatesay)
3063                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
3064
3065         int ret;
3066         if(source && CS(source).muted)
3067         {
3068                 // always fake the message
3069                 ret = -1;
3070         }
3071         else if(flood == 1)
3072         {
3073                 if (autocvar_g_chat_flood_notify_flooder)
3074                 {
3075                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
3076                         ret = 0;
3077                 }
3078                 else
3079                         ret = -1;
3080         }
3081         else
3082         {
3083                 ret = 1;
3084         }
3085
3086         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer) && !game_stopped
3087                 && (IS_PLAYER(privatesay) || privatesay.caplayer) && CHAT_NOSPECTATORS())
3088         {
3089                 ret = -1; // just hide the message completely
3090         }
3091
3092         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3093         ret = M_ARGV(1, int);
3094
3095         string event_log_msg = "";
3096
3097         if(sourcemsgstr != "" && ret != 0)
3098         {
3099                 if(ret < 0) // faked message, because the player is muted
3100                 {
3101                         sprint(source, sourcemsgstr);
3102                         if(sourcecmsgstr != "" && !privatesay)
3103                                 centerprint(source, sourcecmsgstr);
3104                 }
3105                 else if(privatesay) // private message, between 2 people only
3106                 {
3107                         sprint(source, sourcemsgstr);
3108                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
3109                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
3110                         {
3111                                 sprint(privatesay, msgstr);
3112                                 if(cmsgstr != "")
3113                                         centerprint(privatesay, cmsgstr);
3114                         }
3115                 }
3116                 else if ( teamsay && CS(source).active_minigame )
3117                 {
3118                         sprint(source, sourcemsgstr);
3119                         dedicated_print(msgstr); // send to server console too
3120                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3121                                 sprint(it, msgstr);
3122                         });
3123                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3124
3125                 }
3126                 else if(teamsay > 0) // team message, only sent to team mates
3127                 {
3128                         sprint(source, sourcemsgstr);
3129                         dedicated_print(msgstr); // send to server console too
3130                         if(sourcecmsgstr != "")
3131                                 centerprint(source, sourcecmsgstr);
3132                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3133                                 sprint(it, msgstr);
3134                                 if(cmsgstr != "")
3135                                         centerprint(it, cmsgstr);
3136                         });
3137                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3138                 }
3139                 else if(teamsay < 0) // spectator message, only sent to spectators
3140                 {
3141                         sprint(source, sourcemsgstr);
3142                         dedicated_print(msgstr); // send to server console too
3143                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3144                                 sprint(it, msgstr);
3145                         });
3146                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3147                 }
3148                 else
3149                 {
3150                         if (source) {
3151                                 sprint(source, sourcemsgstr);
3152                                 dedicated_print(msgstr); // send to server console too
3153                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3154                         }
3155                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3156                                 sprint(it, msgstr);
3157                         });
3158                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3159                 }
3160         }
3161
3162         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3163                 GameLogEcho(event_log_msg);
3164         }
3165
3166         return ret;
3167 }
3168
3169 // hack to copy the button fields from the client entity to the Client State
3170 void PM_UpdateButtons(entity this, entity store)
3171 {
3172         if(this.impulse)
3173                 store.impulse = this.impulse;
3174         this.impulse = 0;
3175
3176         bool typing = this.buttonchat || this.button12;
3177
3178         store.button0 = (typing) ? 0 : this.button0;
3179         //button1?!
3180         store.button2 = (typing) ? 0 : this.button2;
3181         store.button3 = (typing) ? 0 : this.button3;
3182         store.button4 = this.button4;
3183         store.button5 = (typing) ? 0 : this.button5;
3184         store.button6 = this.button6;
3185         store.button7 = this.button7;
3186         store.button8 = this.button8;
3187         store.button9 = this.button9;
3188         store.button10 = this.button10;
3189         store.button11 = this.button11;
3190         store.button12 = this.button12;
3191         store.button13 = this.button13;
3192         store.button14 = this.button14;
3193         store.button15 = this.button15;
3194         store.button16 = this.button16;
3195         store.buttonuse = this.buttonuse;
3196         store.buttonchat = this.buttonchat;
3197
3198         store.cursor_active = this.cursor_active;
3199         store.cursor_screen = this.cursor_screen;
3200         store.cursor_trace_start = this.cursor_trace_start;
3201         store.cursor_trace_endpos = this.cursor_trace_endpos;
3202         store.cursor_trace_ent = this.cursor_trace_ent;
3203
3204         store.ping = this.ping;
3205         store.ping_packetloss = this.ping_packetloss;
3206         store.ping_movementloss = this.ping_movementloss;
3207
3208         store.v_angle = this.v_angle;
3209         store.movement = this.movement;
3210 }
3211
3212 NET_HANDLE(fpsreport, bool)
3213 {
3214         int fps = ReadShort();
3215         PlayerScore_Set(sender, SP_FPS, fps);
3216         return true;
3217 }