]> git.xonotic.org Git - xonotic/xonotic-data.pk3dir.git/blob - qcsrc/server/cl_weaponsystem.qc
Replace all player/bot/spectator classname checks with macros
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_weaponsystem.qc
1 /*
2 ===========================================================================
3
4   CLIENT WEAPONSYSTEM CODE
5   Bring back W_Weaponframe
6
7 ===========================================================================
8 */
9
10 .float weapon_frametime;
11
12 float W_WeaponRateFactor()
13 {
14         float t;
15         t = 1.0 / g_weaponratefactor;
16
17         if(g_runematch)
18         {
19                 if(self.runes & RUNE_SPEED)
20                 {
21                         if(self.runes & CURSE_SLOW)
22                                 t = t * autocvar_g_balance_rune_speed_combo_atkrate;
23                         else
24                                 t = t * autocvar_g_balance_rune_speed_atkrate;
25                 }
26                 else if(self.runes & CURSE_SLOW)
27                 {
28                         t = t * autocvar_g_balance_curse_slow_atkrate;
29                 }
30         }
31
32         return t;
33 }
34
35 void W_SwitchWeapon_Force(entity e, float w)
36 {
37         e.cnt = e.switchweapon;
38         e.switchweapon = w;
39         e.selectweapon = w;
40 }
41
42 .float antilag_debug;
43
44 // VorteX: static frame globals
45 float WFRAME_DONTCHANGE = -1;
46 float WFRAME_FIRE1 = 0;
47 float WFRAME_FIRE2 = 1;
48 float WFRAME_IDLE = 2;
49 float WFRAME_RELOAD = 3;
50 .float wframe;
51
52 void(float fr, float t, void() func) weapon_thinkf;
53
54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
55 {
56         vector ret;
57         ret_x = screenright * v;
58         ret_y = screenup * v;
59         ret_z = screenforward * v;
60         return ret;
61 }
62
63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
64 {
65         float i, j, k;
66         vector mi, ma, thisv, myv, ret;
67
68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
69
70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
71
72         mi = ma = targ.origin + 0.5 * (targ.mins + targ.maxs);
73         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
74         {
75                 thisv = targ.origin;
76                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
77                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
78                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
79                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
80                 if(i || j || k)
81                 {
82                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
83                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
84                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
85                 }
86                 else
87                 {
88                         // first run
89                         mi = ma = thisv;
90                 }
91         }
92
93         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
94         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
95         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
96         ret_z = thisv_z - myv_z;
97         return ret;
98 }
99
100 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
101 {
102         vector hitplot;
103         vector org;
104         float lag;
105
106         if(player.hitplotfh >= 0)
107         {
108                 lag = ANTILAG_LATENCY(player);
109                 if(lag < 0.001)
110                         lag = 0;
111                 if not(IS_REAL_CLIENT(player))
112                         lag = 0; // only antilag for clients
113
114                 org = player.origin + player.view_ofs;
115                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
116                 if(IS_CLIENT(trace_ent))
117                 {
118                         antilag_takeback(trace_ent, time - lag);
119                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
120                         antilag_restore(trace_ent);
121                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
122                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
123                 }
124         }
125 }
126
127 vector w_shotorg;
128 vector w_shotdir;
129 vector w_shotend;
130
131 .float prevstrengthsound;
132 .float prevstrengthsoundattempt;
133 void W_PlayStrengthSound(entity player) // void W_PlayStrengthSound
134 {
135                 if((!g_minstagib)
136                         && (player.items & IT_STRENGTH)
137                         && ((time > player.prevstrengthsound + autocvar_sv_strengthsound_antispam_time) // prevent insane sound spam
138                         || (time > player.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)))
139                 {
140                         sound(player, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
141                         player.prevstrengthsound = time;
142                 }
143                 player.prevstrengthsoundattempt = time;
144 }
145
146 // this function calculates w_shotorg and w_shotdir based on the weapon model
147 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
148 // make sure you call makevectors first (FIXME?)
149 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
150 {
151         float nudge = 1; // added to traceline target and subtracted from result
152         float oldsolid;
153         vector vecs, dv;
154         oldsolid = ent.dphitcontentsmask;
155         if(ent.weapon == WEP_RIFLE)
156                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
157         else
158                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
159         if(antilag)
160                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
161                 // passing world, because we do NOT want it to touch dphitcontentsmask
162         else
163                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
164         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
165
166         vector vf, vr, vu;
167         vf = v_forward;
168         vr = v_right;
169         vu = v_up;
170         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
171         v_forward = vf;
172         v_right = vr;
173         v_up = vu;
174
175         // un-adjust trueaim if shotend is too close
176         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
177                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
178
179         // track max damage
180         if(accuracy_canbegooddamage(ent))
181                 accuracy_add(ent, ent.weapon, maxdamage, 0);
182
183         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
184
185         if(ent.weaponentity.movedir_x > 0)
186                 vecs = ent.weaponentity.movedir;
187         else
188                 vecs = '0 0 0';
189
190         dv = v_right * -vecs_y + v_up * vecs_z;
191         w_shotorg = ent.origin + ent.view_ofs + dv;
192
193         // now move the shotorg forward as much as requested if possible
194         if(antilag)
195         {
196                 if(ent.antilag_debug)
197                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
198                 else
199                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
200         }
201         else
202                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
203         w_shotorg = trace_endpos - v_forward * nudge;
204         // calculate the shotdir from the chosen shotorg
205         w_shotdir = normalize(w_shotend - w_shotorg);
206
207         if (antilag)
208         if (!ent.cvar_cl_noantilag)
209         {
210                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
211                 {
212                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
213                         if (!trace_ent.takedamage)
214                         {
215                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
216                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
217                                 {
218                                         entity e;
219                                         e = trace_ent;
220                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
221                                         if(trace_ent == e)
222                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
223                                 }
224                         }
225                 }
226                 else if(autocvar_g_antilag == 3) // client side hitscan
227                 {
228                         // this part MUST use prydon cursor
229                         if (ent.cursor_trace_ent)                 // client was aiming at someone
230                         if (ent.cursor_trace_ent != ent)         // just to make sure
231                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
232                         if (IS_PLAYER(ent.cursor_trace_ent)) // and actually a player
233                         {
234                                 // verify that the shot would miss without antilag
235                                 // (avoids an issue where guns would always shoot at their origin)
236                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
237                                 if (!trace_ent.takedamage)
238                                 {
239                                         // verify that the shot would hit if altered
240                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
241                                         if (trace_ent == ent.cursor_trace_ent)
242                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
243                                         else
244                                                 print("antilag fail\n");
245                                 }
246                         }
247                 }
248         }
249
250         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
251
252         if (!g_norecoil)
253                 ent.punchangle_x = recoil * -1;
254
255         if (snd != "")
256         {
257                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
258                 W_PlayStrengthSound(ent);
259         }
260
261         // nudge w_shotend so a trace to w_shotend hits
262         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
263 }
264
265 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
266 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
267 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
268 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
269 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
270
271 float CL_Weaponentity_CustomizeEntityForClient()
272 {
273         self.viewmodelforclient = self.owner;
274         if(IS_SPEC(other))
275                 if(other.enemy == self.owner)
276                         self.viewmodelforclient = other;
277         return TRUE;
278 }
279
280 /*
281  * supported formats:
282  *
283  * 1. simple animated model, muzzle flash handling on h_ model:
284  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
285  *      tags:
286  *        shot = muzzle end (shot origin, also used for muzzle flashes)
287  *        shell = casings ejection point (must be on the right hand side of the gun)
288  *        weapon = attachment for v_tuba.md3
289  *    v_tuba.md3 - first and third person model
290  *    g_tuba.md3 - pickup model
291  *
292  * 2. simple animated model, muzzle flash handling on v_ model:
293  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
294  *      tags:
295  *        weapon = attachment for v_tuba.md3
296  *    v_tuba.md3 - first and third person model
297  *      tags:
298  *        shot = muzzle end (shot origin, also used for muzzle flashes)
299  *        shell = casings ejection point (must be on the right hand side of the gun)
300  *    g_tuba.md3 - pickup model
301  *
302  * 3. fully animated model, muzzle flash handling on h_ model:
303  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
304  *      tags:
305  *        shot = muzzle end (shot origin, also used for muzzle flashes)
306  *        shell = casings ejection point (must be on the right hand side of the gun)
307  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
308  *    v_tuba.md3 - third person model
309  *    g_tuba.md3 - pickup model
310  *
311  * 4. fully animated model, muzzle flash handling on v_ model:
312  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
313  *      tags:
314  *        shot = muzzle end (shot origin)
315  *        shell = casings ejection point (must be on the right hand side of the gun)
316  *    v_tuba.md3 - third person model
317  *      tags:
318  *        shot = muzzle end (for muzzle flashes)
319  *    g_tuba.md3 - pickup model
320  */
321
322 // writes:
323 //   self.origin, self.angles
324 //   self.weaponentity
325 //   self.movedir, self.view_ofs
326 //   attachment stuff
327 //   anim stuff
328 // to free:
329 //   call again with ""
330 //   remove the ent
331 void CL_WeaponEntity_SetModel(string name)
332 {
333         float v_shot_idx;
334         if (name != "")
335         {
336                 // if there is a child entity, hide it until we're sure we use it
337                 if (self.weaponentity)
338                         self.weaponentity.model = "";
339                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
340                 v_shot_idx = gettagindex(self, "shot"); // used later
341                 if(!v_shot_idx)
342                         v_shot_idx = gettagindex(self, "tag_shot");
343
344                 setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
345                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
346                 self.anim_fire1  = animfixfps(self, '0 1 0.01', '0 0 0');
347                 self.anim_fire2  = animfixfps(self, '1 1 0.01', '0 0 0');
348                 self.anim_idle   = animfixfps(self, '2 1 0.01', '0 0 0');
349                 self.anim_reload = animfixfps(self, '3 1 0.01', '0 0 0');
350
351                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
352                 // if we don't, this is a "real" animated model
353                 if(gettagindex(self, "weapon"))
354                 {
355                         if (!self.weaponentity)
356                                 self.weaponentity = spawn();
357                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
358                         setattachment(self.weaponentity, self, "weapon");
359                 }
360                 else if(gettagindex(self, "tag_weapon"))
361                 {
362                         if (!self.weaponentity)
363                                 self.weaponentity = spawn();
364                         setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
365                         setattachment(self.weaponentity, self, "tag_weapon");
366                 }
367                 else
368                 {
369                         if(self.weaponentity)
370                                 remove(self.weaponentity);
371                         self.weaponentity = world;
372                 }
373
374                 setorigin(self,'0 0 0');
375                 self.angles = '0 0 0';
376                 self.frame = 0;
377                 self.viewmodelforclient = world;
378
379                 float idx;
380
381                 if(v_shot_idx) // v_ model attached to invisible h_ model
382                 {
383                         self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
384                 }
385                 else
386                 {
387                         idx = gettagindex(self, "shot");
388                         if(!idx)
389                                 idx = gettagindex(self, "tag_shot");
390                         if(idx)
391                                 self.movedir = gettaginfo(self, idx);
392                         else
393                         {
394                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
395                                 self.movedir = '0 0 0';
396                         }
397                 }
398
399                 if(self.weaponentity) // v_ model attached to invisible h_ model
400                 {
401                         idx = gettagindex(self.weaponentity, "shell");
402                         if(!idx)
403                                 idx = gettagindex(self.weaponentity, "tag_shell");
404                         if(idx)
405                                 self.spawnorigin = gettaginfo(self.weaponentity, idx);
406                 }
407                 else
408                         idx = 0;
409                 if(!idx)
410                 {
411                         idx = gettagindex(self, "shell");
412                         if(!idx)
413                                 idx = gettagindex(self, "tag_shell");
414                         if(idx)
415                                 self.spawnorigin = gettaginfo(self, idx);
416                         else
417                         {
418                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
419                                 self.spawnorigin = self.movedir;
420                         }
421                 }
422
423                 if(v_shot_idx)
424                 {
425                         self.oldorigin = '0 0 0'; // use regular attachment
426                 }
427                 else
428                 {
429                         if(self.weaponentity)
430                         {
431                                 idx = gettagindex(self, "weapon");
432                                 if(!idx)
433                                         idx = gettagindex(self, "tag_weapon");
434                         }
435                         else
436                         {
437                                 idx = gettagindex(self, "handle");
438                                 if(!idx)
439                                         idx = gettagindex(self, "tag_handle");
440                         }
441                         if(idx)
442                         {
443                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
444                         }
445                         else
446                         {
447                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
448                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
449                         }
450                 }
451
452                 self.viewmodelforclient = self.owner;
453         }
454         else
455         {
456                 self.model = "";
457                 if(self.weaponentity)
458                         remove(self.weaponentity);
459                 self.weaponentity = world;
460                 self.movedir = '0 0 0';
461                 self.spawnorigin = '0 0 0';
462                 self.oldorigin = '0 0 0';
463                 self.anim_fire1  = '0 1 0.01';
464                 self.anim_fire2  = '0 1 0.01';
465                 self.anim_idle   = '0 1 0.01';
466                 self.anim_reload = '0 1 0.01';
467         }
468
469         self.view_ofs = '0 0 0';
470
471         if(self.movedir_x >= 0)
472         {
473                 vector v0;
474                 v0 = self.movedir;
475                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
476                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
477         }
478         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
479         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
480
481         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
482
483         // check if an instant weapon switch occurred
484         setorigin(self, self.view_ofs);
485         // reset animstate now
486         self.wframe = WFRAME_IDLE;
487         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
488 }
489
490 vector CL_Weapon_GetShotOrg(float wpn)
491 {
492         entity wi, oldself;
493         vector ret;
494         wi = get_weaponinfo(wpn);
495         oldself = self;
496         self = spawn();
497         CL_WeaponEntity_SetModel(wi.mdl);
498         ret = self.movedir;
499         CL_WeaponEntity_SetModel("");
500         remove(self);
501         self = oldself;
502         return ret;
503 }
504
505 void CL_Weaponentity_Think()
506 {
507         float tb;
508         self.nextthink = time;
509         if (intermission_running)
510                 self.frame = self.anim_idle_x;
511         if (self.owner.weaponentity != self)
512         {
513                 if (self.weaponentity)
514                         remove(self.weaponentity);
515                 remove(self);
516                 return;
517         }
518         if (self.owner.deadflag != DEAD_NO)
519         {
520                 self.model = "";
521                 if (self.weaponentity)
522                         self.weaponentity.model = "";
523                 return;
524         }
525         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
526         {
527                 self.weaponname = self.owner.weaponname;
528                 self.dmg = self.owner.modelindex;
529                 self.deadflag = self.owner.deadflag;
530
531                 CL_WeaponEntity_SetModel(self.owner.weaponname);
532         }
533
534         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
535         self.effects = self.owner.effects & EFMASK_CHEAP;
536         self.effects &~= EF_LOWPRECISION;
537         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
538         self.effects &~= EF_TELEPORT_BIT;
539         self.effects &~= EF_RESTARTANIM_BIT;
540         self.effects |= tb;
541
542         if(self.owner.alpha == default_player_alpha)
543                 self.alpha = default_weapon_alpha;
544         else if(self.owner.alpha != 0)
545                 self.alpha = self.owner.alpha;
546         else
547                 self.alpha = 1;
548
549         self.glowmod = self.owner.weaponentity_glowmod;
550         self.colormap = self.owner.colormap;
551         if (self.weaponentity)
552         {
553                 self.weaponentity.effects = self.effects;
554                 self.weaponentity.alpha = self.alpha;
555                 self.weaponentity.colormap = self.colormap;
556                 self.weaponentity.glowmod = self.glowmod;
557         }
558
559         self.angles = '0 0 0';
560         float f;
561         if (self.state == WS_RAISE && !intermission_running)
562         {
563                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
564                 self.angles_x = -90 * f * f;
565         }
566         else if (self.state == WS_DROP && !intermission_running)
567         {
568                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
569                 self.angles_x = -90 * f * f;
570         }
571         else if (self.state == WS_CLEAR)
572         {
573                 f = 1;
574                 self.angles_x = -90 * f * f;
575         }
576 }
577
578 void CL_ExteriorWeaponentity_Think()
579 {
580         float tag_found;
581         self.nextthink = time;
582         if (self.owner.exteriorweaponentity != self)
583         {
584                 remove(self);
585                 return;
586         }
587         if (self.owner.deadflag != DEAD_NO)
588         {
589                 self.model = "";
590                 return;
591         }
592         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
593         {
594                 self.weaponname = self.owner.weaponname;
595                 self.dmg = self.owner.modelindex;
596                 self.deadflag = self.owner.deadflag;
597                 if (self.owner.weaponname != "")
598                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
599                 else
600                         self.model = "";
601
602                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
603                 {
604                         self.tag_index = tag_found;
605                         self.tag_entity = self.owner;
606                 }
607                 else
608                         setattachment(self, self.owner, "bip01 r hand");
609         }
610         self.effects = self.owner.effects;
611         self.effects |= EF_LOWPRECISION;
612         self.effects = self.effects & EFMASK_CHEAP; // eat performance
613         if(self.owner.alpha == default_player_alpha)
614                 self.alpha = default_weapon_alpha;
615         else if(self.owner.alpha != 0)
616                 self.alpha = self.owner.alpha;
617         else
618                 self.alpha = 1;
619
620         self.glowmod = self.owner.weaponentity_glowmod;
621         self.colormap = self.owner.colormap;
622
623         CSQCMODEL_AUTOUPDATE();
624 }
625
626 // spawning weaponentity for client
627 void CL_SpawnWeaponentity()
628 {
629         self.weaponentity = spawn();
630         self.weaponentity.classname = "weaponentity";
631         self.weaponentity.solid = SOLID_NOT;
632         self.weaponentity.owner = self;
633         setmodel(self.weaponentity, ""); // precision set when changed
634         setorigin(self.weaponentity, '0 0 0');
635         self.weaponentity.angles = '0 0 0';
636         self.weaponentity.viewmodelforclient = self;
637         self.weaponentity.flags = 0;
638         self.weaponentity.think = CL_Weaponentity_Think;
639         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
640         self.weaponentity.nextthink = time;
641
642         self.exteriorweaponentity = spawn();
643         self.exteriorweaponentity.classname = "exteriorweaponentity";
644         self.exteriorweaponentity.solid = SOLID_NOT;
645         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
646         self.exteriorweaponentity.owner = self;
647         setorigin(self.exteriorweaponentity, '0 0 0');
648         self.exteriorweaponentity.angles = '0 0 0';
649         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
650         self.exteriorweaponentity.nextthink = time;
651
652         {
653                 entity oldself = self;
654                 self = self.exteriorweaponentity;
655                 CSQCMODEL_AUTOINIT();
656                 self = oldself;
657         }
658 }
659
660 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
661 {
662         msg_entity = e;
663         WriteByte(MSG_ONE, SVC_TEMPENTITY);
664         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
665         WriteByte(MSG_ONE, wpn);
666         WriteString(MSG_ONE, wpnname);
667         WriteByte(MSG_ONE, type);
668 }
669
670 .float hasweapon_complain_spam;
671
672 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
673 {
674         float f;
675         entity oldself;
676
677         if(time < self.hasweapon_complain_spam)
678                 complain = 0;
679         if(complain)
680                 self.hasweapon_complain_spam = time + 0.2;
681
682         if (wpn < WEP_FIRST || wpn > WEP_LAST)
683         {
684                 if (complain)
685                         sprint(self, "Invalid weapon\n");
686                 return FALSE;
687         }
688         if (WEPSET_CONTAINS_EW(cl, wpn))
689         {
690                 if (andammo)
691                 {
692                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
693                         {
694                                 f = 1;
695                         }
696                         else
697                         {
698                                 oldself = self;
699                                 self = cl;
700                                 f = weapon_action(wpn, WR_CHECKAMMO1);
701                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
702
703                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
704                                 entity mine;
705                                 if(wpn == WEP_MINE_LAYER)
706                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
707                                         f = 1;
708
709                                 self = oldself;
710                         }
711                         if (!f)
712                         {
713                                 if (complain)
714                                 if(IS_REAL_CLIENT(cl))
715                                 {
716                                         play2(cl, "weapons/unavailable.wav");
717                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
718                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
719                                 }
720                                 return FALSE;
721                         }
722                 }
723                 return TRUE;
724         }
725         if (complain)
726         {
727                 // DRESK - 3/16/07
728                 // Report Proper Weapon Status / Modified Weapon Ownership Message
729                 if (WEPSET_CONTAINS_AW(weaponsInMap, wpn))
730                 {
731                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
732                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
733
734                         if(autocvar_g_showweaponspawns)
735                         {
736                                 entity e;
737                                 string s;
738
739                                 e = get_weaponinfo(wpn);
740                                 s = e.model2;
741
742                                 for(e = world; (e = findfloat(e, weapon, wpn)); )
743                                 {
744                                         if(e.classname == "droppedweapon")
745                                                 continue;
746                                         if not(e.flags & FL_ITEM)
747                                                 continue;
748                                         WaypointSprite_Spawn(
749                                                 s,
750                                                 1, 0,
751                                                 world, e.origin,
752                                                 self, 0,
753                                                 world, enemy,
754                                                 0,
755                                                 RADARICON_NONE, '0 0 0'
756                                         );
757                                 }
758                         }
759                 }
760                 else
761                 {
762                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
763                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
764                 }
765
766                 play2(cl, "weapons/unavailable.wav");
767         }
768         return FALSE;
769 }
770
771 // Weapon subs
772 void w_clear()
773 {
774         if (self.weapon != -1)
775         {
776                 self.weapon = 0;
777                 self.switchingweapon = 0;
778         }
779         if (self.weaponentity)
780         {
781                 self.weaponentity.state = WS_CLEAR;
782                 self.weaponentity.effects = 0;
783         }
784 }
785
786 void w_ready()
787 {
788         if (self.weaponentity)
789                 self.weaponentity.state = WS_READY;
790         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
791 }
792
793 // Setup weapon for client (after this raise frame will be launched)
794 void weapon_setup(float windex)
795 {
796         entity e;
797         e = get_weaponinfo(windex);
798         self.items &~= IT_AMMO;
799         self.items = self.items | (e.items & IT_AMMO);
800
801         // the two weapon entities will notice this has changed and update their models
802         self.weapon = windex;
803         self.switchingweapon = windex; // to make sure
804         self.weaponname = e.mdl;
805         self.bulletcounter = 0;
806 }
807
808 // perform weapon to attack (weaponstate and attack_finished check is here)
809 void W_SwitchToOtherWeapon(entity pl)
810 {
811         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
812         float w, ww;
813         w = pl.weapon;
814         if(WEPSET_CONTAINS_EW(pl, w))
815         {
816                 WEPSET_ANDNOT_EW(pl, w);
817                 ww = w_getbestweapon(pl);
818                 WEPSET_OR_EW(pl, w);
819         }
820         else
821                 ww = w_getbestweapon(pl);
822         if(ww)
823                 W_SwitchWeapon_Force(pl, ww);
824 }
825
826 string PrimaryOrSecondary(float secondary)
827 {
828         if(secondary)
829                 return "secondary";
830         else
831                 return "primary";
832 }
833
834 .float prevdryfire;
835 .float prevwarntime;
836 float weapon_prepareattack_checkammo(float secondary)
837 {
838         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
839         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
840         {
841                 // always keep the Mine Layer if we placed mines, so that we can detonate them
842                 entity mine;
843                 if(self.weapon == WEP_MINE_LAYER)
844                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
845                         return FALSE;
846
847                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
848                 {
849                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
850                         self.prevdryfire = time;
851                 }
852
853                 if(weapon_action(self.weapon, WR_CHECKAMMO2 - secondary)) // check if the other firing mode has enough ammo
854                 {
855                         if(time - self.prevwarntime > 1)
856                         {
857                                 sprint(self, strcat("^2", W_Name(self.weapon), " ", PrimaryOrSecondary(secondary), "^7 is unable to fire, but its ^2", PrimaryOrSecondary(1 - secondary), "^7 can.\n"));
858                         }
859                         self.prevwarntime = time;
860                 }
861                 else // this weapon is totally unable to fire, switch to another one
862                 {
863                         W_SwitchToOtherWeapon(self);
864                 }
865                 
866                 return FALSE;
867         }
868         return TRUE;
869 }
870 .float race_penalty;
871 float weapon_prepareattack_check(float secondary, float attacktime)
872 {
873         if(!weapon_prepareattack_checkammo(secondary))
874                 return FALSE;
875
876         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
877         //if all players readied up and the countdown is running
878         if(time < game_starttime || time < self.race_penalty) {
879                 return FALSE;
880         }
881
882         if (timeout_status == TIMEOUT_ACTIVE) //don't allow the player to shoot while game is paused
883                 return FALSE;
884
885         // do not even think about shooting if switching
886         if(self.switchweapon != self.weapon)
887                 return FALSE;
888
889         if(attacktime >= 0)
890         {
891                 // don't fire if previous attack is not finished
892                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
893                         return FALSE;
894                 // don't fire while changing weapon
895                 if (self.weaponentity.state != WS_READY)
896                         return FALSE;
897         }
898
899         return TRUE;
900 }
901 float weapon_prepareattack_do(float secondary, float attacktime)
902 {
903         self.weaponentity.state = WS_INUSE;
904
905         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
906
907         // if the weapon hasn't been firing continuously, reset the timer
908         if(attacktime >= 0)
909         {
910                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
911                 {
912                         ATTACK_FINISHED(self) = time;
913                         //dprint("resetting attack finished to ", ftos(time), "\n");
914                 }
915                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
916         }
917         self.bulletcounter += 1;
918         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
919         return TRUE;
920 }
921 float weapon_prepareattack(float secondary, float attacktime)
922 {
923         if(weapon_prepareattack_check(secondary, attacktime))
924         {
925                 weapon_prepareattack_do(secondary, attacktime);
926                 return TRUE;
927         }
928         else
929                 return FALSE;
930 }
931
932 void weapon_thinkf(float fr, float t, void() func)
933 {
934         vector a;
935         vector of, or, ou;
936         float restartanim;
937
938         if(fr == WFRAME_DONTCHANGE)
939         {
940                 fr = self.weaponentity.wframe;
941                 restartanim = FALSE;
942         }
943         else if (fr == WFRAME_IDLE)
944                 restartanim = FALSE;
945         else
946                 restartanim = TRUE;
947
948         of = v_forward;
949         or = v_right;
950         ou = v_up;
951
952         if (self.weaponentity)
953         {
954                 self.weaponentity.wframe = fr;
955                 a = '0 0 0';
956                 if (fr == WFRAME_IDLE)
957                         a = self.weaponentity.anim_idle;
958                 else if (fr == WFRAME_FIRE1)
959                         a = self.weaponentity.anim_fire1;
960                 else if (fr == WFRAME_FIRE2)
961                         a = self.weaponentity.anim_fire2;
962                 else // if (fr == WFRAME_RELOAD)
963                         a = self.weaponentity.anim_reload;
964                 a_z *= g_weaponratefactor;
965                 setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
966         }
967
968         v_forward = of;
969         v_right = or;
970         v_up = ou;
971
972         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
973         {
974                 backtrace("Tried to override initial weapon think function - should this really happen?");
975         }
976
977         t *= W_WeaponRateFactor();
978
979         // VorteX: haste can be added here
980         if (self.weapon_think == w_ready)
981         {
982                 self.weapon_nextthink = time;
983                 //dprint("started firing at ", ftos(time), "\n");
984         }
985         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
986         {
987                 self.weapon_nextthink = time;
988                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
989         }
990         self.weapon_nextthink = self.weapon_nextthink + t;
991         self.weapon_think = func;
992         //dprint("next ", ftos(self.weapon_nextthink), "\n");
993
994         if((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
995         {
996                 if(self.weapon == WEP_SHOTGUN && fr == WFRAME_FIRE2)
997                         animdecide_setaction(self, ANIMACTION_MELEE, restartanim);
998                 else
999                         animdecide_setaction(self, ANIMACTION_SHOOT, restartanim);
1000         }
1001         else
1002         {
1003                 if(self.anim_upper_action == ANIMACTION_SHOOT || self.anim_upper_action == ANIMACTION_MELEE)
1004                         self.anim_upper_action = 0;
1005         }
1006 }
1007
1008 void weapon_boblayer1(float spd, vector org)
1009 {
1010         // VorteX: haste can be added here
1011 }
1012
1013 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1014 {
1015         vector mdirection;
1016         float mspeed;
1017         vector outvelocity;
1018
1019         mvelocity = mvelocity * g_weaponspeedfactor;
1020
1021         mdirection = normalize(mvelocity);
1022         mspeed = vlen(mvelocity);
1023
1024         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
1025
1026         return outvelocity;
1027 }
1028
1029 void W_AttachToShotorg(entity flash, vector offset)
1030 {
1031         entity xflash;
1032         flash.owner = self;
1033         flash.angles_z = random() * 360;
1034
1035         if(gettagindex(self.weaponentity, "shot"))
1036                 setattachment(flash, self.weaponentity, "shot");
1037         else
1038                 setattachment(flash, self.weaponentity, "tag_shot");
1039         setorigin(flash, offset);
1040
1041         xflash = spawn();
1042         copyentity(flash, xflash);
1043
1044         flash.viewmodelforclient = self;
1045
1046         if(self.weaponentity.oldorigin_x > 0)
1047         {
1048                 setattachment(xflash, self.exteriorweaponentity, "");
1049                 setorigin(xflash, self.weaponentity.oldorigin + offset);
1050         }
1051         else
1052         {
1053                 if(gettagindex(self.exteriorweaponentity, "shot"))
1054                         setattachment(xflash, self.exteriorweaponentity, "shot");
1055                 else
1056                         setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1057                 setorigin(xflash, offset);
1058         }
1059 }
1060
1061 vector cliptoplane(vector v, vector p)
1062 {
1063         return v - (v * p) * p;
1064 }
1065
1066 vector solve_cubic_pq(float p, float q)
1067 {
1068         float D, u, v, a;
1069         D = q*q/4.0 + p*p*p/27.0;
1070         if(D < 0)
1071         {
1072                 // irreducibilis
1073                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1074                 u = sqrt(-4.0/3.0 * p);
1075                 // a in range 0..pi/3
1076                 // cos(a)
1077                 // cos(a + 2pi/3)
1078                 // cos(a + 4pi/3)
1079                 return
1080                         u *
1081                         (
1082                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1083                                 +
1084                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1085                                 +
1086                                 '0 0 1' * cos(a)
1087                         );
1088         }
1089         else if(D == 0)
1090         {
1091                 // simple
1092                 if(p == 0)
1093                         return '0 0 0';
1094                 u = 3*q/p;
1095                 v = -u/2;
1096                 if(u >= v)
1097                         return '1 1 0' * v + '0 0 1' * u;
1098                 else
1099                         return '0 1 1' * v + '1 0 0' * u;
1100         }
1101         else
1102         {
1103                 // cardano
1104                 u = cbrt(-q/2.0 + sqrt(D));
1105                 v = cbrt(-q/2.0 - sqrt(D));
1106                 return '1 1 1' * (u + v);
1107         }
1108 }
1109 vector solve_cubic_abcd(float a, float b, float c, float d)
1110 {
1111         // y = 3*a*x + b
1112         // x = (y - b) / 3a
1113         float p, q;
1114         vector v;
1115         p = (9*a*c - 3*b*b);
1116         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1117         v = solve_cubic_pq(p, q);
1118         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1119         if(a < 0)
1120                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1121         return v;
1122 }
1123
1124 vector findperpendicular(vector v)
1125 {
1126         vector p;
1127         p_x = v_z;
1128         p_y = -v_x;
1129         p_z = v_y;
1130         return normalize(cliptoplane(p, v));
1131 }
1132
1133 vector W_CalculateProjectileSpread(vector forward, float spread)
1134 {
1135         float sigma;
1136         vector v1 = '0 0 0', v2;
1137         float dx, dy, r;
1138         float sstyle;
1139         spread *= g_weaponspreadfactor;
1140         if(spread <= 0)
1141                 return forward;
1142         sstyle = autocvar_g_projectiles_spread_style;
1143         
1144         if(sstyle == 0)
1145         {
1146                 // this is the baseline for the spread value!
1147                 // standard deviation: sqrt(2/5)
1148                 // density function: sqrt(1-r^2)
1149                 return forward + randomvec() * spread;
1150         }
1151         else if(sstyle == 1)
1152         {
1153                 // same thing, basically
1154                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1155         }
1156         else if(sstyle == 2)
1157         {
1158                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1159                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1160                 v1 = findperpendicular(forward);
1161                 v2 = cross(forward, v1);
1162                 // random point on unit circle
1163                 dx = random() * 2 * M_PI;
1164                 dy = sin(dx);
1165                 dx = cos(dx);
1166                 // radius in our dist function
1167                 r = random();
1168                 r = sqrt(r);
1169                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1170         }
1171         else if(sstyle == 3) // gauss 3d
1172         {
1173                 sigma = spread * 0.44721359549996; // match baseline stddev
1174                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1175                 v1 = forward;
1176                 v1_x += gsl_ran_gaussian(sigma);
1177                 v1_y += gsl_ran_gaussian(sigma);
1178                 v1_z += gsl_ran_gaussian(sigma);
1179                 return v1;
1180         }
1181         else if(sstyle == 4) // gauss 2d
1182         {
1183                 sigma = spread * 0.44721359549996; // match baseline stddev
1184                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1185                 v1_x = gsl_ran_gaussian(sigma);
1186                 v1_y = gsl_ran_gaussian(sigma);
1187                 v1_z = gsl_ran_gaussian(sigma);
1188                 return normalize(forward + cliptoplane(v1, forward));
1189         }
1190         else if(sstyle == 5) // 1-r
1191         {
1192                 sigma = spread * 1.154700538379252; // match baseline stddev
1193                 v1 = findperpendicular(forward);
1194                 v2 = cross(forward, v1);
1195                 // random point on unit circle
1196                 dx = random() * 2 * M_PI;
1197                 dy = sin(dx);
1198                 dx = cos(dx);
1199                 // radius in our dist function
1200                 r = random();
1201                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1202                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1203         }
1204         else if(sstyle == 6) // 1-r^2
1205         {
1206                 sigma = spread * 1.095445115010332; // match baseline stddev
1207                 v1 = findperpendicular(forward);
1208                 v2 = cross(forward, v1);
1209                 // random point on unit circle
1210                 dx = random() * 2 * M_PI;
1211                 dy = sin(dx);
1212                 dx = cos(dx);
1213                 // radius in our dist function
1214                 r = random();
1215                 r = sqrt(1 - r);
1216                 r = sqrt(1 - r);
1217                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1218         }
1219         else if(sstyle == 7) // (1-r) (2-r)
1220         {
1221                 sigma = spread * 1.224744871391589; // match baseline stddev
1222                 v1 = findperpendicular(forward);
1223                 v2 = cross(forward, v1);
1224                 // random point on unit circle
1225                 dx = random() * 2 * M_PI;
1226                 dy = sin(dx);
1227                 dx = cos(dx);
1228                 // radius in our dist function
1229                 r = random();
1230                 r = 1 - sqrt(r);
1231                 r = 1 - sqrt(r);
1232                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1233         }
1234         else
1235                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1236         return '0 0 0';
1237         /*
1238          * how to derive falloff functions:
1239          * rho(r) := (2-r) * (1-r);
1240          * a : 0;
1241          * b : 1;
1242          * rhor(r) := r * rho(r);
1243          * cr(t) := integrate(rhor(r), r, a, t);
1244          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1245          * variance : scr(b) / cr(b);
1246          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1247          * sqrt(0.4 / variance), numer;
1248          */
1249 }
1250
1251 #if 0
1252 float mspercallsum;
1253 float mspercallsstyle;
1254 float mspercallcount;
1255 #endif
1256 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1257 {
1258         if(missile.owner == world)
1259                 error("Unowned missile");
1260
1261         dir = dir + upDir * (pUpSpeed / pSpeed);
1262         dir_z += pZSpeed / pSpeed;
1263         pSpeed *= vlen(dir);
1264         dir = normalize(dir);
1265
1266 #if 0
1267         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1268         {
1269                 mspercallsum = mspercallcount = 0;
1270                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1271         }
1272         mspercallsum -= gettime(GETTIME_HIRES);
1273 #endif
1274         dir = W_CalculateProjectileSpread(dir, spread);
1275 #if 0
1276         mspercallsum += gettime(GETTIME_HIRES);
1277         mspercallcount += 1;
1278         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1279 #endif
1280
1281         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1282 }
1283
1284 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1285 {
1286         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1287 }
1288
1289 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1290 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1291
1292 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1293 {
1294         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1295                 return;
1296
1297         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1298         if(ammo_reload)
1299         {
1300                 self.clip_load -= ammo_use;
1301                 self.(weapon_load[self.weapon]) = self.clip_load;
1302         }
1303         else
1304                 self.(self.current_ammo) -= ammo_use;
1305 }
1306
1307 // weapon reloading code
1308
1309 .float reload_ammo_amount, reload_ammo_min, reload_time;
1310 .float reload_complain;
1311 .string reload_sound;
1312
1313 void W_ReloadedAndReady()
1314 {
1315         // finish the reloading process, and do the ammo transfer
1316
1317         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1318
1319         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1320         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1321                 self.clip_load = self.reload_ammo_amount;
1322         else
1323         {
1324                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1325                 {
1326                         self.clip_load += 1;
1327                         self.(self.current_ammo) -= 1;
1328                 }
1329         }
1330         self.(weapon_load[self.weapon]) = self.clip_load;
1331
1332         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1333         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1334         // so your weapon is disabled for a few seconds without reason
1335
1336         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1337
1338         w_ready();
1339 }
1340
1341 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1342 {
1343         // set global values to work with
1344
1345         self.reload_ammo_min = sent_ammo_min;
1346         self.reload_ammo_amount = sent_ammo_amount;
1347         self.reload_time = sent_time;
1348         self.reload_sound = sent_sound;
1349
1350         // check if we meet the necessary conditions to reload
1351
1352         entity e;
1353         e = get_weaponinfo(self.weapon);
1354
1355         // don't reload weapons that don't have the RELOADABLE flag
1356         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1357         {
1358                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1359                 return;
1360         }
1361
1362         // return if reloading is disabled for this weapon
1363         if(!self.reload_ammo_amount)
1364                 return;
1365
1366         // our weapon is fully loaded, no need to reload
1367         if (self.clip_load >= self.reload_ammo_amount)
1368                 return;
1369
1370         // no ammo, so nothing to load
1371         if(!self.(self.current_ammo) && self.reload_ammo_min)
1372         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1373         {
1374                 if(IS_REAL_CLIENT(self) && self.reload_complain < time)
1375                 {
1376                         play2(self, "weapons/unavailable.wav");
1377                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1378                         self.reload_complain = time + 1;
1379                 }
1380                 // switch away if the amount of ammo is not enough to keep using this weapon
1381                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1382                 {
1383                         self.clip_load = -1; // reload later
1384                         W_SwitchToOtherWeapon(self);
1385                 }
1386                 return;
1387         }
1388
1389         if (self.weaponentity)
1390         {
1391                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1392                         return;
1393
1394                 // allow switching away while reloading, but this will cause a new reload!
1395                 self.weaponentity.state = WS_READY;
1396         }
1397
1398         // now begin the reloading process
1399
1400         sound (self, CH_WEAPON_SINGLE, self.reload_sound, VOL_BASE, ATTN_NORM);
1401
1402         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1403         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1404         // so your weapon is disabled for a few seconds without reason
1405
1406         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1407
1408         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1409
1410         if(self.clip_load < 0)
1411                 self.clip_load = 0;
1412         self.old_clip_load = self.clip_load;
1413         self.clip_load = self.(weapon_load[self.weapon]) = -1;
1414 }