qcsrc/server/cl_player.qc

   1 .entity pusher;
   2 .float pushltime;
   3 .float istypefrag;
   4
   5 .float CopyBody_nextthink;
   6 .void(void) CopyBody_think;
   7 void CopyBody_Think(void)
   8 {
   9         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
  10         {
  11                 self.CopyBody_think();
  12                 if(wasfreed(self))
  13                         return;
  14                 self.CopyBody_nextthink = self.nextthink;
  15                 self.CopyBody_think = self.think;
  16                 self.think = CopyBody_Think;
  17         }
  18         CSQCMODEL_AUTOUPDATE();
  19         self.nextthink = time;
  20 }
  21 void CopyBody(float keepvelocity)
  22 {
  23         entity oldself;
  24         if (self.effects & EF_NODRAW)
  25                 return;
  26         oldself = self;
  27         self = spawn();
  28         self.enemy = oldself;
  29         self.lip = oldself.lip;
  30         self.colormap = oldself.colormap;
  31         self.iscreature = oldself.iscreature;
  32         self.teleportable = oldself.teleportable;
  33         self.damagedbycontents = oldself.damagedbycontents;
  34         self.angles = oldself.angles;
  35         self.v_angle = oldself.v_angle;
  36         self.avelocity = oldself.avelocity;
  37         self.classname = "body";
  38         self.damageforcescale = oldself.damageforcescale;
  39         self.effects = oldself.effects;
  40         self.glowmod = oldself.glowmod;
  41         self.event_damage = oldself.event_damage;
  42         self.anim_state = oldself.anim_state;
  43         self.anim_time = oldself.anim_time;
  44         self.anim_lower_action = oldself.anim_lower_action;
  45         self.anim_lower_time = oldself.anim_lower_time;
  46         self.anim_upper_action = oldself.anim_upper_action;
  47         self.anim_upper_time = oldself.anim_upper_time;
  48         self.anim_implicit_state = oldself.anim_implicit_state;
  49         self.anim_implicit_time = oldself.anim_implicit_time;
  50         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
  51         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
  52         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
  53         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
  54         self.dphitcontentsmask = oldself.dphitcontentsmask;
  55         self.death_time = oldself.death_time;
  56         self.pain_finished = oldself.pain_finished;
  57         self.health = oldself.health;
  58         self.armorvalue = oldself.armorvalue;
  59         self.armortype = oldself.armortype;
  60         self.model = oldself.model;
  61         self.modelindex = oldself.modelindex;
  62         self.skin = oldself.skin;
  63         self.species = oldself.species;
  64         self.movetype = oldself.movetype;
  65         self.solid = oldself.solid;
  66         self.ballistics_density = oldself.ballistics_density;
  67         self.takedamage = oldself.takedamage;
  68         self.customizeentityforclient = oldself.customizeentityforclient;
  69         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
  70         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
  71         if (keepvelocity == 1)
  72                 self.velocity = oldself.velocity;
  73         self.oldvelocity = self.velocity;
  74         self.alpha = oldself.alpha;
  75         self.fade_time = oldself.fade_time;
  76         self.fade_rate = oldself.fade_rate;
  77         //self.weapon = oldself.weapon;
  78         setorigin(self, oldself.origin);
  79         setsize(self, oldself.mins, oldself.maxs);
  80         self.prevorigin = oldself.origin;
  81         self.reset = SUB_Remove;
  82
  83         Drag_MoveDrag(oldself, self);
  84
  85         if(self.colormap <= maxclients && self.colormap > 0)
  86                 self.colormap = 1024 + oldself.clientcolors;
  87
  88         CSQCMODEL_AUTOINIT();
  89         self.CopyBody_nextthink = oldself.nextthink;
  90         self.CopyBody_think = oldself.think;
  91         self.nextthink = time;
  92         self.think = CopyBody_Think;
  93         // "bake" the current animation frame for clones (they don't get clientside animation)
  94         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
  95
  96         self = oldself;
  97 }
  98
  99 float player_getspecies()
 100 {
 101         float s;
 102         get_model_parameters(self.model, self.skin);
 103         s = get_model_parameters_species;
 104         get_model_parameters(string_null, 0);
 105         if(s < 0)
 106                 return SPECIES_HUMAN;
 107         return s;
 108 }
 109
 110 void player_setupanimsformodel()
 111 {
 112         // load animation info
 113         animdecide_init(self);
 114         animdecide_setstate(self, 0, FALSE);
 115 }
 116
 117 void player_anim (void)
 118 {
 119         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 120         if(self.deadflag && !deadbits)
 121                 if(random() < 0.5)
 122                         deadbits = ANIMSTATE_DEAD1;
 123                 else
 124                         deadbits = ANIMSTATE_DEAD2;
 125         float animbits = deadbits;
 126         if(self.frozen)
 127                 animbits |= ANIMSTATE_FROZEN;
 128         if(self.crouch)
 129                 animbits |= ANIMSTATE_DUCK;
 130         animdecide_setstate(self, animbits, FALSE);
 131         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 132
 133         if (self.weaponentity)
 134         {
 135                 updateanim(self.weaponentity);
 136                 if (!self.weaponentity.animstate_override)
 137                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 138         }
 139 }
 140
 141 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 142 {
 143         float take, save;
 144         vector v;
 145         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 146
 147         // damage resistance (ignore most of the damage from a bullet or similar)
 148         damage = max(damage - 5, 1);
 149
 150         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 151         take = v_x;
 152         save = v_y;
 153
 154         if(sound_allowed(MSG_BROADCAST, attacker))
 155         {
 156                 if (save > 10)
 157                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 158                 else if (take > 30)
 159                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 160                 else if (take > 10)
 161                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);
 162         }
 163
 164         if (take > 50)
 165                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 166         if (take > 100)
 167                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 168
 169         if (!(self.flags & FL_GODMODE))
 170         {
 171                 self.armorvalue = self.armorvalue - save;
 172                 self.health = self.health - take;
 173                 // pause regeneration for 5 seconds
 174                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 175         }
 176         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 177         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 178         self.dmg_inflictor = inflictor;
 179
 180         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 181         {
 182                 // don't use any animations as a gib
 183                 self.frame = 0;
 184                 // view just above the floor
 185                 self.view_ofs = '0 0 4';
 186
 187                 Violence_GibSplash(self, 1, 1, attacker);
 188                 self.alpha = -1;
 189                 self.solid = SOLID_NOT; // restore later
 190                 self.takedamage = DAMAGE_NO; // restore later
 191                 self.damagedbycontents = FALSE;
 192         }
 193 }
 194
 195 // g_<gametype>_str:
 196 // If 0, default is used.
 197 // If <0, 0 is used.
 198 // Otherwise, g_str (default value) is used.
 199 // For consistency, negative values there are mapped to zero too.
 200 #define GAMETYPE_DEFAULTED_SETTING(str) \
 201         ((gametype_setting_tmp = cvar(strcat("g_", GetGametype(), "_" #str))), \
 202          (gametype_setting_tmp < 0) ? 0 : \
 203          (gametype_setting_tmp == 0) ? max(0, autocvar_g_##str) : \
 204          gametype_setting_tmp)
 205
 206
 207 void calculate_player_respawn_time()
 208 {
 209         float gametype_setting_tmp;
 210         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 211         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 212         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 213         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 214         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 215         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 216
 217         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 218         entity pl;
 219         if (teamplay)
 220         {
 221                 FOR_EACH_PLAYER(pl)
 222                         if (pl != self)
 223                                 if (pl.team == self.team)
 224                                         ++pcount;
 225                 if (sdelay_small_count == 0)
 226                         sdelay_small_count = 1;
 227                 if (sdelay_large_count == 0)
 228                         sdelay_large_count = 1;
 229         }
 230         else
 231         {
 232                 FOR_EACH_PLAYER(pl)
 233                         if (pl != self)
 234                                 ++pcount;
 235                 if (sdelay_small_count == 0)
 236                 {
 237                         if (g_cts)
 238                         {
 239                                 // Players play independently. No point in requiring enemies.
 240                                 sdelay_small_count = 1;
 241                         }
 242                         else
 243                         {
 244                                 // Players play AGAINST each other. Enemies required.
 245                                 sdelay_small_count = 2;
 246                         }
 247                 }
 248                 if (sdelay_large_count == 0)
 249                 {
 250                         if (g_cts)
 251                         {
 252                                 // Players play independently. No point in requiring enemies.
 253                                 sdelay_large_count = 1;
 254                         }
 255                         else
 256                         {
 257                                 // Players play AGAINST each other. Enemies required.
 258                                 sdelay_large_count = 2;
 259                         }
 260                 }
 261         }
 262
 263         float sdelay;
 264
 265         if (pcount <= sdelay_small_count)
 266                 sdelay = sdelay_small;
 267         else if (pcount >= sdelay_large_count)
 268                 sdelay = sdelay_large;
 269         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 270                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 271
 272         if(waves)
 273                 self.respawn_time = ceil((time + sdelay) / waves) * waves;
 274         else
 275                 self.respawn_time = time + sdelay;
 276
 277         if(sdelay < sdelay_max)
 278                 self.respawn_time_max = time + sdelay_max;
 279         else
 280                 self.respawn_time_max = self.respawn_time;
 281
 282         if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 283                 self.respawn_countdown = 10; // first number to count down from is 10
 284         else
 285                 self.respawn_countdown = -1; // do not count down
 286
 287         if(autocvar_g_forced_respawn)
 288                 self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 289 }
 290
 291 void ClientKill_Now_TeamChange();
 292
 293 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 294 {
 295         float take, save, dh, da, j;
 296         vector v;
 297         float valid_damage_for_weaponstats;
 298         float excess;
 299
 300         dh = max(self.health, 0);
 301         da = max(self.armorvalue, 0);
 302
 303         if(!DEATH_ISSPECIAL(deathtype))
 304         {
 305                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 306                 if(self != attacker)
 307                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 308         }
 309
 310         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 311         {
 312                 // tuba causes blood to come out of the ears
 313                 vector ear1, ear2;
 314                 vector d;
 315                 float f;
 316                 ear1 = self.origin;
 317                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 318                 ear2 = ear1;
 319                 makevectors(self.angles);
 320                 ear1 += v_right * -10;
 321                 ear2 += v_right * +10;
 322                 d = inflictor.origin - self.origin;
 323                 if (d)
 324                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 325                 else
 326                         f = 0;  // Assum ecenter.
 327                 force = v_right * vlen(force);
 328                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 329                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 330                 if(f > 0)
 331                 {
 332                         hitloc = ear1;
 333                         force = force * -1;
 334                 }
 335                 else
 336                 {
 337                         hitloc = ear2;
 338                         // force is already good
 339                 }
 340         }
 341         else
 342                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 343
 344
 345         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 346         take = v_x;
 347         save = v_y;
 348
 349         if(attacker == self)
 350         {
 351                 // don't reset pushltime for self damage as it may be an attempt to
 352                 // escape a lava pit or similar
 353                 //self.pushltime = 0;
 354                 self.istypefrag = 0;
 355         }
 356         else if(IS_PLAYER(attacker))
 357         {
 358                 self.pusher = attacker;
 359                 self.pushltime = time + autocvar_g_maxpushtime;
 360                 self.istypefrag = self.BUTTON_CHAT;
 361         }
 362         else if(time < self.pushltime)
 363         {
 364                 attacker = self.pusher;
 365                 self.pushltime = max(self.pushltime, time + 0.6);
 366         }
 367         else
 368         {
 369                 self.pushltime = 0;
 370                 self.istypefrag = 0;
 371         }
 372
 373         frag_inflictor = inflictor;
 374         frag_attacker = attacker;
 375         frag_target = self;
 376         frag_damage = damage;
 377         damage_take = take;
 378         damage_save = save;
 379         damage_force = force;
 380         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 381         take = bound(0, damage_take, self.health);
 382         save = bound(0, damage_save, self.armorvalue);
 383         excess = max(0, damage - take - save);
 384
 385         if(sound_allowed(MSG_BROADCAST, attacker))
 386         {
 387                 if (save > 10)
 388                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 389                 else if (take > 30)
 390                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 391                 else if (take > 10)
 392                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 393         }
 394
 395         if (take > 50)
 396                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 397         if (take > 100)
 398                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 399
 400         if (time >= self.spawnshieldtime)
 401         {
 402                 if (!(self.flags & FL_GODMODE))
 403                 {
 404                         self.armorvalue = self.armorvalue - save;
 405                         self.health = self.health - take;
 406                         // pause regeneration for 5 seconds
 407                         if(take)
 408                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 409
 410                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 411                         {
 412                                 self.pain_finished = time + 0.5;        //Supajoe
 413
 414                                 if(autocvar_sv_gentle < 1) {
 415                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 416                                         {
 417                                                 if (!self.animstate_override)
 418                                                 {
 419                                                         if (random() > 0.5)
 420                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 421                                                         else
 422                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 423                                                 }
 424                                         }
 425
 426                                         if(sound_allowed(MSG_BROADCAST, attacker))
 427                                         if(!DEATH_ISWEAPON(deathtype, WEP_BLASTER) || attacker != self || self.health < 2 * WEP_CVAR_PRI(blaster, damage) * autocvar_g_balance_selfdamagepercent + 1) // WEAPONTODO: create separate limit for pain notification with laser
 428                                         if(self.health > 1)
 429                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 430                                         {
 431                                                 if(deathtype == DEATH_FALL)
 432                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 433                                                 else if(self.health > 75) // TODO make a "gentle" version?
 434                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 435                                                 else if(self.health > 50)
 436                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 437                                                 else if(self.health > 25)
 438                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 439                                                 else
 440                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 441                                         }
 442                                 }
 443
 444                                 // throw off bot aim temporarily
 445                                 float shake;
 446                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 447                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 448                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 449                         }
 450                 }
 451                 else
 452                         self.max_armorvalue += (save + take);
 453         }
 454         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 455         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 456         self.dmg_inflictor = inflictor;
 457
 458         float abot, vbot, awep;
 459         abot = (IS_BOT_CLIENT(attacker));
 460         vbot = (IS_BOT_CLIENT(self));
 461
 462         valid_damage_for_weaponstats = 0;
 463         awep = 0;
 464
 465         if(vbot || IS_REAL_CLIENT(self))
 466         if(abot || IS_REAL_CLIENT(attacker))
 467         if(attacker && self != attacker)
 468         if(DIFF_TEAM(self, attacker))
 469         {
 470                 if(DEATH_ISSPECIAL(deathtype))
 471                         awep = attacker.weapon;
 472                 else
 473                         awep = DEATH_WEAPONOF(deathtype);
 474                 valid_damage_for_weaponstats = 1;
 475         }
 476
 477         if(valid_damage_for_weaponstats)
 478         {
 479                 dh = dh - max(self.health, 0);
 480                 da = da - max(self.armorvalue, 0);
 481                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 482         }
 483
 484         if (self.health < 1)
 485         {
 486                 float defer_ClientKill_Now_TeamChange;
 487                 defer_ClientKill_Now_TeamChange = FALSE;
 488
 489                 if(self.alivetime)
 490                 {
 491                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 492                         self.alivetime = 0;
 493                 }
 494
 495                 if(valid_damage_for_weaponstats)
 496                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 497
 498                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 499                 if(sound_allowed(MSG_BROADCAST, attacker))
 500                 {
 501                         if(deathtype == DEATH_DROWN)
 502                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 503                         else
 504                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 505                 }
 506
 507                 // get rid of kill indicator
 508                 if(self.killindicator)
 509                 {
 510                         remove(self.killindicator);
 511                         self.killindicator = world;
 512                         if(self.killindicator_teamchange)
 513                                 defer_ClientKill_Now_TeamChange = TRUE;
 514
 515                         if(self.classname == "body")
 516                         if(deathtype == DEATH_KILL)
 517                         {
 518                                 // for the lemmings fans, a small harmless explosion
 519                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 520                         }
 521                 }
 522
 523                 // print an obituary message
 524                 Obituary (attacker, inflictor, self, deathtype);
 525
 526         // increment frag counter for used weapon type
 527         float w;
 528         w = DEATH_WEAPONOF(deathtype);
 529         if(WEP_VALID(w))
 530         if(accuracy_isgooddamage(attacker, self))
 531         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 532
 533                 frag_attacker = attacker;
 534                 frag_inflictor = inflictor;
 535                 frag_target = self;
 536                 frag_deathtype = deathtype;
 537                 MUTATOR_CALLHOOK(PlayerDies);
 538
 539                 WEP_ACTION(self.weapon, WR_PLAYERDEATH);
 540
 541                 RemoveGrapplingHook(self);
 542
 543                 Portal_ClearAllLater(self);
 544
 545                 self.fixangle = TRUE;
 546
 547                 if(defer_ClientKill_Now_TeamChange)
 548                         ClientKill_Now_TeamChange(); // can turn player into spectator
 549
 550                 // player could have been miraculously resuscitated ;)
 551                 // e.g. players in freezetag get frozen, they don't really die
 552                 if(self.health >= 1 || !IS_PLAYER(self))
 553                         return;
 554
 555                 // when we get here, player actually dies
 556
 557                 Unfreeze(self); // remove any icy remains
 558                 self.health = 0; // Unfreeze resets health, so we need to set it back
 559
 560                 // clear waypoints
 561                 WaypointSprite_PlayerDead();
 562                 // throw a weapon
 563                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 564
 565                 // become fully visible
 566                 self.alpha = default_player_alpha;
 567                 // make the corpse upright (not tilted)
 568                 self.angles_x = 0;
 569                 self.angles_z = 0;
 570                 // don't spin
 571                 self.avelocity = '0 0 0';
 572                 // view from the floor
 573                 self.view_ofs = '0 0 -8';
 574                 // toss the corpse
 575                 self.movetype = MOVETYPE_TOSS;
 576                 // shootable corpse
 577                 self.solid = SOLID_CORPSE;
 578                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 579                 // don't stick to the floor
 580                 self.flags &= ~FL_ONGROUND;
 581                 // dying animation
 582                 self.deadflag = DEAD_DYING;
 583                 // when to allow respawn
 584                 calculate_player_respawn_time();
 585
 586                 self.death_time = time;
 587                 if (random() < 0.5)
 588                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 589                 else
 590                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 591                 if (self.maxs_z > 5)
 592                 {
 593                         self.maxs_z = 5;
 594                         setsize(self, self.mins, self.maxs);
 595                 }
 596                 // set damage function to corpse damage
 597                 self.event_damage = PlayerCorpseDamage;
 598                 // call the corpse damage function just in case it wants to gib
 599                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 600                 // set up to fade out later
 601                 SUB_SetFade (self, time + 6 + random (), 1);
 602
 603                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 604                         // remove corpse
 605                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 606                 }
 607
 608                 // reset fields the weapons may use just in case
 609                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 610                 {
 611                         WEP_ACTION(j, WR_RESETPLAYER);
 612                         ATTACK_FINISHED_FOR(self, j) = 0;
 613                 }
 614         }
 615 }
 616
 617 .float muted; // to be used by prvm_edictset server playernumber muted 1
 618 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 619 // message "": do not say, just test flood control
 620 // return value:
 621 //   1 = accept
 622 //   0 = reject
 623 //  -1 = fake accept
 624 {
 625         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, colorprefix;
 626         float flood;
 627         var .float flood_field;
 628         entity head;
 629         float ret;
 630         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 631
 632         if(!teamsay && !privatesay)
 633                 if(substring(msgin, 0, 1) == " ")
 634                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 635
 636         msgin = formatmessage(msgin);
 637
 638         if (!IS_PLAYER(source))
 639                 colorstr = "^0"; // black for spectators
 640         else if(teamplay)
 641                 colorstr = Team_ColorCode(source.team);
 642         else
 643         {
 644                 colorstr = "";
 645                 teamsay = FALSE;
 646         }
 647
 648         if(intermission_running)
 649                 teamsay = FALSE;
 650
 651         if(msgin != "")
 652                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 653
 654         /*
 655          * using bprint solves this... me stupid
 656         // how can we prevent the message from appearing in a listen server?
 657         // for now, just give "say" back and only handle say_team
 658         if(!teamsay)
 659         {
 660                 clientcommand(self, strcat("say ", msgin));
 661                 return;
 662         }
 663         */
 664
 665         if(autocvar_g_chat_teamcolors)
 666                 namestr = playername(source);
 667         else
 668                 namestr = source.netname;
 669
 670         if(strdecolorize(namestr) == namestr)
 671                 colorprefix = "^3";
 672         else
 673                 colorprefix = "^7";
 674
 675         if(msgin != "")
 676         {
 677                 if(privatesay)
 678                 {
 679                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 680                         privatemsgprefixlen = strlen(msgstr);
 681                         msgstr = strcat(msgstr, msgin);
 682                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 683                         if(autocvar_g_chat_teamcolors)
 684                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 685                         else
 686                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 687                 }
 688                 else if(teamsay)
 689                 {
 690                         msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 691                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 692                 }
 693                 else
 694                 {
 695                         msgstr = strcat("\{1}", colorprefix, namestr, "^7: ", msgin);
 696                         cmsgstr = "";
 697                 }
 698                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 699         }
 700         else
 701         {
 702                 msgstr = cmsgstr = "";
 703         }
 704
 705         fullmsgstr = msgstr;
 706         fullcmsgstr = cmsgstr;
 707
 708         // FLOOD CONTROL
 709         flood = 0;
 710         flood_field = floodcontrol_chat;
 711         if(floodcontrol)
 712         {
 713                 float flood_spl;
 714                 float flood_burst;
 715                 float flood_lmax;
 716                 float lines;
 717                 if(privatesay)
 718                 {
 719                         flood_spl = autocvar_g_chat_flood_spl_tell;
 720                         flood_burst = autocvar_g_chat_flood_burst_tell;
 721                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 722                         flood_field = floodcontrol_chattell;
 723                 }
 724                 else if(teamsay)
 725                 {
 726                         flood_spl = autocvar_g_chat_flood_spl_team;
 727                         flood_burst = autocvar_g_chat_flood_burst_team;
 728                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 729                         flood_field = floodcontrol_chatteam;
 730                 }
 731                 else
 732                 {
 733                         flood_spl = autocvar_g_chat_flood_spl;
 734                         flood_burst = autocvar_g_chat_flood_burst;
 735                         flood_lmax = autocvar_g_chat_flood_lmax;
 736                         flood_field = floodcontrol_chat;
 737                 }
 738                 flood_burst = max(0, flood_burst - 1);
 739                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 740
 741                 // do flood control for the default line size
 742                 if(msgstr != "")
 743                 {
 744                         getWrappedLine_remaining = msgstr;
 745                         msgstr = "";
 746                         lines = 0;
 747                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 748                         {
 749                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 750                                 ++lines;
 751                         }
 752                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 753
 754                         if(getWrappedLine_remaining != "")
 755                         {
 756                                 msgstr = strcat(msgstr, "\n");
 757                                 flood = 2;
 758                         }
 759
 760                         if(time >= source.flood_field)
 761                         {
 762                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 763                         }
 764                         else
 765                         {
 766                                 flood = 1;
 767                                 msgstr = fullmsgstr;
 768                         }
 769                 }
 770                 else
 771                 {
 772                         if(time >= source.flood_field)
 773                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 774                         else
 775                                 flood = 1;
 776                 }
 777
 778                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 779                         source.flood_field = flood = 0;
 780         }
 781
 782         if(flood == 2) // cannot happen for empty msgstr
 783         {
 784                 if(autocvar_g_chat_flood_notify_flooder)
 785                 {
 786                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 787                         sourcecmsgstr = "";
 788                 }
 789                 else
 790                 {
 791                         sourcemsgstr = fullmsgstr;
 792                         sourcecmsgstr = fullcmsgstr;
 793                 }
 794                 cmsgstr = "";
 795         }
 796         else
 797         {
 798                 sourcemsgstr = msgstr;
 799                 sourcecmsgstr = cmsgstr;
 800         }
 801
 802         if(!privatesay)
 803         if (!IS_PLAYER(source))
 804         {
 805                 if (!intermission_running)
 806                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 807                                 teamsay = -1; // spectators
 808         }
 809
 810         if(flood)
 811                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 812
 813         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 814         if(privatesay)
 815                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 816
 817         if(source.muted)
 818         {
 819                 // always fake the message
 820                 ret = -1;
 821         }
 822         else if(flood == 1)
 823         {
 824                 if(autocvar_g_chat_flood_notify_flooder)
 825                 {
 826                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 827                         ret = 0;
 828                 }
 829                 else
 830                         ret = -1;
 831         }
 832         else
 833         {
 834                 ret = 1;
 835         }
 836
 837         if(sourcemsgstr != "" && ret != 0)
 838         {
 839                 if(ret < 0) // faked message, because the player is muted
 840                 {
 841                         sprint(source, sourcemsgstr);
 842                         if(sourcecmsgstr != "" && !privatesay)
 843                                 centerprint(source, sourcecmsgstr);
 844                 }
 845                 else if(privatesay) // private message, between 2 people only
 846                 {
 847                         sprint(source, sourcemsgstr);
 848                         sprint(privatesay, msgstr);
 849                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 850                         if(cmsgstr != "")
 851                                 centerprint(privatesay, cmsgstr);
 852                 }
 853                 else if(teamsay > 0) // team message, only sent to team mates
 854                 {
 855                         sprint(source, sourcemsgstr);
 856                         dedicated_print(msgstr); // send to server console too
 857                         if(sourcecmsgstr != "")
 858                                 centerprint(source, sourcecmsgstr);
 859                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 860                                 if(head != source)
 861                                 {
 862                                         sprint(head, msgstr);
 863                                         if(cmsgstr != "")
 864                                                 centerprint(head, cmsgstr);
 865                                 }
 866                 }
 867                 else if(teamsay < 0) // spectator message, only sent to spectators
 868                 {
 869                         sprint(source, sourcemsgstr);
 870                         dedicated_print(msgstr); // send to server console too
 871                         FOR_EACH_REALCLIENT(head) if (!IS_PLAYER(head))
 872                                 if(head != source)
 873                                         sprint(head, msgstr);
 874                 }
 875                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 876                 {
 877                         sprint(source, sourcemsgstr);
 878                         dedicated_print(msgstr); // send to server console too
 879                         FOR_EACH_REALCLIENT(head)
 880                                 if(head != source)
 881                                         sprint(head, msgstr);
 882                 }
 883                 else
 884                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 885         }
 886
 887         return ret;
 888 }
 889
 890 float GetVoiceMessageVoiceType(string type)
 891 {
 892         if(type == "taunt")
 893                 return VOICETYPE_TAUNT;
 894         if(type == "teamshoot")
 895                 return VOICETYPE_LASTATTACKER;
 896         return VOICETYPE_TEAMRADIO;
 897 }
 898
 899 string allvoicesamples;
 900 .string GetVoiceMessageSampleField(string type)
 901 {
 902         GetPlayerSoundSampleField_notFound = 0;
 903         switch(type)
 904         {
 905 #define _VOICEMSG(m) case #m: return playersound_##m;
 906                 ALLVOICEMSGS
 907 #undef _VOICEMSG
 908         }
 909         GetPlayerSoundSampleField_notFound = 1;
 910         return playersound_taunt;
 911 }
 912
 913 .string GetPlayerSoundSampleField(string type)
 914 {
 915         GetPlayerSoundSampleField_notFound = 0;
 916         switch(type)
 917         {
 918 #define _VOICEMSG(m) case #m: return playersound_##m;
 919                 ALLPLAYERSOUNDS
 920 #undef _VOICEMSG
 921         }
 922         GetPlayerSoundSampleField_notFound = 1;
 923         return playersound_taunt;
 924 }
 925
 926 void PrecacheGlobalSound(string samplestring)
 927 {
 928         float n, i;
 929         tokenize_console(samplestring);
 930         n = stof(argv(1));
 931         if(n > 0)
 932         {
 933                 for(i = 1; i <= n; ++i)
 934                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 935         }
 936         else
 937         {
 938                 precache_sound(strcat(argv(0), ".wav"));
 939         }
 940 }
 941
 942 void PrecachePlayerSounds(string f)
 943 {
 944         float fh;
 945         string s;
 946         fh = fopen(f, FILE_READ);
 947         if(fh < 0)
 948                 return;
 949         while((s = fgets(fh)))
 950         {
 951                 if(tokenize_console(s) != 3)
 952                 {
 953                         dprint("Invalid sound info line: ", s, "\n");
 954                         continue;
 955                 }
 956                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 957         }
 958         fclose(fh);
 959
 960         if (!allvoicesamples)
 961         {
 962 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
 963                 ALLVOICEMSGS
 964 #undef _VOICEMSG
 965                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
 966         }
 967 }
 968
 969 void ClearPlayerSounds()
 970 {
 971 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
 972         ALLPLAYERSOUNDS
 973         ALLVOICEMSGS
 974 #undef _VOICEMSG
 975 }
 976
 977 float LoadPlayerSounds(string f, float first)
 978 {
 979         float fh;
 980         string s;
 981         var .string field;
 982         fh = fopen(f, FILE_READ);
 983         if(fh < 0)
 984         {
 985                 dprint("Player sound file not found: ", f, "\n");
 986                 return 0;
 987         }
 988         while((s = fgets(fh)))
 989         {
 990                 if(tokenize_console(s) != 3)
 991                         continue;
 992                 field = GetPlayerSoundSampleField(argv(0));
 993                 if(GetPlayerSoundSampleField_notFound)
 994                         field = GetVoiceMessageSampleField(argv(0));
 995                 if(GetPlayerSoundSampleField_notFound)
 996                         continue;
 997                 if(self.field)
 998                         strunzone(self.field);
 999                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1000         }
1001         fclose(fh);
1002         return 1;
1003 }
1004
1005 .float modelindex_for_playersound;
1006 .float skin_for_playersound;
1007 void UpdatePlayerSounds()
1008 {
1009         if(self.modelindex == self.modelindex_for_playersound)
1010         if(self.skin == self.skin_for_playersound)
1011                 return;
1012         self.modelindex_for_playersound = self.modelindex;
1013         self.skin_for_playersound = self.skin;
1014         ClearPlayerSounds();
1015         LoadPlayerSounds("sound/player/default.sounds", 1);
1016         if(!autocvar_g_debug_defaultsounds)
1017                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1018                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1019 }
1020
1021 void FakeGlobalSound(string sample, float chan, float voicetype)
1022 {
1023         float n;
1024         float tauntrand;
1025
1026         if(sample == "")
1027                 return;
1028
1029         tokenize_console(sample);
1030         n = stof(argv(1));
1031         if(n > 0)
1032                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1033         else
1034                 sample = strcat(argv(0), ".wav"); // randomization
1035
1036         switch(voicetype)
1037         {
1038                 case VOICETYPE_LASTATTACKER_ONLY:
1039                         break;
1040                 case VOICETYPE_LASTATTACKER:
1041                         if(self.pusher)
1042                         {
1043                                 msg_entity = self;
1044                                 if(IS_REAL_CLIENT(msg_entity))
1045                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1046                         }
1047                         break;
1048                 case VOICETYPE_TEAMRADIO:
1049                         msg_entity = self;
1050                         if(msg_entity.cvar_cl_voice_directional == 1)
1051                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1052                         else
1053                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1054                         break;
1055                 case VOICETYPE_AUTOTAUNT:
1056                         if(!sv_autotaunt)
1057                                 break;
1058                         if(!sv_taunt)
1059                                 break;
1060                         if(autocvar_sv_gentle)
1061                                 break;
1062                         tauntrand = random();
1063                         msg_entity = self;
1064                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1065                         {
1066                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1067                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1068                                 else
1069                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1070                         }
1071                         break;
1072                 case VOICETYPE_TAUNT:
1073                         if(IS_PLAYER(self))
1074                                 if(self.deadflag == DEAD_NO)
1075                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1076                         if(!sv_taunt)
1077                                 break;
1078                         if(autocvar_sv_gentle)
1079                                 break;
1080                         msg_entity = self;
1081                         if (msg_entity.cvar_cl_voice_directional >= 1)
1082                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1083                         else
1084                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1085                         break;
1086                 case VOICETYPE_PLAYERSOUND:
1087                         msg_entity = self;
1088                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NORM);
1089                         break;
1090                 default:
1091                         backtrace("Invalid voice type!");
1092                         break;
1093         }
1094 }
1095
1096 void GlobalSound(string sample, float chan, float voicetype)
1097 {
1098         float n;
1099         float tauntrand;
1100
1101         if(sample == "")
1102                 return;
1103
1104         tokenize_console(sample);
1105         n = stof(argv(1));
1106         if(n > 0)
1107                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1108         else
1109                 sample = strcat(argv(0), ".wav"); // randomization
1110
1111         switch(voicetype)
1112         {
1113                 case VOICETYPE_LASTATTACKER_ONLY:
1114                         if(self.pusher)
1115                         {
1116                                 msg_entity = self.pusher;
1117                                 if(IS_REAL_CLIENT(msg_entity))
1118                                 {
1119                                         if(msg_entity.cvar_cl_voice_directional == 1)
1120                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1121                                         else
1122                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1123                                 }
1124                         }
1125                         break;
1126                 case VOICETYPE_LASTATTACKER:
1127                         if(self.pusher)
1128                         {
1129                                 msg_entity = self.pusher;
1130                                 if(IS_REAL_CLIENT(msg_entity))
1131                                 {
1132                                         if(msg_entity.cvar_cl_voice_directional == 1)
1133                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1134                                         else
1135                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1136                                 }
1137                                 msg_entity = self;
1138                                 if(IS_REAL_CLIENT(msg_entity))
1139                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1140                         }
1141                         break;
1142                 case VOICETYPE_TEAMRADIO:
1143                         FOR_EACH_REALCLIENT(msg_entity)
1144                                 if(!teamplay || msg_entity.team == self.team)
1145                                 {
1146                                         if(msg_entity.cvar_cl_voice_directional == 1)
1147                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1148                                         else
1149                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1150                                 }
1151                         break;
1152                 case VOICETYPE_AUTOTAUNT:
1153                         if(!sv_autotaunt)
1154                                 break;
1155                         if(!sv_taunt)
1156                                 break;
1157                         if(autocvar_sv_gentle)
1158                                 break;
1159                         tauntrand = random();
1160                         FOR_EACH_REALCLIENT(msg_entity)
1161                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1162                                 {
1163                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1164                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1165                                         else
1166                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1167                                 }
1168                         break;
1169                 case VOICETYPE_TAUNT:
1170                         if(IS_PLAYER(self))
1171                                 if(self.deadflag == DEAD_NO)
1172                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1173                         if(!sv_taunt)
1174                                 break;
1175                         if(autocvar_sv_gentle)
1176                                 break;
1177                         FOR_EACH_REALCLIENT(msg_entity)
1178                         {
1179                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1180                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1181                                 else
1182                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1183                         }
1184                         break;
1185                 case VOICETYPE_PLAYERSOUND:
1186                         sound(self, chan, sample, VOL_BASE, ATTEN_NORM);
1187                         break;
1188                 default:
1189                         backtrace("Invalid voice type!");
1190                         break;
1191         }
1192 }
1193
1194 void PlayerSound(.string samplefield, float chan, float voicetype)
1195 {
1196         GlobalSound(self.samplefield, chan, voicetype);
1197 }
1198
1199 void VoiceMessage(string type, string msg)
1200 {
1201         var .string sample;
1202         float voicetype, ownteam;
1203         float flood;
1204         sample = GetVoiceMessageSampleField(type);
1205
1206         if(GetPlayerSoundSampleField_notFound)
1207         {
1208                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1209                 return;
1210         }
1211
1212         voicetype = GetVoiceMessageVoiceType(type);
1213         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1214
1215         flood = Say(self, ownteam, world, msg, 1);
1216
1217         if (flood > 0)
1218                 GlobalSound(self.sample, CH_VOICE, voicetype);
1219         else if (flood < 0)
1220                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1221 }
1222
1223 void MoveToTeam(entity client, float team_colour, float type)
1224 {
1225         float lockteams_backup;
1226
1227         lockteams_backup = lockteams;  // backup any team lock
1228
1229         lockteams = 0;  // disable locked teams
1230
1231         TeamchangeFrags(client);  // move the players frags
1232         SetPlayerColors(client, team_colour - 1);  // set the players colour
1233         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1234
1235         lockteams = lockteams_backup;  // restore the team lock
1236
1237         LogTeamchange(client.playerid, client.team, type);
1238 }