qcsrc/server/cl_client.qc

   1 #include "waypointsprites.qh"
   2
   3 #include "cl_impulse.qh"
   4 #include "cl_player.qh"
   5 #include "ent_cs.qh"
   6 #include "g_subs.qh"
   7 #include "ipban.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "playerdemo.qh"
  12
  13 #include "bot/bot.qh"
  14 #include "bot/navigation.qh"
  15
  16 #include "weapons/hitplot.qh"
  17 #include "weapons/weaponsystem.qh"
  18
  19 #include "../common/net_notice.qh"
  20 #include "../common/physics.qh"
  21
  22 #include "../common/triggers/subs.qh"
  23 #include "../common/triggers/triggers.qh"
  24 #include "../common/triggers/trigger/secret.qh"
  25
  26 #include "../common/monsters/sv_monsters.qh"
  27
  28 #include "../warpzonelib/server.qh"
  29
  30 float c1, c2, c3, c4;
  31
  32 void send_CSQC_teamnagger() {
  33         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  34         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  35 }
  36
  37 float ClientData_Send(entity to, int sf)
  38 {
  39         if(to != self.owner)
  40         {
  41                 error("wtf");
  42                 return false;
  43         }
  44
  45         entity e;
  46
  47         e = to;
  48         if(IS_SPEC(to))
  49                 e = to.enemy;
  50
  51         sf = 0;
  52
  53         if(e.race_completed)
  54                 sf |= 1; // forced scoreboard
  55         if(to.spectatee_status)
  56                 sf |= 2; // spectator ent number follows
  57         if(e.zoomstate)
  58                 sf |= 4; // zoomed
  59         if(e.porto_v_angle_held)
  60                 sf |= 8; // angles held
  61
  62         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  63         WriteByte(MSG_ENTITY, sf);
  64
  65         if(sf & 2)
  66                 WriteByte(MSG_ENTITY, to.spectatee_status);
  67
  68         if(sf & 8)
  69         {
  70                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  71                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  72         }
  73
  74         return true;
  75 }
  76
  77 void ClientData_Attach()
  78 {
  79         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  80         self.clientdata.drawonlytoclient = self;
  81         self.clientdata.owner = self;
  82 }
  83
  84 void ClientData_Detach()
  85 {
  86         remove(self.clientdata);
  87         self.clientdata = world;
  88 }
  89
  90 void ClientData_Touch(entity e)
  91 {
  92         e.clientdata.SendFlags = 1;
  93
  94         // make it spectatable
  95         entity e2;
  96         FOR_EACH_REALCLIENT(e2)
  97         {
  98                 if(e2 != e)
  99                         if(IS_SPEC(e2))
 100                                 if(e2.enemy == e)
 101                                         e2.clientdata.SendFlags = 1;
 102         }
 103 }
 104
 105 .string netname_previous;
 106
 107 void SetSpectator(entity player, entity spectatee);
 108
 109
 110 /*
 111 =============
 112 CheckPlayerModel
 113
 114 Checks if the argument string can be a valid playermodel.
 115 Returns a valid one in doubt.
 116 =============
 117 */
 118 string FallbackPlayerModel;
 119 string CheckPlayerModel(string plyermodel) {
 120         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 121         {
 122                 // note: we cannot summon Don Strunzone here, some player may
 123                 // still have the model string set. In case anyone manages how
 124                 // to change a cvar default, we'll have a small leak here.
 125                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 126         }
 127         // only in right path
 128         if( substring(plyermodel,0,14) != "models/player/")
 129                 return FallbackPlayerModel;
 130         // only good file extensions
 131         if(substring(plyermodel,-4,4) != ".zym")
 132         if(substring(plyermodel,-4,4) != ".dpm")
 133         if(substring(plyermodel,-4,4) != ".iqm")
 134         if(substring(plyermodel,-4,4) != ".md3")
 135         if(substring(plyermodel,-4,4) != ".psk")
 136                 return FallbackPlayerModel;
 137         // forbid the LOD models
 138         if(substring(plyermodel, -9,5) == "_lod1")
 139                 return FallbackPlayerModel;
 140         if(substring(plyermodel, -9,5) == "_lod2")
 141                 return FallbackPlayerModel;
 142         if(plyermodel != strtolower(plyermodel))
 143                 return FallbackPlayerModel;
 144         // also, restrict to server models
 145         if(autocvar_sv_servermodelsonly)
 146         {
 147                 if(!fexists(plyermodel))
 148                         return FallbackPlayerModel;
 149         }
 150         return plyermodel;
 151 }
 152
 153 void setplayermodel(entity e, string modelname)
 154 {
 155         precache_model(modelname);
 156         setmodel(e, modelname);
 157         player_setupanimsformodel();
 158         UpdatePlayerSounds();
 159 }
 160
 161 /*
 162 =============
 163 PutObserverInServer
 164
 165 putting a client as observer in the server
 166 =============
 167 */
 168 void FixPlayermodel();
 169 void PutObserverInServer (void)
 170 {
 171         entity  spot;
 172     self.hud = HUD_NORMAL;
 173
 174         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 175
 176         spot = SelectSpawnPoint (true);
 177         if(!spot)
 178                 error("No spawnpoints for observers?!?\n");
 179         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 180
 181         if(IS_REAL_CLIENT(self))
 182         {
 183                 msg_entity = self;
 184                 WriteByte(MSG_ONE, SVC_SETVIEW);
 185                 WriteEntity(MSG_ONE, self);
 186         }
 187
 188         self.frags = FRAGS_SPECTATOR;
 189
 190         MUTATOR_CALLHOOK(MakePlayerObserver);
 191
 192         Portal_ClearAll(self);
 193
 194         Unfreeze(self);
 195
 196         if(self.alivetime)
 197         {
 198                 if(!warmup_stage)
 199                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 200                 self.alivetime = 0;
 201         }
 202
 203         if(self.vehicle)
 204                 vehicles_exit(VHEF_RELESE);
 205
 206         WaypointSprite_PlayerDead();
 207
 208         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 209                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 210
 211         if(self.killcount != -666)
 212         {
 213                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 214                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 215                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 216
 217                 if(self.just_joined == false) {
 218                         LogTeamchange(self.playerid, -1, 4);
 219                 } else
 220                         self.just_joined = false;
 221         }
 222
 223         PlayerScore_Clear(self); // clear scores when needed
 224
 225         accuracy_resend(self);
 226
 227         self.spectatortime = time;
 228
 229         self.classname = "observer";
 230         self.iscreature = false;
 231         self.teleportable = TELEPORT_SIMPLE;
 232         self.damagedbycontents = false;
 233         self.health = -666;
 234         self.takedamage = DAMAGE_NO;
 235         self.solid = SOLID_NOT;
 236         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 237         self.flags = FL_CLIENT | FL_NOTARGET;
 238         self.armorvalue = 666;
 239         self.effects = 0;
 240         self.armorvalue = autocvar_g_balance_armor_start;
 241         self.pauserotarmor_finished = 0;
 242         self.pauserothealth_finished = 0;
 243         self.pauseregen_finished = 0;
 244         self.damageforcescale = 0;
 245         self.death_time = 0;
 246         self.respawn_flags = 0;
 247         self.respawn_time = 0;
 248         self.stat_respawn_time = 0;
 249         self.alpha = 0;
 250         self.scale = 0;
 251         self.fade_time = 0;
 252         self.pain_frame = 0;
 253         self.pain_finished = 0;
 254         self.strength_finished = 0;
 255         self.invincible_finished = 0;
 256         self.superweapons_finished = 0;
 257         self.pushltime = 0;
 258         self.istypefrag = 0;
 259         self.think = func_null;
 260         self.nextthink = 0;
 261         self.hook_time = 0;
 262         self.deadflag = DEAD_NO;
 263         self.angles = spot.angles;
 264         self.angles_z = 0;
 265         self.fixangle = true;
 266         self.crouch = false;
 267         self.revival_time = 0;
 268
 269         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 270         self.prevorigin = self.origin;
 271         self.items = 0;
 272         self.weapons = '0 0 0';
 273         self.model = "";
 274         FixPlayermodel();
 275         setmodel(self, "null");
 276         self.drawonlytoclient = self;
 277
 278         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 279         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 280
 281         self.weapon = 0;
 282         self.weaponname = "";
 283         self.switchingweapon = 0;
 284         self.weaponmodel = "";
 285         self.weaponentity = world;
 286         self.exteriorweaponentity = world;
 287         self.killcount = -666;
 288         self.velocity = '0 0 0';
 289         self.avelocity = '0 0 0';
 290         self.punchangle = '0 0 0';
 291         self.punchvector = '0 0 0';
 292         self.oldvelocity = self.velocity;
 293         self.fire_endtime = -1;
 294         self.event_damage = func_null;
 295 }
 296
 297 .float model_randomizer;
 298 void FixPlayermodel()
 299 {
 300         string defaultmodel;
 301         float defaultskin, chmdl, oldskin, n, i;
 302         vector m1, m2;
 303
 304         defaultmodel = "";
 305         defaultskin = 0;
 306         chmdl = false;
 307
 308         if(autocvar_sv_defaultcharacter == 1)
 309         {
 310                 if(teamplay)
 311                 {
 312                         string s;
 313                         s = Static_Team_ColorName_Lower(self.team);
 314                         if(s != "neutral")
 315                         {
 316                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 317                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 318                         }
 319                 }
 320
 321                 if(defaultmodel == "")
 322                 {
 323                         defaultmodel = autocvar_sv_defaultplayermodel;
 324                         defaultskin = autocvar_sv_defaultplayerskin;
 325                 }
 326
 327                 n = tokenize_console(defaultmodel);
 328                 if(n > 0)
 329                 {
 330                         defaultmodel = argv(floor(n * self.model_randomizer));
 331                         // However, do NOT randomize if the player-selected model is in the list.
 332                         for (i = 0; i < n; ++i)
 333                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 334                                         defaultmodel = argv(i);
 335                 }
 336
 337                 i = strstrofs(defaultmodel, ":", 0);
 338                 if(i >= 0)
 339                 {
 340                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 341                         defaultmodel = substring(defaultmodel, 0, i);
 342                 }
 343         }
 344
 345         if(defaultmodel != "")
 346         {
 347                 if (defaultmodel != self.model)
 348                 {
 349                         m1 = self.mins;
 350                         m2 = self.maxs;
 351                         setplayermodel (self, defaultmodel);
 352                         setsize (self, m1, m2);
 353                         chmdl = true;
 354                 }
 355
 356                 oldskin = self.skin;
 357                 self.skin = defaultskin;
 358         } else {
 359                 if (self.playermodel != self.model || self.playermodel == "")
 360                 {
 361                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 362                         m1 = self.mins;
 363                         m2 = self.maxs;
 364                         setplayermodel (self, self.playermodel);
 365                         setsize (self, m1, m2);
 366                         chmdl = true;
 367                 }
 368
 369                 oldskin = self.skin;
 370                 self.skin = stof(self.playerskin);
 371         }
 372
 373         if(chmdl || oldskin != self.skin) // model or skin has changed
 374         {
 375                 self.species = player_getspecies(); // update species
 376                 UpdatePlayerSounds(); // update skin sounds
 377         }
 378
 379         if(!teamplay)
 380                 if(strlen(autocvar_sv_defaultplayercolors))
 381                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 382                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 383 }
 384
 385 /*
 386 =============
 387 PutClientInServer
 388
 389 Called when a client spawns in the server
 390 =============
 391 */
 392 void PutClientInServer (void)
 393 {
 394         if(IS_BOT_CLIENT(self))
 395                 self.classname = "player";
 396         else if(IS_REAL_CLIENT(self))
 397         {
 398                 msg_entity = self;
 399                 WriteByte(MSG_ONE, SVC_SETVIEW);
 400                 WriteEntity(MSG_ONE, self);
 401         }
 402
 403         SetSpectator(self, world);
 404
 405         // reset player keys
 406         self.itemkeys = 0;
 407
 408         MUTATOR_CALLHOOK(PutClientInServer);
 409
 410         if(gameover)
 411                 self.classname = "observer";
 412
 413         if(IS_PLAYER(self))
 414         {
 415                 entity spot, oldself;
 416                 float j;
 417
 418                 accuracy_resend(self);
 419
 420                 if(self.team < 0)
 421                         JoinBestTeam(self, false, true);
 422
 423                 spot = SelectSpawnPoint (false);
 424                 if(!spot)
 425                 {
 426                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 427                         return; // spawn failed
 428                 }
 429
 430                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 431
 432                 if(self.vehicle)
 433                         vehicles_exit(VHEF_RELESE);
 434
 435                 self.classname = "player";
 436                 self.wasplayer = true;
 437                 self.iscreature = true;
 438                 self.teleportable = TELEPORT_NORMAL;
 439                 self.damagedbycontents = true;
 440                 self.movetype = MOVETYPE_WALK;
 441                 self.solid = SOLID_SLIDEBOX;
 442                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 443                 if(autocvar_g_playerclip_collisions)
 444                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 445                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 446                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 447                 self.frags = FRAGS_PLAYER;
 448                 if(INDEPENDENT_PLAYERS)
 449                         MAKE_INDEPENDENT_PLAYER(self);
 450                 self.flags = FL_CLIENT;
 451                 if(autocvar__notarget)
 452                         self.flags |= FL_NOTARGET;
 453                 self.takedamage = DAMAGE_AIM;
 454                 self.effects = 0;
 455                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 456                 self.air_finished = time + 12;
 457                 self.dmg = 2;
 458                 if(WEP_CVAR(vortex, charge))
 459                 {
 460                         if(WEP_CVAR_SEC(vortex, chargepool))
 461                                 self.vortex_chargepool_ammo = 1;
 462                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 463                 }
 464
 465                 if(warmup_stage)
 466                 {
 467                         self.ammo_shells = warmup_start_ammo_shells;
 468                         self.ammo_nails = warmup_start_ammo_nails;
 469                         self.ammo_rockets = warmup_start_ammo_rockets;
 470                         self.ammo_cells = warmup_start_ammo_cells;
 471                         self.ammo_plasma = warmup_start_ammo_plasma;
 472                         self.ammo_fuel = warmup_start_ammo_fuel;
 473                         self.health = warmup_start_health;
 474                         self.armorvalue = warmup_start_armorvalue;
 475                         self.weapons = WARMUP_START_WEAPONS;
 476                 }
 477                 else
 478                 {
 479                         self.ammo_shells = start_ammo_shells;
 480                         self.ammo_nails = start_ammo_nails;
 481                         self.ammo_rockets = start_ammo_rockets;
 482                         self.ammo_cells = start_ammo_cells;
 483                         self.ammo_plasma = start_ammo_plasma;
 484                         self.ammo_fuel = start_ammo_fuel;
 485                         self.health = start_health;
 486                         self.armorvalue = start_armorvalue;
 487                         self.weapons = start_weapons;
 488                 }
 489
 490                 if(self.weapons & WEPSET_SUPERWEAPONS)
 491                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 492                 else
 493                         self.superweapons_finished = 0;
 494
 495                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 496                 {
 497                         if(g_weaponarena_random_with_blaster)
 498                                 self.weapons &= ~WEPSET_BLASTER;
 499                         W_RandomWeapons(self, g_weaponarena_random);
 500                         if(g_weaponarena_random_with_blaster)
 501                                 self.weapons |= WEPSET_BLASTER;
 502                 }
 503
 504                 self.items = start_items;
 505
 506                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 507                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 508                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 509                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 510                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 511                 //extend the pause of rotting if client was reset at the beginning of the countdown
 512                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 513                         self.spawnshieldtime += game_starttime - time;
 514                         self.pauserotarmor_finished += game_starttime - time;
 515                         self.pauserothealth_finished += game_starttime - time;
 516                         self.pauseregen_finished += game_starttime - time;
 517                 }
 518                 self.damageforcescale = 2;
 519                 self.death_time = 0;
 520                 self.respawn_flags = 0;
 521                 self.respawn_time = 0;
 522                 self.stat_respawn_time = 0;
 523                 self.scale = 0;
 524                 self.fade_time = 0;
 525                 self.pain_frame = 0;
 526                 self.pain_finished = 0;
 527                 self.strength_finished = 0;
 528                 self.invincible_finished = 0;
 529                 self.pushltime = 0;
 530                 // players have no think function
 531                 self.think = func_null;
 532                 self.nextthink = 0;
 533                 self.hook_time = 0;
 534                 self.dmg_team = 0;
 535                 self.ballistics_density = autocvar_g_ballistics_density_player;
 536
 537                 self.metertime = 0;
 538
 539                 self.deadflag = DEAD_NO;
 540
 541                 self.angles = spot.angles;
 542
 543                 self.angles_z = 0; // never spawn tilted even if the spot says to
 544                 if(IS_BOT_CLIENT(self))
 545                         self.v_angle = self.angles;
 546                 self.fixangle = true; // turn this way immediately
 547                 self.velocity = '0 0 0';
 548                 self.avelocity = '0 0 0';
 549                 self.punchangle = '0 0 0';
 550                 self.punchvector = '0 0 0';
 551                 self.oldvelocity = self.velocity;
 552                 self.fire_endtime = -1;
 553                 self.revival_time = 0;
 554
 555                 entity spawnevent = spawn();
 556                 spawnevent.owner = self;
 557                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 558
 559                 // Cut off any still running player sounds.
 560                 stopsound(self, CH_PLAYER_SINGLE);
 561
 562                 self.model = "";
 563                 FixPlayermodel();
 564                 self.drawonlytoclient = world;
 565
 566                 self.crouch = false;
 567                 self.view_ofs = PL_VIEW_OFS;
 568                 setsize (self, PL_MIN, PL_MAX);
 569                 self.spawnorigin = spot.origin;
 570                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 571                 // don't reset back to last position, even if new position is stuck in solid
 572                 self.oldorigin = self.origin;
 573                 self.prevorigin = self.origin;
 574                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 575                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 576         self.hud = HUD_NORMAL;
 577
 578                 self.event_damage = PlayerDamage;
 579
 580                 self.bot_attack = true;
 581                 self.monster_attack = true;
 582
 583                 self.spider_slowness = 0;
 584
 585                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 586
 587                 if(self.killcount == -666) {
 588                         PlayerScore_Clear(self);
 589                         self.killcount = 0;
 590                 }
 591
 592                 CL_SpawnWeaponentity();
 593                 self.alpha = default_player_alpha;
 594                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 595                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 596
 597                 self.speedrunning = false;
 598
 599                 //stuffcmd(self, "chase_active 0");
 600                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 601
 602                 target_voicescript_clear(self);
 603
 604                 // reset fields the weapons may use
 605                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 606                 {
 607                         WEP_ACTION(j, WR_RESETPLAYER);
 608
 609                         // all weapons must be fully loaded when we spawn
 610                         entity e = get_weaponinfo(j);
 611                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 612                                 self.(weapon_load[j]) = e.reloading_ammo;
 613                 }
 614
 615                 oldself = self;
 616                 self = spot;
 617                         activator = oldself;
 618                                 string s;
 619                                 s = self.target;
 620                                 self.target = string_null;
 621                                 SUB_UseTargets();
 622                                 self.target = s;
 623                         activator = world;
 624                 self = oldself;
 625
 626                 Unfreeze(self);
 627
 628                 spawn_spot = spot;
 629                 MUTATOR_CALLHOOK(PlayerSpawn);
 630
 631                 if(autocvar_spawn_debug)
 632                 {
 633                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 634                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 635                 }
 636
 637                 self.switchweapon = w_getbestweapon(self);
 638                 self.cnt = -1; // W_LastWeapon will not complain
 639                 self.weapon = 0;
 640                 self.weaponname = "";
 641                 self.switchingweapon = 0;
 642
 643                 if(!warmup_stage)
 644                         if(!self.alivetime)
 645                                 self.alivetime = time;
 646
 647                 antilag_clear(self);
 648         }
 649         else if(IS_OBSERVER(self))
 650         {
 651                 PutObserverInServer ();
 652         }
 653 }
 654
 655 .float ebouncefactor, ebouncestop; // electro's values
 656 // TODO do we need all these fields, or should we stop autodetecting runtime
 657 // changes and just have a console command to update this?
 658 float ClientInit_SendEntity(entity to, float sf)
 659 {
 660         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 661         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 662         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 663         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 664         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 665         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 666         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 667         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 668         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 669         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 670
 671         if(sv_foginterval && world.fog != "")
 672                 WriteString(MSG_ENTITY, world.fog);
 673         else
 674                 WriteString(MSG_ENTITY, "");
 675         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 676         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 677         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 678         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 679         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 680         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 681         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 682         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 683         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 684         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 685         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 686         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 687         return true;
 688 }
 689
 690 void ClientInit_CheckUpdate()
 691 {
 692         self.nextthink = time;
 693         if(self.count != autocvar_g_balance_armor_blockpercent)
 694         {
 695                 self.count = autocvar_g_balance_armor_blockpercent;
 696                 self.SendFlags |= 1;
 697         }
 698         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 699         {
 700                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 701                 self.SendFlags |= 1;
 702         }
 703         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 704         {
 705                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 706                 self.SendFlags |= 1;
 707         }
 708         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 709         {
 710                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 711                 self.SendFlags |= 1;
 712         }
 713         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 714         {
 715                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 716                 self.SendFlags |= 1;
 717         }
 718 }
 719
 720 void ClientInit_Spawn()
 721 {
 722         entity o;
 723         entity e;
 724         e = spawn();
 725         e.classname = "clientinit";
 726         e.think = ClientInit_CheckUpdate;
 727         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 728
 729         o = self;
 730         self = e;
 731         ClientInit_CheckUpdate();
 732         self = o;
 733 }
 734
 735 /*
 736 =============
 737 SetNewParms
 738 =============
 739 */
 740 void SetNewParms (void)
 741 {
 742         // initialize parms for a new player
 743         parm1 = -(86400 * 366);
 744 }
 745
 746 /*
 747 =============
 748 SetChangeParms
 749 =============
 750 */
 751 void SetChangeParms (void)
 752 {
 753         // save parms for level change
 754         parm1 = self.parm_idlesince - time;
 755 }
 756
 757 /*
 758 =============
 759 DecodeLevelParms
 760 =============
 761 */
 762 void DecodeLevelParms (void)
 763 {
 764         // load parms
 765         self.parm_idlesince = parm1;
 766         if(self.parm_idlesince == -(86400 * 366))
 767                 self.parm_idlesince = time;
 768
 769         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 770         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 771 }
 772
 773 /*
 774 =============
 775 ClientKill
 776
 777 Called when a client types 'kill' in the console
 778 =============
 779 */
 780
 781 .float clientkill_nexttime;
 782 void ClientKill_Now_TeamChange()
 783 {
 784         if(self.killindicator_teamchange == -1)
 785         {
 786                 JoinBestTeam( self, false, true );
 787         }
 788         else if(self.killindicator_teamchange == -2)
 789         {
 790                 if(blockSpectators)
 791                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 792                 PutObserverInServer();
 793         }
 794         else
 795                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 796         self.killindicator_teamchange = 0;
 797 }
 798
 799 void ClientKill_Now()
 800 {
 801         if(self.vehicle)
 802         {
 803             vehicles_exit(VHEF_RELESE);
 804             if(!self.killindicator_teamchange)
 805             {
 806             self.vehicle_health = -1;
 807             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 808             }
 809         }
 810
 811         if(self.killindicator && !wasfreed(self.killindicator))
 812                 remove(self.killindicator);
 813
 814         self.killindicator = world;
 815
 816         if(self.killindicator_teamchange)
 817                 ClientKill_Now_TeamChange();
 818
 819         if(IS_PLAYER(self))
 820                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 821
 822         // now I am sure the player IS dead
 823 }
 824 void KillIndicator_Think()
 825 {
 826         if (gameover)
 827         {
 828                 self.owner.killindicator = world;
 829                 remove(self);
 830                 return;
 831         }
 832
 833         if (self.owner.alpha < 0 && !self.owner.vehicle)
 834         {
 835                 self.owner.killindicator = world;
 836                 remove(self);
 837                 return;
 838         }
 839
 840         if(self.cnt <= 0)
 841         {
 842                 self = self.owner;
 843                 ClientKill_Now(); // no oldself needed
 844                 return;
 845         }
 846     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 847     {
 848         self.nextthink = time + 1;
 849         self.cnt -= 1;
 850     }
 851         else
 852         {
 853                 if(self.cnt <= 10)
 854                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 855                 if(IS_REAL_CLIENT(self.owner))
 856                 {
 857                         if(self.cnt <= 10)
 858                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 859                 }
 860                 self.nextthink = time + 1;
 861                 self.cnt -= 1;
 862         }
 863 }
 864
 865 float clientkilltime;
 866 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 867 {
 868         float killtime;
 869         float starttime;
 870         entity e;
 871
 872         if (gameover)
 873                 return;
 874
 875         killtime = autocvar_g_balance_kill_delay;
 876
 877         if(g_race_qualifying || g_cts)
 878                 killtime = 0;
 879
 880     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 881     {
 882                 remove(self.killindicator);
 883                 self.killindicator = world;
 884
 885         ClientKill_Now(); // allow instant kill in this case
 886         return;
 887     }
 888
 889         self.killindicator_teamchange = targetteam;
 890
 891     if(!self.killindicator)
 892         {
 893                 if(self.deadflag == DEAD_NO)
 894                 {
 895                         killtime = max(killtime, self.clientkill_nexttime - time);
 896                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 897                 }
 898
 899                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 900                 {
 901                         ClientKill_Now();
 902                 }
 903                 else
 904                 {
 905                         starttime = max(time, clientkilltime);
 906
 907                         self.killindicator = spawn();
 908                         self.killindicator.owner = self;
 909                         self.killindicator.scale = 0.5;
 910                         setattachment(self.killindicator, self, "");
 911                         setorigin(self.killindicator, '0 0 52');
 912                         self.killindicator.think = KillIndicator_Think;
 913                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 914                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 915                         self.killindicator.cnt = ceil(killtime);
 916                         self.killindicator.count = bound(0, ceil(killtime), 10);
 917                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 918
 919                         for(e = world; (e = find(e, classname, "body")) != world; )
 920                         {
 921                                 if(e.enemy != self)
 922                                         continue;
 923                                 e.killindicator = spawn();
 924                                 e.killindicator.owner = e;
 925                                 e.killindicator.scale = 0.5;
 926                                 setattachment(e.killindicator, e, "");
 927                                 setorigin(e.killindicator, '0 0 52');
 928                                 e.killindicator.think = KillIndicator_Think;
 929                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 930                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 931                                 e.killindicator.cnt = ceil(killtime);
 932                         }
 933                         self.lip = 0;
 934                 }
 935         }
 936         if(self.killindicator)
 937         {
 938                 if(targetteam == 0) // just die
 939                 {
 940                         self.killindicator.colormod = '0 0 0';
 941                         if(IS_REAL_CLIENT(self))
 942                         if(self.killindicator.cnt > 0)
 943                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 944                 }
 945                 else if(targetteam == -1) // auto
 946                 {
 947                         self.killindicator.colormod = '0 1 0';
 948                         if(IS_REAL_CLIENT(self))
 949                         if(self.killindicator.cnt > 0)
 950                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 951                 }
 952                 else if(targetteam == -2) // spectate
 953                 {
 954                         self.killindicator.colormod = '0.5 0.5 0.5';
 955                         if(IS_REAL_CLIENT(self))
 956                         if(self.killindicator.cnt > 0)
 957                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 958                 }
 959                 else
 960                 {
 961                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 962                         if(IS_REAL_CLIENT(self))
 963                         if(self.killindicator.cnt > 0)
 964                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 965                 }
 966         }
 967
 968 }
 969
 970 void ClientKill (void)
 971 {
 972         if(gameover) return;
 973         if(self.player_blocked) return;
 974         if(self.frozen) return;
 975
 976         ClientKill_TeamChange(0);
 977 }
 978
 979 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 980 {
 981     e.killindicator = spawn();
 982     e.killindicator.owner = e;
 983     e.killindicator.think = KillIndicator_Think;
 984     e.killindicator.nextthink = time + (e.lip) * 0.05;
 985     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 986     e.killindicator.health = 1; // this is used to indicate that it should be silent
 987     e.lip = 0;
 988 }
 989
 990 void FixClientCvars(entity e)
 991 {
 992         // send prediction settings to the client
 993         stuffcmd(e, "\nin_bindmap 0 0\n");
 994         if(g_race || g_cts)
 995                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 996         if(autocvar_g_antilag == 3) // client side hitscan
 997                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 998         if(autocvar_sv_gentle)
 999                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1000 }
