qcsrc/server/cl_client.qc

   1 #include "waypointsprites.qh"
   2
   3 #include "cl_impulse.qh"
   4 #include "cl_player.qh"
   5 #include "ent_cs.qh"
   6 #include "g_subs.qh"
   7 #include "ipban.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "playerdemo.qh"
  12 #include "secret.qh"
  13
  14 #include "bot/bot.qh"
  15 #include "bot/navigation.qh"
  16
  17 #include "weapons/hitplot.qh"
  18 #include "weapons/weaponsystem.qh"
  19
  20 #include "../common/net_notice.qh"
  21
  22 #include "../common/monsters/sv_monsters.qh"
  23
  24 #include "../warpzonelib/server.qh"
  25
  26 float c1, c2, c3, c4;
  27
  28 void send_CSQC_teamnagger() {
  29         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  30         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  31 }
  32
  33 float ClientData_Send(entity to, int sf)
  34 {
  35         if(to != self.owner)
  36         {
  37                 error("wtf");
  38                 return false;
  39         }
  40
  41         entity e;
  42
  43         e = to;
  44         if(IS_SPEC(to))
  45                 e = to.enemy;
  46
  47         sf = 0;
  48
  49         if(e.race_completed)
  50                 sf |= 1; // forced scoreboard
  51         if(to.spectatee_status)
  52                 sf |= 2; // spectator ent number follows
  53         if(e.zoomstate)
  54                 sf |= 4; // zoomed
  55         if(e.porto_v_angle_held)
  56                 sf |= 8; // angles held
  57
  58         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  59         WriteByte(MSG_ENTITY, sf);
  60
  61         if(sf & 2)
  62                 WriteByte(MSG_ENTITY, to.spectatee_status);
  63
  64         if(sf & 8)
  65         {
  66                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  67                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  68         }
  69
  70         return true;
  71 }
  72
  73 void ClientData_Attach()
  74 {
  75         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  76         self.clientdata.drawonlytoclient = self;
  77         self.clientdata.owner = self;
  78 }
  79
  80 void ClientData_Detach()
  81 {
  82         remove(self.clientdata);
  83         self.clientdata = world;
  84 }
  85
  86 void ClientData_Touch(entity e)
  87 {
  88         e.clientdata.SendFlags = 1;
  89
  90         // make it spectatable
  91         entity e2;
  92         FOR_EACH_REALCLIENT(e2)
  93         {
  94                 if(e2 != e)
  95                         if(IS_SPEC(e2))
  96                                 if(e2.enemy == e)
  97                                         e2.clientdata.SendFlags = 1;
  98         }
  99 }
 100
 101 .string netname_previous;
 102
 103 void SetSpectator(entity player, entity spectatee);
 104
 105
 106 /*
 107 =============
 108 CheckPlayerModel
 109
 110 Checks if the argument string can be a valid playermodel.
 111 Returns a valid one in doubt.
 112 =============
 113 */
 114 string FallbackPlayerModel;
 115 string CheckPlayerModel(string plyermodel) {
 116         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 117         {
 118                 // note: we cannot summon Don Strunzone here, some player may
 119                 // still have the model string set. In case anyone manages how
 120                 // to change a cvar default, we'll have a small leak here.
 121                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 122         }
 123         // only in right path
 124         if( substring(plyermodel,0,14) != "models/player/")
 125                 return FallbackPlayerModel;
 126         // only good file extensions
 127         if(substring(plyermodel,-4,4) != ".zym")
 128         if(substring(plyermodel,-4,4) != ".dpm")
 129         if(substring(plyermodel,-4,4) != ".iqm")
 130         if(substring(plyermodel,-4,4) != ".md3")
 131         if(substring(plyermodel,-4,4) != ".psk")
 132                 return FallbackPlayerModel;
 133         // forbid the LOD models
 134         if(substring(plyermodel, -9,5) == "_lod1")
 135                 return FallbackPlayerModel;
 136         if(substring(plyermodel, -9,5) == "_lod2")
 137                 return FallbackPlayerModel;
 138         if(plyermodel != strtolower(plyermodel))
 139                 return FallbackPlayerModel;
 140         // also, restrict to server models
 141         if(autocvar_sv_servermodelsonly)
 142         {
 143                 if(!fexists(plyermodel))
 144                         return FallbackPlayerModel;
 145         }
 146         return plyermodel;
 147 }
 148
 149 void setplayermodel(entity e, string modelname)
 150 {
 151         precache_model(modelname);
 152         setmodel(e, modelname);
 153         player_setupanimsformodel();
 154         UpdatePlayerSounds();
 155 }
 156
 157 /*
 158 =============
 159 PutObserverInServer
 160
 161 putting a client as observer in the server
 162 =============
 163 */
 164 void FixPlayermodel();
 165 void PutObserverInServer (void)
 166 {
 167         entity  spot;
 168     self.hud = HUD_NORMAL;
 169
 170         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 171
 172         spot = SelectSpawnPoint (true);
 173         if(!spot)
 174                 error("No spawnpoints for observers?!?\n");
 175         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 176
 177         if(IS_REAL_CLIENT(self))
 178         {
 179                 msg_entity = self;
 180                 WriteByte(MSG_ONE, SVC_SETVIEW);
 181                 WriteEntity(MSG_ONE, self);
 182         }
 183
 184         self.frags = FRAGS_SPECTATOR;
 185
 186         MUTATOR_CALLHOOK(MakePlayerObserver);
 187
 188         Portal_ClearAll(self);
 189
 190         Unfreeze(self);
 191
 192         if(self.alivetime)
 193         {
 194                 if(!warmup_stage)
 195                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 196                 self.alivetime = 0;
 197         }
 198
 199         if(self.vehicle)
 200                 vehicles_exit(VHEF_RELESE);
 201
 202         WaypointSprite_PlayerDead();
 203
 204         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 205                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 206
 207         if(self.killcount != -666)
 208         {
 209                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 210                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 211                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 212
 213                 if(self.just_joined == false) {
 214                         LogTeamchange(self.playerid, -1, 4);
 215                 } else
 216                         self.just_joined = false;
 217         }
 218
 219         PlayerScore_Clear(self); // clear scores when needed
 220
 221         accuracy_resend(self);
 222
 223         self.spectatortime = time;
 224
 225         self.classname = "observer";
 226         self.iscreature = false;
 227         self.teleportable = TELEPORT_SIMPLE;
 228         self.damagedbycontents = false;
 229         self.health = -666;
 230         self.takedamage = DAMAGE_NO;
 231         self.solid = SOLID_NOT;
 232         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 233         self.flags = FL_CLIENT | FL_NOTARGET;
 234         self.armorvalue = 666;
 235         self.effects = 0;
 236         self.armorvalue = autocvar_g_balance_armor_start;
 237         self.pauserotarmor_finished = 0;
 238         self.pauserothealth_finished = 0;
 239         self.pauseregen_finished = 0;
 240         self.damageforcescale = 0;
 241         self.death_time = 0;
 242         self.respawn_flags = 0;
 243         self.respawn_time = 0;
 244         self.stat_respawn_time = 0;
 245         self.alpha = 0;
 246         self.scale = 0;
 247         self.fade_time = 0;
 248         self.pain_frame = 0;
 249         self.pain_finished = 0;
 250         self.strength_finished = 0;
 251         self.invincible_finished = 0;
 252         self.superweapons_finished = 0;
 253         self.pushltime = 0;
 254         self.istypefrag = 0;
 255         self.think = func_null;
 256         self.nextthink = 0;
 257         self.hook_time = 0;
 258         self.deadflag = DEAD_NO;
 259         self.angles = spot.angles;
 260         self.angles_z = 0;
 261         self.fixangle = true;
 262         self.crouch = false;
 263         self.revival_time = 0;
 264
 265         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 266         self.prevorigin = self.origin;
 267         self.items = 0;
 268         self.weapons = '0 0 0';
 269         self.model = "";
 270         FixPlayermodel();
 271         setmodel(self, "null");
 272         self.drawonlytoclient = self;
 273
 274         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 275         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 276
 277         self.weapon = 0;
 278         self.weaponname = "";
 279         self.switchingweapon = 0;
 280         self.weaponmodel = "";
 281         self.weaponentity = world;
 282         self.exteriorweaponentity = world;
 283         self.killcount = -666;
 284         self.velocity = '0 0 0';
 285         self.avelocity = '0 0 0';
 286         self.punchangle = '0 0 0';
 287         self.punchvector = '0 0 0';
 288         self.oldvelocity = self.velocity;
 289         self.fire_endtime = -1;
 290         self.event_damage = func_null;
 291 }
 292
 293 .float model_randomizer;
 294 void FixPlayermodel()
 295 {
 296         string defaultmodel;
 297         float defaultskin, chmdl, oldskin, n, i;
 298         vector m1, m2;
 299
 300         defaultmodel = "";
 301         defaultskin = 0;
 302         chmdl = false;
 303
 304         if(autocvar_sv_defaultcharacter == 1)
 305         {
 306                 if(teamplay)
 307                 {
 308                         string s;
 309                         s = Static_Team_ColorName_Lower(self.team);
 310                         if(s != "neutral")
 311                         {
 312                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 313                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 314                         }
 315                 }
 316
 317                 if(defaultmodel == "")
 318                 {
 319                         defaultmodel = autocvar_sv_defaultplayermodel;
 320                         defaultskin = autocvar_sv_defaultplayerskin;
 321                 }
 322
 323                 n = tokenize_console(defaultmodel);
 324                 if(n > 0)
 325                 {
 326                         defaultmodel = argv(floor(n * self.model_randomizer));
 327                         // However, do NOT randomize if the player-selected model is in the list.
 328                         for (i = 0; i < n; ++i)
 329                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 330                                         defaultmodel = argv(i);
 331                 }
 332
 333                 i = strstrofs(defaultmodel, ":", 0);
 334                 if(i >= 0)
 335                 {
 336                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 337                         defaultmodel = substring(defaultmodel, 0, i);
 338                 }
 339         }
 340
 341         if(defaultmodel != "")
 342         {
 343                 if (defaultmodel != self.model)
 344                 {
 345                         m1 = self.mins;
 346                         m2 = self.maxs;
 347                         setplayermodel (self, defaultmodel);
 348                         setsize (self, m1, m2);
 349                         chmdl = true;
 350                 }
 351
 352                 oldskin = self.skin;
 353                 self.skin = defaultskin;
 354         } else {
 355                 if (self.playermodel != self.model || self.playermodel == "")
 356                 {
 357                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 358                         m1 = self.mins;
 359                         m2 = self.maxs;
 360                         setplayermodel (self, self.playermodel);
 361                         setsize (self, m1, m2);
 362                         chmdl = true;
 363                 }
 364
 365                 oldskin = self.skin;
 366                 self.skin = stof(self.playerskin);
 367         }
 368
 369         if(chmdl || oldskin != self.skin) // model or skin has changed
 370         {
 371                 self.species = player_getspecies(); // update species
 372                 UpdatePlayerSounds(); // update skin sounds
 373         }
 374
 375         if(!teamplay)
 376                 if(strlen(autocvar_sv_defaultplayercolors))
 377                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 378                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 379 }
 380
 381 /*
 382 =============
 383 PutClientInServer
 384
 385 Called when a client spawns in the server
 386 =============
 387 */
 388 void PutClientInServer (void)
 389 {
 390         if(IS_BOT_CLIENT(self))
 391                 self.classname = "player";
 392         else if(IS_REAL_CLIENT(self))
 393         {
 394                 msg_entity = self;
 395                 WriteByte(MSG_ONE, SVC_SETVIEW);
 396                 WriteEntity(MSG_ONE, self);
 397         }
 398
 399         SetSpectator(self, world);
 400
 401         // reset player keys
 402         self.itemkeys = 0;
 403
 404         MUTATOR_CALLHOOK(PutClientInServer);
 405
 406         if(gameover)
 407                 self.classname = "observer";
 408
 409         if(IS_PLAYER(self))
 410         {
 411                 entity spot, oldself;
 412                 float j;
 413
 414                 accuracy_resend(self);
 415
 416                 if(self.team < 0)
 417                         JoinBestTeam(self, false, true);
 418
 419                 spot = SelectSpawnPoint (false);
 420                 if(!spot)
 421                 {
 422                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 423                         return; // spawn failed
 424                 }
 425
 426                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 427
 428                 if(self.vehicle)
 429                         vehicles_exit(VHEF_RELESE);
 430
 431                 self.classname = "player";
 432                 self.wasplayer = true;
 433                 self.iscreature = true;
 434                 self.teleportable = TELEPORT_NORMAL;
 435                 self.damagedbycontents = true;
 436                 self.movetype = MOVETYPE_WALK;
 437                 self.solid = SOLID_SLIDEBOX;
 438                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 439                 if(autocvar_g_playerclip_collisions)
 440                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 441                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 442                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 443                 self.frags = FRAGS_PLAYER;
 444                 if(INDEPENDENT_PLAYERS)
 445                         MAKE_INDEPENDENT_PLAYER(self);
 446                 self.flags = FL_CLIENT;
 447                 if(autocvar__notarget)
 448                         self.flags |= FL_NOTARGET;
 449                 self.takedamage = DAMAGE_AIM;
 450                 self.effects = 0;
 451                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 452                 self.air_finished = time + 12;
 453                 self.dmg = 2;
 454                 if(WEP_CVAR(vortex, charge))
 455                 {
 456                         if(WEP_CVAR_SEC(vortex, chargepool))
 457                                 self.vortex_chargepool_ammo = 1;
 458                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 459                 }
 460
 461                 if(warmup_stage)
 462                 {
 463                         self.ammo_shells = warmup_start_ammo_shells;
 464                         self.ammo_nails = warmup_start_ammo_nails;
 465                         self.ammo_rockets = warmup_start_ammo_rockets;
 466                         self.ammo_cells = warmup_start_ammo_cells;
 467                         self.ammo_plasma = warmup_start_ammo_plasma;
 468                         self.ammo_fuel = warmup_start_ammo_fuel;
 469                         self.health = warmup_start_health;
 470                         self.armorvalue = warmup_start_armorvalue;
 471                         self.weapons = WARMUP_START_WEAPONS;
 472                 }
 473                 else
 474                 {
 475                         self.ammo_shells = start_ammo_shells;
 476                         self.ammo_nails = start_ammo_nails;
 477                         self.ammo_rockets = start_ammo_rockets;
 478                         self.ammo_cells = start_ammo_cells;
 479                         self.ammo_plasma = start_ammo_plasma;
 480                         self.ammo_fuel = start_ammo_fuel;
 481                         self.health = start_health;
 482                         self.armorvalue = start_armorvalue;
 483                         self.weapons = start_weapons;
 484                 }
 485
 486                 if(self.weapons & WEPSET_SUPERWEAPONS)
 487                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 488                 else
 489                         self.superweapons_finished = 0;
 490
 491                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 492                 {
 493                         if(g_weaponarena_random_with_blaster)
 494                                 self.weapons &= ~WEPSET_BLASTER;
 495                         W_RandomWeapons(self, g_weaponarena_random);
 496                         if(g_weaponarena_random_with_blaster)
 497                                 self.weapons |= WEPSET_BLASTER;
 498                 }
 499
 500                 self.items = start_items;
 501
 502                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 503                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 504                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 505                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 506                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 507                 //extend the pause of rotting if client was reset at the beginning of the countdown
 508                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 509                         self.spawnshieldtime += game_starttime - time;
 510                         self.pauserotarmor_finished += game_starttime - time;
 511                         self.pauserothealth_finished += game_starttime - time;
 512                         self.pauseregen_finished += game_starttime - time;
 513                 }
 514                 self.damageforcescale = 2;
 515                 self.death_time = 0;
 516                 self.respawn_flags = 0;
 517                 self.respawn_time = 0;
 518                 self.stat_respawn_time = 0;
 519                 self.scale = 0;
 520                 self.fade_time = 0;
 521                 self.pain_frame = 0;
 522                 self.pain_finished = 0;
 523                 self.strength_finished = 0;
 524                 self.invincible_finished = 0;
 525                 self.pushltime = 0;
 526                 // players have no think function
 527                 self.think = func_null;
 528                 self.nextthink = 0;
 529                 self.hook_time = 0;
 530                 self.dmg_team = 0;
 531                 self.ballistics_density = autocvar_g_ballistics_density_player;
 532
 533                 self.metertime = 0;
 534
 535                 self.deadflag = DEAD_NO;
 536
 537                 self.angles = spot.angles;
 538
 539                 self.angles_z = 0; // never spawn tilted even if the spot says to
 540                 if(IS_BOT_CLIENT(self))
 541                         self.v_angle = self.angles;
 542                 self.fixangle = true; // turn this way immediately
 543                 self.velocity = '0 0 0';
 544                 self.avelocity = '0 0 0';
 545                 self.punchangle = '0 0 0';
 546                 self.punchvector = '0 0 0';
 547                 self.oldvelocity = self.velocity;
 548                 self.fire_endtime = -1;
 549                 self.revival_time = 0;
 550
 551                 entity spawnevent = spawn();
 552                 spawnevent.owner = self;
 553                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 554
 555                 // Cut off any still running player sounds.
 556                 stopsound(self, CH_PLAYER_SINGLE);
 557
 558                 self.model = "";
 559                 FixPlayermodel();
 560                 self.drawonlytoclient = world;
 561
 562                 self.crouch = false;
 563                 self.view_ofs = PL_VIEW_OFS;
 564                 setsize (self, PL_MIN, PL_MAX);
 565                 self.spawnorigin = spot.origin;
 566                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 567                 // don't reset back to last position, even if new position is stuck in solid
 568                 self.oldorigin = self.origin;
 569                 self.prevorigin = self.origin;
 570                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 571                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 572         self.hud = HUD_NORMAL;
 573
 574                 self.event_damage = PlayerDamage;
 575
 576                 self.bot_attack = true;
 577                 self.monster_attack = true;
 578
 579                 self.spider_slowness = 0;
 580
 581                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 582
 583                 if(self.killcount == -666) {
 584                         PlayerScore_Clear(self);
 585                         self.killcount = 0;
 586                 }
 587
 588                 CL_SpawnWeaponentity();
 589                 self.alpha = default_player_alpha;
 590                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 591                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 592
 593                 self.speedrunning = false;
 594
 595                 //stuffcmd(self, "chase_active 0");
 596                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 597
 598                 target_voicescript_clear(self);
 599
 600                 // reset fields the weapons may use
 601                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 602                 {
 603                         WEP_ACTION(j, WR_RESETPLAYER);
 604
 605                         // all weapons must be fully loaded when we spawn
 606                         entity e = get_weaponinfo(j);
 607                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 608                                 self.(weapon_load[j]) = e.reloading_ammo;
 609                 }
 610
 611                 oldself = self;
 612                 self = spot;
 613                         activator = oldself;
 614                                 string s;
 615                                 s = self.target;
 616                                 self.target = string_null;
 617                                 SUB_UseTargets();
 618                                 self.target = s;
 619                         activator = world;
 620                 self = oldself;
 621
 622                 Unfreeze(self);
 623
 624                 spawn_spot = spot;
 625                 MUTATOR_CALLHOOK(PlayerSpawn);
 626
 627                 if(autocvar_spawn_debug)
 628                 {
 629                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 630                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 631                 }
 632
 633                 self.switchweapon = w_getbestweapon(self);
 634                 self.cnt = -1; // W_LastWeapon will not complain
 635                 self.weapon = 0;
 636                 self.weaponname = "";
 637                 self.switchingweapon = 0;
 638
 639                 if(!warmup_stage)
 640                         if(!self.alivetime)
 641                                 self.alivetime = time;
 642
 643                 antilag_clear(self);
 644         }
 645         else if(IS_OBSERVER(self))
 646         {
 647                 PutObserverInServer ();
 648         }
 649 }
 650
 651 .float ebouncefactor, ebouncestop; // electro's values
 652 // TODO do we need all these fields, or should we stop autodetecting runtime
 653 // changes and just have a console command to update this?
 654 float ClientInit_SendEntity(entity to, float sf)
 655 {
 656         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 657         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 658         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 659         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 660         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 661         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 662         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 663         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 664         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 665         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 666
 667         if(sv_foginterval && world.fog != "")
 668                 WriteString(MSG_ENTITY, world.fog);
 669         else
 670                 WriteString(MSG_ENTITY, "");
 671         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 672         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 673         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 674         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 675         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 676         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 677         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 678         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 679         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 680         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 681         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 682         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 683         return true;
 684 }
 685
 686 void ClientInit_CheckUpdate()
 687 {
 688         self.nextthink = time;
 689         if(self.count != autocvar_g_balance_armor_blockpercent)
 690         {
 691                 self.count = autocvar_g_balance_armor_blockpercent;
 692                 self.SendFlags |= 1;
 693         }
 694         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 695         {
 696                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 697                 self.SendFlags |= 1;
 698         }
 699         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 700         {
 701                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 702                 self.SendFlags |= 1;
 703         }
 704         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 705         {
 706                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 707                 self.SendFlags |= 1;
 708         }
 709         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 710         {
 711                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 712                 self.SendFlags |= 1;
 713         }
 714 }
 715
 716 void ClientInit_Spawn()
 717 {
 718         entity o;
 719         entity e;
 720         e = spawn();
 721         e.classname = "clientinit";
 722         e.think = ClientInit_CheckUpdate;
 723         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 724
 725         o = self;
 726         self = e;
 727         ClientInit_CheckUpdate();
 728         self = o;
 729 }
 730
 731 /*
 732 =============
 733 SetNewParms
 734 =============
 735 */
 736 void SetNewParms (void)
 737 {
 738         // initialize parms for a new player
 739         parm1 = -(86400 * 366);
 740 }
 741
 742 /*
 743 =============
 744 SetChangeParms
 745 =============
 746 */
 747 void SetChangeParms (void)
 748 {
 749         // save parms for level change
 750         parm1 = self.parm_idlesince - time;
 751 }
 752
 753 /*
 754 =============
 755 DecodeLevelParms
 756 =============
 757 */
 758 void DecodeLevelParms (void)
 759 {
 760         // load parms
 761         self.parm_idlesince = parm1;
 762         if(self.parm_idlesince == -(86400 * 366))
 763                 self.parm_idlesince = time;
 764
 765         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 766         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 767 }
 768
 769 /*
 770 =============
 771 ClientKill
 772
 773 Called when a client types 'kill' in the console
 774 =============
 775 */
 776
 777 .float clientkill_nexttime;
 778 void ClientKill_Now_TeamChange()
 779 {
 780         if(self.killindicator_teamchange == -1)
 781         {
 782                 JoinBestTeam( self, false, true );
 783         }
 784         else if(self.killindicator_teamchange == -2)
 785         {
 786                 if(blockSpectators)
 787                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 788                 PutObserverInServer();
 789         }
 790         else
 791                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 792         self.killindicator_teamchange = 0;
 793 }
 794
 795 void ClientKill_Now()
 796 {
 797         if(self.vehicle)
 798         {
 799             vehicles_exit(VHEF_RELESE);
 800             if(!self.killindicator_teamchange)
 801             {
 802             self.vehicle_health = -1;
 803             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 804             }
 805         }
 806
 807         if(self.killindicator && !wasfreed(self.killindicator))
 808                 remove(self.killindicator);
 809
 810         self.killindicator = world;
 811
 812         if(self.killindicator_teamchange)
 813                 ClientKill_Now_TeamChange();
 814
 815         if(IS_PLAYER(self))
 816                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 817
 818         // now I am sure the player IS dead
 819 }
 820 void KillIndicator_Think()
 821 {
 822         if (gameover)
 823         {
 824                 self.owner.killindicator = world;
 825                 remove(self);
 826                 return;
 827         }
 828
 829         if (self.owner.alpha < 0 && !self.owner.vehicle)
 830         {
 831                 self.owner.killindicator = world;
 832                 remove(self);
 833                 return;
 834         }
 835
 836         if(self.cnt <= 0)
 837         {
 838                 self = self.owner;
 839                 ClientKill_Now(); // no oldself needed
 840                 return;
 841         }
 842     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 843     {
 844         self.nextthink = time + 1;
 845         self.cnt -= 1;
 846     }
 847         else
 848         {
 849                 if(self.cnt <= 10)
 850                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 851                 if(IS_REAL_CLIENT(self.owner))
 852                 {
 853                         if(self.cnt <= 10)
 854                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 855                 }
 856                 self.nextthink = time + 1;
 857                 self.cnt -= 1;
 858         }
 859 }
 860
 861 float clientkilltime;
 862 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 863 {
 864         float killtime;
 865         float starttime;
 866         entity e;
 867
 868         if (gameover)
 869                 return;
 870
 871         killtime = autocvar_g_balance_kill_delay;
 872
 873         if(g_race_qualifying || g_cts)
 874                 killtime = 0;
 875
 876     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 877     {
 878                 remove(self.killindicator);
 879                 self.killindicator = world;
 880
 881         ClientKill_Now(); // allow instant kill in this case
 882         return;
 883     }
 884
 885         self.killindicator_teamchange = targetteam;
 886
 887     if(!self.killindicator)
 888         {
 889                 if(self.deadflag == DEAD_NO)
 890                 {
 891                         killtime = max(killtime, self.clientkill_nexttime - time);
 892                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 893                 }
 894
 895                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 896                 {
 897                         ClientKill_Now();
 898                 }
 899                 else
 900                 {
 901                         starttime = max(time, clientkilltime);
 902
 903                         self.killindicator = spawn();
 904                         self.killindicator.owner = self;
 905                         self.killindicator.scale = 0.5;
 906                         setattachment(self.killindicator, self, "");
 907                         setorigin(self.killindicator, '0 0 52');
 908                         self.killindicator.think = KillIndicator_Think;
 909                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 910                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 911                         self.killindicator.cnt = ceil(killtime);
 912                         self.killindicator.count = bound(0, ceil(killtime), 10);
 913                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 914
 915                         for(e = world; (e = find(e, classname, "body")) != world; )
 916                         {
 917                                 if(e.enemy != self)
 918                                         continue;
 919                                 e.killindicator = spawn();
 920                                 e.killindicator.owner = e;
 921                                 e.killindicator.scale = 0.5;
 922                                 setattachment(e.killindicator, e, "");
 923                                 setorigin(e.killindicator, '0 0 52');
 924                                 e.killindicator.think = KillIndicator_Think;
 925                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 926                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 927                                 e.killindicator.cnt = ceil(killtime);
 928                         }
 929                         self.lip = 0;
 930                 }
 931         }
 932         if(self.killindicator)
 933         {
 934                 if(targetteam == 0) // just die
 935                 {
 936                         self.killindicator.colormod = '0 0 0';
 937                         if(IS_REAL_CLIENT(self))
 938                         if(self.killindicator.cnt > 0)
 939                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 940                 }
 941                 else if(targetteam == -1) // auto
 942                 {
 943                         self.killindicator.colormod = '0 1 0';
 944                         if(IS_REAL_CLIENT(self))
 945                         if(self.killindicator.cnt > 0)
 946                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 947                 }
 948                 else if(targetteam == -2) // spectate
 949                 {
 950                         self.killindicator.colormod = '0.5 0.5 0.5';
 951                         if(IS_REAL_CLIENT(self))
 952                         if(self.killindicator.cnt > 0)
 953                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 954                 }
 955                 else
 956                 {
 957                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 958                         if(IS_REAL_CLIENT(self))
 959                         if(self.killindicator.cnt > 0)
 960                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 961                 }
 962         }
 963
 964 }
 965
 966 void ClientKill (void)
 967 {
 968         if(gameover) return;
 969         if(self.player_blocked) return;
 970         if(self.frozen) return;
 971
 972         ClientKill_TeamChange(0);
 973 }
 974
 975 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 976 {
 977     e.killindicator = spawn();
 978     e.killindicator.owner = e;
 979     e.killindicator.think = KillIndicator_Think;
 980     e.killindicator.nextthink = time + (e.lip) * 0.05;
 981     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 982     e.killindicator.health = 1; // this is used to indicate that it should be silent
 983     e.lip = 0;
 984 }
 985
 986 void FixClientCvars(entity e)
 987 {
 988         // send prediction settings to the client
 989         stuffcmd(e, "\nin_bindmap 0 0\n");
 990         if(g_race || g_cts)
 991                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 992         if(autocvar_g_antilag == 3) // client side hitscan
 993                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 994         if(autocvar_sv_gentle)
 995                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 996 }
 997
 998 float PlayerInIDList(entity p, string idlist)
 999 {
1000         float n, i;
1001         string s;
1002
1003         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1004         if (!p.crypto_idfp)
1005                 return 0;
1006
1007         // this function allows abbreviated player IDs too!
1008         n = tokenize_console(idlist);
1009         for(i = 0; i < n; ++i)
1010         {
1011                 s = argv(i);
1012                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1013                         return 1;
1014         }
1015
1016         return 0;
1017 }
1018
1019 /*
1020 =============
1021 ClientConnect
1022
1023 Called when a client connects to the server
1024 =============
1025 */
1026 void DecodeLevelParms (void);
1027 //void dom_player_join_team(entity pl);
1028 void set_dom_state(entity e);
1029 void ClientConnect (void)
1030 {
1031         float t;
1032
1033         if(IS_CLIENT(self))
1034         {
1035                 print("Warning: ClientConnect, but already connected!\n");
1036                 return;
1037         }
1038
1039         if(Ban_MaybeEnforceBanOnce(self))
1040                 return;
1041
1042         DecodeLevelParms();
1043
1044 #ifdef WATERMARK
1045         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1046 #endif
1047
1048         self.classname = "player_joining";
1049
1050         self.flags = FL_CLIENT;
1051         self.version_nagtime = time + 10 + random() * 10;
1052
1053         if(player_count<0)
1054         {
1055                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1056                 player_count = 0;
1057         }
1058
1059         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1060
1061         PlayerScore_Attach(self);
1062         ClientData_Attach();
1063         accuracy_init(self);
1064
1065         bot_clientconnect();
1066
1067         playerdemo_init();
1068
1069         anticheat_init();
1070
1071         // identify the right forced team
1072         if(autocvar_g_campaign)
1073         {
1074                 if(IS_REAL_CLIENT(self)) // only players, not bots
1075                 {
1076                         switch(autocvar_g_campaign_forceteam)
1077                         {
1078                                 case 1: self.team_forced = NUM_TEAM_1; break;
1079                                 case 2: self.team_forced = NUM_TEAM_2; break;
1080                                 case 3: self.team_forced = NUM_TEAM_3; break;
1081                                 case 4: self.team_forced = NUM_TEAM_4; break;
1082                                 default: self.team_forced = 0;
1083                         }
1084                 }
1085         }
1086         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1087                 self.team_forced = NUM_TEAM_1;
1088         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1089                 self.team_forced = NUM_TEAM_2;
1090         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1091                 self.team_forced = NUM_TEAM_3;
1092         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1093                 self.team_forced = NUM_TEAM_4;
1094         else if(autocvar_g_forced_team_otherwise == "red")
1095                 self.team_forced = NUM_TEAM_1;
1096         else if(autocvar_g_forced_team_otherwise == "blue")
1097                 self.team_forced = NUM_TEAM_2;
1098         else if(autocvar_g_forced_team_otherwise == "yellow")
1099                 self.team_forced = NUM_TEAM_3;
1100         else if(autocvar_g_forced_team_otherwise == "pink")
1101                 self.team_forced = NUM_TEAM_4;
1102         else if(autocvar_g_forced_team_otherwise == "spectate")
1103                 self.team_forced = -1;
1104         else if(autocvar_g_forced_team_otherwise == "spectator")
1105                 self.team_forced = -1;
1106         else
1107                 self.team_forced = 0;
1108
1109         if(!teamplay)
1110                 if(self.team_forced > 0)
1111                         self.team_forced = 0;
1112
1113         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1114
1115         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1116                 self.classname = "observer";
1117         } else {
1118                 if(teamplay)
1119                 {
1120                         if(autocvar_g_balance_teams)
1121                         {
1122                                 self.classname = "player";
1123                                 campaign_bots_may_start = 1;
1124                         }
1125                         else
1126                         {
1127                                 self.classname = "observer"; // do it anyway
1128                         }
1129                 }
1130                 else
1131                 {
1132                         self.classname = "player";
1133                         campaign_bots_may_start = 1;
1134                 }
1135         }
1136
1137         self.playerid = (playerid_last = playerid_last + 1);
1138
1139         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1140
1141     if(IS_BOT_CLIENT(self))
1142         PlayerStats_GameReport_AddPlayer(self);
1143
1144         if(autocvar_sv_eventlog)
1145                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1146
1147         LogTeamchange(self.playerid, self.team, 1);
1148
1149         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1150
1151         self.netname_previous = strzone(self.netname);
1152
1153         if(IS_PLAYER(self) && teamplay)
1154                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1155         else
1156                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1157
1158         stuffcmd(self, strcat(clientstuff, "\n"));
1159         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1160
1161         FixClientCvars(self);
1162
1163         // spawnfunc_waypoint sprites
1164         WaypointSprite_InitClient(self);
1165
1166         // Wazat's grappling hook
1167         SetGrappleHookBindings();
1168
1169         // Jetpack binds
1170         stuffcmd(self, "alias +jetpack +button10\n");
1171         stuffcmd(self, "alias -jetpack -button10\n");
1172
1173         // get version info from player
1174         stuffcmd(self, "cmd clientversion $gameversion\n");
1175
1176         // get other cvars from player
1177         GetCvars(0);
1178
1179         // notify about available teams
1180         if(teamplay)
1181         {
1182                 CheckAllowedTeams(self);
1183                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1184                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1185         }
1186         else
1187                 stuffcmd(self, "set _teams_available 0\n");
1188
1189         attach_entcs();
1190
1191         bot_relinkplayerlist();
1192
1193         self.spectatortime = time;
1194         if(blockSpectators)
1195         {
1196                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1197         }
1198
1199         self.jointime = time;
1200         self.allowed_timeouts = autocvar_sv_timeout_number;
1201
1202         if(IS_REAL_CLIENT(self))
1203         {
1204                 if(!autocvar_g_campaign)
1205                 {
1206                         self.motd_actived_time = -1;
1207                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1208                 }
1209
1210                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1211                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1212         }
1213
1214         if(!sv_foginterval && world.fog != "")
1215                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1216
1217         W_HitPlotOpen(self);
1218
1219         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1220                 send_CSQC_teamnagger();
1221
1222         CheatInitClient();
1223
1224         CSQCMODEL_AUTOINIT();
1225
1226         self.model_randomizer = random();
1227
1228         if(IS_REAL_CLIENT(self))
1229                 sv_notice_join();
1230
1231         MUTATOR_CALLHOOK(ClientConnect);
1232 }
1233 /*
1234 =============
1235 ClientDisconnect
1236
1237 Called when a client disconnects from the server
1238 =============
1239 */
1240 .entity chatbubbleentity;
1241 void ReadyCount();
1242 void ClientDisconnect (void)
1243 {
1244         if(self.vehicle)
1245             vehicles_exit(VHEF_RELESE);
1246
1247         if (!IS_CLIENT(self))
1248         {
1249                 print("Warning: ClientDisconnect without ClientConnect\n");
1250                 return;
1251         }
1252
1253         PlayerStats_GameReport_FinalizePlayer(self);
1254
1255         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1256
1257         CheatShutdownClient();
1258
1259         W_HitPlotClose(self);
1260
1261         anticheat_report();
1262         anticheat_shutdown();
1263
1264         playerdemo_shutdown();
1265
1266         bot_clientdisconnect();
1267
1268         if(self.entcs)
1269                 detach_entcs();
1270
1271         if(autocvar_sv_eventlog)
1272                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1273
1274         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1275
1276         MUTATOR_CALLHOOK(ClientDisconnect);
1277
1278         Portal_ClearAll(self);
1279
1280         Unfreeze(self);
1281
1282         RemoveGrapplingHook(self);
1283
1284         // Here, everything has been done that requires this player to be a client.
1285
1286         self.flags &= ~FL_CLIENT;
1287
1288         if (self.chatbubbleentity)
1289                 remove (self.chatbubbleentity);
1290
1291         if (self.killindicator)
1292                 remove (self.killindicator);
1293
1294         WaypointSprite_PlayerGone();
1295
1296         bot_relinkplayerlist();
1297
1298         accuracy_free(self);
1299         ClientData_Detach();
1300         PlayerScore_Detach(self);
1301
1302         if(self.netname_previous)
1303                 strunzone(self.netname_previous);
1304         if(self.clientstatus)
1305                 strunzone(self.clientstatus);
1306         if(self.weaponorder_byimpulse)
1307                 strunzone(self.weaponorder_byimpulse);
1308
1309         ClearPlayerSounds();
1310
1311         if(self.personal)
1312                 remove(self.personal);
1313
1314         self.playerid = 0;
1315         ReadyCount();
1316
1317         // free cvars
1318         GetCvars(-1);
1319 }
1320
1321 .float BUTTON_CHAT;
1322 void ChatBubbleThink()
1323 {
1324         self.nextthink = time;
1325         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1326         {
1327                 if(self.owner) // but why can that ever be world?
1328                         self.owner.chatbubbleentity = world;
1329                 remove(self);
1330                 return;
1331         }
1332         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1333 #ifdef TETRIS
1334                 || self.owner.tetris_on
1335 #endif
1336         )
1337                 self.model = self.mdl;
1338         else
1339                 self.model = "";
1340 }
1341
1342 void UpdateChatBubble()
1343 {
1344         if (self.alpha < 0)
1345                 return;
1346         // spawn a chatbubble entity if needed
1347         if (!self.chatbubbleentity)
1348         {
1349                 self.chatbubbleentity = spawn();
1350                 self.chatbubbleentity.owner = self;
1351                 self.chatbubbleentity.exteriormodeltoclient = self;
1352                 self.chatbubbleentity.think = ChatBubbleThink;
1353                 self.chatbubbleentity.nextthink = time;
1354                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1355                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1356                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs.z * '0 0 1');
1357                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1358                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1359                 self.chatbubbleentity.model = "";
1360                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1361         }
1362 }
1363
1364
1365 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1366 // added to the model skins
1367 /*void UpdateColorModHack()
1368 {
1369         float c;
1370         c = self.clientcolors & 15;
1371         // LordHavoc: only bothering to support white, green, red, yellow, blue
1372              if (!teamplay) self.colormod = '0 0 0';
1373         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1374         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1375         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1376         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1377         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1378         else self.colormod = '1 1 1';
1379 }*/
1380
1381 void respawn(void)
1382 {
1383         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1384         {
1385                 self.solid = SOLID_NOT;
1386                 self.takedamage = DAMAGE_NO;
1387                 self.movetype = MOVETYPE_FLY;
1388                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1389                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1390                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1391                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1392                 if(autocvar_g_respawn_ghosts_maxtime)
1393                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1394         }
1395
1396         CopyBody(1);
1397
1398         self.effects |= EF_NODRAW; // prevent another CopyBody
1399         PutClientInServer();
1400 }
1401
1402 void play_countdown(float finished, string samp)
1403 {
1404         if(IS_REAL_CLIENT(self))
1405                 if(floor(finished - time - frametime) != floor(finished - time))
1406                         if(finished - time < 6)
1407                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1408 }
1409
1410 void player_powerups (void)
1411 {
1412         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1413         olditems = self.items;
1414
1415         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1416                 self.modelflags |= MF_ROCKET;
1417         else
1418                 self.modelflags &= ~MF_ROCKET;
1419
1420         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1421
1422         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1423                 return;
1424
1425         Fire_ApplyDamage(self);
1426         Fire_ApplyEffect(self);
1427
1428         if (!g_instagib)
1429         {
1430                 if (self.items & IT_STRENGTH)
1431                 {
1432                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1433                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1434                         if (time > self.strength_finished)
1435                         {
1436                                 self.items = self.items - (self.items & IT_STRENGTH);
1437                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1438                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1439                         }
1440                 }
1441                 else
1442                 {
1443                         if (time < self.strength_finished)
1444                         {
1445                                 self.items = self.items | IT_STRENGTH;
1446                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1447                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1448                         }
1449                 }
1450                 if (self.items & IT_INVINCIBLE)
1451                 {
1452                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1453                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1454                         if (time > self.invincible_finished)
1455                         {
1456                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1457                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1458                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1459                         }
1460                 }
1461                 else
1462                 {
1463                         if (time < self.invincible_finished)
1464                         {
1465                                 self.items = self.items | IT_INVINCIBLE;
1466                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1467                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1468                         }
1469                 }
1470                 if (self.items & IT_SUPERWEAPON)
1471                 {
1472                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1473                         {
1474                                 self.superweapons_finished = 0;
1475                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1476                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1477                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1478                         }
1479                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1480                         {
1481                                 // don't let them run out
1482                         }
1483                         else
1484                         {
1485                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1486                                 if (time > self.superweapons_finished)
1487                                 {
1488                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1489                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1490                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1491                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1492                                 }
1493                         }
1494                 }
1495                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1496                 {
1497                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1498                         {
1499                                 self.items = self.items | IT_SUPERWEAPON;
1500                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1501                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1502                         }
1503                         else
1504                         {
1505                                 self.superweapons_finished = 0;
1506                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1507                         }
1508                 }
1509                 else
1510                 {
1511                         self.superweapons_finished = 0;
1512                 }
1513         }
1514
1515         if(autocvar_g_nodepthtestplayers)
1516                 self.effects = self.effects | EF_NODEPTHTEST;
1517
1518         if(autocvar_g_fullbrightplayers)
1519                 self.effects = self.effects | EF_FULLBRIGHT;
1520
1521         if (time >= game_starttime)
1522         if (time < self.spawnshieldtime)
1523                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1524
1525         MUTATOR_CALLHOOK(PlayerPowerups);
1526 }
1527
1528 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1529 {
1530         if(current > stable)
1531                 return current;
1532         else if(current > stable - 0.25) // when close enough, "snap"
1533                 return stable;
1534         else
1535                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1536 }
1537
1538 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1539 {
1540         if(current < stable)
1541                 return current;
1542         else if(current < stable + 0.25) // when close enough, "snap"
1543                 return stable;
1544         else
1545                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1546 }
1547
1548 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1549 {
1550         if(current > rotstable)
1551         {
1552                 if(rotframetime > 0)
1553                 {
1554                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1555                         current = max(rotstable, current - rotlinear * rotframetime);
1556                 }
1557         }
1558         else if(current < regenstable)
1559         {
1560                 if(regenframetime > 0)
1561                 {
1562                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1563                         current = min(regenstable, current + regenlinear * regenframetime);
1564                 }
1565         }
1566
1567         if(current > limit)
1568                 current = limit;
1569
1570         return current;
1571 }
1572
1573 void player_regen (void)
1574 {
1575         float max_mod, regen_mod, rot_mod, limit_mod;
1576         max_mod = regen_mod = rot_mod = limit_mod = 1;
1577         regen_mod_max = max_mod;
1578         regen_mod_regen = regen_mod;
1579         regen_mod_rot = rot_mod;
1580         regen_mod_limit = limit_mod;
1581         if(!MUTATOR_CALLHOOK(PlayerRegen))
1582         if(!self.frozen)
1583         {
1584                 float minh, mina, maxh, maxa, limith, limita;
1585                 maxh = autocvar_g_balance_health_rotstable;
1586                 maxa = autocvar_g_balance_armor_rotstable;
1587                 minh = autocvar_g_balance_health_regenstable;
1588                 mina = autocvar_g_balance_armor_regenstable;
1589                 limith = autocvar_g_balance_health_limit;
1590                 limita = autocvar_g_balance_armor_limit;
1591
1592                 max_mod = regen_mod_max;
1593                 regen_mod = regen_mod_regen;
1594                 rot_mod = regen_mod_rot;
1595                 limit_mod = regen_mod_limit;
1596
1597                 maxh = maxh * max_mod;
1598                 minh = minh * max_mod;
1599                 limith = limith * limit_mod;
1600                 limita = limita * limit_mod;
1601
1602                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1603                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1604         }
1605
1606         // if player rotted to death...  die!
1607         // check this outside above checks, as player may still be able to rot to death
1608         if(self.health < 1)
1609                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1610
1611         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1612         {
1613                 float minf, maxf, limitf;
1614
1615                 maxf = autocvar_g_balance_fuel_rotstable;
1616                 minf = autocvar_g_balance_fuel_regenstable;
1617                 limitf = autocvar_g_balance_fuel_limit;
1618
1619                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1620         }
1621 }
1622
1623 float zoomstate_set;
1624 void SetZoomState(float z)
1625 {
1626         if(z != self.zoomstate)
1627         {
1628                 self.zoomstate = z;
1629                 ClientData_Touch(self);
1630         }
1631         zoomstate_set = 1;
1632 }
1633
1634 void GetPressedKeys(void) {
1635         MUTATOR_CALLHOOK(GetPressedKeys);
1636         if (self.movement.x > 0) // get if movement keys are pressed
1637         {       // forward key pressed
1638                 self.pressedkeys |= KEY_FORWARD;
1639                 self.pressedkeys &= ~KEY_BACKWARD;
1640         }
1641         else if (self.movement.x < 0)
1642         {       // backward key pressed
1643                 self.pressedkeys |= KEY_BACKWARD;
1644                 self.pressedkeys &= ~KEY_FORWARD;
1645         }
1646         else
1647         {       // no x input
1648                 self.pressedkeys &= ~KEY_FORWARD;
1649                 self.pressedkeys &= ~KEY_BACKWARD;
1650         }
1651
1652         if (self.movement.y > 0)
1653         {       // right key pressed
1654                 self.pressedkeys |= KEY_RIGHT;
1655                 self.pressedkeys &= ~KEY_LEFT;
1656         }
1657         else if (self.movement.y < 0)
1658         {       // left key pressed
1659                 self.pressedkeys |= KEY_LEFT;
1660                 self.pressedkeys &= ~KEY_RIGHT;
1661         }
1662         else
1663         {       // no y input
1664                 self.pressedkeys &= ~KEY_RIGHT;
1665                 self.pressedkeys &= ~KEY_LEFT;
1666         }
1667
1668         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1669                 self.pressedkeys |= KEY_JUMP;
1670         else
1671                 self.pressedkeys &= ~KEY_JUMP;
1672         if (self.BUTTON_CROUCH)
1673                 self.pressedkeys |= KEY_CROUCH;
1674         else
1675                 self.pressedkeys &= ~KEY_CROUCH;
1676
1677         if (self.BUTTON_ATCK)
1678                 self.pressedkeys |= KEY_ATCK;
1679         else
1680                 self.pressedkeys &= ~KEY_ATCK;
1681         if (self.BUTTON_ATCK2)
1682                 self.pressedkeys |= KEY_ATCK2;
1683         else
1684                 self.pressedkeys &= ~KEY_ATCK2;
1685 }
1686
1687 /*
1688 ======================
1689 spectate mode routines
1690 ======================
1691 */
1692
1693 void SpectateCopy(entity spectatee) {
1694         other = spectatee;
1695         MUTATOR_CALLHOOK(SpectateCopy);
1696         self.armortype = spectatee.armortype;
1697         self.armorvalue = spectatee.armorvalue;
1698         self.ammo_cells = spectatee.ammo_cells;
1699         self.ammo_plasma = spectatee.ammo_plasma;
1700         self.ammo_shells = spectatee.ammo_shells;
1701         self.ammo_nails = spectatee.ammo_nails;
1702         self.ammo_rockets = spectatee.ammo_rockets;
1703         self.ammo_fuel = spectatee.ammo_fuel;
1704         self.clip_load = spectatee.clip_load;
1705         self.clip_size = spectatee.clip_size;
1706         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1707         self.health = spectatee.health;
1708         self.impulse = 0;
1709         self.items = spectatee.items;
1710         self.last_pickup = spectatee.last_pickup;
1711         self.hit_time = spectatee.hit_time;
1712         self.metertime = spectatee.metertime;
1713         self.strength_finished = spectatee.strength_finished;
1714         self.invincible_finished = spectatee.invincible_finished;
1715         self.pressedkeys = spectatee.pressedkeys;
1716         self.weapons = spectatee.weapons;
1717         self.switchweapon = spectatee.switchweapon;
1718         self.switchingweapon = spectatee.switchingweapon;
1719         self.weapon = spectatee.weapon;
1720         self.vortex_charge = spectatee.vortex_charge;
1721         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1722         self.hagar_load = spectatee.hagar_load;
1723         self.arc_heat_percent = spectatee.arc_heat_percent;
1724         self.minelayer_mines = spectatee.minelayer_mines;
1725         self.punchangle = spectatee.punchangle;
1726         self.view_ofs = spectatee.view_ofs;
1727         self.velocity = spectatee.velocity;
1728         self.dmg_take = spectatee.dmg_take;
1729         self.dmg_save = spectatee.dmg_save;
1730         self.dmg_inflictor = spectatee.dmg_inflictor;
1731         self.v_angle = spectatee.v_angle;
1732         self.angles = spectatee.v_angle;
1733         self.frozen = spectatee.frozen;
1734         self.revive_progress = spectatee.revive_progress;
1735         if(!self.BUTTON_USE)
1736                 self.fixangle = true;
1737         setorigin(self, spectatee.origin);
1738         setsize(self, spectatee.mins, spectatee.maxs);
1739         SetZoomState(spectatee.zoomstate);
1740
1741     anticheat_spectatecopy(spectatee);
1742         self.hud = spectatee.hud;
1743         if(spectatee.vehicle)
1744     {
1745         self.fixangle = false;
1746         //self.velocity = spectatee.vehicle.velocity;
1747         self.vehicle_health = spectatee.vehicle_health;
1748         self.vehicle_shield = spectatee.vehicle_shield;
1749         self.vehicle_energy = spectatee.vehicle_energy;
1750         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1751         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1752         self.vehicle_reload1 = spectatee.vehicle_reload1;
1753         self.vehicle_reload2 = spectatee.vehicle_reload2;
1754
1755         msg_entity = self;
1756
1757         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1758             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1759             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1760             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1761
1762         //WriteByte (MSG_ONE, SVC_SETVIEW);
1763         //    WriteEntity(MSG_ONE, self);
1764         //makevectors(spectatee.v_angle);
1765         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1766     }
1767 }
1768
1769 float SpectateUpdate()
1770 {
1771         if(!self.enemy)
1772             return 0;
1773
1774         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1775         {
1776                 SetSpectator(self, world);
1777                 return 0;
1778         }
1779
1780         SpectateCopy(self.enemy);
1781
1782         return 1;
1783 }
1784
1785 float SpectateSet()
1786 {
1787         if(self.enemy.classname != "player")
1788                 return false;
1789         /*if(self.enemy.vehicle)
1790         {
1791
1792                 msg_entity = self;
1793                 WriteByte(MSG_ONE, SVC_SETVIEW);
1794                 WriteEntity(MSG_ONE, self.enemy);
1795                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1796
1797                 self.movetype = MOVETYPE_NONE;
1798                 accuracy_resend(self);
1799         }
1800         else
1801         {*/
1802                 msg_entity = self;
1803                 WriteByte(MSG_ONE, SVC_SETVIEW);
1804                 WriteEntity(MSG_ONE, self.enemy);
1805                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1806                 self.movetype = MOVETYPE_NONE;
1807                 accuracy_resend(self);
1808
1809                 if(!SpectateUpdate())
1810                         PutObserverInServer();
1811         //}
1812         return true;
1813 }
1814
1815 void SetSpectator(entity player, entity spectatee)
1816 {
1817         entity old_spectatee = player.enemy;
1818
1819         player.enemy = spectatee;
1820
1821         // WEAPONTODO
1822         // these are required to fix the spectator bug with arc
1823         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1824         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1825 }
1826
1827 float Spectate(entity pl)
1828 {
1829         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1830         if(pl.team != self.team)
1831                 return 0;
1832
1833         SetSpectator(self, pl);
1834         return SpectateSet();
1835 }
1836
1837 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1838 entity CA_SpectateNext(entity start) {
1839         if (start.team == self.team) {
1840                 return start;
1841         }
1842
1843         other = start;
1844         // continue from current player
1845         while(other && other.team != self.team) {
1846                 other = find(other, classname, "player");
1847         }
1848
1849         if (!other) {
1850                 // restart from begining
1851                 other = find(other, classname, "player");
1852                 while(other && other.team != self.team) {
1853                         other = find(other, classname, "player");
1854                 }
1855         }
1856
1857         return other;
1858 }
1859
1860 float SpectateNext()
1861 {
1862         other = find(self.enemy, classname, "player");
1863
1864         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1865                 // CA and ca players when spectating enemies is forbidden
1866                 other = CA_SpectateNext(other);
1867         } else {
1868                 // other modes and ca spectators or spectating enemies is allowed
1869                 if (!other)
1870                         other = find(other, classname, "player");
1871         }
1872
1873         if(other) { SetSpectator(self, other); }
1874
1875         return SpectateSet();
1876 }
1877
1878 float SpectatePrev()
1879 {
1880         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1881         other = findchain(classname, "player");
1882         if (!other) // no player
1883                 return false;
1884
1885         entity first = other;
1886         // skip players until current spectated player
1887         if(self.enemy)
1888         while(other && other != self.enemy)
1889                 other = other.chain;
1890
1891         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1892         {
1893                 do { other = other.chain; }
1894                 while(other && other.team != self.team);
1895
1896                 if (!other)
1897                 {
1898                         other = first;
1899                         while(other.team != self.team)
1900                                 other = other.chain;
1901                         if(other == self.enemy)
1902                                 return true;
1903                 }
1904         }
1905         else
1906         {
1907                 if(other.chain)
1908                         other = other.chain;
1909                 else
1910                         other = first;
1911         }
1912         SetSpectator(self, other);
1913         return SpectateSet();
1914 }
1915
1916 /*
1917 =============
1918 ShowRespawnCountdown()
1919
1920 Update a respawn countdown display.
1921 =============
1922 */
1923 void ShowRespawnCountdown()
1924 {
1925         float number;
1926         if(self.deadflag == DEAD_NO) // just respawned?
1927                 return;
1928         else
1929         {
1930                 number = ceil(self.respawn_time - time);
1931                 if(number <= 0)
1932                         return;
1933                 if(number <= self.respawn_countdown)
1934                 {
1935                         self.respawn_countdown = number - 1;
1936                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1937                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1938                 }
1939         }
1940 }
1941
1942 void LeaveSpectatorMode()
1943 {
1944         if(self.caplayer)
1945                 return;
1946         if(nJoinAllowed(self))
1947         {
1948                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1949                 {
1950                         self.classname = "player";
1951                         nades_RemoveBonus(self);
1952
1953                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1954                                 { JoinBestTeam(self, false, true); }
1955
1956                         if(autocvar_g_campaign)
1957                                 { campaign_bots_may_start = 1; }
1958
1959                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1960
1961                         PutClientInServer();
1962
1963                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1964                 }
1965                 else
1966                         stuffcmd(self, "menu_showteamselect\n");
1967         }
1968         else
1969         {
1970                 // Player may not join because g_maxplayers is set
1971                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1972         }
1973 }
1974
1975 /**
1976  * Determines whether the player is allowed to join. This depends on cvar
1977  * g_maxplayers, if it isn't used this function always return true, otherwise
1978  * it checks whether the number of currently playing players exceeds g_maxplayers.
1979  * @return int number of free slots for players, 0 if none
1980  */
1981 float nJoinAllowed(entity ignore) {
1982         if(!ignore)
1983         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1984         // so report 0 free slots if restricted
1985         {
1986                 if(autocvar_g_forced_team_otherwise == "spectate")
1987                         return 0;
1988                 if(autocvar_g_forced_team_otherwise == "spectator")
1989                         return 0;
1990         }
1991
1992         if(self.team_forced < 0)
1993                 return 0; // forced spectators can never join
1994
1995         // TODO simplify this
1996         entity e;
1997         float totalClients = 0;
1998         FOR_EACH_CLIENT(e)
1999                 if(e != ignore)
2000                         totalClients += 1;
2001
2002         if (!autocvar_g_maxplayers)
2003                 return maxclients - totalClients;
2004
2005         float currentlyPlaying = 0;
2006         FOR_EACH_REALCLIENT(e)
2007                 if(IS_PLAYER(e) || e.caplayer)
2008                         currentlyPlaying += 1;
2009
2010         if(currentlyPlaying < autocvar_g_maxplayers)
2011                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2012
2013         return 0;
2014 }
2015
2016 /**
2017  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2018  * g_maxplayers_spectator_blocktime seconds
2019  */
2020 void checkSpectatorBlock() {
2021         if(IS_SPEC(self) || IS_OBSERVER(self))
2022         if(!self.caplayer)
2023         if(IS_REAL_CLIENT(self))
2024         {
2025                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2026                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2027                         dropclient(self);
2028                 }
2029         }
2030 }
2031
2032 void PrintWelcomeMessage()
2033 {
2034         if(self.motd_actived_time == 0)
2035         {
2036                 if (autocvar_g_campaign) {
2037                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2038                                 self.motd_actived_time = time;
2039                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2040                         }
2041                 } else {
2042                         if (self.BUTTON_INFO) {
2043                                 self.motd_actived_time = time;
2044                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2045                         }
2046                 }
2047         }
2048         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2049         {
2050                 if (autocvar_g_campaign) {
2051                         if (self.BUTTON_INFO)
2052                                 self.motd_actived_time = time;
2053                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2054                                 self.motd_actived_time = 0;
2055                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2056                         }
2057                 } else {
2058                         if (self.BUTTON_INFO)
2059                                 self.motd_actived_time = time;
2060                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2061                                 self.motd_actived_time = 0;
2062                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2063                         }
2064                 }
2065         }
2066         else //if(self.motd_actived_time < 0) // just connected, motd is active
2067         {
2068                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2069                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2070                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2071                 {
2072                         // instanctly hide MOTD
2073                         self.motd_actived_time = 0;
2074                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2075                 }
2076         }
2077 }
2078
2079 void ObserverThink()
2080 {
2081         float prefered_movetype;
2082         if (self.flags & FL_JUMPRELEASED) {
2083                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2084                         self.flags &= ~FL_JUMPRELEASED;
2085                         self.flags |= FL_SPAWNING;
2086                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2087                         self.flags &= ~FL_JUMPRELEASED;
2088                         if(SpectateNext()) {
2089                                 self.classname = "spectator";
2090                         }
2091                 } else {
2092                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2093                         if (self.movetype != prefered_movetype)
2094                                 self.movetype = prefered_movetype;
2095                 }
2096         } else {
2097                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2098                         self.flags |= FL_JUMPRELEASED;
2099                         if(self.flags & FL_SPAWNING)
2100                         {
2101                                 self.flags &= ~FL_SPAWNING;
2102                                 LeaveSpectatorMode();
2103                                 return;
2104                         }
2105                 }
2106         }
2107 }
2108
2109 void SpectatorThink()
2110 {
2111         if (self.flags & FL_JUMPRELEASED) {
2112                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2113                         self.flags &= ~FL_JUMPRELEASED;
2114                         self.flags |= FL_SPAWNING;
2115                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2116                         self.flags &= ~FL_JUMPRELEASED;
2117                         if(SpectateNext()) {
2118                                 self.classname = "spectator";
2119                         } else {
2120                                 self.classname = "observer";
2121                                 PutClientInServer();
2122                         }
2123                         self.impulse = 0;
2124                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2125                         self.flags &= ~FL_JUMPRELEASED;
2126                         if(SpectatePrev()) {
2127                                 self.classname = "spectator";
2128                         } else {
2129                                 self.classname = "observer";
2130                                 PutClientInServer();
2131                         }
2132                         self.impulse = 0;
2133                 } else if (self.BUTTON_ATCK2) {
2134                         self.flags &= ~FL_JUMPRELEASED;
2135                         self.classname = "observer";
2136                         PutClientInServer();
2137                 } else {
2138                         if(!SpectateUpdate())
2139                                 PutObserverInServer();
2140                 }
2141         } else {
2142                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2143                         self.flags |= FL_JUMPRELEASED;
2144                         if(self.flags & FL_SPAWNING)
2145                         {
2146                                 self.flags &= ~FL_SPAWNING;
2147                                 LeaveSpectatorMode();
2148                                 return;
2149                         }
2150                 }
2151                 if(!SpectateUpdate())
2152                         PutObserverInServer();
2153         }
2154
2155         self.flags |= FL_CLIENT | FL_NOTARGET;
2156 }
2157
2158 void PlayerUseKey()
2159 {
2160         if (!IS_PLAYER(self))
2161                 return;
2162
2163         if(self.vehicle)
2164         {
2165         vehicles_exit(VHEF_NORMAL);
2166         return;
2167         }
2168
2169         // a use key was pressed; call handlers
2170         MUTATOR_CALLHOOK(PlayerUseKey);
2171 }
2172
2173 float isInvisibleString(string s)
2174 {
2175         float i, n, c;
2176         s = strdecolorize(s);
2177         for((i = 0), (n = strlen(s)); i < n; ++i)
2178         {
2179                 c = str2chr(s, i);
2180                 switch(c)
2181                 {
2182                         case 0:
2183                         case 32: // space
2184                                 break;
2185                         case 192: // charmap space
2186                                 if (!autocvar_utf8_enable)
2187                                         break;
2188                                 return false;
2189                         case 160: // space in unicode fonts
2190                         case 0xE000 + 192: // utf8 charmap space
2191                                 if (autocvar_utf8_enable)
2192                                         break;
2193                         default:
2194                                 return false;
2195                 }
2196         }
2197         return true;
2198 }
2199
2200 /*
2201 =============
2202 PlayerPreThink
2203
2204 Called every frame for each client before the physics are run
2205 =============
2206 */
2207 .float usekeypressed;
2208 void() nexball_setstatus;
2209 .int items_added;
2210 void PlayerPreThink (void)
2211 {
2212         WarpZone_PlayerPhysics_FixVAngle();
2213
2214         self.stat_game_starttime = game_starttime;
2215         self.stat_round_starttime = round_starttime;
2216         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2217         self.stat_leadlimit = autocvar_leadlimit;
2218
2219         if(frametime)
2220         {
2221                 // physics frames: update anticheat stuff
2222                 anticheat_prethink();
2223         }
2224
2225         if(blockSpectators && frametime)
2226                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2227                 checkSpectatorBlock();
2228
2229         zoomstate_set = 0;
2230
2231         // Savage: Check for nameless players
2232         if (isInvisibleString(self.netname)) {
2233                 string new_name = strzone(strcat("Player@", self.netaddress));
2234                 if(autocvar_sv_eventlog)
2235                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2236                 if(self.netname_previous)
2237                         strunzone(self.netname_previous);
2238                 self.netname_previous = strzone(new_name);
2239                 self.netname = self.netname_previous;
2240                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2241         } else if(self.netname_previous != self.netname) {
2242                 if(autocvar_sv_eventlog)
2243                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2244                 if(self.netname_previous)
2245                         strunzone(self.netname_previous);
2246                 self.netname_previous = strzone(self.netname);
2247         }
2248
2249         // version nagging
2250         if(self.version_nagtime)
2251                 if(self.cvar_g_xonoticversion)
2252                         if(time > self.version_nagtime)
2253                         {
2254                                 // don't notify git users
2255                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2256                                 {
2257                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2258                                         {
2259                                                 // notify release users if connecting to git
2260                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2261                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2262                                         }
2263                                         else
2264                                         {
2265                                                 float r;
2266                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2267                                                 if(r < 0)
2268                                                 {
2269                                                         // give users new version
2270                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2271                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2272                                                 }
2273                                                 else if(r > 0)
2274                                                 {
2275                                                         // notify users about old server version
2276                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2277                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2278                                                 }
2279                                         }
2280                                 }
2281                                 self.version_nagtime = 0;
2282                         }
2283
2284         // GOD MODE info
2285         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2286         {
2287                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2288                 self.max_armorvalue = 0;
2289         }
2290
2291 #ifdef TETRIS
2292         if (TetrisPreFrame())
2293                 return;
2294 #endif
2295
2296         if(self.frozen == 2)
2297         {
2298                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2299                 self.health = max(1, self.revive_progress * start_health);
2300                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2301
2302                 if(self.revive_progress >= 1)
2303                         Unfreeze(self);
2304         }
2305         else if(self.frozen == 3)
2306         {
2307                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2308                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2309
2310                 if(self.health < 1)
2311                 {
2312                         if(self.vehicle)
2313                                 vehicles_exit(VHEF_RELESE);
2314                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2315                 }
2316                 else if ( self.revive_progress <= 0 )
2317                         Unfreeze(self);
2318         }
2319
2320         MUTATOR_CALLHOOK(PlayerPreThink);
2321
2322         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2323         {
2324                 if(self.BUTTON_USE && !self.usekeypressed)
2325                         PlayerUseKey();
2326                 self.usekeypressed = self.BUTTON_USE;
2327         }
2328
2329         if(IS_REAL_CLIENT(self))
2330                 PrintWelcomeMessage();
2331
2332         if(IS_PLAYER(self))
2333         {
2334
2335                 CheckRules_Player();
2336
2337                 if (intermission_running)
2338                 {
2339                         IntermissionThink ();   // otherwise a button could be missed between
2340                         return;                                 // the think tics
2341                 }
2342
2343                 //don't allow the player to turn around while game is paused!
2344                 if(timeout_status == TIMEOUT_ACTIVE) {
2345                         // FIXME turn this into CSQC stuff
2346                         self.v_angle = self.lastV_angle;
2347                         self.angles = self.lastV_angle;
2348                         self.fixangle = true;
2349                 }
2350
2351                 if(frametime)
2352                 {
2353                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2354                         {
2355                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2356                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2357                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2358
2359                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2360                                 {
2361                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2362                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2363                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2364                                 }
2365                         }
2366                         else
2367                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2368
2369                         player_powerups();
2370                 }
2371
2372                 if (self.deadflag != DEAD_NO)
2373                 {
2374                         if(self.personal && g_race_qualifying)
2375                         {
2376                                 if(time > self.respawn_time)
2377                                 {
2378                                         self.respawn_time = time + 1; // only retry once a second
2379                                         self.stat_respawn_time = self.respawn_time;
2380                                         respawn();
2381                                         self.impulse = 141;
2382                                 }
2383                         }
2384                         else
2385                         {
2386                                 float button_pressed;
2387                                 if(frametime)
2388                                         player_anim();
2389                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2390
2391                                 if (self.deadflag == DEAD_DYING)
2392                                 {
2393                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2394                                                 self.deadflag = DEAD_RESPAWNING;
2395                                         else if(!button_pressed)
2396                                                 self.deadflag = DEAD_DEAD;
2397                                 }
2398                                 else if (self.deadflag == DEAD_DEAD)
2399                                 {
2400                                         if(button_pressed)
2401                                                 self.deadflag = DEAD_RESPAWNABLE;
2402                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2403                                                 self.deadflag = DEAD_RESPAWNING;
2404                                 }
2405                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2406                                 {
2407                                         if(!button_pressed)
2408                                                 self.deadflag = DEAD_RESPAWNING;
2409                                 }
2410                                 else if (self.deadflag == DEAD_RESPAWNING)
2411                                 {
2412                                         if(time > self.respawn_time)
2413                                         {
2414                                                 self.respawn_time = time + 1; // only retry once a second
2415                                                 self.respawn_time_max = self.respawn_time;
2416                                                 respawn();
2417                                         }
2418                                 }
2419
2420                                 ShowRespawnCountdown();
2421
2422                                 if(self.respawn_flags & RESPAWN_SILENT)
2423                                         self.stat_respawn_time = 0;
2424                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2425                                         self.stat_respawn_time = self.respawn_time_max;
2426                                 else
2427                                         self.stat_respawn_time = self.respawn_time;
2428                         }
2429
2430                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2431                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2432                                 self.stat_respawn_time *= -1;
2433
2434                         return;
2435                 }
2436
2437                 self.prevorigin = self.origin;
2438
2439                 float do_crouch = self.BUTTON_CROUCH;
2440                 if(self.hook.state)
2441                         do_crouch = 0;
2442                 if(self.vehicle)
2443                         do_crouch = 0;
2444                 if(self.frozen)
2445                         do_crouch = 0;
2446
2447                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2448                 // It cannot be predicted by the engine!
2449                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2450                         do_crouch = 0;
2451
2452                 if (do_crouch)
2453                 {
2454                         if (!self.crouch)
2455                         {
2456                                 self.crouch = true;
2457                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2458                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2459                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2460                         }
2461                 }
2462                 else
2463                 {
2464                         if (self.crouch)
2465                         {
2466                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, false, self);
2467                                 if (!trace_startsolid)
2468                                 {
2469                                         self.crouch = false;
2470                                         self.view_ofs = PL_VIEW_OFS;
2471                                         setsize (self, PL_MIN, PL_MAX);
2472                                 }
2473                         }
2474                 }
2475
2476                 FixPlayermodel();
2477
2478                 GrapplingHookFrame();
2479
2480                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2481                 //if(frametime)
2482                 {
2483                         self.items &= ~self.items_added;
2484
2485                         W_WeaponFrame();
2486
2487                         self.items_added = 0;
2488                         if(self.items & IT_JETPACK)
2489                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2490                                         self.items_added |= IT_FUEL;
2491
2492                         self.items |= self.items_added;
2493                 }
2494
2495                 player_regen();
2496
2497                 // WEAPONTODO: Add a weapon request for this
2498                 // rot vortex charge to the charge limit
2499                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2500                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2501
2502                 if(frametime)
2503                         player_anim();
2504
2505                 // secret status
2506                 secrets_setstatus();
2507
2508                 // monsters status
2509                 monsters_setstatus();
2510
2511                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2512
2513                 //self.angles_y=self.v_angle_y + 90;   // temp
2514         } else if(gameover) {
2515                 if (intermission_running)
2516                         IntermissionThink ();   // otherwise a button could be missed between
2517                 return;
2518         } else if(IS_OBSERVER(self)) {
2519                 ObserverThink();
2520         } else if(IS_SPEC(self)) {
2521                 SpectatorThink();
2522         }
2523
2524         // WEAPONTODO: Add weapon request for this
2525         if(!zoomstate_set)
2526                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2527
2528         float oldspectatee_status;
2529         oldspectatee_status = self.spectatee_status;
2530         if(IS_SPEC(self))
2531                 self.spectatee_status = num_for_edict(self.enemy);
2532         else if(IS_OBSERVER(self))
2533                 self.spectatee_status = num_for_edict(self);
2534         else
2535                 self.spectatee_status = 0;
2536         if(self.spectatee_status != oldspectatee_status)
2537         {
2538                 ClientData_Touch(self);
2539         }
2540
2541         if(self.teamkill_soundtime)
2542         if(time > self.teamkill_soundtime)
2543         {
2544                 self.teamkill_soundtime = 0;
2545
2546                 entity oldpusher, oldself;
2547
2548                 oldself = self; self = self.teamkill_soundsource;
2549                 oldpusher = self.pusher; self.pusher = oldself;
2550
2551                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2552
2553                 self.pusher = oldpusher;
2554                 self = oldself;
2555         }
2556
2557         if(self.taunt_soundtime)
2558         if(time > self.taunt_soundtime)
2559         {
2560                 self.taunt_soundtime = 0;
2561                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2562         }
2563
2564         target_voicescript_next(self);
2565
2566         // WEAPONTODO: Move into weaponsystem somehow
2567         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2568         if(!self.weapon)
2569                 self.clip_load = self.clip_size = 0;
2570 }
2571
2572 /*
2573 =============
2574 PlayerPostThink
2575
2576 Called every frame for each client after the physics are run
2577 =============
2578 */
2579 .float idlekick_lasttimeleft;
2580 void PlayerPostThink (void)
2581 {
2582         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2583         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2584         {
2585                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2586                 {
2587                         if(self.idlekick_lasttimeleft)
2588                         {
2589                                 self.idlekick_lasttimeleft = 0;
2590                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2591                         }
2592                 }
2593                 else
2594                 {
2595                         float timeleft;
2596                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2597                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2598                         {
2599                                 if(!self.idlekick_lasttimeleft)
2600                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2601                         }
2602                         if(timeleft <= 0)
2603                         {
2604                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2605                                 dropclient(self);
2606                                 return;
2607                         }
2608                         else if(timeleft <= 10)
2609                         {
2610                                 if(timeleft != self.idlekick_lasttimeleft)
2611                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2612                                 self.idlekick_lasttimeleft = timeleft;
2613                         }
2614                 }
2615         }
2616
2617 #ifdef TETRIS
2618         if(self.impulse == 100)
2619                 ImpulseCommands();
2620         if (!TetrisPostFrame())
2621         {
2622 #endif
2623
2624         CheatFrame();
2625
2626         //CheckPlayerJump();
2627
2628         if(IS_PLAYER(self)) {
2629                 CheckRules_Player();
2630                 UpdateChatBubble();
2631                 if (self.impulse)
2632                         ImpulseCommands();
2633                 if (intermission_running)
2634                         return;         // intermission or finale
2635                 GetPressedKeys();
2636         }
2637
2638 #ifdef TETRIS
2639         }
2640 #endif
2641
2642         /*
2643         float i;
2644         for(i = 0; i < 1000; ++i)
2645         {
2646                 vector end;
2647                 end = self.origin + '0 0 1024' + 512 * randomvec();
2648                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2649                 if(trace_fraction < 1)
2650                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2651                 {
2652                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2653                         break;
2654                 }
2655         }
2656         */
2657
2658         if(self.waypointsprite_attachedforcarrier)
2659                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2660
2661         playerdemo_write();
2662
2663         CSQCMODEL_AUTOUPDATE();
2664 }