qcsrc/server/cl_client.qc

   1 void send_CSQC_teamnagger() {
   2         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   3         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   4 }
   5
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(IS_SPEC(to))
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(IS_SPEC(e2))
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74 .string netname_previous;
  75
  76
  77 /*
  78 =============
  79 CheckPlayerModel
  80
  81 Checks if the argument string can be a valid playermodel.
  82 Returns a valid one in doubt.
  83 =============
  84 */
  85 string FallbackPlayerModel;
  86 string CheckPlayerModel(string plyermodel) {
  87         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  88         {
  89                 // note: we cannot summon Don Strunzone here, some player may
  90                 // still have the model string set. In case anyone manages how
  91                 // to change a cvar default, we'll have a small leak here.
  92                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  93         }
  94         // only in right path
  95         if( substring(plyermodel,0,14) != "models/player/")
  96                 return FallbackPlayerModel;
  97         // only good file extensions
  98         if(substring(plyermodel,-4,4) != ".zym")
  99         if(substring(plyermodel,-4,4) != ".dpm")
 100         if(substring(plyermodel,-4,4) != ".iqm")
 101         if(substring(plyermodel,-4,4) != ".md3")
 102         if(substring(plyermodel,-4,4) != ".psk")
 103                 return FallbackPlayerModel;
 104         // forbid the LOD models
 105         if(substring(plyermodel, -9,5) == "_lod1")
 106                 return FallbackPlayerModel;
 107         if(substring(plyermodel, -9,5) == "_lod2")
 108                 return FallbackPlayerModel;
 109         if(plyermodel != strtolower(plyermodel))
 110                 return FallbackPlayerModel;
 111         // also, restrict to server models
 112         if(autocvar_sv_servermodelsonly)
 113         {
 114                 if(!fexists(plyermodel))
 115                         return FallbackPlayerModel;
 116         }
 117         return plyermodel;
 118 }
 119
 120 void setplayermodel(entity e, string modelname)
 121 {
 122         precache_model(modelname);
 123         setmodel(e, modelname);
 124         player_setupanimsformodel();
 125         UpdatePlayerSounds();
 126 }
 127
 128 /*
 129 =============
 130 PutObserverInServer
 131
 132 putting a client as observer in the server
 133 =============
 134 */
 135 void FixPlayermodel();
 136 void PutObserverInServer (void)
 137 {
 138         entity  spot;
 139     self.hud = HUD_NORMAL;
 140
 141         spot = SelectSpawnPoint (TRUE);
 142         if(!spot)
 143                 error("No spawnpoints for observers?!?\n");
 144         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 145
 146         if(IS_REAL_CLIENT(self))
 147         {
 148                 msg_entity = self;
 149                 WriteByte(MSG_ONE, SVC_SETVIEW);
 150                 WriteEntity(MSG_ONE, self);
 151         }
 152
 153         self.frags = FRAGS_SPECTATOR;
 154
 155         MUTATOR_CALLHOOK(MakePlayerObserver);
 156
 157         Portal_ClearAll(self);
 158
 159         if(self.alivetime)
 160         {
 161                 if(!warmup_stage)
 162                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 163                 self.alivetime = 0;
 164         }
 165
 166         if(self.vehicle)
 167                 vehicles_exit(VHEF_RELESE);
 168
 169         WaypointSprite_PlayerDead();
 170
 171         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 172                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 173
 174         if(self.killcount != -666)
 175         {
 176                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 177                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 178                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 179
 180                 if(self.just_joined == FALSE) {
 181                         LogTeamchange(self.playerid, -1, 4);
 182                 } else
 183                         self.just_joined = FALSE;
 184         }
 185
 186         PlayerScore_Clear(self); // clear scores when needed
 187
 188         accuracy_resend(self);
 189
 190         self.spectatortime = time;
 191
 192         self.classname = "observer";
 193         self.iscreature = FALSE;
 194         self.teleportable = TELEPORT_SIMPLE;
 195         self.damagedbycontents = FALSE;
 196         self.health = -666;
 197         self.takedamage = DAMAGE_NO;
 198         self.solid = SOLID_NOT;
 199         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 200         self.flags = FL_CLIENT | FL_NOTARGET;
 201         self.armorvalue = 666;
 202         self.effects = 0;
 203         self.armorvalue = autocvar_g_balance_armor_start;
 204         self.pauserotarmor_finished = 0;
 205         self.pauserothealth_finished = 0;
 206         self.pauseregen_finished = 0;
 207         self.damageforcescale = 0;
 208         self.death_time = 0;
 209         self.respawn_flags = 0;
 210         self.respawn_time = 0;
 211         self.stat_respawn_time = 0;
 212         self.alpha = 0;
 213         self.scale = 0;
 214         self.fade_time = 0;
 215         self.pain_frame = 0;
 216         self.pain_finished = 0;
 217         self.strength_finished = 0;
 218         self.invincible_finished = 0;
 219         self.superweapons_finished = 0;
 220         self.pushltime = 0;
 221         self.istypefrag = 0;
 222         self.think = func_null;
 223         self.nextthink = 0;
 224         self.hook_time = 0;
 225         self.deadflag = DEAD_NO;
 226         self.angles = spot.angles;
 227         self.angles_z = 0;
 228         self.fixangle = TRUE;
 229         self.crouch = FALSE;
 230
 231         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 232         self.prevorigin = self.origin;
 233         self.items = 0;
 234         self.weapons = '0 0 0';
 235         self.model = "";
 236         FixPlayermodel();
 237         setmodel(self, "null");
 238         self.drawonlytoclient = self;
 239
 240         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 241         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 242
 243         self.weapon = 0;
 244         self.weaponname = "";
 245         self.switchingweapon = 0;
 246         self.weaponmodel = "";
 247         self.weaponentity = world;
 248         self.exteriorweaponentity = world;
 249         self.killcount = -666;
 250         self.velocity = '0 0 0';
 251         self.avelocity = '0 0 0';
 252         self.punchangle = '0 0 0';
 253         self.punchvector = '0 0 0';
 254         self.oldvelocity = self.velocity;
 255         self.fire_endtime = -1;
 256 }
 257
 258 .float model_randomizer;
 259 void FixPlayermodel()
 260 {
 261         string defaultmodel;
 262         float defaultskin, chmdl, oldskin, n, i;
 263         vector m1, m2;
 264
 265         defaultmodel = "";
 266         defaultskin = 0;
 267         chmdl = FALSE;
 268
 269         if(autocvar_sv_defaultcharacter == 1)
 270         {
 271                 if(teamplay)
 272                 {
 273                         string s;
 274                         s = Static_Team_ColorName_Lower(self.team);
 275                         if(s != "neutral")
 276                         {
 277                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 278                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 279                         }
 280                 }
 281
 282                 if(defaultmodel == "")
 283                 {
 284                         defaultmodel = autocvar_sv_defaultplayermodel;
 285                         defaultskin = autocvar_sv_defaultplayerskin;
 286                 }
 287
 288                 n = tokenize_console(defaultmodel);
 289                 if(n > 0)
 290                 {
 291                         defaultmodel = argv(floor(n * self.model_randomizer));
 292                         // However, do NOT randomize if the player-selected model is in the list.
 293                         for (i = 0; i < n; ++i)
 294                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 295                                         defaultmodel = argv(i);
 296                 }
 297
 298                 i = strstrofs(defaultmodel, ":", 0);
 299                 if(i >= 0)
 300                 {
 301                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 302                         defaultmodel = substring(defaultmodel, 0, i);
 303                 }
 304         }
 305
 306         if(defaultmodel != "")
 307         {
 308                 if (defaultmodel != self.model)
 309                 {
 310                         m1 = self.mins;
 311                         m2 = self.maxs;
 312                         setplayermodel (self, defaultmodel);
 313                         setsize (self, m1, m2);
 314                         chmdl = TRUE;
 315                 }
 316
 317                 oldskin = self.skin;
 318                 self.skin = defaultskin;
 319         } else {
 320                 if (self.playermodel != self.model || self.playermodel == "")
 321                 {
 322                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 323                         m1 = self.mins;
 324                         m2 = self.maxs;
 325                         setplayermodel (self, self.playermodel);
 326                         setsize (self, m1, m2);
 327                         chmdl = TRUE;
 328                 }
 329
 330                 oldskin = self.skin;
 331                 self.skin = stof(self.playerskin);
 332         }
 333
 334         if(chmdl || oldskin != self.skin) // model or skin has changed
 335         {
 336                 self.species = player_getspecies(); // update species
 337                 UpdatePlayerSounds(); // update skin sounds
 338         }
 339
 340         if(!teamplay)
 341                 if(strlen(autocvar_sv_defaultplayercolors))
 342                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 343                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 344 }
 345
 346 /*
 347 =============
 348 PutClientInServer
 349
 350 Called when a client spawns in the server
 351 =============
 352 */
 353 void PutClientInServer (void)
 354 {
 355         if(IS_BOT_CLIENT(self))
 356                 self.classname = "player";
 357         else if(IS_REAL_CLIENT(self))
 358         {
 359                 msg_entity = self;
 360                 WriteByte(MSG_ONE, SVC_SETVIEW);
 361                 WriteEntity(MSG_ONE, self);
 362         }
 363
 364         // reset player keys
 365         self.itemkeys = 0;
 366
 367         MUTATOR_CALLHOOK(PutClientInServer);
 368
 369         if(gameover)
 370                 self.classname = "observer";
 371
 372         if(IS_PLAYER(self))
 373         {
 374                 entity spot, oldself;
 375                 float j;
 376
 377                 accuracy_resend(self);
 378
 379                 if(self.team < 0)
 380                         JoinBestTeam(self, FALSE, TRUE);
 381
 382                 spot = SelectSpawnPoint (FALSE);
 383                 if(!spot)
 384                 {
 385                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 386                         return; // spawn failed
 387                 }
 388
 389                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 390
 391                 if(self.vehicle)
 392                         vehicles_exit(VHEF_RELESE);
 393
 394                 self.classname = "player";
 395                 self.wasplayer = TRUE;
 396                 self.iscreature = TRUE;
 397                 self.teleportable = TELEPORT_NORMAL;
 398                 self.damagedbycontents = TRUE;
 399                 self.movetype = MOVETYPE_WALK;
 400                 self.solid = SOLID_SLIDEBOX;
 401                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 402                 if(autocvar_g_playerclip_collisions)
 403                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 404                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 405                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 406                 self.frags = FRAGS_PLAYER;
 407                 if(INDEPENDENT_PLAYERS)
 408                         MAKE_INDEPENDENT_PLAYER(self);
 409                 self.flags = FL_CLIENT;
 410                 if(autocvar__notarget)
 411                         self.flags |= FL_NOTARGET;
 412                 self.takedamage = DAMAGE_AIM;
 413                 self.effects = 0;
 414                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 415                 self.air_finished = time + 12;
 416                 self.dmg = 2;
 417                 if(autocvar_g_balance_nex_charge)
 418                 {
 419                         if(autocvar_g_balance_nex_secondary_chargepool)
 420                                 self.nex_chargepool_ammo = 1;
 421                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 422                 }
 423
 424                 if(warmup_stage)
 425                 {
 426                         self.ammo_shells = warmup_start_ammo_shells;
 427                         self.ammo_nails = warmup_start_ammo_nails;
 428                         self.ammo_rockets = warmup_start_ammo_rockets;
 429                         self.ammo_cells = warmup_start_ammo_cells;
 430                         self.ammo_fuel = warmup_start_ammo_fuel;
 431                         self.health = warmup_start_health;
 432                         self.armorvalue = warmup_start_armorvalue;
 433                         self.weapons = WARMUP_START_WEAPONS;
 434                 }
 435                 else
 436                 {
 437                         self.ammo_shells = start_ammo_shells;
 438                         self.ammo_nails = start_ammo_nails;
 439                         self.ammo_rockets = start_ammo_rockets;
 440                         self.ammo_cells = start_ammo_cells;
 441                         self.ammo_fuel = start_ammo_fuel;
 442                         self.health = start_health;
 443                         self.armorvalue = start_armorvalue;
 444                         self.weapons = start_weapons;
 445                 }
 446
 447                 if(self.weapons & WEPSET_SUPERWEAPONS)
 448                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 449                 else
 450                         self.superweapons_finished = 0;
 451
 452                 if(g_weaponarena_random)
 453                 {
 454                         if(g_weaponarena_random_with_laser)
 455                                 self.weapons &= ~WEPSET_LASER;
 456                         W_RandomWeapons(self, g_weaponarena_random);
 457                         if(g_weaponarena_random_with_laser)
 458                                 self.weapons |= WEPSET_LASER;
 459                 }
 460
 461                 self.items = start_items;
 462
 463                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 464                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 465                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 466                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 467                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 468                 //extend the pause of rotting if client was reset at the beginning of the countdown
 469                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 470                         self.spawnshieldtime += game_starttime - time;
 471                         self.pauserotarmor_finished += game_starttime - time;
 472                         self.pauserothealth_finished += game_starttime - time;
 473                         self.pauseregen_finished += game_starttime - time;
 474                 }
 475                 self.damageforcescale = 2;
 476                 self.death_time = 0;
 477                 self.respawn_flags = 0;
 478                 self.respawn_time = 0;
 479                 self.stat_respawn_time = 0;
 480                 self.scale = 0;
 481                 self.fade_time = 0;
 482                 self.pain_frame = 0;
 483                 self.pain_finished = 0;
 484                 self.strength_finished = 0;
 485                 self.invincible_finished = 0;
 486                 self.pushltime = 0;
 487                 // players have no think function
 488                 self.think = func_null;
 489                 self.nextthink = 0;
 490                 self.hook_time = 0;
 491                 self.dmg_team = 0;
 492                 self.ballistics_density = autocvar_g_ballistics_density_player;
 493
 494                 self.metertime = 0;
 495
 496                 self.deadflag = DEAD_NO;
 497
 498                 self.angles = spot.angles;
 499
 500                 self.angles_z = 0; // never spawn tilted even if the spot says to
 501                 self.fixangle = TRUE; // turn this way immediately
 502                 self.velocity = '0 0 0';
 503                 self.avelocity = '0 0 0';
 504                 self.punchangle = '0 0 0';
 505                 self.punchvector = '0 0 0';
 506                 self.oldvelocity = self.velocity;
 507                 self.fire_endtime = -1;
 508
 509                 entity spawnevent = spawn();
 510                 spawnevent.owner = self;
 511                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 512
 513                 // Cut off any still running player sounds.
 514                 stopsound(self, CH_PLAYER_SINGLE);
 515
 516                 self.model = "";
 517                 FixPlayermodel();
 518                 self.drawonlytoclient = world;
 519
 520                 self.crouch = FALSE;
 521                 self.view_ofs = PL_VIEW_OFS;
 522                 setsize (self, PL_MIN, PL_MAX);
 523                 self.spawnorigin = spot.origin;
 524                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 525                 // don't reset back to last position, even if new position is stuck in solid
 526                 self.oldorigin = self.origin;
 527                 self.prevorigin = self.origin;
 528                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 529                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 530         self.hud = HUD_NORMAL;
 531
 532                 self.event_damage = PlayerDamage;
 533
 534                 self.bot_attack = TRUE;
 535                 self.monster_attack = TRUE;
 536
 537                 self.spider_slowness = 0;
 538
 539                 self.statdraintime = time + 5;
 540                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 541
 542                 if(self.killcount == -666) {
 543                         PlayerScore_Clear(self);
 544                         self.killcount = 0;
 545                 }
 546
 547                 CL_SpawnWeaponentity();
 548                 self.alpha = default_player_alpha;
 549                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 550                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 551
 552                 self.speedrunning = FALSE;
 553
 554                 //stuffcmd(self, "chase_active 0");
 555                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 556
 557                 target_voicescript_clear(self);
 558
 559                 // reset fields the weapons may use
 560                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 561                 {
 562                         weapon_action(j, WR_RESETPLAYER);
 563
 564                         // all weapons must be fully loaded when we spawn
 565                         entity e;
 566                         e = get_weaponinfo(j);
 567                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 568                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 569                 }
 570
 571                 oldself = self;
 572                 self = spot;
 573                         activator = oldself;
 574                                 string s;
 575                                 s = self.target;
 576                                 self.target = string_null;
 577                                 SUB_UseTargets();
 578                                 self.target = s;
 579                         activator = world;
 580                 self = oldself;
 581
 582                 spawn_spot = spot;
 583                 MUTATOR_CALLHOOK(PlayerSpawn);
 584
 585                 if(autocvar_spawn_debug)
 586                 {
 587                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 588                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 589                 }
 590
 591                 self.switchweapon = w_getbestweapon(self);
 592                 self.cnt = -1; // W_LastWeapon will not complain
 593                 self.weapon = 0;
 594                 self.weaponname = "";
 595                 self.switchingweapon = 0;
 596
 597                 if(!warmup_stage)
 598                         if(!self.alivetime)
 599                                 self.alivetime = time;
 600
 601                 antilag_clear(self);
 602         }
 603         else if(IS_OBSERVER(self))
 604         {
 605                 PutObserverInServer ();
 606         }
 607 }
 608
 609 .float ebouncefactor, ebouncestop; // electro's values
 610 // TODO do we need all these fields, or should we stop autodetecting runtime
 611 // changes and just have a console command to update this?
 612 float ClientInit_SendEntity(entity to, float sf)
 613 {
 614         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 615         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 616         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 617         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 618         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 619         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 620         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 621         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 622         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 623         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 624         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 628         if(sv_foginterval && world.fog != "")
 629                 WriteString(MSG_ENTITY, world.fog);
 630         else
 631                 WriteString(MSG_ENTITY, "");
 632         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 633         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 634         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 635         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 636         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 637         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 638         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 639         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 640         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 641         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 642         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 643         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 644         return TRUE;
 645 }
 646
 647 void ClientInit_CheckUpdate()
 648 {
 649         self.nextthink = time;
 650         if(self.count != autocvar_g_balance_armor_blockpercent)
 651         {
 652                 self.count = autocvar_g_balance_armor_blockpercent;
 653                 self.SendFlags |= 1;
 654         }
 655         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 656         {
 657                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 658                 self.SendFlags |= 1;
 659         }
 660         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 661         {
 662                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 663                 self.SendFlags |= 1;
 664         }
 665         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 666         {
 667                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 668                 self.SendFlags |= 1;
 669         }
 670         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 671         {
 672                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 673                 self.SendFlags |= 1;
 674         }
 675 }
 676
 677 void ClientInit_Spawn()
 678 {
 679         entity o;
 680         entity e;
 681         e = spawn();
 682         e.classname = "clientinit";
 683         e.think = ClientInit_CheckUpdate;
 684         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 685
 686         o = self;
 687         self = e;
 688         ClientInit_CheckUpdate();
 689         self = o;
 690 }
 691
 692 /*
 693 =============
 694 SetNewParms
 695 =============
 696 */
 697 void SetNewParms (void)
 698 {
 699         // initialize parms for a new player
 700         parm1 = -(86400 * 366);
 701 }
 702
 703 /*
 704 =============
 705 SetChangeParms
 706 =============
 707 */
 708 void SetChangeParms (void)
 709 {
 710         // save parms for level change
 711         parm1 = self.parm_idlesince - time;
 712 }
 713
 714 /*
 715 =============
 716 DecodeLevelParms
 717 =============
 718 */
 719 void DecodeLevelParms (void)
 720 {
 721         // load parms
 722         self.parm_idlesince = parm1;
 723         if(self.parm_idlesince == -(86400 * 366))
 724                 self.parm_idlesince = time;
 725
 726         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 727         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 728 }
 729
 730 /*
 731 =============
 732 ClientKill
 733
 734 Called when a client types 'kill' in the console
 735 =============
 736 */
 737
 738 .float clientkill_nexttime;
 739 void ClientKill_Now_TeamChange()
 740 {
 741         if(self.killindicator_teamchange == -1)
 742         {
 743                 JoinBestTeam( self, FALSE, TRUE );
 744         }
 745         else if(self.killindicator_teamchange == -2)
 746         {
 747                 if(blockSpectators)
 748                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 749                 PutObserverInServer();
 750         }
 751         else
 752                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 753         self.killindicator_teamchange = 0;
 754 }
 755
 756 void ClientKill_Now()
 757 {
 758         if(self.vehicle)
 759         {
 760             vehicles_exit(VHEF_RELESE);
 761             if(!self.killindicator_teamchange)
 762             {
 763             self.vehicle_health = -1;
 764             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 765             }
 766         }
 767
 768         if(self.killindicator && !wasfreed(self.killindicator))
 769                 remove(self.killindicator);
 770
 771         self.killindicator = world;
 772
 773         if(self.killindicator_teamchange)
 774                 ClientKill_Now_TeamChange();
 775
 776         // in any case:
 777         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 778
 779         // now I am sure the player IS dead
 780 }
 781 void KillIndicator_Think()
 782 {
 783         if (gameover)
 784         {
 785                 self.owner.killindicator = world;
 786                 remove(self);
 787                 return;
 788         }
 789
 790         if (self.owner.alpha < 0 && !self.owner.vehicle)
 791         {
 792                 self.owner.killindicator = world;
 793                 remove(self);
 794                 return;
 795         }
 796
 797         if(self.cnt <= 0)
 798         {
 799                 self = self.owner;
 800                 ClientKill_Now(); // no oldself needed
 801                 return;
 802         }
 803     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 804     {
 805         self.nextthink = time + 1;
 806         self.cnt -= 1;
 807     }
 808         else
 809         {
 810                 if(self.cnt <= 10)
 811                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 812                 if(IS_REAL_CLIENT(self.owner))
 813                 {
 814                         if(self.cnt <= 10)
 815                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 816                 }
 817                 self.nextthink = time + 1;
 818                 self.cnt -= 1;
 819         }
 820 }
 821
 822 float clientkilltime;
 823 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 824 {
 825         float killtime;
 826         float starttime;
 827         entity e;
 828
 829         if (gameover)
 830                 return;
 831
 832         killtime = autocvar_g_balance_kill_delay;
 833
 834         if(g_race_qualifying || g_cts)
 835                 killtime = 0;
 836
 837     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 838     {
 839                 remove(self.killindicator);
 840                 self.killindicator = world;
 841
 842         ClientKill_Now(); // allow instant kill in this case
 843         return;
 844     }
 845
 846         self.killindicator_teamchange = targetteam;
 847
 848     if(!self.killindicator)
 849         {
 850                 if(self.deadflag == DEAD_NO)
 851                 {
 852                         killtime = max(killtime, self.clientkill_nexttime - time);
 853                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 854                 }
 855
 856                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 857                 {
 858                         ClientKill_Now();
 859                 }
 860                 else
 861                 {
 862                         starttime = max(time, clientkilltime);
 863
 864                         self.killindicator = spawn();
 865                         self.killindicator.owner = self;
 866                         self.killindicator.scale = 0.5;
 867                         setattachment(self.killindicator, self, "");
 868                         setorigin(self.killindicator, '0 0 52');
 869                         self.killindicator.think = KillIndicator_Think;
 870                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 871                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 872                         self.killindicator.cnt = ceil(killtime);
 873                         self.killindicator.count = bound(0, ceil(killtime), 10);
 874                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 875
 876                         for(e = world; (e = find(e, classname, "body")) != world; )
 877                         {
 878                                 if(e.enemy != self)
 879                                         continue;
 880                                 e.killindicator = spawn();
 881                                 e.killindicator.owner = e;
 882                                 e.killindicator.scale = 0.5;
 883                                 setattachment(e.killindicator, e, "");
 884                                 setorigin(e.killindicator, '0 0 52');
 885                                 e.killindicator.think = KillIndicator_Think;
 886                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 887                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 888                                 e.killindicator.cnt = ceil(killtime);
 889                         }
 890                         self.lip = 0;
 891                 }
 892         }
 893         if(self.killindicator)
 894         {
 895                 if(targetteam == 0) // just die
 896                 {
 897                         self.killindicator.colormod = '0 0 0';
 898                         if(IS_REAL_CLIENT(self))
 899                         if(self.killindicator.cnt > 0)
 900                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 901                 }
 902                 else if(targetteam == -1) // auto
 903                 {
 904                         self.killindicator.colormod = '0 1 0';
 905                         if(IS_REAL_CLIENT(self))
 906                         if(self.killindicator.cnt > 0)
 907                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 908                 }
 909                 else if(targetteam == -2) // spectate
 910                 {
 911                         self.killindicator.colormod = '0.5 0.5 0.5';
 912                         if(IS_REAL_CLIENT(self))
 913                         if(self.killindicator.cnt > 0)
 914                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 915                 }
 916                 else
 917                 {
 918                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 919                         if(IS_REAL_CLIENT(self))
 920                         if(self.killindicator.cnt > 0)
 921                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 922                 }
 923         }
 924
 925 }
 926
 927 void ClientKill (void)
 928 {
 929         if(gameover) return;
 930         if(self.player_blocked) return;
 931         if(self.freezetag_frozen) return;
 932
 933         ClientKill_TeamChange(0);
 934 }
 935
 936 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 937 {
 938     e.killindicator = spawn();
 939     e.killindicator.owner = e;
 940     e.killindicator.think = KillIndicator_Think;
 941     e.killindicator.nextthink = time + (e.lip) * 0.05;
 942     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 943     e.killindicator.health = 1; // this is used to indicate that it should be silent
 944     e.lip = 0;
 945 }
 946
 947 void FixClientCvars(entity e)
 948 {
 949         // send prediction settings to the client
 950         stuffcmd(e, "\nin_bindmap 0 0\n");
 951         if(g_race || g_cts)
 952                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 953         if(autocvar_g_antilag == 3) // client side hitscan
 954                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 955         if(autocvar_sv_gentle)
 956                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 957         /*
 958          * we no longer need to stuff this. Remove this comment block if you feel
 959          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 960         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 961         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 962         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 963         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 964         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 965         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 966         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 967         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 968         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 969         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 970         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 971         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 972         stuffcmd(e, "cl_movement_edgefriction 1\n");
 973          */
 974 }
 975
 976 float PlayerInIDList(entity p, string idlist)
 977 {
 978         float n, i;
 979         string s;
 980
 981         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 982         if (!p.crypto_idfp)
 983                 return 0;
 984
 985         // this function allows abbreviated player IDs too!
 986         n = tokenize_console(idlist);
 987         for(i = 0; i < n; ++i)
 988         {
 989                 s = argv(i);
 990                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
 991                         return 1;
 992         }
 993
 994         return 0;
 995 }
 996
 997 /*
 998 =============
 999 ClientConnect
1000
1001 Called when a client connects to the server
1002 =============
1003 */
1004 void DecodeLevelParms (void);
1005 //void dom_player_join_team(entity pl);
1006 void set_dom_state(entity e);
1007 void ClientConnect (void)
1008 {
1009         float t;
1010
1011         if(IS_CLIENT(self))
1012         {
1013                 print("Warning: ClientConnect, but already connected!\n");
1014                 return;
1015         }
1016
1017         if(Ban_MaybeEnforceBanOnce(self))
1018                 return;
1019
1020         DecodeLevelParms();
1021
1022 #ifdef WATERMARK
1023         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1024 #endif
1025
1026         self.classname = "player_joining";
1027
1028         self.flags = FL_CLIENT;
1029         self.version_nagtime = time + 10 + random() * 10;
1030
1031         if(player_count<0)
1032         {
1033                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1034                 player_count = 0;
1035         }
1036
1037         PlayerScore_Attach(self);
1038         ClientData_Attach();
1039         accuracy_init(self);
1040
1041         bot_clientconnect();
1042
1043         playerdemo_init();
1044
1045         anticheat_init();
1046
1047         // identify the right forced team
1048         if(autocvar_g_campaign)
1049         {
1050                 if(IS_REAL_CLIENT(self)) // only players, not bots
1051                 {
1052                         switch(autocvar_g_campaign_forceteam)
1053                         {
1054                                 case 1: self.team_forced = NUM_TEAM_1; break;
1055                                 case 2: self.team_forced = NUM_TEAM_2; break;
1056                                 case 3: self.team_forced = NUM_TEAM_3; break;
1057                                 case 4: self.team_forced = NUM_TEAM_4; break;
1058                                 default: self.team_forced = 0;
1059                         }
1060                 }
1061         }
1062         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1063                 self.team_forced = NUM_TEAM_1;
1064         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1065                 self.team_forced = NUM_TEAM_2;
1066         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1067                 self.team_forced = NUM_TEAM_3;
1068         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1069                 self.team_forced = NUM_TEAM_4;
1070         else if(autocvar_g_forced_team_otherwise == "red")
1071                 self.team_forced = NUM_TEAM_1;
1072         else if(autocvar_g_forced_team_otherwise == "blue")
1073                 self.team_forced = NUM_TEAM_2;
1074         else if(autocvar_g_forced_team_otherwise == "yellow")
1075                 self.team_forced = NUM_TEAM_3;
1076         else if(autocvar_g_forced_team_otherwise == "pink")
1077                 self.team_forced = NUM_TEAM_4;
1078         else if(autocvar_g_forced_team_otherwise == "spectate")
1079                 self.team_forced = -1;
1080         else if(autocvar_g_forced_team_otherwise == "spectator")
1081                 self.team_forced = -1;
1082         else
1083                 self.team_forced = 0;
1084
1085         if(!teamplay)
1086                 if(self.team_forced > 0)
1087                         self.team_forced = 0;
1088
1089         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1090
1091         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1092                 self.classname = "observer";
1093         } else {
1094                 if(teamplay)
1095                 {
1096                         if(autocvar_g_balance_teams)
1097                         {
1098                                 self.classname = "player";
1099                                 campaign_bots_may_start = 1;
1100                         }
1101                         else
1102                         {
1103                                 self.classname = "observer"; // do it anyway
1104                         }
1105                 }
1106                 else
1107                 {
1108                         self.classname = "player";
1109                         campaign_bots_may_start = 1;
1110                 }
1111         }
1112
1113         self.playerid = (playerid_last = playerid_last + 1);
1114
1115         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1116
1117     if(IS_BOT_CLIENT(self))
1118         PlayerStats_AddPlayer(self);
1119
1120         if(autocvar_sv_eventlog)
1121                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1122
1123         LogTeamchange(self.playerid, self.team, 1);
1124
1125         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1126
1127         self.netname_previous = strzone(self.netname);
1128
1129         if(IS_PLAYER(self) && teamplay)
1130                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1131         else
1132                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1133
1134         stuffcmd(self, strcat(clientstuff, "\n"));
1135         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1136
1137         FixClientCvars(self);
1138
1139         // spawnfunc_waypoint sprites
1140         WaypointSprite_InitClient(self);
1141
1142         // Wazat's grappling hook
1143         SetGrappleHookBindings();
1144
1145         // get version info from player
1146         stuffcmd(self, "cmd clientversion $gameversion\n");
1147
1148         // get other cvars from player
1149         GetCvars(0);
1150
1151         // notify about available teams
1152         if(teamplay)
1153         {
1154                 CheckAllowedTeams(self);
1155                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1156                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1157         }
1158         else
1159                 stuffcmd(self, "set _teams_available 0\n");
1160
1161         attach_entcs();
1162
1163         bot_relinkplayerlist();
1164
1165         self.spectatortime = time;
1166         if(blockSpectators)
1167         {
1168                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1169         }
1170
1171         self.jointime = time;
1172         self.allowed_timeouts = autocvar_sv_timeout_number;
1173
1174         if(IS_REAL_CLIENT(self))
1175         {
1176                 if(!autocvar_g_campaign)
1177                 {
1178                         self.motd_actived_time = -1;
1179                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1180                 }
1181
1182                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1183                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1184         }
1185
1186         if(!sv_foginterval && world.fog != "")
1187                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1188
1189         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1190         {
1191                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1192                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1193         }
1194         else
1195                 self.hitplotfh = -1;
1196
1197         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1198                 send_CSQC_teamnagger();
1199
1200         CheatInitClient();
1201
1202         CSQCMODEL_AUTOINIT();
1203
1204         self.model_randomizer = random();
1205
1206         if(IS_REAL_CLIENT(self))
1207                 sv_notice_join();
1208
1209         MUTATOR_CALLHOOK(ClientConnect);
1210 }
1211 /*
1212 =============
1213 ClientDisconnect
1214
1215 Called when a client disconnects from the server
1216 =============
1217 */
1218 .entity chatbubbleentity;
1219 void ReadyCount();
1220 void ClientDisconnect (void)
1221 {
1222         if(self.vehicle)
1223             vehicles_exit(VHEF_RELESE);
1224
1225         if (!IS_CLIENT(self))
1226         {
1227                 print("Warning: ClientDisconnect without ClientConnect\n");
1228                 return;
1229         }
1230
1231         PlayerStats_AddGlobalInfo(self);
1232
1233         CheatShutdownClient();
1234
1235         if(self.hitplotfh >= 0)
1236         {
1237                 fclose(self.hitplotfh);
1238                 self.hitplotfh = -1;
1239         }
1240
1241         anticheat_report();
1242         anticheat_shutdown();
1243
1244         playerdemo_shutdown();
1245
1246         bot_clientdisconnect();
1247
1248         if(self.entcs)
1249                 detach_entcs();
1250
1251         if(autocvar_sv_eventlog)
1252                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1253
1254         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1255
1256         MUTATOR_CALLHOOK(ClientDisconnect);
1257
1258         Portal_ClearAll(self);
1259
1260         RemoveGrapplingHook(self);
1261
1262         // Here, everything has been done that requires this player to be a client.
1263
1264         self.flags &= ~FL_CLIENT;
1265
1266         if (self.chatbubbleentity)
1267                 remove (self.chatbubbleentity);
1268
1269         if (self.killindicator)
1270                 remove (self.killindicator);
1271
1272         WaypointSprite_PlayerGone();
1273
1274         bot_relinkplayerlist();
1275
1276         accuracy_free(self);
1277         ClientData_Detach();
1278         PlayerScore_Detach(self);
1279
1280         if(self.netname_previous)
1281                 strunzone(self.netname_previous);
1282         if(self.clientstatus)
1283                 strunzone(self.clientstatus);
1284         if(self.weaponorder_byimpulse)
1285                 strunzone(self.weaponorder_byimpulse);
1286
1287         ClearPlayerSounds();
1288
1289         if(self.personal)
1290                 remove(self.personal);
1291
1292         self.playerid = 0;
1293         ReadyCount();
1294
1295         // free cvars
1296         GetCvars(-1);
1297 }
1298
1299 .float BUTTON_CHAT;
1300 void ChatBubbleThink()
1301 {
1302         self.nextthink = time;
1303         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1304         {
1305                 if(self.owner) // but why can that ever be world?
1306                         self.owner.chatbubbleentity = world;
1307                 remove(self);
1308                 return;
1309         }
1310         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1311 #ifdef TETRIS
1312                 || self.owner.tetris_on
1313 #endif
1314         )
1315                 self.model = self.mdl;
1316         else
1317                 self.model = "";
1318 }
1319
1320 void UpdateChatBubble()
1321 {
1322         if (self.alpha < 0)
1323                 return;
1324         // spawn a chatbubble entity if needed
1325         if (!self.chatbubbleentity)
1326         {
1327                 self.chatbubbleentity = spawn();
1328                 self.chatbubbleentity.owner = self;
1329                 self.chatbubbleentity.exteriormodeltoclient = self;
1330                 self.chatbubbleentity.think = ChatBubbleThink;
1331                 self.chatbubbleentity.nextthink = time;
1332                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1333                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1334                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1335                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1336                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1337                 self.chatbubbleentity.model = "";
1338                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1339         }
1340 }
1341
1342
1343 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1344 // added to the model skins
1345 /*void UpdateColorModHack()
1346 {
1347         float c;
1348         c = self.clientcolors & 15;
1349         // LordHavoc: only bothering to support white, green, red, yellow, blue
1350              if (!teamplay) self.colormod = '0 0 0';
1351         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1352         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1353         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1354         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1355         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1356         else self.colormod = '1 1 1';
1357 }*/
1358
1359 void respawn(void)
1360 {
1361         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1362         {
1363                 self.solid = SOLID_NOT;
1364                 self.takedamage = DAMAGE_NO;
1365                 self.movetype = MOVETYPE_FLY;
1366                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1367                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1368                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1369                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1370                 if(autocvar_g_respawn_ghosts_maxtime)
1371                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1372         }
1373
1374         CopyBody(1);
1375
1376         self.effects |= EF_NODRAW; // prevent another CopyBody
1377         PutClientInServer();
1378 }
1379
1380 void play_countdown(float finished, string samp)
1381 {
1382         if(IS_REAL_CLIENT(self))
1383                 if(floor(finished - time - frametime) != floor(finished - time))
1384                         if(finished - time < 6)
1385                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1386 }
1387
1388 void player_powerups (void)
1389 {
1390         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1391         olditems = self.items;
1392
1393         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1394                 self.modelflags |= MF_ROCKET;
1395         else
1396                 self.modelflags &= ~MF_ROCKET;
1397
1398         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1399
1400         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1401                 return;
1402
1403         Fire_ApplyDamage(self);
1404         Fire_ApplyEffect(self);
1405
1406         if (!g_minstagib)
1407         {
1408                 if (self.items & IT_STRENGTH)
1409                 {
1410                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1411                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1412                         if (time > self.strength_finished)
1413                         {
1414                                 self.items = self.items - (self.items & IT_STRENGTH);
1415                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1416                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1417                         }
1418                 }
1419                 else
1420                 {
1421                         if (time < self.strength_finished)
1422                         {
1423                                 self.items = self.items | IT_STRENGTH;
1424                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1425                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1426                         }
1427                 }
1428                 if (self.items & IT_INVINCIBLE)
1429                 {
1430                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1431                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1432                         if (time > self.invincible_finished)
1433                         {
1434                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1435                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1436                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1437                         }
1438                 }
1439                 else
1440                 {
1441                         if (time < self.invincible_finished)
1442                         {
1443                                 self.items = self.items | IT_INVINCIBLE;
1444                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1445                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1446                         }
1447                 }
1448                 if (self.items & IT_SUPERWEAPON)
1449                 {
1450                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1451                         {
1452                                 self.superweapons_finished = 0;
1453                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1454                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1455                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1456                         }
1457                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1458                         {
1459                                 // don't let them run out
1460                         }
1461                         else
1462                         {
1463                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1464                                 if (time > self.superweapons_finished)
1465                                 {
1466                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1467                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1468                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1469                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1470                                 }
1471                         }
1472                 }
1473                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1474                 {
1475                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1476                         {
1477                                 self.items = self.items | IT_SUPERWEAPON;
1478                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1479                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1480                         }
1481                         else
1482                         {
1483                                 self.superweapons_finished = 0;
1484                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1485                         }
1486                 }
1487                 else
1488                 {
1489                         self.superweapons_finished = 0;
1490                 }
1491         }
1492
1493         if(autocvar_g_nodepthtestplayers)
1494                 self.effects = self.effects | EF_NODEPTHTEST;
1495
1496         if(autocvar_g_fullbrightplayers)
1497                 self.effects = self.effects | EF_FULLBRIGHT;
1498
1499         if (time >= game_starttime)
1500         if (time < self.spawnshieldtime)
1501                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1502
1503         MUTATOR_CALLHOOK(PlayerPowerups);
1504 }
1505
1506 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1507 {
1508         if(current > stable)
1509                 return current;
1510         else if(current > stable - 0.25) // when close enough, "snap"
1511                 return stable;
1512         else
1513                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1514 }
1515
1516 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1517 {
1518         if(current < stable)
1519                 return current;
1520         else if(current < stable + 0.25) // when close enough, "snap"
1521                 return stable;
1522         else
1523                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1524 }
1525
1526 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1527 {
1528         if(current > rotstable)
1529         {
1530                 if(rotframetime > 0)
1531                 {
1532                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1533                         current = max(rotstable, current - rotlinear * rotframetime);
1534                 }
1535         }
1536         else if(current < regenstable)
1537         {
1538                 if(regenframetime > 0)
1539                 {
1540                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1541                         current = min(regenstable, current + regenlinear * regenframetime);
1542                 }
1543         }
1544
1545         if(current > limit)
1546                 current = limit;
1547
1548         return current;
1549 }
1550
1551 void player_regen (void)
1552 {
1553         float max_mod, regen_mod, rot_mod, limit_mod;
1554         max_mod = regen_mod = rot_mod = limit_mod = 1;
1555         regen_mod_max = max_mod;
1556         regen_mod_regen = regen_mod;
1557         regen_mod_rot = rot_mod;
1558         regen_mod_limit = limit_mod;
1559         if(!MUTATOR_CALLHOOK(PlayerRegen))
1560         {
1561                 float minh, mina, maxh, maxa, limith, limita;
1562                 maxh = autocvar_g_balance_health_rotstable;
1563                 maxa = autocvar_g_balance_armor_rotstable;
1564                 minh = autocvar_g_balance_health_regenstable;
1565                 mina = autocvar_g_balance_armor_regenstable;
1566                 limith = autocvar_g_balance_health_limit;
1567                 limita = autocvar_g_balance_armor_limit;
1568
1569                 max_mod = regen_mod_max;
1570                 regen_mod = regen_mod_regen;
1571                 rot_mod = regen_mod_rot;
1572                 limit_mod = regen_mod_limit;
1573
1574                 maxh = maxh * max_mod;
1575                 minh = minh * max_mod;
1576                 limith = limith * limit_mod;
1577                 limita = limita * limit_mod;
1578
1579                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1580                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1581         }
1582
1583         // if player rotted to death...  die!
1584         // check this outside above checks, as player may still be able to rot to death
1585         if(self.health < 1)
1586                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1587
1588         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1589         {
1590                 float minf, maxf, limitf;
1591
1592                 maxf = autocvar_g_balance_fuel_rotstable;
1593                 minf = autocvar_g_balance_fuel_regenstable;
1594                 limitf = autocvar_g_balance_fuel_limit;
1595
1596                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1597         }
1598 }
1599
1600 float zoomstate_set;
1601 void SetZoomState(float z)
1602 {
1603         if(z != self.zoomstate)
1604         {
1605                 self.zoomstate = z;
1606                 ClientData_Touch(self);
1607         }
1608         zoomstate_set = 1;
1609 }
1610
1611 void GetPressedKeys(void) {
1612         MUTATOR_CALLHOOK(GetPressedKeys);
1613         if (self.movement_x > 0) // get if movement keys are pressed
1614         {       // forward key pressed
1615                 self.pressedkeys |= KEY_FORWARD;
1616                 self.pressedkeys &= ~KEY_BACKWARD;
1617         }
1618         else if (self.movement_x < 0)
1619         {       // backward key pressed
1620                 self.pressedkeys |= KEY_BACKWARD;
1621                 self.pressedkeys &= ~KEY_FORWARD;
1622         }
1623         else
1624         {       // no x input
1625                 self.pressedkeys &= ~KEY_FORWARD;
1626                 self.pressedkeys &= ~KEY_BACKWARD;
1627         }
1628
1629         if (self.movement_y > 0)
1630         {       // right key pressed
1631                 self.pressedkeys |= KEY_RIGHT;
1632                 self.pressedkeys &= ~KEY_LEFT;
1633         }
1634         else if (self.movement_y < 0)
1635         {       // left key pressed
1636                 self.pressedkeys |= KEY_LEFT;
1637                 self.pressedkeys &= ~KEY_RIGHT;
1638         }
1639         else
1640         {       // no y input
1641                 self.pressedkeys &= ~KEY_RIGHT;
1642                 self.pressedkeys &= ~KEY_LEFT;
1643         }
1644
1645         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1646                 self.pressedkeys |= KEY_JUMP;
1647         else
1648                 self.pressedkeys &= ~KEY_JUMP;
1649         if (self.BUTTON_CROUCH)
1650                 self.pressedkeys |= KEY_CROUCH;
1651         else
1652                 self.pressedkeys &= ~KEY_CROUCH;
1653
1654         if (self.BUTTON_ATCK)
1655                 self.pressedkeys |= KEY_ATCK;
1656         else
1657                 self.pressedkeys &= ~KEY_ATCK;
1658         if (self.BUTTON_ATCK2)
1659                 self.pressedkeys |= KEY_ATCK2;
1660         else
1661                 self.pressedkeys &= ~KEY_ATCK2;
1662 }
1663
1664 /*
1665 ======================
1666 spectate mode routines
1667 ======================
1668 */
1669
1670 void SpectateCopy(entity spectatee) {
1671         other = spectatee;
1672         MUTATOR_CALLHOOK(SpectateCopy);
1673         self.armortype = spectatee.armortype;
1674         self.armorvalue = spectatee.armorvalue;
1675         self.ammo_cells = spectatee.ammo_cells;
1676         self.ammo_shells = spectatee.ammo_shells;
1677         self.ammo_nails = spectatee.ammo_nails;
1678         self.ammo_rockets = spectatee.ammo_rockets;
1679         self.ammo_fuel = spectatee.ammo_fuel;
1680         self.clip_load = spectatee.clip_load;
1681         self.clip_size = spectatee.clip_size;
1682         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1683         self.health = spectatee.health;
1684         self.impulse = 0;
1685         self.items = spectatee.items;
1686         self.last_pickup = spectatee.last_pickup;
1687         self.hit_time = spectatee.hit_time;
1688         self.metertime = spectatee.metertime;
1689         self.strength_finished = spectatee.strength_finished;
1690         self.invincible_finished = spectatee.invincible_finished;
1691         self.pressedkeys = spectatee.pressedkeys;
1692         self.weapons = spectatee.weapons;
1693         self.switchweapon = spectatee.switchweapon;
1694         self.switchingweapon = spectatee.switchingweapon;
1695         self.weapon = spectatee.weapon;
1696         self.nex_charge = spectatee.nex_charge;
1697         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1698         self.hagar_load = spectatee.hagar_load;
1699         self.minelayer_mines = spectatee.minelayer_mines;
1700         self.punchangle = spectatee.punchangle;
1701         self.view_ofs = spectatee.view_ofs;
1702         self.velocity = spectatee.velocity;
1703         self.dmg_take = spectatee.dmg_take;
1704         self.dmg_save = spectatee.dmg_save;
1705         self.dmg_inflictor = spectatee.dmg_inflictor;
1706         self.v_angle = spectatee.v_angle;
1707         self.angles = spectatee.v_angle;
1708         if(!self.BUTTON_USE)
1709                 self.fixangle = TRUE;
1710         setorigin(self, spectatee.origin);
1711         setsize(self, spectatee.mins, spectatee.maxs);
1712         SetZoomState(spectatee.zoomstate);
1713
1714     anticheat_spectatecopy(spectatee);
1715         self.hud = spectatee.hud;
1716         if(spectatee.vehicle)
1717     {
1718         self.fixangle = FALSE;
1719         //self.velocity = spectatee.vehicle.velocity;
1720         self.vehicle_health = spectatee.vehicle_health;
1721         self.vehicle_shield = spectatee.vehicle_shield;
1722         self.vehicle_energy = spectatee.vehicle_energy;
1723         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1724         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1725         self.vehicle_reload1 = spectatee.vehicle_reload1;
1726         self.vehicle_reload2 = spectatee.vehicle_reload2;
1727
1728         msg_entity = self;
1729
1730         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1731             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1732             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1733             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1734
1735         //WriteByte (MSG_ONE, SVC_SETVIEW);
1736         //    WriteEntity(MSG_ONE, self);
1737         //makevectors(spectatee.v_angle);
1738         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1739     }
1740 }
1741
1742 float SpectateUpdate() {
1743         if(!self.enemy)
1744             return 0;
1745
1746         if (self == self.enemy)
1747                 return 0;
1748
1749         if (!IS_PLAYER(self.enemy))
1750                 return 0;
1751
1752         SpectateCopy(self.enemy);
1753
1754         return 1;
1755 }
1756
1757
1758 float SpectateSet()
1759 {
1760         if(self.enemy.classname != "player")
1761                 return FALSE;
1762         /*if(self.enemy.vehicle)
1763         {
1764
1765                 msg_entity = self;
1766                 WriteByte(MSG_ONE, SVC_SETVIEW);
1767                 WriteEntity(MSG_ONE, self.enemy);
1768                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1769
1770                 self.movetype = MOVETYPE_NONE;
1771                 accuracy_resend(self);
1772         }
1773         else
1774         {*/
1775                 msg_entity = self;
1776                 WriteByte(MSG_ONE, SVC_SETVIEW);
1777                 WriteEntity(MSG_ONE, self.enemy);
1778                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1779                 self.movetype = MOVETYPE_NONE;
1780                 accuracy_resend(self);
1781
1782                 if(!SpectateUpdate())
1783                         PutObserverInServer();
1784         //}
1785         return TRUE;
1786 }
1787
1788 float Spectate(entity pl)
1789 {
1790         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1791         if(pl.team != self.team)
1792                 return 0;
1793
1794         self.enemy = pl;
1795         return SpectateSet();
1796 }
1797
1798 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1799 entity CA_SpectateNext(entity start) {
1800         if (start.team == self.team) {
1801                 return start;
1802         }
1803
1804         other = start;
1805         // continue from current player
1806         while(other && other.team != self.team) {
1807                 other = find(other, classname, "player");
1808         }
1809
1810         if (!other) {
1811                 // restart from begining
1812                 other = find(other, classname, "player");
1813                 while(other && other.team != self.team) {
1814                         other = find(other, classname, "player");
1815                 }
1816         }
1817
1818         return other;
1819 }
1820
1821 float SpectateNext()
1822 {
1823         other = find(self.enemy, classname, "player");
1824
1825         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1826                 // CA and ca players when spectating enemies is forbidden
1827                 other = CA_SpectateNext(other);
1828         } else {
1829                 // other modes and ca spectators or spectating enemies is allowed
1830                 if (!other)
1831                         other = find(other, classname, "player");
1832         }
1833
1834         if (other)
1835                 self.enemy = other;
1836
1837         return SpectateSet();
1838 }
1839
1840 float SpectatePrev()
1841 {
1842         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1843         other = findchain(classname, "player");
1844         if (!other) // no player
1845                 return FALSE;
1846
1847         entity first = other;
1848         // skip players until current spectated player
1849         if(self.enemy)
1850         while(other && other != self.enemy)
1851                 other = other.chain;
1852
1853         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1854         {
1855                 do { other = other.chain; }
1856                 while(other && other.team != self.team);
1857
1858                 if (!other)
1859                 {
1860                         other = first;
1861                         while(other.team != self.team)
1862                                 other = other.chain;
1863                         if(other == self.enemy)
1864                                 return TRUE;
1865                 }
1866         }
1867         else
1868         {
1869                 if(other.chain)
1870                         other = other.chain;
1871                 else
1872                         other = first;
1873         }
1874         self.enemy = other;
1875         return SpectateSet();
1876 }
1877
1878 /*
1879 =============
1880 ShowRespawnCountdown()
1881
1882 Update a respawn countdown display.
1883 =============
1884 */
1885 void ShowRespawnCountdown()
1886 {
1887         float number;
1888         if(self.deadflag == DEAD_NO) // just respawned?
1889                 return;
1890         else
1891         {
1892                 number = ceil(self.respawn_time - time);
1893                 if(number <= 0)
1894                         return;
1895                 if(number <= self.respawn_countdown)
1896                 {
1897                         self.respawn_countdown = number - 1;
1898                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1899                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1900                 }
1901         }
1902 }
1903
1904 void LeaveSpectatorMode()
1905 {
1906         if(self.caplayer)
1907                 return;
1908         if(nJoinAllowed(self))
1909         {
1910                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1911                 {
1912                         self.classname = "player";
1913
1914                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1915                                 { JoinBestTeam(self, FALSE, TRUE); }
1916
1917                         if(autocvar_g_campaign)
1918                                 { campaign_bots_may_start = 1; }
1919
1920                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1921
1922                         PutClientInServer();
1923
1924                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1925                 }
1926                 else
1927                         stuffcmd(self, "menu_showteamselect\n");
1928         }
1929         else
1930         {
1931                 // Player may not join because g_maxplayers is set
1932                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1933         }
1934 }
1935
1936 /**
1937  * Determines whether the player is allowed to join. This depends on cvar
1938  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1939  * it checks whether the number of currently playing players exceeds g_maxplayers.
1940  * @return int number of free slots for players, 0 if none
1941  */
1942 float nJoinAllowed(entity ignore) {
1943         if(!ignore)
1944         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1945         // so report 0 free slots if restricted
1946         {
1947                 if(autocvar_g_forced_team_otherwise == "spectate")
1948                         return 0;
1949                 if(autocvar_g_forced_team_otherwise == "spectator")
1950                         return 0;
1951         }
1952
1953         if(self.team_forced < 0)
1954                 return 0; // forced spectators can never join
1955
1956         // TODO simplify this
1957         entity e;
1958         float totalClients = 0;
1959         FOR_EACH_CLIENT(e)
1960                 if(e != ignore)
1961                         totalClients += 1;
1962
1963         if (!autocvar_g_maxplayers)
1964                 return maxclients - totalClients;
1965
1966         float currentlyPlaying = 0;
1967         FOR_EACH_REALCLIENT(e)
1968                 if(IS_PLAYER(e) || e.caplayer == 1)
1969                         currentlyPlaying += 1;
1970
1971         if(currentlyPlaying < autocvar_g_maxplayers)
1972                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1973
1974         return 0;
1975 }
1976
1977 /**
1978  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1979  * g_maxplayers_spectator_blocktime seconds
1980  */
1981 void checkSpectatorBlock() {
1982         if(IS_SPEC(self) || IS_OBSERVER(self)) {
1983                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1984                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1985                         dropclient(self);
1986                 }
1987         }
1988 }
1989
1990 void PrintWelcomeMessage()
1991 {
1992         if(self.motd_actived_time == 0)
1993         {
1994                 if (autocvar_g_campaign) {
1995                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
1996                                 self.motd_actived_time = time;
1997                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
1998                         }
1999                 } else {
2000                         if (self.BUTTON_INFO) {
2001                                 self.motd_actived_time = time;
2002                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2003                         }
2004                 }
2005         }
2006         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2007         {
2008                 if (autocvar_g_campaign) {
2009                         if (self.BUTTON_INFO)
2010                                 self.motd_actived_time = time;
2011                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2012                                 self.motd_actived_time = 0;
2013                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2014                         }
2015                 } else {
2016                         if (self.BUTTON_INFO)
2017                                 self.motd_actived_time = time;
2018                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2019                                 self.motd_actived_time = 0;
2020                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2021                         }
2022                 }
2023         }
2024         else //if(self.motd_actived_time < 0) // just connected, motd is active
2025         {
2026                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2027                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2028                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2029                 {
2030                         // instanctly hide MOTD
2031                         self.motd_actived_time = 0;
2032                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2033                 }
2034         }
2035 }
2036
2037 void ObserverThink()
2038 {
2039         float prefered_movetype;
2040         if (self.flags & FL_JUMPRELEASED) {
2041                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2042                         self.flags &= ~FL_JUMPRELEASED;
2043                         self.flags |= FL_SPAWNING;
2044                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2045                         self.flags &= ~FL_JUMPRELEASED;
2046                         if(SpectateNext()) {
2047                                 self.classname = "spectator";
2048                         }
2049                 } else {
2050                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2051                         if (self.movetype != prefered_movetype)
2052                                 self.movetype = prefered_movetype;
2053                 }
2054         } else {
2055                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2056                         self.flags |= FL_JUMPRELEASED;
2057                         if(self.flags & FL_SPAWNING)
2058                         {
2059                                 self.flags &= ~FL_SPAWNING;
2060                                 LeaveSpectatorMode();
2061                                 return;
2062                         }
2063                 }
2064         }
2065 }
2066
2067 void SpectatorThink()
2068 {
2069         if (self.flags & FL_JUMPRELEASED) {
2070                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2071                         self.flags &= ~FL_JUMPRELEASED;
2072                         self.flags |= FL_SPAWNING;
2073                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2074                         self.flags &= ~FL_JUMPRELEASED;
2075                         if(SpectateNext()) {
2076                                 self.classname = "spectator";
2077                         } else {
2078                                 self.classname = "observer";
2079                                 PutClientInServer();
2080                         }
2081                         self.impulse = 0;
2082                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2083                         self.flags &= ~FL_JUMPRELEASED;
2084                         if(SpectatePrev()) {
2085                                 self.classname = "spectator";
2086                         } else {
2087                                 self.classname = "observer";
2088                                 PutClientInServer();
2089                         }
2090                         self.impulse = 0;
2091                 } else if (self.BUTTON_ATCK2) {
2092                         self.flags &= ~FL_JUMPRELEASED;
2093                         self.classname = "observer";
2094                         PutClientInServer();
2095                 } else {
2096                         if(!SpectateUpdate())
2097                                 PutObserverInServer();
2098                 }
2099         } else {
2100                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2101                         self.flags |= FL_JUMPRELEASED;
2102                         if(self.flags & FL_SPAWNING)
2103                         {
2104                                 self.flags &= ~FL_SPAWNING;
2105                                 LeaveSpectatorMode();
2106                                 return;
2107                         }
2108                 }
2109                 if(!SpectateUpdate())
2110                         PutObserverInServer();
2111         }
2112
2113         self.flags |= FL_CLIENT | FL_NOTARGET;
2114 }
2115
2116 void PlayerUseKey()
2117 {
2118         if (!IS_PLAYER(self))
2119                 return;
2120
2121         if(self.vehicle)
2122         {
2123         vehicles_exit(VHEF_NORMAL);
2124         return;
2125         }
2126
2127         // a use key was pressed; call handlers
2128         MUTATOR_CALLHOOK(PlayerUseKey);
2129 }
2130
2131 /*
2132 =============
2133 PlayerPreThink
2134
2135 Called every frame for each client before the physics are run
2136 =============
2137 */
2138 .float usekeypressed;
2139 void() nexball_setstatus;
2140 .float items_added;
2141 void PlayerPreThink (void)
2142 {
2143         WarpZone_PlayerPhysics_FixVAngle();
2144
2145         self.stat_game_starttime = game_starttime;
2146         self.stat_round_starttime = round_starttime;
2147         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2148         self.stat_leadlimit = autocvar_leadlimit;
2149
2150         if(frametime)
2151         {
2152                 // physics frames: update anticheat stuff
2153                 anticheat_prethink();
2154         }
2155
2156         if(blockSpectators && frametime)
2157                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2158                 checkSpectatorBlock();
2159
2160         zoomstate_set = 0;
2161
2162         if(self.netname_previous != self.netname)
2163         {
2164                 if(autocvar_sv_eventlog)
2165                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2166                 if(self.netname_previous)
2167                         strunzone(self.netname_previous);
2168                 self.netname_previous = strzone(self.netname);
2169         }
2170
2171         // version nagging
2172         if(self.version_nagtime)
2173                 if(self.cvar_g_xonoticversion)
2174                         if(time > self.version_nagtime)
2175                         {
2176                                 // don't notify git users
2177                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2178                                 {
2179                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2180                                         {
2181                                                 // notify release users if connecting to git
2182                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2183                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2184                                         }
2185                                         else
2186                                         {
2187                                                 float r;
2188                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2189                                                 if(r < 0)
2190                                                 {
2191                                                         // give users new version
2192                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2193                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2194                                                 }
2195                                                 else if(r > 0)
2196                                                 {
2197                                                         // notify users about old server version
2198                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2199                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2200                                                 }
2201                                         }
2202                                 }
2203                                 self.version_nagtime = 0;
2204                         }
2205
2206         // GOD MODE info
2207         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2208         {
2209                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2210                 self.max_armorvalue = 0;
2211         }
2212
2213 #ifdef TETRIS
2214         if (TetrisPreFrame())
2215                 return;
2216 #endif
2217
2218         MUTATOR_CALLHOOK(PlayerPreThink);
2219
2220         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2221         {
2222                 if(self.BUTTON_USE && !self.usekeypressed)
2223                         PlayerUseKey();
2224                 self.usekeypressed = self.BUTTON_USE;
2225         }
2226
2227         if(IS_REAL_CLIENT(self))
2228                 PrintWelcomeMessage();
2229
2230         if(IS_PLAYER(self))
2231         {
2232
2233                 CheckRules_Player();
2234
2235                 if (intermission_running)
2236                 {
2237                         IntermissionThink ();   // otherwise a button could be missed between
2238                         return;                                 // the think tics
2239                 }
2240
2241                 //don't allow the player to turn around while game is paused!
2242                 if(timeout_status == TIMEOUT_ACTIVE) {
2243                         // FIXME turn this into CSQC stuff
2244                         self.v_angle = self.lastV_angle;
2245                         self.angles = self.lastV_angle;
2246                         self.fixangle = TRUE;
2247                 }
2248
2249                 if(frametime)
2250                 {
2251                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2252                         {
2253                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2254                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2255                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2256
2257                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2258                                 {
2259                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2260                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2261                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2262                                 }
2263                         }
2264                         else
2265                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2266
2267                         player_powerups();
2268                 }
2269
2270                 if (self.deadflag != DEAD_NO)
2271                 {
2272                         if(self.personal && g_race_qualifying)
2273                         {
2274                                 if(time > self.respawn_time)
2275                                 {
2276                                         self.respawn_time = time + 1; // only retry once a second
2277                                         self.stat_respawn_time = self.respawn_time;
2278                                         respawn();
2279                                         self.impulse = 141;
2280                                 }
2281                         }
2282                         else
2283                         {
2284                                 float button_pressed;
2285                                 if(frametime)
2286                                         player_anim();
2287                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2288
2289                                 if (self.deadflag == DEAD_DYING)
2290                                 {
2291                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2292                                                 self.deadflag = DEAD_RESPAWNING;
2293                                         else if(!button_pressed)
2294                                                 self.deadflag = DEAD_DEAD;
2295                                 }
2296                                 else if (self.deadflag == DEAD_DEAD)
2297                                 {
2298                                         if(button_pressed)
2299                                                 self.deadflag = DEAD_RESPAWNABLE;
2300                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2301                                                 self.deadflag = DEAD_RESPAWNING;
2302                                 }
2303                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2304                                 {
2305                                         if(!button_pressed)
2306                                                 self.deadflag = DEAD_RESPAWNING;
2307                                 }
2308                                 else if (self.deadflag == DEAD_RESPAWNING)
2309                                 {
2310                                         if(time > self.respawn_time)
2311                                         {
2312                                                 self.respawn_time = time + 1; // only retry once a second
2313                                                 self.respawn_time_max = self.respawn_time;
2314                                                 respawn();
2315                                         }
2316                                 }
2317
2318                                 ShowRespawnCountdown();
2319
2320                                 if(self.respawn_flags & RESPAWN_SILENT)
2321                                         self.stat_respawn_time = 0;
2322                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2323                                         self.stat_respawn_time = self.respawn_time_max;
2324                                 else
2325                                         self.stat_respawn_time = self.respawn_time;
2326                         }
2327
2328                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2329                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2330                                 self.stat_respawn_time *= -1;
2331
2332                         return;
2333                 }
2334
2335                 self.prevorigin = self.origin;
2336
2337                 float do_crouch = self.BUTTON_CROUCH;
2338                 if(self.hook.state)
2339                         do_crouch = 0;
2340                 if(self.vehicle)
2341                         do_crouch = 0;
2342                 if(self.freezetag_frozen)
2343                         do_crouch = 0;
2344                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2345                         do_crouch = 0;
2346
2347                 if (do_crouch)
2348                 {
2349                         if (!self.crouch)
2350                         {
2351                                 self.crouch = TRUE;
2352                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2353                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2354                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2355                         }
2356                 }
2357                 else
2358                 {
2359                         if (self.crouch)
2360                         {
2361                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2362                                 if (!trace_startsolid)
2363                                 {
2364                                         self.crouch = FALSE;
2365                                         self.view_ofs = PL_VIEW_OFS;
2366                                         setsize (self, PL_MIN, PL_MAX);
2367                                 }
2368                         }
2369                 }
2370
2371                 FixPlayermodel();
2372
2373                 GrapplingHookFrame();
2374
2375                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2376                 //if(frametime)
2377                 {
2378                         self.items &= ~self.items_added;
2379
2380                         W_WeaponFrame();
2381
2382                         self.items_added = 0;
2383                         if(self.items & IT_JETPACK)
2384                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2385                                         self.items_added |= IT_FUEL;
2386
2387                         self.items |= self.items_added;
2388                 }
2389
2390                 player_regen();
2391
2392                 // rot nex charge to the charge limit
2393                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2394                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2395
2396                 if(frametime)
2397                         player_anim();
2398
2399                 // secret status
2400                 secrets_setstatus();
2401
2402                 // monsters status
2403                 monsters_setstatus();
2404
2405                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2406
2407                 //self.angles_y=self.v_angle_y + 90;   // temp
2408         } else if(gameover) {
2409                 if (intermission_running)
2410                         IntermissionThink ();   // otherwise a button could be missed between
2411                 return;
2412         } else if(IS_OBSERVER(self)) {
2413                 ObserverThink();
2414         } else if(IS_SPEC(self)) {
2415                 SpectatorThink();
2416         }
2417
2418         if(!zoomstate_set)
2419                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2420
2421         float oldspectatee_status;
2422         oldspectatee_status = self.spectatee_status;
2423         if(IS_SPEC(self))
2424                 self.spectatee_status = num_for_edict(self.enemy);
2425         else if(IS_OBSERVER(self))
2426                 self.spectatee_status = num_for_edict(self);
2427         else
2428                 self.spectatee_status = 0;
2429         if(self.spectatee_status != oldspectatee_status)
2430         {
2431                 ClientData_Touch(self);
2432         }
2433
2434         if(self.teamkill_soundtime)
2435         if(time > self.teamkill_soundtime)
2436         {
2437                 self.teamkill_soundtime = 0;
2438
2439                 entity oldpusher, oldself;
2440
2441                 oldself = self; self = self.teamkill_soundsource;
2442                 oldpusher = self.pusher; self.pusher = oldself;
2443
2444                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2445
2446                 self.pusher = oldpusher;
2447                 self = oldself;
2448         }
2449
2450         if(self.taunt_soundtime)
2451         if(time > self.taunt_soundtime)
2452         {
2453                 self.taunt_soundtime = 0;
2454                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2455         }
2456
2457         target_voicescript_next(self);
2458
2459         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2460         if(!self.weapon)
2461                 self.clip_load = self.clip_size = 0;
2462 }
2463
2464 float isInvisibleString(string s)
2465 {
2466         float i, n, c;
2467         s = strdecolorize(s);
2468         for((i = 0), (n = strlen(s)); i < n; ++i)
2469         {
2470                 c = str2chr(s, i);
2471                 switch(c)
2472                 {
2473                         case 0:
2474                         case 32: // space
2475                                 break;
2476                         case 192: // charmap space
2477                                 if (!autocvar_utf8_enable)
2478                                         break;
2479                                 return FALSE;
2480                         case 160: // space in unicode fonts
2481                         case 0xE000 + 192: // utf8 charmap space
2482                                 if (autocvar_utf8_enable)
2483                                         break;
2484                         default:
2485                                 return FALSE;
2486                 }
2487         }
2488         return TRUE;
2489 }
2490
2491 /*
2492 =============
2493 PlayerPostThink
2494
2495 Called every frame for each client after the physics are run
2496 =============
2497 */
2498 .float idlekick_lasttimeleft;
2499 void PlayerPostThink (void)
2500 {
2501         // Savage: Check for nameless players
2502         if (isInvisibleString(self.netname)) {
2503                 self.netname = "Player";
2504                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2505         }
2506
2507         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2508         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2509         {
2510                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2511                 {
2512                         if(self.idlekick_lasttimeleft)
2513                         {
2514                                 self.idlekick_lasttimeleft = 0;
2515                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2516                         }
2517                 }
2518                 else
2519                 {
2520                         float timeleft;
2521                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2522                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2523                         {
2524                                 if(!self.idlekick_lasttimeleft)
2525                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2526                         }
2527                         if(timeleft <= 0)
2528                         {
2529                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2530                                 dropclient(self);
2531                                 return;
2532                         }
2533                         else if(timeleft <= 10)
2534                         {
2535                                 if(timeleft != self.idlekick_lasttimeleft)
2536                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2537                                 self.idlekick_lasttimeleft = timeleft;
2538                         }
2539                 }
2540         }
2541
2542 #ifdef TETRIS
2543         if(self.impulse == 100)
2544                 ImpulseCommands();
2545         if (!TetrisPostFrame())
2546         {
2547 #endif
2548
2549         CheatFrame();
2550
2551         //CheckPlayerJump();
2552
2553         if(IS_PLAYER(self)) {
2554                 CheckRules_Player();
2555                 UpdateChatBubble();
2556                 if (self.impulse)
2557                         ImpulseCommands();
2558                 if (intermission_running)
2559                         return;         // intermission or finale
2560                 GetPressedKeys();
2561         }
2562
2563 #ifdef TETRIS
2564         }
2565 #endif
2566
2567         /*
2568         float i;
2569         for(i = 0; i < 1000; ++i)
2570         {
2571                 vector end;
2572                 end = self.origin + '0 0 1024' + 512 * randomvec();
2573                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2574                 if(trace_fraction < 1)
2575                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2576                 {
2577                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2578                         break;
2579                 }
2580         }
2581         */
2582
2583         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2584
2585         if(self.waypointsprite_attachedforcarrier)
2586                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2587
2588         playerdemo_write();
2589
2590         CSQCMODEL_AUTOUPDATE();
2591 }