qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "g_damage.qh"
  16 #include "g_hook.qh"
  17 #include "command/common.qh"
  18 #include "cheats.qh"
  19 #include "g_world.qh"
  20 #include "race.qh"
  21 #include "antilag.qh"
  22 #include "campaign.qh"
  23 #include "command/common.qh"
  24 #include "scores_rules.qh"
  25
  26 #include "bot/api.qh"
  27
  28 #include "../common/ent_cs.qh"
  29 #include "../common/wepent.qh"
  30 #include <common/state.qh>
  31
  32 #include <common/effects/qc/globalsound.qh>
  33
  34 #include "../common/triggers/func/conveyor.qh"
  35 #include "../common/triggers/teleporters.qh"
  36
  37 #include "../common/vehicles/all.qh"
  38
  39 #include "weapons/hitplot.qh"
  40 #include "weapons/weaponsystem.qh"
  41
  42 #include "../common/net_notice.qh"
  43 #include "../common/net_linked.qh"
  44 #include "../common/physics/player.qh"
  45
  46 #include "../common/items/_mod.qh"
  47
  48 #include "../common/mutators/mutator/waypoints/all.qh"
  49
  50 #include "../common/triggers/subs.qh"
  51 #include "../common/triggers/triggers.qh"
  52 #include "../common/triggers/trigger/secret.qh"
  53
  54 #include "../common/minigames/sv_minigames.qh"
  55
  56 #include "../common/items/inventory.qh"
  57
  58 #include "../common/monsters/sv_monsters.qh"
  59
  60 #include "../lib/warpzone/server.qh"
  61
  62 STATIC_METHOD(Client, Add, void(Client this, int _team))
  63 {
  64     ClientConnect(this);
  65     TRANSMUTE(Player, this);
  66     this.frame = 12; // 7
  67     this.team = _team;
  68     PutClientInServer(this);
  69 }
  70
  71 void PutObserverInServer(entity this);
  72
  73 STATIC_METHOD(Client, Remove, void(Client this))
  74 {
  75     TRANSMUTE(Observer, this);
  76     PutClientInServer(this);
  77     ClientDisconnect(this);
  78 }
  79
  80 void send_CSQC_teamnagger() {
  81         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  82 }
  83
  84 int CountSpectators(entity player, entity to)
  85 {
  86         if(!player) { return 0; } // not sure how, but best to be safe
  87
  88         int spec_count = 0;
  89
  90         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  91         {
  92                 spec_count++;
  93         });
  94
  95         return spec_count;
  96 }
  97
  98 void WriteSpectators(entity player, entity to)
  99 {
 100         if(!player) { return; } // not sure how, but best to be safe
 101
 102         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 103         {
 104                 WriteByte(MSG_ENTITY, num_for_edict(it));
 105         });
 106 }
 107
 108 bool ClientData_Send(entity this, entity to, int sf)
 109 {
 110         assert(to == this.owner, return false);
 111
 112         entity e = to;
 113         if (IS_SPEC(e)) e = e.enemy;
 114
 115         sf = 0;
 116         if (CS(e).race_completed)       sf |= 1; // forced scoreboard
 117         if (CS(to).spectatee_status)    sf |= 2; // spectator ent number follows
 118         if (CS(e).zoomstate)            sf |= 4; // zoomed
 119         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 120
 121         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 122         WriteByte(MSG_ENTITY, sf);
 123
 124         if (sf & 2)
 125         {
 126                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 127         }
 128
 129         if(sf & 16)
 130         {
 131                 float specs = CountSpectators(e, to);
 132                 WriteByte(MSG_ENTITY, specs);
 133                 WriteSpectators(e, to);
 134         }
 135
 136         return true;
 137 }
 138
 139 void ClientData_Attach(entity this)
 140 {
 141         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 142         CS(this).clientdata.drawonlytoclient = this;
 143         CS(this).clientdata.owner = this;
 144 }
 145
 146 void ClientData_Detach(entity this)
 147 {
 148         delete(CS(this).clientdata);
 149         CS(this).clientdata = NULL;
 150 }
 151
 152 void ClientData_Touch(entity e)
 153 {
 154         CS(e).clientdata.SendFlags = 1;
 155
 156         // make it spectatable
 157         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 158 }
 159
 160 void SetSpectatee(entity this, entity spectatee);
 161 void SetSpectatee_status(entity this, int spectatee_num);
 162
 163
 164 /*
 165 =============
 166 CheckPlayerModel
 167
 168 Checks if the argument string can be a valid playermodel.
 169 Returns a valid one in doubt.
 170 =============
 171 */
 172 string FallbackPlayerModel;
 173 string CheckPlayerModel(string plyermodel) {
 174         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 175         {
 176                 // note: we cannot summon Don Strunzone here, some player may
 177                 // still have the model string set. In case anyone manages how
 178                 // to change a cvar default, we'll have a small leak here.
 179                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 180         }
 181         // only in right path
 182         if( substring(plyermodel,0,14) != "models/player/")
 183                 return FallbackPlayerModel;
 184         // only good file extensions
 185         if(substring(plyermodel,-4,4) != ".zym")
 186         if(substring(plyermodel,-4,4) != ".dpm")
 187         if(substring(plyermodel,-4,4) != ".iqm")
 188         if(substring(plyermodel,-4,4) != ".md3")
 189         if(substring(plyermodel,-4,4) != ".psk")
 190                 return FallbackPlayerModel;
 191         // forbid the LOD models
 192         if(substring(plyermodel, -9,5) == "_lod1")
 193                 return FallbackPlayerModel;
 194         if(substring(plyermodel, -9,5) == "_lod2")
 195                 return FallbackPlayerModel;
 196         if(plyermodel != strtolower(plyermodel))
 197                 return FallbackPlayerModel;
 198         // also, restrict to server models
 199         if(autocvar_sv_servermodelsonly)
 200         {
 201                 if(!fexists(plyermodel))
 202                         return FallbackPlayerModel;
 203         }
 204         return plyermodel;
 205 }
 206
 207 void setplayermodel(entity e, string modelname)
 208 {
 209         precache_model(modelname);
 210         _setmodel(e, modelname);
 211         player_setupanimsformodel(e);
 212         if(!autocvar_g_debug_globalsounds)
 213                 UpdatePlayerSounds(e);
 214 }
 215
 216 void FixPlayermodel(entity player);
 217 /** putting a client as observer in the server */
 218 void PutObserverInServer(entity this)
 219 {
 220     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 221         PlayerState_detach(this);
 222
 223         if (IS_PLAYER(this) && this.health >= 1) {
 224         // despawn effect
 225                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 226     }
 227
 228     {
 229         entity spot = SelectSpawnPoint(this, true);
 230         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 231         this.angles = vec2(spot.angles);
 232         this.fixangle = true;
 233         // offset it so that the spectator spawns higher off the ground, looks better this way
 234         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 235         if (IS_REAL_CLIENT(this))
 236         {
 237             msg_entity = this;
 238             WriteByte(MSG_ONE, SVC_SETVIEW);
 239             WriteEntity(MSG_ONE, this);
 240         }
 241         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 242         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 243         if(!autocvar_g_debug_globalsounds)
 244         {
 245                 // needed for player sounds
 246                 this.model = "";
 247                 FixPlayermodel(this);
 248         }
 249         setmodel(this, MDL_Null);
 250         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 251         this.view_ofs = '0 0 0';
 252     }
 253
 254     RemoveGrapplingHooks(this);
 255         Portal_ClearAll(this);
 256         Unfreeze(this);
 257         SetSpectatee(this, NULL);
 258
 259         if (this.alivetime)
 260         {
 261                 if (!warmup_stage)
 262                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 263                 this.alivetime = 0;
 264         }
 265
 266         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 267
 268         WaypointSprite_PlayerDead(this);
 269
 270         if (mutator_returnvalue) {
 271             // mutator prevents resetting teams+score
 272         } else {
 273                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 274         this.frags = FRAGS_SPECTATOR;
 275         PlayerScore_Clear(this);  // clear scores when needed
 276     }
 277
 278         if (CS(this).killcount != FRAGS_SPECTATOR)
 279         {
 280                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 281                 if(!game_stopped)
 282                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 283                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 284
 285                 if(!CS(this).just_joined)
 286                         LogTeamchange(this.playerid, -1, 4);
 287                 else
 288                         CS(this).just_joined = false;
 289         }
 290
 291         accuracy_resend(this);
 292
 293         CS(this).spectatortime = time;
 294         if(this.bot_attack)
 295                 IL_REMOVE(g_bot_targets, this);
 296         this.bot_attack = false;
 297     this.hud = HUD_NORMAL;
 298         TRANSMUTE(Observer, this);
 299         this.iscreature = false;
 300         this.teleportable = TELEPORT_SIMPLE;
 301         if(this.damagedbycontents)
 302                 IL_REMOVE(g_damagedbycontents, this);
 303         this.damagedbycontents = false;
 304         this.health = FRAGS_SPECTATOR;
 305         SetSpectatee_status(this, etof(this));
 306         this.takedamage = DAMAGE_NO;
 307         this.solid = SOLID_NOT;
 308         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 309         this.flags = FL_CLIENT | FL_NOTARGET;
 310         this.armorvalue = 666;
 311         this.effects = 0;
 312         this.armorvalue = autocvar_g_balance_armor_start;
 313         this.pauserotarmor_finished = 0;
 314         this.pauserothealth_finished = 0;
 315         this.pauseregen_finished = 0;
 316         this.damageforcescale = 0;
 317         this.death_time = 0;
 318         this.respawn_flags = 0;
 319         this.respawn_time = 0;
 320         this.stat_respawn_time = 0;
 321         this.alpha = 0;
 322         this.scale = 0;
 323         this.fade_time = 0;
 324         this.pain_frame = 0;
 325         this.pain_finished = 0;
 326         this.strength_finished = 0;
 327         this.invincible_finished = 0;
 328         this.superweapons_finished = 0;
 329         this.pushltime = 0;
 330         this.istypefrag = 0;
 331         setthink(this, func_null);
 332         this.nextthink = 0;
 333         this.deadflag = DEAD_NO;
 334         this.crouch = false;
 335         this.revive_progress = 0;
 336         this.revival_time = 0;
 337
 338         this.items = 0;
 339         this.weapons = '0 0 0';
 340         this.drawonlytoclient = this;
 341
 342         this.weaponmodel = "";
 343         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 344         {
 345                 this.weaponentities[slot] = NULL;
 346         }
 347         this.exteriorweaponentity = NULL;
 348         CS(this).killcount = FRAGS_SPECTATOR;
 349         this.velocity = '0 0 0';
 350         this.avelocity = '0 0 0';
 351         this.punchangle = '0 0 0';
 352         this.punchvector = '0 0 0';
 353         this.oldvelocity = this.velocity;
 354         this.fire_endtime = -1;
 355         this.event_damage = func_null;
 356
 357         for(int slot = 0; slot < MAX_AXH; ++slot)
 358         {
 359                 entity axh = this.(AuxiliaryXhair[slot]);
 360                 this.(AuxiliaryXhair[slot]) = NULL;
 361
 362                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 363                         delete(axh);
 364         }
 365 }
 366
 367 int player_getspecies(entity this)
 368 {
 369         get_model_parameters(this.model, this.skin);
 370         int s = get_model_parameters_species;
 371         get_model_parameters(string_null, 0);
 372         if (s < 0) return SPECIES_HUMAN;
 373         return s;
 374 }
 375
 376 .float model_randomizer;
 377 void FixPlayermodel(entity player)
 378 {
 379         string defaultmodel = "";
 380         int defaultskin = 0;
 381         if(autocvar_sv_defaultcharacter)
 382         {
 383                 if(teamplay)
 384                 {
 385                         switch(player.team)
 386                         {
 387                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 388                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 389                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 390                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 391                         }
 392                 }
 393
 394                 if(defaultmodel == "")
 395                 {
 396                         defaultmodel = autocvar_sv_defaultplayermodel;
 397                         defaultskin = autocvar_sv_defaultplayerskin;
 398                 }
 399
 400                 int n = tokenize_console(defaultmodel);
 401                 if(n > 0)
 402                 {
 403                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 404                         // However, do NOT randomize if the player-selected model is in the list.
 405                         for (int i = 0; i < n; ++i)
 406                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 407                                         defaultmodel = argv(i);
 408                 }
 409
 410                 int i = strstrofs(defaultmodel, ":", 0);
 411                 if(i >= 0)
 412                 {
 413                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 414                         defaultmodel = substring(defaultmodel, 0, i);
 415                 }
 416         }
 417         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 418         {
 419                 if(teamplay)
 420                 {
 421                         switch(player.team)
 422                         {
 423                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 424                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 425                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 426                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 427                         }
 428                 }
 429
 430                 if(!defaultskin)
 431                         defaultskin = autocvar_sv_defaultplayerskin;
 432         }
 433
 434         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 435         defaultmodel = M_ARGV(0, string);
 436         defaultskin = M_ARGV(1, int);
 437
 438         bool chmdl = false;
 439         int oldskin;
 440         if(defaultmodel != "")
 441         {
 442                 if (defaultmodel != player.model)
 443                 {
 444                         vector m1 = player.mins;
 445                         vector m2 = player.maxs;
 446                         setplayermodel (player, defaultmodel);
 447                         setsize (player, m1, m2);
 448                         chmdl = true;
 449                 }
 450
 451                 oldskin = player.skin;
 452                 player.skin = defaultskin;
 453         } else {
 454                 if (player.playermodel != player.model || player.playermodel == "")
 455                 {
 456                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 457                         vector m1 = player.mins;
 458                         vector m2 = player.maxs;
 459                         setplayermodel (player, player.playermodel);
 460                         setsize (player, m1, m2);
 461                         chmdl = true;
 462                 }
 463
 464                 if(!autocvar_sv_defaultcharacterskin)
 465                 {
 466                         oldskin = player.skin;
 467                         player.skin = stof(player.playerskin);
 468                 }
 469                 else
 470                 {
 471                         oldskin = player.skin;
 472                         player.skin = defaultskin;
 473                 }
 474         }
 475
 476         if(chmdl || oldskin != player.skin) // model or skin has changed
 477         {
 478                 player.species = player_getspecies(player); // update species
 479                 if(!autocvar_g_debug_globalsounds)
 480                         UpdatePlayerSounds(player); // update skin sounds
 481         }
 482
 483         if(!teamplay)
 484                 if(strlen(autocvar_sv_defaultplayercolors))
 485                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 486                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 487 }
 488
 489 void PutPlayerInServer(entity this)
 490 {
 491         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 492
 493         PlayerState_attach(this);
 494         accuracy_resend(this);
 495
 496         if (this.team < 0)
 497                 JoinBestTeam(this, false, true);
 498
 499         entity spot = SelectSpawnPoint(this, false);
 500         if (!spot) {
 501                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 502                 return; // spawn failed
 503         }
 504
 505         TRANSMUTE(Player, this);
 506
 507         CS(this).wasplayer = true;
 508         this.iscreature = true;
 509         this.teleportable = TELEPORT_NORMAL;
 510         if(!this.damagedbycontents)
 511                 IL_PUSH(g_damagedbycontents, this);
 512         this.damagedbycontents = true;
 513         set_movetype(this, MOVETYPE_WALK);
 514         this.solid = SOLID_SLIDEBOX;
 515         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 516         if (autocvar_g_playerclip_collisions)
 517                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 518         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 519                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 520         this.frags = FRAGS_PLAYER;
 521         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 522         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 523         if (autocvar__notarget)
 524                 this.flags |= FL_NOTARGET;
 525         this.takedamage = DAMAGE_AIM;
 526         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 527         this.dmg = 2; // WTF
 528
 529         if (warmup_stage) {
 530                 this.ammo_shells = warmup_start_ammo_shells;
 531                 this.ammo_nails = warmup_start_ammo_nails;
 532                 this.ammo_rockets = warmup_start_ammo_rockets;
 533                 this.ammo_cells = warmup_start_ammo_cells;
 534                 this.ammo_plasma = warmup_start_ammo_plasma;
 535                 this.ammo_fuel = warmup_start_ammo_fuel;
 536                 this.health = warmup_start_health;
 537                 this.armorvalue = warmup_start_armorvalue;
 538                 this.weapons = WARMUP_START_WEAPONS;
 539         } else {
 540                 this.ammo_shells = start_ammo_shells;
 541                 this.ammo_nails = start_ammo_nails;
 542                 this.ammo_rockets = start_ammo_rockets;
 543                 this.ammo_cells = start_ammo_cells;
 544                 this.ammo_plasma = start_ammo_plasma;
 545                 this.ammo_fuel = start_ammo_fuel;
 546                 this.health = start_health;
 547                 this.armorvalue = start_armorvalue;
 548                 this.weapons = start_weapons;
 549         }
 550         SetSpectatee_status(this, 0);
 551
 552         PS(this).dual_weapons = '0 0 0';
 553
 554         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 555
 556         this.items = start_items;
 557
 558         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 559         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 560         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 561         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 562         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 563         // extend the pause of rotting if client was reset at the beginning of the countdown
 564         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 565                 float f = game_starttime - time;
 566                 this.spawnshieldtime += f;
 567                 this.pauserotarmor_finished += f;
 568                 this.pauserothealth_finished += f;
 569                 this.pauseregen_finished += f;
 570         }
 571         this.damageforcescale = 2;
 572         this.death_time = 0;
 573         this.respawn_flags = 0;
 574         this.respawn_time = 0;
 575         this.stat_respawn_time = 0;
 576         this.scale = autocvar_sv_player_scale;
 577         this.fade_time = 0;
 578         this.pain_frame = 0;
 579         this.pain_finished = 0;
 580         this.pushltime = 0;
 581         setthink(this, func_null); // players have no think function
 582         this.nextthink = 0;
 583         this.dmg_team = 0;
 584         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 585
 586         this.deadflag = DEAD_NO;
 587
 588         this.angles = spot.angles;
 589         this.angles_z = 0; // never spawn tilted even if the spot says to
 590         if (IS_BOT_CLIENT(this))
 591                 this.v_angle = this.angles;
 592         this.fixangle = true; // turn this way immediately
 593         this.oldvelocity = this.velocity = '0 0 0';
 594         this.avelocity = '0 0 0';
 595         this.punchangle = '0 0 0';
 596         this.punchvector = '0 0 0';
 597
 598         this.strength_finished = 0;
 599         this.invincible_finished = 0;
 600         this.fire_endtime = -1;
 601         this.revive_progress = 0;
 602         this.revival_time = 0;
 603         this.air_finished = time + 12;
 604
 605         entity spawnevent = new_pure(spawnevent);
 606         spawnevent.owner = this;
 607         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 608
 609         // Cut off any still running player sounds.
 610         stopsound(this, CH_PLAYER_SINGLE);
 611
 612         this.model = "";
 613         FixPlayermodel(this);
 614         this.drawonlytoclient = NULL;
 615
 616         this.viewloc = NULL;
 617
 618         this.crouch = false;
 619         this.view_ofs = STAT(PL_VIEW_OFS, this);
 620         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 621         this.spawnorigin = spot.origin;
 622         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 623         // don't reset back to last position, even if new position is stuck in solid
 624         this.oldorigin = this.origin;
 625         this.lastteleporttime = time; // prevent insane speeds due to changing origin
 626         if(this.conveyor)
 627                 IL_REMOVE(g_conveyed, this);
 628         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 629         this.hud = HUD_NORMAL;
 630
 631         this.event_damage = PlayerDamage;
 632
 633         if(!this.bot_attack)
 634                 IL_PUSH(g_bot_targets, this);
 635         this.bot_attack = true;
 636         if(!this.monster_attack)
 637                 IL_PUSH(g_monster_targets, this);
 638         this.monster_attack = true;
 639         navigation_dynamicgoal_init(this, false);
 640
 641         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 642
 643         if (CS(this).killcount == FRAGS_SPECTATOR) {
 644                 PlayerScore_Clear(this);
 645                 CS(this).killcount = 0;
 646         }
 647
 648         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 649         {
 650                 .entity weaponentity = weaponentities[slot];
 651                 entity oldwep = this.(weaponentity);
 652                 CL_SpawnWeaponentity(this, weaponentity);
 653                 if(oldwep && oldwep.owner == this)
 654                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 655         }
 656         this.alpha = default_player_alpha;
 657         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 658         this.exteriorweaponentity.alpha = default_weapon_alpha;
 659
 660         this.speedrunning = false;
 661
 662         target_voicescript_clear(this);
 663
 664         // reset fields the weapons may use
 665         FOREACH(Weapons, true, {
 666                 it.wr_resetplayer(it, this);
 667                         // reload all reloadable weapons
 668                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 669                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 670                         {
 671                                 .entity weaponentity = weaponentities[slot];
 672                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 673                         }
 674                 }
 675         });
 676
 677         {
 678                 string s = spot.target;
 679                 spot.target = string_null;
 680                 SUB_UseTargets(spot, this, NULL);
 681                 spot.target = s;
 682         }
 683
 684         Unfreeze(this);
 685
 686         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 687
 688         if (autocvar_spawn_debug)
 689         {
 690                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 691                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 692         }
 693
 694         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 695         {
 696                 .entity weaponentity = weaponentities[slot];
 697                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 698                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 699                 else
 700                         this.(weaponentity).m_switchweapon = WEP_Null;
 701                 this.(weaponentity).m_weapon = WEP_Null;
 702                 this.(weaponentity).weaponname = "";
 703                 this.(weaponentity).m_switchingweapon = WEP_Null;
 704                 this.(weaponentity).cnt = -1;
 705         }
 706
 707         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 708
 709         if (!warmup_stage && !this.alivetime)
 710                 this.alivetime = time;
 711
 712         antilag_clear(this, CS(this));
 713 }
 714
 715 /** Called when a client spawns in the server */
 716 void PutClientInServer(entity this)
 717 {
 718         if (IS_BOT_CLIENT(this)) {
 719                 TRANSMUTE(Player, this);
 720         } else if (IS_REAL_CLIENT(this)) {
 721                 msg_entity = this;
 722                 WriteByte(MSG_ONE, SVC_SETVIEW);
 723                 WriteEntity(MSG_ONE, this);
 724         }
 725         if (game_stopped)
 726                 TRANSMUTE(Observer, this);
 727
 728         SetSpectatee(this, NULL);
 729
 730         // reset player keys
 731         if(PS(this))
 732                 PS(this).itemkeys = 0;
 733
 734         MUTATOR_CALLHOOK(PutClientInServer, this);
 735
 736         if (IS_OBSERVER(this)) {
 737                 PutObserverInServer(this);
 738         } else if (IS_PLAYER(this)) {
 739                 PutPlayerInServer(this);
 740         }
 741 }
 742
 743 void ClientInit_misc(entity this);
 744
 745 // TODO do we need all these fields, or should we stop autodetecting runtime
 746 // changes and just have a console command to update this?
 747 bool ClientInit_SendEntity(entity this, entity to, int sf)
 748 {
 749         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 750         return = true;
 751         msg_entity = to;
 752         // MSG_INIT replacement
 753         // TODO: make easier to use
 754         Registry_send_all();
 755         W_PROP_reload(MSG_ONE, to);
 756         ClientInit_misc(this);
 757         MUTATOR_CALLHOOK(Ent_Init);
 758 }
 759 void ClientInit_misc(entity this)
 760 {
 761         int channel = MSG_ONE;
 762         WriteHeader(channel, ENT_CLIENT_INIT);
 763         WriteByte(channel, g_nexball_meter_period * 32);
 764         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 765         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 766         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 767         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 768         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 769         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 770         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 771         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 772
 773         if(sv_foginterval && world.fog != "")
 774                 WriteString(channel, world.fog);
 775         else
 776                 WriteString(channel, "");
 777         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 778         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 779         WriteByte(channel, serverflags);
 780         WriteCoord(channel, autocvar_g_trueaim_minrange);
 781 }
 782
 783 void ClientInit_CheckUpdate(entity this)
 784 {
 785         this.nextthink = time;
 786         if(this.count != autocvar_g_balance_armor_blockpercent)
 787         {
 788                 this.count = autocvar_g_balance_armor_blockpercent;
 789                 this.SendFlags |= 1;
 790         }
 791         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 792         {
 793                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 794                 this.SendFlags |= 1;
 795         }
 796 }
 797
 798 void ClientInit_Spawn()
 799 {
 800         entity e = new_pure(clientinit);
 801         setthink(e, ClientInit_CheckUpdate);
 802         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 803
 804         ClientInit_CheckUpdate(e);
 805 }
 806
 807 /*
 808 =============
 809 SetNewParms
 810 =============
 811 */
 812 void SetNewParms ()
 813 {
 814         // initialize parms for a new player
 815         parm1 = -(86400 * 366);
 816
 817         MUTATOR_CALLHOOK(SetNewParms);
 818 }
 819
 820 /*
 821 =============
 822 SetChangeParms
 823 =============
 824 */
 825 void SetChangeParms (entity this)
 826 {
 827         // save parms for level change
 828         parm1 = CS(this).parm_idlesince - time;
 829
 830         MUTATOR_CALLHOOK(SetChangeParms);
 831 }
 832
 833 /*
 834 =============
 835 DecodeLevelParms
 836 =============
 837 */
 838 void DecodeLevelParms(entity this)
 839 {
 840         // load parms
 841         CS(this).parm_idlesince = parm1;
 842         if (CS(this).parm_idlesince == -(86400 * 366))
 843                 CS(this).parm_idlesince = time;
 844
 845         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 846         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 847
 848         MUTATOR_CALLHOOK(DecodeLevelParms);
 849 }
 850
 851 /*
 852 =============
 853 ClientKill
 854
 855 Called when a client types 'kill' in the console
 856 =============
 857 */
 858
 859 .float clientkill_nexttime;
 860 void ClientKill_Now_TeamChange(entity this)
 861 {
 862         if(CS(this).killindicator_teamchange == -1)
 863         {
 864                 JoinBestTeam( this, false, true );
 865         }
 866         else if(CS(this).killindicator_teamchange == -2)
 867         {
 868                 if(blockSpectators)
 869                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 870                 PutObserverInServer(this);
 871         }
 872         else
 873                 SV_ChangeTeam(this, CS(this).killindicator_teamchange - 1);
 874         CS(this).killindicator_teamchange = 0;
 875 }
 876
 877 void ClientKill_Now(entity this)
 878 {
 879         if(this.vehicle)
 880         {
 881             vehicles_exit(this.vehicle, VHEF_RELEASE);
 882             if(!CS(this).killindicator_teamchange)
 883             {
 884             this.vehicle_health = -1;
 885             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 886             }
 887         }
 888
 889         if(this.killindicator && !wasfreed(this.killindicator))
 890                 delete(this.killindicator);
 891
 892         this.killindicator = NULL;
 893
 894         if(CS(this).killindicator_teamchange)
 895                 ClientKill_Now_TeamChange(this);
 896
 897         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 898                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 899
 900         // now I am sure the player IS dead
 901 }
 902 void KillIndicator_Think(entity this)
 903 {
 904         if (game_stopped)
 905         {
 906                 this.owner.killindicator = NULL;
 907                 delete(this);
 908                 return;
 909         }
 910
 911         if (this.owner.alpha < 0 && !this.owner.vehicle)
 912         {
 913                 this.owner.killindicator = NULL;
 914                 delete(this);
 915                 return;
 916         }
 917
 918         if(this.cnt <= 0)
 919         {
 920                 ClientKill_Now(this.owner);
 921                 return;
 922         }
 923     else if(this.health == 1) // health == 1 means that it's silent
 924     {
 925         this.nextthink = time + 1;
 926         this.cnt -= 1;
 927     }
 928         else
 929         {
 930                 if(this.cnt <= 10)
 931                         setmodel(this, MDL_NUM(this.cnt));
 932                 if(IS_REAL_CLIENT(this.owner))
 933                 {
 934                         if(this.cnt <= 10)
 935                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 936                 }
 937                 this.nextthink = time + 1;
 938                 this.cnt -= 1;
 939         }
 940 }
 941
 942 float clientkilltime;
 943 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 944 {
 945         float killtime;
 946         float starttime;
 947
 948         if (game_stopped)
 949                 return;
 950
 951         killtime = autocvar_g_balance_kill_delay;
 952
 953     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 954         return;
 955     killtime = M_ARGV(1, float);
 956
 957         CS(this).killindicator_teamchange = targetteam;
 958
 959     if(!this.killindicator)
 960         {
 961                 if(!IS_DEAD(this))
 962                 {
 963                         killtime = max(killtime, this.clientkill_nexttime - time);
 964                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 965                 }
 966
 967                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 968                 {
 969                         ClientKill_Now(this);
 970                 }
 971                 else
 972                 {
 973                         starttime = max(time, clientkilltime);
 974
 975                         this.killindicator = spawn();
 976                         this.killindicator.owner = this;
 977                         this.killindicator.scale = 0.5;
 978                         setattachment(this.killindicator, this, "");
 979                         setorigin(this.killindicator, '0 0 52');
 980                         setthink(this.killindicator, KillIndicator_Think);
 981                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 982                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 983                         this.killindicator.cnt = ceil(killtime);
 984                         this.killindicator.count = bound(0, ceil(killtime), 10);
 985                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 986
 987                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 988                         {
 989                                 it.killindicator = spawn();
 990                                 it.killindicator.owner = it;
 991                                 it.killindicator.scale = 0.5;
 992                                 setattachment(it.killindicator, it, "");
 993                                 setorigin(it.killindicator, '0 0 52');
 994                                 setthink(it.killindicator, KillIndicator_Think);
 995                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 996                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 997                                 it.killindicator.cnt = ceil(killtime);
 998                         });
 999                         this.lip = 0;
1000                 }
1001         }
1002         if(this.killindicator)
1003         {
1004                 if(targetteam == 0) // just die
1005                 {
1006                         this.killindicator.colormod = '0 0 0';
1007                         if(IS_REAL_CLIENT(this))
1008                         if(this.killindicator.cnt > 0)
1009                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1010                 }
1011                 else if(targetteam == -1) // auto
1012                 {
1013                         this.killindicator.colormod = '0 1 0';
1014                         if(IS_REAL_CLIENT(this))
1015                         if(this.killindicator.cnt > 0)
1016                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1017                 }
1018                 else if(targetteam == -2) // spectate
1019                 {
1020                         this.killindicator.colormod = '0.5 0.5 0.5';
1021                         if(IS_REAL_CLIENT(this))
1022                         if(this.killindicator.cnt > 0)
1023                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1024                 }
1025                 else
1026                 {
1027                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1028                         if(IS_REAL_CLIENT(this))
1029                         if(this.killindicator.cnt > 0)
1030                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1031                 }
1032         }
1033
1034 }
1035
1036 void ClientKill (entity this)
1037 {
1038         if(game_stopped) return;
1039         if(this.player_blocked) return;
1040         if(STAT(FROZEN, this)) return;
1041
1042         ClientKill_TeamChange(this, 0);
1043 }
1044
1045 void FixClientCvars(entity e)
1046 {
1047         // send prediction settings to the client
1048         stuffcmd(e, "\nin_bindmap 0 0\n");
1049         if(autocvar_g_antilag == 3) // client side hitscan
1050                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1051         if(autocvar_sv_gentle)
1052                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1053
1054         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1055         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1056
1057         MUTATOR_CALLHOOK(FixClientCvars, e);
1058 }
1059
1060 bool findinlist_abbrev(string tofind, string list)
1061 {
1062         if(list == "" || tofind == "")
1063                 return false; // empty list or search, just return
1064
1065         // this function allows abbreviated strings!
1066         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1067         {
1068                 return true;
1069         });
1070
1071         return false;
1072 }
1073
1074 bool PlayerInIPList(entity p, string iplist)
1075 {
1076         // some safety checks (never allow local?)
1077         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1078                 return false;
1079
1080         return findinlist_abbrev(p.netaddress, iplist);
1081 }
1082
1083 bool PlayerInIDList(entity p, string idlist)
1084 {
1085         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1086         if(!p.crypto_idfp)
1087                 return false;
1088
1089         return findinlist_abbrev(p.crypto_idfp, idlist);
1090 }
1091
1092 bool PlayerInList(entity player, string list)
1093 {
1094         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1095 }
1096
1097 #ifdef DP_EXT_PRECONNECT
1098 /*
1099 =============
1100 ClientPreConnect
1101
1102 Called once (not at each match start) when a client begins a connection to the server
1103 =============
1104 */
1105 void ClientPreConnect(entity this)
1106 {
1107         if(autocvar_sv_eventlog)
1108         {
1109                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1110                         this.playerid,
1111                         etof(this),
1112                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1113                 ));
1114         }
1115 }
1116 #endif
1117
1118 /**
1119 =============
1120 ClientConnect
1121
1122 Called when a client connects to the server
1123 =============
1124 */
1125 void ClientConnect(entity this)
1126 {
1127         if (Ban_MaybeEnforceBanOnce(this)) return;
1128         assert(!IS_CLIENT(this), return);
1129         this.flags |= FL_CLIENT;
1130         assert(player_count >= 0, player_count = 0);
1131
1132 #ifdef WATERMARK
1133         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1134 #endif
1135         TRANSMUTE(Client, this);
1136         CS(this).version_nagtime = time + 10 + random() * 10;
1137
1138         // identify the right forced team
1139         if (autocvar_g_campaign)
1140         {
1141                 if (IS_REAL_CLIENT(this)) // only players, not bots
1142                 {
1143                         switch (autocvar_g_campaign_forceteam)
1144                         {
1145                                 case 1: this.team_forced = NUM_TEAM_1; break;
1146                                 case 2: this.team_forced = NUM_TEAM_2; break;
1147                                 case 3: this.team_forced = NUM_TEAM_3; break;
1148                                 case 4: this.team_forced = NUM_TEAM_4; break;
1149                                 default: this.team_forced = 0;
1150                         }
1151                 }
1152         }
1153         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1154         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1155         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1156         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1157         else switch (autocvar_g_forced_team_otherwise)
1158         {
1159                 default: this.team_forced = 0; break;
1160                 case "red": this.team_forced = NUM_TEAM_1; break;
1161                 case "blue": this.team_forced = NUM_TEAM_2; break;
1162                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1163                 case "pink": this.team_forced = NUM_TEAM_4; break;
1164                 case "spectate":
1165                 case "spectator":
1166                         this.team_forced = -1;
1167                         break;
1168         }
1169         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1170
1171     {
1172         int id = this.playerid;
1173         this.playerid = 0; // silent
1174             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1175             this.playerid = id;
1176     }
1177
1178         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1179                 TRANSMUTE(Observer, this);
1180         } else {
1181                 if (!teamplay || autocvar_g_balance_teams) {
1182                         TRANSMUTE(Player, this);
1183                         campaign_bots_may_start = true;
1184                 } else {
1185                         TRANSMUTE(Observer, this); // do it anyway
1186                 }
1187         }
1188
1189         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1190
1191         // always track bots, don't ask for cl_allow_uidtracking
1192     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1193
1194         if (autocvar_sv_eventlog)
1195                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1196
1197         LogTeamchange(this.playerid, this.team, 1);
1198
1199         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1200
1201         CS(this).netname_previous = strzone(this.netname);
1202
1203         if(teamplay && IS_PLAYER(this))
1204                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1205         else
1206                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1207
1208         stuffcmd(this, clientstuff, "\n");
1209         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1210
1211         FixClientCvars(this);
1212
1213         // get version info from player
1214         stuffcmd(this, "cmd clientversion $gameversion\n");
1215
1216         // notify about available teams
1217         if (teamplay)
1218         {
1219                 CheckAllowedTeams(this);
1220                 int t = 0;
1221                 if (c1 >= 0) t |= BIT(0);
1222                 if (c2 >= 0) t |= BIT(1);
1223                 if (c3 >= 0) t |= BIT(2);
1224                 if (c4 >= 0) t |= BIT(3);
1225                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1226         }
1227         else
1228         {
1229                 stuffcmd(this, "set _teams_available 0\n");
1230         }
1231
1232         bot_relinkplayerlist();
1233
1234         CS(this).spectatortime = time;
1235         if (blockSpectators)
1236         {
1237                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1238         }
1239
1240         CS(this).jointime = time;
1241         CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1242
1243         if (IS_REAL_CLIENT(this))
1244         {
1245                 if (g_weaponarena_weapons == WEPSET(TUBA))
1246                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1247         }
1248
1249         if (!sv_foginterval && world.fog != "")
1250                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1251
1252         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1253                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1254                         send_CSQC_teamnagger();
1255
1256         CSQCMODEL_AUTOINIT(this);
1257
1258         CS(this).model_randomizer = random();
1259
1260         if (IS_REAL_CLIENT(this))
1261                 sv_notice_join(this);
1262
1263         // update physics stats (players can spawn before physics runs)
1264         Physics_UpdateStats(this);
1265
1266         IL_EACH(g_initforplayer, it.init_for_player, {
1267                 it.init_for_player(it, this);
1268         });
1269
1270         MUTATOR_CALLHOOK(ClientConnect, this);
1271
1272         if (IS_REAL_CLIENT(this))
1273         {
1274                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1275                 {
1276                         CS(this).motd_actived_time = -1;
1277                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1278                 }
1279         }
1280 }
1281 /*
1282 =============
1283 ClientDisconnect
1284
1285 Called when a client disconnects from the server
1286 =============
1287 */
1288 .entity chatbubbleentity;
1289 void ReadyCount();
1290 void ClientDisconnect(entity this)
1291 {
1292         assert(IS_CLIENT(this), return);
1293
1294         PlayerStats_GameReport_FinalizePlayer(this);
1295         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1296         if (CS(this).active_minigame) part_minigame(this);
1297         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1298
1299         if (autocvar_sv_eventlog)
1300                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1301
1302         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1303
1304         if(IS_SPEC(this))
1305                 SetSpectatee(this, NULL);
1306
1307     MUTATOR_CALLHOOK(ClientDisconnect, this);
1308
1309         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1310         ClientState_detach(this);
1311
1312         Portal_ClearAll(this);
1313
1314         Unfreeze(this);
1315
1316         RemoveGrapplingHooks(this);
1317
1318         // Here, everything has been done that requires this player to be a client.
1319
1320         this.flags &= ~FL_CLIENT;
1321
1322         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1323         if (this.killindicator) delete(this.killindicator);
1324
1325         WaypointSprite_PlayerGone(this);
1326
1327         bot_relinkplayerlist();
1328
1329         if (this.clientstatus) strunzone(this.clientstatus);
1330         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1331         if (this.personal) delete(this.personal);
1332
1333         this.playerid = 0;
1334         ReadyCount();
1335         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1336
1337         ONREMOVE(this);
1338 }
1339
1340 void ChatBubbleThink(entity this)
1341 {
1342         this.nextthink = time;
1343         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1344         {
1345                 if(this.owner) // but why can that ever be NULL?
1346                         this.owner.chatbubbleentity = NULL;
1347                 delete(this);
1348                 return;
1349         }
1350
1351         this.mdl = "";
1352
1353         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1354         {
1355                 if ( CS(this.owner).active_minigame )
1356                         this.mdl = "models/sprites/minigame_busy.iqm";
1357                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1358                         this.mdl = "models/misc/chatbubble.spr";
1359         }
1360
1361         if ( this.model != this.mdl )
1362                 _setmodel(this, this.mdl);
1363
1364 }
1365
1366 void UpdateChatBubble(entity this)
1367 {
1368         if (this.alpha < 0)
1369                 return;
1370         // spawn a chatbubble entity if needed
1371         if (!this.chatbubbleentity)
1372         {
1373                 this.chatbubbleentity = new(chatbubbleentity);
1374                 this.chatbubbleentity.owner = this;
1375                 this.chatbubbleentity.exteriormodeltoclient = this;
1376                 setthink(this.chatbubbleentity, ChatBubbleThink);
1377                 this.chatbubbleentity.nextthink = time;
1378                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1379                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1380                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1381                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1382                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1383                 //this.chatbubbleentity.model = "";
1384                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1385         }
1386 }
1387
1388
1389 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1390 // added to the model skins
1391 /*void UpdateColorModHack()
1392 {
1393         float c;
1394         c = this.clientcolors & 15;
1395         // LordHavoc: only bothering to support white, green, red, yellow, blue
1396              if (!teamplay) this.colormod = '0 0 0';
1397         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1398         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1399         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1400         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1401         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1402         else this.colormod = '1 1 1';
1403 }*/
1404
1405 void respawn(entity this)
1406 {
1407         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1408         {
1409                 this.solid = SOLID_NOT;
1410                 this.takedamage = DAMAGE_NO;
1411                 set_movetype(this, MOVETYPE_FLY);
1412                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1413                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1414                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1415                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1416                 if(autocvar_g_respawn_ghosts_maxtime)
1417                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1418         }
1419
1420         CopyBody(this, 1);
1421
1422         this.effects |= EF_NODRAW; // prevent another CopyBody
1423         PutClientInServer(this);
1424 }
1425
1426 void play_countdown(entity this, float finished, Sound samp)
1427 {
1428     TC(Sound, samp);
1429         if(IS_REAL_CLIENT(this))
1430                 if(floor(finished - time - frametime) != floor(finished - time))
1431                         if(finished - time < 6)
1432                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1433 }
1434
1435 void player_powerups(entity this)
1436 {
1437         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1438         int items_prev = this.items;
1439
1440         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1441                 this.modelflags |= MF_ROCKET;
1442         else
1443                 this.modelflags &= ~MF_ROCKET;
1444
1445         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1446
1447         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1448                 return;
1449
1450         Fire_ApplyDamage(this);
1451         Fire_ApplyEffect(this);
1452
1453         if (!g_instagib)
1454         {
1455                 if (this.items & ITEM_Strength.m_itemid)
1456                 {
1457                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1458                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1459                         if (time > this.strength_finished)
1460                         {
1461                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1462                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1463                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1464                         }
1465                 }
1466                 else
1467                 {
1468                         if (time < this.strength_finished)
1469                         {
1470                                 this.items = this.items | ITEM_Strength.m_itemid;
1471                                 if(!g_cts)
1472                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1473                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1474                         }
1475                 }
1476                 if (this.items & ITEM_Shield.m_itemid)
1477                 {
1478                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1479                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1480                         if (time > this.invincible_finished)
1481                         {
1482                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1483                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1484                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1485                         }
1486                 }
1487                 else
1488                 {
1489                         if (time < this.invincible_finished)
1490                         {
1491                                 this.items = this.items | ITEM_Shield.m_itemid;
1492                                 if(!g_cts)
1493                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1494                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1495                         }
1496                 }
1497                 if (this.items & IT_SUPERWEAPON)
1498                 {
1499                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1500                         {
1501                                 this.superweapons_finished = 0;
1502                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1503                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1504                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1505                         }
1506                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1507                         {
1508                                 // don't let them run out
1509                         }
1510                         else
1511                         {
1512                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1513                                 if (time > this.superweapons_finished)
1514                                 {
1515                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1516                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1517                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1518                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1519                                 }
1520                         }
1521                 }
1522                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1523                 {
1524                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1525                         {
1526                                 this.items = this.items | IT_SUPERWEAPON;
1527                                 if(!g_cts)
1528                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1529                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1530                         }
1531                         else
1532                         {
1533                                 this.superweapons_finished = 0;
1534                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1535                         }
1536                 }
1537                 else
1538                 {
1539                         this.superweapons_finished = 0;
1540                 }
1541         }
1542
1543         if(autocvar_g_nodepthtestplayers)
1544                 this.effects = this.effects | EF_NODEPTHTEST;
1545
1546         if(autocvar_g_fullbrightplayers)
1547                 this.effects = this.effects | EF_FULLBRIGHT;
1548
1549         if (time >= game_starttime)
1550         if (time < this.spawnshieldtime)
1551                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1552
1553         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1554 }
1555
1556 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1557 {
1558         if(current > stable)
1559                 return current;
1560         else if(current > stable - 0.25) // when close enough, "snap"
1561                 return stable;
1562         else
1563                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1564 }
1565
1566 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1567 {
1568         if(current < stable)
1569                 return current;
1570         else if(current < stable + 0.25) // when close enough, "snap"
1571                 return stable;
1572         else
1573                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1574 }
1575
1576 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1577 {
1578         if(current > rotstable)
1579         {
1580                 if(rotframetime > 0)
1581                 {
1582                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1583                         current = max(rotstable, current - rotlinear * rotframetime);
1584                 }
1585         }
1586         else if(current < regenstable)
1587         {
1588                 if(regenframetime > 0)
1589                 {
1590                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1591                         current = min(regenstable, current + regenlinear * regenframetime);
1592                 }
1593         }
1594
1595         if(current > limit)
1596                 current = limit;
1597
1598         return current;
1599 }
1600
1601 void player_regen(entity this)
1602 {
1603         float max_mod, regen_mod, rot_mod, limit_mod;
1604         max_mod = regen_mod = rot_mod = limit_mod = 1;
1605
1606         float regen_health = autocvar_g_balance_health_regen;
1607         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1608         float regen_health_rot = autocvar_g_balance_health_rot;
1609         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1610         float regen_health_stable = autocvar_g_balance_health_regenstable;
1611         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1612         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1613                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1614         max_mod = M_ARGV(1, float);
1615         regen_mod = M_ARGV(2, float);
1616         rot_mod = M_ARGV(3, float);
1617         limit_mod = M_ARGV(4, float);
1618         regen_health = M_ARGV(5, float);
1619         regen_health_linear = M_ARGV(6, float);
1620         regen_health_rot = M_ARGV(7, float);
1621         regen_health_rotlinear = M_ARGV(8, float);
1622         regen_health_stable = M_ARGV(9, float);
1623         regen_health_rotstable = M_ARGV(10, float);
1624
1625         // Ugly hack to make sure the haelth and armor don't go beyond hard limit.
1626         // TODO: Remove this hack when all code uses GivePlayerHealth and
1627         // GivePlayerArmor.
1628         this.health = bound(0, this.health, ITEM_COUNT_HARD_LIMIT);
1629         this.armorvalue = bound(0, this.armorvalue, ITEM_COUNT_HARD_LIMIT);
1630         // End hack.
1631
1632         if(!mutator_returnvalue)
1633         if(!STAT(FROZEN, this))
1634         {
1635                 float mina, maxa, limith, limita;
1636                 maxa = autocvar_g_balance_armor_rotstable;
1637                 mina = autocvar_g_balance_armor_regenstable;
1638                 limith = autocvar_g_balance_health_limit;
1639                 limita = autocvar_g_balance_armor_limit;
1640
1641                 regen_health_rotstable = regen_health_rotstable * max_mod;
1642                 regen_health_stable = regen_health_stable * max_mod;
1643                 limith = limith * limit_mod;
1644                 limita = limita * limit_mod;
1645
1646                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1647                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1648         }
1649
1650         // if player rotted to death...  die!
1651         // check this outside above checks, as player may still be able to rot to death
1652         if(this.health < 1)
1653         {
1654                 if(this.vehicle)
1655                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1656                 if(this.event_damage)
1657                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1658         }
1659
1660         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1661         {
1662                 float minf, maxf, limitf;
1663
1664                 maxf = autocvar_g_balance_fuel_rotstable;
1665                 minf = autocvar_g_balance_fuel_regenstable;
1666                 limitf = autocvar_g_balance_fuel_limit;
1667
1668                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1669         }
1670 }
1671
1672 bool zoomstate_set;
1673 void SetZoomState(entity this, float newzoom)
1674 {
1675         if(newzoom != CS(this).zoomstate)
1676         {
1677                 CS(this).zoomstate = newzoom;
1678                 ClientData_Touch(this);
1679         }
1680         zoomstate_set = true;
1681 }
1682
1683 void GetPressedKeys(entity this)
1684 {
1685         MUTATOR_CALLHOOK(GetPressedKeys, this);
1686         int keys = STAT(PRESSED_KEYS, this);
1687         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1688         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1689         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1690         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1691
1692         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1693         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1694         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1695         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1696         CS(this).pressedkeys = keys; // store for other users
1697
1698         STAT(PRESSED_KEYS, this) = keys;
1699 }
1700
1701 /*
1702 ======================
1703 spectate mode routines
1704 ======================
1705 */
1706
1707 void SpectateCopy(entity this, entity spectatee)
1708 {
1709     TC(Client, this); TC(Client, spectatee);
1710
1711         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1712         PS(this) = PS(spectatee);
1713         this.armortype = spectatee.armortype;
1714         this.armorvalue = spectatee.armorvalue;
1715         this.ammo_cells = spectatee.ammo_cells;
1716         this.ammo_plasma = spectatee.ammo_plasma;
1717         this.ammo_shells = spectatee.ammo_shells;
1718         this.ammo_nails = spectatee.ammo_nails;
1719         this.ammo_rockets = spectatee.ammo_rockets;
1720         this.ammo_fuel = spectatee.ammo_fuel;
1721         this.clip_load = spectatee.clip_load;
1722         this.clip_size = spectatee.clip_size;
1723         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1724         this.health = spectatee.health;
1725         CS(this).impulse = 0;
1726         this.items = spectatee.items;
1727         this.last_pickup = spectatee.last_pickup;
1728         this.hit_time = spectatee.hit_time;
1729         this.strength_finished = spectatee.strength_finished;
1730         this.invincible_finished = spectatee.invincible_finished;
1731         this.superweapons_finished = spectatee.superweapons_finished;
1732         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1733         this.weapons = spectatee.weapons;
1734         this.vortex_charge = spectatee.vortex_charge;
1735         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1736         this.hagar_load = spectatee.hagar_load;
1737         this.arc_heat_percent = spectatee.arc_heat_percent;
1738         this.minelayer_mines = spectatee.minelayer_mines;
1739         this.punchangle = spectatee.punchangle;
1740         this.view_ofs = spectatee.view_ofs;
1741         this.velocity = spectatee.velocity;
1742         this.dmg_take = spectatee.dmg_take;
1743         this.dmg_save = spectatee.dmg_save;
1744         this.dmg_inflictor = spectatee.dmg_inflictor;
1745         this.v_angle = spectatee.v_angle;
1746         this.angles = spectatee.v_angle;
1747         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1748         this.revive_progress = spectatee.revive_progress;
1749         this.viewloc = spectatee.viewloc;
1750         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1751                 this.fixangle = true;
1752         setorigin(this, spectatee.origin);
1753         setsize(this, spectatee.mins, spectatee.maxs);
1754         SetZoomState(this, CS(spectatee).zoomstate);
1755
1756         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1757         {
1758                 .entity weaponentity = weaponentities[slot];
1759                 this.(weaponentity) = spectatee.(weaponentity);
1760         }
1761
1762         for(int slot = 0; slot < MAX_AXH; ++slot)
1763         {
1764                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1765         }
1766
1767     anticheat_spectatecopy(this, spectatee);
1768         this.hud = spectatee.hud;
1769         if(spectatee.vehicle)
1770     {
1771         this.angles = spectatee.v_angle;
1772
1773         //this.fixangle = false;
1774         //this.velocity = spectatee.vehicle.velocity;
1775         this.vehicle_health = spectatee.vehicle_health;
1776         this.vehicle_shield = spectatee.vehicle_shield;
1777         this.vehicle_energy = spectatee.vehicle_energy;
1778         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1779         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1780         this.vehicle_reload1 = spectatee.vehicle_reload1;
1781         this.vehicle_reload2 = spectatee.vehicle_reload2;
1782
1783         //msg_entity = this;
1784
1785        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1786             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1787            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1788            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1789
1790         //WriteByte (MSG_ONE, SVC_SETVIEW);
1791         //    WriteEntity(MSG_ONE, this);
1792         //makevectors(spectatee.v_angle);
1793         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1794     }
1795 }
1796
1797 bool SpectateUpdate(entity this)
1798 {
1799         if(!this.enemy)
1800                 return false;
1801
1802         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1803         {
1804                 SetSpectatee(this, NULL);
1805                 return false;
1806         }
1807
1808         SpectateCopy(this, this.enemy);
1809
1810         return true;
1811 }
1812
1813 bool SpectateSet(entity this)
1814 {
1815         if(!IS_PLAYER(this.enemy))
1816                 return false;
1817
1818         ClientData_Touch(this.enemy);
1819
1820         msg_entity = this;
1821         WriteByte(MSG_ONE, SVC_SETVIEW);
1822         WriteEntity(MSG_ONE, this.enemy);
1823         set_movetype(this, MOVETYPE_NONE);
1824         accuracy_resend(this);
1825
1826         if(!SpectateUpdate(this))
1827                 PutObserverInServer(this);
1828
1829         return true;
1830 }
1831
1832 void SetSpectatee_status(entity this, int spectatee_num)
1833 {
1834         int oldspectatee_status = CS(this).spectatee_status;
1835         CS(this).spectatee_status = spectatee_num;
1836
1837         if (CS(this).spectatee_status != oldspectatee_status)
1838         {
1839                 ClientData_Touch(this);
1840                 if (g_race || g_cts) race_InitSpectator();
1841         }
1842 }
1843
1844 void SetSpectatee(entity this, entity spectatee)
1845 {
1846         if(IS_BOT_CLIENT(this))
1847                 return; // bots abuse .enemy, this code is useless to them
1848
1849         entity old_spectatee = this.enemy;
1850
1851         this.enemy = spectatee;
1852
1853         // WEAPONTODO
1854         // these are required to fix the spectator bug with arc
1855         if(old_spectatee)
1856         {
1857                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1858                 {
1859                         .entity weaponentity = weaponentities[slot];
1860                         if(old_spectatee.(weaponentity).arc_beam)
1861                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1862                 }
1863         }
1864         if(this.enemy)
1865         {
1866                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1867                 {
1868                         .entity weaponentity = weaponentities[slot];
1869                         if(this.enemy.(weaponentity).arc_beam)
1870                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1871                 }
1872         }
1873
1874         if (this.enemy)
1875                 SetSpectatee_status(this, etof(this.enemy));
1876
1877         // needed to update spectator list
1878         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1879 }
1880
1881 bool Spectate(entity this, entity pl)
1882 {
1883         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1884                 return false;
1885         pl = M_ARGV(1, entity);
1886
1887         SetSpectatee(this, pl);
1888         return SpectateSet(this);
1889 }
1890
1891 bool SpectateNext(entity this)
1892 {
1893         entity ent = find(this.enemy, classname, STR_PLAYER);
1894
1895         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1896                 ent = M_ARGV(1, entity);
1897         else if (!ent)
1898                 ent = find(ent, classname, STR_PLAYER);
1899
1900         if(ent) { SetSpectatee(this, ent); }
1901
1902         return SpectateSet(this);
1903 }
1904
1905 bool SpectatePrev(entity this)
1906 {
1907         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1908         entity ent = findchain(classname, STR_PLAYER);
1909         if (!ent) // no player
1910                 return false;
1911
1912         entity first = ent;
1913         // skip players until current spectated player
1914         if(this.enemy)
1915         while(ent && ent != this.enemy)
1916                 ent = ent.chain;
1917
1918         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1919         {
1920                 case MUT_SPECPREV_FOUND:
1921                     ent = M_ARGV(1, entity);
1922                     break;
1923                 case MUT_SPECPREV_RETURN:
1924                     return true;
1925                 case MUT_SPECPREV_CONTINUE:
1926                 default:
1927                 {
1928                         if(ent.chain)
1929                                 ent = ent.chain;
1930                         else
1931                                 ent = first;
1932                         break;
1933                 }
1934         }
1935
1936         SetSpectatee(this, ent);
1937         return SpectateSet(this);
1938 }
1939
1940 /*
1941 =============
1942 ShowRespawnCountdown()
1943
1944 Update a respawn countdown display.
1945 =============
1946 */
1947 void ShowRespawnCountdown(entity this)
1948 {
1949         float number;
1950         if(!IS_DEAD(this)) // just respawned?
1951                 return;
1952         else
1953         {
1954                 number = ceil(this.respawn_time - time);
1955                 if(number <= 0)
1956                         return;
1957                 if(number <= this.respawn_countdown)
1958                 {
1959                         this.respawn_countdown = number - 1;
1960                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1961                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1962                 }
1963         }
1964 }
1965
1966 .bool team_selected;
1967 bool ShowTeamSelection(entity this)
1968 {
1969         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1970                 return false;
1971         stuffcmd(this, "menu_showteamselect\n");
1972         return true;
1973 }
1974 void Join(entity this)
1975 {
1976         TRANSMUTE(Player, this);
1977
1978         if(!this.team_selected)
1979         if(autocvar_g_campaign || autocvar_g_balance_teams)
1980                 JoinBestTeam(this, false, true);
1981
1982         if(autocvar_g_campaign)
1983                 campaign_bots_may_start = true;
1984
1985         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1986
1987         PutClientInServer(this);
1988
1989         if(IS_PLAYER(this))
1990         if(teamplay && this.team != -1)
1991                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1992         else
1993                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1994         this.team_selected = false;
1995 }
1996
1997 /**
1998  * Determines whether the player is allowed to join. This depends on cvar
1999  * g_maxplayers, if it isn't used this function always return true, otherwise
2000  * it checks whether the number of currently playing players exceeds g_maxplayers.
2001  * @return int number of free slots for players, 0 if none
2002  */
2003 int nJoinAllowed(entity this, entity ignore)
2004 {
2005         if(!ignore)
2006         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2007         // so report 0 free slots if restricted
2008         {
2009                 if(autocvar_g_forced_team_otherwise == "spectate")
2010                         return 0;
2011                 if(autocvar_g_forced_team_otherwise == "spectator")
2012                         return 0;
2013         }
2014
2015         if(this && this.team_forced < 0)
2016                 return 0; // forced spectators can never join
2017
2018         // TODO simplify this
2019         int totalClients = 0;
2020         int currentlyPlaying = 0;
2021         FOREACH_CLIENT(true, {
2022                 if(it != ignore)
2023                         ++totalClients;
2024                 if(IS_REAL_CLIENT(it))
2025                 if(IS_PLAYER(it) || it.caplayer)
2026                         ++currentlyPlaying;
2027         });
2028
2029         float free_slots = 0;
2030         if (!autocvar_g_maxplayers)
2031                 free_slots = maxclients - totalClients;
2032         else if(currentlyPlaying < autocvar_g_maxplayers)
2033                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2034
2035         static float join_prevent_msg_time = 0;
2036         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2037         {
2038                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2039                 join_prevent_msg_time = time + 3;
2040         }
2041
2042         return free_slots;
2043 }
2044
2045 /**
2046  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2047  * g_maxplayers_spectator_blocktime seconds
2048  */
2049 void checkSpectatorBlock(entity this)
2050 {
2051         if(IS_SPEC(this) || IS_OBSERVER(this))
2052         if(!this.caplayer)
2053         if(IS_REAL_CLIENT(this))
2054         {
2055                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2056                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2057                         dropclient(this);
2058                 }
2059         }
2060 }
2061
2062 void PrintWelcomeMessage(entity this)
2063 {
2064         if(CS(this).motd_actived_time == 0)
2065         {
2066                 if (autocvar_g_campaign) {
2067                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2068                                 CS(this).motd_actived_time = time;
2069                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2070                         }
2071                 } else {
2072                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2073                                 CS(this).motd_actived_time = time;
2074                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2075                         }
2076                 }
2077         }
2078         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2079         {
2080                 if (autocvar_g_campaign) {
2081                         if (PHYS_INPUT_BUTTON_INFO(this))
2082                                 CS(this).motd_actived_time = time;
2083                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2084                                 CS(this).motd_actived_time = 0;
2085                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2086                         }
2087                 } else {
2088                         if (PHYS_INPUT_BUTTON_INFO(this))
2089                                 CS(this).motd_actived_time = time;
2090                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2091                                 CS(this).motd_actived_time = 0;
2092                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2093                         }
2094                 }
2095         }
2096         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2097         {
2098                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2099                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2100                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2101                 {
2102                         // instanctly hide MOTD
2103                         CS(this).motd_actived_time = 0;
2104                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2105                 }
2106         }
2107 }
2108
2109 bool joinAllowed(entity this)
2110 {
2111         if (CS(this).version_mismatch) return false;
2112         if (!nJoinAllowed(this, this)) return false;
2113         if (teamplay && lockteams) return false;
2114         if (ShowTeamSelection(this)) return false;
2115         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2116         return true;
2117 }
2118
2119 .int items_added;
2120 bool PlayerThink(entity this)
2121 {
2122         if (game_stopped || intermission_running) {
2123                 this.modelflags &= ~MF_ROCKET;
2124                 if(intermission_running)
2125                         IntermissionThink(this);
2126                 return false;
2127         }
2128
2129         if (timeout_status == TIMEOUT_ACTIVE) {
2130         // don't allow the player to turn around while game is paused
2131                 // FIXME turn this into CSQC stuff
2132                 this.v_angle = this.lastV_angle;
2133                 this.angles = this.lastV_angle;
2134                 this.fixangle = true;
2135         }
2136
2137         if (frametime) player_powerups(this);
2138
2139         if (IS_DEAD(this)) {
2140                 if (this.personal && g_race_qualifying) {
2141                         if (time > this.respawn_time) {
2142                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2143                                 respawn(this);
2144                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2145                         }
2146                 } else {
2147                         if (frametime) player_anim(this);
2148
2149                         if (this.respawn_flags & RESPAWN_DENY)
2150                         {
2151                                 STAT(RESPAWN_TIME, this) = 0;
2152                                 return false;
2153                         }
2154
2155                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2156
2157                         switch(this.deadflag)
2158                         {
2159                                 case DEAD_DYING:
2160                                 {
2161                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2162                                                 this.deadflag = DEAD_RESPAWNING;
2163                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2164                                                 this.deadflag = DEAD_DEAD;
2165                                         break;
2166                                 }
2167                                 case DEAD_DEAD:
2168                                 {
2169                                         if (button_pressed)
2170                                                 this.deadflag = DEAD_RESPAWNABLE;
2171                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2172                                                 this.deadflag = DEAD_RESPAWNING;
2173                                         break;
2174                                 }
2175                                 case DEAD_RESPAWNABLE:
2176                                 {
2177                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2178                                                 this.deadflag = DEAD_RESPAWNING;
2179                                         break;
2180                                 }
2181                                 case DEAD_RESPAWNING:
2182                                 {
2183                                         if (time > this.respawn_time)
2184                                         {
2185                                                 this.respawn_time = time + 1; // only retry once a second
2186                                                 this.respawn_time_max = this.respawn_time;
2187                                                 respawn(this);
2188                                         }
2189                                         break;
2190                                 }
2191                         }
2192
2193                         ShowRespawnCountdown(this);
2194
2195                         if (this.respawn_flags & RESPAWN_SILENT)
2196                                 STAT(RESPAWN_TIME, this) = 0;
2197                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2198                         {
2199                                 if (time < this.respawn_time)
2200                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2201                                 else if (this.deadflag != DEAD_RESPAWNING)
2202                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2203                         }
2204                         else
2205                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2206                 }
2207
2208                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2209                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2210                         STAT(RESPAWN_TIME, this) *= -1;
2211
2212                 return false;
2213         }
2214
2215         bool have_hook = false;
2216         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2217         {
2218                 .entity weaponentity = weaponentities[slot];
2219                 if(this.(weaponentity).hook.state)
2220                 {
2221                         have_hook = true;
2222                         break;
2223                 }
2224         }
2225         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2226         if (have_hook) {
2227                 do_crouch = false;
2228         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2229                 do_crouch = false;
2230         } else if (this.vehicle) {
2231                 do_crouch = false;
2232         } else if (STAT(FROZEN, this)) {
2233                 do_crouch = false;
2234     }
2235
2236         if (do_crouch) {
2237                 if (!this.crouch) {
2238                         this.crouch = true;
2239                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2240                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2241                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2242                 }
2243         } else if (this.crouch) {
2244         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2245         if (!trace_startsolid) {
2246             this.crouch = false;
2247             this.view_ofs = STAT(PL_VIEW_OFS, this);
2248             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2249         }
2250         }
2251
2252         FixPlayermodel(this);
2253
2254         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2255         //if(frametime)
2256         {
2257                 this.items &= ~this.items_added;
2258
2259                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2260                 {
2261                         .entity weaponentity = weaponentities[slot];
2262                         W_WeaponFrame(this, weaponentity);
2263
2264                         if(slot == 0)
2265                         {
2266                                 this.clip_load = this.(weaponentity).clip_load;
2267                                 this.clip_size = this.(weaponentity).clip_size;
2268                         }
2269                 }
2270
2271                 this.items_added = 0;
2272                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2273             this.items_added |= IT_FUEL;
2274
2275                 this.items |= this.items_added;
2276         }
2277
2278         player_regen(this);
2279
2280         // WEAPONTODO: Add a weapon request for this
2281         // rot vortex charge to the charge limit
2282         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2283         {
2284                 .entity weaponentity = weaponentities[slot];
2285                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2286                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2287         }
2288
2289         if (frametime) player_anim(this);
2290
2291         // secret status
2292         secrets_setstatus(this);
2293
2294         // monsters status
2295         monsters_setstatus(this);
2296
2297         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2298
2299         return true;
2300 }
2301
2302 void ObserverThink(entity this)
2303 {
2304         if ( CS(this).impulse )
2305         {
2306                 MinigameImpulse(this, CS(this).impulse);
2307                 CS(this).impulse = 0;
2308         }
2309
2310         if (this.flags & FL_JUMPRELEASED) {
2311                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2312                         this.flags &= ~FL_JUMPRELEASED;
2313                         this.flags |= FL_SPAWNING;
2314                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2315                         this.flags &= ~FL_JUMPRELEASED;
2316                         if(SpectateNext(this)) {
2317                                 TRANSMUTE(Spectator, this);
2318                         }
2319                 } else {
2320                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2321                         set_movetype(this, preferred_movetype);
2322                 }
2323         } else {
2324                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2325                         this.flags |= FL_JUMPRELEASED;
2326                         if(this.flags & FL_SPAWNING)
2327                         {
2328                                 this.flags &= ~FL_SPAWNING;
2329                                 Join(this);
2330                                 return;
2331                         }
2332                 }
2333         }
2334 }
2335
2336 void SpectatorThink(entity this)
2337 {
2338         if ( CS(this).impulse )
2339         {
2340                 if(MinigameImpulse(this, CS(this).impulse))
2341                         CS(this).impulse = 0;
2342
2343                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2344                 {
2345                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2346                         CS(this).impulse = 0;
2347                         return;
2348                 }
2349         }
2350
2351         if (this.flags & FL_JUMPRELEASED) {
2352                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2353                         this.flags &= ~FL_JUMPRELEASED;
2354                         this.flags |= FL_SPAWNING;
2355                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2356                         this.flags &= ~FL_JUMPRELEASED;
2357                         if(SpectateNext(this)) {
2358                                 TRANSMUTE(Spectator, this);
2359                         } else {
2360                                 TRANSMUTE(Observer, this);
2361                                 PutClientInServer(this);
2362                         }
2363                         CS(this).impulse = 0;
2364                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2365                         this.flags &= ~FL_JUMPRELEASED;
2366                         if(SpectatePrev(this)) {
2367                                 TRANSMUTE(Spectator, this);
2368                         } else {
2369                                 TRANSMUTE(Observer, this);
2370                                 PutClientInServer(this);
2371                         }
2372                         CS(this).impulse = 0;
2373                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2374                         this.flags &= ~FL_JUMPRELEASED;
2375                         TRANSMUTE(Observer, this);
2376                         PutClientInServer(this);
2377                 } else {
2378                         if(!SpectateUpdate(this))
2379                                 PutObserverInServer(this);
2380                 }
2381         } else {
2382                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2383                         this.flags |= FL_JUMPRELEASED;
2384                         if(this.flags & FL_SPAWNING)
2385                         {
2386                                 this.flags &= ~FL_SPAWNING;
2387                                 Join(this);
2388                                 return;
2389                         }
2390                 }
2391                 if(!SpectateUpdate(this))
2392                         PutObserverInServer(this);
2393         }
2394
2395         this.flags |= FL_CLIENT | FL_NOTARGET;
2396 }
2397
2398 void vehicles_enter (entity pl, entity veh);
2399 void PlayerUseKey(entity this)
2400 {
2401         if (!IS_PLAYER(this))
2402                 return;
2403
2404         if(this.vehicle)
2405         {
2406                 if(!game_stopped)
2407                 {
2408                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2409                         return;
2410                 }
2411         }
2412         else if(autocvar_g_vehicles_enter)
2413         {
2414                 if(!STAT(FROZEN, this))
2415                 if(!IS_DEAD(this))
2416                 if(!game_stopped)
2417                 {
2418                         entity head, closest_target = NULL;
2419                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2420
2421                         while(head) // find the closest acceptable target to enter
2422                         {
2423                                 if(IS_VEHICLE(head))
2424                                 if(!IS_DEAD(head))
2425                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2426                                 if(head.takedamage != DAMAGE_NO)
2427                                 {
2428                                         if(closest_target)
2429                                         {
2430                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2431                                                 { closest_target = head; }
2432                                         }
2433                                         else { closest_target = head; }
2434                                 }
2435
2436                                 head = head.chain;
2437                         }
2438
2439                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2440                 }
2441         }
2442
2443         // a use key was pressed; call handlers
2444         MUTATOR_CALLHOOK(PlayerUseKey, this);
2445 }
2446
2447
2448 /*
2449 =============
2450 PlayerPreThink
2451
2452 Called every frame for each client before the physics are run
2453 =============
2454 */
2455 .float last_vehiclecheck;
2456 void PlayerPreThink (entity this)
2457 {
2458         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2459         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2460
2461         WarpZone_PlayerPhysics_FixVAngle(this);
2462
2463         if (frametime) {
2464                 // physics frames: update anticheat stuff
2465                 anticheat_prethink(this);
2466         }
2467
2468         if (blockSpectators && frametime) {
2469                 // WORKAROUND: only use dropclient in server frames (frametime set).
2470                 // Never use it in cl_movement frames (frametime zero).
2471                 checkSpectatorBlock(this);
2472     }
2473
2474         zoomstate_set = false;
2475
2476         // Check for nameless players
2477         if (isInvisibleString(this.netname)) {
2478                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2479                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2480         }
2481         if (this.netname != CS(this).netname_previous) {
2482                 if (autocvar_sv_eventlog) {
2483                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2484         }
2485                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2486                 CS(this).netname_previous = strzone(this.netname);
2487         }
2488
2489         // version nagging
2490         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2491         CS(this).version_nagtime = 0;
2492         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2493             // git client
2494         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2495             // git server
2496             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2497         } else {
2498             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2499             if (r < 0) { // old client
2500                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2501             } else if (r > 0) { // old server
2502                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2503             }
2504         }
2505     }
2506
2507         // GOD MODE info
2508         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2509         {
2510                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2511                 this.max_armorvalue = 0;
2512         }
2513
2514         if(IS_PLAYER(this))
2515         {
2516                 if (STAT(FROZEN, this) == 2)
2517                 {
2518                         this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2519                         this.health = max(1, this.revive_progress * start_health);
2520                         this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2521
2522                         if (this.revive_progress >= 1)
2523                                 Unfreeze(this);
2524                 }
2525                 else if (STAT(FROZEN, this) == 3)
2526                 {
2527                         this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2528                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2529
2530                         if (this.health < 1)
2531                         {
2532                                 if (this.vehicle)
2533                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2534                                 if(this.event_damage)
2535                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2536                         }
2537                         else if (this.revive_progress <= 0)
2538                                 Unfreeze(this);
2539                 }
2540         }
2541
2542         MUTATOR_CALLHOOK(PlayerPreThink, this);
2543
2544         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2545         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2546         {
2547                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2548                 {
2549                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2550                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2551                         {
2552                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2553                         }
2554                         else if(!it.owner)
2555                         {
2556                                 if(!it.team || SAME_TEAM(this, it))
2557                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2558                                 else if(autocvar_g_vehicles_steal)
2559                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2560                         }
2561                 });
2562
2563                 this.last_vehiclecheck = time + 1;
2564         }
2565
2566         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2567         {
2568                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2569                         PlayerUseKey(this);
2570                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2571         }
2572
2573         if (IS_REAL_CLIENT(this))
2574                 PrintWelcomeMessage(this);
2575
2576         if (IS_PLAYER(this)) {
2577                 if(!PlayerThink(this))
2578                         return;
2579         }
2580         else if (game_stopped || intermission_running) {
2581                 if(intermission_running)
2582                         IntermissionThink(this);
2583                 return;
2584         }
2585         else if (IS_OBSERVER(this)) {
2586                 ObserverThink(this);
2587         }
2588         else if (IS_SPEC(this)) {
2589                 SpectatorThink(this);
2590         }
2591
2592         // WEAPONTODO: Add weapon request for this
2593         if (!zoomstate_set) {
2594                 bool wep_zoomed = false;
2595                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2596                 {
2597                         .entity weaponentity = weaponentities[slot];
2598                         Weapon thiswep = this.(weaponentity).m_weapon;
2599                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2600                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2601                 }
2602                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2603     }
2604
2605         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2606         {
2607                 CS(this).teamkill_soundtime = 0;
2608
2609                 entity e = CS(this).teamkill_soundsource;
2610                 entity oldpusher = e.pusher;
2611                 e.pusher = this;
2612                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2613                 e.pusher = oldpusher;
2614         }
2615
2616         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2617                 CS(this).taunt_soundtime = 0;
2618                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2619         }
2620
2621         target_voicescript_next(this);
2622
2623         // WEAPONTODO: Move into weaponsystem somehow
2624         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2625         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2626         {
2627                 .entity weaponentity = weaponentities[slot];
2628                 if(this.(weaponentity).m_weapon == WEP_Null)
2629                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2630         }
2631 }
2632
2633 void DrownPlayer(entity this)
2634 {
2635         if(IS_DEAD(this))
2636                 return;
2637
2638         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2639         {
2640                 if(this.air_finished < time)
2641                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2642                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2643                 this.dmg = 2;
2644         }
2645         else if (this.air_finished < time)
2646         {       // drown!
2647                 if (this.pain_finished < time)
2648                 {
2649                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2650                         this.pain_finished = time + 0.5;
2651                 }
2652         }
2653 }
2654
2655 .bool move_qcphysics;
2656
2657 void Player_Physics(entity this)
2658 {
2659         set_movetype(this, this.move_movetype);
2660
2661         if(!this.move_qcphysics)
2662                 return;
2663
2664         if(!frametime && !CS(this).pm_frametime)
2665                 return;
2666
2667         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2668
2669         CS(this).pm_frametime = 0;
2670 }
2671
2672 /*
2673 =============
2674 PlayerPostThink
2675
2676 Called every frame for each client after the physics are run
2677 =============
2678 */
2679 void PlayerPostThink (entity this)
2680 {
2681         Player_Physics(this);
2682
2683         if (sv_maxidle > 0)
2684         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2685         if (IS_REAL_CLIENT(this))
2686         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2687         {
2688                 int totalClients = 0;
2689                 if(sv_maxidle_slots > 0)
2690                 {
2691                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2692                         {
2693                                 ++totalClients;
2694                         });
2695                 }
2696
2697                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2698                 { /* do nothing */ }
2699                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2700                 {
2701                         if (CS(this).idlekick_lasttimeleft)
2702                         {
2703                                 CS(this).idlekick_lasttimeleft = 0;
2704                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2705                         }
2706                 }
2707                 else
2708                 {
2709                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2710                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2711                                 if (!CS(this).idlekick_lasttimeleft)
2712                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2713                         }
2714                         if (timeleft <= 0) {
2715                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2716                                 dropclient(this);
2717                                 return;
2718                         }
2719                         else if (timeleft <= 10) {
2720                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2721                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2722                 }
2723                                 CS(this).idlekick_lasttimeleft = timeleft;
2724                         }
2725                 }
2726         }
2727
2728         CheatFrame(this);
2729
2730         if (game_stopped)
2731         {
2732                 this.solid = SOLID_NOT;
2733                 this.takedamage = DAMAGE_NO;
2734                 set_movetype(this, MOVETYPE_NONE);
2735         }
2736
2737         if (IS_PLAYER(this)) {
2738                 DrownPlayer(this);
2739                 UpdateChatBubble(this);
2740                 if (CS(this).impulse) ImpulseCommands(this);
2741                 if (game_stopped)
2742                 {
2743                         CSQCMODEL_AUTOUPDATE(this);
2744                         return;
2745                 }
2746                 GetPressedKeys(this);
2747         }
2748
2749         if (this.waypointsprite_attachedforcarrier) {
2750             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2751                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2752     }
2753
2754         playerdemo_write(this);
2755
2756         CSQCMODEL_AUTOUPDATE(this);
2757 }
2758
2759 // hack to copy the button fields from the client entity to the Client State
2760 void PM_UpdateButtons(entity this, entity store)
2761 {
2762         if(this.impulse)
2763                 store.impulse = this.impulse;
2764         this.impulse = 0;
2765
2766         store.button0 = this.button0;
2767         store.button2 = this.button2;
2768         store.button3 = this.button3;
2769         store.button4 = this.button4;
2770         store.button5 = this.button5;
2771         store.button6 = this.button6;
2772         store.button7 = this.button7;
2773         store.button8 = this.button8;
2774         store.button9 = this.button9;
2775         store.button10 = this.button10;
2776         store.button11 = this.button11;
2777         store.button12 = this.button12;
2778         store.button13 = this.button13;
2779         store.button14 = this.button14;
2780         store.button15 = this.button15;
2781         store.button16 = this.button16;
2782         store.buttonuse = this.buttonuse;
2783         store.buttonchat = this.buttonchat;
2784
2785         store.cursor_active = this.cursor_active;
2786         store.cursor_screen = this.cursor_screen;
2787         store.cursor_trace_start = this.cursor_trace_start;
2788         store.cursor_trace_endpos = this.cursor_trace_endpos;
2789         store.cursor_trace_ent = this.cursor_trace_ent;
2790
2791         store.ping = this.ping;
2792         store.ping_packetloss = this.ping_packetloss;
2793         store.ping_movementloss = this.ping_movementloss;
2794
2795         store.v_angle = this.v_angle;
2796         store.movement = this.movement;
2797 }