qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/weapons/_all.qh>
   4 #include <common/stats.qh>
   5 #include <server/miscfunctions.qh>
   6 #include <common/effects/all.qh>
   7 #include "anticheat.qh"
   8 #include "impulse.qh"
   9 #include "player.qh"
  10 #include "ipban.qh"
  11 #include "miscfunctions.qh"
  12 #include "portals.qh"
  13 #include "teamplay.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "damage.qh"
  17 #include "handicap.qh"
  18 #include "hook.qh"
  19 #include "command/common.qh"
  20 #include "command/vote.qh"
  21 #include "clientkill.qh"
  22 #include "cheats.qh"
  23 #include "world.qh"
  24 #include <server/gamelog.qh>
  25 #include "race.qh"
  26 #include <server/main.qh>
  27 #include "antilag.qh"
  28 #include "campaign.qh"
  29 #include "command/common.qh"
  30 #include "scores_rules.qh"
  31 #include "weapons/common.qh"
  32
  33 #include "bot/api.qh"
  34
  35 #include "../common/ent_cs.qh"
  36 #include "../common/wepent.qh"
  37 #include <common/state.qh>
  38
  39 #include "compat/quake3.qh"
  40
  41 #include <common/effects/qc/globalsound.qh>
  42
  43 #include "../common/mapobjects/func/conveyor.qh"
  44 #include <common/mapobjects/func/ladder.qh>
  45 #include "../common/mapobjects/teleporters.qh"
  46 #include "../common/mapobjects/target/spawnpoint.qh"
  47 #include <common/mapobjects/trigger/counter.qh>
  48 #include <common/mapobjects/trigger/swamp.qh>
  49
  50 #include "../common/vehicles/all.qh"
  51
  52 #include "weapons/hitplot.qh"
  53 #include "weapons/selection.qh"
  54 #include "weapons/weaponsystem.qh"
  55
  56 #include "../common/net_notice.qh"
  57 #include "../common/net_linked.qh"
  58 #include "../common/physics/player.qh"
  59
  60 #include <common/vehicles/sv_vehicles.qh>
  61
  62 #include "../common/items/_mod.qh"
  63
  64 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  65
  66 #include "../common/mutators/mutator/waypoints/all.qh"
  67 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  68 #include <common/gamemodes/_mod.qh>
  69
  70 #include "../common/mapobjects/subs.qh"
  71 #include "../common/mapobjects/triggers.qh"
  72 #include "../common/mapobjects/trigger/secret.qh"
  73
  74 #include "../common/minigames/sv_minigames.qh"
  75
  76 #include "../common/items/inventory.qh"
  77
  78 #include "../common/monsters/sv_monsters.qh"
  79
  80 #include "../lib/warpzone/server.qh"
  81
  82 #include <common/mutators/mutator/overkill/oknex.qh>
  83
  84 #include <common/weapons/weapon/vortex.qh>
  85
  86 #define CHAT_NOSPECTATORS() ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
  87
  88 STATIC_METHOD(Client, Add, void(Client this, int _team))
  89 {
  90     ClientConnect(this);
  91     TRANSMUTE(Player, this);
  92     this.frame = 12; // 7
  93     this.team = _team;
  94     PutClientInServer(this);
  95 }
  96
  97 STATIC_METHOD(Client, Remove, void(Client this))
  98 {
  99     TRANSMUTE(Observer, this);
 100     PutClientInServer(this);
 101     ClientDisconnect(this);
 102 }
 103
 104 void send_CSQC_teamnagger() {
 105         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 106 }
 107
 108 int CountSpectators(entity player, entity to)
 109 {
 110         if(!player) { return 0; } // not sure how, but best to be safe
 111
 112         int spec_count = 0;
 113
 114         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 115         {
 116                 spec_count++;
 117         });
 118
 119         return spec_count;
 120 }
 121
 122 void WriteSpectators(entity player, entity to)
 123 {
 124         if(!player) { return; } // not sure how, but best to be safe
 125
 126         int spec_count = 0;
 127         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 128         {
 129                 if(spec_count >= MAX_SPECTATORS)
 130                         break;
 131                 WriteByte(MSG_ENTITY, num_for_edict(it));
 132                 ++spec_count;
 133         });
 134 }
 135
 136 bool ClientData_Send(entity this, entity to, int sf)
 137 {
 138         assert(to == this.owner, return false);
 139
 140         entity e = to;
 141         if (IS_SPEC(e)) e = e.enemy;
 142
 143         sf = 0;
 144         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 145         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 146         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 147         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 148
 149         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 150         WriteByte(MSG_ENTITY, sf);
 151
 152         if (sf & BIT(1))
 153                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 154
 155         if(sf & BIT(4))
 156         {
 157                 float specs = CountSpectators(e, to);
 158                 WriteByte(MSG_ENTITY, specs);
 159                 WriteSpectators(e, to);
 160         }
 161
 162         return true;
 163 }
 164
 165 void ClientData_Attach(entity this)
 166 {
 167         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 168         CS(this).clientdata.drawonlytoclient = this;
 169         CS(this).clientdata.owner = this;
 170 }
 171
 172 void ClientData_Detach(entity this)
 173 {
 174         delete(CS(this).clientdata);
 175         CS(this).clientdata = NULL;
 176 }
 177
 178 void ClientData_Touch(entity e)
 179 {
 180         entity cd = CS(e).clientdata;
 181         if (cd) { cd.SendFlags = 1; }
 182
 183         // make it spectatable
 184         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 185         {
 186                 entity cd = CS(it).clientdata;
 187                 if (cd) { cd.SendFlags = 1; }
 188         });
 189 }
 190
 191
 192 /*
 193 =============
 194 CheckPlayerModel
 195
 196 Checks if the argument string can be a valid playermodel.
 197 Returns a valid one in doubt.
 198 =============
 199 */
 200 string FallbackPlayerModel;
 201 string CheckPlayerModel(string plyermodel) {
 202         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 203         {
 204                 // note: we cannot summon Don Strunzone here, some player may
 205                 // still have the model string set. In case anyone manages how
 206                 // to change a cvar default, we'll have a small leak here.
 207                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 208         }
 209         // only in right path
 210         if( substring(plyermodel,0,14) != "models/player/")
 211                 return FallbackPlayerModel;
 212         // only good file extensions
 213         if(substring(plyermodel,-4,4) != ".zym")
 214         if(substring(plyermodel,-4,4) != ".dpm")
 215         if(substring(plyermodel,-4,4) != ".iqm")
 216         if(substring(plyermodel,-4,4) != ".md3")
 217         if(substring(plyermodel,-4,4) != ".psk")
 218                 return FallbackPlayerModel;
 219         // forbid the LOD models
 220         if(substring(plyermodel, -9,5) == "_lod1")
 221                 return FallbackPlayerModel;
 222         if(substring(plyermodel, -9,5) == "_lod2")
 223                 return FallbackPlayerModel;
 224         if(plyermodel != strtolower(plyermodel))
 225                 return FallbackPlayerModel;
 226         // also, restrict to server models
 227         if(autocvar_sv_servermodelsonly)
 228         {
 229                 if(!fexists(plyermodel))
 230                         return FallbackPlayerModel;
 231         }
 232         return plyermodel;
 233 }
 234
 235 void setplayermodel(entity e, string modelname)
 236 {
 237         precache_model(modelname);
 238         _setmodel(e, modelname);
 239         player_setupanimsformodel(e);
 240         if(!autocvar_g_debug_globalsounds)
 241                 UpdatePlayerSounds(e);
 242 }
 243
 244 /** putting a client as observer in the server */
 245 void PutObserverInServer(entity this)
 246 {
 247     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 248         PlayerState_detach(this);
 249
 250         if (IS_PLAYER(this))
 251         {
 252                 if(GetResource(this, RES_HEALTH) >= 1)
 253                 {
 254                         // despawn effect
 255                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 256                 }
 257
 258                 // was a player, recount votes and ready status
 259                 if(IS_REAL_CLIENT(this))
 260                 {
 261                         if (vote_called) { VoteCount(false); }
 262                         ReadyCount();
 263                 }
 264     }
 265
 266     {
 267         entity spot = SelectSpawnPoint(this, true);
 268         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 269         this.angles = vec2(spot.angles);
 270         this.fixangle = true;
 271         // offset it so that the spectator spawns higher off the ground, looks better this way
 272         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 273         if (IS_REAL_CLIENT(this))
 274         {
 275             msg_entity = this;
 276             WriteByte(MSG_ONE, SVC_SETVIEW);
 277             WriteEntity(MSG_ONE, this);
 278         }
 279         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 280         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 281         if(!autocvar_g_debug_globalsounds)
 282         {
 283                 // needed for player sounds
 284                 this.model = "";
 285                 FixPlayermodel(this);
 286         }
 287         setmodel(this, MDL_Null);
 288         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 289         this.view_ofs = '0 0 0';
 290     }
 291
 292     RemoveGrapplingHooks(this);
 293         Portal_ClearAll(this);
 294         Unfreeze(this, false);
 295         SetSpectatee(this, NULL);
 296
 297         if (this.alivetime)
 298         {
 299                 if (!warmup_stage)
 300                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 301                 this.alivetime = 0;
 302         }
 303
 304         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 305
 306         WaypointSprite_PlayerDead(this);
 307
 308         if (CS(this).killcount != FRAGS_SPECTATOR)
 309         {
 310                 if(!game_stopped)
 311                 if(CHAT_NOSPECTATORS())
 312                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 313         }
 314
 315         accuracy_resend(this);
 316
 317         CS(this).spectatortime = time;
 318         if(this.bot_attack)
 319                 IL_REMOVE(g_bot_targets, this);
 320         this.bot_attack = false;
 321         if(this.monster_attack)
 322                 IL_REMOVE(g_monster_targets, this);
 323         this.monster_attack = false;
 324     STAT(HUD, this) = HUD_NORMAL;
 325         TRANSMUTE(Observer, this);
 326         this.iscreature = false;
 327         this.teleportable = TELEPORT_SIMPLE;
 328         if(this.damagedbycontents)
 329                 IL_REMOVE(g_damagedbycontents, this);
 330         this.damagedbycontents = false;
 331         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 332         SetSpectatee_status(this, etof(this));
 333         this.takedamage = DAMAGE_NO;
 334         this.solid = SOLID_NOT;
 335         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 336         this.flags = FL_CLIENT | FL_NOTARGET;
 337         this.effects = 0;
 338         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 339         this.pauserotarmor_finished = 0;
 340         this.pauserothealth_finished = 0;
 341         this.pauseregen_finished = 0;
 342         this.damageforcescale = 0;
 343         this.death_time = 0;
 344         this.respawn_flags = 0;
 345         this.respawn_time = 0;
 346         STAT(RESPAWN_TIME, this) = 0;
 347         this.alpha = 0;
 348         this.scale = 0;
 349         this.fade_time = 0;
 350         this.pain_finished = 0;
 351         STAT(STRENGTH_FINISHED, this) = 0;
 352         STAT(INVINCIBLE_FINISHED, this) = 0;
 353         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 354         STAT(AIR_FINISHED, this) = 0;
 355         //this.dphitcontentsmask = 0;
 356         this.dphitcontentsmask = DPCONTENTS_SOLID;
 357         if (autocvar_g_playerclip_collisions)
 358                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 359         this.pushltime = 0;
 360         this.istypefrag = 0;
 361         setthink(this, func_null);
 362         this.nextthink = 0;
 363         this.deadflag = DEAD_NO;
 364         UNSET_DUCKED(this);
 365         STAT(REVIVE_PROGRESS, this) = 0;
 366         this.revival_time = 0;
 367         this.draggable = drag_undraggable;
 368
 369         this.items = 0;
 370         STAT(WEAPONS, this) = '0 0 0';
 371         this.drawonlytoclient = this;
 372
 373         this.viewloc = NULL;
 374
 375         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 376
 377         this.weaponmodel = "";
 378         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 379         {
 380                 this.weaponentities[slot] = NULL;
 381         }
 382         this.exteriorweaponentity = NULL;
 383         CS(this).killcount = FRAGS_SPECTATOR;
 384         this.velocity = '0 0 0';
 385         this.avelocity = '0 0 0';
 386         this.punchangle = '0 0 0';
 387         this.punchvector = '0 0 0';
 388         this.oldvelocity = this.velocity;
 389         this.fire_endtime = -1;
 390         this.event_damage = func_null;
 391         this.event_heal = func_null;
 392
 393         for(int slot = 0; slot < MAX_AXH; ++slot)
 394         {
 395                 entity axh = this.(AuxiliaryXhair[slot]);
 396                 this.(AuxiliaryXhair[slot]) = NULL;
 397
 398                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 399                         delete(axh);
 400         }
 401
 402         if (mutator_returnvalue)
 403         {
 404                 // mutator prevents resetting teams+score
 405         }
 406         else
 407         {
 408                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 409                 this.frags = FRAGS_SPECTATOR;
 410         }
 411         if (CS(this).just_joined)
 412                 CS(this).just_joined = false;
 413 }
 414
 415 int player_getspecies(entity this)
 416 {
 417         get_model_parameters(this.model, this.skin);
 418         int s = get_model_parameters_species;
 419         get_model_parameters(string_null, 0);
 420         if (s < 0) return SPECIES_HUMAN;
 421         return s;
 422 }
 423
 424 .float model_randomizer;
 425 void FixPlayermodel(entity player)
 426 {
 427         string defaultmodel = "";
 428         int defaultskin = 0;
 429         if(autocvar_sv_defaultcharacter)
 430         {
 431                 if(teamplay)
 432                 {
 433                         switch(player.team)
 434                         {
 435                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 436                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 437                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 438                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 439                         }
 440                 }
 441
 442                 if(defaultmodel == "")
 443                 {
 444                         defaultmodel = autocvar_sv_defaultplayermodel;
 445                         defaultskin = autocvar_sv_defaultplayerskin;
 446                 }
 447
 448                 int n = tokenize_console(defaultmodel);
 449                 if(n > 0)
 450                 {
 451                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 452                         // However, do NOT randomize if the player-selected model is in the list.
 453                         for (int i = 0; i < n; ++i)
 454                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 455                                         defaultmodel = argv(i);
 456                 }
 457
 458                 int i = strstrofs(defaultmodel, ":", 0);
 459                 if(i >= 0)
 460                 {
 461                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 462                         defaultmodel = substring(defaultmodel, 0, i);
 463                 }
 464         }
 465         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 466         {
 467                 if(teamplay)
 468                 {
 469                         switch(player.team)
 470                         {
 471                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 472                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 473                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 474                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 475                         }
 476                 }
 477
 478                 if(!defaultskin)
 479                         defaultskin = autocvar_sv_defaultplayerskin;
 480         }
 481
 482         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 483         defaultmodel = M_ARGV(0, string);
 484         defaultskin = M_ARGV(1, int);
 485
 486         bool chmdl = false;
 487         int oldskin;
 488         if(defaultmodel != "")
 489         {
 490                 if (defaultmodel != player.model)
 491                 {
 492                         vector m1 = player.mins;
 493                         vector m2 = player.maxs;
 494                         setplayermodel (player, defaultmodel);
 495                         setsize (player, m1, m2);
 496                         chmdl = true;
 497                 }
 498
 499                 oldskin = player.skin;
 500                 player.skin = defaultskin;
 501         } else {
 502                 if (player.playermodel != player.model || player.playermodel == "")
 503                 {
 504                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 505                         vector m1 = player.mins;
 506                         vector m2 = player.maxs;
 507                         setplayermodel (player, player.playermodel);
 508                         setsize (player, m1, m2);
 509                         chmdl = true;
 510                 }
 511
 512                 if(!autocvar_sv_defaultcharacterskin)
 513                 {
 514                         oldskin = player.skin;
 515                         player.skin = stof(player.playerskin);
 516                 }
 517                 else
 518                 {
 519                         oldskin = player.skin;
 520                         player.skin = defaultskin;
 521                 }
 522         }
 523
 524         if(chmdl || oldskin != player.skin) // model or skin has changed
 525         {
 526                 player.species = player_getspecies(player); // update species
 527                 if(!autocvar_g_debug_globalsounds)
 528                         UpdatePlayerSounds(player); // update skin sounds
 529         }
 530
 531         if(!teamplay)
 532                 if(strlen(autocvar_sv_defaultplayercolors))
 533                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 534                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 535 }
 536
 537 void PutPlayerInServer(entity this)
 538 {
 539         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 540
 541         PlayerState_attach(this);
 542         accuracy_resend(this);
 543
 544         if (this.team < 0)
 545                 TeamBalance_JoinBestTeam(this);
 546
 547         entity spot = SelectSpawnPoint(this, false);
 548         if (!spot) {
 549                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 550                 return; // spawn failed
 551         }
 552
 553         TRANSMUTE(Player, this);
 554
 555         CS(this).wasplayer = true;
 556         this.iscreature = true;
 557         this.teleportable = TELEPORT_NORMAL;
 558         if(!this.damagedbycontents)
 559                 IL_PUSH(g_damagedbycontents, this);
 560         this.damagedbycontents = true;
 561         set_movetype(this, MOVETYPE_WALK);
 562         this.solid = SOLID_SLIDEBOX;
 563         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 564         if (autocvar_g_playerclip_collisions)
 565                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 566         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 567                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 568         this.frags = FRAGS_PLAYER;
 569         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 570         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 571         if (autocvar__notarget)
 572                 this.flags |= FL_NOTARGET;
 573         this.takedamage = DAMAGE_AIM;
 574         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 575
 576         if (warmup_stage) {
 577                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 578                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 579                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 580                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 581                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 582                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 583                 SetResource(this, RES_HEALTH, warmup_start_health);
 584                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 585                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 586         } else {
 587                 SetResource(this, RES_SHELLS, start_ammo_shells);
 588                 SetResource(this, RES_BULLETS, start_ammo_nails);
 589                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 590                 SetResource(this, RES_CELLS, start_ammo_cells);
 591                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 592                 SetResource(this, RES_FUEL, start_ammo_fuel);
 593                 SetResource(this, RES_HEALTH, start_health);
 594                 SetResource(this, RES_ARMOR, start_armorvalue);
 595                 STAT(WEAPONS, this) = start_weapons;
 596                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 597                 {
 598                         GiveRandomWeapons(this, random_start_weapons_count,
 599                                 autocvar_g_random_start_weapons, random_start_ammo);
 600                 }
 601         }
 602         SetSpectatee_status(this, 0);
 603
 604         PS(this).dual_weapons = '0 0 0';
 605
 606         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 607
 608         this.items = start_items;
 609
 610         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 611         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 612         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 613         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 614         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 615         if (!sv_ready_restart_after_countdown && time < game_starttime)
 616         {
 617                 float f = game_starttime - time;
 618                 this.spawnshieldtime += f;
 619                 this.pauserotarmor_finished += f;
 620                 this.pauserothealth_finished += f;
 621                 this.pauseregen_finished += f;
 622         }
 623
 624         this.damageforcescale = autocvar_g_player_damageforcescale;
 625         this.death_time = 0;
 626         this.respawn_flags = 0;
 627         this.respawn_time = 0;
 628         STAT(RESPAWN_TIME, this) = 0;
 629         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 630         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 631         this.fade_time = 0;
 632         this.pain_finished = 0;
 633         this.pushltime = 0;
 634         setthink(this, func_null); // players have no think function
 635         this.nextthink = 0;
 636         this.dmg_team = 0;
 637         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 638
 639         this.deadflag = DEAD_NO;
 640
 641         this.angles = spot.angles;
 642         this.angles_z = 0; // never spawn tilted even if the spot says to
 643         if (IS_BOT_CLIENT(this))
 644         {
 645                 this.v_angle = this.angles;
 646                 bot_aim_reset(this);
 647         }
 648         this.fixangle = true; // turn this way immediately
 649         this.oldvelocity = this.velocity = '0 0 0';
 650         this.avelocity = '0 0 0';
 651         this.punchangle = '0 0 0';
 652         this.punchvector = '0 0 0';
 653
 654         STAT(STRENGTH_FINISHED, this) = 0;
 655         STAT(INVINCIBLE_FINISHED, this) = 0;
 656         this.fire_endtime = -1;
 657         STAT(REVIVE_PROGRESS, this) = 0;
 658         this.revival_time = 0;
 659
 660         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 661         STAT(BUFFS, this) = 0;
 662         STAT(BUFF_TIME, this) = 0;
 663
 664         STAT(AIR_FINISHED, this) = 0;
 665         this.waterlevel = WATERLEVEL_NONE;
 666         this.watertype = CONTENT_EMPTY;
 667
 668         entity spawnevent = new_pure(spawnevent);
 669         spawnevent.owner = this;
 670         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 671
 672         // Cut off any still running player sounds.
 673         stopsound(this, CH_PLAYER_SINGLE);
 674
 675         this.model = "";
 676         FixPlayermodel(this);
 677         this.drawonlytoclient = NULL;
 678
 679         this.viewloc = NULL;
 680
 681         for(int slot = 0; slot < MAX_AXH; ++slot)
 682         {
 683                 entity axh = this.(AuxiliaryXhair[slot]);
 684                 this.(AuxiliaryXhair[slot]) = NULL;
 685
 686                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 687                         delete(axh);
 688         }
 689
 690         this.spawnpoint_targ = NULL;
 691
 692         UNSET_DUCKED(this);
 693         this.view_ofs = STAT(PL_VIEW_OFS, this);
 694         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 695         this.spawnorigin = spot.origin;
 696         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 697         // don't reset back to last position, even if new position is stuck in solid
 698         this.oldorigin = this.origin;
 699         if(this.conveyor)
 700                 IL_REMOVE(g_conveyed, this);
 701         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 702         if(this.swampslug)
 703                 IL_REMOVE(g_swamped, this);
 704         this.swampslug = NULL;
 705         this.swamp_interval = 0;
 706         if(this.ladder_entity)
 707                 IL_REMOVE(g_ladderents, this);
 708         this.ladder_entity = NULL;
 709         IL_EACH(g_counters, it.realowner == this,
 710         {
 711                 delete(it);
 712         });
 713         STAT(HUD, this) = HUD_NORMAL;
 714
 715         this.event_damage = PlayerDamage;
 716         this.event_heal = PlayerHeal;
 717
 718         this.draggable = func_null;
 719
 720         if(!this.bot_attack)
 721                 IL_PUSH(g_bot_targets, this);
 722         this.bot_attack = true;
 723         if(!this.monster_attack)
 724                 IL_PUSH(g_monster_targets, this);
 725         this.monster_attack = true;
 726         navigation_dynamicgoal_init(this, false);
 727
 728         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 729
 730         // player was spectator
 731         if (CS(this).killcount == FRAGS_SPECTATOR) {
 732                 PlayerScore_Clear(this);
 733                 CS(this).killcount = 0;
 734                 CS(this).startplaytime = time;
 735         }
 736
 737         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 738         {
 739                 .entity weaponentity = weaponentities[slot];
 740                 CL_SpawnWeaponentity(this, weaponentity);
 741         }
 742         this.alpha = default_player_alpha;
 743         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 744         this.exteriorweaponentity.alpha = default_weapon_alpha;
 745
 746         this.speedrunning = false;
 747
 748         this.counter_cnt = 0;
 749         this.fragsfilter_cnt = 0;
 750
 751         target_voicescript_clear(this);
 752
 753         // reset fields the weapons may use
 754         FOREACH(Weapons, true, {
 755                 it.wr_resetplayer(it, this);
 756                         // reload all reloadable weapons
 757                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 758                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 759                         {
 760                                 .entity weaponentity = weaponentities[slot];
 761                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 762                         }
 763                 }
 764         });
 765
 766         {
 767                 string s = spot.target;
 768                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 769                         spot.target = string_null;
 770                 SUB_UseTargets(spot, this, NULL);
 771                 if(g_assault || g_race)
 772                         spot.target = s;
 773         }
 774
 775         Unfreeze(this, false);
 776
 777         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 778
 779         if (autocvar_spawn_debug)
 780         {
 781                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 782                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 783         }
 784
 785         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 786         {
 787                 .entity weaponentity = weaponentities[slot];
 788                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 789                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 790                 else
 791                         this.(weaponentity).m_switchweapon = WEP_Null;
 792                 this.(weaponentity).m_weapon = WEP_Null;
 793                 this.(weaponentity).weaponname = "";
 794                 this.(weaponentity).m_switchingweapon = WEP_Null;
 795                 this.(weaponentity).cnt = -1;
 796         }
 797
 798         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 799
 800         if (CS(this).impulse) ImpulseCommands(this);
 801
 802         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 803         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 804         {
 805                 .entity weaponentity = weaponentities[slot];
 806                 W_WeaponFrame(this, weaponentity);
 807         }
 808
 809         if (!warmup_stage && !this.alivetime)
 810                 this.alivetime = time;
 811
 812         antilag_clear(this, CS(this));
 813 }
 814
 815 /** Called when a client spawns in the server */
 816 void PutClientInServer(entity this)
 817 {
 818         if (IS_BOT_CLIENT(this)) {
 819                 TRANSMUTE(Player, this);
 820         } else if (IS_REAL_CLIENT(this)) {
 821                 msg_entity = this;
 822                 WriteByte(MSG_ONE, SVC_SETVIEW);
 823                 WriteEntity(MSG_ONE, this);
 824         }
 825         if (game_stopped)
 826                 TRANSMUTE(Observer, this);
 827
 828         SetSpectatee(this, NULL);
 829
 830         // reset player keys
 831         if(PS(this))
 832                 PS(this).itemkeys = 0;
 833
 834         MUTATOR_CALLHOOK(PutClientInServer, this);
 835
 836         if (IS_OBSERVER(this)) {
 837                 PutObserverInServer(this);
 838         } else if (IS_PLAYER(this)) {
 839                 PutPlayerInServer(this);
 840         }
 841 }
 842
 843 // TODO do we need all these fields, or should we stop autodetecting runtime
 844 // changes and just have a console command to update this?
 845 bool ClientInit_SendEntity(entity this, entity to, int sf)
 846 {
 847         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 848         return = true;
 849         msg_entity = to;
 850         // MSG_INIT replacement
 851         // TODO: make easier to use
 852         Registry_send_all();
 853         W_PROP_reload(MSG_ONE, to);
 854         ClientInit_misc(this);
 855         MUTATOR_CALLHOOK(Ent_Init);
 856 }
 857 void ClientInit_misc(entity this)
 858 {
 859         int channel = MSG_ONE;
 860         WriteHeader(channel, ENT_CLIENT_INIT);
 861         WriteByte(channel, g_nexball_meter_period * 32);
 862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 863         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 864         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 865         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 867         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 868         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 869         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 870
 871         if(sv_foginterval && world.fog != "")
 872                 WriteString(channel, world.fog);
 873         else
 874                 WriteString(channel, "");
 875         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 876         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 877         WriteByte(channel, serverflags);
 878         WriteCoord(channel, autocvar_g_trueaim_minrange);
 879 }
 880
 881 void ClientInit_CheckUpdate(entity this)
 882 {
 883         this.nextthink = time;
 884         if(this.count != autocvar_g_balance_armor_blockpercent)
 885         {
 886                 this.count = autocvar_g_balance_armor_blockpercent;
 887                 this.SendFlags |= 1;
 888         }
 889         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 890         {
 891                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 892                 this.SendFlags |= 1;
 893         }
 894 }
 895
 896 void ClientInit_Spawn()
 897 {
 898         entity e = new_pure(clientinit);
 899         setthink(e, ClientInit_CheckUpdate);
 900         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 901
 902         ClientInit_CheckUpdate(e);
 903 }
 904
 905 /*
 906 =============
 907 SetNewParms
 908 =============
 909 */
 910 void SetNewParms ()
 911 {
 912         // initialize parms for a new player
 913         parm1 = -(86400 * 366);
 914
 915         MUTATOR_CALLHOOK(SetNewParms);
 916 }
 917
 918 /*
 919 =============
 920 SetChangeParms
 921 =============
 922 */
 923 void SetChangeParms (entity this)
 924 {
 925         // save parms for level change
 926         parm1 = CS(this).parm_idlesince - time;
 927
 928         MUTATOR_CALLHOOK(SetChangeParms);
 929 }
 930
 931 /*
 932 =============
 933 DecodeLevelParms
 934 =============
 935 */
 936 void DecodeLevelParms(entity this)
 937 {
 938         // load parms
 939         CS(this).parm_idlesince = parm1;
 940         if (CS(this).parm_idlesince == -(86400 * 366))
 941                 CS(this).parm_idlesince = time;
 942
 943         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 944         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 945
 946         MUTATOR_CALLHOOK(DecodeLevelParms);
 947 }
 948
 949 void FixClientCvars(entity e)
 950 {
 951         // send prediction settings to the client
 952         stuffcmd(e, "\nin_bindmap 0 0\n");
 953         if(autocvar_g_antilag == 3) // client side hitscan
 954                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 955         if(autocvar_sv_gentle)
 956                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 957
 958         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 959         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 960
 961         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 962
 963         MUTATOR_CALLHOOK(FixClientCvars, e);
 964 }
 965
 966 bool findinlist_abbrev(string tofind, string list)
 967 {
 968         if(list == "" || tofind == "")
 969                 return false; // empty list or search, just return
 970
 971         // this function allows abbreviated strings!
 972         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 973         {
 974                 return true;
 975         });
 976
 977         return false;
 978 }
 979
 980 bool PlayerInIPList(entity p, string iplist)
 981 {
 982         // some safety checks (never allow local?)
 983         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 984                 return false;
 985
 986         return findinlist_abbrev(p.netaddress, iplist);
 987 }
 988
 989 bool PlayerInIDList(entity p, string idlist)
 990 {
 991         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 992         if(!p.crypto_idfp)
 993                 return false;
 994
 995         return findinlist_abbrev(p.crypto_idfp, idlist);
 996 }
 997
 998 bool PlayerInList(entity player, string list)
 999 {
1000         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1001 }
1002
1003 #ifdef DP_EXT_PRECONNECT
1004 /*
1005 =============
1006 ClientPreConnect
1007
1008 Called once (not at each match start) when a client begins a connection to the server
1009 =============
1010 */
1011 void ClientPreConnect(entity this)
1012 {
1013         if(autocvar_sv_eventlog)
1014         {
1015                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1016                         this.playerid,
1017                         etof(this),
1018                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1019                 ));
1020         }
1021 }
1022 #endif
1023
1024 string GetClientVersionMessage(entity this)
1025 {
1026         if (CS(this).version_mismatch) {
1027                 if(CS(this).version < autocvar_gameversion) {
1028                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1029                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1030                 } else {
1031                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1032                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1033                 }
1034         } else {
1035                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1036         }
1037 }
1038
1039 string getwelcomemessage(entity this)
1040 {
1041         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1042         string modifications = M_ARGV(0, string);
1043
1044         if(g_weaponarena)
1045         {
1046                 if(g_weaponarena_random)
1047                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1048                 else
1049                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1050         }
1051         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1052                 modifications = strcat(modifications, ", No start weapons");
1053         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1054                 modifications = strcat(modifications, ", Low gravity");
1055         if(g_weapon_stay && !g_cts)
1056                 modifications = strcat(modifications, ", Weapons stay");
1057         if(g_jetpack)
1058                 modifications = strcat(modifications, ", Jet pack");
1059         if(autocvar_g_powerups == 0)
1060                 modifications = strcat(modifications, ", No powerups");
1061         if(autocvar_g_powerups > 0)
1062                 modifications = strcat(modifications, ", Powerups");
1063         modifications = substring(modifications, 2, strlen(modifications) - 2);
1064
1065         string versionmessage = GetClientVersionMessage(this);
1066         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1067
1068         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1069
1070         if(modifications != "")
1071                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1072
1073         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1074         {
1075                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1076                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1077         }
1078
1079         if (cache_mutatormsg != "") {
1080                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1081         }
1082
1083         string mutator_msg = "";
1084         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1085         mutator_msg = M_ARGV(0, string);
1086
1087         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1088
1089         string motd = autocvar_sv_motd;
1090         if (motd != "") {
1091                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1092         }
1093         return s;
1094 }
1095
1096 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1097
1098 /**
1099 =============
1100 ClientConnect
1101
1102 Called when a client connects to the server
1103 =============
1104 */
1105 void ClientConnect(entity this)
1106 {
1107         if (Ban_MaybeEnforceBanOnce(this)) return;
1108         assert(!IS_CLIENT(this), return);
1109         this.flags |= FL_CLIENT;
1110         assert(player_count >= 0, player_count = 0);
1111
1112 #ifdef WATERMARK
1113         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1114 #endif
1115         TRANSMUTE(Client, this);
1116         CS(this).version_nagtime = time + 10 + random() * 10;
1117
1118         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1119
1120         bot_clientconnect(this);
1121
1122         Player_DetermineForcedTeam(this);
1123
1124         TRANSMUTE(Observer, this);
1125
1126         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1127
1128         // always track bots, don't ask for cl_allow_uidtracking
1129         if (IS_BOT_CLIENT(this))
1130                 PlayerStats_GameReport_AddPlayer(this);
1131         else
1132                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1133
1134         if (autocvar_sv_eventlog)
1135                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1136
1137         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1138
1139         stuffcmd(this, clientstuff, "\n");
1140         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1141
1142         FixClientCvars(this);
1143
1144         // get version info from player
1145         stuffcmd(this, "cmd clientversion $gameversion\n");
1146
1147         // notify about available teams
1148         if (teamplay)
1149         {
1150                 entity balance = TeamBalance_CheckAllowedTeams(this);
1151                 int t = TeamBalance_GetAllowedTeams(balance);
1152                 TeamBalance_Destroy(balance);
1153                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1154         }
1155         else
1156         {
1157                 stuffcmd(this, "set _teams_available 0\n");
1158         }
1159
1160         bot_relinkplayerlist();
1161
1162         CS(this).spectatortime = time;
1163         if (blockSpectators)
1164         {
1165                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1166         }
1167
1168         CS(this).jointime = time;
1169
1170         if (IS_REAL_CLIENT(this))
1171         {
1172                 if (g_weaponarena_weapons == WEPSET(TUBA))
1173                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1174         }
1175
1176         if (!sv_foginterval && world.fog != "")
1177                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1178
1179         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1180                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1181                         send_CSQC_teamnagger();
1182
1183         CSQCMODEL_AUTOINIT(this);
1184
1185         CS(this).model_randomizer = random();
1186
1187         if (IS_REAL_CLIENT(this))
1188                 sv_notice_join(this);
1189
1190         this.move_qcphysics = autocvar_sv_qcphysics;
1191
1192         // update physics stats (players can spawn before physics runs)
1193         Physics_UpdateStats(this);
1194
1195         IL_EACH(g_initforplayer, it.init_for_player, {
1196                 it.init_for_player(it, this);
1197         });
1198
1199         Handicap_Initialize(this);
1200
1201         MUTATOR_CALLHOOK(ClientConnect, this);
1202
1203         if (IS_REAL_CLIENT(this))
1204         {
1205                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1206                 {
1207                         CS(this).motd_actived_time = -1;
1208                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1209                 }
1210         }
1211 }
1212 /*
1213 =============
1214 ClientDisconnect
1215
1216 Called when a client disconnects from the server
1217 =============
1218 */
1219 .entity chatbubbleentity;
1220 void ClientDisconnect(entity this)
1221 {
1222         assert(IS_CLIENT(this), return);
1223
1224         PlayerStats_GameReport_FinalizePlayer(this);
1225         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1226         if (CS(this).active_minigame) part_minigame(this);
1227         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1228
1229         if (autocvar_sv_eventlog)
1230                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1231
1232         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1233
1234         if(IS_SPEC(this))
1235                 SetSpectatee(this, NULL);
1236
1237     MUTATOR_CALLHOOK(ClientDisconnect, this);
1238
1239         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1240         strfree(CS(this).weaponorder_byimpulse);
1241         ClientState_detach(this);
1242
1243         Portal_ClearAll(this);
1244
1245         Unfreeze(this, false);
1246
1247         RemoveGrapplingHooks(this);
1248
1249         // Here, everything has been done that requires this player to be a client.
1250
1251         this.flags &= ~FL_CLIENT;
1252
1253         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1254         if (this.killindicator) delete(this.killindicator);
1255
1256         IL_EACH(g_counters, it.realowner == this,
1257         {
1258                 delete(it);
1259         });
1260
1261         WaypointSprite_PlayerGone(this);
1262
1263         bot_relinkplayerlist();
1264
1265         strfree(this.clientstatus);
1266         if (this.personal) delete(this.personal);
1267
1268         this.playerid = 0;
1269         ReadyCount();
1270         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1271
1272         ONREMOVE(this);
1273 }
1274
1275 void ChatBubbleThink(entity this)
1276 {
1277         this.nextthink = time;
1278         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1279         {
1280                 if(this.owner) // but why can that ever be NULL?
1281                         this.owner.chatbubbleentity = NULL;
1282                 delete(this);
1283                 return;
1284         }
1285
1286         this.mdl = "";
1287
1288         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1289         {
1290                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1291                         this.mdl = "models/sprites/minigame_busy.iqm";
1292                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1293                         this.mdl = "models/misc/chatbubble.spr";
1294         }
1295
1296         if ( this.model != this.mdl )
1297                 _setmodel(this, this.mdl);
1298
1299 }
1300
1301 void UpdateChatBubble(entity this)
1302 {
1303         if (this.alpha < 0)
1304                 return;
1305         // spawn a chatbubble entity if needed
1306         if (!this.chatbubbleentity)
1307         {
1308                 this.chatbubbleentity = new(chatbubbleentity);
1309                 this.chatbubbleentity.owner = this;
1310                 this.chatbubbleentity.exteriormodeltoclient = this;
1311                 setthink(this.chatbubbleentity, ChatBubbleThink);
1312                 this.chatbubbleentity.nextthink = time;
1313                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1314                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1315                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1316                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1317                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1318                 //this.chatbubbleentity.model = "";
1319                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1320         }
1321 }
1322
1323 void calculate_player_respawn_time(entity this)
1324 {
1325         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1326                 return;
1327
1328         float gametype_setting_tmp;
1329         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1330         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1331         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1332         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1333         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1334         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1335
1336         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1337         if (teamplay)
1338         {
1339                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1340                         if(it.team == this.team)
1341                                 ++pcount;
1342                 });
1343                 if (sdelay_small_count == 0)
1344                         sdelay_small_count = 1;
1345                 if (sdelay_large_count == 0)
1346                         sdelay_large_count = 1;
1347         }
1348         else
1349         {
1350                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1351                         ++pcount;
1352                 });
1353                 if (sdelay_small_count == 0)
1354                 {
1355                         if (IS_INDEPENDENT_PLAYER(this))
1356                         {
1357                                 // Players play independently. No point in requiring enemies.
1358                                 sdelay_small_count = 1;
1359                         }
1360                         else
1361                         {
1362                                 // Players play AGAINST each other. Enemies required.
1363                                 sdelay_small_count = 2;
1364                         }
1365                 }
1366                 if (sdelay_large_count == 0)
1367                 {
1368                         if (IS_INDEPENDENT_PLAYER(this))
1369                         {
1370                                 // Players play independently. No point in requiring enemies.
1371                                 sdelay_large_count = 1;
1372                         }
1373                         else
1374                         {
1375                                 // Players play AGAINST each other. Enemies required.
1376                                 sdelay_large_count = 2;
1377                         }
1378                 }
1379         }
1380
1381         float sdelay;
1382
1383         if (pcount <= sdelay_small_count)
1384                 sdelay = sdelay_small;
1385         else if (pcount >= sdelay_large_count)
1386                 sdelay = sdelay_large;
1387         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1388                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1389
1390         if(waves)
1391                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1392         else
1393                 this.respawn_time = time + sdelay;
1394
1395         if(sdelay < sdelay_max)
1396                 this.respawn_time_max = time + sdelay_max;
1397         else
1398                 this.respawn_time_max = this.respawn_time;
1399
1400         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1401                 this.respawn_countdown = 10; // first number to count down from is 10
1402         else
1403                 this.respawn_countdown = -1; // do not count down
1404
1405         if(autocvar_g_forced_respawn)
1406                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1407 }
1408
1409 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1410 // added to the model skins
1411 /*void UpdateColorModHack()
1412 {
1413         float c;
1414         c = this.clientcolors & 15;
1415         // LordHavoc: only bothering to support white, green, red, yellow, blue
1416              if (!teamplay) this.colormod = '0 0 0';
1417         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1418         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1419         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1420         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1421         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1422         else this.colormod = '1 1 1';
1423 }*/
1424
1425 void respawn(entity this)
1426 {
1427         bool damagedbycontents_prev = this.damagedbycontents;
1428         if(this.alpha >= 0)
1429         {
1430                 if(autocvar_g_respawn_ghosts)
1431                 {
1432                         this.solid = SOLID_NOT;
1433                         this.takedamage = DAMAGE_NO;
1434                         this.damagedbycontents = false;
1435                         set_movetype(this, MOVETYPE_FLY);
1436                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1437                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1438                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1439                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1440                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1441                         if(autocvar_g_respawn_ghosts_time > 0)
1442                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1443                 }
1444                 else
1445                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1446         }
1447
1448         CopyBody(this, 1);
1449         this.damagedbycontents = damagedbycontents_prev;
1450
1451         this.effects |= EF_NODRAW; // prevent another CopyBody
1452         PutClientInServer(this);
1453 }
1454
1455 ERASEABLE
1456 void PrintToChat(entity client, string text)
1457 {
1458         text = strcat("\{1}^7", text, "\n");
1459         sprint(client, text);
1460 }
1461
1462 ERASEABLE
1463 void DebugPrintToChat(entity client, string text)
1464 {
1465         if (autocvar_developer > 0)
1466         {
1467                 PrintToChat(client, text);
1468         }
1469 }
1470
1471 ERASEABLE
1472 void PrintToChatAll(string text)
1473 {
1474         text = strcat("\{1}^7", text, "\n");
1475         bprint(text);
1476 }
1477
1478 ERASEABLE
1479 void DebugPrintToChatAll(string text)
1480 {
1481         if (autocvar_developer > 0)
1482         {
1483                 PrintToChatAll(text);
1484         }
1485 }
1486
1487 ERASEABLE
1488 void PrintToChatTeam(int team_num, string text)
1489 {
1490         text = strcat("\{1}^7", text, "\n");
1491         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1492         {
1493                 if (it.team == team_num)
1494                 {
1495                         sprint(it, text);
1496                 }
1497         });
1498 }
1499
1500 ERASEABLE
1501 void DebugPrintToChatTeam(int team_num, string text)
1502 {
1503         if (autocvar_developer > 0)
1504         {
1505                 PrintToChatTeam(team_num, text);
1506         }
1507 }
1508
1509 void play_countdown(entity this, float finished, Sound samp)
1510 {
1511         TC(Sound, samp);
1512         if(IS_REAL_CLIENT(this))
1513                 if(floor(finished - time - frametime) != floor(finished - time))
1514                         if(finished - time < 6)
1515                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1516 }
1517
1518 void player_powerups(entity this)
1519 {
1520         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1521                 this.modelflags |= MF_ROCKET;
1522         else
1523                 this.modelflags &= ~MF_ROCKET;
1524
1525         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1526
1527         if (IS_DEAD(this))
1528         {
1529                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1530                 {
1531                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1532                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1533                         this.items &= ~ITEM_Strength.m_itemid;
1534                         this.items &= ~ITEM_Shield.m_itemid;
1535                         this.items -= (this.items & IT_SUPERWEAPON);
1536                 }
1537         }
1538
1539         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1540                 return;
1541
1542         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1543         int items_prev = this.items;
1544
1545         Fire_ApplyDamage(this);
1546         Fire_ApplyEffect(this);
1547
1548         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1549         {
1550                 if (this.items & ITEM_Strength.m_itemid)
1551                 {
1552                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1553                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1554                         if (time > STAT(STRENGTH_FINISHED, this))
1555                         {
1556                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1557                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1558                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1559                         }
1560                 }
1561                 else
1562                 {
1563                         if (time < STAT(STRENGTH_FINISHED, this))
1564                         {
1565                                 this.items = this.items | ITEM_Strength.m_itemid;
1566                                 if(!g_cts)
1567                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1568                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1569                         }
1570                 }
1571                 if (this.items & ITEM_Shield.m_itemid)
1572                 {
1573                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1574                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1575                         if (time > STAT(INVINCIBLE_FINISHED, this))
1576                         {
1577                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1578                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1579                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1580                         }
1581                 }
1582                 else
1583                 {
1584                         if (time < STAT(INVINCIBLE_FINISHED, this))
1585                         {
1586                                 this.items = this.items | ITEM_Shield.m_itemid;
1587                                 if(!g_cts)
1588                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1589                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1590                         }
1591                 }
1592                 if (this.items & IT_SUPERWEAPON)
1593                 {
1594                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1595                         {
1596                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1597                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1598                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1599                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1600                         }
1601                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1602                         {
1603                                 // don't let them run out
1604                         }
1605                         else
1606                         {
1607                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1608                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1609                                 {
1610                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1611                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1612                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1613                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1614                                 }
1615                         }
1616                 }
1617                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1618                 {
1619                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1620                         {
1621                                 this.items = this.items | IT_SUPERWEAPON;
1622                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1623                                 {
1624                                         if(!g_cts)
1625                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1626                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1627                                 }
1628                         }
1629                         else
1630                         {
1631                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1632                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1633                         }
1634                 }
1635                 else
1636                 {
1637                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1638                 }
1639         }
1640
1641         if(autocvar_g_nodepthtestplayers)
1642                 this.effects = this.effects | EF_NODEPTHTEST;
1643
1644         if(autocvar_g_fullbrightplayers)
1645                 this.effects = this.effects | EF_FULLBRIGHT;
1646
1647         if (time >= game_starttime)
1648         if (time < this.spawnshieldtime)
1649                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1650
1651         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1652 }
1653
1654 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1655 {
1656         if(current > stable)
1657                 return current;
1658         else if(current > stable - 0.25) // when close enough, "snap"
1659                 return stable;
1660         else
1661                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1662 }
1663
1664 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1665 {
1666         if(current < stable)
1667                 return current;
1668         else if(current < stable + 0.25) // when close enough, "snap"
1669                 return stable;
1670         else
1671                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1672 }
1673
1674 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1675 {
1676         float old = GetResource(this, res);
1677         float current = old;
1678         if(current > rotstable)
1679         {
1680                 if(rotframetime > 0)
1681                 {
1682                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1683                         current = max(rotstable, current - rotlinear * rotframetime);
1684                 }
1685         }
1686         else if(current < regenstable)
1687         {
1688                 if(regenframetime > 0)
1689                 {
1690                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1691                         current = min(regenstable, current + regenlinear * regenframetime);
1692                 }
1693         }
1694
1695         float limit = GetResourceLimit(this, res) * limit_mod;
1696         if(current > limit)
1697                 current = limit;
1698
1699         if (current != old)
1700                 SetResource(this, res, current);
1701 }
1702
1703 void player_regen(entity this)
1704 {
1705         float max_mod, regen_mod, rot_mod, limit_mod;
1706         max_mod = regen_mod = rot_mod = limit_mod = 1;
1707
1708         float regen_health = autocvar_g_balance_health_regen;
1709         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1710         float regen_health_rot = autocvar_g_balance_health_rot;
1711         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1712         float regen_health_stable = autocvar_g_balance_health_regenstable;
1713         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1714         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1715                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1716         max_mod = M_ARGV(1, float);
1717         regen_mod = M_ARGV(2, float);
1718         rot_mod = M_ARGV(3, float);
1719         limit_mod = M_ARGV(4, float);
1720         regen_health = M_ARGV(5, float);
1721         regen_health_linear = M_ARGV(6, float);
1722         regen_health_rot = M_ARGV(7, float);
1723         regen_health_rotlinear = M_ARGV(8, float);
1724         regen_health_stable = M_ARGV(9, float);
1725         regen_health_rotstable = M_ARGV(10, float);
1726
1727         if(!mutator_returnvalue)
1728         if(!STAT(FROZEN, this))
1729         {
1730                 float maxa = autocvar_g_balance_armor_rotstable;
1731                 float mina = autocvar_g_balance_armor_regenstable;
1732
1733                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1734                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1735                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1736
1737                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1738                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1739                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1740         }
1741
1742         // if player rotted to death...  die!
1743         // check this outside above checks, as player may still be able to rot to death
1744         if(GetResource(this, RES_HEALTH) < 1)
1745         {
1746                 if(this.vehicle)
1747                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1748                 if(this.event_damage)
1749                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1750         }
1751
1752         if (!(this.items & IT_UNLIMITED_AMMO))
1753         {
1754                 float maxf = autocvar_g_balance_fuel_rotstable;
1755                 float minf = autocvar_g_balance_fuel_regenstable;
1756
1757                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1758                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1759                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1760         }
1761 }
1762
1763 bool zoomstate_set;
1764 void SetZoomState(entity this, float newzoom)
1765 {
1766         if(newzoom != CS(this).zoomstate)
1767         {
1768                 CS(this).zoomstate = newzoom;
1769                 ClientData_Touch(this);
1770         }
1771         zoomstate_set = true;
1772 }
1773
1774 void GetPressedKeys(entity this)
1775 {
1776         MUTATOR_CALLHOOK(GetPressedKeys, this);
1777         int keys = STAT(PRESSED_KEYS, this);
1778         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1779         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1780         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1781         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1782
1783         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1784         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1785         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1786         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1787         CS(this).pressedkeys = keys; // store for other users
1788
1789         STAT(PRESSED_KEYS, this) = keys;
1790 }
1791
1792 /*
1793 ======================
1794 spectate mode routines
1795 ======================
1796 */
1797
1798 void SpectateCopy(entity this, entity spectatee)
1799 {
1800         TC(Client, this); TC(Client, spectatee);
1801
1802         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1803         PS(this) = PS(spectatee);
1804         this.armortype = spectatee.armortype;
1805         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1806         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1807         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1808         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1809         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1810         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1811         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1812         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1813         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1814         CS(this).impulse = 0;
1815         this.disableclientprediction = 1; // no need to run prediction on a spectator
1816         this.items = spectatee.items;
1817         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1818         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1819         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1820         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1821         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1822         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1823         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1824         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1825         this.punchangle = spectatee.punchangle;
1826         this.view_ofs = spectatee.view_ofs;
1827         this.velocity = spectatee.velocity;
1828         this.dmg_take = spectatee.dmg_take;
1829         this.dmg_save = spectatee.dmg_save;
1830         this.dmg_inflictor = spectatee.dmg_inflictor;
1831         this.v_angle = spectatee.v_angle;
1832         this.angles = spectatee.v_angle;
1833         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1834         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1835         this.viewloc = spectatee.viewloc;
1836         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1837                 this.fixangle = true;
1838         setorigin(this, spectatee.origin);
1839         setsize(this, spectatee.mins, spectatee.maxs);
1840         SetZoomState(this, CS(spectatee).zoomstate);
1841
1842     anticheat_spectatecopy(this, spectatee);
1843         STAT(HUD, this) = STAT(HUD, spectatee);
1844         if(spectatee.vehicle)
1845     {
1846         this.angles = spectatee.v_angle;
1847
1848         //this.fixangle = false;
1849         //this.velocity = spectatee.vehicle.velocity;
1850         this.vehicle_health = spectatee.vehicle_health;
1851         this.vehicle_shield = spectatee.vehicle_shield;
1852         this.vehicle_energy = spectatee.vehicle_energy;
1853         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1854         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1855         this.vehicle_reload1 = spectatee.vehicle_reload1;
1856         this.vehicle_reload2 = spectatee.vehicle_reload2;
1857
1858         //msg_entity = this;
1859
1860        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1861             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1862            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1863            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1864
1865         //WriteByte (MSG_ONE, SVC_SETVIEW);
1866         //    WriteEntity(MSG_ONE, this);
1867         //makevectors(spectatee.v_angle);
1868         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1869     }
1870 }
1871
1872 bool SpectateUpdate(entity this)
1873 {
1874         if(!this.enemy)
1875                 return false;
1876
1877         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1878         {
1879                 SetSpectatee(this, NULL);
1880                 return false;
1881         }
1882
1883         SpectateCopy(this, this.enemy);
1884
1885         return true;
1886 }
1887
1888 bool SpectateSet(entity this)
1889 {
1890         if(!IS_PLAYER(this.enemy))
1891                 return false;
1892
1893         ClientData_Touch(this.enemy);
1894
1895         msg_entity = this;
1896         WriteByte(MSG_ONE, SVC_SETVIEW);
1897         WriteEntity(MSG_ONE, this.enemy);
1898         set_movetype(this, MOVETYPE_NONE);
1899         accuracy_resend(this);
1900
1901         if(!SpectateUpdate(this))
1902                 PutObserverInServer(this);
1903
1904         return true;
1905 }
1906
1907 void SetSpectatee_status(entity this, int spectatee_num)
1908 {
1909         int oldspectatee_status = CS(this).spectatee_status;
1910         CS(this).spectatee_status = spectatee_num;
1911
1912         if (CS(this).spectatee_status != oldspectatee_status)
1913         {
1914                 if (STAT(PRESSED_KEYS, this))
1915                 {
1916                         CS(this).pressedkeys = 0;
1917                         STAT(PRESSED_KEYS, this) = 0;
1918                 }
1919                 ClientData_Touch(this);
1920                 if (g_race || g_cts) race_InitSpectator();
1921         }
1922 }
1923
1924 void SetSpectatee(entity this, entity spectatee)
1925 {
1926         if(IS_BOT_CLIENT(this))
1927                 return; // bots abuse .enemy, this code is useless to them
1928
1929         entity old_spectatee = this.enemy;
1930
1931         this.enemy = spectatee;
1932
1933         // WEAPONTODO
1934         // these are required to fix the spectator bug with arc
1935         if(old_spectatee)
1936         {
1937                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1938                 {
1939                         .entity weaponentity = weaponentities[slot];
1940                         if(old_spectatee.(weaponentity).arc_beam)
1941                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1942                 }
1943         }
1944         if(this.enemy)
1945         {
1946                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1947                 {
1948                         .entity weaponentity = weaponentities[slot];
1949                         if(this.enemy.(weaponentity).arc_beam)
1950                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1951                 }
1952         }
1953
1954         if (this.enemy)
1955                 SetSpectatee_status(this, etof(this.enemy));
1956
1957         // needed to update spectator list
1958         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1959 }
1960
1961 bool Spectate(entity this, entity pl)
1962 {
1963         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1964                 return false;
1965         pl = M_ARGV(1, entity);
1966
1967         SetSpectatee(this, pl);
1968         return SpectateSet(this);
1969 }
1970
1971 bool SpectateNext(entity this)
1972 {
1973         entity ent = find(this.enemy, classname, STR_PLAYER);
1974
1975         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1976                 ent = M_ARGV(1, entity);
1977         else if (!ent)
1978                 ent = find(ent, classname, STR_PLAYER);
1979
1980         if(ent) { SetSpectatee(this, ent); }
1981
1982         return SpectateSet(this);
1983 }
1984
1985 bool SpectatePrev(entity this)
1986 {
1987         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1988         entity ent = findchain(classname, STR_PLAYER);
1989         if (!ent) // no player
1990                 return false;
1991
1992         entity first = ent;
1993         // skip players until current spectated player
1994         if(this.enemy)
1995         while(ent && ent != this.enemy)
1996                 ent = ent.chain;
1997
1998         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1999         {
2000                 case MUT_SPECPREV_FOUND:
2001                     ent = M_ARGV(1, entity);
2002                     break;
2003                 case MUT_SPECPREV_RETURN:
2004                     return true;
2005                 case MUT_SPECPREV_CONTINUE:
2006                 default:
2007                 {
2008                         if(ent.chain)
2009                                 ent = ent.chain;
2010                         else
2011                                 ent = first;
2012                         break;
2013                 }
2014         }
2015
2016         SetSpectatee(this, ent);
2017         return SpectateSet(this);
2018 }
2019
2020 /*
2021 =============
2022 ShowRespawnCountdown()
2023
2024 Update a respawn countdown display.
2025 =============
2026 */
2027 void ShowRespawnCountdown(entity this)
2028 {
2029         float number;
2030         if(!IS_DEAD(this)) // just respawned?
2031                 return;
2032         else
2033         {
2034                 number = ceil(this.respawn_time - time);
2035                 if(number <= 0)
2036                         return;
2037                 if(number <= this.respawn_countdown)
2038                 {
2039                         this.respawn_countdown = number - 1;
2040                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2041                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2042                 }
2043         }
2044 }
2045
2046 .bool team_selected;
2047 bool ShowTeamSelection(entity this)
2048 {
2049         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2050                 return false;
2051         stuffcmd(this, "menu_showteamselect\n");
2052         return true;
2053 }
2054 void Join(entity this)
2055 {
2056         TRANSMUTE(Player, this);
2057
2058         if(!this.team_selected)
2059         if(autocvar_g_campaign || autocvar_g_balance_teams)
2060                 TeamBalance_JoinBestTeam(this);
2061
2062         if(autocvar_g_campaign)
2063                 campaign_bots_may_start = true;
2064
2065         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2066
2067         PutClientInServer(this);
2068
2069         if(IS_PLAYER(this))
2070         if(teamplay && this.team != -1)
2071         {
2072         }
2073         else
2074                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2075         this.team_selected = false;
2076 }
2077
2078 int GetPlayerLimit()
2079 {
2080         if(g_duel)
2081                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2082         int player_limit = autocvar_g_maxplayers;
2083         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2084         player_limit = M_ARGV(0, int);
2085         return player_limit;
2086 }
2087
2088 /**
2089  * Determines whether the player is allowed to join. This depends on cvar
2090  * g_maxplayers, if it isn't used this function always return true, otherwise
2091  * it checks whether the number of currently playing players exceeds g_maxplayers.
2092  * @return int number of free slots for players, 0 if none
2093  */
2094 int nJoinAllowed(entity this, entity ignore)
2095 {
2096         if(!ignore)
2097         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2098         // so report 0 free slots if restricted
2099         {
2100                 if(autocvar_g_forced_team_otherwise == "spectate")
2101                         return 0;
2102                 if(autocvar_g_forced_team_otherwise == "spectator")
2103                         return 0;
2104         }
2105
2106         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2107                 return 0; // forced spectators can never join
2108
2109         // TODO simplify this
2110         int totalClients = 0;
2111         int currentlyPlaying = 0;
2112         FOREACH_CLIENT(true, {
2113                 if(it != ignore)
2114                         ++totalClients;
2115                 if(IS_REAL_CLIENT(it))
2116                 if(IS_PLAYER(it) || it.caplayer)
2117                         ++currentlyPlaying;
2118         });
2119
2120         int player_limit = GetPlayerLimit();
2121
2122         int free_slots = 0;
2123         if (!player_limit)
2124                 free_slots = maxclients - totalClients;
2125         else if(player_limit > 0 && currentlyPlaying < player_limit)
2126                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2127
2128         static float msg_time = 0;
2129         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2130         {
2131                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2132                 msg_time = time + 0.5;
2133         }
2134
2135         return free_slots;
2136 }
2137
2138 /**
2139  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2140  * g_maxplayers_spectator_blocktime seconds
2141  */
2142 void checkSpectatorBlock(entity this)
2143 {
2144         if(IS_SPEC(this) || IS_OBSERVER(this))
2145         if(!this.caplayer)
2146         if(IS_REAL_CLIENT(this))
2147         {
2148                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2149                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2150                         dropclient(this);
2151                 }
2152         }
2153 }
2154
2155 void PrintWelcomeMessage(entity this)
2156 {
2157         if(CS(this).motd_actived_time == 0)
2158         {
2159                 if (autocvar_g_campaign) {
2160                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2161                                 CS(this).motd_actived_time = time;
2162                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2163                         }
2164                 } else {
2165                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2166                                 CS(this).motd_actived_time = time;
2167                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2168                         }
2169                 }
2170         }
2171         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2172         {
2173                 if (autocvar_g_campaign) {
2174                         if (PHYS_INPUT_BUTTON_INFO(this))
2175                                 CS(this).motd_actived_time = time;
2176                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2177                                 CS(this).motd_actived_time = 0;
2178                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2179                         }
2180                 } else {
2181                         if (PHYS_INPUT_BUTTON_INFO(this))
2182                                 CS(this).motd_actived_time = time;
2183                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2184                                 CS(this).motd_actived_time = 0;
2185                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2186                         }
2187                 }
2188         }
2189         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2190         {
2191                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2192                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2193                 else if (CS(this).motd_actived_time == -2)
2194                 {
2195                         // instantly hide MOTD
2196                         CS(this).motd_actived_time = 0;
2197                         if (autocvar_g_campaign)
2198                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2199                         else
2200                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2201                 }
2202                 else if (IS_PLAYER(this) || IS_SPEC(this))
2203                 {
2204                         // FIXME occasionally for some reason MOTD never goes away
2205                         // delay MOTD removal a little bit in the hope it fixes this bug
2206                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2207                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2208                         else //if (CS(this).motd_actived_time < -2)
2209                                 CS(this).motd_actived_time++;
2210                 }
2211         }
2212 }
2213
2214 bool joinAllowed(entity this)
2215 {
2216         if (CS(this).version_mismatch) return false;
2217         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2218         if (!nJoinAllowed(this, this)) return false;
2219         if (teamplay && lockteams) return false;
2220         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2221         if (ShowTeamSelection(this)) return false;
2222         return true;
2223 }
2224
2225 .string shootfromfixedorigin;
2226 .bool dualwielding_prev;
2227 bool PlayerThink(entity this)
2228 {
2229         if (game_stopped || intermission_running) {
2230                 this.modelflags &= ~MF_ROCKET;
2231                 if(intermission_running)
2232                         IntermissionThink(this);
2233                 return false;
2234         }
2235
2236         if (timeout_status == TIMEOUT_ACTIVE) {
2237         // don't allow the player to turn around while game is paused
2238                 // FIXME turn this into CSQC stuff
2239                 this.v_angle = this.lastV_angle;
2240                 this.angles = this.lastV_angle;
2241                 this.fixangle = true;
2242         }
2243
2244         if (frametime) player_powerups(this);
2245
2246         if (IS_DEAD(this)) {
2247                 if (this.personal && g_race_qualifying) {
2248                         if (time > this.respawn_time) {
2249                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2250                                 respawn(this);
2251                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2252                         }
2253                 } else {
2254                         if (frametime) player_anim(this);
2255
2256                         if (this.respawn_flags & RESPAWN_DENY)
2257                         {
2258                                 STAT(RESPAWN_TIME, this) = 0;
2259                                 return false;
2260                         }
2261
2262                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2263
2264                         switch(this.deadflag)
2265                         {
2266                                 case DEAD_DYING:
2267                                 {
2268                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2269                                                 this.deadflag = DEAD_RESPAWNING;
2270                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2271                                                 this.deadflag = DEAD_DEAD;
2272                                         break;
2273                                 }
2274                                 case DEAD_DEAD:
2275                                 {
2276                                         if (button_pressed)
2277                                                 this.deadflag = DEAD_RESPAWNABLE;
2278                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2279                                                 this.deadflag = DEAD_RESPAWNING;
2280                                         break;
2281                                 }
2282                                 case DEAD_RESPAWNABLE:
2283                                 {
2284                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2285                                                 this.deadflag = DEAD_RESPAWNING;
2286                                         break;
2287                                 }
2288                                 case DEAD_RESPAWNING:
2289                                 {
2290                                         if (time > this.respawn_time)
2291                                         {
2292                                                 this.respawn_time = time + 1; // only retry once a second
2293                                                 this.respawn_time_max = this.respawn_time;
2294                                                 respawn(this);
2295                                         }
2296                                         break;
2297                                 }
2298                         }
2299
2300                         ShowRespawnCountdown(this);
2301
2302                         if (this.respawn_flags & RESPAWN_SILENT)
2303                                 STAT(RESPAWN_TIME, this) = 0;
2304                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2305                         {
2306                                 if (time < this.respawn_time)
2307                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2308                                 else if (this.deadflag != DEAD_RESPAWNING)
2309                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2310                         }
2311                         else
2312                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2313                 }
2314
2315                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2316                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2317                         STAT(RESPAWN_TIME, this) *= -1;
2318
2319                 return false;
2320         }
2321
2322         FixPlayermodel(this);
2323
2324         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2325                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2326                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2327         }
2328
2329         // reset gun alignment when dual wielding status changes
2330         // to ensure guns are always aligned right and left
2331         bool dualwielding = W_DualWielding(this);
2332         if(this.dualwielding_prev != dualwielding)
2333         {
2334                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2335                 this.dualwielding_prev = dualwielding;
2336         }
2337
2338         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2339         //if(frametime)
2340         {
2341                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2342                 {
2343                         .entity weaponentity = weaponentities[slot];
2344                         if(WEP_CVAR(vortex, charge_always))
2345                                 W_Vortex_Charge(this, weaponentity, frametime);
2346                         W_WeaponFrame(this, weaponentity);
2347                 }
2348         }
2349
2350         if (frametime)
2351         {
2352                 // WEAPONTODO: Add a weapon request for this
2353                 // rot vortex charge to the charge limit
2354                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2355                 {
2356                         .entity weaponentity = weaponentities[slot];
2357                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2358                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2359                 }
2360
2361                 player_regen(this);
2362                 player_anim(this);
2363                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2364         }
2365
2366         monsters_setstatus(this);
2367
2368         return true;
2369 }
2370
2371 .bool would_spectate;
2372 void ObserverOrSpectatorThink(entity this)
2373 {
2374         bool is_spec = IS_SPEC(this);
2375         if ( CS(this).impulse )
2376         {
2377                 int r = MinigameImpulse(this, CS(this).impulse);
2378                 if (!is_spec || r)
2379                         CS(this).impulse = 0;
2380
2381                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2382                 {
2383                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2384                         CS(this).impulse = 0;
2385                         return;
2386                 }
2387         }
2388
2389         if (this.flags & FL_JUMPRELEASED) {
2390                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2391                         this.flags &= ~FL_JUMPRELEASED;
2392                         this.flags |= FL_SPAWNING;
2393                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2394                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2395                         this.flags &= ~FL_JUMPRELEASED;
2396                         if(SpectateNext(this)) {
2397                                 TRANSMUTE(Spectator, this);
2398                         } else if (is_spec) {
2399                                 TRANSMUTE(Observer, this);
2400                                 PutClientInServer(this);
2401                         }
2402                         if (is_spec)
2403                                 CS(this).impulse = 0;
2404                 } else if (is_spec) {
2405                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2406                                 this.flags &= ~FL_JUMPRELEASED;
2407                                 if(SpectatePrev(this)) {
2408                                         TRANSMUTE(Spectator, this);
2409                                 } else {
2410                                         TRANSMUTE(Observer, this);
2411                                         PutClientInServer(this);
2412                                 }
2413                                 CS(this).impulse = 0;
2414                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2415                                 this.would_spectate = false;
2416                                 this.flags &= ~FL_JUMPRELEASED;
2417                                 TRANSMUTE(Observer, this);
2418                                 PutClientInServer(this);
2419                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2420                                 PutObserverInServer(this);
2421                                 this.would_spectate = true;
2422                         }
2423                 }
2424                 else {
2425                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2426                         set_movetype(this, preferred_movetype);
2427                 }
2428         } else {
2429                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2430                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2431                         this.flags |= FL_JUMPRELEASED;
2432                         if(this.flags & FL_SPAWNING)
2433                         {
2434                                 this.flags &= ~FL_SPAWNING;
2435                                 if(joinAllowed(this))
2436                                         Join(this);
2437                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2438                                         CS(this).autojoin_checked = -1;
2439                                 return;
2440                         }
2441                 }
2442                 if(is_spec && !SpectateUpdate(this))
2443                         PutObserverInServer(this);
2444         }
2445         if (is_spec)
2446                 this.flags |= FL_CLIENT | FL_NOTARGET;
2447 }
2448
2449 void PlayerUseKey(entity this)
2450 {
2451         if (!IS_PLAYER(this))
2452                 return;
2453
2454         if(this.vehicle)
2455         {
2456                 if(!game_stopped)
2457                 {
2458                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2459                         return;
2460                 }
2461         }
2462         else if(autocvar_g_vehicles_enter)
2463         {
2464                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2465                 {
2466                         entity head, closest_target = NULL;
2467                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2468
2469                         while(head) // find the closest acceptable target to enter
2470                         {
2471                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2472                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2473                                 {
2474                                         if(closest_target)
2475                                         {
2476                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2477                                                 { closest_target = head; }
2478                                         }
2479                                         else { closest_target = head; }
2480                                 }
2481
2482                                 head = head.chain;
2483                         }
2484
2485                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2486                 }
2487         }
2488
2489         // a use key was pressed; call handlers
2490         MUTATOR_CALLHOOK(PlayerUseKey, this);
2491 }
2492
2493
2494 /*
2495 =============
2496 PlayerPreThink
2497
2498 Called every frame for each client before the physics are run
2499 =============
2500 */
2501 .float last_vehiclecheck;
2502 void PlayerPreThink (entity this)
2503 {
2504         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2505         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2506
2507         WarpZone_PlayerPhysics_FixVAngle(this);
2508
2509         if (frametime) {
2510                 // physics frames: update anticheat stuff
2511                 anticheat_prethink(this);
2512         }
2513
2514         if (blockSpectators && frametime) {
2515                 // WORKAROUND: only use dropclient in server frames (frametime set).
2516                 // Never use it in cl_movement frames (frametime zero).
2517                 checkSpectatorBlock(this);
2518         }
2519
2520         zoomstate_set = false;
2521
2522         // Check for nameless players
2523         if (this.netname == "" || this.netname != CS(this).netname_previous)
2524         {
2525                 bool assume_unchanged = (CS(this).netname_previous == "");
2526                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2527                 {
2528                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2529                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2530                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2531                         assume_unchanged = false;
2532                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2533                 }
2534                 if (isInvisibleString(this.netname))
2535                 {
2536                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2537                         sprint(this, "Warning: invisible names are not allowed.\n");
2538                         assume_unchanged = false;
2539                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2540                 }
2541                 if (!assume_unchanged && autocvar_sv_eventlog)
2542                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2543                 strcpy(CS(this).netname_previous, this.netname);
2544         }
2545
2546         // version nagging
2547         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2548         CS(this).version_nagtime = 0;
2549         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2550             // git client
2551         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2552             // git server
2553             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2554         } else {
2555             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2556             if (r < 0) { // old client
2557                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2558             } else if (r > 0) { // old server
2559                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2560             }
2561         }
2562     }
2563
2564         // GOD MODE info
2565         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2566         {
2567                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2568                 this.max_armorvalue = 0;
2569         }
2570
2571         if (frametime && IS_PLAYER(this))
2572         {
2573                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2574                 {
2575                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2576                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2577                         if (this.iceblock)
2578                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2579
2580                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2581                                 Unfreeze(this, false);
2582                 }
2583                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2584                 {
2585                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2586                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2587
2588                         if (GetResource(this, RES_HEALTH) < 1)
2589                         {
2590                                 if (this.vehicle)
2591                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2592                                 if(this.event_damage)
2593                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2594                         }
2595                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2596                                 Unfreeze(this, false);
2597                 }
2598         }
2599
2600         MUTATOR_CALLHOOK(PlayerPreThink, this);
2601
2602         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2603         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2604         {
2605                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2606                 {
2607                         if(!it.owner)
2608                         {
2609                                 if(!it.team || SAME_TEAM(this, it))
2610                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2611                                 else if(autocvar_g_vehicles_steal)
2612                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2613                         }
2614                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2615                         {
2616                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2617                         }
2618                 });
2619
2620                 this.last_vehiclecheck = time + 1;
2621         }
2622
2623         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2624         {
2625                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2626                         PlayerUseKey(this);
2627                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2628         }
2629
2630         if (IS_REAL_CLIENT(this))
2631                 PrintWelcomeMessage(this);
2632
2633         if (IS_PLAYER(this)) {
2634                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2635                         error("Client can't be spawned as player on connection!");
2636                 if(!PlayerThink(this))
2637                         return;
2638         }
2639         else if (game_stopped || intermission_running) {
2640                 if(intermission_running)
2641                         IntermissionThink(this);
2642                 return;
2643         }
2644         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2645         {
2646                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2647                 CS(this).autojoin_checked = 1;
2648                 // don't do this in ClientConnect
2649                 // many things can go wrong if a client is spawned as player on connection
2650                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2651                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2652                                 && (!teamplay || autocvar_g_balance_teams)))
2653                 {
2654                         campaign_bots_may_start = true;
2655                         if(joinAllowed(this))
2656                                 Join(this);
2657                         return;
2658                 }
2659         }
2660         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2661                 ObserverOrSpectatorThink(this);
2662         }
2663
2664         // WEAPONTODO: Add weapon request for this
2665         if (!zoomstate_set) {
2666                 bool wep_zoomed = false;
2667                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2668                 {
2669                         .entity weaponentity = weaponentities[slot];
2670                         Weapon thiswep = this.(weaponentity).m_weapon;
2671                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2672                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2673                 }
2674                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2675         }
2676
2677         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2678         {
2679                 CS(this).teamkill_soundtime = 0;
2680
2681                 entity e = CS(this).teamkill_soundsource;
2682                 entity oldpusher = e.pusher;
2683                 e.pusher = this;
2684                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2685                 e.pusher = oldpusher;
2686         }
2687
2688         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2689                 CS(this).taunt_soundtime = 0;
2690                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2691         }
2692
2693         target_voicescript_next(this);
2694
2695         // WEAPONTODO: Move into weaponsystem somehow
2696         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2697         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2698         {
2699                 .entity weaponentity = weaponentities[slot];
2700                 if(this.(weaponentity).m_weapon == WEP_Null)
2701                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2702         }
2703 }
2704
2705 void DrownPlayer(entity this)
2706 {
2707         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2708                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2709         {
2710                 STAT(AIR_FINISHED, this) = 0;
2711                 return;
2712         }
2713
2714         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2715         {
2716                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2717                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2718                 STAT(AIR_FINISHED, this) = 0;
2719         }
2720         else
2721         {
2722                 if (!STAT(AIR_FINISHED, this))
2723                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2724                 if (STAT(AIR_FINISHED, this) < time)
2725                 {       // drown!
2726                         if (this.pain_finished < time)
2727                         {
2728                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2729                                 this.pain_finished = time + 0.5;
2730                         }
2731                 }
2732         }
2733 }
2734
2735 .bool move_qcphysics;
2736
2737 void Player_Physics(entity this)
2738 {
2739         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2740
2741         if(!this.move_qcphysics)
2742                 return;
2743
2744         if(!frametime && !CS(this).pm_frametime)
2745                 return;
2746
2747         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2748
2749         CS(this).pm_frametime = 0;
2750 }
2751
2752 /*
2753 =============
2754 PlayerPostThink
2755
2756 Called every frame for each client after the physics are run
2757 =============
2758 */
2759 void PlayerPostThink (entity this)
2760 {
2761         Player_Physics(this);
2762
2763         if (sv_maxidle > 0)
2764         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2765         if (IS_REAL_CLIENT(this))
2766         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2767         {
2768                 int totalClients = 0;
2769                 if(sv_maxidle_slots > 0)
2770                 {
2771                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2772                         {
2773                                 ++totalClients;
2774                         });
2775                 }
2776
2777                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2778                 { /* do nothing */ }
2779                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2780                 {
2781                         if (CS(this).idlekick_lasttimeleft)
2782                         {
2783                                 CS(this).idlekick_lasttimeleft = 0;
2784                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2785                         }
2786                 }
2787                 else
2788                 {
2789                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2790                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2791                                 if (!CS(this).idlekick_lasttimeleft)
2792                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2793                         }
2794                         if (timeleft <= 0) {
2795                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2796                                 dropclient(this);
2797                                 return;
2798                         }
2799                         else if (timeleft <= 10) {
2800                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2801                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2802                 }
2803                                 CS(this).idlekick_lasttimeleft = timeleft;
2804                         }
2805                 }
2806         }
2807
2808         CheatFrame(this);
2809
2810         if (game_stopped)
2811         {
2812                 this.solid = SOLID_NOT;
2813                 this.takedamage = DAMAGE_NO;
2814                 set_movetype(this, MOVETYPE_NONE);
2815                 CS(this).teamkill_complain = 0;
2816                 CS(this).teamkill_soundtime = 0;
2817                 CS(this).teamkill_soundsource = NULL;
2818         }
2819
2820         if (IS_PLAYER(this)) {
2821                 if(this.death_time == time && IS_DEAD(this))
2822                 {
2823                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2824                         // once all the damage events of this frame have been processed with normal size
2825                         this.maxs.z = 5;
2826                         setsize(this, this.mins, this.maxs);
2827                 }
2828                 DrownPlayer(this);
2829                 UpdateChatBubble(this);
2830                 if (CS(this).impulse) ImpulseCommands(this);
2831                 if (game_stopped)
2832                 {
2833                         CSQCMODEL_AUTOUPDATE(this);
2834                         return;
2835                 }
2836                 GetPressedKeys(this);
2837         }
2838         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2839         {
2840                 CS(this).pressedkeys = 0;
2841                 STAT(PRESSED_KEYS, this) = 0;
2842         }
2843
2844         if (this.waypointsprite_attachedforcarrier) {
2845                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2846                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2847         }
2848
2849         CSQCMODEL_AUTOUPDATE(this);
2850 }
2851
2852 /**
2853  * message "": do not say, just test flood control
2854  * return value:
2855  *   1 = accept
2856  *   0 = reject
2857  *  -1 = fake accept
2858  */
2859 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2860 {
2861         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2862                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2863
2864         if (source)
2865                 msgin = formatmessage(source, msgin);
2866
2867         string colorstr;
2868         if (!(IS_PLAYER(source) || source.caplayer))
2869                 colorstr = "^0"; // black for spectators
2870         else if(teamplay)
2871                 colorstr = Team_ColorCode(source.team);
2872         else
2873         {
2874                 colorstr = "";
2875                 teamsay = false;
2876         }
2877
2878         if (!source) {
2879                 colorstr = "";
2880                 teamsay = false;
2881         }
2882
2883         if(msgin != "")
2884                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2885
2886         /*
2887          * using bprint solves this... me stupid
2888         // how can we prevent the message from appearing in a listen server?
2889         // for now, just give "say" back and only handle say_team
2890         if(!teamsay)
2891         {
2892                 clientcommand(source, strcat("say ", msgin));
2893                 return;
2894         }
2895         */
2896
2897         string namestr = "";
2898         if (source)
2899                 namestr = playername(source, autocvar_g_chat_teamcolors);
2900
2901         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2902
2903         string msgstr = "", cmsgstr = "";
2904         string privatemsgprefix = string_null;
2905         int privatemsgprefixlen = 0;
2906         if (msgin != "")
2907         {
2908                 bool found_me = false;
2909                 if(strstrofs(msgin, "/me", 0) >= 0)
2910                 {
2911                         string newmsgin = "";
2912                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2913                         FOREACH_WORD(msgin, true,
2914                         {
2915                                 if(strdecolorize(it) == "/me")
2916                                 {
2917                                         found_me = true;
2918                                         newmsgin = cons(newmsgin, newnamestr);
2919                                 }
2920                                 else
2921                                         newmsgin = cons(newmsgin, it);
2922                         });
2923                         msgin = newmsgin;
2924                 }
2925
2926                 if(privatesay)
2927                 {
2928                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2929                         privatemsgprefixlen = strlen(msgstr);
2930                         msgstr = strcat(msgstr, msgin);
2931                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2932                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2933                 }
2934                 else if(teamsay)
2935                 {
2936                         if(found_me)
2937                         {
2938                                 //msgin = strreplace("/me", "", msgin);
2939                                 //msgin = substring(msgin, 3, strlen(msgin));
2940                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2941                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2942                         }
2943                         else
2944                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2945                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2946                 }
2947                 else
2948                 {
2949                         if(found_me)
2950                         {
2951                                 //msgin = strreplace("/me", "", msgin);
2952                                 //msgin = substring(msgin, 3, strlen(msgin));
2953                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2954                                 msgstr = strcat("\{1}^4* ^7", msgin);
2955                         }
2956                         else {
2957                                 msgstr = "\{1}";
2958                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2959                                 msgstr = strcat(msgstr, msgin);
2960                         }
2961                         cmsgstr = "";
2962                 }
2963                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2964         }
2965
2966         string fullmsgstr = msgstr;
2967         string fullcmsgstr = cmsgstr;
2968
2969         // FLOOD CONTROL
2970         int flood = 0;
2971         var .float flood_field = floodcontrol_chat;
2972         if(floodcontrol && source)
2973         {
2974                 float flood_spl, flood_burst, flood_lmax;
2975                 if(privatesay)
2976                 {
2977                         flood_spl = autocvar_g_chat_flood_spl_tell;
2978                         flood_burst = autocvar_g_chat_flood_burst_tell;
2979                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2980                         flood_field = floodcontrol_chattell;
2981                 }
2982                 else if(teamsay)
2983                 {
2984                         flood_spl = autocvar_g_chat_flood_spl_team;
2985                         flood_burst = autocvar_g_chat_flood_burst_team;
2986                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2987                         flood_field = floodcontrol_chatteam;
2988                 }
2989                 else
2990                 {
2991                         flood_spl = autocvar_g_chat_flood_spl;
2992                         flood_burst = autocvar_g_chat_flood_burst;
2993                         flood_lmax = autocvar_g_chat_flood_lmax;
2994                         flood_field = floodcontrol_chat;
2995                 }
2996                 flood_burst = max(0, flood_burst - 1);
2997                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2998
2999                 // do flood control for the default line size
3000                 if(msgstr != "")
3001                 {
3002                         getWrappedLine_remaining = msgstr;
3003                         msgstr = "";
3004                         int lines = 0;
3005                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
3006                         {
3007                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
3008                                 ++lines;
3009                         }
3010                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
3011
3012                         if(getWrappedLine_remaining != "")
3013                         {
3014                                 msgstr = strcat(msgstr, "\n");
3015                                 flood = 2;
3016                         }
3017
3018                         if (time >= source.(flood_field))
3019                         {
3020                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
3021                         }
3022                         else
3023                         {
3024                                 flood = 1;
3025                                 msgstr = fullmsgstr;
3026                         }
3027                 }
3028                 else
3029                 {
3030                         if (time >= source.(flood_field))
3031                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
3032                         else
3033                                 flood = 1;
3034                 }
3035
3036                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
3037                         source.(flood_field) = flood = 0;
3038         }
3039
3040         string sourcemsgstr, sourcecmsgstr;
3041         if(flood == 2) // cannot happen for empty msgstr
3042         {
3043                 if(autocvar_g_chat_flood_notify_flooder)
3044                 {
3045                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
3046                         sourcecmsgstr = "";
3047                 }
3048                 else
3049                 {
3050                         sourcemsgstr = fullmsgstr;
3051                         sourcecmsgstr = fullcmsgstr;
3052                 }
3053                 cmsgstr = "";
3054         }
3055         else
3056         {
3057                 sourcemsgstr = msgstr;
3058                 sourcecmsgstr = cmsgstr;
3059         }
3060
3061         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3062         {
3063                 if (!game_stopped)
3064                 if (teamsay || CHAT_NOSPECTATORS())
3065                         teamsay = -1; // spectators
3066         }
3067
3068         if(flood)
3069                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
3070
3071         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
3072         if(privatesay)
3073                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
3074
3075         int ret;
3076         if(source && CS(source).muted)
3077         {
3078                 // always fake the message
3079                 ret = -1;
3080         }
3081         else if(flood == 1)
3082         {
3083                 if (autocvar_g_chat_flood_notify_flooder)
3084                 {
3085                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
3086                         ret = 0;
3087                 }
3088                 else
3089                         ret = -1;
3090         }
3091         else
3092         {
3093                 ret = 1;
3094         }
3095
3096         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3097         {
3098                 if (!game_stopped)
3099                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && CHAT_NOSPECTATORS())
3100                         ret = -1; // just hide the message completely
3101         }
3102
3103         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3104         ret = M_ARGV(1, int);
3105
3106         string event_log_msg = "";
3107
3108         if(sourcemsgstr != "" && ret != 0)
3109         {
3110                 if(ret < 0) // faked message, because the player is muted
3111                 {
3112                         sprint(source, sourcemsgstr);
3113                         if(sourcecmsgstr != "" && !privatesay)
3114                                 centerprint(source, sourcecmsgstr);
3115                 }
3116                 else if(privatesay) // private message, between 2 people only
3117                 {
3118                         sprint(source, sourcemsgstr);
3119                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
3120                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
3121                         {
3122                                 sprint(privatesay, msgstr);
3123                                 if(cmsgstr != "")
3124                                         centerprint(privatesay, cmsgstr);
3125                         }
3126                 }
3127                 else if ( teamsay && CS(source).active_minigame )
3128                 {
3129                         sprint(source, sourcemsgstr);
3130                         dedicated_print(msgstr); // send to server console too
3131                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3132                                 sprint(it, msgstr);
3133                         });
3134                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3135
3136                 }
3137                 else if(teamsay > 0) // team message, only sent to team mates
3138                 {
3139                         sprint(source, sourcemsgstr);
3140                         dedicated_print(msgstr); // send to server console too
3141                         if(sourcecmsgstr != "")
3142                                 centerprint(source, sourcecmsgstr);
3143                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3144                                 sprint(it, msgstr);
3145                                 if(cmsgstr != "")
3146                                         centerprint(it, cmsgstr);
3147                         });
3148                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3149                 }
3150                 else if(teamsay < 0) // spectator message, only sent to spectators
3151                 {
3152                         sprint(source, sourcemsgstr);
3153                         dedicated_print(msgstr); // send to server console too
3154                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3155                                 sprint(it, msgstr);
3156                         });
3157                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3158                 }
3159                 else
3160                 {
3161                         if (source) {
3162                                 sprint(source, sourcemsgstr);
3163                                 dedicated_print(msgstr); // send to server console too
3164                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3165                         }
3166                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3167                                 sprint(it, msgstr);
3168                         });
3169                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3170                 }
3171         }
3172
3173         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3174                 GameLogEcho(event_log_msg);
3175         }
3176
3177         return ret;
3178 }
3179
3180 // hack to copy the button fields from the client entity to the Client State
3181 void PM_UpdateButtons(entity this, entity store)
3182 {
3183         if(this.impulse)
3184                 store.impulse = this.impulse;
3185         this.impulse = 0;
3186
3187         bool typing = this.buttonchat || this.button12;
3188
3189         store.button0 = (typing) ? 0 : this.button0;
3190         //button1?!
3191         store.button2 = (typing) ? 0 : this.button2;
3192         store.button3 = (typing) ? 0 : this.button3;
3193         store.button4 = this.button4;
3194         store.button5 = (typing) ? 0 : this.button5;
3195         store.button6 = this.button6;
3196         store.button7 = this.button7;
3197         store.button8 = this.button8;
3198         store.button9 = this.button9;
3199         store.button10 = this.button10;
3200         store.button11 = this.button11;
3201         store.button12 = this.button12;
3202         store.button13 = this.button13;
3203         store.button14 = this.button14;
3204         store.button15 = this.button15;
3205         store.button16 = this.button16;
3206         store.buttonuse = this.buttonuse;
3207         store.buttonchat = this.buttonchat;
3208
3209         store.cursor_active = this.cursor_active;
3210         store.cursor_screen = this.cursor_screen;
3211         store.cursor_trace_start = this.cursor_trace_start;
3212         store.cursor_trace_endpos = this.cursor_trace_endpos;
3213         store.cursor_trace_ent = this.cursor_trace_ent;
3214
3215         store.ping = this.ping;
3216         store.ping_packetloss = this.ping_packetloss;
3217         store.ping_movementloss = this.ping_movementloss;
3218
3219         store.v_angle = this.v_angle;
3220         store.movement = this.movement;
3221 }
3222
3223 NET_HANDLE(fpsreport, bool)
3224 {
3225         int fps = ReadShort();
3226         PlayerScore_Set(sender, SP_FPS, fps);
3227         return true;
3228 }