qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include <server/gamelog.qh>
  24 #include "race.qh"
  25 #include "antilag.qh"
  26 #include "campaign.qh"
  27 #include "command/common.qh"
  28 #include "scores_rules.qh"
  29 #include "weapons/common.qh"
  30
  31 #include "bot/api.qh"
  32
  33 #include "../common/ent_cs.qh"
  34 #include "../common/wepent.qh"
  35 #include <common/state.qh>
  36
  37 #include "compat/quake3.qh"
  38
  39 #include <common/effects/qc/globalsound.qh>
  40
  41 #include "../common/mapobjects/func/conveyor.qh"
  42 #include <common/mapobjects/func/ladder.qh>
  43 #include "../common/mapobjects/teleporters.qh"
  44 #include "../common/mapobjects/target/spawnpoint.qh"
  45 #include <common/mapobjects/trigger/counter.qh>
  46 #include <common/mapobjects/trigger/swamp.qh>
  47
  48 #include "../common/vehicles/all.qh"
  49
  50 #include "weapons/hitplot.qh"
  51 #include "weapons/weaponsystem.qh"
  52
  53 #include "../common/net_notice.qh"
  54 #include "../common/net_linked.qh"
  55 #include "../common/physics/player.qh"
  56
  57 #include <common/vehicles/sv_vehicles.qh>
  58
  59 #include "../common/items/_mod.qh"
  60
  61 #include "../common/mutators/mutator/waypoints/all.qh"
  62 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  63 #include <common/gamemodes/_mod.qh>
  64
  65 #include "../common/mapobjects/subs.qh"
  66 #include "../common/mapobjects/triggers.qh"
  67 #include "../common/mapobjects/trigger/secret.qh"
  68
  69 #include "../common/minigames/sv_minigames.qh"
  70
  71 #include "../common/items/inventory.qh"
  72
  73 #include "../common/monsters/sv_monsters.qh"
  74
  75 #include "../lib/warpzone/server.qh"
  76
  77 #include <common/mutators/mutator/overkill/oknex.qh>
  78
  79 STATIC_METHOD(Client, Add, void(Client this, int _team))
  80 {
  81     ClientConnect(this);
  82     TRANSMUTE(Player, this);
  83     this.frame = 12; // 7
  84     this.team = _team;
  85     PutClientInServer(this);
  86 }
  87
  88 STATIC_METHOD(Client, Remove, void(Client this))
  89 {
  90     TRANSMUTE(Observer, this);
  91     PutClientInServer(this);
  92     ClientDisconnect(this);
  93 }
  94
  95 void send_CSQC_teamnagger() {
  96         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  97 }
  98
  99 int CountSpectators(entity player, entity to)
 100 {
 101         if(!player) { return 0; } // not sure how, but best to be safe
 102
 103         int spec_count = 0;
 104
 105         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 106         {
 107                 spec_count++;
 108         });
 109
 110         return spec_count;
 111 }
 112
 113 void WriteSpectators(entity player, entity to)
 114 {
 115         if(!player) { return; } // not sure how, but best to be safe
 116
 117         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 118         {
 119                 WriteByte(MSG_ENTITY, num_for_edict(it));
 120         });
 121 }
 122
 123 bool ClientData_Send(entity this, entity to, int sf)
 124 {
 125         assert(to == this.owner, return false);
 126
 127         entity e = to;
 128         if (IS_SPEC(e)) e = e.enemy;
 129
 130         sf = 0;
 131         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 132         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 133         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 134         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 135
 136         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 137         WriteByte(MSG_ENTITY, sf);
 138
 139         if (sf & BIT(1))
 140                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 141
 142         if(sf & BIT(4))
 143         {
 144                 float specs = CountSpectators(e, to);
 145                 WriteByte(MSG_ENTITY, specs);
 146                 WriteSpectators(e, to);
 147         }
 148
 149         return true;
 150 }
 151
 152 void ClientData_Attach(entity this)
 153 {
 154         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 155         CS(this).clientdata.drawonlytoclient = this;
 156         CS(this).clientdata.owner = this;
 157 }
 158
 159 void ClientData_Detach(entity this)
 160 {
 161         delete(CS(this).clientdata);
 162         CS(this).clientdata = NULL;
 163 }
 164
 165 void ClientData_Touch(entity e)
 166 {
 167         entity cd = CS(e).clientdata;
 168         if (cd) { cd.SendFlags = 1; }
 169
 170         // make it spectatable
 171         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 172         {
 173                 entity cd = CS(it).clientdata;
 174                 if (cd) { cd.SendFlags = 1; }
 175         });
 176 }
 177
 178
 179 /*
 180 =============
 181 CheckPlayerModel
 182
 183 Checks if the argument string can be a valid playermodel.
 184 Returns a valid one in doubt.
 185 =============
 186 */
 187 string FallbackPlayerModel;
 188 string CheckPlayerModel(string plyermodel) {
 189         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 190         {
 191                 // note: we cannot summon Don Strunzone here, some player may
 192                 // still have the model string set. In case anyone manages how
 193                 // to change a cvar default, we'll have a small leak here.
 194                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 195         }
 196         // only in right path
 197         if( substring(plyermodel,0,14) != "models/player/")
 198                 return FallbackPlayerModel;
 199         // only good file extensions
 200         if(substring(plyermodel,-4,4) != ".zym")
 201         if(substring(plyermodel,-4,4) != ".dpm")
 202         if(substring(plyermodel,-4,4) != ".iqm")
 203         if(substring(plyermodel,-4,4) != ".md3")
 204         if(substring(plyermodel,-4,4) != ".psk")
 205                 return FallbackPlayerModel;
 206         // forbid the LOD models
 207         if(substring(plyermodel, -9,5) == "_lod1")
 208                 return FallbackPlayerModel;
 209         if(substring(plyermodel, -9,5) == "_lod2")
 210                 return FallbackPlayerModel;
 211         if(plyermodel != strtolower(plyermodel))
 212                 return FallbackPlayerModel;
 213         // also, restrict to server models
 214         if(autocvar_sv_servermodelsonly)
 215         {
 216                 if(!fexists(plyermodel))
 217                         return FallbackPlayerModel;
 218         }
 219         return plyermodel;
 220 }
 221
 222 void setplayermodel(entity e, string modelname)
 223 {
 224         precache_model(modelname);
 225         _setmodel(e, modelname);
 226         player_setupanimsformodel(e);
 227         if(!autocvar_g_debug_globalsounds)
 228                 UpdatePlayerSounds(e);
 229 }
 230
 231 /** putting a client as observer in the server */
 232 void PutObserverInServer(entity this)
 233 {
 234     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 235         PlayerState_detach(this);
 236
 237         if (IS_PLAYER(this))
 238         {
 239                 if(GetResource(this, RES_HEALTH) >= 1)
 240                 {
 241                         // despawn effect
 242                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 243                 }
 244
 245                 // was a player, recount votes and ready status
 246                 if(IS_REAL_CLIENT(this))
 247                 {
 248                         if (vote_called) { VoteCount(false); }
 249                         ReadyCount();
 250                 }
 251     }
 252
 253     {
 254         entity spot = SelectSpawnPoint(this, true);
 255         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 256         this.angles = vec2(spot.angles);
 257         this.fixangle = true;
 258         // offset it so that the spectator spawns higher off the ground, looks better this way
 259         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 260         if (IS_REAL_CLIENT(this))
 261         {
 262             msg_entity = this;
 263             WriteByte(MSG_ONE, SVC_SETVIEW);
 264             WriteEntity(MSG_ONE, this);
 265         }
 266         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 267         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 268         if(!autocvar_g_debug_globalsounds)
 269         {
 270                 // needed for player sounds
 271                 this.model = "";
 272                 FixPlayermodel(this);
 273         }
 274         setmodel(this, MDL_Null);
 275         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 276         this.view_ofs = '0 0 0';
 277     }
 278
 279     RemoveGrapplingHooks(this);
 280         Portal_ClearAll(this);
 281         Unfreeze(this, false);
 282         SetSpectatee(this, NULL);
 283
 284         if (this.alivetime)
 285         {
 286                 if (!warmup_stage)
 287                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 288                 this.alivetime = 0;
 289         }
 290
 291         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 292
 293         WaypointSprite_PlayerDead(this);
 294
 295         if (CS(this).killcount != FRAGS_SPECTATOR)
 296         {
 297                 if(!game_stopped)
 298                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 299                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 300         }
 301
 302         accuracy_resend(this);
 303
 304         CS(this).spectatortime = time;
 305         if(this.bot_attack)
 306                 IL_REMOVE(g_bot_targets, this);
 307         this.bot_attack = false;
 308         if(this.monster_attack)
 309                 IL_REMOVE(g_monster_targets, this);
 310         this.monster_attack = false;
 311     STAT(HUD, this) = HUD_NORMAL;
 312         TRANSMUTE(Observer, this);
 313         this.iscreature = false;
 314         this.teleportable = TELEPORT_SIMPLE;
 315         if(this.damagedbycontents)
 316                 IL_REMOVE(g_damagedbycontents, this);
 317         this.damagedbycontents = false;
 318         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 319         SetSpectatee_status(this, etof(this));
 320         this.takedamage = DAMAGE_NO;
 321         this.solid = SOLID_NOT;
 322         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 323         this.flags = FL_CLIENT | FL_NOTARGET;
 324         this.effects = 0;
 325         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 326         this.pauserotarmor_finished = 0;
 327         this.pauserothealth_finished = 0;
 328         this.pauseregen_finished = 0;
 329         this.damageforcescale = 0;
 330         this.death_time = 0;
 331         this.respawn_flags = 0;
 332         this.respawn_time = 0;
 333         STAT(RESPAWN_TIME, this) = 0;
 334         this.alpha = 0;
 335         this.scale = 0;
 336         this.fade_time = 0;
 337         this.pain_frame = 0;
 338         this.pain_finished = 0;
 339         STAT(STRENGTH_FINISHED, this) = 0;
 340         STAT(INVINCIBLE_FINISHED, this) = 0;
 341         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 342         this.air_finished = 0;
 343         //this.dphitcontentsmask = 0;
 344         this.dphitcontentsmask = DPCONTENTS_SOLID;
 345         if (autocvar_g_playerclip_collisions)
 346                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 347         this.pushltime = 0;
 348         this.istypefrag = 0;
 349         setthink(this, func_null);
 350         this.nextthink = 0;
 351         this.deadflag = DEAD_NO;
 352         UNSET_DUCKED(this);
 353         STAT(REVIVE_PROGRESS, this) = 0;
 354         this.revival_time = 0;
 355         this.draggable = drag_undraggable;
 356
 357         this.items = 0;
 358         STAT(WEAPONS, this) = '0 0 0';
 359         this.drawonlytoclient = this;
 360
 361         this.viewloc = NULL;
 362
 363         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 364
 365         this.weaponmodel = "";
 366         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 367         {
 368                 this.weaponentities[slot] = NULL;
 369         }
 370         this.exteriorweaponentity = NULL;
 371         CS(this).killcount = FRAGS_SPECTATOR;
 372         this.velocity = '0 0 0';
 373         this.avelocity = '0 0 0';
 374         this.punchangle = '0 0 0';
 375         this.punchvector = '0 0 0';
 376         this.oldvelocity = this.velocity;
 377         this.fire_endtime = -1;
 378         this.event_damage = func_null;
 379         this.event_heal = func_null;
 380
 381         for(int slot = 0; slot < MAX_AXH; ++slot)
 382         {
 383                 entity axh = this.(AuxiliaryXhair[slot]);
 384                 this.(AuxiliaryXhair[slot]) = NULL;
 385
 386                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 387                         delete(axh);
 388         }
 389
 390         if (mutator_returnvalue)
 391         {
 392                 // mutator prevents resetting teams+score
 393         }
 394         else
 395         {
 396                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 397                 this.frags = FRAGS_SPECTATOR;
 398         }
 399         if (CS(this).just_joined)
 400                 CS(this).just_joined = false;
 401 }
 402
 403 int player_getspecies(entity this)
 404 {
 405         get_model_parameters(this.model, this.skin);
 406         int s = get_model_parameters_species;
 407         get_model_parameters(string_null, 0);
 408         if (s < 0) return SPECIES_HUMAN;
 409         return s;
 410 }
 411
 412 .float model_randomizer;
 413 void FixPlayermodel(entity player)
 414 {
 415         string defaultmodel = "";
 416         int defaultskin = 0;
 417         if(autocvar_sv_defaultcharacter)
 418         {
 419                 if(teamplay)
 420                 {
 421                         switch(player.team)
 422                         {
 423                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 424                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 425                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 426                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 427                         }
 428                 }
 429
 430                 if(defaultmodel == "")
 431                 {
 432                         defaultmodel = autocvar_sv_defaultplayermodel;
 433                         defaultskin = autocvar_sv_defaultplayerskin;
 434                 }
 435
 436                 int n = tokenize_console(defaultmodel);
 437                 if(n > 0)
 438                 {
 439                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 440                         // However, do NOT randomize if the player-selected model is in the list.
 441                         for (int i = 0; i < n; ++i)
 442                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 443                                         defaultmodel = argv(i);
 444                 }
 445
 446                 int i = strstrofs(defaultmodel, ":", 0);
 447                 if(i >= 0)
 448                 {
 449                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 450                         defaultmodel = substring(defaultmodel, 0, i);
 451                 }
 452         }
 453         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 454         {
 455                 if(teamplay)
 456                 {
 457                         switch(player.team)
 458                         {
 459                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 460                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 461                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 462                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 463                         }
 464                 }
 465
 466                 if(!defaultskin)
 467                         defaultskin = autocvar_sv_defaultplayerskin;
 468         }
 469
 470         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 471         defaultmodel = M_ARGV(0, string);
 472         defaultskin = M_ARGV(1, int);
 473
 474         bool chmdl = false;
 475         int oldskin;
 476         if(defaultmodel != "")
 477         {
 478                 if (defaultmodel != player.model)
 479                 {
 480                         vector m1 = player.mins;
 481                         vector m2 = player.maxs;
 482                         setplayermodel (player, defaultmodel);
 483                         setsize (player, m1, m2);
 484                         chmdl = true;
 485                 }
 486
 487                 oldskin = player.skin;
 488                 player.skin = defaultskin;
 489         } else {
 490                 if (player.playermodel != player.model || player.playermodel == "")
 491                 {
 492                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 493                         vector m1 = player.mins;
 494                         vector m2 = player.maxs;
 495                         setplayermodel (player, player.playermodel);
 496                         setsize (player, m1, m2);
 497                         chmdl = true;
 498                 }
 499
 500                 if(!autocvar_sv_defaultcharacterskin)
 501                 {
 502                         oldskin = player.skin;
 503                         player.skin = stof(player.playerskin);
 504                 }
 505                 else
 506                 {
 507                         oldskin = player.skin;
 508                         player.skin = defaultskin;
 509                 }
 510         }
 511
 512         if(chmdl || oldskin != player.skin) // model or skin has changed
 513         {
 514                 player.species = player_getspecies(player); // update species
 515                 if(!autocvar_g_debug_globalsounds)
 516                         UpdatePlayerSounds(player); // update skin sounds
 517         }
 518
 519         if(!teamplay)
 520                 if(strlen(autocvar_sv_defaultplayercolors))
 521                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 522                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 523 }
 524
 525 void PutPlayerInServer(entity this)
 526 {
 527         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 528
 529         PlayerState_attach(this);
 530         accuracy_resend(this);
 531
 532         if (this.team < 0)
 533                 TeamBalance_JoinBestTeam(this);
 534
 535         entity spot = SelectSpawnPoint(this, false);
 536         if (!spot) {
 537                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 538                 return; // spawn failed
 539         }
 540
 541         TRANSMUTE(Player, this);
 542
 543         CS(this).wasplayer = true;
 544         this.iscreature = true;
 545         this.teleportable = TELEPORT_NORMAL;
 546         if(!this.damagedbycontents)
 547                 IL_PUSH(g_damagedbycontents, this);
 548         this.damagedbycontents = true;
 549         set_movetype(this, MOVETYPE_WALK);
 550         this.solid = SOLID_SLIDEBOX;
 551         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 552         if (autocvar_g_playerclip_collisions)
 553                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 554         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 555                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 556         this.frags = FRAGS_PLAYER;
 557         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 558         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 559         if (autocvar__notarget)
 560                 this.flags |= FL_NOTARGET;
 561         this.takedamage = DAMAGE_AIM;
 562         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 563
 564         if (warmup_stage) {
 565                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 566                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 567                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 568                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 569                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 570                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 571                 SetResource(this, RES_HEALTH, warmup_start_health);
 572                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 573                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 574         } else {
 575                 SetResource(this, RES_SHELLS, start_ammo_shells);
 576                 SetResource(this, RES_BULLETS, start_ammo_nails);
 577                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 578                 SetResource(this, RES_CELLS, start_ammo_cells);
 579                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 580                 SetResource(this, RES_FUEL, start_ammo_fuel);
 581                 SetResource(this, RES_HEALTH, start_health);
 582                 SetResource(this, RES_ARMOR, start_armorvalue);
 583                 STAT(WEAPONS, this) = start_weapons;
 584                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 585                 {
 586                         GiveRandomWeapons(this, random_start_weapons_count,
 587                                 autocvar_g_random_start_weapons, random_start_ammo);
 588                 }
 589         }
 590         SetSpectatee_status(this, 0);
 591
 592         PS(this).dual_weapons = '0 0 0';
 593
 594         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 595
 596         this.items = start_items;
 597
 598         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 599         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 600         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 601         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 602         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 603         if (!sv_ready_restart_after_countdown && time < game_starttime)
 604         {
 605                 float f = game_starttime - time;
 606                 this.spawnshieldtime += f;
 607                 this.pauserotarmor_finished += f;
 608                 this.pauserothealth_finished += f;
 609                 this.pauseregen_finished += f;
 610         }
 611
 612         this.damageforcescale = autocvar_g_player_damageforcescale;
 613         this.death_time = 0;
 614         this.respawn_flags = 0;
 615         this.respawn_time = 0;
 616         STAT(RESPAWN_TIME, this) = 0;
 617         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 618         this.fade_time = 0;
 619         this.pain_frame = 0;
 620         this.pain_finished = 0;
 621         this.pushltime = 0;
 622         setthink(this, func_null); // players have no think function
 623         this.nextthink = 0;
 624         this.dmg_team = 0;
 625         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 626
 627         this.deadflag = DEAD_NO;
 628
 629         this.angles = spot.angles;
 630         this.angles_z = 0; // never spawn tilted even if the spot says to
 631         if (IS_BOT_CLIENT(this))
 632         {
 633                 this.v_angle = this.angles;
 634                 bot_aim_reset(this);
 635         }
 636         this.fixangle = true; // turn this way immediately
 637         this.oldvelocity = this.velocity = '0 0 0';
 638         this.avelocity = '0 0 0';
 639         this.punchangle = '0 0 0';
 640         this.punchvector = '0 0 0';
 641
 642         STAT(STRENGTH_FINISHED, this) = 0;
 643         STAT(INVINCIBLE_FINISHED, this) = 0;
 644         this.fire_endtime = -1;
 645         STAT(REVIVE_PROGRESS, this) = 0;
 646         this.revival_time = 0;
 647
 648         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 649         STAT(BUFFS, this) = 0;
 650         STAT(BUFF_TIME, this) = 0;
 651
 652         this.air_finished = 0;
 653         this.waterlevel = WATERLEVEL_NONE;
 654         this.watertype = CONTENT_EMPTY;
 655
 656         entity spawnevent = new_pure(spawnevent);
 657         spawnevent.owner = this;
 658         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 659
 660         // Cut off any still running player sounds.
 661         stopsound(this, CH_PLAYER_SINGLE);
 662
 663         this.model = "";
 664         FixPlayermodel(this);
 665         this.drawonlytoclient = NULL;
 666
 667         this.viewloc = NULL;
 668
 669         for(int slot = 0; slot < MAX_AXH; ++slot)
 670         {
 671                 entity axh = this.(AuxiliaryXhair[slot]);
 672                 this.(AuxiliaryXhair[slot]) = NULL;
 673
 674                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 675                         delete(axh);
 676         }
 677
 678         this.spawnpoint_targ = NULL;
 679
 680         UNSET_DUCKED(this);
 681         this.view_ofs = STAT(PL_VIEW_OFS, this);
 682         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 683         this.spawnorigin = spot.origin;
 684         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 685         // don't reset back to last position, even if new position is stuck in solid
 686         this.oldorigin = this.origin;
 687         if(this.conveyor)
 688                 IL_REMOVE(g_conveyed, this);
 689         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 690         if(this.swampslug)
 691                 IL_REMOVE(g_swamped, this);
 692         this.swampslug = NULL;
 693         this.swamp_interval = 0;
 694         if(this.ladder_entity)
 695                 IL_REMOVE(g_ladderents, this);
 696         this.ladder_entity = NULL;
 697         IL_EACH(g_counters, it.realowner == this,
 698         {
 699                 delete(it);
 700         });
 701         STAT(HUD, this) = HUD_NORMAL;
 702
 703         this.event_damage = PlayerDamage;
 704         this.event_heal = PlayerHeal;
 705
 706         this.draggable = func_null;
 707
 708         if(!this.bot_attack)
 709                 IL_PUSH(g_bot_targets, this);
 710         this.bot_attack = true;
 711         if(!this.monster_attack)
 712                 IL_PUSH(g_monster_targets, this);
 713         this.monster_attack = true;
 714         navigation_dynamicgoal_init(this, false);
 715
 716         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 717
 718         // player was spectator
 719         if (CS(this).killcount == FRAGS_SPECTATOR) {
 720                 PlayerScore_Clear(this);
 721                 CS(this).killcount = 0;
 722                 CS(this).startplaytime = time;
 723         }
 724
 725         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 726         {
 727                 .entity weaponentity = weaponentities[slot];
 728                 CL_SpawnWeaponentity(this, weaponentity);
 729         }
 730         this.alpha = default_player_alpha;
 731         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 732         this.exteriorweaponentity.alpha = default_weapon_alpha;
 733
 734         this.speedrunning = false;
 735
 736         this.counter_cnt = 0;
 737         this.fragsfilter_cnt = 0;
 738
 739         target_voicescript_clear(this);
 740
 741         // reset fields the weapons may use
 742         FOREACH(Weapons, true, {
 743                 it.wr_resetplayer(it, this);
 744                         // reload all reloadable weapons
 745                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 746                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 747                         {
 748                                 .entity weaponentity = weaponentities[slot];
 749                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 750                         }
 751                 }
 752         });
 753
 754         {
 755                 string s = spot.target;
 756                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 757                         spot.target = string_null;
 758                 SUB_UseTargets(spot, this, NULL);
 759                 if(g_assault || g_race)
 760                         spot.target = s;
 761         }
 762
 763         Unfreeze(this, false);
 764
 765         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 766
 767         if (autocvar_spawn_debug)
 768         {
 769                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 770                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 771         }
 772
 773         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 774         {
 775                 .entity weaponentity = weaponentities[slot];
 776                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 777                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 778                 else
 779                         this.(weaponentity).m_switchweapon = WEP_Null;
 780                 this.(weaponentity).m_weapon = WEP_Null;
 781                 this.(weaponentity).weaponname = "";
 782                 this.(weaponentity).m_switchingweapon = WEP_Null;
 783                 this.(weaponentity).cnt = -1;
 784         }
 785
 786         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 787
 788         if (CS(this).impulse) ImpulseCommands(this);
 789
 790         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 791         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 792         {
 793                 .entity weaponentity = weaponentities[slot];
 794                 W_WeaponFrame(this, weaponentity);
 795         }
 796
 797         if (!warmup_stage && !this.alivetime)
 798                 this.alivetime = time;
 799
 800         antilag_clear(this, CS(this));
 801 }
 802
 803 /** Called when a client spawns in the server */
 804 void PutClientInServer(entity this)
 805 {
 806         if (IS_BOT_CLIENT(this)) {
 807                 TRANSMUTE(Player, this);
 808         } else if (IS_REAL_CLIENT(this)) {
 809                 msg_entity = this;
 810                 WriteByte(MSG_ONE, SVC_SETVIEW);
 811                 WriteEntity(MSG_ONE, this);
 812         }
 813         if (game_stopped)
 814                 TRANSMUTE(Observer, this);
 815
 816         SetSpectatee(this, NULL);
 817
 818         // reset player keys
 819         if(PS(this))
 820                 PS(this).itemkeys = 0;
 821
 822         MUTATOR_CALLHOOK(PutClientInServer, this);
 823
 824         if (IS_OBSERVER(this)) {
 825                 PutObserverInServer(this);
 826         } else if (IS_PLAYER(this)) {
 827                 PutPlayerInServer(this);
 828         }
 829 }
 830
 831 // TODO do we need all these fields, or should we stop autodetecting runtime
 832 // changes and just have a console command to update this?
 833 bool ClientInit_SendEntity(entity this, entity to, int sf)
 834 {
 835         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 836         return = true;
 837         msg_entity = to;
 838         // MSG_INIT replacement
 839         // TODO: make easier to use
 840         Registry_send_all();
 841         W_PROP_reload(MSG_ONE, to);
 842         ClientInit_misc(this);
 843         MUTATOR_CALLHOOK(Ent_Init);
 844 }
 845 void ClientInit_misc(entity this)
 846 {
 847         int channel = MSG_ONE;
 848         WriteHeader(channel, ENT_CLIENT_INIT);
 849         WriteByte(channel, g_nexball_meter_period * 32);
 850         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 851         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 852         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 853         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 854         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 855         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 856         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 857         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 858
 859         if(sv_foginterval && world.fog != "")
 860                 WriteString(channel, world.fog);
 861         else
 862                 WriteString(channel, "");
 863         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 864         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 865         WriteByte(channel, serverflags);
 866         WriteCoord(channel, autocvar_g_trueaim_minrange);
 867 }
 868
 869 void ClientInit_CheckUpdate(entity this)
 870 {
 871         this.nextthink = time;
 872         if(this.count != autocvar_g_balance_armor_blockpercent)
 873         {
 874                 this.count = autocvar_g_balance_armor_blockpercent;
 875                 this.SendFlags |= 1;
 876         }
 877         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 878         {
 879                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 880                 this.SendFlags |= 1;
 881         }
 882 }
 883
 884 void ClientInit_Spawn()
 885 {
 886         entity e = new_pure(clientinit);
 887         setthink(e, ClientInit_CheckUpdate);
 888         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 889
 890         ClientInit_CheckUpdate(e);
 891 }
 892
 893 /*
 894 =============
 895 SetNewParms
 896 =============
 897 */
 898 void SetNewParms ()
 899 {
 900         // initialize parms for a new player
 901         parm1 = -(86400 * 366);
 902
 903         MUTATOR_CALLHOOK(SetNewParms);
 904 }
 905
 906 /*
 907 =============
 908 SetChangeParms
 909 =============
 910 */
 911 void SetChangeParms (entity this)
 912 {
 913         // save parms for level change
 914         parm1 = CS(this).parm_idlesince - time;
 915
 916         MUTATOR_CALLHOOK(SetChangeParms);
 917 }
 918
 919 /*
 920 =============
 921 DecodeLevelParms
 922 =============
 923 */
 924 void DecodeLevelParms(entity this)
 925 {
 926         // load parms
 927         CS(this).parm_idlesince = parm1;
 928         if (CS(this).parm_idlesince == -(86400 * 366))
 929                 CS(this).parm_idlesince = time;
 930
 931         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 932         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 933
 934         MUTATOR_CALLHOOK(DecodeLevelParms);
 935 }
 936
 937 void FixClientCvars(entity e)
 938 {
 939         // send prediction settings to the client
 940         stuffcmd(e, "\nin_bindmap 0 0\n");
 941         if(autocvar_g_antilag == 3) // client side hitscan
 942                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 943         if(autocvar_sv_gentle)
 944                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 945
 946         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 947         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 948
 949         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 950
 951         MUTATOR_CALLHOOK(FixClientCvars, e);
 952 }
 953
 954 bool findinlist_abbrev(string tofind, string list)
 955 {
 956         if(list == "" || tofind == "")
 957                 return false; // empty list or search, just return
 958
 959         // this function allows abbreviated strings!
 960         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 961         {
 962                 return true;
 963         });
 964
 965         return false;
 966 }
 967
 968 bool PlayerInIPList(entity p, string iplist)
 969 {
 970         // some safety checks (never allow local?)
 971         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 972                 return false;
 973
 974         return findinlist_abbrev(p.netaddress, iplist);
 975 }
 976
 977 bool PlayerInIDList(entity p, string idlist)
 978 {
 979         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 980         if(!p.crypto_idfp)
 981                 return false;
 982
 983         return findinlist_abbrev(p.crypto_idfp, idlist);
 984 }
 985
 986 bool PlayerInList(entity player, string list)
 987 {
 988         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 989 }
 990
 991 #ifdef DP_EXT_PRECONNECT
 992 /*
 993 =============
 994 ClientPreConnect
 995
 996 Called once (not at each match start) when a client begins a connection to the server
 997 =============
 998 */
 999 void ClientPreConnect(entity this)
