qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(IS_SPEC(to))
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(IS_SPEC(e2))
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77 .string netname_previous;
  78
  79
  80 /*
  81 =============
  82 CheckPlayerModel
  83
  84 Checks if the argument string can be a valid playermodel.
  85 Returns a valid one in doubt.
  86 =============
  87 */
  88 string FallbackPlayerModel;
  89 string CheckPlayerModel(string plyermodel) {
  90         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  91         {
  92                 // note: we cannot summon Don Strunzone here, some player may
  93                 // still have the model string set. In case anyone manages how
  94                 // to change a cvar default, we'll have a small leak here.
  95                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  96         }
  97         // only in right path
  98         if( substring(plyermodel,0,14) != "models/player/")
  99                 return FallbackPlayerModel;
 100         // only good file extensions
 101         if(substring(plyermodel,-4,4) != ".zym")
 102         if(substring(plyermodel,-4,4) != ".dpm")
 103         if(substring(plyermodel,-4,4) != ".iqm")
 104         if(substring(plyermodel,-4,4) != ".md3")
 105         if(substring(plyermodel,-4,4) != ".psk")
 106                 return FallbackPlayerModel;
 107         // forbid the LOD models
 108         if(substring(plyermodel, -9,5) == "_lod1")
 109                 return FallbackPlayerModel;
 110         if(substring(plyermodel, -9,5) == "_lod2")
 111                 return FallbackPlayerModel;
 112         if(plyermodel != strtolower(plyermodel))
 113                 return FallbackPlayerModel;
 114         // also, restrict to server models
 115         if(autocvar_sv_servermodelsonly)
 116         {
 117                 if(!fexists(plyermodel))
 118                         return FallbackPlayerModel;
 119         }
 120         return plyermodel;
 121 }
 122
 123 void setplayermodel(entity e, string modelname)
 124 {
 125         precache_model(modelname);
 126         setmodel(e, modelname);
 127         player_setupanimsformodel();
 128         UpdatePlayerSounds();
 129 }
 130
 131 /*
 132 =============
 133 PutObserverInServer
 134
 135 putting a client as observer in the server
 136 =============
 137 */
 138 void FixPlayermodel();
 139 void PutObserverInServer (void)
 140 {
 141         entity  spot;
 142     self.hud = HUD_NORMAL;
 143         race_PreSpawnObserver();
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         if((g_race && g_race_qualifying) || g_cts)
 158         {
 159                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 160                         self.frags = FRAGS_LMS_LOSER;
 161                 else
 162                         self.frags = FRAGS_SPECTATOR;
 163         }
 164         else
 165                 self.frags = FRAGS_SPECTATOR;
 166
 167         MUTATOR_CALLHOOK(MakePlayerObserver);
 168
 169         Portal_ClearAll(self);
 170
 171         if(self.alivetime)
 172         {
 173                 if(!inWarmupStage)
 174                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 175                 self.alivetime = 0;
 176         }
 177
 178         if(self.vehicle)
 179                 vehicles_exit(VHEF_RELESE);
 180
 181         WaypointSprite_PlayerDead();
 182
 183         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 184                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 185
 186         if(self.killcount != -666)
 187         {
 188                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 189
 190                 if(self.just_joined == FALSE) {
 191                         LogTeamchange(self.playerid, -1, 4);
 192                 } else
 193                         self.just_joined = FALSE;
 194         }
 195
 196         PlayerScore_Clear(self); // clear scores when needed
 197
 198         accuracy_resend(self);
 199
 200         self.spectatortime = time;
 201
 202         self.classname = "observer";
 203         self.iscreature = FALSE;
 204         self.teleportable = TELEPORT_SIMPLE;
 205         self.damagedbycontents = FALSE;
 206         self.health = -666;
 207         self.takedamage = DAMAGE_NO;
 208         self.solid = SOLID_NOT;
 209         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 210         self.flags = FL_CLIENT | FL_NOTARGET;
 211         self.armorvalue = 666;
 212         self.effects = 0;
 213         self.armorvalue = autocvar_g_balance_armor_start;
 214         self.pauserotarmor_finished = 0;
 215         self.pauserothealth_finished = 0;
 216         self.pauseregen_finished = 0;
 217         self.damageforcescale = 0;
 218         self.death_time = 0;
 219         self.respawn_flags = 0;
 220         self.respawn_time = 0;
 221         self.stat_respawn_time = 0;
 222         self.alpha = 0;
 223         self.scale = 0;
 224         self.fade_time = 0;
 225         self.pain_frame = 0;
 226         self.pain_finished = 0;
 227         self.strength_finished = 0;
 228         self.invincible_finished = 0;
 229         self.superweapons_finished = 0;
 230         self.pushltime = 0;
 231         self.istypefrag = 0;
 232         self.think = func_null;
 233         self.nextthink = 0;
 234         self.hook_time = 0;
 235         self.deadflag = DEAD_NO;
 236         self.angles = spot.angles;
 237         self.angles_z = 0;
 238         self.fixangle = TRUE;
 239         self.crouch = FALSE;
 240
 241         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 242         self.prevorigin = self.origin;
 243         self.items = 0;
 244         WEPSET_CLEAR_E(self);
 245         self.model = "";
 246         FixPlayermodel();
 247         setmodel(self, "null");
 248         self.drawonlytoclient = self;
 249
 250         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 251         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 252
 253         self.weapon = 0;
 254         self.weaponname = "";
 255         self.switchingweapon = 0;
 256         self.weaponmodel = "";
 257         self.weaponentity = world;
 258         self.exteriorweaponentity = world;
 259         self.killcount = -666;
 260         self.velocity = '0 0 0';
 261         self.avelocity = '0 0 0';
 262         self.punchangle = '0 0 0';
 263         self.punchvector = '0 0 0';
 264         self.oldvelocity = self.velocity;
 265         self.fire_endtime = -1;
 266 }
 267
 268 .float model_randomizer;
 269 void FixPlayermodel()
 270 {
 271         string defaultmodel;
 272         float defaultskin, chmdl, oldskin, n, i;
 273         vector m1, m2;
 274
 275         defaultmodel = "";
 276         defaultskin = 0;
 277         chmdl = FALSE;
 278
 279         if(autocvar_sv_defaultcharacter == 1)
 280         {
 281                 if(teamplay)
 282                 {
 283                         string s;
 284                         s = Team_ColorName_Lower(self.team);
 285                         if(s != "neutral")
 286                         {
 287                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 288                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 289                         }
 290                 }
 291
 292                 if(defaultmodel == "")
 293                 {
 294                         defaultmodel = autocvar_sv_defaultplayermodel;
 295                         defaultskin = autocvar_sv_defaultplayerskin;
 296                 }
 297
 298                 n = tokenize_console(defaultmodel);
 299                 if(n > 0)
 300                         defaultmodel = argv(floor(n * self.model_randomizer));
 301
 302                 i = strstrofs(defaultmodel, ":", 0);
 303                 if(i >= 0)
 304                 {
 305                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 306                         defaultmodel = substring(defaultmodel, 0, i);
 307                 }
 308         }
 309
 310         if(defaultmodel != "")
 311         {
 312                 if (defaultmodel != self.model)
 313                 {
 314                         m1 = self.mins;
 315                         m2 = self.maxs;
 316                         setplayermodel (self, defaultmodel);
 317                         setsize (self, m1, m2);
 318                         chmdl = TRUE;
 319                 }
 320
 321                 oldskin = self.skin;
 322                 self.skin = defaultskin;
 323         } else {
 324                 if (self.playermodel != self.model || self.playermodel == "")
 325                 {
 326                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 327                         m1 = self.mins;
 328                         m2 = self.maxs;
 329                         setplayermodel (self, self.playermodel);
 330                         setsize (self, m1, m2);
 331                         chmdl = TRUE;
 332                 }
 333
 334                 oldskin = self.skin;
 335                 self.skin = stof(self.playerskin);
 336         }
 337
 338         if(chmdl || oldskin != self.skin) // model or skin has changed
 339         {
 340                 self.species = player_getspecies(); // update species
 341                 UpdatePlayerSounds(); // update skin sounds
 342         }
 343
 344         if(!teamplay)
 345                 if(strlen(autocvar_sv_defaultplayercolors))
 346                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 347                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 348 }
 349
 350 /*
 351 =============
 352 PutClientInServer
 353
 354 Called when a client spawns in the server
 355 =============
 356 */
 357 void PutClientInServer (void)
 358 {
 359         if(IS_BOT_CLIENT(self))
 360                 self.classname = "player";
 361         else if(IS_REAL_CLIENT(self))
 362         {
 363                 msg_entity = self;
 364                 WriteByte(MSG_ONE, SVC_SETVIEW);
 365                 WriteEntity(MSG_ONE, self);
 366         }
 367
 368         // reset player keys
 369         self.itemkeys = 0;
 370
 371         MUTATOR_CALLHOOK(PutClientInServer);
 372
 373         if(gameover)
 374                 self.classname = "observer";
 375
 376         if(IS_PLAYER(self))
 377         {
 378                 entity spot, oldself;
 379                 float j;
 380
 381                 accuracy_resend(self);
 382
 383                 if(self.team < 0)
 384                         JoinBestTeam(self, FALSE, TRUE);
 385
 386                 race_PreSpawn();
 387
 388                 spot = SelectSpawnPoint (FALSE);
 389                 if(!spot)
 390                 {
 391                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 392                         return; // spawn failed
 393                 }
 394
 395                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397                 self.classname = "player";
 398                 self.wasplayer = TRUE;
 399                 self.iscreature = TRUE;
 400                 self.teleportable = TELEPORT_NORMAL;
 401                 self.damagedbycontents = TRUE;
 402                 self.movetype = MOVETYPE_WALK;
 403                 self.solid = SOLID_SLIDEBOX;
 404                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 405                 if(autocvar_g_playerclip_collisions)
 406                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 407                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 408                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 409                 self.frags = FRAGS_PLAYER;
 410                 if(INDEPENDENT_PLAYERS)
 411                         MAKE_INDEPENDENT_PLAYER(self);
 412                 self.flags = FL_CLIENT;
 413                 if(autocvar__notarget)
 414                         self.flags |= FL_NOTARGET;
 415                 self.takedamage = DAMAGE_AIM;
 416                 self.effects = 0;
 417                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 418                 self.air_finished = time + 12;
 419                 self.dmg = 2;
 420                 if(autocvar_g_balance_nex_charge)
 421                 {
 422                         if(autocvar_g_balance_nex_secondary_chargepool)
 423                                 self.nex_chargepool_ammo = 1;
 424                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 425                 }
 426
 427                 if(inWarmupStage)
 428                 {
 429                         self.ammo_shells = warmup_start_ammo_shells;
 430                         self.ammo_nails = warmup_start_ammo_nails;
 431                         self.ammo_rockets = warmup_start_ammo_rockets;
 432                         self.ammo_cells = warmup_start_ammo_cells;
 433                         self.ammo_fuel = warmup_start_ammo_fuel;
 434                         self.health = warmup_start_health;
 435                         self.armorvalue = warmup_start_armorvalue;
 436                         WEPSET_COPY_EA(self, warmup_start_weapons);
 437                 }
 438                 else
 439                 {
 440                         self.ammo_shells = start_ammo_shells;
 441                         self.ammo_nails = start_ammo_nails;
 442                         self.ammo_rockets = start_ammo_rockets;
 443                         self.ammo_cells = start_ammo_cells;
 444                         self.ammo_fuel = start_ammo_fuel;
 445                         self.health = start_health;
 446                         self.armorvalue = start_armorvalue;
 447                         WEPSET_COPY_EA(self, start_weapons);
 448                 }
 449
 450                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 451                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 452                 else
 453                         self.superweapons_finished = 0;
 454
 455                 if(g_weaponarena_random)
 456                 {
 457                         if(g_weaponarena_random_with_laser)
 458                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 459                         W_RandomWeapons(self, g_weaponarena_random);
 460                         if(g_weaponarena_random_with_laser)
 461                                 WEPSET_OR_EW(self, WEP_LASER);
 462                 }
 463
 464                 self.items = start_items;
 465
 466                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 467                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 468                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 469                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 470                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 471                 //extend the pause of rotting if client was reset at the beginning of the countdown
 472                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 473                         self.spawnshieldtime += game_starttime - time;
 474                         self.pauserotarmor_finished += game_starttime - time;
 475                         self.pauserothealth_finished += game_starttime - time;
 476                         self.pauseregen_finished += game_starttime - time;
 477                 }
 478                 self.damageforcescale = 2;
 479                 self.death_time = 0;
 480                 self.respawn_flags = 0;
 481                 self.respawn_time = 0;
 482                 self.stat_respawn_time = 0;
 483                 self.scale = 0;
 484                 self.fade_time = 0;
 485                 self.pain_frame = 0;
 486                 self.pain_finished = 0;
 487                 self.strength_finished = 0;
 488                 self.invincible_finished = 0;
 489                 self.pushltime = 0;
 490                 // players have no think function
 491                 self.think = func_null;
 492                 self.nextthink = 0;
 493                 self.hook_time = 0;
 494                 self.dmg_team = 0;
 495                 self.ballistics_density = autocvar_g_ballistics_density_player;
 496
 497                 self.metertime = 0;
 498
 499                 self.deadflag = DEAD_NO;
 500
 501                 self.angles = spot.angles;
 502
 503                 self.angles_z = 0; // never spawn tilted even if the spot says to
 504                 self.fixangle = TRUE; // turn this way immediately
 505                 self.velocity = '0 0 0';
 506                 self.avelocity = '0 0 0';
 507                 self.punchangle = '0 0 0';
 508                 self.punchvector = '0 0 0';
 509                 self.oldvelocity = self.velocity;
 510                 self.fire_endtime = -1;
 511
 512                 entity spawnevent = spawn();
 513                 spawnevent.owner = self;
 514                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 515
 516                 self.model = "";
 517                 FixPlayermodel();
 518                 self.drawonlytoclient = world;
 519
 520                 self.crouch = FALSE;
 521                 self.view_ofs = PL_VIEW_OFS;
 522                 setsize (self, PL_MIN, PL_MAX);
 523                 self.spawnorigin = spot.origin;
 524                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 525                 // don't reset back to last position, even if new position is stuck in solid
 526                 self.oldorigin = self.origin;
 527                 self.prevorigin = self.origin;
 528                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 529                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 530         self.hud = HUD_NORMAL;
 531
 532                 self.event_damage = PlayerDamage;
 533
 534                 self.bot_attack = TRUE;
 535
 536                 self.statdraintime = time + 5;
 537                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 538
 539                 if(self.killcount == -666) {
 540                         PlayerScore_Clear(self);
 541                         self.killcount = 0;
 542                 }
 543
 544                 CL_SpawnWeaponentity();
 545                 self.alpha = default_player_alpha;
 546                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 547                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 548
 549                 self.speedrunning = FALSE;
 550
 551                 race_PostSpawn(spot);
 552
 553                 //stuffcmd(self, "chase_active 0");
 554                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 555
 556                 target_voicescript_clear(self);
 557
 558                 // reset fields the weapons may use
 559                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 560                 {
 561                         weapon_action(j, WR_RESETPLAYER);
 562
 563                         // all weapons must be fully loaded when we spawn
 564                         entity e;
 565                         e = get_weaponinfo(j);
 566                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 567                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 568                 }
 569
 570                 oldself = self;
 571                 self = spot;
 572                         activator = oldself;
 573                                 string s;
 574                                 s = self.target;
 575                                 self.target = string_null;
 576                                 SUB_UseTargets();
 577                                 self.target = s;
 578                         activator = world;
 579                 self = oldself;
 580
 581                 spawn_spot = spot;
 582                 MUTATOR_CALLHOOK(PlayerSpawn);
 583
 584                 if(autocvar_spawn_debug)
 585                 {
 586                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 587                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 588                 }
 589
 590                 self.switchweapon = w_getbestweapon(self);
 591                 self.cnt = -1; // W_LastWeapon will not complain
 592                 self.weapon = 0;
 593                 self.weaponname = "";
 594                 self.switchingweapon = 0;
 595
 596                 if(!inWarmupStage)
 597                         if(!self.alivetime)
 598                                 self.alivetime = time;
 599
 600                 antilag_clear(self);
 601         }
 602         else if(IS_OBSERVER(self))
 603         {
 604                 PutObserverInServer ();
 605         }
 606 }
 607
 608 .float ebouncefactor, ebouncestop; // electro's values
 609 // TODO do we need all these fields, or should we stop autodetecting runtime
 610 // changes and just have a console command to update this?
 611 float ClientInit_SendEntity(entity to, float sf)
 612 {
 613         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 614         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 615         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 616         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 617         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 618         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 619         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 620         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 621         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 622         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 623         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 624         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 627         if(sv_foginterval && world.fog != "")
 628                 WriteString(MSG_ENTITY, world.fog);
 629         else
 630                 WriteString(MSG_ENTITY, "");
 631         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 632         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 633         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 634         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 635         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 636         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 637         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 638         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 639         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 640         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 641         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 642         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 643         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 644         return TRUE;
 645 }
 646
 647 void ClientInit_CheckUpdate()
 648 {
 649         self.nextthink = time;
 650         if(self.count != autocvar_g_balance_armor_blockpercent)
 651         {
 652                 self.count = autocvar_g_balance_armor_blockpercent;
 653                 self.SendFlags |= 1;
 654         }
 655         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 656         {
 657                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 658                 self.SendFlags |= 1;
 659         }
 660         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 661         {
 662                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 663                 self.SendFlags |= 1;
 664         }
 665         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 666         {
 667                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 668                 self.SendFlags |= 1;
 669         }
 670         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 671         {
 672                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 673                 self.SendFlags |= 1;
 674         }
 675         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 676         {
 677                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 678                 self.SendFlags |= 1;
 679         }
 680 }
 681
 682 void ClientInit_Spawn()
 683 {
 684         entity o;
 685         entity e;
 686         e = spawn();
 687         e.classname = "clientinit";
 688         e.think = ClientInit_CheckUpdate;
 689         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 690
 691         o = self;
 692         self = e;
 693         ClientInit_CheckUpdate();
 694         self = o;
 695 }
 696
 697 /*
 698 =============
 699 SetNewParms
 700 =============
 701 */
 702 void SetNewParms (void)
 703 {
 704         // initialize parms for a new player
 705         parm1 = -(86400 * 366);
 706 }
 707
 708 /*
 709 =============
 710 SetChangeParms
 711 =============
 712 */
 713 void SetChangeParms (void)
 714 {
 715         // save parms for level change
 716         parm1 = self.parm_idlesince - time;
 717 }
 718
 719 /*
 720 =============
 721 DecodeLevelParms
 722 =============
 723 */
 724 void DecodeLevelParms (void)
 725 {
 726         // load parms
 727         self.parm_idlesince = parm1;
 728         if(self.parm_idlesince == -(86400 * 366))
 729                 self.parm_idlesince = time;
 730
 731         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 732         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 733 }
 734
 735 /*
 736 =============
 737 ClientKill
 738
 739 Called when a client types 'kill' in the console
 740 =============
 741 */
 742
 743 .float clientkill_nexttime;
 744 void ClientKill_Now_TeamChange()
 745 {
 746         if(self.killindicator_teamchange == -1)
 747         {
 748                 JoinBestTeam( self, FALSE, TRUE );
 749         }
 750         else if(self.killindicator_teamchange == -2)
 751         {
 752                 if(blockSpectators)
 753                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 754                 PutObserverInServer();
 755         }
 756         else
 757                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 758         self.killindicator_teamchange = 0;
 759 }
 760
 761 void ClientKill_Now()
 762 {
 763         if(self.vehicle)
 764         {
 765             vehicles_exit(VHEF_RELESE);
 766             if(!self.killindicator_teamchange)
 767             {
 768             self.vehicle_health = -1;
 769             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 770             }
 771         }
 772
 773         if(self.killindicator && !wasfreed(self.killindicator))
 774                 remove(self.killindicator);
 775
 776         self.killindicator = world;
 777
 778         if(self.killindicator_teamchange)
 779                 ClientKill_Now_TeamChange();
 780
 781         // in any case:
 782         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 783
 784         // now I am sure the player IS dead
 785 }
 786 void KillIndicator_Think()
 787 {
 788         if (gameover)
 789         {
 790                 self.owner.killindicator = world;
 791                 remove(self);
 792                 return;
 793         }
 794
 795         if (self.owner.alpha < 0 && !self.owner.vehicle)
 796         {
 797                 self.owner.killindicator = world;
 798                 remove(self);
 799                 return;
 800         }
 801
 802         if(self.cnt <= 0)
 803         {
 804                 self = self.owner;
 805                 ClientKill_Now(); // no oldself needed
 806                 return;
 807         }
 808     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 809     {
 810         self.nextthink = time + 1;
 811         self.cnt -= 1;
 812     }
 813         else
 814         {
 815                 if(self.cnt <= 10)
 816                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 817                 if(IS_REAL_CLIENT(self.owner))
 818                 {
 819                         if(self.cnt <= 10)
 820                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(self.cnt)); }
 821                 }
 822                 self.nextthink = time + 1;
 823                 self.cnt -= 1;
 824         }
 825 }
 826
 827 float clientkilltime;
 828 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 829 {
 830         float killtime;
 831         float starttime;
 832         entity e;
 833
 834         if (gameover)
 835                 return;
 836
 837         killtime = autocvar_g_balance_kill_delay;
 838
 839         if(g_race_qualifying || g_cts)
 840                 killtime = 0;
 841
 842     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 843     {
 844                 remove(self.killindicator);
 845                 self.killindicator = world;
 846
 847         ClientKill_Now(); // allow instant kill in this case
 848         return;
 849     }
 850
 851         self.killindicator_teamchange = targetteam;
 852
 853     if(!self.killindicator)
 854         {
 855                 if(self.deadflag == DEAD_NO)
 856                 {
 857                         killtime = max(killtime, self.clientkill_nexttime - time);
 858                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 859                 }
 860
 861                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 862                 {
 863                         ClientKill_Now();
 864                 }
 865                 else
 866                 {
 867                         starttime = max(time, clientkilltime);
 868
 869                         self.killindicator = spawn();
 870                         self.killindicator.owner = self;
 871                         self.killindicator.scale = 0.5;
 872                         setattachment(self.killindicator, self, "");
 873                         setorigin(self.killindicator, '0 0 52');
 874                         self.killindicator.think = KillIndicator_Think;
 875                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 876                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 877                         self.killindicator.cnt = ceil(killtime);
 878                         self.killindicator.count = bound(0, ceil(killtime), 10);
 879                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 880
 881                         for(e = world; (e = find(e, classname, "body")) != world; )
 882                         {
 883                                 if(e.enemy != self)
 884                                         continue;
 885                                 e.killindicator = spawn();
 886                                 e.killindicator.owner = e;
 887                                 e.killindicator.scale = 0.5;
 888                                 setattachment(e.killindicator, e, "");
 889                                 setorigin(e.killindicator, '0 0 52');
 890                                 e.killindicator.think = KillIndicator_Think;
 891                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 892                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 893                                 e.killindicator.cnt = ceil(killtime);
 894                         }
 895                         self.lip = 0;
 896                 }
 897         }
 898         if(self.killindicator)
 899         {
 900                 if(targetteam == 0) // just die
 901                 {
 902                         self.killindicator.colormod = '0 0 0';
 903                         if(IS_REAL_CLIENT(self))
 904                         if(self.killindicator.cnt > 0)
 905                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 906                 }
 907                 else if(targetteam == -1) // auto
 908                 {
 909                         self.killindicator.colormod = '0 1 0';
 910                         if(IS_REAL_CLIENT(self))
 911                         if(self.killindicator.cnt > 0)
 912                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 913                 }
 914                 else if(targetteam == -2) // spectate
 915                 {
 916                         self.killindicator.colormod = '0.5 0.5 0.5';
 917                         if(IS_REAL_CLIENT(self))
 918                         if(self.killindicator.cnt > 0)
 919                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 920                 }
 921                 else
 922                 {
 923                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 924                         if(IS_REAL_CLIENT(self))
 925                         if(self.killindicator.cnt > 0)
 926                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 927                 }
 928         }
 929
 930 }
 931
 932 void ClientKill (void)
 933 {
 934         if(gameover) return;
 935         if(self.player_blocked) return;
 936         if(self.freezetag_frozen) return;
 937
 938         ClientKill_TeamChange(0);
 939 }
 940
 941 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 942 {
 943     e.killindicator = spawn();
 944     e.killindicator.owner = e;
 945     e.killindicator.think = KillIndicator_Think;
 946     e.killindicator.nextthink = time + (e.lip) * 0.05;
 947     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 948     e.killindicator.health = 1; // this is used to indicate that it should be silent
 949     e.lip = 0;
 950 }
 951
 952 void FixClientCvars(entity e)
 953 {
 954         // send prediction settings to the client
 955         stuffcmd(e, "\nin_bindmap 0 0\n");
 956         if(g_race || g_cts)
 957                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 958         if(autocvar_g_antilag == 3) // client side hitscan
 959                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 960         if(autocvar_sv_gentle)
 961                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 962         /*
 963          * we no longer need to stuff this. Remove this comment block if you feel
 964          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 965         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 966         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 967         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 968         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 969         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 970         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 971         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 972         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 973         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 974         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 975         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 976         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 977         stuffcmd(e, "cl_movement_edgefriction 1\n");
 978          */
 979 }
 980
 981 float PlayerInIDList(entity p, string idlist)
 982 {
 983         float n, i;
 984         string s;
 985
 986         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 987         if not(p.crypto_idfp)
 988                 return 0;
 989
 990         // this function allows abbreviated player IDs too!
 991         n = tokenize_console(idlist);
 992         for(i = 0; i < n; ++i)
 993         {
 994                 s = argv(i);
 995                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 996                         return 1;
 997         }
 998
 999         return 0;
1000 }
1001
1002 /*
1003 =============
1004 ClientConnect
1005
1006 Called when a client connects to the server
1007 =============
1008 */
1009 void DecodeLevelParms (void);
1010 //void dom_player_join_team(entity pl);
1011 void set_dom_state(entity e);
1012 void ClientConnect (void)
1013 {
1014         float t;
1015
1016         if(IS_CLIENT(self))
1017         {
1018                 print("Warning: ClientConnect, but already connected!\n");
1019                 return;
1020         }
1021
1022         if(Ban_MaybeEnforceBanOnce(self))
1023                 return;
1024
1025         DecodeLevelParms();
1026
1027 #ifdef WATERMARK
1028         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1029 #endif
1030
1031         self.classname = "player_joining";
1032
1033         self.flags = FL_CLIENT;
1034         self.version_nagtime = time + 10 + random() * 10;
1035
1036         if(player_count<0)
1037         {
1038                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1039                 player_count = 0;
1040         }
1041
1042         PlayerScore_Attach(self);
1043         ClientData_Attach();
1044         accuracy_init(self);
1045
1046         bot_clientconnect();
1047
1048         playerdemo_init();
1049
1050         anticheat_init();
1051
1052         race_PreSpawnObserver();
1053
1054         // identify the right forced team
1055         if(autocvar_g_campaign)
1056         {
1057                 if(IS_REAL_CLIENT(self)) // only players, not bots
1058                 {
1059                         switch(autocvar_g_campaign_forceteam)
1060                         {
1061                                 case 1: self.team_forced = NUM_TEAM_1; break;
1062                                 case 2: self.team_forced = NUM_TEAM_2; break;
1063                                 case 3: self.team_forced = NUM_TEAM_3; break;
1064                                 case 4: self.team_forced = NUM_TEAM_4; break;
1065                                 default: self.team_forced = 0;
1066                         }
1067                 }
1068         }
1069         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1070                 self.team_forced = NUM_TEAM_1;
1071         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1072                 self.team_forced = NUM_TEAM_2;
1073         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1074                 self.team_forced = NUM_TEAM_3;
1075         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1076                 self.team_forced = NUM_TEAM_4;
1077         else if(autocvar_g_forced_team_otherwise == "red")
1078                 self.team_forced = NUM_TEAM_1;
1079         else if(autocvar_g_forced_team_otherwise == "blue")
1080                 self.team_forced = NUM_TEAM_2;
1081         else if(autocvar_g_forced_team_otherwise == "yellow")
1082                 self.team_forced = NUM_TEAM_3;
1083         else if(autocvar_g_forced_team_otherwise == "pink")
1084                 self.team_forced = NUM_TEAM_4;
1085         else if(autocvar_g_forced_team_otherwise == "spectate")
1086                 self.team_forced = -1;
1087         else if(autocvar_g_forced_team_otherwise == "spectator")
1088                 self.team_forced = -1;
1089         else
1090                 self.team_forced = 0;
1091
1092         if(!teamplay)
1093                 if(self.team_forced > 0)
1094                         self.team_forced = 0;
1095
1096         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1097
1098         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1099                 self.classname = "observer";
1100         } else {
1101                 if(teamplay)
1102                 {
1103                         if(autocvar_g_balance_teams)
1104                         {
1105                                 self.classname = "player";
1106                                 campaign_bots_may_start = 1;
1107                         }
1108                         else
1109                         {
1110                                 self.classname = "observer"; // do it anyway
1111                         }
1112                 }
1113                 else
1114                 {
1115                         self.classname = "player";
1116                         campaign_bots_may_start = 1;
1117                 }
1118         }
1119
1120         self.playerid = (playerid_last = playerid_last + 1);
1121
1122         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1123
1124     if(IS_BOT_CLIENT(self))
1125         PlayerStats_AddPlayer(self);
1126
1127         if(autocvar_sv_eventlog)
1128                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1129
1130         LogTeamchange(self.playerid, self.team, 1);
1131
1132         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1133
1134         self.netname_previous = strzone(self.netname);
1135
1136         if(IS_PLAYER(self) && teamplay)
1137                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1138         else
1139                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1140
1141         stuffcmd(self, strcat(clientstuff, "\n"));
1142         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1143
1144         FixClientCvars(self);
1145
1146         // spawnfunc_waypoint sprites
1147         WaypointSprite_InitClient(self);
1148
1149         // Wazat's grappling hook
1150         SetGrappleHookBindings();
1151
1152         // get version info from player
1153         stuffcmd(self, "cmd clientversion $gameversion\n");
1154
1155         // get other cvars from player
1156         GetCvars(0);
1157
1158         // notify about available teams
1159         if(teamplay)
1160         {
1161                 CheckAllowedTeams(self);
1162                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1163                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1164         }
1165         else
1166                 stuffcmd(self, "set _teams_available 0\n");
1167
1168         attach_entcs();
1169
1170         bot_relinkplayerlist();
1171
1172         self.spectatortime = time;
1173         if(blockSpectators)
1174         {
1175                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1176         }
1177
1178         self.jointime = time;
1179         self.allowed_timeouts = autocvar_sv_timeout_number;
1180
1181         if(IS_REAL_CLIENT(self))
1182         {
1183                 if(!autocvar_g_campaign)
1184                 {
1185                         self.motd_actived_time = -1;
1186                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1187                 }
1188
1189                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1190                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1191         }
1192
1193         if(!sv_foginterval && world.fog != "")
1194                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1195
1196         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1197         {
1198                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1199                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1200         }
1201         else
1202                 self.hitplotfh = -1;
1203
1204         if(g_race || g_cts) {
1205                 string rr;
1206                 if(g_cts)
1207                         rr = CTS_RECORD;
1208                 else
1209                         rr = RACE_RECORD;
1210
1211                 msg_entity = self;
1212                 race_send_recordtime(MSG_ONE);
1213                 race_send_speedaward(MSG_ONE);
1214
1215                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1216                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1217                 race_send_speedaward_alltimebest(MSG_ONE);
1218
1219                 float i;
1220                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1221                         race_SendRankings(i, 0, 0, MSG_ONE);
1222                 }
1223         }
1224         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1225                 send_CSQC_teamnagger();
1226
1227         CheatInitClient();
1228
1229         CSQCMODEL_AUTOINIT();
1230
1231         self.model_randomizer = random();
1232
1233         if(IS_REAL_CLIENT(self))
1234                 sv_notice_join();
1235
1236         MUTATOR_CALLHOOK(ClientConnect);
1237 }
1238 /*
1239 =============
1240 ClientDisconnect
1241
1242 Called when a client disconnects from the server
1243 =============
1244 */
1245 .entity chatbubbleentity;
1246 void ReadyCount();
1247 void ClientDisconnect (void)
1248 {
1249         if(self.vehicle)
1250             vehicles_exit(VHEF_RELESE);
1251
1252         if not(IS_CLIENT(self))
1253         {
1254                 print("Warning: ClientDisconnect without ClientConnect\n");
1255                 return;
1256         }
1257
1258         PlayerStats_AddGlobalInfo(self);
1259
1260         CheatShutdownClient();
1261
1262         if(self.hitplotfh >= 0)
1263         {
1264                 fclose(self.hitplotfh);
1265                 self.hitplotfh = -1;
1266         }
1267
1268         anticheat_report();
1269         anticheat_shutdown();
1270
1271         playerdemo_shutdown();
1272
1273         bot_clientdisconnect();
1274
1275         if(self.entcs)
1276                 detach_entcs();
1277
1278         if(autocvar_sv_eventlog)
1279                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1280
1281         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1282
1283         MUTATOR_CALLHOOK(ClientDisconnect);
1284
1285         Portal_ClearAll(self);
1286
1287         RemoveGrapplingHook(self);
1288
1289         // Here, everything has been done that requires this player to be a client.
1290
1291         self.flags &~= FL_CLIENT;
1292
1293         if (self.chatbubbleentity)
1294                 remove (self.chatbubbleentity);
1295
1296         if (self.killindicator)
1297                 remove (self.killindicator);
1298
1299         WaypointSprite_PlayerGone();
1300
1301         bot_relinkplayerlist();
1302
1303         accuracy_free(self);
1304         ClientData_Detach();
1305         PlayerScore_Detach(self);
1306
1307         if(self.netname_previous)
1308                 strunzone(self.netname_previous);
1309         if(self.clientstatus)
1310                 strunzone(self.clientstatus);
1311         if(self.weaponorder_byimpulse)
1312                 strunzone(self.weaponorder_byimpulse);
1313
1314         ClearPlayerSounds();
1315
1316         if(self.personal)
1317                 remove(self.personal);
1318
1319         self.playerid = 0;
1320         ReadyCount();
1321
1322         // free cvars
1323         GetCvars(-1);
1324 }
1325
1326 .float BUTTON_CHAT;
1327 void ChatBubbleThink()
1328 {
1329         self.nextthink = time;
1330         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1331         {
1332                 if(self.owner) // but why can that ever be world?
1333                         self.owner.chatbubbleentity = world;
1334                 remove(self);
1335                 return;
1336         }
1337         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1338 #ifdef TETRIS
1339                 || self.owner.tetris_on
1340 #endif
1341         )
1342                 self.model = self.mdl;
1343         else
1344                 self.model = "";
1345 }
1346
1347 void UpdateChatBubble()
1348 {
1349         if (self.alpha < 0)
1350                 return;
1351         // spawn a chatbubble entity if needed
1352         if (!self.chatbubbleentity)
1353         {
1354                 self.chatbubbleentity = spawn();
1355                 self.chatbubbleentity.owner = self;
1356                 self.chatbubbleentity.exteriormodeltoclient = self;
1357                 self.chatbubbleentity.think = ChatBubbleThink;
1358                 self.chatbubbleentity.nextthink = time;
1359                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1360                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1361                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1362                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1363                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1364                 self.chatbubbleentity.model = "";
1365                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1366         }
1367 }
1368
1369
1370 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1371 // added to the model skins
1372 /*void UpdateColorModHack()
1373 {
1374         float c;
1375         c = self.clientcolors & 15;
1376         // LordHavoc: only bothering to support white, green, red, yellow, blue
1377              if (!teamplay) self.colormod = '0 0 0';
1378         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1379         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1380         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1381         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1382         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1383         else self.colormod = '1 1 1';
1384 }*/
1385
1386 void respawn(void)
1387 {
1388         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1389         {
1390                 self.solid = SOLID_NOT;
1391                 self.takedamage = DAMAGE_NO;
1392                 self.movetype = MOVETYPE_FLY;
1393                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1394                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1395                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1396                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1397                 if(autocvar_g_respawn_ghosts_maxtime)
1398                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1399         }
1400
1401         CopyBody(1);
1402
1403         self.effects |= EF_NODRAW; // prevent another CopyBody
1404         PutClientInServer();
1405 }
1406
1407 void play_countdown(float finished, string samp)
1408 {
1409         if(IS_REAL_CLIENT(self))
1410                 if(floor(finished - time - frametime) != floor(finished - time))
1411                         if(finished - time < 6)
1412                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1413 }
1414
1415 void player_powerups (void)
1416 {
1417         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1418         olditems = self.items;
1419
1420         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1421                 self.modelflags |= MF_ROCKET;
1422         else
1423                 self.modelflags &~= MF_ROCKET;
1424
1425         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1426
1427         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1428                 return;
1429
1430         Fire_ApplyDamage(self);
1431         Fire_ApplyEffect(self);
1432
1433         if not(g_minstagib)
1434         {
1435                 if (self.items & IT_STRENGTH)
1436                 {
1437                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1438                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1439                         if (time > self.strength_finished)
1440                         {
1441                                 self.items = self.items - (self.items & IT_STRENGTH);
1442                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1443                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1444                         }
1445                 }
1446                 else
1447                 {
1448                         if (time < self.strength_finished)
1449                         {
1450                                 self.items = self.items | IT_STRENGTH;
1451                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1452                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1453                         }
1454                 }
1455                 if (self.items & IT_INVINCIBLE)
1456                 {
1457                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1458                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1459                         if (time > self.invincible_finished)
1460                         {
1461                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1462                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1463                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1464                         }
1465                 }
1466                 else
1467                 {
1468                         if (time < self.invincible_finished)
1469                         {
1470                                 self.items = self.items | IT_INVINCIBLE;
1471                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1472                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1473                         }
1474                 }
1475                 if (self.items & IT_SUPERWEAPON)
1476                 {
1477                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1478                         {
1479                                 self.superweapons_finished = 0;
1480                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1481                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1482                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1483                         }
1484                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1485                         {
1486                                 // don't let them run out
1487                         }
1488                         else
1489                         {
1490                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1491                                 if (time > self.superweapons_finished)
1492                                 {
1493                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1494                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1495                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1496                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1497                                 }
1498                         }
1499                 }
1500                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1501                 {
1502                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1503                         {
1504                                 self.items = self.items | IT_SUPERWEAPON;
1505                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1506                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1507                         }
1508                         else
1509                         {
1510                                 self.superweapons_finished = 0;
1511                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1512                         }
1513                 }
1514                 else
1515                 {
1516                         self.superweapons_finished = 0;
1517                 }
1518         }
1519
1520         if(autocvar_g_nodepthtestplayers)
1521                 self.effects = self.effects | EF_NODEPTHTEST;
1522
1523         if(autocvar_g_fullbrightplayers)
1524                 self.effects = self.effects | EF_FULLBRIGHT;
1525
1526         // midair gamemode: damage only while in the air
1527         // if in midair mode, being on ground grants temporary invulnerability
1528         // (this is so that multishot weapon don't clear the ground flag on the
1529         // first damage in the frame, leaving the player vulnerable to the
1530         // remaining hits in the same frame)
1531         if (self.flags & FL_ONGROUND)
1532         if (g_midair)
1533                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1534
1535         if (time >= game_starttime)
1536         if (time < self.spawnshieldtime)
1537                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1538
1539         MUTATOR_CALLHOOK(PlayerPowerups);
1540 }
1541
1542 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1543 {
1544         if(current > stable)
1545                 return current;
1546         else if(current > stable - 0.25) // when close enough, "snap"
1547                 return stable;
1548         else
1549                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1550 }
1551
1552 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1553 {
1554         if(current < stable)
1555                 return current;
1556         else if(current < stable + 0.25) // when close enough, "snap"
1557                 return stable;
1558         else
1559                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1560 }
1561
1562 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1563 {
1564         if(current > rotstable)
1565         {
1566                 if(rotframetime > 0)
1567                 {
1568                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1569                         current = max(rotstable, current - rotlinear * rotframetime);
1570                 }
1571         }
1572         else if(current < regenstable)
1573         {
1574                 if(regenframetime > 0)
1575                 {
1576                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1577                         current = min(regenstable, current + regenlinear * regenframetime);
1578                 }
1579         }
1580
1581         if(current > limit)
1582                 current = limit;
1583
1584         return current;
1585 }
1586
1587 void player_regen (void)
1588 {
1589         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1590         maxh = autocvar_g_balance_health_rotstable;
1591         maxa = autocvar_g_balance_armor_rotstable;
1592         maxf = autocvar_g_balance_fuel_rotstable;
1593         minh = autocvar_g_balance_health_regenstable;
1594         mina = autocvar_g_balance_armor_regenstable;
1595         minf = autocvar_g_balance_fuel_regenstable;
1596         limith = autocvar_g_balance_health_limit;
1597         limita = autocvar_g_balance_armor_limit;
1598         limitf = autocvar_g_balance_fuel_limit;
1599
1600         max_mod = regen_mod = rot_mod = limit_mod = 1;
1601
1602         maxh = maxh * max_mod;
1603         //maxa = maxa * max_mod;
1604         //maxf = maxf * max_mod;
1605         minh = minh * max_mod;
1606         //mina = mina * max_mod;
1607         //minf = minf * max_mod;
1608         limith = limith * limit_mod;
1609         limita = limita * limit_mod;
1610         //limitf = limitf * limit_mod;
1611
1612         if(g_ca)
1613                 rot_mod = 0;
1614
1615         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1616         {
1617                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1618                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1619
1620                 // if player rotted to death...  die!
1621                 if(self.health < 1)
1622                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1623         }
1624
1625         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1626                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1627 }
1628
1629 float zoomstate_set;
1630 void SetZoomState(float z)
1631 {
1632         if(z != self.zoomstate)
1633         {
1634                 self.zoomstate = z;
1635                 ClientData_Touch(self);
1636         }
1637         zoomstate_set = 1;
1638 }
1639
1640 void GetPressedKeys(void) {
1641         MUTATOR_CALLHOOK(GetPressedKeys);
1642         if (self.movement_x > 0) // get if movement keys are pressed
1643         {       // forward key pressed
1644                 self.pressedkeys |= KEY_FORWARD;
1645                 self.pressedkeys &~= KEY_BACKWARD;
1646         }
1647         else if (self.movement_x < 0)
1648         {       // backward key pressed
1649                 self.pressedkeys |= KEY_BACKWARD;
1650                 self.pressedkeys &~= KEY_FORWARD;
1651         }
1652         else
1653         {       // no x input
1654                 self.pressedkeys &~= KEY_FORWARD;
1655                 self.pressedkeys &~= KEY_BACKWARD;
1656         }
1657
1658         if (self.movement_y > 0)
1659         {       // right key pressed
1660                 self.pressedkeys |= KEY_RIGHT;
1661                 self.pressedkeys &~= KEY_LEFT;
1662         }
1663         else if (self.movement_y < 0)
1664         {       // left key pressed
1665                 self.pressedkeys |= KEY_LEFT;
1666                 self.pressedkeys &~= KEY_RIGHT;
1667         }
1668         else
1669         {       // no y input
1670                 self.pressedkeys &~= KEY_RIGHT;
1671                 self.pressedkeys &~= KEY_LEFT;
1672         }
1673
1674         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1675                 self.pressedkeys |= KEY_JUMP;
1676         else
1677                 self.pressedkeys &~= KEY_JUMP;
1678         if (self.BUTTON_CROUCH)
1679                 self.pressedkeys |= KEY_CROUCH;
1680         else
1681                 self.pressedkeys &~= KEY_CROUCH;
1682
1683         if (self.BUTTON_ATCK)
1684                 self.pressedkeys |= KEY_ATCK;
1685         else
1686                 self.pressedkeys &~= KEY_ATCK;
1687         if (self.BUTTON_ATCK2)
1688                 self.pressedkeys |= KEY_ATCK2;
1689         else
1690                 self.pressedkeys &~= KEY_ATCK2;
1691 }
1692
1693 /*
1694 ======================
1695 spectate mode routines
1696 ======================
1697 */
1698
1699 void SpectateCopy(entity spectatee) {
1700         other = spectatee;
1701         MUTATOR_CALLHOOK(SpectateCopy);
1702         self.armortype = spectatee.armortype;
1703         self.armorvalue = spectatee.armorvalue;
1704         self.ammo_cells = spectatee.ammo_cells;
1705         self.ammo_shells = spectatee.ammo_shells;
1706         self.ammo_nails = spectatee.ammo_nails;
1707         self.ammo_rockets = spectatee.ammo_rockets;
1708         self.ammo_fuel = spectatee.ammo_fuel;
1709         self.clip_load = spectatee.clip_load;
1710         self.clip_size = spectatee.clip_size;
1711         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1712         self.health = spectatee.health;
1713         self.impulse = 0;
1714         self.items = spectatee.items;
1715         self.last_pickup = spectatee.last_pickup;
1716         self.hit_time = spectatee.hit_time;
1717         self.metertime = spectatee.metertime;
1718         self.strength_finished = spectatee.strength_finished;
1719         self.invincible_finished = spectatee.invincible_finished;
1720         self.pressedkeys = spectatee.pressedkeys;
1721         WEPSET_COPY_EE(self, spectatee);
1722         self.switchweapon = spectatee.switchweapon;
1723         self.switchingweapon = spectatee.switchingweapon;
1724         self.weapon = spectatee.weapon;
1725         self.nex_charge = spectatee.nex_charge;
1726         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1727         self.hagar_load = spectatee.hagar_load;
1728         self.minelayer_mines = spectatee.minelayer_mines;
1729         self.punchangle = spectatee.punchangle;
1730         self.view_ofs = spectatee.view_ofs;
1731         self.velocity = spectatee.velocity;
1732         self.dmg_take = spectatee.dmg_take;
1733         self.dmg_save = spectatee.dmg_save;
1734         self.dmg_inflictor = spectatee.dmg_inflictor;
1735         self.v_angle = spectatee.v_angle;
1736         self.angles = spectatee.v_angle;
1737         if(!self.BUTTON_USE)
1738                 self.fixangle = TRUE;
1739         setorigin(self, spectatee.origin);
1740         setsize(self, spectatee.mins, spectatee.maxs);
1741         SetZoomState(spectatee.zoomstate);
1742
1743     anticheat_spectatecopy(spectatee);
1744         self.hud = spectatee.hud;
1745         if(spectatee.vehicle)
1746     {
1747         self.fixangle = FALSE;
1748         //self.velocity = spectatee.vehicle.velocity;
1749         self.vehicle_health = spectatee.vehicle_health;
1750         self.vehicle_shield = spectatee.vehicle_shield;
1751         self.vehicle_energy = spectatee.vehicle_energy;
1752         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1753         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1754         self.vehicle_reload1 = spectatee.vehicle_reload1;
1755         self.vehicle_reload2 = spectatee.vehicle_reload2;
1756
1757         msg_entity = self;
1758
1759         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1760             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1761             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1762             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1763
1764         //WriteByte (MSG_ONE, SVC_SETVIEW);
1765         //    WriteEntity(MSG_ONE, self);
1766         //makevectors(spectatee.v_angle);
1767         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1768     }
1769 }
1770
1771 float SpectateUpdate() {
1772         if(!self.enemy)
1773             return 0;
1774
1775         if (self == self.enemy)
1776                 return 0;
1777
1778         if not(IS_PLAYER(self.enemy))
1779                 return 0;
1780
1781         SpectateCopy(self.enemy);
1782
1783         return 1;
1784 }
1785
1786
1787 float SpectateSet()
1788 {
1789         if(self.enemy.classname != "player")
1790                 return FALSE;
1791         /*if(self.enemy.vehicle)
1792         {
1793
1794                 msg_entity = self;
1795                 WriteByte(MSG_ONE, SVC_SETVIEW);
1796                 WriteEntity(MSG_ONE, self.enemy);
1797                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1798
1799                 self.movetype = MOVETYPE_NONE;
1800                 accuracy_resend(self);
1801         }
1802         else
1803         {*/
1804                 msg_entity = self;
1805                 WriteByte(MSG_ONE, SVC_SETVIEW);
1806                 WriteEntity(MSG_ONE, self.enemy);
1807                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1808                 self.movetype = MOVETYPE_NONE;
1809                 accuracy_resend(self);
1810
1811                 if(!SpectateUpdate())
1812                         PutObserverInServer();
1813         //}
1814         return TRUE;
1815 }
1816
1817 float Spectate(entity pl)
1818 {
1819         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1820         if(pl.team != self.team)
1821                 return 0;
1822
1823         self.enemy = pl;
1824         return SpectateSet();
1825 }
1826
1827 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1828 entity CA_SpectateNext(entity start) {
1829         if (start.team == self.team) {
1830                 return start;
1831         }
1832
1833         other = start;
1834         // continue from current player
1835         while(other && other.team != self.team) {
1836                 other = find(other, classname, "player");
1837         }
1838
1839         if (!other) {
1840                 // restart from begining
1841                 other = find(other, classname, "player");
1842                 while(other && other.team != self.team) {
1843                         other = find(other, classname, "player");
1844                 }
1845         }
1846
1847         return other;
1848 }
1849
1850 float SpectateNext()
1851 {
1852         other = find(self.enemy, classname, "player");
1853
1854         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1855                 // CA and ca players when spectating enemies is forbidden
1856                 other = CA_SpectateNext(other);
1857         } else {
1858                 // other modes and ca spectators or spectating enemies is allowed
1859                 if (!other)
1860                         other = find(other, classname, "player");
1861         }
1862
1863         if (other)
1864                 self.enemy = other;
1865
1866         return SpectateSet();
1867 }
1868
1869 float SpectatePrev()
1870 {
1871         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1872         other = findchain(classname, "player");
1873         if not(other) // no player
1874                 return FALSE;
1875
1876         entity first = other;
1877         // skip players until current spectated player
1878         if(self.enemy)
1879         while(other && other != self.enemy)
1880                 other = other.chain;
1881
1882         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1883         {
1884                 do { other = other.chain; }
1885                 while(other && other.team != self.team);
1886
1887                 if not(other)
1888                 {
1889                         other = first;
1890                         while(other.team != self.team)
1891                                 other = other.chain;
1892                         if(other == self.enemy)
1893                                 return TRUE;
1894                 }
1895         }
1896         else
1897         {
1898                 if(other.chain)
1899                         other = other.chain;
1900                 else
1901                         other = first;
1902         }
1903         self.enemy = other;
1904         return SpectateSet();
1905 }
1906
1907 /*
1908 =============
1909 ShowRespawnCountdown()
1910
1911 Update a respawn countdown display.
1912 =============
1913 */
1914 void ShowRespawnCountdown()
1915 {
1916         float number;
1917         if(self.deadflag == DEAD_NO) // just respawned?
1918                 return;
1919         else
1920         {
1921                 number = ceil(self.respawn_time - time);
1922                 if(number <= 0)
1923                         return;
1924                 if(number <= self.respawn_countdown)
1925                 {
1926                         self.respawn_countdown = number - 1;
1927                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1928                                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(number));
1929                 }
1930         }
1931 }
1932
1933 void LeaveSpectatorMode()
1934 {
1935         if(self.caplayer)
1936                 return;
1937         if(nJoinAllowed(self))
1938         {
1939                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1940                 {
1941                         self.classname = "player";
1942
1943                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1944                                 { JoinBestTeam(self, FALSE, TRUE); }
1945
1946                         if(autocvar_g_campaign)
1947                                 { campaign_bots_may_start = 1; }
1948
1949                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1950
1951                         PutClientInServer();
1952
1953                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1954                 }
1955                 else
1956                         stuffcmd(self, "menu_showteamselect\n");
1957         }
1958         else
1959         {
1960                 // Player may not join because g_maxplayers is set
1961                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1962         }
1963 }
1964
1965 /**
1966  * Determines whether the player is allowed to join. This depends on cvar
1967  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1968  * it checks whether the number of currently playing players exceeds g_maxplayers.
1969  * @return int number of free slots for players, 0 if none
1970  */
1971 float nJoinAllowed(entity ignore) {
1972         if(!ignore)
1973         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1974         // so report 0 free slots if restricted
1975         {
1976                 if(autocvar_g_forced_team_otherwise == "spectate")
1977                         return 0;
1978                 if(autocvar_g_forced_team_otherwise == "spectator")
1979                         return 0;
1980         }
1981
1982         if(self.team_forced < 0)
1983                 return 0; // forced spectators can never join
1984
1985         // TODO simplify this
1986         entity e;
1987         float totalClients = 0;
1988         FOR_EACH_CLIENT(e)
1989                 if(e != ignore)
1990                         totalClients += 1;
1991
1992         if (!autocvar_g_maxplayers)
1993                 return maxclients - totalClients;
1994
1995         float currentlyPlaying = 0;
1996         FOR_EACH_REALCLIENT(e)
1997                 if(IS_PLAYER(e) || e.caplayer == 1)
1998                         currentlyPlaying += 1;
1999
2000         if(currentlyPlaying < autocvar_g_maxplayers)
2001                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2002
2003         return 0;
2004 }
2005
2006 /**
2007  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2008  * g_maxplayers_spectator_blocktime seconds
2009  */
2010 void checkSpectatorBlock() {
2011         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2012                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2013                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2014                         dropclient(self);
2015                 }
2016         }
2017 }
2018
2019 void PrintWelcomeMessage()
2020 {
2021         if(self.motd_actived_time == 0)
2022         {
2023                 if (autocvar_g_campaign) {
2024                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2025                                 self.motd_actived_time = time;
2026                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2027                         }
2028                 } else {
2029                         if (self.BUTTON_INFO) {
2030                                 self.motd_actived_time = time;
2031                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2032                         }
2033                 }
2034         }
2035         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2036         {
2037                 if (autocvar_g_campaign) {
2038                         if (self.BUTTON_INFO)
2039                                 self.motd_actived_time = time;
2040                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2041                                 self.motd_actived_time = 0;
2042                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2043                         }
2044                 } else {
2045                         if (self.BUTTON_INFO)
2046                                 self.motd_actived_time = time;
2047                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2048                                 self.motd_actived_time = 0;
2049                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2050                         }
2051                 }
2052         }
2053         else //if(self.motd_actived_time < 0) // just connected, motd is active
2054         {
2055                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2056                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2057                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2058                 {
2059                         // instanctly hide MOTD
2060                         self.motd_actived_time = 0;
2061                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2062                 }
2063         }
2064 }
2065
2066 void ObserverThink()
2067 {
2068         float prefered_movetype;
2069         if (self.flags & FL_JUMPRELEASED) {
2070                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2071                         self.flags &~= FL_JUMPRELEASED;
2072                         self.flags |= FL_SPAWNING;
2073                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2074                         self.flags &~= FL_JUMPRELEASED;
2075                         if(SpectateNext()) {
2076                                 self.classname = "spectator";
2077                         }
2078                 } else {
2079                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2080                         if (self.movetype != prefered_movetype)
2081                                 self.movetype = prefered_movetype;
2082                 }
2083         } else {
2084                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2085                         self.flags |= FL_JUMPRELEASED;
2086                         if(self.flags & FL_SPAWNING)
2087                         {
2088                                 self.flags &~= FL_SPAWNING;
2089                                 LeaveSpectatorMode();
2090                                 return;
2091                         }
2092                 }
2093         }
2094 }
2095
2096 void SpectatorThink()
2097 {
2098         if (self.flags & FL_JUMPRELEASED) {
2099                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2100                         self.flags &~= FL_JUMPRELEASED;
2101                         self.flags |= FL_SPAWNING;
2102                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || self.impulse >= 200 && self.impulse <= 209) {
2103                         self.flags &~= FL_JUMPRELEASED;
2104                         if(SpectateNext()) {
2105                                 self.classname = "spectator";
2106                         } else {
2107                                 self.classname = "observer";
2108                                 PutClientInServer();
2109                         }
2110                         self.impulse = 0;
2111                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || self.impulse >= 220 && self.impulse <= 229) {
2112                         self.flags &~= FL_JUMPRELEASED;
2113                         if(SpectatePrev()) {
2114                                 self.classname = "spectator";
2115                         } else {
2116                                 self.classname = "observer";
2117                                 PutClientInServer();
2118                         }
2119                         self.impulse = 0;
2120                 } else if (self.BUTTON_ATCK2) {
2121                         self.flags &~= FL_JUMPRELEASED;
2122                         self.classname = "observer";
2123                         PutClientInServer();
2124                 } else {
2125                         if(!SpectateUpdate())
2126                                 PutObserverInServer();
2127                 }
2128         } else {
2129                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2130                         self.flags |= FL_JUMPRELEASED;
2131                         if(self.flags & FL_SPAWNING)
2132                         {
2133                                 self.flags &~= FL_SPAWNING;
2134                                 LeaveSpectatorMode();
2135                                 return;
2136                         }
2137                 }
2138                 if(!SpectateUpdate())
2139                         PutObserverInServer();
2140         }
2141
2142         self.flags |= FL_CLIENT | FL_NOTARGET;
2143 }
2144
2145 void PlayerUseKey()
2146 {
2147         if not(IS_PLAYER(self))
2148                 return;
2149
2150         if(self.vehicle)
2151         {
2152         vehicles_exit(VHEF_NORMAL);
2153         return;
2154         }
2155
2156         // a use key was pressed; call handlers
2157         MUTATOR_CALLHOOK(PlayerUseKey);
2158 }
2159
2160 /*
2161 =============
2162 PlayerPreThink
2163
2164 Called every frame for each client before the physics are run
2165 =============
2166 */
2167 .float usekeypressed;
2168 void() nexball_setstatus;
2169 .float items_added;
2170 void PlayerPreThink (void)
2171 {
2172         WarpZone_PlayerPhysics_FixVAngle();
2173
2174         self.stat_game_starttime = game_starttime;
2175         self.stat_round_starttime = round_starttime;
2176         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2177         self.stat_leadlimit = autocvar_leadlimit;
2178
2179         if(frametime)
2180         {
2181                 // physics frames: update anticheat stuff
2182                 anticheat_prethink();
2183         }
2184
2185         if(blockSpectators && frametime)
2186                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2187                 checkSpectatorBlock();
2188
2189         zoomstate_set = 0;
2190
2191         if(self.netname_previous != self.netname)
2192         {
2193                 if(autocvar_sv_eventlog)
2194                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2195                 if(self.netname_previous)
2196                         strunzone(self.netname_previous);
2197                 self.netname_previous = strzone(self.netname);
2198         }
2199
2200         // version nagging
2201         if(self.version_nagtime)
2202                 if(self.cvar_g_xonoticversion)
2203                         if(time > self.version_nagtime)
2204                         {
2205                                 // don't notify git users
2206                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2207                                 {
2208                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2209                                         {
2210                                                 // notify release users if connecting to git
2211                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2212                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2213                                         }
2214                                         else
2215                                         {
2216                                                 float r;
2217                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2218                                                 if(r < 0)
2219                                                 {
2220                                                         // give users new version
2221                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2222                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2223                                                 }
2224                                                 else if(r > 0)
2225                                                 {
2226                                                         // notify users about old server version
2227                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2228                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2229                                                 }
2230                                         }
2231                                 }
2232                                 self.version_nagtime = 0;
2233                         }
2234
2235         // GOD MODE info
2236         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2237         {
2238                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2239                 self.max_armorvalue = 0;
2240         }
2241
2242 #ifdef TETRIS
2243         if (TetrisPreFrame())
2244                 return;
2245 #endif
2246
2247         MUTATOR_CALLHOOK(PlayerPreThink);
2248
2249         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2250         {
2251                 if(self.BUTTON_USE && !self.usekeypressed)
2252                         PlayerUseKey();
2253                 self.usekeypressed = self.BUTTON_USE;
2254         }
2255
2256         if(IS_REAL_CLIENT(self))
2257                 PrintWelcomeMessage();
2258
2259         if(IS_PLAYER(self))
2260         {
2261
2262                 CheckRules_Player();
2263
2264                 if (intermission_running)
2265                 {
2266                         IntermissionThink ();   // otherwise a button could be missed between
2267                         return;                                 // the think tics
2268                 }
2269
2270                 //don't allow the player to turn around while game is paused!
2271                 if(timeout_status == TIMEOUT_ACTIVE) {
2272                         // FIXME turn this into CSQC stuff
2273                         self.v_angle = self.lastV_angle;
2274                         self.angles = self.lastV_angle;
2275                         self.fixangle = TRUE;
2276                 }
2277
2278                 if(frametime)
2279                 {
2280                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2281                         {
2282                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2283                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2284                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2285
2286                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2287                                 {
2288                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2289                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2290                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2291                                 }
2292                         }
2293                         else
2294                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2295
2296                         player_powerups();
2297                 }
2298
2299                 if (self.deadflag != DEAD_NO)
2300                 {
2301                         if(self.personal && g_race_qualifying)
2302                         {
2303                                 if(time > self.respawn_time)
2304                                 {
2305                                         self.respawn_time = time + 1; // only retry once a second
2306                                         self.stat_respawn_time = self.respawn_time;
2307                                         respawn();
2308                                         self.impulse = 141;
2309                                 }
2310                         }
2311                         else
2312                         {
2313                                 float button_pressed;
2314                                 if(frametime)
2315                                         player_anim();
2316                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2317
2318                                 if (self.deadflag == DEAD_DYING)
2319                                 {
2320                                         if(self.respawn_flags & RESPAWN_FORCE)
2321                                                 self.deadflag = DEAD_RESPAWNING;
2322                                         else if(!button_pressed)
2323                                                 self.deadflag = DEAD_DEAD;
2324                                 }
2325                                 else if (self.deadflag == DEAD_DEAD)
2326                                 {
2327                                         if(button_pressed)
2328                                                 self.deadflag = DEAD_RESPAWNABLE;
2329                                 }
2330                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2331                                 {
2332                                         if(!button_pressed)
2333                                                 self.deadflag = DEAD_RESPAWNING;
2334                                 }
2335                                 else if (self.deadflag == DEAD_RESPAWNING)
2336                                 {
2337                                         if(time > self.respawn_time)
2338                                         {
2339                                                 self.respawn_time = time + 1; // only retry once a second
2340                                                 respawn();
2341                                         }
2342                                 }
2343
2344                                 ShowRespawnCountdown();
2345
2346                                 if(self.respawn_flags & RESPAWN_SILENT)
2347                                         self.stat_respawn_time = 0;
2348                                 else
2349                                         self.stat_respawn_time = self.respawn_time;
2350                         }
2351
2352                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2353                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2354                                 self.stat_respawn_time *= -1;
2355
2356                         return;
2357                 }
2358
2359                 self.prevorigin = self.origin;
2360
2361                 float do_crouch = self.BUTTON_CROUCH;
2362                 if(self.hook.state)
2363                         do_crouch = 0;
2364                 if(self.health <= g_bloodloss)
2365                         do_crouch = 1;
2366                 if(self.vehicle)
2367                         do_crouch = 0;
2368                 if(self.freezetag_frozen)
2369                         do_crouch = 0;
2370                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2371                         do_crouch = 0;
2372
2373                 if (do_crouch)
2374                 {
2375                         if (!self.crouch)
2376                         {
2377                                 self.crouch = TRUE;
2378                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2379                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2380                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2381                         }
2382                 }
2383                 else
2384                 {
2385                         if (self.crouch)
2386                         {
2387                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2388                                 if (!trace_startsolid)
2389                                 {
2390                                         self.crouch = FALSE;
2391                                         self.view_ofs = PL_VIEW_OFS;
2392                                         setsize (self, PL_MIN, PL_MAX);
2393                                 }
2394                         }
2395                 }
2396
2397                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2398                 {
2399                         if(self.bloodloss_timer < time)
2400                         {
2401                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2402                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2403                         }
2404                 }
2405
2406                 FixPlayermodel();
2407
2408                 GrapplingHookFrame();
2409
2410                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2411                 //if(frametime)
2412                 {
2413                         self.items &~= self.items_added;
2414
2415                         W_WeaponFrame();
2416
2417                         self.items_added = 0;
2418                         if(self.items & IT_JETPACK)
2419                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2420                                         self.items_added |= IT_FUEL;
2421
2422                         self.items |= self.items_added;
2423                 }
2424
2425                 player_regen();
2426
2427                 // rot nex charge to the charge limit
2428                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2429                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2430
2431                 if(frametime)
2432                         player_anim();
2433
2434                 if(g_nexball)
2435                         nexball_setstatus();
2436
2437                 // secret status
2438                 secrets_setstatus();
2439
2440                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2441
2442                 //self.angles_y=self.v_angle_y + 90;   // temp
2443         } else if(gameover) {
2444                 if (intermission_running)
2445                         IntermissionThink ();   // otherwise a button could be missed between
2446                 return;
2447         } else if(IS_OBSERVER(self)) {
2448                 ObserverThink();
2449         } else if(IS_SPEC(self)) {
2450                 SpectatorThink();
2451         }
2452
2453         if(!zoomstate_set)
2454                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2455
2456         float oldspectatee_status;
2457         oldspectatee_status = self.spectatee_status;
2458         if(IS_SPEC(self))
2459                 self.spectatee_status = num_for_edict(self.enemy);
2460         else if(IS_OBSERVER(self))
2461                 self.spectatee_status = num_for_edict(self);
2462         else
2463                 self.spectatee_status = 0;
2464         if(self.spectatee_status != oldspectatee_status)
2465         {
2466                 ClientData_Touch(self);
2467                 if(g_race || g_cts)
2468                         race_InitSpectator();
2469         }
2470
2471         if(self.teamkill_soundtime)
2472         if(time > self.teamkill_soundtime)
2473         {
2474                 self.teamkill_soundtime = 0;
2475
2476                 entity oldpusher, oldself;
2477
2478                 oldself = self; self = self.teamkill_soundsource;
2479                 oldpusher = self.pusher; self.pusher = oldself;
2480
2481                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2482
2483                 self.pusher = oldpusher;
2484                 self = oldself;
2485         }
2486
2487         if(self.taunt_soundtime)
2488         if(time > self.taunt_soundtime)
2489         {
2490                 self.taunt_soundtime = 0;
2491                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2492         }
2493
2494         target_voicescript_next(self);
2495
2496         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2497         if(!self.weapon)
2498                 self.clip_load = self.clip_size = 0;
2499 }
2500
2501 float isInvisibleString(string s)
2502 {
2503         float i, n, c;
2504         s = strdecolorize(s);
2505         for((i = 0), (n = strlen(s)); i < n; ++i)
2506         {
2507                 c = str2chr(s, i);
2508                 switch(c)
2509                 {
2510                         case 0:
2511                         case 32: // space
2512                                 break;
2513                         case 192: // charmap space
2514                                 if (!autocvar_utf8_enable)
2515                                         break;
2516                                 return FALSE;
2517                         case 160: // space in unicode fonts
2518                         case 0xE000 + 192: // utf8 charmap space
2519                                 if (autocvar_utf8_enable)
2520                                         break;
2521                         default:
2522                                 return FALSE;
2523                 }
2524         }
2525         return TRUE;
2526 }
2527
2528 /*
2529 =============
2530 PlayerPostThink
2531
2532 Called every frame for each client after the physics are run
2533 =============
2534 */
2535 .float idlekick_lasttimeleft;
2536 void PlayerPostThink (void)
2537 {
2538         // Savage: Check for nameless players
2539         if (isInvisibleString(self.netname)) {
2540                 self.netname = "Player";
2541                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2542         }
2543
2544         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2545         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2546         {
2547                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2548                 {
2549                         if(self.idlekick_lasttimeleft)
2550                         {
2551                                 self.idlekick_lasttimeleft = 0;
2552                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2553                         }
2554                 }
2555                 else
2556                 {
2557                         float timeleft;
2558                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2559                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2560                         {
2561                                 if(!self.idlekick_lasttimeleft)
2562                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2563                         }
2564                         if(timeleft <= 0)
2565                         {
2566                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2567                                 dropclient(self);
2568                                 return;
2569                         }
2570                         else if(timeleft <= 10)
2571                         {
2572                                 if(timeleft != self.idlekick_lasttimeleft)
2573                                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(timeleft));
2574                                 self.idlekick_lasttimeleft = timeleft;
2575                         }
2576                 }
2577         }
2578
2579 #ifdef TETRIS
2580         if(self.impulse == 100)
2581                 ImpulseCommands();
2582         if (!TetrisPostFrame())
2583         {
2584 #endif
2585
2586         CheatFrame();
2587
2588         //CheckPlayerJump();
2589
2590         if(IS_PLAYER(self)) {
2591                 CheckRules_Player();
2592                 UpdateChatBubble();
2593                 if (self.impulse)
2594                         ImpulseCommands();
2595                 if (intermission_running)
2596                         return;         // intermission or finale
2597                 GetPressedKeys();
2598         }
2599
2600 #ifdef TETRIS
2601         }
2602 #endif
2603
2604         /*
2605         float i;
2606         for(i = 0; i < 1000; ++i)
2607         {
2608                 vector end;
2609                 end = self.origin + '0 0 1024' + 512 * randomvec();
2610                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2611                 if(trace_fraction < 1)
2612                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2613                 {
2614                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2615                         break;
2616                 }
2617         }
2618         */
2619
2620         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2621
2622         if(self.waypointsprite_attachedforcarrier)
2623                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2624
2625         playerdemo_write();
2626
2627         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2628         {
2629                 if not(self.stored_netname)
2630                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2631                 if(self.stored_netname != self.netname)
2632                 {
2633                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2634                         strunzone(self.stored_netname);
2635                         self.stored_netname = strzone(self.netname);
2636                 }
2637         }
2638
2639         /*
2640         if(g_race)
2641                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2642         */
2643
2644         CSQCMODEL_AUTOUPDATE();
2645 }