qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.anim_state = oldself.anim_state;
 165         self.anim_time = oldself.anim_time;
 166         self.anim_lower_action = oldself.anim_lower_action;
 167         self.anim_lower_time = oldself.anim_lower_time;
 168         self.anim_upper_action = oldself.anim_upper_action;
 169         self.anim_upper_time = oldself.anim_upper_time;
 170         self.anim_implicit_state = oldself.anim_implicit_state;
 171         self.anim_implicit_time = oldself.anim_implicit_time;
 172         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 173         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 174         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 175         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 176         self.dphitcontentsmask = oldself.dphitcontentsmask;
 177         self.death_time = oldself.death_time;
 178         self.pain_finished = oldself.pain_finished;
 179         self.health = oldself.health;
 180         self.armorvalue = oldself.armorvalue;
 181         self.armortype = oldself.armortype;
 182         self.model = oldself.model;
 183         self.modelindex = oldself.modelindex;
 184         self.skin = oldself.skin;
 185         self.species = oldself.species;
 186         self.movetype = oldself.movetype;
 187         self.solid = oldself.solid;
 188         self.ballistics_density = oldself.ballistics_density;
 189         self.takedamage = oldself.takedamage;
 190         self.customizeentityforclient = oldself.customizeentityforclient;
 191         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 192         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 193         if (keepvelocity == 1)
 194                 self.velocity = oldself.velocity;
 195         self.oldvelocity = self.velocity;
 196         self.alpha = oldself.alpha;
 197         self.fade_time = oldself.fade_time;
 198         self.fade_rate = oldself.fade_rate;
 199         //self.weapon = oldself.weapon;
 200         setorigin(self, oldself.origin);
 201         setsize(self, oldself.mins, oldself.maxs);
 202         self.prevorigin = oldself.origin;
 203         self.reset = SUB_Remove;
 204
 205         Drag_MoveDrag(oldself, self);
 206
 207         if(self.colormap <= maxclients && self.colormap > 0)
 208                 self.colormap = 1024 + oldself.clientcolors;
 209
 210         CSQCMODEL_AUTOINIT();
 211         self.CopyBody_nextthink = oldself.nextthink;
 212         self.CopyBody_think = oldself.think;
 213         self.nextthink = time;
 214         self.think = CopyBody_Think;
 215         // "bake" the current animation frame for clones (they don't get clientside animation)
 216         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 217
 218         self = oldself;
 219 }
 220
 221 float player_getspecies()
 222 {
 223         float s;
 224         get_model_parameters(self.model, self.skin);
 225         s = get_model_parameters_species;
 226         get_model_parameters(string_null, 0);
 227         if(s < 0)
 228                 return SPECIES_HUMAN;
 229         return s;
 230 }
 231
 232 void player_setupanimsformodel()
 233 {
 234         // load animation info
 235         animdecide_init(self);
 236         animdecide_setstate(self, 0, FALSE);
 237 }
 238
 239 void player_anim (void)
 240 {
 241         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 242         if(self.deadflag && !deadbits)
 243                 if(random() < 0.5)
 244                         deadbits = ANIMSTATE_DEAD1;
 245                 else
 246                         deadbits = ANIMSTATE_DEAD2;
 247         float animbits = deadbits;
 248         if(self.freezetag_frozen)
 249                 animbits |= ANIMSTATE_FROZEN;
 250         if(self.crouch)
 251                 animbits |= ANIMSTATE_DUCK;
 252         animdecide_setstate(self, animbits, FALSE);
 253         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 254
 255         if (self.weaponentity)
 256         {
 257                 updateanim(self.weaponentity);
 258                 if (!self.weaponentity.animstate_override)
 259                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 260         }
 261 }
 262
 263 void SpawnThrownWeapon (vector org, float w)
 264 {
 265         if(g_minstagib)
 266         if(self.ammo_cells <= 0)
 267                 return;
 268
 269         if(g_pinata)
 270         {
 271                 float j;
 272                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 273                 {
 274                         if(WEPSET_CONTAINS_EW(self, j))
 275                                 if(W_IsWeaponThrowable(j))
 276                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 277                 }
 278         }
 279         else
 280         {
 281                 if(W_IsWeaponThrowable(self.weapon))
 282                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 283         }
 284 }
 285
 286 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 287 {
 288         float take, save;
 289         vector v;
 290         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 291
 292         // damage resistance (ignore most of the damage from a bullet or similar)
 293         damage = max(damage - 5, 1);
 294
 295         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 296         take = v_x;
 297         save = v_y;
 298
 299         if(sound_allowed(MSG_BROADCAST, attacker))
 300         {
 301                 if (save > 10)
 302                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 303                 else if (take > 30)
 304                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 305                 else if (take > 10)
 306                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 307         }
 308
 309         if (take > 50)
 310                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 311         if (take > 100)
 312                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 313
 314         if (!(self.flags & FL_GODMODE))
 315         {
 316                 self.armorvalue = self.armorvalue - save;
 317                 self.health = self.health - take;
 318                 // pause regeneration for 5 seconds
 319                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 320         }
 321         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 322         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 323         self.dmg_inflictor = inflictor;
 324
 325         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 326         {
 327                 // don't use any animations as a gib
 328                 self.frame = 0;
 329                 // view just above the floor
 330                 self.view_ofs = '0 0 4';
 331
 332                 Violence_GibSplash(self, 1, 1, attacker);
 333                 self.alpha = -1;
 334                 self.solid = SOLID_NOT; // restore later
 335                 self.takedamage = DAMAGE_NO; // restore later
 336                 self.damagedbycontents = FALSE;
 337         }
 338 }
 339
 340 void ClientKill_Now_TeamChange();
 341
 342 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 343 {
 344         float take, save, waves, sdelay, dh, da, j;
 345         vector v;
 346         float valid_damage_for_weaponstats;
 347         float excess;
 348
 349         dh = max(self.health, 0);
 350         da = max(self.armorvalue, 0);
 351
 352         if(!DEATH_ISSPECIAL(deathtype))
 353         {
 354                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 355                 if(self != attacker)
 356                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 357         }
 358
 359         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 360         {
 361                 // tuba causes blood to come out of the ears
 362                 vector ear1, ear2;
 363                 vector d;
 364                 float f;
 365                 ear1 = self.origin;
 366                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 367                 ear2 = ear1;
 368                 makevectors(self.angles);
 369                 ear1 += v_right * -10;
 370                 ear2 += v_right * +10;
 371                 d = inflictor.origin - self.origin;
 372                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 373                 force = v_right * vlen(force);
 374                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 375                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 376                 if(f > 0)
 377                 {
 378                         hitloc = ear1;
 379                         force = force * -1;
 380                 }
 381                 else
 382                 {
 383                         hitloc = ear2;
 384                         // force is already good
 385                 }
 386         }
 387         else
 388                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 389
 390         if (!g_minstagib)
 391         {
 392                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 393                 take = v_x;
 394                 save = v_y;
 395         }
 396         else
 397         {
 398                 save = 0;
 399                 take = damage;
 400         }
 401
 402         if(attacker == self)
 403         {
 404                 // don't reset pushltime for self damage as it may be an attempt to
 405                 // escape a lava pit or similar
 406                 //self.pushltime = 0;
 407                 self.istypefrag = 0;
 408         }
 409         else if(attacker.classname == "player")
 410         {
 411                 self.pusher = attacker;
 412                 self.pushltime = time + autocvar_g_maxpushtime;
 413                 self.istypefrag = self.BUTTON_CHAT;
 414         }
 415         else if(time < self.pushltime)
 416         {
 417                 attacker = self.pusher;
 418                 self.pushltime = max(self.pushltime, time + 0.6);
 419         }
 420         else
 421         {
 422                 self.pushltime = 0;
 423                 self.istypefrag = 0;
 424         }
 425
 426         frag_inflictor = inflictor;
 427         frag_attacker = attacker;
 428         frag_target = self;
 429         damage_take = take;
 430         damage_save = save;
 431         damage_force = force;
 432         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 433         take = bound(0, damage_take, self.health);
 434         save = bound(0, damage_save, self.armorvalue);
 435         excess = max(0, damage - take - save);
 436
 437         if(sound_allowed(MSG_BROADCAST, attacker))
 438         {
 439                 if (save > 10)
 440                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 441                 else if (take > 30)
 442                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 443                 else if (take > 10)
 444                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 445         }
 446
 447         if (take > 50)
 448                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 449         if (take > 100)
 450                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 451
 452         if (time >= self.spawnshieldtime)
 453         {
 454                 if (!(self.flags & FL_GODMODE))
 455                 {
 456                         self.armorvalue = self.armorvalue - save;
 457                         self.health = self.health - take;
 458                         // pause regeneration for 5 seconds
 459                         if(take)
 460                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 461
 462                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 463                         {
 464                                 self.pain_finished = time + 0.5;        //Supajoe
 465
 466                                 if(autocvar_sv_gentle < 1) {
 467                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 468                                         {
 469                                                 if (!self.animstate_override)
 470                                                 {
 471                                                         if (random() > 0.5)
 472                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 473                                                         else
 474                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 475                                                 }
 476                                         }
 477
 478                                         if(sound_allowed(MSG_BROADCAST, attacker))
 479                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 480                                         if(self.health > 1)
 481                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 482                                         {
 483                                                 if(deathtype == DEATH_FALL)
 484                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 485                                                 else if(self.health > 75) // TODO make a "gentle" version?
 486                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 487                                                 else if(self.health > 50)
 488                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 489                                                 else if(self.health > 25)
 490                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 491                                                 else
 492                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 493                                         }
 494                                 }
 495
 496                                 // throw off bot aim temporarily
 497                                 float shake;
 498                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 499                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 500                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 501                         }
 502                 }
 503                 else
 504                         self.max_armorvalue += (save + take);
 505         }
 506         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 507         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 508         self.dmg_inflictor = inflictor;
 509
 510         if(g_ca && self != attacker && attacker.classname == "player")
 511                 PlayerScore_Add(attacker, SP_SCORE, (damage - excess) * autocvar_g_ca_damage2score_multiplier);
 512
 513         float abot, vbot, awep;
 514         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 515         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 516
 517         valid_damage_for_weaponstats = 0;
 518         awep = 0;
 519
 520         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 521         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 522         if(attacker && self != attacker)
 523         if(IsDifferentTeam(self, attacker))
 524         {
 525                 if(DEATH_ISSPECIAL(deathtype))
 526                         awep = attacker.weapon;
 527                 else
 528                         awep = DEATH_WEAPONOF(deathtype);
 529                 valid_damage_for_weaponstats = 1;
 530         }
 531
 532         if(valid_damage_for_weaponstats)
 533         {
 534                 dh = dh - max(self.health, 0);
 535                 da = da - max(self.armorvalue, 0);
 536                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 537         }
 538
 539         if (self.health < 1)
 540         {
 541                 float defer_ClientKill_Now_TeamChange;
 542                 defer_ClientKill_Now_TeamChange = FALSE;
 543
 544                 if(self.alivetime)
 545                 {
 546                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 547                         self.alivetime = 0;
 548                 }
 549
 550                 if(valid_damage_for_weaponstats)
 551                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 552
 553                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 554                 if(sound_allowed(MSG_BROADCAST, attacker))
 555                 {
 556                         if(deathtype == DEATH_DROWN)
 557                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 558                         else
 559                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 560                 }
 561
 562                 // get rid of kill indicator
 563                 if(self.killindicator)
 564                 {
 565                         remove(self.killindicator);
 566                         self.killindicator = world;
 567                         if(self.killindicator_teamchange)
 568                                 defer_ClientKill_Now_TeamChange = TRUE;
 569
 570                         if(self.classname == "body")
 571                         if(deathtype == DEATH_KILL)
 572                         {
 573                                 // for the lemmings fans, a small harmless explosion
 574                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 575                         }
 576                 }
 577
 578                 // print an obituary message
 579                 Obituary (attacker, inflictor, self, deathtype);
 580                 race_PreDie();
 581                 DropAllRunes(self);
 582
 583         // increment frag counter for used weapon type
 584         float w;
 585         w = DEATH_WEAPONOF(deathtype);
 586         if(WEP_VALID(w))
 587         if(accuracy_isgooddamage(attacker, self))
 588         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 589
 590                 frag_attacker = attacker;
 591                 frag_inflictor = inflictor;
 592                 frag_target = self;
 593                 frag_deathtype = deathtype;
 594                 MUTATOR_CALLHOOK(PlayerDies);
 595
 596                 weapon_action(self.weapon, WR_PLAYERDEATH);
 597
 598                 RemoveGrapplingHook(self);
 599
 600                 Portal_ClearAllLater(self);
 601
 602                 if(clienttype(self) == CLIENTTYPE_REAL)
 603                 {
 604                         stuffcmd(self, "-zoom\n");
 605                         self.fixangle = TRUE;
 606                         //msg_entity = self;
 607                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 608                         //WriteAngle (MSG_ONE, self.v_angle_x);
 609                         //WriteAngle (MSG_ONE, self.v_angle_y);
 610                         //WriteAngle (MSG_ONE, 80);
 611                 }
 612
 613                 if(defer_ClientKill_Now_TeamChange)
 614                         ClientKill_Now_TeamChange(); // can turn player into spectator
 615
 616                 // player could have been miraculously resuscitated ;)
 617                 // e.g. players in freezetag get frozen, they don't really die
 618                 if(self.health >= 1 || self.classname != "player")
 619                         return;
 620
 621                 // when we get here, player actually dies
 622
 623                 // clear waypoints
 624                 WaypointSprite_PlayerDead();
 625                 // throw a weapon
 626                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 627
 628                 // become fully visible
 629                 self.alpha = default_player_alpha;
 630                 // make the corpse upright (not tilted)
 631                 self.angles_x = 0;
 632                 self.angles_z = 0;
 633                 // don't spin
 634                 self.avelocity = '0 0 0';
 635                 // view from the floor
 636                 self.view_ofs = '0 0 -8';
 637                 // toss the corpse
 638                 self.movetype = MOVETYPE_TOSS;
 639                 // shootable corpse
 640                 self.solid = SOLID_CORPSE;
 641                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 642                 // don't stick to the floor
 643                 self.flags &~= FL_ONGROUND;
 644                 // dying animation
 645                 self.deadflag = DEAD_DYING;
 646                 // when to allow respawn
 647                 sdelay = 0;
 648                 waves = 0;
 649                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 650                 if(!sdelay)
 651                 {
 652                         if(g_cts)
 653                                 sdelay = 0; // no respawn delay in CTS
 654                         else
 655                                 sdelay = autocvar_g_respawn_delay;
 656                 }
 657                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 658                 if(!waves)
 659                         waves = autocvar_g_respawn_waves;
 660                 if(waves)
 661                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 662                 else
 663                         self.respawn_time = time + sdelay;
 664                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 665                         self.respawn_countdown = 10; // first number to count down from is 10
 666                 else
 667                         self.respawn_countdown = -1; // do not count down
 668                 self.death_time = time;
 669                 if (random() < 0.5)
 670                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 671                 else
 672                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 673                 if (self.maxs_z > 5)
 674                 {
 675                         self.maxs_z = 5;
 676                         setsize(self, self.mins, self.maxs);
 677                 }
 678                 // set damage function to corpse damage
 679                 self.event_damage = PlayerCorpseDamage;
 680                 // call the corpse damage function just in case it wants to gib
 681                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 682                 // set up to fade out later
 683                 SUB_SetFade (self, time + 6 + random (), 1);
 684
 685                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 686                         // remove corpse
 687                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 688                 }
 689
 690                 // reset fields the weapons may use just in case
 691                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 692                 {
 693                         weapon_action(j, WR_RESETPLAYER);
 694                         ATTACK_FINISHED_FOR(self, j) = 0;
 695                 }
 696         }
 697 }
 698
 699 .float muted; // to be used by prvm_edictset server playernumber muted 1
 700 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 701 // message "": do not say, just test flood control
 702 // return value:
 703 //   1 = accept
 704 //   0 = reject
 705 //  -1 = fake accept
 706 {
 707         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 708         float flood;
 709         var .float flood_field;
 710         entity head;
 711         float ret;
 712         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 713
 714         if(!teamsay && !privatesay)
 715                 if(substring(msgin, 0, 1) == " ")
 716                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 717
 718         msgin = formatmessage(msgin);
 719
 720         if(source.classname != "player")
 721                 colorstr = "^0"; // black for spectators
 722         else if(teamplay)
 723                 colorstr = Team_ColorCode(source.team);
 724         else
 725         {
 726                 colorstr = "";
 727                 teamsay = FALSE;
 728         }
 729
 730         if(intermission_running)
 731                 teamsay = FALSE;
 732
 733         if(msgin != "")
 734                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 735
 736         /*
 737          * using bprint solves this... me stupid
 738         // how can we prevent the message from appearing in a listen server?
 739         // for now, just give "say" back and only handle say_team
 740         if(!teamsay)
 741         {
 742                 clientcommand(self, strcat("say ", msgin));
 743                 return;
 744         }
 745         */
 746
 747         if(autocvar_g_chat_teamcolors)
 748                 namestr = playername(source);
 749         else
 750                 namestr = source.netname;
 751
 752         if(msgin != "")
 753         {
 754                 if(privatesay)
 755                 {
 756                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 757                         privatemsgprefixlen = strlen(msgstr);
 758                         msgstr = strcat(msgstr, msgin);
 759                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 760                         if(autocvar_g_chat_teamcolors)
 761                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 762                         else
 763                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 764                 }
 765                 else if(teamsay)
 766                 {
 767                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 768                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 769                 }
 770                 else
 771                 {
 772                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 773                         cmsgstr = "";
 774                 }
 775                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 776         }
 777         else
 778         {
 779                 msgstr = cmsgstr = "";
 780         }
 781
 782         fullmsgstr = msgstr;
 783         fullcmsgstr = cmsgstr;
 784
 785         // FLOOD CONTROL
 786         flood = 0;
 787         flood_field = floodcontrol_chat;
 788         if(floodcontrol)
 789         {
 790                 float flood_spl;
 791                 float flood_burst;
 792                 float flood_lmax;
 793                 float lines;
 794                 if(privatesay)
 795                 {
 796                         flood_spl = autocvar_g_chat_flood_spl_tell;
 797                         flood_burst = autocvar_g_chat_flood_burst_tell;
 798                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 799                         flood_field = floodcontrol_chattell;
 800                 }
 801                 else if(teamsay)
 802                 {
 803                         flood_spl = autocvar_g_chat_flood_spl_team;
 804                         flood_burst = autocvar_g_chat_flood_burst_team;
 805                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 806                         flood_field = floodcontrol_chatteam;
 807                 }
 808                 else
 809                 {
 810                         flood_spl = autocvar_g_chat_flood_spl;
 811                         flood_burst = autocvar_g_chat_flood_burst;
 812                         flood_lmax = autocvar_g_chat_flood_lmax;
 813                         flood_field = floodcontrol_chat;
 814                 }
 815                 flood_burst = max(0, flood_burst - 1);
 816                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 817
 818                 // do flood control for the default line size
 819                 if(msgstr != "")
 820                 {
 821                         getWrappedLine_remaining = msgstr;
 822                         msgstr = "";
 823                         lines = 0;
 824                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 825                         {
 826                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 827                                 ++lines;
 828                         }
 829                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 830
 831                         if(getWrappedLine_remaining != "")
 832                         {
 833                                 msgstr = strcat(msgstr, "\n");
 834                                 flood = 2;
 835                         }
 836
 837                         if(time >= source.flood_field)
 838                         {
 839                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 840                         }
 841                         else
 842                         {
 843                                 flood = 1;
 844                                 msgstr = fullmsgstr;
 845                         }
 846                 }
 847                 else
 848                 {
 849                         if(time >= source.flood_field)
 850                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 851                         else
 852                                 flood = 1;
 853                 }
 854
 855                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 856                         source.flood_field = flood = 0;
 857         }
 858
 859         if(flood == 2) // cannot happen for empty msgstr
 860         {
 861                 if(autocvar_g_chat_flood_notify_flooder)
 862                 {
 863                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 864                         sourcecmsgstr = "";
 865                 }
 866                 else
 867                 {
 868                         sourcemsgstr = fullmsgstr;
 869                         sourcecmsgstr = fullcmsgstr;
 870                 }
 871                 cmsgstr = "";
 872         }
 873         else
 874         {
 875                 sourcemsgstr = msgstr;
 876                 sourcecmsgstr = cmsgstr;
 877         }
 878
 879         if(!privatesay)
 880         if(source.classname != "player")
 881         {
 882                 if not(intermission_running)
 883                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 884                                 teamsay = -1; // spectators
 885         }
 886
 887         if(flood)
 888                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 889
 890         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 891         if(privatesay)
 892                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 893
 894         if(source.muted)
 895         {
 896                 // always fake the message
 897                 ret = -1;
 898         }
 899         else if(flood == 1)
 900         {
 901                 if(autocvar_g_chat_flood_notify_flooder)
 902                 {
 903                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 904                         ret = 0;
 905                 }
 906                 else
 907                         ret = -1;
 908         }
 909         else
 910         {
 911                 ret = 1;
 912         }
 913
 914         if(sourcemsgstr != "" && ret != 0)
 915         {
 916                 if(ret < 0) // faked message, because the player is muted
 917                 {
 918                         sprint(source, sourcemsgstr);
 919                         if(sourcecmsgstr != "" && !privatesay)
 920                                 centerprint(source, sourcecmsgstr);
 921                 }
 922                 else if(privatesay) // private message, between 2 people only
 923                 {
 924                         sprint(source, sourcemsgstr);
 925                         sprint(privatesay, msgstr);
 926                         if not(autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 927                         if(cmsgstr != "")
 928                                 centerprint(privatesay, cmsgstr);
 929                 }
 930                 else if(teamsay > 0) // team message, only sent to team mates
 931                 {
 932                         sprint(source, sourcemsgstr);
 933                         dedicated_print(msgstr); // send to server console too
 934                         if(sourcecmsgstr != "")
 935                                 centerprint(source, sourcecmsgstr);
 936                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 937                                 if(head != source)
 938                                 {
 939                                         sprint(head, msgstr);
 940                                         if(cmsgstr != "")
 941                                                 centerprint(head, cmsgstr);
 942                                 }
 943                 }
 944                 else if(teamsay < 0) // spectator message, only sent to spectators
 945                 {
 946                         sprint(source, sourcemsgstr);
 947                         dedicated_print(msgstr); // send to server console too
 948                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 949                                 if(head != source)
 950                                         sprint(head, msgstr);
 951                 }
 952                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 953                 {
 954                         sprint(source, sourcemsgstr);
 955                         dedicated_print(msgstr); // send to server console too
 956                         FOR_EACH_REALCLIENT(head)
 957                                 if(head != source)
 958                                         sprint(head, msgstr);
 959                 }
 960                 else
 961                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 962         }
 963
 964         return ret;
 965 }
 966
 967 float GetVoiceMessageVoiceType(string type)
 968 {
 969         if(type == "taunt")
 970                 return VOICETYPE_TAUNT;
 971         if(type == "teamshoot")
 972                 return VOICETYPE_LASTATTACKER;
 973         return VOICETYPE_TEAMRADIO;
 974 }
 975
 976 string allvoicesamples;
 977 .string GetVoiceMessageSampleField(string type)
 978 {
 979         GetPlayerSoundSampleField_notFound = 0;
 980         switch(type)
 981         {
 982 #define _VOICEMSG(m) case #m: return playersound_##m;
 983                 ALLVOICEMSGS
 984 #undef _VOICEMSG
 985         }
 986         GetPlayerSoundSampleField_notFound = 1;
 987         return playersound_taunt;
 988 }
 989
 990 .string GetPlayerSoundSampleField(string type)
 991 {
 992         GetPlayerSoundSampleField_notFound = 0;
 993         switch(type)
 994         {
 995 #define _VOICEMSG(m) case #m: return playersound_##m;
 996                 ALLPLAYERSOUNDS
 997 #undef _VOICEMSG
 998         }
 999         GetPlayerSoundSampleField_notFound = 1;
1000         return playersound_taunt;
1001 }
1002
1003 void PrecacheGlobalSound(string samplestring)
1004 {
1005         float n, i;
1006         tokenize_console(samplestring);
1007         n = stof(argv(1));
1008         if(n > 0)
1009         {
1010                 for(i = 1; i <= n; ++i)
1011                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1012         }
1013         else
1014         {
1015                 precache_sound(strcat(argv(0), ".wav"));
1016         }
1017 }
1018
1019 void PrecachePlayerSounds(string f)
1020 {
1021         float fh;
1022         string s;
1023         fh = fopen(f, FILE_READ);
1024         if(fh < 0)
1025                 return;
1026         while((s = fgets(fh)))
1027         {
1028                 if(tokenize_console(s) != 3)
1029                 {
1030                         dprint("Invalid sound info line: ", s, "\n");
1031                         continue;
1032                 }
1033                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1034         }
1035         fclose(fh);
1036
1037         if not(allvoicesamples)
1038         {
1039 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1040                 ALLVOICEMSGS
1041 #undef _VOICEMSG
1042                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1043         }
1044 }
1045
1046 void ClearPlayerSounds()
1047 {
1048 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1049         ALLPLAYERSOUNDS
1050         ALLVOICEMSGS
1051 #undef _VOICEMSG
1052 }
1053
1054 float LoadPlayerSounds(string f, float first)
1055 {
1056         float fh;
1057         string s;
1058         var .string field;
1059         fh = fopen(f, FILE_READ);
1060         if(fh < 0)
1061         {
1062                 dprint("Player sound file not found: ", f, "\n");
1063                 return 0;
1064         }
1065         while((s = fgets(fh)))
1066         {
1067                 if(tokenize_console(s) != 3)
1068                         continue;
1069                 field = GetPlayerSoundSampleField(argv(0));
1070                 if(GetPlayerSoundSampleField_notFound)
1071                         field = GetVoiceMessageSampleField(argv(0));
1072                 if(GetPlayerSoundSampleField_notFound)
1073                         continue;
1074                 if(self.field)
1075                         strunzone(self.field);
1076                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1077         }
1078         fclose(fh);
1079         return 1;
1080 }
1081
1082 .float modelindex_for_playersound;
1083 .float skin_for_playersound;
1084 void UpdatePlayerSounds()
1085 {
1086         if(self.modelindex == self.modelindex_for_playersound)
1087         if(self.skin == self.skin_for_playersound)
1088                 return;
1089         self.modelindex_for_playersound = self.modelindex;
1090         self.skin_for_playersound = self.skin;
1091         ClearPlayerSounds();
1092         LoadPlayerSounds("sound/player/default.sounds", 1);
1093         if(!autocvar_g_debug_defaultsounds)
1094                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1095                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1096 }
1097
1098 void FakeGlobalSound(string sample, float chan, float voicetype)
1099 {
1100         float n;
1101         float tauntrand;
1102
1103         if(sample == "")
1104                 return;
1105
1106         tokenize_console(sample);
1107         n = stof(argv(1));
1108         if(n > 0)
1109                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1110         else
1111                 sample = strcat(argv(0), ".wav"); // randomization
1112
1113         switch(voicetype)
1114         {
1115                 case VOICETYPE_LASTATTACKER_ONLY:
1116                         break;
1117                 case VOICETYPE_LASTATTACKER:
1118                         if(self.pusher)
1119                         {
1120                                 msg_entity = self;
1121                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1122                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1123                         }
1124                         break;
1125                 case VOICETYPE_TEAMRADIO:
1126                         msg_entity = self;
1127                         if(msg_entity.cvar_cl_voice_directional == 1)
1128                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1129                         else
1130                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1131                         break;
1132                 case VOICETYPE_AUTOTAUNT:
1133                         if(!sv_autotaunt)
1134                                 break;
1135                         if(!sv_taunt)
1136                                 break;
1137                         if(autocvar_sv_gentle)
1138                                 break;
1139                         tauntrand = random();
1140                         msg_entity = self;
1141                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1142                         {
1143                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1144                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1145                                 else
1146                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1147                         }
1148                         break;
1149                 case VOICETYPE_TAUNT:
1150                         if(self.classname == "player")
1151                                 if(self.deadflag == DEAD_NO)
1152                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1153                         if(!sv_taunt)
1154                                 break;
1155                         if(autocvar_sv_gentle)
1156                                 break;
1157                         msg_entity = self;
1158                         if (msg_entity.cvar_cl_voice_directional >= 1)
1159                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1160                         else
1161                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1162                         break;
1163                 case VOICETYPE_PLAYERSOUND:
1164                         msg_entity = self;
1165                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1166                         break;
1167                 default:
1168                         backtrace("Invalid voice type!");
1169                         break;
1170         }
1171 }
1172
1173 void GlobalSound(string sample, float chan, float voicetype)
1174 {
1175         float n;
1176         float tauntrand;
1177
1178         if(sample == "")
1179                 return;
1180
1181         tokenize_console(sample);
1182         n = stof(argv(1));
1183         if(n > 0)
1184                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1185         else
1186                 sample = strcat(argv(0), ".wav"); // randomization
1187
1188         switch(voicetype)
1189         {
1190                 case VOICETYPE_LASTATTACKER_ONLY:
1191                         if(self.pusher)
1192                         {
1193                                 msg_entity = self.pusher;
1194                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1195                                 {
1196                                         if(msg_entity.cvar_cl_voice_directional == 1)
1197                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1198                                         else
1199                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1200                                 }
1201                         }
1202                         break;
1203                 case VOICETYPE_LASTATTACKER:
1204                         if(self.pusher)
1205                         {
1206                                 msg_entity = self.pusher;
1207                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1208                                 {
1209                                         if(msg_entity.cvar_cl_voice_directional == 1)
1210                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1211                                         else
1212                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1213                                 }
1214                                 msg_entity = self;
1215                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1216                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1217                         }
1218                         break;
1219                 case VOICETYPE_TEAMRADIO:
1220                         FOR_EACH_REALCLIENT(msg_entity)
1221                                 if(!teamplay || msg_entity.team == self.team)
1222                                 {
1223                                         if(msg_entity.cvar_cl_voice_directional == 1)
1224                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1225                                         else
1226                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1227                                 }
1228                         break;
1229                 case VOICETYPE_AUTOTAUNT:
1230                         if(!sv_autotaunt)
1231                                 break;
1232                         if(!sv_taunt)
1233                                 break;
1234                         if(autocvar_sv_gentle)
1235                                 break;
1236                         tauntrand = random();
1237                         FOR_EACH_REALCLIENT(msg_entity)
1238                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1239                                 {
1240                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1241                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1242                                         else
1243                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1244                                 }
1245                         break;
1246                 case VOICETYPE_TAUNT:
1247                         if(self.classname == "player")
1248                                 if(self.deadflag == DEAD_NO)
1249                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1250                         if(!sv_taunt)
1251                                 break;
1252                         if(autocvar_sv_gentle)
1253                                 break;
1254                         FOR_EACH_REALCLIENT(msg_entity)
1255                         {
1256                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1257                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1258                                 else
1259                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1260                         }
1261                         break;
1262                 case VOICETYPE_PLAYERSOUND:
1263                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1264                         break;
1265                 default:
1266                         backtrace("Invalid voice type!");
1267                         break;
1268         }
1269 }
1270
1271 void PlayerSound(.string samplefield, float chan, float voicetype)
1272 {
1273         GlobalSound(self.samplefield, chan, voicetype);
1274 }
1275
1276 void VoiceMessage(string type, string msg)
1277 {
1278         var .string sample;
1279         float voicetype, ownteam;
1280         float flood;
1281         sample = GetVoiceMessageSampleField(type);
1282
1283         if(GetPlayerSoundSampleField_notFound)
1284         {
1285                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1286                 return;
1287         }
1288
1289         voicetype = GetVoiceMessageVoiceType(type);
1290         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1291
1292         flood = Say(self, ownteam, world, msg, 1);
1293
1294         if (flood > 0)
1295                 GlobalSound(self.sample, CH_VOICE, voicetype);
1296         else if (flood < 0)
1297                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1298 }
1299
1300 void MoveToTeam(entity client, float team_colour, float type)
1301 {
1302         float lockteams_backup;
1303
1304         lockteams_backup = lockteams;  // backup any team lock
1305
1306         lockteams = 0;  // disable locked teams
1307
1308         TeamchangeFrags(client);  // move the players frags
1309         SetPlayerColors(client, team_colour - 1);  // set the players colour
1310         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1311
1312         lockteams = lockteams_backup;  // restore the team lock
1313
1314         LogTeamchange(client.playerid, client.team, type);
1315 }