1000 {
1001         if(autocvar_sv_eventlog)
1002         {
1003                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1004                         this.playerid,
1005                         etof(this),
1006                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1007                 ));
1008         }
1009 }
1010 #endif
1011
1012 string GetClientVersionMessage(entity this)
1013 {
1014         if (CS(this).version_mismatch) {
1015                 if(CS(this).version < autocvar_gameversion) {
1016                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1017                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1018                 } else {
1019                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1020                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1021                 }
1022         } else {
1023                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1024         }
1025 }
1026
1027 string getwelcomemessage(entity this)
1028 {
1029         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1030         string modifications = M_ARGV(0, string);
1031
1032         if(g_weaponarena)
1033         {
1034                 if(g_weaponarena_random)
1035                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1036                 else
1037                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1038         }
1039         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1040                 modifications = strcat(modifications, ", No start weapons");
1041         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1042                 modifications = strcat(modifications, ", Low gravity");
1043         if(g_weapon_stay && !g_cts)
1044                 modifications = strcat(modifications, ", Weapons stay");
1045         if(g_jetpack)
1046                 modifications = strcat(modifications, ", Jet pack");
1047         if(autocvar_g_powerups == 0)
1048                 modifications = strcat(modifications, ", No powerups");
1049         if(autocvar_g_powerups > 0)
1050                 modifications = strcat(modifications, ", Powerups");
1051         modifications = substring(modifications, 2, strlen(modifications) - 2);
1052
1053         string versionmessage = GetClientVersionMessage(this);
1054         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1055
1056         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1057
1058         if(modifications != "")
1059                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1060
1061         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1062         {
1063                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1064                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1065         }
1066
1067         if (cache_mutatormsg != "") {
1068                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1069         }
1070
1071         string mutator_msg = "";
1072         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1073         mutator_msg = M_ARGV(0, string);
1074
1075         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1076
1077         string motd = autocvar_sv_motd;
1078         if (motd != "") {
1079                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1080         }
1081         return s;
1082 }
1083
1084 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1085
1086 /**
1087 =============
1088 ClientConnect
1089
1090 Called when a client connects to the server
1091 =============
1092 */
1093 void ClientConnect(entity this)
1094 {
1095         if (Ban_MaybeEnforceBanOnce(this)) return;
1096         assert(!IS_CLIENT(this), return);
1097         this.flags |= FL_CLIENT;
1098         assert(player_count >= 0, player_count = 0);
1099
1100 #ifdef WATERMARK
1101         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1102 #endif
1103         TRANSMUTE(Client, this);
1104         CS(this).version_nagtime = time + 10 + random() * 10;
1105
1106         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1107
1108         bot_clientconnect(this);
1109
1110         Player_DetermineForcedTeam(this);
1111
1112         TRANSMUTE(Observer, this);
1113
1114         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1115
1116         // always track bots, don't ask for cl_allow_uidtracking
1117         if (IS_BOT_CLIENT(this))
1118                 PlayerStats_GameReport_AddPlayer(this);
1119         else
1120                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1121
1122         if (autocvar_sv_eventlog)
1123                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1124
1125         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1126
1127         stuffcmd(this, clientstuff, "\n");
1128         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1129
1130         FixClientCvars(this);
1131
1132         // get version info from player
1133         stuffcmd(this, "cmd clientversion $gameversion\n");
1134
1135         // notify about available teams
1136         if (teamplay)
1137         {
1138                 entity balance = TeamBalance_CheckAllowedTeams(this);
1139                 int t = TeamBalance_GetAllowedTeams(balance);
1140                 TeamBalance_Destroy(balance);
1141                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1142         }
1143         else
1144         {
1145                 stuffcmd(this, "set _teams_available 0\n");
1146         }
1147
1148         bot_relinkplayerlist();
1149
1150         CS(this).spectatortime = time;
1151         if (blockSpectators)
1152         {
1153                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1154         }
1155
1156         CS(this).jointime = time;
1157
1158         if (IS_REAL_CLIENT(this))
1159         {
1160                 if (g_weaponarena_weapons == WEPSET(TUBA))
1161                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1162         }
1163
1164         if (!sv_foginterval && world.fog != "")
1165                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1166
1167         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1168                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1169                         send_CSQC_teamnagger();
1170
1171         CSQCMODEL_AUTOINIT(this);
1172
1173         CS(this).model_randomizer = random();
1174
1175         if (IS_REAL_CLIENT(this))
1176                 sv_notice_join(this);
1177
1178         this.move_qcphysics = autocvar_sv_qcphysics;
1179
1180         // update physics stats (players can spawn before physics runs)
1181         Physics_UpdateStats(this);
1182
1183         IL_EACH(g_initforplayer, it.init_for_player, {
1184                 it.init_for_player(it, this);
1185         });
1186
1187         Handicap_Initialize(this);
1188
1189         MUTATOR_CALLHOOK(ClientConnect, this);
1190
1191         if (IS_REAL_CLIENT(this))
1192         {
1193                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1194                 {
1195                         CS(this).motd_actived_time = -1;
1196                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1197                 }
1198         }
1199 }
1200 /*
1201 =============
1202 ClientDisconnect
1203
1204 Called when a client disconnects from the server
1205 =============
1206 */
1207 .entity chatbubbleentity;
1208 void ClientDisconnect(entity this)
1209 {
1210         assert(IS_CLIENT(this), return);
1211
1212         PlayerStats_GameReport_FinalizePlayer(this);
1213         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1214         if (CS(this).active_minigame) part_minigame(this);
1215         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1216
1217         if (autocvar_sv_eventlog)
1218                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1219
1220         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1221
1222         if(IS_SPEC(this))
1223                 SetSpectatee(this, NULL);
1224
1225     MUTATOR_CALLHOOK(ClientDisconnect, this);
1226
1227         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1228         strfree(CS(this).weaponorder_byimpulse);
1229         ClientState_detach(this);
1230
1231         Portal_ClearAll(this);
1232
1233         Unfreeze(this, false);
1234
1235         RemoveGrapplingHooks(this);
1236
1237         // Here, everything has been done that requires this player to be a client.
1238
1239         this.flags &= ~FL_CLIENT;
1240
1241         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1242         if (this.killindicator) delete(this.killindicator);
1243
1244         IL_EACH(g_counters, it.realowner == this,
1245         {
1246                 delete(it);
1247         });
1248
1249         WaypointSprite_PlayerGone(this);
1250
1251         bot_relinkplayerlist();
1252
1253         strfree(this.clientstatus);
1254         if (this.personal) delete(this.personal);
1255
1256         this.playerid = 0;
1257         ReadyCount();
1258         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1259
1260         ONREMOVE(this);
1261 }
1262
1263 void ChatBubbleThink(entity this)
1264 {
1265         this.nextthink = time;
1266         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1267         {
1268                 if(this.owner) // but why can that ever be NULL?
1269                         this.owner.chatbubbleentity = NULL;
1270                 delete(this);
1271                 return;
1272         }
1273
1274         this.mdl = "";
1275
1276         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1277         {
1278                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1279                         this.mdl = "models/sprites/minigame_busy.iqm";
1280                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1281                         this.mdl = "models/misc/chatbubble.spr";
1282         }
1283
1284         if ( this.model != this.mdl )
1285                 _setmodel(this, this.mdl);
1286
1287 }
1288
1289 void UpdateChatBubble(entity this)
1290 {
1291         if (this.alpha < 0)
1292                 return;
1293         // spawn a chatbubble entity if needed
1294         if (!this.chatbubbleentity)
1295         {
1296                 this.chatbubbleentity = new(chatbubbleentity);
1297                 this.chatbubbleentity.owner = this;
1298                 this.chatbubbleentity.exteriormodeltoclient = this;
1299                 setthink(this.chatbubbleentity, ChatBubbleThink);
1300                 this.chatbubbleentity.nextthink = time;
1301                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1302                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1303                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1304                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1305                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1306                 //this.chatbubbleentity.model = "";
1307                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1308         }
1309 }
1310
1311 void calculate_player_respawn_time(entity this)
1312 {
1313         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1314                 return;
1315
1316         float gametype_setting_tmp;
1317         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1318         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1319         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1320         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1321         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1322         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1323
1324         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1325         if (teamplay)
1326         {
1327                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1328                         if(it.team == this.team)
1329                                 ++pcount;
1330                 });
1331                 if (sdelay_small_count == 0)
1332                         sdelay_small_count = 1;
1333                 if (sdelay_large_count == 0)
1334                         sdelay_large_count = 1;
1335         }
1336         else
1337         {
1338                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1339                         ++pcount;
1340                 });
1341                 if (sdelay_small_count == 0)
1342                 {
1343                         if (IS_INDEPENDENT_PLAYER(this))
1344                         {
1345                                 // Players play independently. No point in requiring enemies.
1346                                 sdelay_small_count = 1;
1347                         }
1348                         else
1349                         {
1350                                 // Players play AGAINST each other. Enemies required.
1351                                 sdelay_small_count = 2;
1352                         }
1353                 }
1354                 if (sdelay_large_count == 0)
1355                 {
1356                         if (IS_INDEPENDENT_PLAYER(this))
1357                         {
1358                                 // Players play independently. No point in requiring enemies.
1359                                 sdelay_large_count = 1;
1360                         }
1361                         else
1362                         {
1363                                 // Players play AGAINST each other. Enemies required.
1364                                 sdelay_large_count = 2;
1365                         }
1366                 }
1367         }
1368
1369         float sdelay;
1370
1371         if (pcount <= sdelay_small_count)
1372                 sdelay = sdelay_small;
1373         else if (pcount >= sdelay_large_count)
1374                 sdelay = sdelay_large;
1375         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1376                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1377
1378         if(waves)
1379                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1380         else
1381                 this.respawn_time = time + sdelay;
1382
1383         if(sdelay < sdelay_max)
1384                 this.respawn_time_max = time + sdelay_max;
1385         else
1386                 this.respawn_time_max = this.respawn_time;
1387
1388         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1389                 this.respawn_countdown = 10; // first number to count down from is 10
1390         else
1391                 this.respawn_countdown = -1; // do not count down
1392
1393         if(autocvar_g_forced_respawn)
1394                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1395 }
1396
1397 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1398 // added to the model skins
1399 /*void UpdateColorModHack()
1400 {
1401         float c;
1402         c = this.clientcolors & 15;
1403         // LordHavoc: only bothering to support white, green, red, yellow, blue
1404              if (!teamplay) this.colormod = '0 0 0';
1405         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1406         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1407         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1408         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1409         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1410         else this.colormod = '1 1 1';
1411 }*/
1412
1413 void respawn(entity this)
1414 {
1415         bool damagedbycontents_prev = this.damagedbycontents;
1416         if(this.alpha >= 0)
1417         {
1418                 if(autocvar_g_respawn_ghosts)
1419                 {
1420                         this.solid = SOLID_NOT;
1421                         this.takedamage = DAMAGE_NO;
1422                         this.damagedbycontents = false;
1423                         set_movetype(this, MOVETYPE_FLY);
1424                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1425                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1426                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1427                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1428                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1429                         if(autocvar_g_respawn_ghosts_time > 0)
1430                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1431                 }
1432                 else
1433                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1434         }
1435
1436         CopyBody(this, 1);
1437         this.damagedbycontents = damagedbycontents_prev;
1438
1439         this.effects |= EF_NODRAW; // prevent another CopyBody
1440         PutClientInServer(this);
1441 }
1442
1443 ERASEABLE
1444 void PrintToChat(entity client, string text)
1445 {
1446         text = strcat("\{1}^7", text, "\n");
1447         sprint(client, text);
1448 }
1449
1450 ERASEABLE
1451 void DebugPrintToChat(entity client, string text)
1452 {
1453         if (autocvar_developer > 0)
1454         {
1455                 PrintToChat(client, text);
1456         }
1457 }
1458
1459 ERASEABLE
1460 void PrintToChatAll(string text)
1461 {
1462         text = strcat("\{1}^7", text, "\n");
1463         bprint(text);
1464 }
1465
1466 ERASEABLE
1467 void DebugPrintToChatAll(string text)
1468 {
1469         if (autocvar_developer > 0)
1470         {
1471                 PrintToChatAll(text);
1472         }
1473 }
1474
1475 ERASEABLE
1476 void PrintToChatTeam(int team_num, string text)
1477 {
1478         text = strcat("\{1}^7", text, "\n");
1479         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1480         {
1481                 if (it.team == team_num)
1482                 {
1483                         sprint(it, text);
1484                 }
1485         });
1486 }
1487
1488 ERASEABLE
1489 void DebugPrintToChatTeam(int team_num, string text)
1490 {
1491         if (autocvar_developer > 0)
1492         {
1493                 PrintToChatTeam(team_num, text);
1494         }
1495 }
1496
1497 void play_countdown(entity this, float finished, Sound samp)
1498 {
1499         TC(Sound, samp);
1500         if(IS_REAL_CLIENT(this))
1501                 if(floor(finished - time - frametime) != floor(finished - time))
1502                         if(finished - time < 6)
1503                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1504 }
1505
1506 void player_powerups(entity this)
1507 {
1508         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1509                 this.modelflags |= MF_ROCKET;
1510         else
1511                 this.modelflags &= ~MF_ROCKET;
1512
1513         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1514
1515         if (IS_DEAD(this))
1516         {
1517                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1518                 {
1519                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1520                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1521                         this.items &= ~ITEM_Strength.m_itemid;
1522                         this.items &= ~ITEM_Shield.m_itemid;
1523                         this.items -= (this.items & IT_SUPERWEAPON);
1524                 }
1525         }
1526
1527         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1528                 return;
1529
1530         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1531         int items_prev = this.items;
1532
1533         Fire_ApplyDamage(this);
1534         Fire_ApplyEffect(this);
1535
1536         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1537         {
1538                 if (this.items & ITEM_Strength.m_itemid)
1539                 {
1540                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1541                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1542                         if (time > STAT(STRENGTH_FINISHED, this))
1543                         {
1544                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1545                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1546                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1547                         }
1548                 }
1549                 else
1550                 {
1551                         if (time < STAT(STRENGTH_FINISHED, this))
1552                         {
1553                                 this.items = this.items | ITEM_Strength.m_itemid;
1554                                 if(!g_cts)
1555                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1556                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1557                         }
1558                 }
1559                 if (this.items & ITEM_Shield.m_itemid)
1560                 {
1561                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1562                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1563                         if (time > STAT(INVINCIBLE_FINISHED, this))
1564                         {
1565                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1566                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1567                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1568                         }
1569                 }
1570                 else
1571                 {
1572                         if (time < STAT(INVINCIBLE_FINISHED, this))
1573                         {
1574                                 this.items = this.items | ITEM_Shield.m_itemid;
1575                                 if(!g_cts)
1576                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1577                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1578                         }
1579                 }
1580                 if (this.items & IT_SUPERWEAPON)
1581                 {
1582                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1583                         {
1584                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1585                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1586                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1587                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1588                         }
1589                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1590                         {
1591                                 // don't let them run out
1592                         }
1593                         else
1594                         {
1595                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1596                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1597                                 {
1598                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1599                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1600                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1601                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1602                                 }
1603                         }
1604                 }
1605                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1606                 {
1607                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1608                         {
1609                                 this.items = this.items | IT_SUPERWEAPON;
1610                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1611                                 {
1612                                         if(!g_cts)
1613                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1614                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1615                                 }
1616                         }
1617                         else
1618                         {
1619                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1620                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1621                         }
1622                 }
1623                 else
1624                 {
1625                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1626                 }
1627         }
1628
1629         if(autocvar_g_nodepthtestplayers)
1630                 this.effects = this.effects | EF_NODEPTHTEST;
1631
1632         if(autocvar_g_fullbrightplayers)
1633                 this.effects = this.effects | EF_FULLBRIGHT;
1634
1635         if (time >= game_starttime)
1636         if (time < this.spawnshieldtime)
1637                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1638
1639         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1640 }
1641
1642 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1643 {
1644         if(current > stable)
1645                 return current;
1646         else if(current > stable - 0.25) // when close enough, "snap"
1647                 return stable;
1648         else
1649                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1650 }
1651
1652 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1653 {
1654         if(current < stable)
1655                 return current;
1656         else if(current < stable + 0.25) // when close enough, "snap"
1657                 return stable;
1658         else
1659                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1660 }
1661
1662 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1663 {
1664         float old = GetResource(this, res);
1665         float current = old;
1666         if(current > rotstable)
1667         {
1668                 if(rotframetime > 0)
1669                 {
1670                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1671                         current = max(rotstable, current - rotlinear * rotframetime);
1672                 }
1673         }
1674         else if(current < regenstable)
1675         {
1676                 if(regenframetime > 0)
1677                 {
1678                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1679                         current = min(regenstable, current + regenlinear * regenframetime);
1680                 }
1681         }
1682
1683         float limit = GetResourceLimit(this, res) * limit_mod;
1684         if(current > limit)
1685                 current = limit;
1686
1687         if (current != old)
1688                 SetResource(this, res, current);
1689 }
1690
1691 void player_regen(entity this)
1692 {
1693         float max_mod, regen_mod, rot_mod, limit_mod;
1694         max_mod = regen_mod = rot_mod = limit_mod = 1;
1695
1696         float regen_health = autocvar_g_balance_health_regen;
1697         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1698         float regen_health_rot = autocvar_g_balance_health_rot;
1699         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1700         float regen_health_stable = autocvar_g_balance_health_regenstable;
1701         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1702         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1703                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1704         max_mod = M_ARGV(1, float);
1705         regen_mod = M_ARGV(2, float);
1706         rot_mod = M_ARGV(3, float);
1707         limit_mod = M_ARGV(4, float);
1708         regen_health = M_ARGV(5, float);
1709         regen_health_linear = M_ARGV(6, float);
1710         regen_health_rot = M_ARGV(7, float);
1711         regen_health_rotlinear = M_ARGV(8, float);
1712         regen_health_stable = M_ARGV(9, float);
1713         regen_health_rotstable = M_ARGV(10, float);
1714
1715         if(!mutator_returnvalue)
1716         if(!STAT(FROZEN, this))
1717         {
1718                 float maxa = autocvar_g_balance_armor_rotstable;
1719                 float mina = autocvar_g_balance_armor_regenstable;
1720
1721                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1722                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1723                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1724
1725                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1726                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1727                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1728         }
1729
1730         // if player rotted to death...  die!
1731         // check this outside above checks, as player may still be able to rot to death
1732         if(GetResource(this, RES_HEALTH) < 1)
1733         {
1734                 if(this.vehicle)
1735                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1736                 if(this.event_damage)
1737                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1738         }
1739
1740         if (!(this.items & IT_UNLIMITED_AMMO))
1741         {
1742                 float maxf = autocvar_g_balance_fuel_rotstable;
1743                 float minf = autocvar_g_balance_fuel_regenstable;
1744
1745                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1746                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1747                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1748         }
1749 }
1750
1751 bool zoomstate_set;
1752 void SetZoomState(entity this, float newzoom)
1753 {
1754         if(newzoom != CS(this).zoomstate)
1755         {
1756                 CS(this).zoomstate = newzoom;
1757                 ClientData_Touch(this);
1758         }
1759         zoomstate_set = true;
1760 }
1761
1762 void GetPressedKeys(entity this)
1763 {
1764         MUTATOR_CALLHOOK(GetPressedKeys, this);
1765         int keys = STAT(PRESSED_KEYS, this);
1766         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1767         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1768         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1769         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1770
1771         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1772         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1773         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1774         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1775         CS(this).pressedkeys = keys; // store for other users
1776
1777         STAT(PRESSED_KEYS, this) = keys;
1778 }
1779
1780 /*
1781 ======================
1782 spectate mode routines
1783 ======================
1784 */
1785
1786 void SpectateCopy(entity this, entity spectatee)
1787 {
1788         TC(Client, this); TC(Client, spectatee);
1789
1790         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1791         PS(this) = PS(spectatee);
1792         this.armortype = spectatee.armortype;
1793         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1794         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1795         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1796         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1797         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1798         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1799         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1800         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1801         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1802         CS(this).impulse = 0;
1803         this.disableclientprediction = 1; // no need to run prediction on a spectator
1804         this.items = spectatee.items;
1805         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1806         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1807         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1808         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1809         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1810         this.air_finished = spectatee.air_finished;
1811         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1812         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1813         this.punchangle = spectatee.punchangle;
1814         this.view_ofs = spectatee.view_ofs;
1815         this.velocity = spectatee.velocity;
1816         this.dmg_take = spectatee.dmg_take;
1817         this.dmg_save = spectatee.dmg_save;
1818         this.dmg_inflictor = spectatee.dmg_inflictor;
1819         this.v_angle = spectatee.v_angle;
1820         this.angles = spectatee.v_angle;
1821         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1822         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1823         this.viewloc = spectatee.viewloc;
1824         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1825                 this.fixangle = true;
1826         setorigin(this, spectatee.origin);
1827         setsize(this, spectatee.mins, spectatee.maxs);
1828         SetZoomState(this, CS(spectatee).zoomstate);
1829
1830     anticheat_spectatecopy(this, spectatee);
1831         STAT(HUD, this) = STAT(HUD, spectatee);
1832         if(spectatee.vehicle)
1833     {
1834         this.angles = spectatee.v_angle;
1835
1836         //this.fixangle = false;
1837         //this.velocity = spectatee.vehicle.velocity;
1838         this.vehicle_health = spectatee.vehicle_health;
1839         this.vehicle_shield = spectatee.vehicle_shield;
1840         this.vehicle_energy = spectatee.vehicle_energy;
1841         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1842         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1843         this.vehicle_reload1 = spectatee.vehicle_reload1;
1844         this.vehicle_reload2 = spectatee.vehicle_reload2;
1845
1846         //msg_entity = this;
1847
1848        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1849             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1850            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1851            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1852
1853         //WriteByte (MSG_ONE, SVC_SETVIEW);
1854         //    WriteEntity(MSG_ONE, this);
1855         //makevectors(spectatee.v_angle);
1856         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1857     }
1858 }
1859
1860 bool SpectateUpdate(entity this)
1861 {
1862         if(!this.enemy)
1863                 return false;
1864
1865         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1866         {
1867                 SetSpectatee(this, NULL);
1868                 return false;
1869         }
1870
1871         SpectateCopy(this, this.enemy);
1872
1873         return true;
1874 }
1875
1876 bool SpectateSet(entity this)
1877 {
1878         if(!IS_PLAYER(this.enemy))
1879                 return false;
1880
1881         ClientData_Touch(this.enemy);
1882
1883         msg_entity = this;
1884         WriteByte(MSG_ONE, SVC_SETVIEW);
1885         WriteEntity(MSG_ONE, this.enemy);
1886         set_movetype(this, MOVETYPE_NONE);
1887         accuracy_resend(this);
1888
1889         if(!SpectateUpdate(this))
1890                 PutObserverInServer(this);
1891
1892         return true;
1893 }
1894
1895 void SetSpectatee_status(entity this, int spectatee_num)
1896 {
1897         int oldspectatee_status = CS(this).spectatee_status;
1898         CS(this).spectatee_status = spectatee_num;
1899
1900         if (CS(this).spectatee_status != oldspectatee_status)
1901         {
1902                 if (STAT(PRESSED_KEYS, this))
1903                 {
1904                         CS(this).pressedkeys = 0;
1905                         STAT(PRESSED_KEYS, this) = 0;
1906                 }
1907                 ClientData_Touch(this);
1908                 if (g_race || g_cts) race_InitSpectator();
1909         }
1910 }
1911
1912 void SetSpectatee(entity this, entity spectatee)
1913 {
1914         if(IS_BOT_CLIENT(this))
1915                 return; // bots abuse .enemy, this code is useless to them
1916
1917         entity old_spectatee = this.enemy;
1918
1919         this.enemy = spectatee;
1920
1921         // WEAPONTODO
1922         // these are required to fix the spectator bug with arc
1923         if(old_spectatee)
1924         {
1925                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1926                 {
1927                         .entity weaponentity = weaponentities[slot];
1928                         if(old_spectatee.(weaponentity).arc_beam)
1929                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1930                 }
1931         }
1932         if(this.enemy)
1933         {
1934                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1935                 {
1936                         .entity weaponentity = weaponentities[slot];
1937                         if(this.enemy.(weaponentity).arc_beam)
1938                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1939                 }
1940         }
1941
1942         if (this.enemy)
1943                 SetSpectatee_status(this, etof(this.enemy));
1944
1945         // needed to update spectator list
1946         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1947 }
1948
1949 bool Spectate(entity this, entity pl)
1950 {
1951         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1952                 return false;
1953         pl = M_ARGV(1, entity);
1954
1955         SetSpectatee(this, pl);
1956         return SpectateSet(this);
1957 }
1958
1959 bool SpectateNext(entity this)
1960 {
1961         entity ent = find(this.enemy, classname, STR_PLAYER);
1962
1963         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1964                 ent = M_ARGV(1, entity);
1965         else if (!ent)
1966                 ent = find(ent, classname, STR_PLAYER);
1967
1968         if(ent) { SetSpectatee(this, ent); }
1969
1970         return SpectateSet(this);
1971 }
1972
1973 bool SpectatePrev(entity this)
1974 {
1975         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1976         entity ent = findchain(classname, STR_PLAYER);
1977         if (!ent) // no player
1978                 return false;
1979
1980         entity first = ent;
1981         // skip players until current spectated player
1982         if(this.enemy)
1983         while(ent && ent != this.enemy)
1984                 ent = ent.chain;
1985
1986         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1987         {
1988                 case MUT_SPECPREV_FOUND:
1989                     ent = M_ARGV(1, entity);
1990                     break;
1991                 case MUT_SPECPREV_RETURN:
1992                     return true;
1993                 case MUT_SPECPREV_CONTINUE:
1994                 default:
1995                 {
1996                         if(ent.chain)
1997                                 ent = ent.chain;
1998                         else
1999                                 ent = first;
2000                         break;
2001                 }
2002         }
2003
2004         SetSpectatee(this, ent);
2005         return SpectateSet(this);
2006 }
2007
2008 /*
2009 =============
2010 ShowRespawnCountdown()
2011
2012 Update a respawn countdown display.
2013 =============
2014 */
2015 void ShowRespawnCountdown(entity this)
2016 {
2017         float number;
2018         if(!IS_DEAD(this)) // just respawned?
2019                 return;
2020         else
2021         {
2022                 number = ceil(this.respawn_time - time);
2023                 if(number <= 0)
2024                         return;
2025                 if(number <= this.respawn_countdown)
2026                 {
2027                         this.respawn_countdown = number - 1;
2028                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2029                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2030                 }
2031         }
2032 }
2033
2034 .bool team_selected;
2035 bool ShowTeamSelection(entity this)
2036 {
2037         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2038                 return false;
2039         stuffcmd(this, "menu_showteamselect\n");
2040         return true;
2041 }
2042 void Join(entity this)
2043 {
2044         TRANSMUTE(Player, this);
2045
2046         if(!this.team_selected)
2047         if(autocvar_g_campaign || autocvar_g_balance_teams)
2048                 TeamBalance_JoinBestTeam(this);
2049
2050         if(autocvar_g_campaign)
2051                 campaign_bots_may_start = true;
2052
2053         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2054
2055         PutClientInServer(this);
2056
2057         if(IS_PLAYER(this))
2058         if(teamplay && this.team != -1)
2059         {
2060         }
2061         else
2062                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2063         this.team_selected = false;
2064 }
2065
2066 int GetPlayerLimit()
2067 {
2068         if(g_duel)
2069                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2070         int player_limit = autocvar_g_maxplayers;
2071         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2072         player_limit = M_ARGV(0, int);
2073         return player_limit;
2074 }
2075
2076 /**
2077  * Determines whether the player is allowed to join. This depends on cvar
2078  * g_maxplayers, if it isn't used this function always return true, otherwise
2079  * it checks whether the number of currently playing players exceeds g_maxplayers.
2080  * @return int number of free slots for players, 0 if none
2081  */
2082 int nJoinAllowed(entity this, entity ignore)
2083 {
2084         if(!ignore)
2085         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2086         // so report 0 free slots if restricted
2087         {
2088                 if(autocvar_g_forced_team_otherwise == "spectate")
2089                         return 0;
2090                 if(autocvar_g_forced_team_otherwise == "spectator")
2091                         return 0;
2092         }
2093
2094         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2095                 return 0; // forced spectators can never join
2096
2097         // TODO simplify this
2098         int totalClients = 0;
2099         int currentlyPlaying = 0;
2100         FOREACH_CLIENT(true, {
2101                 if(it != ignore)
2102                         ++totalClients;
2103                 if(IS_REAL_CLIENT(it))
2104                 if(IS_PLAYER(it) || it.caplayer)
2105                         ++currentlyPlaying;
2106         });
2107
2108         int player_limit = GetPlayerLimit();
2109
2110         int free_slots = 0;
2111         if (!player_limit)
2112                 free_slots = maxclients - totalClients;
2113         else if(player_limit > 0 && currentlyPlaying < player_limit)
2114                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2115
2116         static float msg_time = 0;
2117         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2118         {
2119                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2120                 msg_time = time + 0.5;
2121         }
2122
2123         return free_slots;
2124 }
2125
2126 /**
2127  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2128  * g_maxplayers_spectator_blocktime seconds
2129  */
2130 void checkSpectatorBlock(entity this)
2131 {
2132         if(IS_SPEC(this) || IS_OBSERVER(this))
2133         if(!this.caplayer)
2134         if(IS_REAL_CLIENT(this))
2135         {
2136                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2137                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2138                         dropclient(this);
2139                 }
2140         }
2141 }
2142
2143 void PrintWelcomeMessage(entity this)
2144 {
2145         if(CS(this).motd_actived_time == 0)
2146         {
2147                 if (autocvar_g_campaign) {
2148                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2149                                 CS(this).motd_actived_time = time;
2150                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2151                         }
2152                 } else {
2153                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2154                                 CS(this).motd_actived_time = time;
2155                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2156                         }
2157                 }
2158         }
2159         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2160         {
2161                 if (autocvar_g_campaign) {
2162                         if (PHYS_INPUT_BUTTON_INFO(this))
2163                                 CS(this).motd_actived_time = time;
2164                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2165                                 CS(this).motd_actived_time = 0;
2166                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2167                         }
2168                 } else {
2169                         if (PHYS_INPUT_BUTTON_INFO(this))
2170                                 CS(this).motd_actived_time = time;
2171                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2172                                 CS(this).motd_actived_time = 0;
2173                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2174                         }
2175                 }
2176         }
2177         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2178         {
2179                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2180                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2181                 else if (CS(this).motd_actived_time == -2)
2182                 {
2183                         // instantly hide MOTD
2184                         CS(this).motd_actived_time = 0;
2185                         if (autocvar_g_campaign)
2186                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2187                         else
2188                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2189                 }
2190                 else if (IS_PLAYER(this) || IS_SPEC(this))
2191                 {
2192                         // FIXME occasionally for some reason MOTD never goes away
2193                         // delay MOTD removal a little bit in the hope it fixes this bug
2194                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2195                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2196                         else //if (CS(this).motd_actived_time < -2)
2197                                 CS(this).motd_actived_time++;
2198                 }
2199         }
2200 }
2201
2202 bool joinAllowed(entity this)
2203 {
2204         if (CS(this).version_mismatch) return false;
2205         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2206         if (!nJoinAllowed(this, this)) return false;
2207         if (teamplay && lockteams) return false;
2208         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2209         if (ShowTeamSelection(this)) return false;
2210         return true;
2211 }
2212
2213 .string shootfromfixedorigin;
2214 .bool dualwielding_prev;
2215 bool PlayerThink(entity this)
2216 {
2217         if (game_stopped || intermission_running) {
2218                 this.modelflags &= ~MF_ROCKET;
2219                 if(intermission_running)
2220                         IntermissionThink(this);
2221                 return false;
2222         }
2223
2224         if (timeout_status == TIMEOUT_ACTIVE) {
2225         // don't allow the player to turn around while game is paused
2226                 // FIXME turn this into CSQC stuff
2227                 this.v_angle = this.lastV_angle;
2228                 this.angles = this.lastV_angle;
2229                 this.fixangle = true;
2230         }
2231
2232         if (frametime) player_powerups(this);
2233
2234         if (IS_DEAD(this)) {
2235                 if (this.personal && g_race_qualifying) {
2236                         if (time > this.respawn_time) {
2237                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2238                                 respawn(this);
2239                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2240                         }
2241                 } else {
2242                         if (frametime) player_anim(this);
2243
2244                         if (this.respawn_flags & RESPAWN_DENY)
2245                         {
2246                                 STAT(RESPAWN_TIME, this) = 0;
2247                                 return false;
2248                         }
2249
2250                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2251
2252                         switch(this.deadflag)
2253                         {
2254                                 case DEAD_DYING:
2255                                 {
2256                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2257                                                 this.deadflag = DEAD_RESPAWNING;
2258                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2259                                                 this.deadflag = DEAD_DEAD;
2260                                         break;
2261                                 }
2262                                 case DEAD_DEAD:
2263                                 {
2264                                         if (button_pressed)
2265                                                 this.deadflag = DEAD_RESPAWNABLE;
2266                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2267                                                 this.deadflag = DEAD_RESPAWNING;
2268                                         break;
2269                                 }
2270                                 case DEAD_RESPAWNABLE:
2271                                 {
2272                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2273                                                 this.deadflag = DEAD_RESPAWNING;
2274                                         break;
2275                                 }
2276                                 case DEAD_RESPAWNING:
2277                                 {
2278                                         if (time > this.respawn_time)
2279                                         {
2280                                                 this.respawn_time = time + 1; // only retry once a second
2281                                                 this.respawn_time_max = this.respawn_time;
2282                                                 respawn(this);
2283                                         }
2284                                         break;
2285                                 }
2286                         }
2287
2288                         ShowRespawnCountdown(this);
2289
2290                         if (this.respawn_flags & RESPAWN_SILENT)
2291                                 STAT(RESPAWN_TIME, this) = 0;
2292                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2293                         {
2294                                 if (time < this.respawn_time)
2295                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2296                                 else if (this.deadflag != DEAD_RESPAWNING)
2297                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2298                         }
2299                         else
2300                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2301                 }
2302
2303                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2304                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2305                         STAT(RESPAWN_TIME, this) *= -1;
2306
2307                 return false;
2308         }
2309
2310         FixPlayermodel(this);
2311
2312         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2313                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2314                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2315         }
2316
2317         // reset gun alignment when dual wielding status changes
2318         // to ensure guns are always aligned right and left
2319         bool dualwielding = W_DualWielding(this);
2320         if(this.dualwielding_prev != dualwielding)
2321         {
2322                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2323                 this.dualwielding_prev = dualwielding;
2324         }
2325
2326         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2327         //if(frametime)
2328         {
2329                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2330                 {
2331                         .entity weaponentity = weaponentities[slot];
2332                         if(WEP_CVAR(vortex, charge_always))
2333                                 W_Vortex_Charge(this, weaponentity, frametime);
2334                         W_WeaponFrame(this, weaponentity);
2335                 }
2336         }
2337
2338         if (frametime)
2339         {
2340                 // WEAPONTODO: Add a weapon request for this
2341                 // rot vortex charge to the charge limit
2342                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2343                 {
2344                         .entity weaponentity = weaponentities[slot];
2345                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2346                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2347                 }
2348
2349                 player_regen(this);
2350                 player_anim(this);
2351                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2352         }
2353
2354         monsters_setstatus(this);
2355
2356         return true;
2357 }
2358
2359 .bool would_spectate;
2360 void ObserverOrSpectatorThink(entity this)
2361 {
2362         bool is_spec = IS_SPEC(this);
2363         if ( CS(this).impulse )
2364         {
2365                 int r = MinigameImpulse(this, CS(this).impulse);
2366                 if (!is_spec || r)
2367                         CS(this).impulse = 0;
2368
2369                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2370                 {
2371                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2372                         CS(this).impulse = 0;
2373                         return;
2374                 }
2375         }
2376
2377         if (this.flags & FL_JUMPRELEASED) {
2378                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2379                         this.flags &= ~FL_JUMPRELEASED;
2380                         this.flags |= FL_SPAWNING;
2381                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2382                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2383                         this.flags &= ~FL_JUMPRELEASED;
2384                         if(SpectateNext(this)) {
2385                                 TRANSMUTE(Spectator, this);
2386                         } else if (is_spec) {
2387                                 TRANSMUTE(Observer, this);
2388                                 PutClientInServer(this);
2389                         }
2390                         if (is_spec)
2391                                 CS(this).impulse = 0;
2392                 } else if (is_spec) {
2393                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2394                                 this.flags &= ~FL_JUMPRELEASED;
2395                                 if(SpectatePrev(this)) {
2396                                         TRANSMUTE(Spectator, this);
2397                                 } else {
2398                                         TRANSMUTE(Observer, this);
2399                                         PutClientInServer(this);
2400                                 }
2401                                 CS(this).impulse = 0;
2402                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2403                                 this.would_spectate = false;
2404                                 this.flags &= ~FL_JUMPRELEASED;
2405                                 TRANSMUTE(Observer, this);
2406                                 PutClientInServer(this);
2407                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2408                                 PutObserverInServer(this);
2409                                 this.would_spectate = true;
2410                         }
2411                 }
2412                 else {
2413                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2414                         set_movetype(this, preferred_movetype);
2415                 }
2416         } else {
2417                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2418                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2419                         this.flags |= FL_JUMPRELEASED;
2420                         if(this.flags & FL_SPAWNING)
2421                         {
2422                                 this.flags &= ~FL_SPAWNING;
2423                                 if(joinAllowed(this))
2424                                         Join(this);
2425                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2426                                         CS(this).autojoin_checked = -1;
2427                                 return;
2428                         }
2429                 }
2430                 if(is_spec && !SpectateUpdate(this))
2431                         PutObserverInServer(this);
2432         }
2433         if (is_spec)
2434                 this.flags |= FL_CLIENT | FL_NOTARGET;
2435 }
2436
2437 void PlayerUseKey(entity this)
2438 {
2439         if (!IS_PLAYER(this))
2440                 return;
2441
2442         if(this.vehicle)
2443         {
2444                 if(!game_stopped)
2445                 {
2446                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2447                         return;
2448                 }
2449         }
2450         else if(autocvar_g_vehicles_enter)
2451         {
2452                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2453                 {
2454                         entity head, closest_target = NULL;
2455                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2456
2457                         while(head) // find the closest acceptable target to enter
2458                         {
2459                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2460                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2461                                 {
2462                                         if(closest_target)
2463                                         {
2464                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2465                                                 { closest_target = head; }
2466                                         }
2467                                         else { closest_target = head; }
2468                                 }
2469
2470                                 head = head.chain;
2471                         }
2472
2473                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2474                 }
2475         }
2476
2477         // a use key was pressed; call handlers
2478         MUTATOR_CALLHOOK(PlayerUseKey, this);
2479 }
2480
2481
2482 /*
2483 =============
2484 PlayerPreThink
2485
2486 Called every frame for each client before the physics are run
2487 =============
2488 */
2489 .float last_vehiclecheck;
2490 void PlayerPreThink (entity this)
2491 {
2492         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2493         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2494
2495         WarpZone_PlayerPhysics_FixVAngle(this);
2496
2497         if (frametime) {
2498                 // physics frames: update anticheat stuff
2499                 anticheat_prethink(this);
2500         }
2501
2502         if (blockSpectators && frametime) {
2503                 // WORKAROUND: only use dropclient in server frames (frametime set).
2504                 // Never use it in cl_movement frames (frametime zero).
2505                 checkSpectatorBlock(this);
2506         }
2507
2508         zoomstate_set = false;
2509
2510         // Check for nameless players
2511         if (this.netname == "" || this.netname != CS(this).netname_previous)
2512         {
2513                 bool assume_unchanged = (CS(this).netname_previous == "");
2514                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2515                 {
2516                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2517                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2518                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2519                         assume_unchanged = false;
2520                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2521                 }
2522                 if (isInvisibleString(this.netname))
2523                 {
2524                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2525                         sprint(this, "Warning: invisible names are not allowed.\n");
2526                         assume_unchanged = false;
2527                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2528                 }
2529                 if (!assume_unchanged && autocvar_sv_eventlog)
2530                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2531                 strcpy(CS(this).netname_previous, this.netname);
2532         }
2533
2534         // version nagging
2535         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2536         CS(this).version_nagtime = 0;
2537         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2538             // git client
2539         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2540             // git server
2541             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2542         } else {
2543             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2544             if (r < 0) { // old client
2545                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2546             } else if (r > 0) { // old server
2547                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2548             }
2549         }
2550     }
2551
2552         // GOD MODE info
2553         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2554         {
2555                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2556                 this.max_armorvalue = 0;
2557         }
2558
2559         if (frametime && IS_PLAYER(this))
2560         {
2561                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2562                 {
2563                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2564                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2565                         if (this.iceblock)
2566                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2567
2568                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2569                                 Unfreeze(this, false);
2570                 }
2571                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2572                 {
2573                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2574                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2575
2576                         if (GetResource(this, RES_HEALTH) < 1)
2577                         {
2578                                 if (this.vehicle)
2579                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2580                                 if(this.event_damage)
2581                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2582                         }
2583                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2584                                 Unfreeze(this, false);
2585                 }
2586         }
2587
2588         MUTATOR_CALLHOOK(PlayerPreThink, this);
2589
2590         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2591         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2592         {
2593                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2594                 {
2595                         if(!it.owner)
2596                         {
2597                                 if(!it.team || SAME_TEAM(this, it))
2598                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2599                                 else if(autocvar_g_vehicles_steal)
2600                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2601                         }
2602                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2603                         {
2604                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2605                         }
2606                 });
2607
2608                 this.last_vehiclecheck = time + 1;
2609         }
2610
2611         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2612         {
2613                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2614                         PlayerUseKey(this);
2615                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2616         }
2617
2618         if (IS_REAL_CLIENT(this))
2619                 PrintWelcomeMessage(this);
2620
2621         if (IS_PLAYER(this)) {
2622                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2623                         error("Client can't be spawned as player on connection!");
2624                 if(!PlayerThink(this))
2625                         return;
2626         }
2627         else if (game_stopped || intermission_running) {
2628                 if(intermission_running)
2629                         IntermissionThink(this);
2630                 return;
2631         }
2632         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2633         {
2634                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2635                 CS(this).autojoin_checked = 1;
2636                 // don't do this in ClientConnect
2637                 // many things can go wrong if a client is spawned as player on connection
2638                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2639                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2640                                 && (!teamplay || autocvar_g_balance_teams)))
2641                 {
2642                         campaign_bots_may_start = true;
2643                         if(joinAllowed(this))
2644                                 Join(this);
2645                         return;
2646                 }
2647         }
2648         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2649                 ObserverOrSpectatorThink(this);
2650         }
2651
2652         // WEAPONTODO: Add weapon request for this
2653         if (!zoomstate_set) {
2654                 bool wep_zoomed = false;
2655                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2656                 {
2657                         .entity weaponentity = weaponentities[slot];
2658                         Weapon thiswep = this.(weaponentity).m_weapon;
2659                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2660                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2661                 }
2662                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2663         }
2664
2665         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2666         {
2667                 CS(this).teamkill_soundtime = 0;
2668
2669                 entity e = CS(this).teamkill_soundsource;
2670                 entity oldpusher = e.pusher;
2671                 e.pusher = this;
2672                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2673                 e.pusher = oldpusher;
2674         }
2675
2676         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2677                 CS(this).taunt_soundtime = 0;
2678                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2679         }
2680
2681         target_voicescript_next(this);
2682
2683         // WEAPONTODO: Move into weaponsystem somehow
2684         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2685         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2686         {
2687                 .entity weaponentity = weaponentities[slot];
2688                 if(this.(weaponentity).m_weapon == WEP_Null)
2689                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2690         }
2691 }
2692
2693 void DrownPlayer(entity this)
2694 {
2695         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2696                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2697         {
2698                 this.air_finished = 0;
2699                 return;
2700         }
2701
2702         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2703         {
2704                 if(this.air_finished && this.air_finished < time)
2705                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2706                 this.air_finished = 0;
2707         }
2708         else
2709         {
2710                 if (!this.air_finished)
2711                         this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2712                 if (this.air_finished < time)
2713                 {       // drown!
2714                         if (this.pain_finished < time)
2715                         {
2716                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2717                                 this.pain_finished = time + 0.5;
2718                         }
2719                 }
2720         }
2721 }
2722
2723 .bool move_qcphysics;
2724
2725 void Player_Physics(entity this)
2726 {
2727         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2728
2729         if(!this.move_qcphysics)
2730                 return;
2731
2732         if(!frametime && !CS(this).pm_frametime)
2733                 return;
2734
2735         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2736
2737         CS(this).pm_frametime = 0;
2738 }
2739
2740 /*
2741 =============
2742 PlayerPostThink
2743
2744 Called every frame for each client after the physics are run
2745 =============
2746 */
2747 void PlayerPostThink (entity this)
2748 {
2749         Player_Physics(this);
2750
2751         if (sv_maxidle > 0)
2752         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2753         if (IS_REAL_CLIENT(this))
2754         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2755         {
2756                 int totalClients = 0;
2757                 if(sv_maxidle_slots > 0)
2758                 {
2759                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2760                         {
2761                                 ++totalClients;
2762                         });
2763                 }
2764
2765                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2766                 { /* do nothing */ }
2767                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2768                 {
2769                         if (CS(this).idlekick_lasttimeleft)
2770                         {
2771                                 CS(this).idlekick_lasttimeleft = 0;
2772                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2773                         }
2774                 }
2775                 else
2776                 {
2777                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2778                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2779                                 if (!CS(this).idlekick_lasttimeleft)
2780                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2781                         }
2782                         if (timeleft <= 0) {
2783                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2784                                 dropclient(this);
2785                                 return;
2786                         }
2787                         else if (timeleft <= 10) {
2788                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2789                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2790                 }
2791                                 CS(this).idlekick_lasttimeleft = timeleft;
2792                         }
2793                 }
2794         }
2795
2796         CheatFrame(this);
2797
2798         if (game_stopped)
2799         {
2800                 this.solid = SOLID_NOT;
2801                 this.takedamage = DAMAGE_NO;
2802                 set_movetype(this, MOVETYPE_NONE);
2803                 CS(this).teamkill_complain = 0;
2804                 CS(this).teamkill_soundtime = 0;
2805                 CS(this).teamkill_soundsource = NULL;
2806         }
2807
2808         if (IS_PLAYER(this)) {
2809                 if(this.death_time == time && IS_DEAD(this))
2810                 {
2811                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2812                         // once all the damage events of this frame have been processed with normal size
2813                         this.maxs.z = 5;
2814                         setsize(this, this.mins, this.maxs);
2815                 }
2816                 DrownPlayer(this);
2817                 UpdateChatBubble(this);
2818                 if (CS(this).impulse) ImpulseCommands(this);
2819                 if (game_stopped)
2820                 {
2821                         CSQCMODEL_AUTOUPDATE(this);
2822                         return;
2823                 }
2824                 GetPressedKeys(this);
2825         }
2826         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2827         {
2828                 CS(this).pressedkeys = 0;
2829                 STAT(PRESSED_KEYS, this) = 0;
2830         }
2831
2832         if (this.waypointsprite_attachedforcarrier) {
2833                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2834                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2835         }
2836
2837         CSQCMODEL_AUTOUPDATE(this);
2838 }
2839
2840 /**
2841  * message "": do not say, just test flood control
2842  * return value:
2843  *   1 = accept
2844  *   0 = reject
2845  *  -1 = fake accept
2846  */
2847 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2848 {
2849         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2850                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2851
2852         if (source)
2853                 msgin = formatmessage(source, msgin);
2854
2855         string colorstr;
2856         if (!(IS_PLAYER(source) || source.caplayer))
2857                 colorstr = "^0"; // black for spectators
2858         else if(teamplay)
2859                 colorstr = Team_ColorCode(source.team);
2860         else
2861         {
2862                 colorstr = "";
2863                 teamsay = false;
2864         }
2865
2866         if (!source) {
2867                 colorstr = "";
2868                 teamsay = false;
2869         }
2870
2871         if(msgin != "")
2872                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2873
2874         /*
2875          * using bprint solves this... me stupid
2876         // how can we prevent the message from appearing in a listen server?
2877         // for now, just give "say" back and only handle say_team
2878         if(!teamsay)
2879         {
2880                 clientcommand(source, strcat("say ", msgin));
2881                 return;
2882         }
2883         */
2884
2885         string namestr = "";
2886         if (source)
2887                 namestr = playername(source, autocvar_g_chat_teamcolors);
2888
2889         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2890
2891         string msgstr = "", cmsgstr = "";
2892         string privatemsgprefix = string_null;
2893         int privatemsgprefixlen = 0;
2894         if (msgin != "")
2895         {
2896                 bool found_me = false;
2897                 if(strstrofs(msgin, "/me", 0) >= 0)
2898                 {
2899                         string newmsgin = "";
2900                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2901                         FOREACH_WORD(msgin, true,
2902                         {
2903                                 if(strdecolorize(it) == "/me")
2904                                 {
2905                                         found_me = true;
2906                                         newmsgin = cons(newmsgin, newnamestr);
2907                                 }
2908                                 else
2909                                         newmsgin = cons(newmsgin, it);
2910                         });
2911                         msgin = newmsgin;
2912                 }
2913
2914                 if(privatesay)
2915                 {
2916                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2917                         privatemsgprefixlen = strlen(msgstr);
2918                         msgstr = strcat(msgstr, msgin);
2919                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2920                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2921                 }
2922                 else if(teamsay)
2923                 {
2924                         if(found_me)
2925                         {
2926                                 //msgin = strreplace("/me", "", msgin);
2927                                 //msgin = substring(msgin, 3, strlen(msgin));
2928                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2929                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2930                         }
2931                         else
2932                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2933                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2934                 }
2935                 else
2936                 {
2937                         if(found_me)
2938                         {
2939                                 //msgin = strreplace("/me", "", msgin);
2940                                 //msgin = substring(msgin, 3, strlen(msgin));
2941                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2942                                 msgstr = strcat("\{1}^4* ^7", msgin);
2943                         }
2944                         else {
2945                                 msgstr = "\{1}";
2946                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2947                                 msgstr = strcat(msgstr, msgin);
2948                         }
2949                         cmsgstr = "";
2950                 }
2951                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2952         }
2953
2954         string fullmsgstr = msgstr;
2955         string fullcmsgstr = cmsgstr;
2956
2957         // FLOOD CONTROL
2958         int flood = 0;
2959         var .float flood_field = floodcontrol_chat;
2960         if(floodcontrol && source)
2961         {
2962                 float flood_spl;
2963                 float flood_burst;
2964                 float flood_lmax;
2965                 float lines;
2966                 if(privatesay)
2967                 {
2968                         flood_spl = autocvar_g_chat_flood_spl_tell;
2969                         flood_burst = autocvar_g_chat_flood_burst_tell;
2970                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2971                         flood_field = floodcontrol_chattell;
2972                 }
2973                 else if(teamsay)
2974                 {
2975                         flood_spl = autocvar_g_chat_flood_spl_team;
2976                         flood_burst = autocvar_g_chat_flood_burst_team;
2977                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2978                         flood_field = floodcontrol_chatteam;
2979                 }
2980                 else
2981                 {
2982                         flood_spl = autocvar_g_chat_flood_spl;
2983                         flood_burst = autocvar_g_chat_flood_burst;
2984                         flood_lmax = autocvar_g_chat_flood_lmax;
2985                         flood_field = floodcontrol_chat;
2986                 }
2987                 flood_burst = max(0, flood_burst - 1);
2988                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2989
2990                 // do flood control for the default line size
2991                 if(msgstr != "")
2992                 {
2993                         getWrappedLine_remaining = msgstr;
2994                         msgstr = "";
2995                         lines = 0;
2996                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2997                         {
2998                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2999                                 ++lines;
3000                         }
3001                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
3002
3003                         if(getWrappedLine_remaining != "")
3004                         {
3005                                 msgstr = strcat(msgstr, "\n");
3006                                 flood = 2;
3007                         }
3008
3009                         if (time >= source.(flood_field))
3010                         {
3011                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
3012                         }
3013                         else
3014                         {
3015                                 flood = 1;
3016                                 msgstr = fullmsgstr;
3017                         }
3018                 }
3019                 else
3020                 {
3021                         if (time >= source.(flood_field))
3022                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
3023                         else
3024                                 flood = 1;
3025                 }
3026
3027                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
3028                         source.(flood_field) = flood = 0;
3029         }
3030
3031         string sourcemsgstr, sourcecmsgstr;
3032         if(flood == 2) // cannot happen for empty msgstr
3033         {
3034                 if(autocvar_g_chat_flood_notify_flooder)
3035                 {
3036                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
3037                         sourcecmsgstr = "";
3038                 }
3039                 else
3040                 {
3041                         sourcemsgstr = fullmsgstr;
3042                         sourcecmsgstr = fullcmsgstr;
3043                 }
3044                 cmsgstr = "";
3045         }
3046         else
3047         {
3048                 sourcemsgstr = msgstr;
3049                 sourcecmsgstr = cmsgstr;
3050         }
3051
3052         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3053         {
3054                 if (!game_stopped)
3055                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
3056                         teamsay = -1; // spectators
3057         }
3058
3059         if(flood)
3060                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
3061
3062         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
3063         if(privatesay)
3064                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
3065
3066         int ret;
3067         if(source && CS(source).muted)
3068         {
3069                 // always fake the message
3070                 ret = -1;
3071         }
3072         else if(flood == 1)
3073         {
3074                 if (autocvar_g_chat_flood_notify_flooder)
3075                 {
3076                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
3077                         ret = 0;
3078                 }
3079                 else
3080                         ret = -1;
3081         }
3082         else
3083         {
3084                 ret = 1;
3085         }
3086
3087         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3088         {
3089                 if (!game_stopped)
3090                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
3091                         ret = -1; // just hide the message completely
3092         }
3093
3094         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3095         ret = M_ARGV(1, int);
3096
3097         string event_log_msg = "";
3098
3099         if(sourcemsgstr != "" && ret != 0)
3100         {
3101                 if(ret < 0) // faked message, because the player is muted
3102                 {
3103                         sprint(source, sourcemsgstr);
3104                         if(sourcecmsgstr != "" && !privatesay)
3105                                 centerprint(source, sourcecmsgstr);
3106                 }
3107                 else if(privatesay) // private message, between 2 people only
3108                 {
3109                         sprint(source, sourcemsgstr);
3110                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
3111                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
3112                         {
3113                                 sprint(privatesay, msgstr);
3114                                 if(cmsgstr != "")
3115                                         centerprint(privatesay, cmsgstr);
3116                         }
3117                 }
3118                 else if ( teamsay && CS(source).active_minigame )
3119                 {
3120                         sprint(source, sourcemsgstr);
3121                         dedicated_print(msgstr); // send to server console too
3122                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3123                                 sprint(it, msgstr);
3124                         });
3125                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3126
3127                 }
3128                 else if(teamsay > 0) // team message, only sent to team mates
3129                 {
3130                         sprint(source, sourcemsgstr);
3131                         dedicated_print(msgstr); // send to server console too
3132                         if(sourcecmsgstr != "")
3133                                 centerprint(source, sourcecmsgstr);
3134                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3135                                 sprint(it, msgstr);
3136                                 if(cmsgstr != "")
3137                                         centerprint(it, cmsgstr);
3138                         });
3139                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3140                 }
3141                 else if(teamsay < 0) // spectator message, only sent to spectators
3142                 {
3143                         sprint(source, sourcemsgstr);
3144                         dedicated_print(msgstr); // send to server console too
3145                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3146                                 sprint(it, msgstr);
3147                         });
3148                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3149                 }
3150                 else
3151                 {
3152                         if (source) {
3153                                 sprint(source, sourcemsgstr);
3154                                 dedicated_print(msgstr); // send to server console too
3155                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3156                         }
3157                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3158                                 sprint(it, msgstr);
3159                         });
3160                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3161                 }
3162         }
3163
3164         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3165                 GameLogEcho(event_log_msg);
3166         }
3167
3168         return ret;
3169 }
3170
3171 // hack to copy the button fields from the client entity to the Client State
3172 void PM_UpdateButtons(entity this, entity store)
3173 {
3174         if(this.impulse)
3175                 store.impulse = this.impulse;
3176         this.impulse = 0;
3177
3178         bool typing = this.buttonchat || this.button12;
3179
3180         store.button0 = (typing) ? 0 : this.button0;
3181         //button1?!
3182         store.button2 = (typing) ? 0 : this.button2;
3183         store.button3 = (typing) ? 0 : this.button3;
3184         store.button4 = this.button4;
3185         store.button5 = (typing) ? 0 : this.button5;
3186         store.button6 = this.button6;
3187         store.button7 = this.button7;
3188         store.button8 = this.button8;
3189         store.button9 = this.button9;
3190         store.button10 = this.button10;
3191         store.button11 = this.button11;
3192         store.button12 = this.button12;
3193         store.button13 = this.button13;
3194         store.button14 = this.button14;
3195         store.button15 = this.button15;
3196         store.button16 = this.button16;
3197         store.buttonuse = this.buttonuse;
3198         store.buttonchat = this.buttonchat;
3199
3200         store.cursor_active = this.cursor_active;
3201         store.cursor_screen = this.cursor_screen;
3202         store.cursor_trace_start = this.cursor_trace_start;
3203         store.cursor_trace_endpos = this.cursor_trace_endpos;
3204         store.cursor_trace_ent = this.cursor_trace_ent;
3205
3206         store.ping = this.ping;
3207         store.ping_packetloss = this.ping_packetloss;
3208         store.ping_movementloss = this.ping_movementloss;
3209
3210         store.v_angle = this.v_angle;
3211         store.movement = this.movement;
3212 }
3213
3214 NET_HANDLE(fpsreport, bool)
3215 {
3216         int fps = ReadShort();
3217         PlayerScore_Set(sender, SP_FPS, fps);
3218         return true;
3219 }