qcsrc/server/cl_physics.qc

   1 .float race_penalty;
   2 .float restart_jump;
   3
   4 .float ladder_time;
   5 .entity ladder_entity;
   6 .float gravity;
   7 .float swamp_slowdown;
   8 .float lastflags;
   9 .float lastground;
  10 .float wasFlying;
  11 .float spectatorspeed;
  12
  13 .float multijump_count;
  14 .float multijump_ready;
  15 .float prevjumpbutton;
  16
  17 /*
  18 =============
  19 PlayerJump
  20
  21 When you press the jump key
  22 =============
  23 */
  24 void PlayerJump (void)
  25 {
  26         if(self.freezetag_frozen)
  27                 return; // no jumping in freezetag when frozen
  28
  29         float mjumpheight;
  30         float doublejump;
  31
  32         doublejump = FALSE;
  33         if (autocvar_sv_doublejump)
  34         {
  35                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
  36                 if (trace_fraction < 1 && trace_plane_normal_z > 0.7)
  37                 {
  38                         doublejump = TRUE;
  39
  40                         // we MUST clip velocity here!
  41                         float f;
  42                         f = self.velocity * trace_plane_normal;
  43                         if(f < 0)
  44                                 self.velocity -= f * trace_plane_normal;
  45                 }
  46         }
  47
  48         mjumpheight = autocvar_sv_jumpvelocity;
  49         if (self.waterlevel >= WATERLEVEL_SWIMMING)
  50         {
  51                 if (self.watertype == CONTENT_WATER)
  52                         self.velocity_z = 200;
  53                 else if (self.watertype == CONTENT_SLIME)
  54                         self.velocity_z = 80;
  55                 else
  56                         self.velocity_z = 50;
  57
  58                 return;
  59         }
  60
  61         if (autocvar_g_multijump)
  62         {
  63                 if (self.prevjumpbutton == FALSE && !(self.flags & FL_ONGROUND)) // jump button pressed this frame and we are in midair
  64                         self.multijump_ready = TRUE;  // this is necessary to check that we released the jump button and pressed it again
  65                 else
  66                         self.multijump_ready = FALSE;
  67         }
  68
  69         if(!doublejump && self.multijump_ready && self.multijump_count < autocvar_g_multijump && self.velocity_z > autocvar_g_multijump_speed)
  70         {
  71                 // doublejump = FALSE; // checked above in the if
  72                 if (autocvar_g_multijump)
  73                 {
  74                         if (autocvar_g_multijump_add == 0) // in this case we make the z velocity == jumpvelocity
  75                         {
  76                                 if (self.velocity_z < mjumpheight)
  77                                 {
  78                                         doublejump = TRUE;
  79                                         self.velocity_z = 0;
  80                                 }
  81                         }
  82                         else
  83                                 doublejump = TRUE;
  84
  85                         if(doublejump)
  86                         {
  87                                 if(self.movement_x != 0 || self.movement_y != 0) // don't remove all speed if player isnt pressing any movement keys
  88                                 {
  89                                         float curspeed;
  90                                         vector wishvel, wishdir;
  91
  92                                         curspeed = max(
  93                                                 vlen(vec2(self.velocity)), // current xy speed
  94                                                 vlen(vec2(antilag_takebackavgvelocity(self, max(self.lastteleporttime + sys_frametime, time - 0.25), time))) // average xy topspeed over the last 0.25 secs
  95                                         );
  96                                         makevectors(self.v_angle_y * '0 1 0');
  97                                         wishvel = v_forward * self.movement_x + v_right * self.movement_y;
  98                                         wishdir = normalize(wishvel);
  99
 100                                         self.velocity_x = wishdir_x * curspeed; // allow "dodging" at a multijump
 101                                         self.velocity_y = wishdir_y * curspeed;
 102                                         // keep velocity_z unchanged!
 103                                 }
 104                                 if (autocvar_g_multijump > 0)
 105                                         self.multijump_count += 1;
 106                         }
 107                 }
 108                 self.multijump_ready = FALSE; // require releasing and pressing the jump button again for the next jump
 109         }
 110
 111         if (!doublejump)
 112                 if (!(self.flags & FL_ONGROUND))
 113                         return;
 114
 115         if(self.cvar_cl_movement_track_canjump)
 116                 if (!(self.flags & FL_JUMPRELEASED))
 117                         return;
 118
 119         if(self.health <= g_bloodloss)
 120                 return;
 121
 122         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
 123         // velocity bounds.  Final velocity is bound between (jumpheight *
 124         // min + jumpheight) and (jumpheight * max + jumpheight);
 125
 126         if(autocvar_sv_jumpspeedcap_min != "")
 127         {
 128                 float minjumpspeed;
 129
 130                 minjumpspeed = mjumpheight * stof(autocvar_sv_jumpspeedcap_min);
 131
 132                 if (self.velocity_z < minjumpspeed)
 133                         mjumpheight += minjumpspeed - self.velocity_z;
 134         }
 135
 136         if(autocvar_sv_jumpspeedcap_max != "")
 137         {
 138                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
 139                 tracebox(self.origin + '0 0 0.01', self.mins, self.maxs, self.origin - '0 0 0.01', MOVE_NORMAL, self);
 140
 141                 if(!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && autocvar_sv_jumpspeedcap_max_disable_on_ramps))
 142                 {
 143                         float maxjumpspeed;
 144
 145                         maxjumpspeed = mjumpheight * stof(autocvar_sv_jumpspeedcap_max);
 146
 147                         if (self.velocity_z > maxjumpspeed)
 148                                 mjumpheight -= self.velocity_z - maxjumpspeed;
 149                 }
 150         }
 151
 152         if(!(self.lastflags & FL_ONGROUND))
 153         {
 154                 if(autocvar_speedmeter)
 155                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 156                 if(self.lastground < time - 0.3)
 157                 {
 158                         self.velocity_x *= (1 - autocvar_sv_friction_on_land);
 159                         self.velocity_y *= (1 - autocvar_sv_friction_on_land);
 160                 }
 161                 if(self.jumppadcount > 1)
 162                         dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 163                 self.jumppadcount = 0;
 164         }
 165
 166         self.velocity_z = self.velocity_z + mjumpheight;
 167         self.oldvelocity_z = self.velocity_z;
 168
 169         self.flags &~= FL_ONGROUND;
 170         self.flags &~= FL_JUMPRELEASED;
 171
 172         animdecide_setaction(self, ANIMACTION_JUMP, TRUE);
 173
 174         if(g_jump_grunt)
 175                 PlayerSound(playersound_jump, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 176
 177         self.restart_jump = -1; // restart jump anim next time
 178         // value -1 is used to not use the teleport bit (workaround for tiny hitch when re-jumping)
 179 }
 180 void CheckWaterJump()
 181 {
 182         vector start, end;
 183
 184 // check for a jump-out-of-water
 185         makevectors (self.angles);
 186         start = self.origin;
 187         start_z = start_z + 8;
 188         v_forward_z = 0;
 189         normalize(v_forward);
 190         end = start + v_forward*24;
 191         traceline (start, end, TRUE, self);
 192         if (trace_fraction < 1)
 193         {       // solid at waist
 194                 start_z = start_z + self.maxs_z - 8;
 195                 end = start + v_forward*24;
 196                 self.movedir = trace_plane_normal * -50;
 197                 traceline (start, end, TRUE, self);
 198                 if (trace_fraction == 1)
 199                 {       // open at eye level
 200                         self.flags |= FL_WATERJUMP;
 201                         self.velocity_z = 225;
 202                         self.flags &~= FL_JUMPRELEASED;
 203                         self.teleport_time = time + 2;  // safety net
 204                         return;
 205                 }
 206         }
 207 }
 208 void CheckPlayerJump()
 209 {
 210         if(self.flags & FL_ONGROUND)
 211         {
 212                 if (autocvar_g_multijump > 0)
 213                         self.multijump_count = 0;
 214                 else
 215                         self.multijump_count = -2; // the cvar value for infinite jumps is -1, so this needs to be smaller
 216         }
 217
 218         if (self.BUTTON_JUMP)
 219                 PlayerJump ();
 220         else
 221                 self.flags |= FL_JUMPRELEASED;
 222
 223         if (self.waterlevel == WATERLEVEL_SWIMMING)
 224                 CheckWaterJump ();
 225         self.prevjumpbutton = self.BUTTON_JUMP;
 226 }
 227
 228 float racecar_angle(float forward, float down)
 229 {
 230         float ret, angle_mult;
 231
 232         if(forward < 0)
 233         {
 234                 forward = -forward;
 235                 down = -down;
 236         }
 237
 238         ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 239
 240         angle_mult = forward / (800 + forward);
 241
 242         if(ret > 180)
 243                 return ret * angle_mult + 360 * (1 - angle_mult);
 244         else
 245                 return ret * angle_mult;
 246 }
 247
 248 void RaceCarPhysics()
 249 {
 250         // using this move type for "big rigs"
 251         // the engine does not push the entity!
 252
 253         float accel, steer, f, myspeed, steerfactor;
 254         vector angles_save, rigvel;
 255
 256         angles_save = self.angles;
 257         accel = bound(-1, self.movement_x / self.stat_sv_maxspeed, 1);
 258         steer = bound(-1, self.movement_y / self.stat_sv_maxspeed, 1);
 259
 260         if(g_bugrigs_reverse_speeding)
 261         {
 262                 if(accel < 0)
 263                 {
 264                         // back accel is DIGITAL
 265                         // to prevent speedhack
 266                         if(accel < -0.5)
 267                                 accel = -1;
 268                         else
 269                                 accel = 0;
 270                 }
 271         }
 272
 273         self.angles_x = 0;
 274         self.angles_z = 0;
 275         makevectors(self.angles); // new forward direction!
 276
 277         if(self.flags & FL_ONGROUND || g_bugrigs_air_steering)
 278         {
 279                 float upspeed, accelfactor;
 280
 281                 myspeed = self.velocity * v_forward;
 282                 upspeed = self.velocity * v_up;
 283
 284                 // responsiveness factor for steering and acceleration
 285                 f = 1 / (1 + pow(max(-myspeed, myspeed) / g_bugrigs_speed_ref, g_bugrigs_speed_pow));
 286                 //MAXIMA: f(v) := 1 / (1 + (v / g_bugrigs_speed_ref) ^ g_bugrigs_speed_pow);
 287
 288                 if(myspeed < 0 && g_bugrigs_reverse_spinning)
 289                         steerfactor = -myspeed * g_bugrigs_steer;
 290                 else
 291                         steerfactor = -myspeed * f * g_bugrigs_steer;
 292
 293                 if(myspeed < 0 && g_bugrigs_reverse_speeding)
 294                         accelfactor = g_bugrigs_accel;
 295                 else
 296                         accelfactor = f * g_bugrigs_accel;
 297                 //MAXIMA: accel(v) := f(v) * g_bugrigs_accel;
 298
 299                 if(accel < 0)
 300                 {
 301                         if(myspeed > 0)
 302                         {
 303                                 myspeed = max(0, myspeed - frametime * (g_bugrigs_friction_floor - g_bugrigs_friction_brake * accel));
 304                         }
 305                         else
 306                         {
 307                                 if(!g_bugrigs_reverse_speeding)
 308                                         myspeed = min(0, myspeed + frametime * g_bugrigs_friction_floor);
 309                         }
 310                 }
 311                 else
 312                 {
 313                         if(myspeed >= 0)
 314                         {
 315                                 myspeed = max(0, myspeed - frametime * g_bugrigs_friction_floor);
 316                         }
 317                         else
 318                         {
 319                                 if(g_bugrigs_reverse_stopping)
 320                                         myspeed = 0;
 321                                 else
 322                                         myspeed = min(0, myspeed + frametime * (g_bugrigs_friction_floor + g_bugrigs_friction_brake * accel));
 323                         }
 324                 }
 325                 // terminal velocity = velocity at which 50 == accelfactor, that is, 1549 units/sec
 326                 //MAXIMA: friction(v) := g_bugrigs_friction_floor;
 327
 328                 self.angles_y += steer * frametime * steerfactor; // apply steering
 329                 makevectors(self.angles); // new forward direction!
 330
 331                 myspeed += accel * accelfactor * frametime;
 332
 333                 rigvel = myspeed * v_forward + '0 0 1' * upspeed;
 334         }
 335         else
 336         {
 337                 myspeed = vlen(self.velocity);
 338
 339                 // responsiveness factor for steering and acceleration
 340                 f = 1 / (1 + pow(max(0, myspeed / g_bugrigs_speed_ref), g_bugrigs_speed_pow));
 341                 steerfactor = -myspeed * f;
 342                 self.angles_y += steer * frametime * steerfactor; // apply steering
 343
 344                 rigvel = self.velocity;
 345                 makevectors(self.angles); // new forward direction!
 346         }
 347
 348         rigvel = rigvel * max(0, 1 - vlen(rigvel) * g_bugrigs_friction_air * frametime);
 349         //MAXIMA: airfriction(v) := v * v * g_bugrigs_friction_air;
 350         //MAXIMA: total_acceleration(v) := accel(v) - friction(v) - airfriction(v);
 351         //MAXIMA: solve(total_acceleration(v) = 0, v);
 352
 353         if(g_bugrigs_planar_movement)
 354         {
 355                 vector rigvel_xy, neworigin, up;
 356                 float mt;
 357
 358                 rigvel_z -= frametime * autocvar_sv_gravity; // 4x gravity plays better
 359                 rigvel_xy = vec2(rigvel);
 360
 361                 if(g_bugrigs_planar_movement_car_jumping)
 362                         mt = MOVE_NORMAL;
 363                 else
 364                         mt = MOVE_NOMONSTERS;
 365
 366                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 1024', mt, self);
 367                 up = trace_endpos - self.origin;
 368
 369                 // BUG RIGS: align the move to the surface instead of doing collision testing
 370                 // can we move?
 371                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos + rigvel_xy * frametime, mt, self);
 372
 373                 // align to surface
 374                 tracebox(trace_endpos, self.mins, self.maxs, trace_endpos - up + '0 0 1' * rigvel_z * frametime, mt, self);
 375
 376                 if(trace_fraction < 0.5)
 377                 {
 378                         trace_fraction = 1;
 379                         neworigin = self.origin;
 380                 }
 381                 else
 382                         neworigin = trace_endpos;
 383
 384                 if(trace_fraction < 1)
 385                 {
 386                         // now set angles_x so that the car points parallel to the surface
 387                         self.angles = vectoangles(
 388                                         '1 0 0' * v_forward_x * trace_plane_normal_z
 389                                         +
 390                                         '0 1 0' * v_forward_y * trace_plane_normal_z
 391                                         +
 392                                         '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y)
 393                                         );
 394                         self.flags |= FL_ONGROUND;
 395                 }
 396                 else
 397                 {
 398                         // now set angles_x so that the car points forward, but is tilted in velocity direction
 399                         self.flags &~= FL_ONGROUND;
 400                 }
 401
 402                 self.velocity = (neworigin - self.origin) * (1.0 / frametime);
 403                 self.movetype = MOVETYPE_NOCLIP;
 404         }
 405         else
 406         {
 407                 rigvel_z -= frametime * autocvar_sv_gravity; // 4x gravity plays better
 408                 self.velocity = rigvel;
 409                 self.movetype = MOVETYPE_FLY;
 410         }
 411
 412         trace_fraction = 1;
 413         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 414         if(trace_fraction != 1)
 415         {
 416                 self.angles = vectoangles2(
 417                                 '1 0 0' * v_forward_x * trace_plane_normal_z
 418                                 +
 419                                 '0 1 0' * v_forward_y * trace_plane_normal_z
 420                                 +
 421                                 '0 0 1' * -(v_forward_x * trace_plane_normal_x + v_forward_y * trace_plane_normal_y),
 422                                 trace_plane_normal
 423                                 );
 424         }
 425         else
 426         {
 427                 vector vel_local;
 428
 429                 vel_local_x = v_forward * self.velocity;
 430                 vel_local_y = v_right * self.velocity;
 431                 vel_local_z = v_up * self.velocity;
 432
 433                 self.angles_x = racecar_angle(vel_local_x, vel_local_z);
 434                 self.angles_z = racecar_angle(-vel_local_y, vel_local_z);
 435         }
 436
 437         // smooth the angles
 438         vector vf1, vu1, smoothangles;
 439         makevectors(self.angles);
 440         f = bound(0, frametime * g_bugrigs_angle_smoothing, 1);
 441         if(f == 0)
 442                 f = 1;
 443         vf1 = v_forward * f;
 444         vu1 = v_up * f;
 445         makevectors(angles_save);
 446         vf1 = vf1 + v_forward * (1 - f);
 447         vu1 = vu1 + v_up * (1 - f);
 448         smoothangles = vectoangles2(vf1, vu1);
 449         self.angles_x = -smoothangles_x;
 450         self.angles_z =  smoothangles_z;
 451 }
 452
 453 float IsMoveInDirection(vector mv, float angle) // key mix factor
 454 {
 455         if(mv_x == 0 && mv_y == 0)
 456                 return 0; // avoid division by zero
 457         angle -= RAD2DEG * atan2(mv_y, mv_x);
 458         angle = remainder(angle, 360) / 45;
 459         if(angle >  1)
 460                 return 0;
 461         if(angle < -1)
 462                 return 0;
 463         return 1 - fabs(angle);
 464 }
 465
 466 float GeomLerp(float a, float lerp, float b)
 467 {
 468         if(a == 0)
 469         {
 470                 if(lerp < 1)
 471                         return 0;
 472                 else
 473                         return b;
 474         }
 475         if(b == 0)
 476         {
 477                 if(lerp > 0)
 478                         return 0;
 479                 else
 480                         return a;
 481         }
 482         return a * pow(fabs(b / a), lerp);
 483 }
 484
 485 void CPM_PM_Aircontrol(vector wishdir, float wishspeed)
 486 {
 487         float zspeed, xyspeed, dot, k;
 488
 489 #if 0
 490         // this doesn't play well with analog input
 491         if(self.movement_x == 0 || self.movement_y != 0)
 492                 return; // can't control movement if not moving forward or backward
 493         k = 32;
 494 #else
 495         k = 32 * (2 * IsMoveInDirection(self.movement, 0) - 1);
 496         if(k <= 0)
 497                 return;
 498 #endif
 499
 500         k *= bound(0, wishspeed / autocvar_sv_maxairspeed, 1);
 501
 502         zspeed = self.velocity_z;
 503         self.velocity_z = 0;
 504         xyspeed = vlen(self.velocity); self.velocity = normalize(self.velocity);
 505
 506         dot = self.velocity * wishdir;
 507
 508         if(dot > 0) // we can't change direction while slowing down
 509         {
 510                 k *= pow(dot, autocvar_sv_aircontrol_power)*frametime;
 511                 xyspeed = max(0, xyspeed - autocvar_sv_aircontrol_penalty * sqrt(max(0, 1 - dot*dot)) * k/32);
 512                 k *= autocvar_sv_aircontrol;
 513                 self.velocity = normalize(self.velocity * xyspeed + wishdir * k);
 514         }
 515
 516         self.velocity = self.velocity * xyspeed;
 517         self.velocity_z = zspeed;
 518 }
 519
 520 float AdjustAirAccelQW(float accelqw, float factor)
 521 {
 522         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 523 }
 524
 525 // example config for alternate speed clamping:
 526 //   sv_airaccel_qw 0.8
 527 //   sv_airaccel_sideways_friction 0
 528 //   prvm_globalset server speedclamp_mode 1
 529 //     (or 2)
 530 void PM_Accelerate(vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float stretchfactor, float sidefric, float speedlimit)
 531 {
 532         float vel_straight;
 533         float vel_z;
 534         vector vel_perpend;
 535         float step;
 536
 537         vector vel_xy;
 538         float vel_xy_current;
 539         float vel_xy_backward, vel_xy_forward;
 540         float speedclamp;
 541
 542         if(stretchfactor > 0)
 543                 speedclamp = stretchfactor;
 544         else if(accelqw < 0)
 545                 speedclamp = 1; // full clamping, no stretch
 546         else
 547                 speedclamp = -1; // no clamping
 548
 549         if(accelqw < 0)
 550                 accelqw = -accelqw;
 551
 552         if(autocvar_sv_gameplayfix_q2airaccelerate)
 553                 wishspeed0 = wishspeed;
 554
 555         vel_straight = self.velocity * wishdir;
 556         vel_z = self.velocity_z;
 557         vel_xy = vec2(self.velocity);
 558         vel_perpend = vel_xy - vel_straight * wishdir;
 559
 560         step = accel * frametime * wishspeed0;
 561
 562         vel_xy_current  = vlen(vel_xy);
 563         if(speedlimit)
 564                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
 565         vel_xy_forward  = vel_xy_current + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 566         vel_xy_backward = vel_xy_current - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 567         if(vel_xy_backward < 0)
 568                 vel_xy_backward = 0; // not that it REALLY occurs that this would cause wrong behaviour afterwards
 569
 570         vel_straight = vel_straight + bound(0, wishspeed - vel_straight, step) * accelqw + step * (1 - accelqw);
 571
 572         if(sidefric < 0 && (vel_perpend*vel_perpend))
 573                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 574         {
 575                 float f, fminimum;
 576                 f = max(0, 1 + frametime * wishspeed * sidefric);
 577                 fminimum = (vel_xy_backward*vel_xy_backward - vel_straight*vel_straight) / (vel_perpend*vel_perpend);
 578                 // this cannot be > 1
 579                 if(fminimum <= 0)
 580                         vel_perpend = vel_perpend * max(0, f);
 581                 else
 582                 {
 583                         fminimum = sqrt(fminimum);
 584                         vel_perpend = vel_perpend * max(fminimum, f);
 585                 }
 586         }
 587         else
 588                 vel_perpend = vel_perpend * max(0, 1 - frametime * wishspeed * sidefric);
 589
 590         vel_xy = vel_straight * wishdir + vel_perpend;
 591
 592         if(speedclamp >= 0)
 593         {
 594                 float vel_xy_preclamp;
 595                 vel_xy_preclamp = vlen(vel_xy);
 596                 if(vel_xy_preclamp > 0) // prevent division by zero
 597                 {
 598                         vel_xy_current += (vel_xy_forward - vel_xy_current) * speedclamp;
 599                         if(vel_xy_current < vel_xy_preclamp)
 600                                 vel_xy = vel_xy * (vel_xy_current / vel_xy_preclamp);
 601                 }
 602         }
 603
 604         self.velocity = vel_xy + vel_z * '0 0 1';
 605 }
 606
 607 void PM_AirAccelerate(vector wishdir, float wishspeed)
 608 {
 609         vector curvel, wishvel, acceldir, curdir;
 610         float addspeed, accelspeed, curspeed, f;
 611         float dot;
 612
 613         if(wishspeed == 0)
 614                 return;
 615
 616         curvel = self.velocity;
 617         curvel_z = 0;
 618         curspeed = vlen(curvel);
 619
 620         if(wishspeed > curspeed * 1.01)
 621         {
 622                 wishspeed = min(wishspeed, curspeed + autocvar_sv_warsowbunny_airforwardaccel * self.stat_sv_maxspeed * frametime);
 623         }
 624         else
 625         {
 626                 f = max(0, (autocvar_sv_warsowbunny_topspeed - curspeed) / (autocvar_sv_warsowbunny_topspeed - self.stat_sv_maxspeed));
 627                 wishspeed = max(curspeed, self.stat_sv_maxspeed) + autocvar_sv_warsowbunny_accel * f * self.stat_sv_maxspeed * frametime;
 628         }
 629         wishvel = wishdir * wishspeed;
 630         acceldir = wishvel - curvel;
 631         addspeed = vlen(acceldir);
 632         acceldir = normalize(acceldir);
 633
 634         accelspeed = min(addspeed, autocvar_sv_warsowbunny_turnaccel * self.stat_sv_maxspeed * frametime);
 635
 636         if(autocvar_sv_warsowbunny_backtosideratio < 1)
 637         {
 638                 curdir = normalize(curvel);
 639                 dot = acceldir * curdir;
 640                 if(dot < 0)
 641                         acceldir = acceldir - (1 - autocvar_sv_warsowbunny_backtosideratio) * dot * curdir;
 642         }
 643
 644         self.velocity += accelspeed * acceldir;
 645 }
 646
 647 .vector movement_old;
 648 .float buttons_old;
 649 .vector v_angle_old;
 650 .string lastclassname;
 651
 652 .float() PlayerPhysplug;
 653
 654 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 655 .float specialcommand_pos;
 656 void SpecialCommand()
 657 {
 658 #ifdef TETRIS
 659         TetrisImpulse();
 660 #else
 661         if(!CheatImpulse(99))
 662                 print("A hollow voice says \"Plugh\".\n");
 663 #endif
 664 }
 665
 666 float speedaward_speed;
 667 string speedaward_holder;
 668 string speedaward_uid;
 669 void race_send_speedaward(float msg)
 670 {
 671         // send the best speed of the round
 672         WriteByte(msg, SVC_TEMPENTITY);
 673         WriteByte(msg, TE_CSQC_RACE);
 674         WriteByte(msg, RACE_NET_SPEED_AWARD);
 675         WriteInt24_t(msg, floor(speedaward_speed+0.5));
 676         WriteString(msg, speedaward_holder);
 677 }
 678
 679 float speedaward_alltimebest;
 680 string speedaward_alltimebest_holder;
 681 string speedaward_alltimebest_uid;
 682 void race_send_speedaward_alltimebest(float msg)
 683 {
 684         // send the best speed
 685         WriteByte(msg, SVC_TEMPENTITY);
 686         WriteByte(msg, TE_CSQC_RACE);
 687         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 688         WriteInt24_t(msg, floor(speedaward_alltimebest+0.5));
 689         WriteString(msg, speedaward_alltimebest_holder);
 690 }
 691
 692 string GetMapname(void);
 693 float speedaward_lastupdate;
 694 float speedaward_lastsent;
 695 void SV_PlayerPhysics()
 696 {
 697         vector wishvel, wishdir, v;
 698         float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod, buttons;
 699         string temps;
 700         float buttons_prev;
 701         float not_allowed_to_move;
 702         string c;
 703
 704         WarpZone_PlayerPhysics_FixVAngle();
 705
 706         maxspd_mod = 1;
 707         if(g_minstagib && (self.items & IT_INVINCIBLE))
 708                 maxspd_mod *= autocvar_g_minstagib_speed_highspeed;
 709         if(self.ballcarried)
 710                 if(g_nexball)
 711                         maxspd_mod *= autocvar_g_nexball_basketball_carrier_highspeed;
 712                 else if(g_keepaway)
 713                         maxspd_mod *= autocvar_g_keepaway_ballcarrier_highspeed;
 714
 715         maxspd_mod *= autocvar_g_movement_highspeed;
 716
 717         // fix physics stats for g_movement_highspeed
 718         // TODO maybe rather use maxairspeed? needs testing
 719         self.stat_sv_airaccel_qw = AdjustAirAccelQW(autocvar_sv_airaccel_qw, maxspd_mod);
 720         if(autocvar_sv_airstrafeaccel_qw)
 721                 self.stat_sv_airstrafeaccel_qw = AdjustAirAccelQW(autocvar_sv_airstrafeaccel_qw, maxspd_mod);
 722         else
 723                 self.stat_sv_airstrafeaccel_qw = 0;
 724         self.stat_sv_airspeedlimit_nonqw = autocvar_sv_airspeedlimit_nonqw * maxspd_mod;
 725         self.stat_sv_maxspeed = autocvar_sv_maxspeed * maxspd_mod; // also slow walking
 726
 727     if(self.PlayerPhysplug)
 728         if(self.PlayerPhysplug())
 729             return;
 730
 731         self.race_movetime_frac += frametime;
 732         f = floor(self.race_movetime_frac);
 733         self.race_movetime_frac -= f;
 734         self.race_movetime_count += f;
 735         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
 736
 737         anticheat_physics();
 738
 739         buttons = self.BUTTON_ATCK + 2 * self.BUTTON_JUMP + 4 * self.BUTTON_ATCK2 + 8 * self.BUTTON_ZOOM + 16 * self.BUTTON_CROUCH + 32 * self.BUTTON_HOOK + 64 * self.BUTTON_USE + 128 * (self.movement_x < 0) + 256 * (self.movement_x > 0) + 512 * (self.movement_y < 0) + 1024 * (self.movement_y > 0);
 740
 741         if(!buttons)
 742                 c = "x";
 743         else if(buttons == 1)
 744                 c = "1";
 745         else if(buttons == 2)
 746                 c = " ";
 747         else if(buttons == 128)
 748                 c = "s";
 749         else if(buttons == 256)
 750                 c = "w";
 751         else if(buttons == 512)
 752                 c = "a";
 753         else if(buttons == 1024)
 754                 c = "d";
 755         else
 756                 c = "?";
 757
 758         if(c == substring(specialcommand, self.specialcommand_pos, 1))
 759         {
 760                 self.specialcommand_pos += 1;
 761                 if(self.specialcommand_pos >= strlen(specialcommand))
 762                 {
 763                         self.specialcommand_pos = 0;
 764                         SpecialCommand();
 765                         return;
 766                 }
 767         }
 768         else if(self.specialcommand_pos && (c != substring(specialcommand, self.specialcommand_pos - 1, 1)))
 769                 self.specialcommand_pos = 0;
 770
 771         if(!sv_maxidle_spectatorsareidle || self.movetype == MOVETYPE_WALK)
 772         {
 773                 if(buttons != self.buttons_old || self.movement != self.movement_old || self.v_angle != self.v_angle_old)
 774                         self.parm_idlesince = time;
 775         }
 776         buttons_prev = self.buttons_old;
 777         self.buttons_old = buttons;
 778         self.movement_old = self.movement;
 779         self.v_angle_old = self.v_angle;
 780
 781         if(time < self.nickspamtime)
 782         if(self.nickspamcount >= autocvar_g_nick_flood_penalty_yellow)
 783         {
 784                 // slight annoyance for nick change scripts
 785                 self.movement = -1 * self.movement;
 786                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = self.BUTTON_ZOOM = self.BUTTON_CROUCH = self.BUTTON_HOOK = self.BUTTON_USE = 0;
 787
 788                 if(self.nickspamcount >= autocvar_g_nick_flood_penalty_red) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 789                 {
 790                         self.angles_x = random() * 360;
 791                         self.angles_y = random() * 360;
 792                         // at least I'm not forcing retardedview by also assigning to angles_z
 793                         self.fixangle = TRUE;
 794                 }
 795         }
 796
 797         if (self.punchangle != '0 0 0')
 798         {
 799                 f = vlen(self.punchangle) - 10 * frametime;
 800                 if (f > 0)
 801                         self.punchangle = normalize(self.punchangle) * f;
 802                 else
 803                         self.punchangle = '0 0 0';
 804         }
 805
 806         if (self.punchvector != '0 0 0')
 807         {
 808                 f = vlen(self.punchvector) - 30 * frametime;
 809                 if (f > 0)
 810                         self.punchvector = normalize(self.punchvector) * f;
 811                 else
 812                         self.punchvector = '0 0 0';
 813         }
 814
 815         if (IS_BOT_CLIENT(self))
 816         {
 817                 if(playerdemo_read())
 818                         return;
 819                 bot_think();
 820         }
 821
 822         self.items &~= IT_USING_JETPACK;
 823
 824         if(IS_PLAYER(self))
 825         {
 826                 if(self.race_penalty)
 827                         if(time > self.race_penalty)
 828                                 self.race_penalty = 0;
 829
 830                 not_allowed_to_move = 0;
 831                 if(self.race_penalty)
 832                         not_allowed_to_move = 1;
 833                 if(!autocvar_sv_ready_restart_after_countdown)
 834                 if(time < game_starttime)
 835                         not_allowed_to_move = 1;
 836
 837                 if(not_allowed_to_move)
 838                 {
 839                         self.velocity = '0 0 0';
 840                         self.movetype = MOVETYPE_NONE;
 841                         self.disableclientprediction = 2;
 842                 }
 843                 else if(self.disableclientprediction == 2)
 844                 {
 845                         if(self.movetype == MOVETYPE_NONE)
 846                                 self.movetype = MOVETYPE_WALK;
 847                         self.disableclientprediction = 0;
 848                 }
 849         }
 850
 851         if (self.movetype == MOVETYPE_NONE)
 852                 return;
 853
 854         // when we get here, disableclientprediction cannot be 2
 855         self.disableclientprediction = 0;
 856         if(time < self.ladder_time)
 857                 self.disableclientprediction = 1;
 858
 859         MUTATOR_CALLHOOK(PlayerPhysics);
 860
 861         if(self.player_blocked)
 862         {
 863                 self.movement = '0 0 0';
 864                 self.disableclientprediction = 1;
 865         }
 866
 867         maxspd_mod = 1;
 868
 869         swampspd_mod = 1;
 870         if(self.in_swamp) {
 871                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 872         }
 873
 874         // conveyors: first fix velocity
 875         if(self.conveyor.state)
 876                 self.velocity -= self.conveyor.movedir;
 877
 878         if not(IS_PLAYER(self))
 879         {
 880                 maxspd_mod = autocvar_sv_spectator_speed_multiplier;
 881                 if(!self.spectatorspeed)
 882                         self.spectatorspeed = maxspd_mod;
 883                 if(self.impulse && self.impulse <= 19 || self.impulse >= 200 && self.impulse <= 209 || self.impulse >= 220 && self.impulse <= 229)
 884                 {
 885                         if(self.lastclassname != "player")
 886                         {
 887                                 if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || self.impulse >= 200 && self.impulse <= 209)
 888                                         self.spectatorspeed = bound(1, self.spectatorspeed + 0.5, 5);
 889                                 else if(self.impulse == 11)
 890                                         self.spectatorspeed = maxspd_mod;
 891                                 else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || self.impulse >= 220 && self.impulse <= 229)
 892                                         self.spectatorspeed = bound(1, self.spectatorspeed - 0.5, 5);
 893                                 else if(self.impulse >= 1 && self.impulse <= 9)
 894                                         self.spectatorspeed = 1 + 0.5 * (self.impulse - 1);
 895                         } // otherwise just clear
 896                         self.impulse = 0;
 897                 }
 898                 maxspd_mod = self.spectatorspeed;
 899         }
 900
 901         spd = max(self.stat_sv_maxspeed, autocvar_sv_maxairspeed) * maxspd_mod * swampspd_mod;
 902         if(self.speed != spd)
 903         {
 904                 self.speed = spd;
 905                 temps = ftos(spd);
 906                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 907                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 908                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 909                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 910         }
 911
 912         maxspd_mod *= swampspd_mod; // only one common speed modder please!
 913         swampspd_mod = 1;
 914
 915         // if dead, behave differently
 916         if (self.deadflag)
 917                 goto end;
 918
 919         if (!self.fixangle && !g_bugrigs)
 920         {
 921                 self.angles_x = 0;
 922                 self.angles_y = self.v_angle_y;
 923                 self.angles_z = 0;
 924         }
 925
 926         if(self.flags & FL_ONGROUND)
 927         if(IS_PLAYER(self)) // no fall sounds for observers thank you very much
 928         if(self.wasFlying)
 929         {
 930                 self.wasFlying = 0;
 931
 932                 if(self.waterlevel < WATERLEVEL_SWIMMING)
 933                 if(time >= self.ladder_time)
 934                 if not(self.hook)
 935                 {
 936                         self.nextstep = time + 0.3 + random() * 0.1;
 937                         trace_dphitq3surfaceflags = 0;
 938                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 939                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 940                         {
 941                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 942                                         GlobalSound(globalsound_metalfall, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 943                                 else
 944                                         GlobalSound(globalsound_fall, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 945                         }
 946                 }
 947         }
 948
 949         if(IsFlying(self))
 950                 self.wasFlying = 1;
 951
 952         if(IS_PLAYER(self))
 953                 CheckPlayerJump();
 954
 955         if (self.flags & FL_WATERJUMP )
 956         {
 957                 self.velocity_x = self.movedir_x;
 958                 self.velocity_y = self.movedir_y;
 959                 if (time > self.teleport_time || self.waterlevel == WATERLEVEL_NONE)
 960                 {
 961                         self.flags &~= FL_WATERJUMP;
 962                         self.teleport_time = 0;
 963                 }
 964         }
 965         else if (g_bugrigs && IS_PLAYER(self))
 966         {
 967                 RaceCarPhysics();
 968         }
 969         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY || self.movetype == MOVETYPE_FLY_WORLDONLY)
 970         {
 971                 // noclipping or flying
 972                 self.flags &~= FL_ONGROUND;
 973
 974                 self.velocity = self.velocity * (1 - frametime * autocvar_sv_friction);
 975                 makevectors(self.v_angle);
 976                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 977                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 978                 // acceleration
 979                 wishdir = normalize(wishvel);
 980                 wishspeed = vlen(wishvel);
 981                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
 982                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
 983                 if (time >= self.teleport_time)
 984                         PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
 985         }
 986         else if (self.waterlevel >= WATERLEVEL_SWIMMING)
 987         {
 988                 // swimming
 989                 self.flags &~= FL_ONGROUND;
 990
 991                 makevectors(self.v_angle);
 992                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 993                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 994                 if (wishvel == '0 0 0')
 995                         wishvel = '0 0 -60'; // drift towards bottom
 996
 997                 wishdir = normalize(wishvel);
 998                 wishspeed = vlen(wishvel);
 999                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1000                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1001                 wishspeed = wishspeed * 0.7;
1002
1003                 // water friction
1004                 self.velocity = self.velocity * (1 - frametime * autocvar_sv_friction);
1005
1006                 // water acceleration
1007                 PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1008         }
1009         else if (time < self.ladder_time)
1010         {
1011                 // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
1012                 self.flags &~= FL_ONGROUND;
1013
1014                 float g;
1015                 g = autocvar_sv_gravity * frametime;
1016                 if(self.gravity)
1017                         g *= self.gravity;
1018                 if(autocvar_sv_gameplayfix_gravityunaffectedbyticrate)
1019                 {
1020                         g *= 0.5;
1021                         self.velocity_z += g;
1022                 }
1023
1024                 self.velocity = self.velocity * (1 - frametime * autocvar_sv_friction);
1025                 makevectors(self.v_angle);
1026                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
1027                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
1028                 self.velocity_z += g;
1029                 if (self.ladder_entity.classname == "func_water")
1030                 {
1031                         f = vlen(wishvel);
1032                         if (f > self.ladder_entity.speed)
1033                                 wishvel = wishvel * (self.ladder_entity.speed / f);
1034
1035                         self.watertype = self.ladder_entity.skin;
1036                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
1037                         if ((self.origin_z + self.view_ofs_z) < f)
1038                                 self.waterlevel = WATERLEVEL_SUBMERGED;
1039                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
1040                                 self.waterlevel = WATERLEVEL_SWIMMING;
1041                         else if ((self.origin_z + self.mins_z + 1) < f)
1042                                 self.waterlevel = WATERLEVEL_WETFEET;
1043                         else
1044                         {
1045                                 self.waterlevel = WATERLEVEL_NONE;
1046                                 self.watertype = CONTENT_EMPTY;
1047                         }
1048                 }
1049                 // acceleration
1050                 wishdir = normalize(wishvel);
1051                 wishspeed = vlen(wishvel);
1052                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1053                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1054                 if (time >= self.teleport_time)
1055                 {
1056                         // water acceleration
1057                         PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1058                 }
1059         }
1060         else if ((self.items & IT_JETPACK) && self.BUTTON_HOOK && (!autocvar_g_jetpack_fuel || self.ammo_fuel >= 0.01 || self.items & IT_UNLIMITED_WEAPON_AMMO) && !self.freezetag_frozen)
1061         {
1062                 //makevectors(self.v_angle_y * '0 1 0');
1063                 makevectors(self.v_angle);
1064                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1065                 // add remaining speed as Z component
1066                 maxairspd = autocvar_sv_maxairspeed*max(1, maxspd_mod);
1067                 // fix speedhacks :P
1068                 wishvel = normalize(wishvel) * min(vlen(wishvel) / maxairspd, 1);
1069                 // add the unused velocity as up component
1070                 wishvel_z = 0;
1071
1072                 // if(self.BUTTON_JUMP)
1073                         wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
1074
1075                 // it is now normalized, so...
1076                 float a_side, a_up, a_add, a_diff;
1077                 a_side = autocvar_g_jetpack_acceleration_side;
1078                 a_up = autocvar_g_jetpack_acceleration_up;
1079                 a_add = autocvar_g_jetpack_antigravity * autocvar_sv_gravity;
1080
1081                 wishvel_x *= a_side;
1082                 wishvel_y *= a_side;
1083                 wishvel_z *= a_up;
1084                 wishvel_z += a_add;
1085
1086                 float best;
1087                 best = 0;
1088                 //////////////////////////////////////////////////////////////////////////////////////
1089                 // finding the maximum over all vectors of above form
1090                 // with wishvel having an absolute value of 1
1091                 //////////////////////////////////////////////////////////////////////////////////////
1092                 // we're finding the maximum over
1093                 //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
1094                 // for z in the range from -1 to 1
1095                 //////////////////////////////////////////////////////////////////////////////////////
1096                 // maximum is EITHER attained at the single extreme point:
1097                 a_diff = a_side * a_side - a_up * a_up;
1098                 if(a_diff != 0)
1099                 {
1100                         f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
1101                         if(f > -1 && f < 1) // can it be attained?
1102                         {
1103                                 best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
1104                                 //print("middle\n");
1105                         }
1106                 }
1107                 // OR attained at z = 1:
1108                 f = (a_up + a_add) * (a_up + a_add);
1109                 if(f > best)
1110                 {
1111                         best = f;
1112                         //print("top\n");
1113                 }
1114                 // OR attained at z = -1:
1115                 f = (a_up - a_add) * (a_up - a_add);
1116                 if(f > best)
1117                 {
1118                         best = f;
1119                         //print("bottom\n");
1120                 }
1121                 best = sqrt(best);
1122                 //////////////////////////////////////////////////////////////////////////////////////
1123
1124                 //print("best possible acceleration: ", ftos(best), "\n");
1125
1126                 float fxy, fz;
1127                 fxy = bound(0, 1 - (self.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / autocvar_g_jetpack_maxspeed_side, 1);
1128                 if(wishvel_z - autocvar_sv_gravity > 0)
1129                         fz = bound(0, 1 - self.velocity_z / autocvar_g_jetpack_maxspeed_up, 1);
1130                 else
1131                         fz = bound(0, 1 + self.velocity_z / autocvar_g_jetpack_maxspeed_up, 1);
1132
1133                 float fvel;
1134                 fvel = vlen(wishvel);
1135                 wishvel_x *= fxy;
1136                 wishvel_y *= fxy;
1137                 wishvel_z = (wishvel_z - autocvar_sv_gravity) * fz + autocvar_sv_gravity;
1138
1139                 fvel = min(1, vlen(wishvel) / best);
1140                 if(autocvar_g_jetpack_fuel && !(self.items & IT_UNLIMITED_WEAPON_AMMO))
1141                         f = min(1, self.ammo_fuel / (autocvar_g_jetpack_fuel * frametime * fvel));
1142                 else
1143                         f = 1;
1144
1145                 //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1146
1147                 if (f > 0 && wishvel != '0 0 0')
1148                 {
1149                         self.velocity = self.velocity + wishvel * f * frametime;
1150                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1151                                 self.ammo_fuel -= autocvar_g_jetpack_fuel * frametime * fvel * f;
1152                         self.flags &~= FL_ONGROUND;
1153                         self.items |= IT_USING_JETPACK;
1154
1155                         // jetpack also inhibits health regeneration, but only for 1 second
1156                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
1157                 }
1158         }
1159         else if (self.flags & FL_ONGROUND)
1160         {
1161                 // we get here if we ran out of ammo
1162                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32) && self.ammo_fuel < 0.01)
1163                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1164
1165                 // walking
1166                 makevectors(self.v_angle_y * '0 1 0');
1167                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1168
1169                 if(!(self.lastflags & FL_ONGROUND))
1170                 {
1171                         if(autocvar_speedmeter)
1172                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
1173                         if(self.lastground < time - 0.3)
1174                                 self.velocity = self.velocity * (1 - autocvar_sv_friction_on_land);
1175                         if(self.jumppadcount > 1)
1176                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
1177                         self.jumppadcount = 0;
1178                 }
1179
1180 #ifdef LETS_TEST_FTEQCC
1181                 if(self.velocity_x || self.velocity_y)
1182                 {
1183                         // good
1184                 }
1185                 else
1186                 {
1187                         if(self.velocity_x)
1188                                 checkclient();
1189                         if(self.velocity_y)
1190                                 checkclient();
1191                 }
1192 #endif
1193
1194                 v = self.velocity;
1195                 v_z = 0;
1196                 f = vlen(v);
1197                 if(f > 0)
1198                 {
1199                         if (f < autocvar_sv_stopspeed)
1200                                 f = 1 - frametime * (autocvar_sv_stopspeed / f) * autocvar_sv_friction;
1201                         else
1202                                 f = 1 - frametime * autocvar_sv_friction;
1203                         if (f > 0)
1204                                 self.velocity = self.velocity * f;
1205                         else
1206                                 self.velocity = '0 0 0';
1207                         /*
1208                            Mathematical analysis time!
1209
1210                            Our goal is to invert this mess.
1211
1212                            For the two cases we get:
1213                                 v = v0 * (1 - frametime * (autocvar_sv_stopspeed / v0) * autocvar_sv_friction)
1214                                   = v0 - frametime * autocvar_sv_stopspeed * autocvar_sv_friction
1215                                 v0 = v + frametime * autocvar_sv_stopspeed * autocvar_sv_friction
1216                            and
1217                                 v = v0 * (1 - frametime * autocvar_sv_friction)
1218                                 v0 = v / (1 - frametime * autocvar_sv_friction)
1219
1220                            These cases would be chosen ONLY if:
1221                                 v0 < autocvar_sv_stopspeed
1222                                 v + frametime * autocvar_sv_stopspeed * autocvar_sv_friction < autocvar_sv_stopspeed
1223                                 v < autocvar_sv_stopspeed * (1 - frametime * autocvar_sv_friction)
1224                            and, respectively:
1225                                 v0 >= autocvar_sv_stopspeed
1226                                 v / (1 - frametime * autocvar_sv_friction) >= autocvar_sv_stopspeed
1227                                 v >= autocvar_sv_stopspeed * (1 - frametime * autocvar_sv_friction)
1228                          */
1229                 }
1230
1231                 // acceleration
1232                 wishdir = normalize(wishvel);
1233                 wishspeed = vlen(wishvel);
1234                 if (wishspeed > self.stat_sv_maxspeed*maxspd_mod)
1235                         wishspeed = self.stat_sv_maxspeed*maxspd_mod;
1236                 if (self.crouch)
1237                         wishspeed = wishspeed * 0.5;
1238                 if (time >= self.teleport_time)
1239                         PM_Accelerate(wishdir, wishspeed, wishspeed, autocvar_sv_accelerate*maxspd_mod, 1, 0, 0, 0);
1240         }
1241         else
1242         {
1243                 float wishspeed0;
1244                 // we get here if we ran out of ammo
1245                 if((self.items & IT_JETPACK) && self.BUTTON_HOOK && !(buttons_prev & 32) && self.ammo_fuel < 0.01)
1246                         sprint(self, "You don't have any fuel for the ^2Jetpack\n");
1247
1248                 if(maxspd_mod < 1)
1249                 {
1250                         maxairspd = autocvar_sv_maxairspeed*maxspd_mod;
1251                         airaccel = autocvar_sv_airaccelerate*maxspd_mod;
1252                 }
1253                 else
1254                 {
1255                         maxairspd = autocvar_sv_maxairspeed;
1256                         airaccel = autocvar_sv_airaccelerate;
1257                 }
1258                 // airborn
1259                 makevectors(self.v_angle_y * '0 1 0');
1260                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
1261                 // acceleration
1262                 wishdir = normalize(wishvel);
1263                 wishspeed = wishspeed0 = vlen(wishvel);
1264                 if (wishspeed0 > self.stat_sv_maxspeed*maxspd_mod)
1265                         wishspeed0 = self.stat_sv_maxspeed*maxspd_mod;
1266                 if (wishspeed > maxairspd)
1267                         wishspeed = maxairspd;
1268                 if (self.crouch)
1269                         wishspeed = wishspeed * 0.5;
1270                 if (time >= self.teleport_time)
1271                 {
1272                         float accelerating;
1273                         float wishspeed2;
1274                         float airaccelqw;
1275                         float strafity;
1276
1277                         airaccelqw = self.stat_sv_airaccel_qw;
1278                         accelerating = (self.velocity * wishdir > 0);
1279                         wishspeed2 = wishspeed;
1280
1281                         // CPM
1282                         if(autocvar_sv_airstopaccelerate)
1283                         {
1284                                 vector curdir;
1285                                 curdir = self.velocity;
1286                                 curdir_z = 0;
1287                                 curdir = normalize(curdir);
1288                                 airaccel = airaccel + (autocvar_sv_airstopaccelerate*maxspd_mod - airaccel) * max(0, -(curdir * wishdir));
1289                         }
1290                         // note that for straight forward jumping:
1291                         // step = accel * frametime * wishspeed0;
1292                         // accel  = bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
1293                         // -->
1294                         // dv/dt = accel * maxspeed (when slow)
1295                         // dv/dt = accel * maxspeed * (1 - accelqw) (when fast)
1296                         // log dv/dt = logaccel + logmaxspeed (when slow)
1297                         // log dv/dt = logaccel + logmaxspeed + log(1 - accelqw) (when fast)
1298                         strafity = IsMoveInDirection(self.movement, -90) + IsMoveInDirection(self.movement, +90); // if one is nonzero, other is always zero
1299                         if(autocvar_sv_maxairstrafespeed)
1300                                 wishspeed = min(wishspeed, GeomLerp(autocvar_sv_maxairspeed*maxspd_mod, strafity, autocvar_sv_maxairstrafespeed*maxspd_mod));
1301                         if(autocvar_sv_airstrafeaccelerate)
1302                                 airaccel = GeomLerp(airaccel, strafity, autocvar_sv_airstrafeaccelerate*maxspd_mod);
1303                         if(self.stat_sv_airstrafeaccel_qw)
1304                                 airaccelqw = copysign(1-GeomLerp(1-fabs(self.stat_sv_airaccel_qw), strafity, 1-fabs(self.stat_sv_airstrafeaccel_qw)), ((strafity > 0.5) ? self.stat_sv_airstrafeaccel_qw : self.stat_sv_airaccel_qw));
1305                         // !CPM
1306
1307                         if(autocvar_sv_warsowbunny_turnaccel && accelerating && self.movement_y == 0 && self.movement_x != 0)
1308                                 PM_AirAccelerate(wishdir, wishspeed);
1309                         else
1310                                 PM_Accelerate(wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, autocvar_sv_airaccel_qw_stretchfactor, autocvar_sv_airaccel_sideways_friction / maxairspd, self.stat_sv_airspeedlimit_nonqw);
1311
1312                         if(autocvar_sv_aircontrol)
1313                                 CPM_PM_Aircontrol(wishdir, wishspeed2);
1314                 }
1315         }
1316
1317         if((g_cts || g_race) && !IS_OBSERVER(self)) {
1318                 if(vlen(self.velocity - self.velocity_z * '0 0 1') > speedaward_speed) {
1319                         speedaward_speed = vlen(self.velocity - self.velocity_z * '0 0 1');
1320                         speedaward_holder = self.netname;
1321                         speedaward_uid = self.crypto_idfp;
1322                         speedaward_lastupdate = time;
1323                 }
1324                 if(speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1) {
1325                         string rr;
1326                         if(g_cts)
1327                                 rr = CTS_RECORD;
1328                         else
1329                                 rr = RACE_RECORD;
1330                         race_send_speedaward(MSG_ALL);
1331                         speedaward_lastsent = speedaward_speed;
1332                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "") {
1333                                 speedaward_alltimebest = speedaward_speed;
1334                                 speedaward_alltimebest_holder = speedaward_holder;
1335                                 speedaward_alltimebest_uid = speedaward_uid;
1336                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
1337                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
1338                                 race_send_speedaward_alltimebest(MSG_ALL);
1339                         }
1340                 }
1341         }
1342
1343         float xyspeed;
1344         xyspeed = vlen('1 0 0' * self.velocity_x + '0 1 0' * self.velocity_y);
1345         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge && autocvar_g_balance_nex_charge_velocity_rate && xyspeed > autocvar_g_balance_nex_charge_minspeed)
1346         {
1347                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
1348                 xyspeed = min(xyspeed, autocvar_g_balance_nex_charge_maxspeed);
1349                 f = (xyspeed - autocvar_g_balance_nex_charge_minspeed) / (autocvar_g_balance_nex_charge_maxspeed - autocvar_g_balance_nex_charge_minspeed);
1350                 // add the extra charge
1351                 self.nex_charge = min(1, self.nex_charge + autocvar_g_balance_nex_charge_velocity_rate * f * frametime);
1352         }
1353 :end
1354         if(self.flags & FL_ONGROUND)
1355                 self.lastground = time;
1356
1357         // conveyors: then break velocity again
1358         if(self.conveyor.state)
1359                 self.velocity += self.conveyor.movedir;
1360
1361         self.lastflags = self.flags;
1362         self.lastclassname = self.classname;
1363 }