1001
1002 float PlayerInIDList(entity p, string idlist)
1003 {
1004         float n, i;
1005         string s;
1006
1007         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1008         if (!p.crypto_idfp)
1009                 return 0;
1010
1011         // this function allows abbreviated player IDs too!
1012         n = tokenize_console(idlist);
1013         for(i = 0; i < n; ++i)
1014         {
1015                 s = argv(i);
1016                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1017                         return 1;
1018         }
1019
1020         return 0;
1021 }
1022
1023 #ifdef DP_EXT_PRECONNECT
1024 /*
1025 =============
1026 ClientPreConnect
1027
1028 Called once (not at each match start) when a client begins a connection to the server
1029 =============
1030 */
1031 void ClientPreConnect (void)
1032 {
1033         if(autocvar_sv_eventlog)
1034         {
1035                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1036                         self.playerid,
1037                         num_for_edict(self),
1038                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1039                 ));
1040         }
1041 }
1042 #endif
1043
1044 /*
1045 =============
1046 ClientConnect
1047
1048 Called when a client connects to the server
1049 =============
1050 */
1051 void DecodeLevelParms (void);
1052 //void dom_player_join_team(entity pl);
1053 void set_dom_state(entity e);
1054 void ClientConnect (void)
1055 {
1056         float t;
1057
1058         if(IS_CLIENT(self))
1059         {
1060                 print("Warning: ClientConnect, but already connected!\n");
1061                 return;
1062         }
1063
1064         if(Ban_MaybeEnforceBanOnce(self))
1065                 return;
1066
1067         DecodeLevelParms();
1068
1069 #ifdef WATERMARK
1070         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1071 #endif
1072
1073         self.classname = "player_joining";
1074
1075         self.flags = FL_CLIENT;
1076         self.version_nagtime = time + 10 + random() * 10;
1077
1078         if(player_count<0)
1079         {
1080                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1081                 player_count = 0;
1082         }
1083
1084         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1085
1086         PlayerScore_Attach(self);
1087         ClientData_Attach();
1088         accuracy_init(self);
1089
1090         bot_clientconnect();
1091
1092         playerdemo_init();
1093
1094         anticheat_init();
1095
1096         // identify the right forced team
1097         if(autocvar_g_campaign)
1098         {
1099                 if(IS_REAL_CLIENT(self)) // only players, not bots
1100                 {
1101                         switch(autocvar_g_campaign_forceteam)
1102                         {
1103                                 case 1: self.team_forced = NUM_TEAM_1; break;
1104                                 case 2: self.team_forced = NUM_TEAM_2; break;
1105                                 case 3: self.team_forced = NUM_TEAM_3; break;
1106                                 case 4: self.team_forced = NUM_TEAM_4; break;
1107                                 default: self.team_forced = 0;
1108                         }
1109                 }
1110         }
1111         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1112                 self.team_forced = NUM_TEAM_1;
1113         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1114                 self.team_forced = NUM_TEAM_2;
1115         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1116                 self.team_forced = NUM_TEAM_3;
1117         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1118                 self.team_forced = NUM_TEAM_4;
1119         else if(autocvar_g_forced_team_otherwise == "red")
1120                 self.team_forced = NUM_TEAM_1;
1121         else if(autocvar_g_forced_team_otherwise == "blue")
1122                 self.team_forced = NUM_TEAM_2;
1123         else if(autocvar_g_forced_team_otherwise == "yellow")
1124                 self.team_forced = NUM_TEAM_3;
1125         else if(autocvar_g_forced_team_otherwise == "pink")
1126                 self.team_forced = NUM_TEAM_4;
1127         else if(autocvar_g_forced_team_otherwise == "spectate")
1128                 self.team_forced = -1;
1129         else if(autocvar_g_forced_team_otherwise == "spectator")
1130                 self.team_forced = -1;
1131         else
1132                 self.team_forced = 0;
1133
1134         if(!teamplay)
1135                 if(self.team_forced > 0)
1136                         self.team_forced = 0;
1137
1138         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1139
1140         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1141                 self.classname = "observer";
1142         } else {
1143                 if(teamplay)
1144                 {
1145                         if(autocvar_g_balance_teams)
1146                         {
1147                                 self.classname = "player";
1148                                 campaign_bots_may_start = 1;
1149                         }
1150                         else
1151                         {
1152                                 self.classname = "observer"; // do it anyway
1153                         }
1154                 }
1155                 else
1156                 {
1157                         self.classname = "player";
1158                         campaign_bots_may_start = 1;
1159                 }
1160         }
1161
1162         self.playerid = (playerid_last = playerid_last + 1);
1163
1164         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1165
1166     if(IS_BOT_CLIENT(self))
1167         PlayerStats_GameReport_AddPlayer(self);
1168
1169         if(autocvar_sv_eventlog)
1170                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1171
1172         LogTeamchange(self.playerid, self.team, 1);
1173
1174         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1175
1176         self.netname_previous = strzone(self.netname);
1177
1178         if(IS_PLAYER(self) && teamplay)
1179                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1180         else
1181                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1182
1183         stuffcmd(self, strcat(clientstuff, "\n"));
1184         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1185
1186         FixClientCvars(self);
1187
1188         // spawnfunc_waypoint sprites
1189         WaypointSprite_InitClient(self);
1190
1191         // Wazat's grappling hook
1192         SetGrappleHookBindings();
1193
1194         // Jetpack binds
1195         stuffcmd(self, "alias +jetpack +button10\n");
1196         stuffcmd(self, "alias -jetpack -button10\n");
1197
1198         // get version info from player
1199         stuffcmd(self, "cmd clientversion $gameversion\n");
1200
1201         // get other cvars from player
1202         GetCvars(0);
1203
1204         // notify about available teams
1205         if(teamplay)
1206         {
1207                 CheckAllowedTeams(self);
1208                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1209                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1210         }
1211         else
1212                 stuffcmd(self, "set _teams_available 0\n");
1213
1214         attach_entcs();
1215
1216         bot_relinkplayerlist();
1217
1218         self.spectatortime = time;
1219         if(blockSpectators)
1220         {
1221                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1222         }
1223
1224         self.jointime = time;
1225         self.allowed_timeouts = autocvar_sv_timeout_number;
1226
1227         if(IS_REAL_CLIENT(self))
1228         {
1229                 if(!autocvar_g_campaign)
1230                 {
1231                         self.motd_actived_time = -1;
1232                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1233                 }
1234
1235                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1236                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1237         }
1238
1239         if(!sv_foginterval && world.fog != "")
1240                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1241
1242         W_HitPlotOpen(self);
1243
1244         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1245                 send_CSQC_teamnagger();
1246
1247         CheatInitClient();
1248
1249         CSQCMODEL_AUTOINIT();
1250
1251         self.model_randomizer = random();
1252
1253         if(IS_REAL_CLIENT(self))
1254                 sv_notice_join();
1255
1256         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1257                 entity oldself = self;
1258                 self = e;
1259                 e.init_for_player(oldself);
1260                 self = oldself;
1261         }
1262
1263         MUTATOR_CALLHOOK(ClientConnect);
1264 }
1265 /*
1266 =============
1267 ClientDisconnect
1268
1269 Called when a client disconnects from the server
1270 =============
1271 */
1272 .entity chatbubbleentity;
1273 void ReadyCount();
1274 void ClientDisconnect (void)
1275 {
1276         if(self.vehicle)
1277             vehicles_exit(VHEF_RELESE);
1278
1279         if (!IS_CLIENT(self))
1280         {
1281                 print("Warning: ClientDisconnect without ClientConnect\n");
1282                 return;
1283         }
1284
1285         PlayerStats_GameReport_FinalizePlayer(self);
1286
1287         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1288
1289         CheatShutdownClient();
1290
1291         W_HitPlotClose(self);
1292
1293         anticheat_report();
1294         anticheat_shutdown();
1295
1296         playerdemo_shutdown();
1297
1298         bot_clientdisconnect();
1299
1300         if(self.entcs)
1301                 detach_entcs();
1302
1303         if(autocvar_sv_eventlog)
1304                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1305
1306         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1307
1308         MUTATOR_CALLHOOK(ClientDisconnect);
1309
1310         Portal_ClearAll(self);
1311
1312         Unfreeze(self);
1313
1314         RemoveGrapplingHook(self);
1315
1316         // Here, everything has been done that requires this player to be a client.
1317
1318         self.flags &= ~FL_CLIENT;
1319
1320         if (self.chatbubbleentity)
1321                 remove (self.chatbubbleentity);
1322
1323         if (self.killindicator)
1324                 remove (self.killindicator);
1325
1326         WaypointSprite_PlayerGone();
1327
1328         bot_relinkplayerlist();
1329
1330         accuracy_free(self);
1331         ClientData_Detach();
1332         PlayerScore_Detach(self);
1333
1334         if(self.netname_previous)
1335                 strunzone(self.netname_previous);
1336         if(self.clientstatus)
1337                 strunzone(self.clientstatus);
1338         if(self.weaponorder_byimpulse)
1339                 strunzone(self.weaponorder_byimpulse);
1340
1341         ClearPlayerSounds();
1342
1343         if(self.personal)
1344                 remove(self.personal);
1345
1346         self.playerid = 0;
1347         ReadyCount();
1348
1349         // free cvars
1350         GetCvars(-1);
1351 }
1352
1353 .float BUTTON_CHAT;
1354 void ChatBubbleThink()
1355 {
1356         self.nextthink = time;
1357         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1358         {
1359                 if(self.owner) // but why can that ever be world?
1360                         self.owner.chatbubbleentity = world;
1361                 remove(self);
1362                 return;
1363         }
1364         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1365 #ifdef TETRIS
1366                 || self.owner.tetris_on
1367 #endif
1368         )
1369                 self.model = self.mdl;
1370         else
1371                 self.model = "";
1372 }
1373
1374 void UpdateChatBubble()
1375 {
1376         if (self.alpha < 0)
1377                 return;
1378         // spawn a chatbubble entity if needed
1379         if (!self.chatbubbleentity)
1380         {
1381                 self.chatbubbleentity = spawn();
1382                 self.chatbubbleentity.owner = self;
1383                 self.chatbubbleentity.exteriormodeltoclient = self;
1384                 self.chatbubbleentity.think = ChatBubbleThink;
1385                 self.chatbubbleentity.nextthink = time;
1386                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1387                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1388                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs.z * '0 0 1');
1389                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1390                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1391                 self.chatbubbleentity.model = "";
1392                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1393         }
1394 }
1395
1396
1397 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1398 // added to the model skins
1399 /*void UpdateColorModHack()
1400 {
1401         float c;
1402         c = self.clientcolors & 15;
1403         // LordHavoc: only bothering to support white, green, red, yellow, blue
1404              if (!teamplay) self.colormod = '0 0 0';
1405         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1406         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1407         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1408         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1409         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1410         else self.colormod = '1 1 1';
1411 }*/
1412
1413 void respawn(void)
1414 {
1415         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1416         {
1417                 self.solid = SOLID_NOT;
1418                 self.takedamage = DAMAGE_NO;
1419                 self.movetype = MOVETYPE_FLY;
1420                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1421                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1422                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1423                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1424                 if(autocvar_g_respawn_ghosts_maxtime)
1425                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1426         }
1427
1428         CopyBody(1);
1429
1430         self.effects |= EF_NODRAW; // prevent another CopyBody
1431         PutClientInServer();
1432 }
1433
1434 void play_countdown(float finished, string samp)
1435 {
1436         if(IS_REAL_CLIENT(self))
1437                 if(floor(finished - time - frametime) != floor(finished - time))
1438                         if(finished - time < 6)
1439                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1440 }
1441
1442 void player_powerups (void)
1443 {
1444         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1445         olditems = self.items;
1446
1447         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1448                 self.modelflags |= MF_ROCKET;
1449         else
1450                 self.modelflags &= ~MF_ROCKET;
1451
1452         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1453
1454         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1455                 return;
1456
1457         Fire_ApplyDamage(self);
1458         Fire_ApplyEffect(self);
1459
1460         if (!g_instagib)
1461         {
1462                 if (self.items & IT_STRENGTH)
1463                 {
1464                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1465                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1466                         if (time > self.strength_finished)
1467                         {
1468                                 self.items = self.items - (self.items & IT_STRENGTH);
1469                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1470                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1471                         }
1472                 }
1473                 else
1474                 {
1475                         if (time < self.strength_finished)
1476                         {
1477                                 self.items = self.items | IT_STRENGTH;
1478                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1479                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1480                         }
1481                 }
1482                 if (self.items & IT_INVINCIBLE)
1483                 {
1484                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1485                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1486                         if (time > self.invincible_finished)
1487                         {
1488                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1489                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1490                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1491                         }
1492                 }
1493                 else
1494                 {
1495                         if (time < self.invincible_finished)
1496                         {
1497                                 self.items = self.items | IT_INVINCIBLE;
1498                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1499                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1500                         }
1501                 }
1502                 if (self.items & IT_SUPERWEAPON)
1503                 {
1504                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1505                         {
1506                                 self.superweapons_finished = 0;
1507                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1508                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1509                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1510                         }
1511                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1512                         {
1513                                 // don't let them run out
1514                         }
1515                         else
1516                         {
1517                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1518                                 if (time > self.superweapons_finished)
1519                                 {
1520                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1521                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1522                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1523                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1524                                 }
1525                         }
1526                 }
1527                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1528                 {
1529                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1530                         {
1531                                 self.items = self.items | IT_SUPERWEAPON;
1532                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1533                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1534                         }
1535                         else
1536                         {
1537                                 self.superweapons_finished = 0;
1538                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1539                         }
1540                 }
1541                 else
1542                 {
1543                         self.superweapons_finished = 0;
1544                 }
1545         }
1546
1547         if(autocvar_g_nodepthtestplayers)
1548                 self.effects = self.effects | EF_NODEPTHTEST;
1549
1550         if(autocvar_g_fullbrightplayers)
1551                 self.effects = self.effects | EF_FULLBRIGHT;
1552
1553         if (time >= game_starttime)
1554         if (time < self.spawnshieldtime)
1555                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1556
1557         MUTATOR_CALLHOOK(PlayerPowerups);
1558 }
1559
1560 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1561 {
1562         if(current > stable)
1563                 return current;
1564         else if(current > stable - 0.25) // when close enough, "snap"
1565                 return stable;
1566         else
1567                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1568 }
1569
1570 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1571 {
1572         if(current < stable)
1573                 return current;
1574         else if(current < stable + 0.25) // when close enough, "snap"
1575                 return stable;
1576         else
1577                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1578 }
1579
1580 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1581 {
1582         if(current > rotstable)
1583         {
1584                 if(rotframetime > 0)
1585                 {
1586                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1587                         current = max(rotstable, current - rotlinear * rotframetime);
1588                 }
1589         }
1590         else if(current < regenstable)
1591         {
1592                 if(regenframetime > 0)
1593                 {
1594                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1595                         current = min(regenstable, current + regenlinear * regenframetime);
1596                 }
1597         }
1598
1599         if(current > limit)
1600                 current = limit;
1601
1602         return current;
1603 }
1604
1605 void player_regen (void)
1606 {
1607         float max_mod, regen_mod, rot_mod, limit_mod;
1608         max_mod = regen_mod = rot_mod = limit_mod = 1;
1609         regen_mod_max = max_mod;
1610         regen_mod_regen = regen_mod;
1611         regen_mod_rot = rot_mod;
1612         regen_mod_limit = limit_mod;
1613         if(!MUTATOR_CALLHOOK(PlayerRegen))
1614         if(!self.frozen)
1615         {
1616                 float minh, mina, maxh, maxa, limith, limita;
1617                 maxh = autocvar_g_balance_health_rotstable;
1618                 maxa = autocvar_g_balance_armor_rotstable;
1619                 minh = autocvar_g_balance_health_regenstable;
1620                 mina = autocvar_g_balance_armor_regenstable;
1621                 limith = autocvar_g_balance_health_limit;
1622                 limita = autocvar_g_balance_armor_limit;
1623
1624                 max_mod = regen_mod_max;
1625                 regen_mod = regen_mod_regen;
1626                 rot_mod = regen_mod_rot;
1627                 limit_mod = regen_mod_limit;
1628
1629                 maxh = maxh * max_mod;
1630                 minh = minh * max_mod;
1631                 limith = limith * limit_mod;
1632                 limita = limita * limit_mod;
1633
1634                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1635                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1636         }
1637
1638         // if player rotted to death...  die!
1639         // check this outside above checks, as player may still be able to rot to death
1640         if(self.health < 1)
1641                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1642
1643         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1644         {
1645                 float minf, maxf, limitf;
1646
1647                 maxf = autocvar_g_balance_fuel_rotstable;
1648                 minf = autocvar_g_balance_fuel_regenstable;
1649                 limitf = autocvar_g_balance_fuel_limit;
1650
1651                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1652         }
1653 }
1654
1655 float zoomstate_set;
1656 void SetZoomState(float z)
1657 {
1658         if(z != self.zoomstate)
1659         {
1660                 self.zoomstate = z;
1661                 ClientData_Touch(self);
1662         }
1663         zoomstate_set = 1;
1664 }
1665
1666 void GetPressedKeys(void) {
1667         MUTATOR_CALLHOOK(GetPressedKeys);
1668         #define X(var,bit,flag) (flag ? var |= bit : var &= ~bit)
1669         X(self.pressedkeys, KEY_FORWARD,        PHYS_INPUT_MOVEVALUES(self)_x > 0);
1670         X(self.pressedkeys, KEY_BACKWARD,       PHYS_INPUT_MOVEVALUES(self)_x < 0);
1671         X(self.pressedkeys, KEY_RIGHT,          PHYS_INPUT_MOVEVALUES(self)_y > 0);
1672         X(self.pressedkeys, KEY_LEFT,           PHYS_INPUT_MOVEVALUES(self)_y < 0);
1673
1674         X(self.pressedkeys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(self));
1675         X(self.pressedkeys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(self));
1676         X(self.pressedkeys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(self));
1677         X(self.pressedkeys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(self));
1678         #undef X
1679 }
1680
1681 /*
1682 ======================
1683 spectate mode routines
1684 ======================
1685 */
1686
1687 void SpectateCopy(entity spectatee) {
1688         other = spectatee;
1689         MUTATOR_CALLHOOK(SpectateCopy);
1690         self.armortype = spectatee.armortype;
1691         self.armorvalue = spectatee.armorvalue;
1692         self.ammo_cells = spectatee.ammo_cells;
1693         self.ammo_plasma = spectatee.ammo_plasma;
1694         self.ammo_shells = spectatee.ammo_shells;
1695         self.ammo_nails = spectatee.ammo_nails;
1696         self.ammo_rockets = spectatee.ammo_rockets;
1697         self.ammo_fuel = spectatee.ammo_fuel;
1698         self.clip_load = spectatee.clip_load;
1699         self.clip_size = spectatee.clip_size;
1700         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1701         self.health = spectatee.health;
1702         self.impulse = 0;
1703         self.items = spectatee.items;
1704         self.last_pickup = spectatee.last_pickup;
1705         self.hit_time = spectatee.hit_time;
1706         self.metertime = spectatee.metertime;
1707         self.strength_finished = spectatee.strength_finished;
1708         self.invincible_finished = spectatee.invincible_finished;
1709         self.pressedkeys = spectatee.pressedkeys;
1710         self.weapons = spectatee.weapons;
1711         self.switchweapon = spectatee.switchweapon;
1712         self.switchingweapon = spectatee.switchingweapon;
1713         self.weapon = spectatee.weapon;
1714         self.vortex_charge = spectatee.vortex_charge;
1715         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1716         self.hagar_load = spectatee.hagar_load;
1717         self.arc_heat_percent = spectatee.arc_heat_percent;
1718         self.minelayer_mines = spectatee.minelayer_mines;
1719         self.punchangle = spectatee.punchangle;
1720         self.view_ofs = spectatee.view_ofs;
1721         self.velocity = spectatee.velocity;
1722         self.dmg_take = spectatee.dmg_take;
1723         self.dmg_save = spectatee.dmg_save;
1724         self.dmg_inflictor = spectatee.dmg_inflictor;
1725         self.v_angle = spectatee.v_angle;
1726         self.angles = spectatee.v_angle;
1727         self.frozen = spectatee.frozen;
1728         self.revive_progress = spectatee.revive_progress;
1729         if(!self.BUTTON_USE)
1730                 self.fixangle = true;
1731         setorigin(self, spectatee.origin);
1732         setsize(self, spectatee.mins, spectatee.maxs);
1733         SetZoomState(spectatee.zoomstate);
1734
1735     anticheat_spectatecopy(spectatee);
1736         self.hud = spectatee.hud;
1737         if(spectatee.vehicle)
1738     {
1739         self.fixangle = false;
1740         //self.velocity = spectatee.vehicle.velocity;
1741         self.vehicle_health = spectatee.vehicle_health;
1742         self.vehicle_shield = spectatee.vehicle_shield;
1743         self.vehicle_energy = spectatee.vehicle_energy;
1744         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1745         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1746         self.vehicle_reload1 = spectatee.vehicle_reload1;
1747         self.vehicle_reload2 = spectatee.vehicle_reload2;
1748
1749         msg_entity = self;
1750
1751         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1752             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1753             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1754             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1755
1756         //WriteByte (MSG_ONE, SVC_SETVIEW);
1757         //    WriteEntity(MSG_ONE, self);
1758         //makevectors(spectatee.v_angle);
1759         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1760     }
1761 }
1762
1763 float SpectateUpdate()
1764 {
1765         if(!self.enemy)
1766             return 0;
1767
1768         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1769         {
1770                 SetSpectator(self, world);
1771                 return 0;
1772         }
1773
1774         SpectateCopy(self.enemy);
1775
1776         return 1;
1777 }
1778
1779 float SpectateSet()
1780 {
1781         if(self.enemy.classname != "player")
1782                 return false;
1783         /*if(self.enemy.vehicle)
1784         {
1785
1786                 msg_entity = self;
1787                 WriteByte(MSG_ONE, SVC_SETVIEW);
1788                 WriteEntity(MSG_ONE, self.enemy);
1789                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1790
1791                 self.movetype = MOVETYPE_NONE;
1792                 accuracy_resend(self);
1793         }
1794         else
1795         {*/
1796                 msg_entity = self;
1797                 WriteByte(MSG_ONE, SVC_SETVIEW);
1798                 WriteEntity(MSG_ONE, self.enemy);
1799                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1800                 self.movetype = MOVETYPE_NONE;
1801                 accuracy_resend(self);
1802
1803                 if(!SpectateUpdate())
1804                         PutObserverInServer();
1805         //}
1806         return true;
1807 }
1808
1809 void SetSpectator(entity player, entity spectatee)
1810 {
1811         entity old_spectatee = player.enemy;
1812
1813         player.enemy = spectatee;
1814
1815         // WEAPONTODO
1816         // these are required to fix the spectator bug with arc
1817         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1818         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1819 }
1820
1821 float Spectate(entity pl)
1822 {
1823         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1824         if(pl.team != self.team)
1825                 return 0;
1826
1827         SetSpectator(self, pl);
1828         return SpectateSet();
1829 }
1830
1831 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1832 entity CA_SpectateNext(entity start) {
1833         if (start.team == self.team) {
1834                 return start;
1835         }
1836
1837         other = start;
1838         // continue from current player
1839         while(other && other.team != self.team) {
1840                 other = find(other, classname, "player");
1841         }
1842
1843         if (!other) {
1844                 // restart from begining
1845                 other = find(other, classname, "player");
1846                 while(other && other.team != self.team) {
1847                         other = find(other, classname, "player");
1848                 }
1849         }
1850
1851         return other;
1852 }
1853
1854 float SpectateNext()
1855 {
1856         other = find(self.enemy, classname, "player");
1857
1858         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1859                 // CA and ca players when spectating enemies is forbidden
1860                 other = CA_SpectateNext(other);
1861         } else {
1862                 // other modes and ca spectators or spectating enemies is allowed
1863                 if (!other)
1864                         other = find(other, classname, "player");
1865         }
1866
1867         if(other) { SetSpectator(self, other); }
1868
1869         return SpectateSet();
1870 }
1871
1872 float SpectatePrev()
1873 {
1874         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1875         other = findchain(classname, "player");
1876         if (!other) // no player
1877                 return false;
1878
1879         entity first = other;
1880         // skip players until current spectated player
1881         if(self.enemy)
1882         while(other && other != self.enemy)
1883                 other = other.chain;
1884
1885         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1886         {
1887                 do { other = other.chain; }
1888                 while(other && other.team != self.team);
1889
1890                 if (!other)
1891                 {
1892                         other = first;
1893                         while(other.team != self.team)
1894                                 other = other.chain;
1895                         if(other == self.enemy)
1896                                 return true;
1897                 }
1898         }
1899         else
1900         {
1901                 if(other.chain)
1902                         other = other.chain;
1903                 else
1904                         other = first;
1905         }
1906         SetSpectator(self, other);
1907         return SpectateSet();
1908 }
1909
1910 /*
1911 =============
1912 ShowRespawnCountdown()
1913
1914 Update a respawn countdown display.
1915 =============
1916 */
1917 void ShowRespawnCountdown()
1918 {
1919         float number;
1920         if(self.deadflag == DEAD_NO) // just respawned?
1921                 return;
1922         else
1923         {
1924                 number = ceil(self.respawn_time - time);
1925                 if(number <= 0)
1926                         return;
1927                 if(number <= self.respawn_countdown)
1928                 {
1929                         self.respawn_countdown = number - 1;
1930                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1931                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1932                 }
1933         }
1934 }
1935
1936 void LeaveSpectatorMode()
1937 {
1938         if(self.caplayer)
1939                 return;
1940         if(nJoinAllowed(self))
1941         {
1942                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1943                 {
1944                         self.classname = "player";
1945                         nades_RemoveBonus(self);
1946
1947                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1948                                 { JoinBestTeam(self, false, true); }
1949
1950                         if(autocvar_g_campaign)
1951                                 { campaign_bots_may_start = 1; }
1952
1953                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1954
1955                         PutClientInServer();
1956
1957                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1958                 }
1959                 else
1960                         stuffcmd(self, "menu_showteamselect\n");
1961         }
1962         else
1963         {
1964                 // Player may not join because g_maxplayers is set
1965                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1966         }
1967 }
1968
1969 /**
1970  * Determines whether the player is allowed to join. This depends on cvar
1971  * g_maxplayers, if it isn't used this function always return true, otherwise
1972  * it checks whether the number of currently playing players exceeds g_maxplayers.
1973  * @return int number of free slots for players, 0 if none
1974  */
1975 float nJoinAllowed(entity ignore) {
1976         if(!ignore)
1977         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1978         // so report 0 free slots if restricted
1979         {
1980                 if(autocvar_g_forced_team_otherwise == "spectate")
1981                         return 0;
1982                 if(autocvar_g_forced_team_otherwise == "spectator")
1983                         return 0;
1984         }
1985
1986         if(self.team_forced < 0)
1987                 return 0; // forced spectators can never join
1988
1989         // TODO simplify this
1990         entity e;
1991         float totalClients = 0;
1992         FOR_EACH_CLIENT(e)
1993                 if(e != ignore)
1994                         totalClients += 1;
1995
1996         if (!autocvar_g_maxplayers)
1997                 return maxclients - totalClients;
1998
1999         float currentlyPlaying = 0;
2000         FOR_EACH_REALCLIENT(e)
2001                 if(IS_PLAYER(e) || e.caplayer)
2002                         currentlyPlaying += 1;
2003
2004         if(currentlyPlaying < autocvar_g_maxplayers)
2005                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2006
2007         return 0;
2008 }
2009
2010 /**
2011  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2012  * g_maxplayers_spectator_blocktime seconds
2013  */
2014 void checkSpectatorBlock() {
2015         if(IS_SPEC(self) || IS_OBSERVER(self))
2016         if(!self.caplayer)
2017         if(IS_REAL_CLIENT(self))
2018         {
2019                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2020                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2021                         dropclient(self);
2022                 }
2023         }
2024 }
2025
2026 void PrintWelcomeMessage()
2027 {
2028         if(self.motd_actived_time == 0)
2029         {
2030                 if (autocvar_g_campaign) {
2031                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2032                                 self.motd_actived_time = time;
2033                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2034                         }
2035                 } else {
2036                         if (self.BUTTON_INFO) {
2037                                 self.motd_actived_time = time;
2038                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2039                         }
2040                 }
2041         }
2042         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2043         {
2044                 if (autocvar_g_campaign) {
2045                         if (self.BUTTON_INFO)
2046                                 self.motd_actived_time = time;
2047                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2048                                 self.motd_actived_time = 0;
2049                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2050                         }
2051                 } else {
2052                         if (self.BUTTON_INFO)
2053                                 self.motd_actived_time = time;
2054                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2055                                 self.motd_actived_time = 0;
2056                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2057                         }
2058                 }
2059         }
2060         else //if(self.motd_actived_time < 0) // just connected, motd is active
2061         {
2062                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2063                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2064                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2065                 {
2066                         // instanctly hide MOTD
2067                         self.motd_actived_time = 0;
2068                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2069                 }
2070         }
2071 }
2072
2073 void ObserverThink()
2074 {
2075         float prefered_movetype;
2076         if (self.flags & FL_JUMPRELEASED) {
2077                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2078                         self.flags &= ~FL_JUMPRELEASED;
2079                         self.flags |= FL_SPAWNING;
2080                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2081                         self.flags &= ~FL_JUMPRELEASED;
2082                         if(SpectateNext()) {
2083                                 self.classname = "spectator";
2084                         }
2085                 } else {
2086                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2087                         if (self.movetype != prefered_movetype)
2088                                 self.movetype = prefered_movetype;
2089                 }
2090         } else {
2091                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2092                         self.flags |= FL_JUMPRELEASED;
2093                         if(self.flags & FL_SPAWNING)
2094                         {
2095                                 self.flags &= ~FL_SPAWNING;
2096                                 LeaveSpectatorMode();
2097                                 return;
2098                         }
2099                 }
2100         }
2101 }
2102
2103 void SpectatorThink()
2104 {
2105         if (self.flags & FL_JUMPRELEASED) {
2106                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2107                         self.flags &= ~FL_JUMPRELEASED;
2108                         self.flags |= FL_SPAWNING;
2109                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2110                         self.flags &= ~FL_JUMPRELEASED;
2111                         if(SpectateNext()) {
2112                                 self.classname = "spectator";
2113                         } else {
2114                                 self.classname = "observer";
2115                                 PutClientInServer();
2116                         }
2117                         self.impulse = 0;
2118                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2119                         self.flags &= ~FL_JUMPRELEASED;
2120                         if(SpectatePrev()) {
2121                                 self.classname = "spectator";
2122                         } else {
2123                                 self.classname = "observer";
2124                                 PutClientInServer();
2125                         }
2126                         self.impulse = 0;
2127                 } else if (self.BUTTON_ATCK2) {
2128                         self.flags &= ~FL_JUMPRELEASED;
2129                         self.classname = "observer";
2130                         PutClientInServer();
2131                 } else {
2132                         if(!SpectateUpdate())
2133                                 PutObserverInServer();
2134                 }
2135         } else {
2136                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2137                         self.flags |= FL_JUMPRELEASED;
2138                         if(self.flags & FL_SPAWNING)
2139                         {
2140                                 self.flags &= ~FL_SPAWNING;
2141                                 LeaveSpectatorMode();
2142                                 return;
2143                         }
2144                 }
2145                 if(!SpectateUpdate())
2146                         PutObserverInServer();
2147         }
2148
2149         self.flags |= FL_CLIENT | FL_NOTARGET;
2150 }
2151
2152 void PlayerUseKey()
2153 {
2154         if (!IS_PLAYER(self))
2155                 return;
2156
2157         if(self.vehicle)
2158         {
2159         vehicles_exit(VHEF_NORMAL);
2160         return;
2161         }
2162
2163         // a use key was pressed; call handlers
2164         MUTATOR_CALLHOOK(PlayerUseKey);
2165 }
2166
2167 float isInvisibleString(string s)
2168 {
2169         float i, n, c;
2170         s = strdecolorize(s);
2171         for((i = 0), (n = strlen(s)); i < n; ++i)
2172         {
2173                 c = str2chr(s, i);
2174                 switch(c)
2175                 {
2176                         case 0:
2177                         case 32: // space
2178                                 break;
2179                         case 192: // charmap space
2180                                 if (!autocvar_utf8_enable)
2181                                         break;
2182                                 return false;
2183                         case 160: // space in unicode fonts
2184                         case 0xE000 + 192: // utf8 charmap space
2185                                 if (autocvar_utf8_enable)
2186                                         break;
2187                         default:
2188                                 return false;
2189                 }
2190         }
2191         return true;
2192 }
2193
2194 /*
2195 =============
2196 PlayerPreThink
2197
2198 Called every frame for each client before the physics are run
2199 =============
2200 */
2201 .float usekeypressed;
2202 void() nexball_setstatus;
2203 .int items_added;
2204 void PlayerPreThink (void)
2205 {
2206         WarpZone_PlayerPhysics_FixVAngle();
2207
2208         self.stat_game_starttime = game_starttime;
2209         self.stat_round_starttime = round_starttime;
2210         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2211         self.stat_leadlimit = autocvar_leadlimit;
2212
2213         if(frametime)
2214         {
2215                 // physics frames: update anticheat stuff
2216                 anticheat_prethink();
2217         }
2218
2219         if(blockSpectators && frametime)
2220                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2221                 checkSpectatorBlock();
2222
2223         zoomstate_set = 0;
2224
2225         // Savage: Check for nameless players
2226         if (isInvisibleString(self.netname)) {
2227                 string new_name = strzone(strcat("Player@", self.netaddress));
2228                 if(autocvar_sv_eventlog)
2229                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2230                 if(self.netname_previous)
2231                         strunzone(self.netname_previous);
2232                 self.netname_previous = strzone(new_name);
2233                 self.netname = self.netname_previous;
2234                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2235         } else if(self.netname_previous != self.netname) {
2236                 if(autocvar_sv_eventlog)
2237                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2238                 if(self.netname_previous)
2239                         strunzone(self.netname_previous);
2240                 self.netname_previous = strzone(self.netname);
2241         }
2242
2243         // version nagging
2244         if(self.version_nagtime)
2245                 if(self.cvar_g_xonoticversion)
2246                         if(time > self.version_nagtime)
2247                         {
2248                                 // don't notify git users
2249                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2250                                 {
2251                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2252                                         {
2253                                                 // notify release users if connecting to git
2254                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2255                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2256                                         }
2257                                         else
2258                                         {
2259                                                 float r;
2260                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2261                                                 if(r < 0)
2262                                                 {
2263                                                         // give users new version
2264                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2265                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2266                                                 }
2267                                                 else if(r > 0)
2268                                                 {
2269                                                         // notify users about old server version
2270                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2271                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2272                                                 }
2273                                         }
2274                                 }
2275                                 self.version_nagtime = 0;
2276                         }
2277
2278         // GOD MODE info
2279         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2280         {
2281                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2282                 self.max_armorvalue = 0;
2283         }
2284
2285 #ifdef TETRIS
2286         if (TetrisPreFrame())
2287                 return;
2288 #endif
2289
2290         if(self.frozen == 2)
2291         {
2292                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2293                 self.health = max(1, self.revive_progress * start_health);
2294                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2295
2296                 if(self.revive_progress >= 1)
2297                         Unfreeze(self);
2298         }
2299         else if(self.frozen == 3)
2300         {
2301                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2302                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2303
2304                 if(self.health < 1)
2305                 {
2306                         if(self.vehicle)
2307                                 vehicles_exit(VHEF_RELESE);
2308                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2309                 }
2310                 else if ( self.revive_progress <= 0 )
2311                         Unfreeze(self);
2312         }
2313
2314         MUTATOR_CALLHOOK(PlayerPreThink);
2315
2316         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2317         {
2318                 if(self.BUTTON_USE && !self.usekeypressed)
2319                         PlayerUseKey();
2320                 self.usekeypressed = self.BUTTON_USE;
2321         }
2322
2323         if(IS_REAL_CLIENT(self))
2324                 PrintWelcomeMessage();
2325
2326         if(IS_PLAYER(self))
2327         {
2328
2329                 CheckRules_Player();
2330
2331                 if (intermission_running)
2332                 {
2333                         IntermissionThink ();   // otherwise a button could be missed between
2334                         return;                                 // the think tics
2335                 }
2336
2337                 //don't allow the player to turn around while game is paused!
2338                 if(timeout_status == TIMEOUT_ACTIVE) {
2339                         // FIXME turn this into CSQC stuff
2340                         self.v_angle = self.lastV_angle;
2341                         self.angles = self.lastV_angle;
2342                         self.fixangle = true;
2343                 }
2344
2345                 if(frametime)
2346                 {
2347                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2348                         {
2349                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2350                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2351                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2352
2353                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2354                                 {
2355                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2356                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2357                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2358                                 }
2359                         }
2360                         else
2361                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2362
2363                         player_powerups();
2364                 }
2365
2366                 if (self.deadflag != DEAD_NO)
2367                 {
2368                         if(self.personal && g_race_qualifying)
2369                         {
2370                                 if(time > self.respawn_time)
2371                                 {
2372                                         self.respawn_time = time + 1; // only retry once a second
2373                                         self.stat_respawn_time = self.respawn_time;
2374                                         respawn();
2375                                         self.impulse = 141;
2376                                 }
2377                         }
2378                         else
2379                         {
2380                                 float button_pressed;
2381                                 if(frametime)
2382                                         player_anim();
2383                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2384
2385                                 if (self.deadflag == DEAD_DYING)
2386                                 {
2387                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2388                                                 self.deadflag = DEAD_RESPAWNING;
2389                                         else if(!button_pressed)
2390                                                 self.deadflag = DEAD_DEAD;
2391                                 }
2392                                 else if (self.deadflag == DEAD_DEAD)
2393                                 {
2394                                         if(button_pressed)
2395                                                 self.deadflag = DEAD_RESPAWNABLE;
2396                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2397                                                 self.deadflag = DEAD_RESPAWNING;
2398                                 }
2399                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2400                                 {
2401                                         if(!button_pressed)
2402                                                 self.deadflag = DEAD_RESPAWNING;
2403                                 }
2404                                 else if (self.deadflag == DEAD_RESPAWNING)
2405                                 {
2406                                         if(time > self.respawn_time)
2407                                         {
2408                                                 self.respawn_time = time + 1; // only retry once a second
2409                                                 self.respawn_time_max = self.respawn_time;
2410                                                 respawn();
2411                                         }
2412                                 }
2413
2414                                 ShowRespawnCountdown();
2415
2416                                 if(self.respawn_flags & RESPAWN_SILENT)
2417                                         self.stat_respawn_time = 0;
2418                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2419                                         self.stat_respawn_time = self.respawn_time_max;
2420                                 else
2421                                         self.stat_respawn_time = self.respawn_time;
2422                         }
2423
2424                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2425                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2426                                 self.stat_respawn_time *= -1;
2427
2428                         return;
2429                 }
2430
2431                 self.prevorigin = self.origin;
2432
2433                 float do_crouch = self.BUTTON_CROUCH;
2434                 if(self.hook.state)
2435                         do_crouch = 0;
2436                 if(self.vehicle)
2437                         do_crouch = 0;
2438                 if(self.frozen)
2439                         do_crouch = 0;
2440
2441                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2442                 // It cannot be predicted by the engine!
2443                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2444                         do_crouch = 0;
2445
2446                 if (do_crouch)
2447                 {
2448                         if (!self.crouch)
2449                         {
2450                                 self.crouch = true;
2451                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2452                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2453                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2454                         }
2455                 }
2456                 else
2457                 {
2458                         if (self.crouch)
2459                         {
2460                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, false, self);
2461                                 if (!trace_startsolid)
2462                                 {
2463                                         self.crouch = false;
2464                                         self.view_ofs = PL_VIEW_OFS;
2465                                         setsize (self, PL_MIN, PL_MAX);
2466                                 }
2467                         }
2468                 }
2469
2470                 FixPlayermodel();
2471
2472                 GrapplingHookFrame();
2473
2474                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2475                 //if(frametime)
2476                 {
2477                         self.items &= ~self.items_added;
2478
2479                         W_WeaponFrame();
2480
2481                         self.items_added = 0;
2482                         if(self.items & IT_JETPACK)
2483                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2484                                         self.items_added |= IT_FUEL;
2485
2486                         self.items |= self.items_added;
2487                 }
2488
2489                 player_regen();
2490
2491                 // WEAPONTODO: Add a weapon request for this
2492                 // rot vortex charge to the charge limit
2493                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2494                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2495
2496                 if(frametime)
2497                         player_anim();
2498
2499                 // secret status
2500                 secrets_setstatus();
2501
2502                 // monsters status
2503                 monsters_setstatus();
2504
2505                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2506
2507                 //self.angles_y=self.v_angle_y + 90;   // temp
2508         } else if(gameover) {
2509                 if (intermission_running)
2510                         IntermissionThink ();   // otherwise a button could be missed between
2511                 return;
2512         } else if(IS_OBSERVER(self)) {
2513                 ObserverThink();
2514         } else if(IS_SPEC(self)) {
2515                 SpectatorThink();
2516         }
2517
2518         // WEAPONTODO: Add weapon request for this
2519         if(!zoomstate_set)
2520                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2521
2522         float oldspectatee_status;
2523         oldspectatee_status = self.spectatee_status;
2524         if(IS_SPEC(self))
2525                 self.spectatee_status = num_for_edict(self.enemy);
2526         else if(IS_OBSERVER(self))
2527                 self.spectatee_status = num_for_edict(self);
2528         else
2529                 self.spectatee_status = 0;
2530         if(self.spectatee_status != oldspectatee_status)
2531         {
2532                 ClientData_Touch(self);
2533         }
2534
2535         if(self.teamkill_soundtime)
2536         if(time > self.teamkill_soundtime)
2537         {
2538                 self.teamkill_soundtime = 0;
2539
2540                 entity oldpusher, oldself;
2541
2542                 oldself = self; self = self.teamkill_soundsource;
2543                 oldpusher = self.pusher; self.pusher = oldself;
2544
2545                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2546
2547                 self.pusher = oldpusher;
2548                 self = oldself;
2549         }
2550
2551         if(self.taunt_soundtime)
2552         if(time > self.taunt_soundtime)
2553         {
2554                 self.taunt_soundtime = 0;
2555                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2556         }
2557
2558         target_voicescript_next(self);
2559
2560         // WEAPONTODO: Move into weaponsystem somehow
2561         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2562         if(!self.weapon)
2563                 self.clip_load = self.clip_size = 0;
2564 }
2565
2566 /*
2567 =============
2568 PlayerPostThink
2569
2570 Called every frame for each client after the physics are run
2571 =============
2572 */
2573 .float idlekick_lasttimeleft;
2574 void PlayerPostThink (void)
2575 {
2576         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2577         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2578         {
2579                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2580                 {
2581                         if(self.idlekick_lasttimeleft)
2582                         {
2583                                 self.idlekick_lasttimeleft = 0;
2584                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2585                         }
2586                 }
2587                 else
2588                 {
2589                         float timeleft;
2590                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2591                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2592                         {
2593                                 if(!self.idlekick_lasttimeleft)
2594                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2595                         }
2596                         if(timeleft <= 0)
2597                         {
2598                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2599                                 dropclient(self);
2600                                 return;
2601                         }
2602                         else if(timeleft <= 10)
2603                         {
2604                                 if(timeleft != self.idlekick_lasttimeleft)
2605                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2606                                 self.idlekick_lasttimeleft = timeleft;
2607                         }
2608                 }
2609         }
2610
2611 #ifdef TETRIS
2612         if(self.impulse == 100)
2613                 ImpulseCommands();
2614         if (!TetrisPostFrame())
2615         {
2616 #endif
2617
2618         CheatFrame();
2619
2620         //CheckPlayerJump();
2621
2622         if(IS_PLAYER(self)) {
2623                 CheckRules_Player();
2624                 UpdateChatBubble();
2625                 if (self.impulse)
2626                         ImpulseCommands();
2627                 if (intermission_running)
2628                         return;         // intermission or finale
2629                 GetPressedKeys();
2630         }
2631
2632 #ifdef TETRIS
2633         }
2634 #endif
2635
2636         /*
2637         float i;
2638         for(i = 0; i < 1000; ++i)
2639         {
2640                 vector end;
2641                 end = self.origin + '0 0 1024' + 512 * randomvec();
2642                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2643                 if(trace_fraction < 1)
2644                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2645                 {
2646                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2647                         break;
2648                 }
2649         }
2650         */
2651
2652         if(self.waypointsprite_attachedforcarrier)
2653                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2654
2655         playerdemo_write();
2656
2657         CSQCMODEL_AUTOUPDATE();
2658 }