qcsrc/server/cl_client.qc

   1 void send_CSQC_teamnagger() {
   2         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   3         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   4 }
   5
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(IS_SPEC(to))
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(IS_SPEC(e2))
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74 .string netname_previous;
  75
  76 void SetSpectator(entity player, entity spectatee);
  77
  78
  79 /*
  80 =============
  81 CheckPlayerModel
  82
  83 Checks if the argument string can be a valid playermodel.
  84 Returns a valid one in doubt.
  85 =============
  86 */
  87 string FallbackPlayerModel;
  88 string CheckPlayerModel(string plyermodel) {
  89         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  90         {
  91                 // note: we cannot summon Don Strunzone here, some player may
  92                 // still have the model string set. In case anyone manages how
  93                 // to change a cvar default, we'll have a small leak here.
  94                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  95         }
  96         // only in right path
  97         if( substring(plyermodel,0,14) != "models/player/")
  98                 return FallbackPlayerModel;
  99         // only good file extensions
 100         if(substring(plyermodel,-4,4) != ".zym")
 101         if(substring(plyermodel,-4,4) != ".dpm")
 102         if(substring(plyermodel,-4,4) != ".iqm")
 103         if(substring(plyermodel,-4,4) != ".md3")
 104         if(substring(plyermodel,-4,4) != ".psk")
 105                 return FallbackPlayerModel;
 106         // forbid the LOD models
 107         if(substring(plyermodel, -9,5) == "_lod1")
 108                 return FallbackPlayerModel;
 109         if(substring(plyermodel, -9,5) == "_lod2")
 110                 return FallbackPlayerModel;
 111         if(plyermodel != strtolower(plyermodel))
 112                 return FallbackPlayerModel;
 113         // also, restrict to server models
 114         if(autocvar_sv_servermodelsonly)
 115         {
 116                 if(!fexists(plyermodel))
 117                         return FallbackPlayerModel;
 118         }
 119         return plyermodel;
 120 }
 121
 122 void setplayermodel(entity e, string modelname)
 123 {
 124         precache_model(modelname);
 125         setmodel(e, modelname);
 126         player_setupanimsformodel();
 127         UpdatePlayerSounds();
 128 }
 129
 130 /*
 131 =============
 132 PutObserverInServer
 133
 134 putting a client as observer in the server
 135 =============
 136 */
 137 void FixPlayermodel();
 138 void PutObserverInServer (void)
 139 {
 140         entity  spot;
 141     self.hud = HUD_NORMAL;
 142
 143         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         self.frags = FRAGS_SPECTATOR;
 158
 159         MUTATOR_CALLHOOK(MakePlayerObserver);
 160
 161         Portal_ClearAll(self);
 162
 163         Unfreeze(self);
 164
 165         if(self.alivetime)
 166         {
 167                 if(!warmup_stage)
 168                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 169                 self.alivetime = 0;
 170         }
 171
 172         if(self.vehicle)
 173                 vehicles_exit(VHEF_RELESE);
 174
 175         WaypointSprite_PlayerDead();
 176
 177         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 178                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 179
 180         if(self.killcount != -666)
 181         {
 182                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 183                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 184                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 185
 186                 if(self.just_joined == FALSE) {
 187                         LogTeamchange(self.playerid, -1, 4);
 188                 } else
 189                         self.just_joined = FALSE;
 190         }
 191
 192         PlayerScore_Clear(self); // clear scores when needed
 193
 194         accuracy_resend(self);
 195
 196         self.spectatortime = time;
 197
 198         self.classname = "observer";
 199         self.iscreature = FALSE;
 200         self.teleportable = TELEPORT_SIMPLE;
 201         self.damagedbycontents = FALSE;
 202         self.health = -666;
 203         self.takedamage = DAMAGE_NO;
 204         self.solid = SOLID_NOT;
 205         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 206         self.flags = FL_CLIENT | FL_NOTARGET;
 207         self.armorvalue = 666;
 208         self.effects = 0;
 209         self.armorvalue = autocvar_g_balance_armor_start;
 210         self.pauserotarmor_finished = 0;
 211         self.pauserothealth_finished = 0;
 212         self.pauseregen_finished = 0;
 213         self.damageforcescale = 0;
 214         self.death_time = 0;
 215         self.respawn_flags = 0;
 216         self.respawn_time = 0;
 217         self.stat_respawn_time = 0;
 218         self.alpha = 0;
 219         self.scale = 0;
 220         self.fade_time = 0;
 221         self.pain_frame = 0;
 222         self.pain_finished = 0;
 223         self.strength_finished = 0;
 224         self.invincible_finished = 0;
 225         self.superweapons_finished = 0;
 226         self.pushltime = 0;
 227         self.istypefrag = 0;
 228         self.think = func_null;
 229         self.nextthink = 0;
 230         self.hook_time = 0;
 231         self.deadflag = DEAD_NO;
 232         self.angles = spot.angles;
 233         self.angles_z = 0;
 234         self.fixangle = TRUE;
 235         self.crouch = FALSE;
 236         self.revival_time = 0;
 237
 238         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 239         self.prevorigin = self.origin;
 240         self.items = 0;
 241         self.weapons = '0 0 0';
 242         self.model = "";
 243         FixPlayermodel();
 244         setmodel(self, "null");
 245         self.drawonlytoclient = self;
 246
 247         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 248         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 249
 250         self.weapon = 0;
 251         self.weaponname = "";
 252         self.switchingweapon = 0;
 253         self.weaponmodel = "";
 254         self.weaponentity = world;
 255         self.exteriorweaponentity = world;
 256         self.killcount = -666;
 257         self.velocity = '0 0 0';
 258         self.avelocity = '0 0 0';
 259         self.punchangle = '0 0 0';
 260         self.punchvector = '0 0 0';
 261         self.oldvelocity = self.velocity;
 262         self.fire_endtime = -1;
 263         self.event_damage = func_null;
 264 }
 265
 266 .float model_randomizer;
 267 void FixPlayermodel()
 268 {
 269         string defaultmodel;
 270         float defaultskin, chmdl, oldskin, n, i;
 271         vector m1, m2;
 272
 273         defaultmodel = "";
 274         defaultskin = 0;
 275         chmdl = FALSE;
 276
 277         if(autocvar_sv_defaultcharacter == 1)
 278         {
 279                 if(teamplay)
 280                 {
 281                         string s;
 282                         s = Static_Team_ColorName_Lower(self.team);
 283                         if(s != "neutral")
 284                         {
 285                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 286                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 287                         }
 288                 }
 289
 290                 if(defaultmodel == "")
 291                 {
 292                         defaultmodel = autocvar_sv_defaultplayermodel;
 293                         defaultskin = autocvar_sv_defaultplayerskin;
 294                 }
 295
 296                 n = tokenize_console(defaultmodel);
 297                 if(n > 0)
 298                 {
 299                         defaultmodel = argv(floor(n * self.model_randomizer));
 300                         // However, do NOT randomize if the player-selected model is in the list.
 301                         for (i = 0; i < n; ++i)
 302                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 303                                         defaultmodel = argv(i);
 304                 }
 305
 306                 i = strstrofs(defaultmodel, ":", 0);
 307                 if(i >= 0)
 308                 {
 309                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 310                         defaultmodel = substring(defaultmodel, 0, i);
 311                 }
 312         }
 313
 314         if(defaultmodel != "")
 315         {
 316                 if (defaultmodel != self.model)
 317                 {
 318                         m1 = self.mins;
 319                         m2 = self.maxs;
 320                         setplayermodel (self, defaultmodel);
 321                         setsize (self, m1, m2);
 322                         chmdl = TRUE;
 323                 }
 324
 325                 oldskin = self.skin;
 326                 self.skin = defaultskin;
 327         } else {
 328                 if (self.playermodel != self.model || self.playermodel == "")
 329                 {
 330                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 331                         m1 = self.mins;
 332                         m2 = self.maxs;
 333                         setplayermodel (self, self.playermodel);
 334                         setsize (self, m1, m2);
 335                         chmdl = TRUE;
 336                 }
 337
 338                 oldskin = self.skin;
 339                 self.skin = stof(self.playerskin);
 340         }
 341
 342         if(chmdl || oldskin != self.skin) // model or skin has changed
 343         {
 344                 self.species = player_getspecies(); // update species
 345                 UpdatePlayerSounds(); // update skin sounds
 346         }
 347
 348         if(!teamplay)
 349                 if(strlen(autocvar_sv_defaultplayercolors))
 350                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 351                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 352 }
 353
 354 /*
 355 =============
 356 PutClientInServer
 357
 358 Called when a client spawns in the server
 359 =============
 360 */
 361 void PutClientInServer (void)
 362 {
 363         if(IS_BOT_CLIENT(self))
 364                 self.classname = "player";
 365         else if(IS_REAL_CLIENT(self))
 366         {
 367                 msg_entity = self;
 368                 WriteByte(MSG_ONE, SVC_SETVIEW);
 369                 WriteEntity(MSG_ONE, self);
 370         }
 371
 372         SetSpectator(self, world);
 373
 374         // reset player keys
 375         self.itemkeys = 0;
 376
 377         MUTATOR_CALLHOOK(PutClientInServer);
 378
 379         if(gameover)
 380                 self.classname = "observer";
 381
 382         if(IS_PLAYER(self))
 383         {
 384                 entity spot, oldself;
 385                 float j;
 386
 387                 accuracy_resend(self);
 388
 389                 if(self.team < 0)
 390                         JoinBestTeam(self, FALSE, TRUE);
 391
 392                 spot = SelectSpawnPoint (FALSE);
 393                 if(!spot)
 394                 {
 395                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 396                         return; // spawn failed
 397                 }
 398
 399                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 400
 401                 if(self.vehicle)
 402                         vehicles_exit(VHEF_RELESE);
 403
 404                 self.classname = "player";
 405                 self.wasplayer = TRUE;
 406                 self.iscreature = TRUE;
 407                 self.teleportable = TELEPORT_NORMAL;
 408                 self.damagedbycontents = TRUE;
 409                 self.movetype = MOVETYPE_WALK;
 410                 self.solid = SOLID_SLIDEBOX;
 411                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 412                 if(autocvar_g_playerclip_collisions)
 413                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 414                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 415                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 416                 self.frags = FRAGS_PLAYER;
 417                 if(INDEPENDENT_PLAYERS)
 418                         MAKE_INDEPENDENT_PLAYER(self);
 419                 self.flags = FL_CLIENT;
 420                 if(autocvar__notarget)
 421                         self.flags |= FL_NOTARGET;
 422                 self.takedamage = DAMAGE_AIM;
 423                 self.effects = 0;
 424                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 425                 self.air_finished = time + 12;
 426                 self.dmg = 2;
 427                 if(WEP_CVAR(vortex, charge))
 428                 {
 429                         if(WEP_CVAR_SEC(vortex, chargepool))
 430                                 self.vortex_chargepool_ammo = 1;
 431                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 432                 }
 433
 434                 if(warmup_stage)
 435                 {
 436                         self.ammo_shells = warmup_start_ammo_shells;
 437                         self.ammo_nails = warmup_start_ammo_nails;
 438                         self.ammo_rockets = warmup_start_ammo_rockets;
 439                         self.ammo_cells = warmup_start_ammo_cells;
 440                         self.ammo_plasma = warmup_start_ammo_plasma;
 441                         self.ammo_fuel = warmup_start_ammo_fuel;
 442                         self.health = warmup_start_health;
 443                         self.armorvalue = warmup_start_armorvalue;
 444                         self.weapons = WARMUP_START_WEAPONS;
 445                 }
 446                 else
 447                 {
 448                         self.ammo_shells = start_ammo_shells;
 449                         self.ammo_nails = start_ammo_nails;
 450                         self.ammo_rockets = start_ammo_rockets;
 451                         self.ammo_cells = start_ammo_cells;
 452                         self.ammo_plasma = start_ammo_plasma;
 453                         self.ammo_fuel = start_ammo_fuel;
 454                         self.health = start_health;
 455                         self.armorvalue = start_armorvalue;
 456                         self.weapons = start_weapons;
 457                 }
 458
 459                 if(self.weapons & WEPSET_SUPERWEAPONS)
 460                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 461                 else
 462                         self.superweapons_finished = 0;
 463
 464                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 465                 {
 466                         if(g_weaponarena_random_with_blaster)
 467                                 self.weapons &= ~WEPSET_BLASTER;
 468                         W_RandomWeapons(self, g_weaponarena_random);
 469                         if(g_weaponarena_random_with_blaster)
 470                                 self.weapons |= WEPSET_BLASTER;
 471                 }
 472
 473                 self.items = start_items;
 474
 475                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 476                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 477                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 478                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 479                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 480                 //extend the pause of rotting if client was reset at the beginning of the countdown
 481                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 482                         self.spawnshieldtime += game_starttime - time;
 483                         self.pauserotarmor_finished += game_starttime - time;
 484                         self.pauserothealth_finished += game_starttime - time;
 485                         self.pauseregen_finished += game_starttime - time;
 486                 }
 487                 self.damageforcescale = 2;
 488                 self.death_time = 0;
 489                 self.respawn_flags = 0;
 490                 self.respawn_time = 0;
 491                 self.stat_respawn_time = 0;
 492                 self.scale = 0;
 493                 self.fade_time = 0;
 494                 self.pain_frame = 0;
 495                 self.pain_finished = 0;
 496                 self.strength_finished = 0;
 497                 self.invincible_finished = 0;
 498                 self.pushltime = 0;
 499                 // players have no think function
 500                 self.think = func_null;
 501                 self.nextthink = 0;
 502                 self.hook_time = 0;
 503                 self.dmg_team = 0;
 504                 self.ballistics_density = autocvar_g_ballistics_density_player;
 505
 506                 self.metertime = 0;
 507
 508                 self.deadflag = DEAD_NO;
 509
 510                 self.angles = spot.angles;
 511
 512                 self.angles_z = 0; // never spawn tilted even if the spot says to
 513                 if(IS_BOT_CLIENT(self))
 514                         self.v_angle = self.angles;
 515                 self.fixangle = TRUE; // turn this way immediately
 516                 self.velocity = '0 0 0';
 517                 self.avelocity = '0 0 0';
 518                 self.punchangle = '0 0 0';
 519                 self.punchvector = '0 0 0';
 520                 self.oldvelocity = self.velocity;
 521                 self.fire_endtime = -1;
 522                 self.revival_time = 0;
 523
 524                 entity spawnevent = spawn();
 525                 spawnevent.owner = self;
 526                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 527
 528                 // Cut off any still running player sounds.
 529                 stopsound(self, CH_PLAYER_SINGLE);
 530
 531                 self.model = "";
 532                 FixPlayermodel();
 533                 self.drawonlytoclient = world;
 534
 535                 self.crouch = FALSE;
 536                 self.view_ofs = PL_VIEW_OFS;
 537                 setsize (self, PL_MIN, PL_MAX);
 538                 self.spawnorigin = spot.origin;
 539                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 540                 // don't reset back to last position, even if new position is stuck in solid
 541                 self.oldorigin = self.origin;
 542                 self.prevorigin = self.origin;
 543                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 544                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 545         self.hud = HUD_NORMAL;
 546
 547                 self.event_damage = PlayerDamage;
 548
 549                 self.bot_attack = TRUE;
 550                 self.monster_attack = TRUE;
 551
 552                 self.spider_slowness = 0;
 553
 554                 self.statdraintime = time + 5;
 555                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 556
 557                 if(self.killcount == -666) {
 558                         PlayerScore_Clear(self);
 559                         self.killcount = 0;
 560                 }
 561
 562                 CL_SpawnWeaponentity();
 563                 self.alpha = default_player_alpha;
 564                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 565                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 566
 567                 self.speedrunning = FALSE;
 568
 569                 //stuffcmd(self, "chase_active 0");
 570                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 571
 572                 target_voicescript_clear(self);
 573
 574                 // reset fields the weapons may use
 575                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 576                 {
 577                         WEP_ACTION(j, WR_RESETPLAYER);
 578
 579                         // all weapons must be fully loaded when we spawn
 580                         entity e;
 581                         e = get_weaponinfo(j);
 582                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 583                                 self.(weapon_load[j]) = e.reloading_ammo;
 584                 }
 585
 586                 oldself = self;
 587                 self = spot;
 588                         activator = oldself;
 589                                 string s;
 590                                 s = self.target;
 591                                 self.target = string_null;
 592                                 SUB_UseTargets();
 593                                 self.target = s;
 594                         activator = world;
 595                 self = oldself;
 596
 597                 Unfreeze(self);
 598
 599                 spawn_spot = spot;
 600                 MUTATOR_CALLHOOK(PlayerSpawn);
 601
 602                 if(autocvar_spawn_debug)
 603                 {
 604                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 605                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 606                 }
 607
 608                 self.switchweapon = w_getbestweapon(self);
 609                 self.cnt = -1; // W_LastWeapon will not complain
 610                 self.weapon = 0;
 611                 self.weaponname = "";
 612                 self.switchingweapon = 0;
 613
 614                 if(!warmup_stage)
 615                         if(!self.alivetime)
 616                                 self.alivetime = time;
 617
 618                 antilag_clear(self);
 619         }
 620         else if(IS_OBSERVER(self))
 621         {
 622                 PutObserverInServer ();
 623         }
 624 }
 625
 626 .float ebouncefactor, ebouncestop; // electro's values
 627 // TODO do we need all these fields, or should we stop autodetecting runtime
 628 // changes and just have a console command to update this?
 629 float ClientInit_SendEntity(entity to, float sf)
 630 {
 631         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 632         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 636         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 637         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 638         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 639         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 640         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 641
 642         if(sv_foginterval && world.fog != "")
 643                 WriteString(MSG_ENTITY, world.fog);
 644         else
 645                 WriteString(MSG_ENTITY, "");
 646         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 647         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 648         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 649         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 650         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 651         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 652         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 653         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 654         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 655         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 656         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 657         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 658         return TRUE;
 659 }
 660
 661 void ClientInit_CheckUpdate()
 662 {
 663         self.nextthink = time;
 664         if(self.count != autocvar_g_balance_armor_blockpercent)
 665         {
 666                 self.count = autocvar_g_balance_armor_blockpercent;
 667                 self.SendFlags |= 1;
 668         }
 669         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 670         {
 671                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 672                 self.SendFlags |= 1;
 673         }
 674         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 675         {
 676                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 677                 self.SendFlags |= 1;
 678         }
 679         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 680         {
 681                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 682                 self.SendFlags |= 1;
 683         }
 684         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 685         {
 686                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 687                 self.SendFlags |= 1;
 688         }
 689 }
 690
 691 void ClientInit_Spawn()
 692 {
 693         entity o;
 694         entity e;
 695         e = spawn();
 696         e.classname = "clientinit";
 697         e.think = ClientInit_CheckUpdate;
 698         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 699
 700         o = self;
 701         self = e;
 702         ClientInit_CheckUpdate();
 703         self = o;
 704 }
 705
 706 /*
 707 =============
 708 SetNewParms
 709 =============
 710 */
 711 void SetNewParms (void)
 712 {
 713         // initialize parms for a new player
 714         parm1 = -(86400 * 366);
 715 }
 716
 717 /*
 718 =============
 719 SetChangeParms
 720 =============
 721 */
 722 void SetChangeParms (void)
 723 {
 724         // save parms for level change
 725         parm1 = self.parm_idlesince - time;
 726 }
 727
 728 /*
 729 =============
 730 DecodeLevelParms
 731 =============
 732 */
 733 void DecodeLevelParms (void)
 734 {
 735         // load parms
 736         self.parm_idlesince = parm1;
 737         if(self.parm_idlesince == -(86400 * 366))
 738                 self.parm_idlesince = time;
 739
 740         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 741         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 742 }
 743
 744 /*
 745 =============
 746 ClientKill
 747
 748 Called when a client types 'kill' in the console
 749 =============
 750 */
 751
 752 .float clientkill_nexttime;
 753 void ClientKill_Now_TeamChange()
 754 {
 755         if(self.killindicator_teamchange == -1)
 756         {
 757                 JoinBestTeam( self, FALSE, TRUE );
 758         }
 759         else if(self.killindicator_teamchange == -2)
 760         {
 761                 if(blockSpectators)
 762                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 763                 PutObserverInServer();
 764         }
 765         else
 766                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 767         self.killindicator_teamchange = 0;
 768 }
 769
 770 void ClientKill_Now()
 771 {
 772         if(self.vehicle)
 773         {
 774             vehicles_exit(VHEF_RELESE);
 775             if(!self.killindicator_teamchange)
 776             {
 777             self.vehicle_health = -1;
 778             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 779             }
 780         }
 781
 782         if(self.killindicator && !wasfreed(self.killindicator))
 783                 remove(self.killindicator);
 784
 785         self.killindicator = world;
 786
 787         if(self.killindicator_teamchange)
 788                 ClientKill_Now_TeamChange();
 789
 790         if(IS_PLAYER(self))
 791                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 792
 793         // now I am sure the player IS dead
 794 }
 795 void KillIndicator_Think()
 796 {
 797         if (gameover)
 798         {
 799                 self.owner.killindicator = world;
 800                 remove(self);
 801                 return;
 802         }
 803
 804         if (self.owner.alpha < 0 && !self.owner.vehicle)
 805         {
 806                 self.owner.killindicator = world;
 807                 remove(self);
 808                 return;
 809         }
 810
 811         if(self.cnt <= 0)
 812         {
 813                 self = self.owner;
 814                 ClientKill_Now(); // no oldself needed
 815                 return;
 816         }
 817     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 818     {
 819         self.nextthink = time + 1;
 820         self.cnt -= 1;
 821     }
 822         else
 823         {
 824                 if(self.cnt <= 10)
 825                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 826                 if(IS_REAL_CLIENT(self.owner))
 827                 {
 828                         if(self.cnt <= 10)
 829                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 830                 }
 831                 self.nextthink = time + 1;
 832                 self.cnt -= 1;
 833         }
 834 }
 835
 836 float clientkilltime;
 837 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 838 {
 839         float killtime;
 840         float starttime;
 841         entity e;
 842
 843         if (gameover)
 844                 return;
 845
 846         killtime = autocvar_g_balance_kill_delay;
 847
 848         if(g_race_qualifying || g_cts)
 849                 killtime = 0;
 850
 851     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 852     {
 853                 remove(self.killindicator);
 854                 self.killindicator = world;
 855
 856         ClientKill_Now(); // allow instant kill in this case
 857         return;
 858     }
 859
 860         self.killindicator_teamchange = targetteam;
 861
 862     if(!self.killindicator)
 863         {
 864                 if(self.deadflag == DEAD_NO)
 865                 {
 866                         killtime = max(killtime, self.clientkill_nexttime - time);
 867                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 868                 }
 869
 870                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 871                 {
 872                         ClientKill_Now();
 873                 }
 874                 else
 875                 {
 876                         starttime = max(time, clientkilltime);
 877
 878                         self.killindicator = spawn();
 879                         self.killindicator.owner = self;
 880                         self.killindicator.scale = 0.5;
 881                         setattachment(self.killindicator, self, "");
 882                         setorigin(self.killindicator, '0 0 52');
 883                         self.killindicator.think = KillIndicator_Think;
 884                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 885                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 886                         self.killindicator.cnt = ceil(killtime);
 887                         self.killindicator.count = bound(0, ceil(killtime), 10);
 888                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 889
 890                         for(e = world; (e = find(e, classname, "body")) != world; )
 891                         {
 892                                 if(e.enemy != self)
 893                                         continue;
 894                                 e.killindicator = spawn();
 895                                 e.killindicator.owner = e;
 896                                 e.killindicator.scale = 0.5;
 897                                 setattachment(e.killindicator, e, "");
 898                                 setorigin(e.killindicator, '0 0 52');
 899                                 e.killindicator.think = KillIndicator_Think;
 900                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 901                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 902                                 e.killindicator.cnt = ceil(killtime);
 903                         }
 904                         self.lip = 0;
 905                 }
 906         }
 907         if(self.killindicator)
 908         {
 909                 if(targetteam == 0) // just die
 910                 {
 911                         self.killindicator.colormod = '0 0 0';
 912                         if(IS_REAL_CLIENT(self))
 913                         if(self.killindicator.cnt > 0)
 914                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 915                 }
 916                 else if(targetteam == -1) // auto
 917                 {
 918                         self.killindicator.colormod = '0 1 0';
 919                         if(IS_REAL_CLIENT(self))
 920                         if(self.killindicator.cnt > 0)
 921                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 922                 }
 923                 else if(targetteam == -2) // spectate
 924                 {
 925                         self.killindicator.colormod = '0.5 0.5 0.5';
 926                         if(IS_REAL_CLIENT(self))
 927                         if(self.killindicator.cnt > 0)
 928                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 929                 }
 930                 else
 931                 {
 932                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 933                         if(IS_REAL_CLIENT(self))
 934                         if(self.killindicator.cnt > 0)
 935                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 936                 }
 937         }
 938
 939 }
 940
 941 void ClientKill (void)
 942 {
 943         if(gameover) return;
 944         if(self.player_blocked) return;
 945         if(self.frozen) return;
 946
 947         ClientKill_TeamChange(0);
 948 }
 949
 950 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 951 {
 952     e.killindicator = spawn();
 953     e.killindicator.owner = e;
 954     e.killindicator.think = KillIndicator_Think;
 955     e.killindicator.nextthink = time + (e.lip) * 0.05;
 956     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 957     e.killindicator.health = 1; // this is used to indicate that it should be silent
 958     e.lip = 0;
 959 }
 960
 961 void FixClientCvars(entity e)
 962 {
 963         // send prediction settings to the client
 964         stuffcmd(e, "\nin_bindmap 0 0\n");
 965         if(g_race || g_cts)
 966                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 967         if(autocvar_g_antilag == 3) // client side hitscan
 968                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 969         if(autocvar_sv_gentle)
 970                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 971         /*
 972          * we no longer need to stuff this. Remove this comment block if you feel
 973          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 974         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 975         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 976         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 977         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 978         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 979         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 980         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 981         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 982         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 983         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 984         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 985         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 986         stuffcmd(e, "cl_movement_edgefriction 1\n");
 987          */
 988 }
 989
 990 float PlayerInIDList(entity p, string idlist)
 991 {
 992         float n, i;
 993         string s;
 994
 995         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 996         if (!p.crypto_idfp)
 997                 return 0;
 998
 999         // this function allows abbreviated player IDs too!
1000         n = tokenize_console(idlist);
1001         for(i = 0; i < n; ++i)
1002         {
1003                 s = argv(i);
1004                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1005                         return 1;
1006         }
1007
1008         return 0;
1009 }
1010
1011 /*
1012 =============
1013 ClientConnect
1014
1015 Called when a client connects to the server
1016 =============
1017 */
1018 void DecodeLevelParms (void);
1019 //void dom_player_join_team(entity pl);
1020 void set_dom_state(entity e);
1021 void ClientConnect (void)
1022 {
1023         float t;
1024
1025         if(IS_CLIENT(self))
1026         {
1027                 print("Warning: ClientConnect, but already connected!\n");
1028                 return;
1029         }
1030
1031         if(Ban_MaybeEnforceBanOnce(self))
1032                 return;
1033
1034         DecodeLevelParms();
1035
1036 #ifdef WATERMARK
1037         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1038 #endif
1039
1040         self.classname = "player_joining";
1041
1042         self.flags = FL_CLIENT;
1043         self.version_nagtime = time + 10 + random() * 10;
1044
1045         if(player_count<0)
1046         {
1047                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1048                 player_count = 0;
1049         }
1050
1051         PlayerScore_Attach(self);
1052         ClientData_Attach();
1053         accuracy_init(self);
1054
1055         bot_clientconnect();
1056
1057         playerdemo_init();
1058
1059         anticheat_init();
1060
1061         // identify the right forced team
1062         if(autocvar_g_campaign)
1063         {
1064                 if(IS_REAL_CLIENT(self)) // only players, not bots
1065                 {
1066                         switch(autocvar_g_campaign_forceteam)
1067                         {
1068                                 case 1: self.team_forced = NUM_TEAM_1; break;
1069                                 case 2: self.team_forced = NUM_TEAM_2; break;
1070                                 case 3: self.team_forced = NUM_TEAM_3; break;
1071                                 case 4: self.team_forced = NUM_TEAM_4; break;
1072                                 default: self.team_forced = 0;
1073                         }
1074                 }
1075         }
1076         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1077                 self.team_forced = NUM_TEAM_1;
1078         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1079                 self.team_forced = NUM_TEAM_2;
1080         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1081                 self.team_forced = NUM_TEAM_3;
1082         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1083                 self.team_forced = NUM_TEAM_4;
1084         else if(autocvar_g_forced_team_otherwise == "red")
1085                 self.team_forced = NUM_TEAM_1;
1086         else if(autocvar_g_forced_team_otherwise == "blue")
1087                 self.team_forced = NUM_TEAM_2;
1088         else if(autocvar_g_forced_team_otherwise == "yellow")
1089                 self.team_forced = NUM_TEAM_3;
1090         else if(autocvar_g_forced_team_otherwise == "pink")
1091                 self.team_forced = NUM_TEAM_4;
1092         else if(autocvar_g_forced_team_otherwise == "spectate")
1093                 self.team_forced = -1;
1094         else if(autocvar_g_forced_team_otherwise == "spectator")
1095                 self.team_forced = -1;
1096         else
1097                 self.team_forced = 0;
1098
1099         if(!teamplay)
1100                 if(self.team_forced > 0)
1101                         self.team_forced = 0;
1102
1103         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1104
1105         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1106                 self.classname = "observer";
1107         } else {
1108                 if(teamplay)
1109                 {
1110                         if(autocvar_g_balance_teams)
1111                         {
1112                                 self.classname = "player";
1113                                 campaign_bots_may_start = 1;
1114                         }
1115                         else
1116                         {
1117                                 self.classname = "observer"; // do it anyway
1118                         }
1119                 }
1120                 else
1121                 {
1122                         self.classname = "player";
1123                         campaign_bots_may_start = 1;
1124                 }
1125         }
1126
1127         self.playerid = (playerid_last = playerid_last + 1);
1128
1129         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1130
1131     if(IS_BOT_CLIENT(self))
1132         PlayerStats_AddPlayer(self);
1133
1134         if(autocvar_sv_eventlog)
1135                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1136
1137         LogTeamchange(self.playerid, self.team, 1);
1138
1139         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1140
1141         self.netname_previous = strzone(self.netname);
1142
1143         if(IS_PLAYER(self) && teamplay)
1144                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1145         else
1146                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1147
1148         stuffcmd(self, strcat(clientstuff, "\n"));
1149         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1150
1151         FixClientCvars(self);
1152
1153         // spawnfunc_waypoint sprites
1154         WaypointSprite_InitClient(self);
1155
1156         // Wazat's grappling hook
1157         SetGrappleHookBindings();
1158
1159         // get version info from player
1160         stuffcmd(self, "cmd clientversion $gameversion\n");
1161
1162         // get other cvars from player
1163         GetCvars(0);
1164
1165         // notify about available teams
1166         if(teamplay)
1167         {
1168                 CheckAllowedTeams(self);
1169                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1170                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1171         }
1172         else
1173                 stuffcmd(self, "set _teams_available 0\n");
1174
1175         attach_entcs();
1176
1177         bot_relinkplayerlist();
1178
1179         self.spectatortime = time;
1180         if(blockSpectators)
1181         {
1182                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1183         }
1184
1185         self.jointime = time;
1186         self.allowed_timeouts = autocvar_sv_timeout_number;
1187
1188         if(IS_REAL_CLIENT(self))
1189         {
1190                 if(!autocvar_g_campaign)
1191                 {
1192                         self.motd_actived_time = -1;
1193                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1194                 }
1195
1196                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1197                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1198         }
1199
1200         if(!sv_foginterval && world.fog != "")
1201                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1202
1203         W_HitPlotOpen(self);
1204
1205         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1206                 send_CSQC_teamnagger();
1207
1208         CheatInitClient();
1209
1210         CSQCMODEL_AUTOINIT();
1211
1212         self.model_randomizer = random();
1213
1214         if(IS_REAL_CLIENT(self))
1215                 sv_notice_join();
1216
1217         MUTATOR_CALLHOOK(ClientConnect);
1218 }
1219 /*
1220 =============
1221 ClientDisconnect
1222
1223 Called when a client disconnects from the server
1224 =============
1225 */
1226 .entity chatbubbleentity;
1227 void ReadyCount();
1228 void ClientDisconnect (void)
1229 {
1230         if(self.vehicle)
1231             vehicles_exit(VHEF_RELESE);
1232
1233         if (!IS_CLIENT(self))
1234         {
1235                 print("Warning: ClientDisconnect without ClientConnect\n");
1236                 return;
1237         }
1238
1239         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1240
1241         PlayerStats_AddGlobalInfo(self);
1242
1243         CheatShutdownClient();
1244
1245         W_HitPlotClose(self);
1246
1247         anticheat_report();
1248         anticheat_shutdown();
1249
1250         playerdemo_shutdown();
1251
1252         bot_clientdisconnect();
1253
1254         if(self.entcs)
1255                 detach_entcs();
1256
1257         if(autocvar_sv_eventlog)
1258                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1259
1260         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1261
1262         MUTATOR_CALLHOOK(ClientDisconnect);
1263
1264         Portal_ClearAll(self);
1265
1266         Unfreeze(self);
1267
1268         RemoveGrapplingHook(self);
1269
1270         // Here, everything has been done that requires this player to be a client.
1271
1272         self.flags &= ~FL_CLIENT;
1273
1274         if (self.chatbubbleentity)
1275                 remove (self.chatbubbleentity);
1276
1277         if (self.killindicator)
1278                 remove (self.killindicator);
1279
1280         WaypointSprite_PlayerGone();
1281
1282         bot_relinkplayerlist();
1283
1284         accuracy_free(self);
1285         ClientData_Detach();
1286         PlayerScore_Detach(self);
1287
1288         if(self.netname_previous)
1289                 strunzone(self.netname_previous);
1290         if(self.clientstatus)
1291                 strunzone(self.clientstatus);
1292         if(self.weaponorder_byimpulse)
1293                 strunzone(self.weaponorder_byimpulse);
1294
1295         ClearPlayerSounds();
1296
1297         if(self.personal)
1298                 remove(self.personal);
1299
1300         self.playerid = 0;
1301         ReadyCount();
1302
1303         // free cvars
1304         GetCvars(-1);
1305 }
1306
1307 .float BUTTON_CHAT;
1308 void ChatBubbleThink()
1309 {
1310         self.nextthink = time;
1311         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1312         {
1313                 if(self.owner) // but why can that ever be world?
1314                         self.owner.chatbubbleentity = world;
1315                 remove(self);
1316                 return;
1317         }
1318         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1319 #ifdef TETRIS
1320                 || self.owner.tetris_on
1321 #endif
1322         )
1323                 self.model = self.mdl;
1324         else
1325                 self.model = "";
1326 }
1327
1328 void UpdateChatBubble()
1329 {
1330         if (self.alpha < 0)
1331                 return;
1332         // spawn a chatbubble entity if needed
1333         if (!self.chatbubbleentity)
1334         {
1335                 self.chatbubbleentity = spawn();
1336                 self.chatbubbleentity.owner = self;
1337                 self.chatbubbleentity.exteriormodeltoclient = self;
1338                 self.chatbubbleentity.think = ChatBubbleThink;
1339                 self.chatbubbleentity.nextthink = time;
1340                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1341                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1342                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1343                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1344                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1345                 self.chatbubbleentity.model = "";
1346                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1347         }
1348 }
1349
1350
1351 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1352 // added to the model skins
1353 /*void UpdateColorModHack()
1354 {
1355         float c;
1356         c = self.clientcolors & 15;
1357         // LordHavoc: only bothering to support white, green, red, yellow, blue
1358              if (!teamplay) self.colormod = '0 0 0';
1359         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1360         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1361         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1362         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1363         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1364         else self.colormod = '1 1 1';
1365 }*/
1366
1367 void respawn(void)
1368 {
1369         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1370         {
1371                 self.solid = SOLID_NOT;
1372                 self.takedamage = DAMAGE_NO;
1373                 self.movetype = MOVETYPE_FLY;
1374                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1375                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1376                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1377                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1378                 if(autocvar_g_respawn_ghosts_maxtime)
1379                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1380         }
1381
1382         CopyBody(1);
1383
1384         self.effects |= EF_NODRAW; // prevent another CopyBody
1385         PutClientInServer();
1386 }
1387
1388 void play_countdown(float finished, string samp)
1389 {
1390         if(IS_REAL_CLIENT(self))
1391                 if(floor(finished - time - frametime) != floor(finished - time))
1392                         if(finished - time < 6)
1393                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1394 }
1395
1396 void player_powerups (void)
1397 {
1398         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1399         olditems = self.items;
1400
1401         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1402                 self.modelflags |= MF_ROCKET;
1403         else
1404                 self.modelflags &= ~MF_ROCKET;
1405
1406         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1407
1408         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1409                 return;
1410
1411         Fire_ApplyDamage(self);
1412         Fire_ApplyEffect(self);
1413
1414         if (!g_instagib)
1415         {
1416                 if (self.items & IT_STRENGTH)
1417                 {
1418                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1419                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1420                         if (time > self.strength_finished)
1421                         {
1422                                 self.items = self.items - (self.items & IT_STRENGTH);
1423                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1424                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1425                         }
1426                 }
1427                 else
1428                 {
1429                         if (time < self.strength_finished)
1430                         {
1431                                 self.items = self.items | IT_STRENGTH;
1432                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1433                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1434                         }
1435                 }
1436                 if (self.items & IT_INVINCIBLE)
1437                 {
1438                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1439                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1440                         if (time > self.invincible_finished)
1441                         {
1442                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1443                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1444                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1445                         }
1446                 }
1447                 else
1448                 {
1449                         if (time < self.invincible_finished)
1450                         {
1451                                 self.items = self.items | IT_INVINCIBLE;
1452                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1453                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1454                         }
1455                 }
1456                 if (self.items & IT_SUPERWEAPON)
1457                 {
1458                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1459                         {
1460                                 self.superweapons_finished = 0;
1461                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1462                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1463                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1464                         }
1465                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1466                         {
1467                                 // don't let them run out
1468                         }
1469                         else
1470                         {
1471                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1472                                 if (time > self.superweapons_finished)
1473                                 {
1474                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1475                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1476                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1477                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1478                                 }
1479                         }
1480                 }
1481                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1482                 {
1483                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1484                         {
1485                                 self.items = self.items | IT_SUPERWEAPON;
1486                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1487                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1488                         }
1489                         else
1490                         {
1491                                 self.superweapons_finished = 0;
1492                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1493                         }
1494                 }
1495                 else
1496                 {
1497                         self.superweapons_finished = 0;
1498                 }
1499         }
1500
1501         if(autocvar_g_nodepthtestplayers)
1502                 self.effects = self.effects | EF_NODEPTHTEST;
1503
1504         if(autocvar_g_fullbrightplayers)
1505                 self.effects = self.effects | EF_FULLBRIGHT;
1506
1507         if (time >= game_starttime)
1508         if (time < self.spawnshieldtime)
1509                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1510
1511         MUTATOR_CALLHOOK(PlayerPowerups);
1512 }
1513
1514 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1515 {
1516         if(current > stable)
1517                 return current;
1518         else if(current > stable - 0.25) // when close enough, "snap"
1519                 return stable;
1520         else
1521                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1522 }
1523
1524 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1525 {
1526         if(current < stable)
1527                 return current;
1528         else if(current < stable + 0.25) // when close enough, "snap"
1529                 return stable;
1530         else
1531                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1532 }
1533
1534 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1535 {
1536         if(current > rotstable)
1537         {
1538                 if(rotframetime > 0)
1539                 {
1540                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1541                         current = max(rotstable, current - rotlinear * rotframetime);
1542                 }
1543         }
1544         else if(current < regenstable)
1545         {
1546                 if(regenframetime > 0)
1547                 {
1548                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1549                         current = min(regenstable, current + regenlinear * regenframetime);
1550                 }
1551         }
1552
1553         if(current > limit)
1554                 current = limit;
1555
1556         return current;
1557 }
1558
1559 void player_regen (void)
1560 {
1561         float max_mod, regen_mod, rot_mod, limit_mod;
1562         max_mod = regen_mod = rot_mod = limit_mod = 1;
1563         regen_mod_max = max_mod;
1564         regen_mod_regen = regen_mod;
1565         regen_mod_rot = rot_mod;
1566         regen_mod_limit = limit_mod;
1567         if(!MUTATOR_CALLHOOK(PlayerRegen))
1568         if(!self.frozen)
1569         {
1570                 float minh, mina, maxh, maxa, limith, limita;
1571                 maxh = autocvar_g_balance_health_rotstable;
1572                 maxa = autocvar_g_balance_armor_rotstable;
1573                 minh = autocvar_g_balance_health_regenstable;
1574                 mina = autocvar_g_balance_armor_regenstable;
1575                 limith = autocvar_g_balance_health_limit;
1576                 limita = autocvar_g_balance_armor_limit;
1577
1578                 max_mod = regen_mod_max;
1579                 regen_mod = regen_mod_regen;
1580                 rot_mod = regen_mod_rot;
1581                 limit_mod = regen_mod_limit;
1582
1583                 maxh = maxh * max_mod;
1584                 minh = minh * max_mod;
1585                 limith = limith * limit_mod;
1586                 limita = limita * limit_mod;
1587
1588                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1589                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1590         }
1591
1592         // if player rotted to death...  die!
1593         // check this outside above checks, as player may still be able to rot to death
1594         if(self.health < 1)
1595                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1596
1597         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1598         {
1599                 float minf, maxf, limitf;
1600
1601                 maxf = autocvar_g_balance_fuel_rotstable;
1602                 minf = autocvar_g_balance_fuel_regenstable;
1603                 limitf = autocvar_g_balance_fuel_limit;
1604
1605                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1606         }
1607 }
1608
1609 float zoomstate_set;
1610 void SetZoomState(float z)
1611 {
1612         if(z != self.zoomstate)
1613         {
1614                 self.zoomstate = z;
1615                 ClientData_Touch(self);
1616         }
1617         zoomstate_set = 1;
1618 }
1619
1620 void GetPressedKeys(void) {
1621         MUTATOR_CALLHOOK(GetPressedKeys);
1622         #define X(var,bit,flag) (flag ? var |= bit : var &= ~bit)
1623         X(self.pressedkeys, KEY_FORWARD,        PHYS_INPUT_MOVEVALUES(self)_x > 0);
1624         X(self.pressedkeys, KEY_BACKWARD,       PHYS_INPUT_MOVEVALUES(self)_x < 0);
1625         X(self.pressedkeys, KEY_RIGHT,          PHYS_INPUT_MOVEVALUES(self)_y > 0);
1626         X(self.pressedkeys, KEY_LEFT,           PHYS_INPUT_MOVEVALUES(self)_y < 0);
1627
1628         X(self.pressedkeys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(self));
1629         X(self.pressedkeys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(self));
1630         X(self.pressedkeys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(self));
1631         X(self.pressedkeys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(self));
1632         #undef X
1633 }
1634
1635 /*
1636 ======================
1637 spectate mode routines
1638 ======================
1639 */
1640
1641 void SpectateCopy(entity spectatee) {
1642         other = spectatee;
1643         MUTATOR_CALLHOOK(SpectateCopy);
1644         self.armortype = spectatee.armortype;
1645         self.armorvalue = spectatee.armorvalue;
1646         self.ammo_cells = spectatee.ammo_cells;
1647         self.ammo_plasma = spectatee.ammo_plasma;
1648         self.ammo_shells = spectatee.ammo_shells;
1649         self.ammo_nails = spectatee.ammo_nails;
1650         self.ammo_rockets = spectatee.ammo_rockets;
1651         self.ammo_fuel = spectatee.ammo_fuel;
1652         self.clip_load = spectatee.clip_load;
1653         self.clip_size = spectatee.clip_size;
1654         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1655         self.health = spectatee.health;
1656         self.impulse = 0;
1657         self.items = spectatee.items;
1658         self.last_pickup = spectatee.last_pickup;
1659         self.hit_time = spectatee.hit_time;
1660         self.metertime = spectatee.metertime;
1661         self.strength_finished = spectatee.strength_finished;
1662         self.invincible_finished = spectatee.invincible_finished;
1663         self.pressedkeys = spectatee.pressedkeys;
1664         self.weapons = spectatee.weapons;
1665         self.switchweapon = spectatee.switchweapon;
1666         self.switchingweapon = spectatee.switchingweapon;
1667         self.weapon = spectatee.weapon;
1668         self.vortex_charge = spectatee.vortex_charge;
1669         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1670         self.hagar_load = spectatee.hagar_load;
1671         self.arc_heat_percent = spectatee.arc_heat_percent;
1672         self.minelayer_mines = spectatee.minelayer_mines;
1673         self.punchangle = spectatee.punchangle;
1674         self.view_ofs = spectatee.view_ofs;
1675         self.velocity = spectatee.velocity;
1676         self.dmg_take = spectatee.dmg_take;
1677         self.dmg_save = spectatee.dmg_save;
1678         self.dmg_inflictor = spectatee.dmg_inflictor;
1679         self.v_angle = spectatee.v_angle;
1680         self.angles = spectatee.v_angle;
1681         self.frozen = spectatee.frozen;
1682         self.revive_progress = spectatee.revive_progress;
1683         if(!self.BUTTON_USE)
1684                 self.fixangle = TRUE;
1685         setorigin(self, spectatee.origin);
1686         setsize(self, spectatee.mins, spectatee.maxs);
1687         SetZoomState(spectatee.zoomstate);
1688
1689     anticheat_spectatecopy(spectatee);
1690         self.hud = spectatee.hud;
1691         if(spectatee.vehicle)
1692     {
1693         self.fixangle = FALSE;
1694         //self.velocity = spectatee.vehicle.velocity;
1695         self.vehicle_health = spectatee.vehicle_health;
1696         self.vehicle_shield = spectatee.vehicle_shield;
1697         self.vehicle_energy = spectatee.vehicle_energy;
1698         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1699         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1700         self.vehicle_reload1 = spectatee.vehicle_reload1;
1701         self.vehicle_reload2 = spectatee.vehicle_reload2;
1702
1703         msg_entity = self;
1704
1705         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1706             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1707             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1708             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1709
1710         //WriteByte (MSG_ONE, SVC_SETVIEW);
1711         //    WriteEntity(MSG_ONE, self);
1712         //makevectors(spectatee.v_angle);
1713         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1714     }
1715 }
1716
1717 float SpectateUpdate()
1718 {
1719         if(!self.enemy)
1720             return 0;
1721
1722         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1723         {
1724                 SetSpectator(self, world);
1725                 return 0;
1726         }
1727
1728         SpectateCopy(self.enemy);
1729
1730         return 1;
1731 }
1732
1733
1734 float SpectateSet()
1735 {
1736         if(self.enemy.classname != "player")
1737                 return FALSE;
1738         /*if(self.enemy.vehicle)
1739         {
1740
1741                 msg_entity = self;
1742                 WriteByte(MSG_ONE, SVC_SETVIEW);
1743                 WriteEntity(MSG_ONE, self.enemy);
1744                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1745
1746                 self.movetype = MOVETYPE_NONE;
1747                 accuracy_resend(self);
1748         }
1749         else
1750         {*/
1751                 msg_entity = self;
1752                 WriteByte(MSG_ONE, SVC_SETVIEW);
1753                 WriteEntity(MSG_ONE, self.enemy);
1754                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1755                 self.movetype = MOVETYPE_NONE;
1756                 accuracy_resend(self);
1757
1758                 if(!SpectateUpdate())
1759                         PutObserverInServer();
1760         //}
1761         return TRUE;
1762 }
1763
1764 void SetSpectator(entity player, entity spectatee)
1765 {
1766         entity old_spectatee = player.enemy;
1767
1768         player.enemy = spectatee;
1769
1770         // WEAPONTODO
1771         // these are required to fix the spectator bug with arc
1772         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1773         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1774 }
1775
1776 float Spectate(entity pl)
1777 {
1778         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1779         if(pl.team != self.team)
1780                 return 0;
1781
1782         SetSpectator(self, pl);
1783         return SpectateSet();
1784 }
1785
1786 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1787 entity CA_SpectateNext(entity start) {
1788         if (start.team == self.team) {
1789                 return start;
1790         }
1791
1792         other = start;
1793         // continue from current player
1794         while(other && other.team != self.team) {
1795                 other = find(other, classname, "player");
1796         }
1797
1798         if (!other) {
1799                 // restart from begining
1800                 other = find(other, classname, "player");
1801                 while(other && other.team != self.team) {
1802                         other = find(other, classname, "player");
1803                 }
1804         }
1805
1806         return other;
1807 }
1808
1809 float SpectateNext()
1810 {
1811         other = find(self.enemy, classname, "player");
1812
1813         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1814                 // CA and ca players when spectating enemies is forbidden
1815                 other = CA_SpectateNext(other);
1816         } else {
1817                 // other modes and ca spectators or spectating enemies is allowed
1818                 if (!other)
1819                         other = find(other, classname, "player");
1820         }
1821
1822         if(other) { SetSpectator(self, other); }
1823
1824         return SpectateSet();
1825 }
1826
1827 float SpectatePrev()
1828 {
1829         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1830         other = findchain(classname, "player");
1831         if (!other) // no player
1832                 return FALSE;
1833
1834         entity first = other;
1835         // skip players until current spectated player
1836         if(self.enemy)
1837         while(other && other != self.enemy)
1838                 other = other.chain;
1839
1840         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1841         {
1842                 do { other = other.chain; }
1843                 while(other && other.team != self.team);
1844
1845                 if (!other)
1846                 {
1847                         other = first;
1848                         while(other.team != self.team)
1849                                 other = other.chain;
1850                         if(other == self.enemy)
1851                                 return TRUE;
1852                 }
1853         }
1854         else
1855         {
1856                 if(other.chain)
1857                         other = other.chain;
1858                 else
1859                         other = first;
1860         }
1861         SetSpectator(self, other);
1862         return SpectateSet();
1863 }
1864
1865 /*
1866 =============
1867 ShowRespawnCountdown()
1868
1869 Update a respawn countdown display.
1870 =============
1871 */
1872 void ShowRespawnCountdown()
1873 {
1874         float number;
1875         if(self.deadflag == DEAD_NO) // just respawned?
1876                 return;
1877         else
1878         {
1879                 number = ceil(self.respawn_time - time);
1880                 if(number <= 0)
1881                         return;
1882                 if(number <= self.respawn_countdown)
1883                 {
1884                         self.respawn_countdown = number - 1;
1885                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1886                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1887                 }
1888         }
1889 }
1890
1891 void LeaveSpectatorMode()
1892 {
1893         if(self.caplayer)
1894                 return;
1895         if(nJoinAllowed(self))
1896         {
1897                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1898                 {
1899                         self.classname = "player";
1900                         nades_RemoveBonus(self);
1901
1902                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1903                                 { JoinBestTeam(self, FALSE, TRUE); }
1904
1905                         if(autocvar_g_campaign)
1906                                 { campaign_bots_may_start = 1; }
1907
1908                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1909
1910                         PutClientInServer();
1911
1912                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1913                 }
1914                 else
1915                         stuffcmd(self, "menu_showteamselect\n");
1916         }
1917         else
1918         {
1919                 // Player may not join because g_maxplayers is set
1920                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1921         }
1922 }
1923
1924 /**
1925  * Determines whether the player is allowed to join. This depends on cvar
1926  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1927  * it checks whether the number of currently playing players exceeds g_maxplayers.
1928  * @return int number of free slots for players, 0 if none
1929  */
1930 float nJoinAllowed(entity ignore) {
1931         if(!ignore)
1932         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1933         // so report 0 free slots if restricted
1934         {
1935                 if(autocvar_g_forced_team_otherwise == "spectate")
1936                         return 0;
1937                 if(autocvar_g_forced_team_otherwise == "spectator")
1938                         return 0;
1939         }
1940
1941         if(self.team_forced < 0)
1942                 return 0; // forced spectators can never join
1943
1944         // TODO simplify this
1945         entity e;
1946         float totalClients = 0;
1947         FOR_EACH_CLIENT(e)
1948                 if(e != ignore)
1949                         totalClients += 1;
1950
1951         if (!autocvar_g_maxplayers)
1952                 return maxclients - totalClients;
1953
1954         float currentlyPlaying = 0;
1955         FOR_EACH_REALCLIENT(e)
1956                 if(IS_PLAYER(e) || e.caplayer)
1957                         currentlyPlaying += 1;
1958
1959         if(currentlyPlaying < autocvar_g_maxplayers)
1960                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1961
1962         return 0;
1963 }
1964
1965 /**
1966  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1967  * g_maxplayers_spectator_blocktime seconds
1968  */
1969 void checkSpectatorBlock() {
1970         if(IS_SPEC(self) || IS_OBSERVER(self))
1971         if(!self.caplayer)
1972         if(IS_REAL_CLIENT(self))
1973         {
1974                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1975                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1976                         dropclient(self);
1977                 }
1978         }
1979 }
1980
1981 void PrintWelcomeMessage()
1982 {
1983         if(self.motd_actived_time == 0)
1984         {
1985                 if (autocvar_g_campaign) {
1986                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
1987                                 self.motd_actived_time = time;
1988                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
1989                         }
1990                 } else {
1991                         if (self.BUTTON_INFO) {
1992                                 self.motd_actived_time = time;
1993                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1994                         }
1995                 }
1996         }
1997         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
1998         {
1999                 if (autocvar_g_campaign) {
2000                         if (self.BUTTON_INFO)
2001                                 self.motd_actived_time = time;
2002                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2003                                 self.motd_actived_time = 0;
2004                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2005                         }
2006                 } else {
2007                         if (self.BUTTON_INFO)
2008                                 self.motd_actived_time = time;
2009                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2010                                 self.motd_actived_time = 0;
2011                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2012                         }
2013                 }
2014         }
2015         else //if(self.motd_actived_time < 0) // just connected, motd is active
2016         {
2017                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2018                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2019                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2020                 {
2021                         // instanctly hide MOTD
2022                         self.motd_actived_time = 0;
2023                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2024                 }
2025         }
2026 }
2027
2028 void ObserverThink()
2029 {
2030         float prefered_movetype;
2031         if (self.flags & FL_JUMPRELEASED) {
2032                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2033                         self.flags &= ~FL_JUMPRELEASED;
2034                         self.flags |= FL_SPAWNING;
2035                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2036                         self.flags &= ~FL_JUMPRELEASED;
2037                         if(SpectateNext()) {
2038                                 self.classname = "spectator";
2039                         }
2040                 } else {
2041                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2042                         if (self.movetype != prefered_movetype)
2043                                 self.movetype = prefered_movetype;
2044                 }
2045         } else {
2046                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2047                         self.flags |= FL_JUMPRELEASED;
2048                         if(self.flags & FL_SPAWNING)
2049                         {
2050                                 self.flags &= ~FL_SPAWNING;
2051                                 LeaveSpectatorMode();
2052                                 return;
2053                         }
2054                 }
2055         }
2056 }
2057
2058 void SpectatorThink()
2059 {
2060         if (self.flags & FL_JUMPRELEASED) {
2061                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2062                         self.flags &= ~FL_JUMPRELEASED;
2063                         self.flags |= FL_SPAWNING;
2064                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2065                         self.flags &= ~FL_JUMPRELEASED;
2066                         if(SpectateNext()) {
2067                                 self.classname = "spectator";
2068                         } else {
2069                                 self.classname = "observer";
2070                                 PutClientInServer();
2071                         }
2072                         self.impulse = 0;
2073                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2074                         self.flags &= ~FL_JUMPRELEASED;
2075                         if(SpectatePrev()) {
2076                                 self.classname = "spectator";
2077                         } else {
2078                                 self.classname = "observer";
2079                                 PutClientInServer();
2080                         }
2081                         self.impulse = 0;
2082                 } else if (self.BUTTON_ATCK2) {
2083                         self.flags &= ~FL_JUMPRELEASED;
2084                         self.classname = "observer";
2085                         PutClientInServer();
2086                 } else {
2087                         if(!SpectateUpdate())
2088                                 PutObserverInServer();
2089                 }
2090         } else {
2091                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2092                         self.flags |= FL_JUMPRELEASED;
2093                         if(self.flags & FL_SPAWNING)
2094                         {
2095                                 self.flags &= ~FL_SPAWNING;
2096                                 LeaveSpectatorMode();
2097                                 return;
2098                         }
2099                 }
2100                 if(!SpectateUpdate())
2101                         PutObserverInServer();
2102         }
2103
2104         self.flags |= FL_CLIENT | FL_NOTARGET;
2105 }
2106
2107 void PlayerUseKey()
2108 {
2109         if (!IS_PLAYER(self))
2110                 return;
2111
2112         if(self.vehicle)
2113         {
2114         vehicles_exit(VHEF_NORMAL);
2115         return;
2116         }
2117
2118         // a use key was pressed; call handlers
2119         MUTATOR_CALLHOOK(PlayerUseKey);
2120 }
2121
2122 /*
2123 =============
2124 PlayerPreThink
2125
2126 Called every frame for each client before the physics are run
2127 =============
2128 */
2129 .float usekeypressed;
2130 void() nexball_setstatus;
2131 .float items_added;
2132 void PlayerPreThink (void)
2133 {
2134         WarpZone_PlayerPhysics_FixVAngle();
2135
2136         self.stat_game_starttime = game_starttime;
2137         self.stat_round_starttime = round_starttime;
2138         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2139         self.stat_leadlimit = autocvar_leadlimit;
2140
2141         if(frametime)
2142         {
2143                 // physics frames: update anticheat stuff
2144                 anticheat_prethink();
2145         }
2146
2147         if(blockSpectators && frametime)
2148                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2149                 checkSpectatorBlock();
2150
2151         zoomstate_set = 0;
2152
2153         if(self.netname_previous != self.netname)
2154         {
2155                 if(autocvar_sv_eventlog)
2156                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2157                 if(self.netname_previous)
2158                         strunzone(self.netname_previous);
2159                 self.netname_previous = strzone(self.netname);
2160         }
2161
2162         // version nagging
2163         if(self.version_nagtime)
2164                 if(self.cvar_g_xonoticversion)
2165                         if(time > self.version_nagtime)
2166                         {
2167                                 // don't notify git users
2168                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2169                                 {
2170                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2171                                         {
2172                                                 // notify release users if connecting to git
2173                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2174                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2175                                         }
2176                                         else
2177                                         {
2178                                                 float r;
2179                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2180                                                 if(r < 0)
2181                                                 {
2182                                                         // give users new version
2183                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2184                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2185                                                 }
2186                                                 else if(r > 0)
2187                                                 {
2188                                                         // notify users about old server version
2189                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2190                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2191                                                 }
2192                                         }
2193                                 }
2194                                 self.version_nagtime = 0;
2195                         }
2196
2197         // GOD MODE info
2198         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2199         {
2200                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2201                 self.max_armorvalue = 0;
2202         }
2203
2204 #ifdef TETRIS
2205         if (TetrisPreFrame())
2206                 return;
2207 #endif
2208
2209         if(self.frozen == 2)
2210         {
2211                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2212                 self.health = max(1, self.revive_progress * start_health);
2213                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2214
2215                 if(self.revive_progress >= 1)
2216                         Unfreeze(self);
2217         }
2218         else if(self.frozen == 3)
2219         {
2220                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2221                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2222
2223                 if(self.health < 1)
2224                 {
2225                         if(self.vehicle)
2226                                 vehicles_exit(VHEF_RELESE);
2227                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2228                 }
2229                 else if ( self.revive_progress <= 0 )
2230                         Unfreeze(self);
2231         }
2232
2233         MUTATOR_CALLHOOK(PlayerPreThink);
2234
2235         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2236         {
2237                 if(self.BUTTON_USE && !self.usekeypressed)
2238                         PlayerUseKey();
2239                 self.usekeypressed = self.BUTTON_USE;
2240         }
2241
2242         if(IS_REAL_CLIENT(self))
2243                 PrintWelcomeMessage();
2244
2245         if(IS_PLAYER(self))
2246         {
2247
2248                 CheckRules_Player();
2249
2250                 if (intermission_running)
2251                 {
2252                         IntermissionThink ();   // otherwise a button could be missed between
2253                         return;                                 // the think tics
2254                 }
2255
2256                 //don't allow the player to turn around while game is paused!
2257                 if(timeout_status == TIMEOUT_ACTIVE) {
2258                         // FIXME turn this into CSQC stuff
2259                         self.v_angle = self.lastV_angle;
2260                         self.angles = self.lastV_angle;
2261                         self.fixangle = TRUE;
2262                 }
2263
2264                 if(frametime)
2265                 {
2266                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2267                         {
2268                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2269                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2270                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2271
2272                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2273                                 {
2274                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2275                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2276                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2277                                 }
2278                         }
2279                         else
2280                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2281
2282                         player_powerups();
2283                 }
2284
2285                 if (self.deadflag != DEAD_NO)
2286                 {
2287                         if(self.personal && g_race_qualifying)
2288                         {
2289                                 if(time > self.respawn_time)
2290                                 {
2291                                         self.respawn_time = time + 1; // only retry once a second
2292                                         self.stat_respawn_time = self.respawn_time;
2293                                         respawn();
2294                                         self.impulse = 141;
2295                                 }
2296                         }
2297                         else
2298                         {
2299                                 float button_pressed;
2300                                 if(frametime)
2301                                         player_anim();
2302                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2303
2304                                 if (self.deadflag == DEAD_DYING)
2305                                 {
2306                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2307                                                 self.deadflag = DEAD_RESPAWNING;
2308                                         else if(!button_pressed)
2309                                                 self.deadflag = DEAD_DEAD;
2310                                 }
2311                                 else if (self.deadflag == DEAD_DEAD)
2312                                 {
2313                                         if(button_pressed)
2314                                                 self.deadflag = DEAD_RESPAWNABLE;
2315                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2316                                                 self.deadflag = DEAD_RESPAWNING;
2317                                 }
2318                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2319                                 {
2320                                         if(!button_pressed)
2321                                                 self.deadflag = DEAD_RESPAWNING;
2322                                 }
2323                                 else if (self.deadflag == DEAD_RESPAWNING)
2324                                 {
2325                                         if(time > self.respawn_time)
2326                                         {
2327                                                 self.respawn_time = time + 1; // only retry once a second
2328                                                 self.respawn_time_max = self.respawn_time;
2329                                                 respawn();
2330                                         }
2331                                 }
2332
2333                                 ShowRespawnCountdown();
2334
2335                                 if(self.respawn_flags & RESPAWN_SILENT)
2336                                         self.stat_respawn_time = 0;
2337                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2338                                         self.stat_respawn_time = self.respawn_time_max;
2339                                 else
2340                                         self.stat_respawn_time = self.respawn_time;
2341                         }
2342
2343                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2344                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2345                                 self.stat_respawn_time *= -1;
2346
2347                         return;
2348                 }
2349
2350                 self.prevorigin = self.origin;
2351
2352                 float do_crouch = self.BUTTON_CROUCH;
2353                 if(self.hook.state)
2354                         do_crouch = 0;
2355                 if(self.vehicle)
2356                         do_crouch = 0;
2357                 if(self.frozen)
2358                         do_crouch = 0;
2359
2360                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2361                 // It cannot be predicted by the engine!
2362                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2363                         do_crouch = 0;
2364
2365                 if (do_crouch)
2366                 {
2367                         if (!self.crouch)
2368                         {
2369                                 self.crouch = TRUE;
2370                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2371                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2372                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2373                         }
2374                 }
2375                 else
2376                 {
2377                         if (self.crouch)
2378                         {
2379                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2380                                 if (!trace_startsolid)
2381                                 {
2382                                         self.crouch = FALSE;
2383                                         self.view_ofs = PL_VIEW_OFS;
2384                                         setsize (self, PL_MIN, PL_MAX);
2385                                 }
2386                         }
2387                 }
2388
2389                 FixPlayermodel();
2390
2391                 GrapplingHookFrame();
2392
2393                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2394                 //if(frametime)
2395                 {
2396                         self.items &= ~self.items_added;
2397
2398                         W_WeaponFrame();
2399
2400                         self.items_added = 0;
2401                         if(self.items & IT_JETPACK)
2402                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2403                                         self.items_added |= IT_FUEL;
2404
2405                         self.items |= self.items_added;
2406                 }
2407
2408                 player_regen();
2409
2410                 // WEAPONTODO: Add a weapon request for this
2411                 // rot vortex charge to the charge limit
2412                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2413                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2414
2415                 if(frametime)
2416                         player_anim();
2417
2418                 // secret status
2419                 secrets_setstatus();
2420
2421                 // monsters status
2422                 monsters_setstatus();
2423
2424                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2425
2426                 //self.angles_y=self.v_angle_y + 90;   // temp
2427         } else if(gameover) {
2428                 if (intermission_running)
2429                         IntermissionThink ();   // otherwise a button could be missed between
2430                 return;
2431         } else if(IS_OBSERVER(self)) {
2432                 ObserverThink();
2433         } else if(IS_SPEC(self)) {
2434                 SpectatorThink();
2435         }
2436
2437         // WEAPONTODO: Add weapon request for this
2438         if(!zoomstate_set)
2439                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2440
2441         float oldspectatee_status;
2442         oldspectatee_status = self.spectatee_status;
2443         if(IS_SPEC(self))
2444                 self.spectatee_status = num_for_edict(self.enemy);
2445         else if(IS_OBSERVER(self))
2446                 self.spectatee_status = num_for_edict(self);
2447         else
2448                 self.spectatee_status = 0;
2449         if(self.spectatee_status != oldspectatee_status)
2450         {
2451                 ClientData_Touch(self);
2452         }
2453
2454         if(self.teamkill_soundtime)
2455         if(time > self.teamkill_soundtime)
2456         {
2457                 self.teamkill_soundtime = 0;
2458
2459                 entity oldpusher, oldself;
2460
2461                 oldself = self; self = self.teamkill_soundsource;
2462                 oldpusher = self.pusher; self.pusher = oldself;
2463
2464                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2465
2466                 self.pusher = oldpusher;
2467                 self = oldself;
2468         }
2469
2470         if(self.taunt_soundtime)
2471         if(time > self.taunt_soundtime)
2472         {
2473                 self.taunt_soundtime = 0;
2474                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2475         }
2476
2477         target_voicescript_next(self);
2478
2479         // WEAPONTODO: Move into weaponsystem somehow
2480         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2481         if(!self.weapon)
2482                 self.clip_load = self.clip_size = 0;
2483 }
2484
2485 float isInvisibleString(string s)
2486 {
2487         float i, n, c;
2488         s = strdecolorize(s);
2489         for((i = 0), (n = strlen(s)); i < n; ++i)
2490         {
2491                 c = str2chr(s, i);
2492                 switch(c)
2493                 {
2494                         case 0:
2495                         case 32: // space
2496                                 break;
2497                         case 192: // charmap space
2498                                 if (!autocvar_utf8_enable)
2499                                         break;
2500                                 return FALSE;
2501                         case 160: // space in unicode fonts
2502                         case 0xE000 + 192: // utf8 charmap space
2503                                 if (autocvar_utf8_enable)
2504                                         break;
2505                         default:
2506                                 return FALSE;
2507                 }
2508         }
2509         return TRUE;
2510 }
2511
2512 /*
2513 =============
2514 PlayerPostThink
2515
2516 Called every frame for each client after the physics are run
2517 =============
2518 */
2519 .float idlekick_lasttimeleft;
2520 void PlayerPostThink (void)
2521 {
2522         // Savage: Check for nameless players
2523         if (isInvisibleString(self.netname)) {
2524                 self.netname = "Player";
2525                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2526         }
2527
2528         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2529         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2530         {
2531                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2532                 {
2533                         if(self.idlekick_lasttimeleft)
2534                         {
2535                                 self.idlekick_lasttimeleft = 0;
2536                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2537                         }
2538                 }
2539                 else
2540                 {
2541                         float timeleft;
2542                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2543                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2544                         {
2545                                 if(!self.idlekick_lasttimeleft)
2546                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2547                         }
2548                         if(timeleft <= 0)
2549                         {
2550                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2551                                 dropclient(self);
2552                                 return;
2553                         }
2554                         else if(timeleft <= 10)
2555                         {
2556                                 if(timeleft != self.idlekick_lasttimeleft)
2557                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2558                                 self.idlekick_lasttimeleft = timeleft;
2559                         }
2560                 }
2561         }
2562
2563 #ifdef TETRIS
2564         if(self.impulse == 100)
2565                 ImpulseCommands();
2566         if (!TetrisPostFrame())
2567         {
2568 #endif
2569
2570         CheatFrame();
2571
2572         //CheckPlayerJump();
2573
2574         if(IS_PLAYER(self)) {
2575                 CheckRules_Player();
2576                 UpdateChatBubble();
2577                 if (self.impulse)
2578                         ImpulseCommands();
2579                 if (intermission_running)
2580                         return;         // intermission or finale
2581                 GetPressedKeys();
2582         }
2583
2584 #ifdef TETRIS
2585         }
2586 #endif
2587
2588         /*
2589         float i;
2590         for(i = 0; i < 1000; ++i)
2591         {
2592                 vector end;
2593                 end = self.origin + '0 0 1024' + 512 * randomvec();
2594                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2595                 if(trace_fraction < 1)
2596                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2597                 {
2598                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2599                         break;
2600                 }
2601         }
2602         */
2603
2604         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2605
2606         if(self.waypointsprite_attachedforcarrier)
2607                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2608
2609         playerdemo_write();
2610
2611         CSQCMODEL_AUTOUPDATE();
2612 }