qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  11         WriteByte(MSG_BROADCAST, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_BROADCAST, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 }
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         shortest = vlen(world.maxs - world.mins);
 155         FOR_EACH_PLAYER(player) if (player != self)
 156         {
 157                 thisdist = vlen(player.origin - spot.origin);
 158                 if (thisdist < shortest)
 159                         shortest = thisdist;
 160         }
 161         if(shortest > mindist)
 162                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 163
 164         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 165         spawn_spot = spot;
 166
 167         // filter out spots for assault
 168         if(spot.target != "") {
 169                 entity ent;
 170                 float found;
 171
 172                 found = 0;
 173                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 174                 {
 175                         ++found;
 176                         if(ent.spawn_evalfunc)
 177                         {
 178                                 entity oldself = self;
 179                                 self = ent;
 180                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 181                                 self = oldself;
 182                                 if(spawn_score_x < 0)
 183                                         return spawn_score;
 184                         }
 185                 }
 186
 187                 if(!found)
 188                 {
 189                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 190                         return '-1 0 0';
 191                 }
 192         }
 193
 194         MUTATOR_CALLHOOK(Spawn_Score);
 195         return spawn_score;
 196 }
 197
 198 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 199 {
 200         entity spot;
 201         for(spot = firstspot; spot; spot = spot.chain)
 202                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 203 }
 204
 205 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 206 {
 207         entity spot, spotlist, spotlistend;
 208
 209         spotlist = world;
 210         spotlistend = world;
 211
 212         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 213
 214         for(spot = firstspot; spot; spot = spot.chain)
 215         {
 216                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 217                 {
 218                         if(spotlistend)
 219                                 spotlistend.chain = spot;
 220                         spotlistend = spot;
 221                         if(!spotlist)
 222                                 spotlist = spot;
 223                 }
 224         }
 225         if(spotlistend)
 226                 spotlistend.chain = world;
 227
 228         return spotlist;
 229 }
 230
 231 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 232 {
 233         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 234         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 235         entity spot;
 236
 237         RandomSelection_Init();
 238         for(spot = firstspot; spot; spot = spot.chain)
 239                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 240
 241         return RandomSelection_chosen_ent;
 242 }
 243
 244 /*
 245 =============
 246 SelectSpawnPoint
 247
 248 Finds a point to respawn
 249 =============
 250 */
 251 entity SelectSpawnPoint (float anypoint)
 252 {
 253         float teamcheck;
 254         entity spot, firstspot;
 255
 256         spot = find (world, classname, "testplayerstart");
 257         if (spot)
 258                 return spot;
 259
 260         if(anypoint || autocvar_g_spawn_useallspawns)
 261                 teamcheck = -1;
 262         else if(have_team_spawns > 0)
 263         {
 264                 if(have_team_spawns_forteam[self.team] == 0)
 265                 {
 266                         // we request a spawn for a team, and we have team
 267                         // spawns, but that team has no spawns?
 268                         if(have_team_spawns_forteam[0])
 269                                 // try noteam spawns
 270                                 teamcheck = 0;
 271                         else
 272                                 // if not, any spawn has to do
 273                                 teamcheck = -1;
 274                 }
 275                 else
 276                         teamcheck = self.team; // MUST be team
 277         }
 278         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 279                 teamcheck = 0; // MUST be noteam
 280         else
 281                 teamcheck = -1;
 282                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 283
 284
 285         // get the entire list of spots
 286         firstspot = findchain(classname, "info_player_deathmatch");
 287         // filter out the bad ones
 288         // (note this returns the original list if none survived)
 289         if(anypoint)
 290         {
 291                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 292         }
 293         else
 294         {
 295                 float mindist;
 296                 if (g_arena && arena_roundbased)
 297                         mindist = 800;
 298                 else
 299                         mindist = 100;
 300                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 301
 302                 // there is 50/50 chance of choosing a random spot or the furthest spot
 303                 // (this means that roughly every other spawn will be furthest, so you
 304                 // usually won't get fragged at spawn twice in a row)
 305                 if (random() > autocvar_g_spawn_furthest)
 306                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 307                 else
 308                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 309         }
 310
 311         if (!spot)
 312         {
 313                 if(autocvar_spawn_debug)
 314                         GotoNextMap(0);
 315                 else
 316                 {
 317                         if(some_spawn_has_been_used)
 318                                 return world; // team can't spawn any more, because of actions of other team
 319                         else
 320                                 error("Cannot find a spawn point - please fix the map!");
 321                 }
 322         }
 323
 324         return spot;
 325 }
 326
 327 /*
 328 =============
 329 CheckPlayerModel
 330
 331 Checks if the argument string can be a valid playermodel.
 332 Returns a valid one in doubt.
 333 =============
 334 */
 335 string FallbackPlayerModel;
 336 string CheckPlayerModel(string plyermodel) {
 337         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 338         {
 339                 // note: we cannot summon Don Strunzone here, some player may
 340                 // still have the model string set. In case anyone manages how
 341                 // to change a cvar default, we'll have a small leak here.
 342                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 343         }
 344         // only in right path
 345         if( substring(plyermodel,0,14) != "models/player/")
 346                 return FallbackPlayerModel;
 347         // only good file extensions
 348         if(substring(plyermodel,-4,4) != ".zym")
 349         if(substring(plyermodel,-4,4) != ".dpm")
 350         if(substring(plyermodel,-4,4) != ".iqm")
 351         if(substring(plyermodel,-4,4) != ".md3")
 352         if(substring(plyermodel,-4,4) != ".psk")
 353                 return FallbackPlayerModel;
 354         // forbid the LOD models
 355         if(substring(plyermodel, -9,5) == "_lod1")
 356                 return FallbackPlayerModel;
 357         if(substring(plyermodel, -9,5) == "_lod2")
 358                 return FallbackPlayerModel;
 359         if(plyermodel != strtolower(plyermodel))
 360                 return FallbackPlayerModel;
 361         // also, restrict to server models
 362         if(autocvar_sv_servermodelsonly)
 363         {
 364                 if(!fexists(plyermodel))
 365                         return FallbackPlayerModel;
 366         }
 367         return plyermodel;
 368 }
 369
 370 void setplayermodel(entity e, string modelname)
 371 {
 372         precache_model(modelname);
 373         setmodel(e, modelname);
 374         player_setupanimsformodel();
 375         UpdatePlayerSounds();
 376 }
 377
 378 /*
 379 =============
 380 PutObserverInServer
 381
 382 putting a client as observer in the server
 383 =============
 384 */
 385 void FixPlayermodel();
 386 void PutObserverInServer (void)
 387 {
 388         entity  spot;
 389     self.hud = HUD_NORMAL;
 390         race_PreSpawnObserver();
 391
 392         spot = SelectSpawnPoint (TRUE);
 393         if(!spot)
 394                 error("No spawnpoints for observers?!?\n");
 395         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397         if(clienttype(self) == CLIENTTYPE_REAL)
 398         {
 399                 msg_entity = self;
 400                 WriteByte(MSG_ONE, SVC_SETVIEW);
 401                 WriteEntity(MSG_ONE, self);
 402         }
 403
 404         if(g_lms)
 405         {
 406                 // Only if the player cannot play at all
 407                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 408                         self.frags = FRAGS_SPECTATOR;
 409                 else
 410                         self.frags = FRAGS_LMS_LOSER;
 411         }
 412         else if((g_race && g_race_qualifying) || g_cts)
 413         {
 414                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 415                         self.frags = FRAGS_LMS_LOSER;
 416                 else
 417                         self.frags = FRAGS_SPECTATOR;
 418         }
 419         else
 420                 self.frags = FRAGS_SPECTATOR;
 421
 422         DropAllRunes(self);
 423         MUTATOR_CALLHOOK(MakePlayerObserver);
 424
 425         minstagib_stop_countdown(self);
 426
 427         Portal_ClearAll(self);
 428
 429         if(self.alivetime)
 430         {
 431                 if(!inWarmupStage)
 432                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 433                 self.alivetime = 0;
 434         }
 435
 436         if(self.vehicle)
 437                 vehicles_exit(VHEF_RELESE);
 438
 439         WaypointSprite_PlayerDead();
 440
 441         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 442                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 443
 444         if(self.killcount != -666) {
 445                 if(g_lms) {
 446                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 447                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 448                         else
 449                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 450                 } else
 451                         bprint ("^4", self.netname, "^4 is spectating now\n");
 452
 453                 if(self.just_joined == FALSE) {
 454                         LogTeamchange(self.playerid, -1, 4);
 455                 } else
 456                         self.just_joined = FALSE;
 457         }
 458
 459         PlayerScore_Clear(self); // clear scores when needed
 460
 461         accuracy_resend(self);
 462
 463         self.spectatortime = time;
 464
 465         self.classname = "observer";
 466         self.iscreature = FALSE;
 467         self.teleportable = TELEPORT_SIMPLE;
 468         self.damagedbycontents = FALSE;
 469         self.health = -666;
 470         self.takedamage = DAMAGE_NO;
 471         self.solid = SOLID_NOT;
 472         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 473         self.flags = FL_CLIENT | FL_NOTARGET;
 474         self.armorvalue = 666;
 475         self.effects = 0;
 476         self.armorvalue = autocvar_g_balance_armor_start;
 477         self.pauserotarmor_finished = 0;
 478         self.pauserothealth_finished = 0;
 479         self.pauseregen_finished = 0;
 480         self.damageforcescale = 0;
 481         self.death_time = 0;
 482         self.respawn_time = 0;
 483         self.alpha = 0;
 484         self.scale = 0;
 485         self.fade_time = 0;
 486         self.pain_frame = 0;
 487         self.pain_finished = 0;
 488         self.strength_finished = 0;
 489         self.invincible_finished = 0;
 490         self.superweapons_finished = 0;
 491         self.pushltime = 0;
 492         self.istypefrag = 0;
 493         self.think = func_null;
 494         self.nextthink = 0;
 495         self.hook_time = 0;
 496         self.runes = 0;
 497         self.deadflag = DEAD_NO;
 498         self.angles = spot.angles;
 499         self.angles_z = 0;
 500         self.fixangle = TRUE;
 501         self.crouch = FALSE;
 502
 503         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 504         self.prevorigin = self.origin;
 505         self.items = 0;
 506         WEPSET_CLEAR_E(self);
 507         self.model = "";
 508         FixPlayermodel();
 509         setmodel(self, "null");
 510         self.drawonlytoclient = self;
 511
 512         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 513         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 514
 515         self.weapon = 0;
 516         self.weaponname = "";
 517         self.switchingweapon = 0;
 518         self.weaponmodel = "";
 519         self.weaponentity = world;
 520         self.exteriorweaponentity = world;
 521         self.killcount = -666;
 522         self.velocity = '0 0 0';
 523         self.avelocity = '0 0 0';
 524         self.punchangle = '0 0 0';
 525         self.punchvector = '0 0 0';
 526         self.oldvelocity = self.velocity;
 527         self.fire_endtime = -1;
 528 }
 529
 530 .float model_randomizer;
 531 void FixPlayermodel()
 532 {
 533         string defaultmodel;
 534         float defaultskin, chmdl, oldskin, n, i;
 535         vector m1, m2;
 536
 537         defaultmodel = "";
 538         defaultskin = 0;
 539         chmdl = FALSE;
 540
 541         if(autocvar_sv_defaultcharacter == 1)
 542         {
 543                 if(teamplay)
 544                 {
 545                         string s;
 546                         s = Team_ColorNameLowerCase(self.team);
 547                         if(s != "neutral")
 548                         {
 549                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 550                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 551                         }
 552                 }
 553
 554                 if(defaultmodel == "")
 555                 {
 556                         defaultmodel = autocvar_sv_defaultplayermodel;
 557                         defaultskin = autocvar_sv_defaultplayerskin;
 558                 }
 559
 560                 n = tokenize_console(defaultmodel);
 561                 if(n > 0)
 562                         defaultmodel = argv(floor(n * self.model_randomizer));
 563
 564                 i = strstrofs(defaultmodel, ":", 0);
 565                 if(i >= 0)
 566                 {
 567                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 568                         defaultmodel = substring(defaultmodel, 0, i);
 569                 }
 570         }
 571
 572         if(defaultmodel != "")
 573         {
 574                 if (defaultmodel != self.model)
 575                 {
 576                         m1 = self.mins;
 577                         m2 = self.maxs;
 578                         setplayermodel (self, defaultmodel);
 579                         setsize (self, m1, m2);
 580                         chmdl = TRUE;
 581                 }
 582
 583                 oldskin = self.skin;
 584                 self.skin = defaultskin;
 585         } else {
 586                 if (self.playermodel != self.model || self.playermodel == "")
 587                 {
 588                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 589                         m1 = self.mins;
 590                         m2 = self.maxs;
 591                         setplayermodel (self, self.playermodel);
 592                         setsize (self, m1, m2);
 593                         chmdl = TRUE;
 594                 }
 595
 596                 oldskin = self.skin;
 597                 self.skin = stof(self.playerskin);
 598         }
 599
 600         if(chmdl || oldskin != self.skin)
 601                 self.species = player_getspecies(); // model or skin has changed
 602
 603         if(!teamplay)
 604                 if(strlen(autocvar_sv_defaultplayercolors))
 605                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 606                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 607 }
 608
 609 void PlayerTouchExplode(entity p1, entity p2)
 610 {
 611         vector org;
 612         org = (p1.origin + p2.origin) * 0.5;
 613         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 614
 615         te_explosion(org);
 616
 617         entity e;
 618         e = spawn();
 619         setorigin(e, org);
 620         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 621         remove(e);
 622 }
 623
 624 /*
 625 =============
 626 PutClientInServer
 627
 628 Called when a client spawns in the server
 629 =============
 630 */
 631
 632 void PutClientInServer (void)
 633 {
 634         if(clienttype(self) == CLIENTTYPE_BOT)
 635                 self.classname = "player";
 636         else if(clienttype(self) == CLIENTTYPE_REAL)
 637         {
 638                 msg_entity = self;
 639                 WriteByte(MSG_ONE, SVC_SETVIEW);
 640                 WriteEntity(MSG_ONE, self);
 641         }
 642
 643         // reset player keys
 644         self.itemkeys = 0;
 645
 646         // player is dead and becomes observer
 647         // FIXME fix LMS scoring for new system
 648         if(g_lms)
 649         {
 650                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 651                         self.classname = "observer";
 652         }
 653
 654         MUTATOR_CALLHOOK(PutClientInServer);
 655
 656         if(gameover)
 657                 self.classname = "observer";
 658
 659         if(self.classname == "player") {
 660                 entity spot, oldself;
 661                 float j;
 662
 663                 accuracy_resend(self);
 664
 665                 if(self.team < 0)
 666                         JoinBestTeam(self, FALSE, TRUE);
 667
 668                 race_PreSpawn();
 669
 670                 spot = SelectSpawnPoint (FALSE);
 671                 if(!spot)
 672                 {
 673                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 674                         return; // spawn failed
 675                 }
 676
 677                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 678
 679                 self.classname = "player";
 680                 self.wasplayer = TRUE;
 681                 self.iscreature = TRUE;
 682                 self.teleportable = TELEPORT_NORMAL;
 683                 self.damagedbycontents = TRUE;
 684                 self.movetype = MOVETYPE_WALK;
 685                 self.solid = SOLID_SLIDEBOX;
 686                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 687                 if(autocvar_g_playerclip_collisions)
 688                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 689                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 690                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 691                 self.frags = FRAGS_PLAYER;
 692                 if(INDEPENDENT_PLAYERS)
 693                         MAKE_INDEPENDENT_PLAYER(self);
 694                 self.flags = FL_CLIENT;
 695                 if(autocvar__notarget)
 696                         self.flags |= FL_NOTARGET;
 697                 self.takedamage = DAMAGE_AIM;
 698                 if(g_minstagib)
 699                         self.effects = EF_FULLBRIGHT;
 700                 else
 701                         self.effects = 0;
 702                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 703                 self.air_finished = time + 12;
 704                 self.dmg = 2;
 705                 if(autocvar_g_balance_nex_charge)
 706                 {
 707                         if(autocvar_g_balance_nex_secondary_chargepool)
 708                                 self.nex_chargepool_ammo = 1;
 709                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 710                 }
 711
 712                 if(inWarmupStage)
 713                 {
 714                         self.ammo_shells = warmup_start_ammo_shells;
 715                         self.ammo_nails = warmup_start_ammo_nails;
 716                         self.ammo_rockets = warmup_start_ammo_rockets;
 717                         self.ammo_cells = warmup_start_ammo_cells;
 718                         self.ammo_fuel = warmup_start_ammo_fuel;
 719                         self.health = warmup_start_health;
 720                         self.armorvalue = warmup_start_armorvalue;
 721                         WEPSET_COPY_EA(self, warmup_start_weapons);
 722                 }
 723                 else
 724                 {
 725                         self.ammo_shells = start_ammo_shells;
 726                         self.ammo_nails = start_ammo_nails;
 727                         self.ammo_rockets = start_ammo_rockets;
 728                         self.ammo_cells = start_ammo_cells;
 729                         self.ammo_fuel = start_ammo_fuel;
 730                         self.health = start_health;
 731                         self.armorvalue = start_armorvalue;
 732                         WEPSET_COPY_EA(self, start_weapons);
 733                 }
 734
 735                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 736                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 737                 else
 738                         self.superweapons_finished = 0;
 739
 740                 if(g_weaponarena_random)
 741                 {
 742                         if(g_weaponarena_random_with_laser)
 743                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 744                         W_RandomWeapons(self, g_weaponarena_random);
 745                         if(g_weaponarena_random_with_laser)
 746                                 WEPSET_OR_EW(self, WEP_LASER);
 747                 }
 748
 749                 self.items = start_items;
 750
 751                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 752                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 753                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 754                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 755                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 756                 //extend the pause of rotting if client was reset at the beginning of the countdown
 757                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 758                         self.spawnshieldtime += game_starttime - time;
 759                         self.pauserotarmor_finished += game_starttime - time;
 760                         self.pauserothealth_finished += game_starttime - time;
 761                         self.pauseregen_finished += game_starttime - time;
 762                 }
 763                 self.damageforcescale = 2;
 764                 self.death_time = 0;
 765                 self.respawn_time = 0;
 766                 self.scale = 0;
 767                 self.fade_time = 0;
 768                 self.pain_frame = 0;
 769                 self.pain_finished = 0;
 770                 self.strength_finished = 0;
 771                 self.invincible_finished = 0;
 772                 self.pushltime = 0;
 773                 // players have no think function
 774                 self.think = func_null;
 775                 self.nextthink = 0;
 776                 self.hook_time = 0;
 777                 self.dmg_team = 0;
 778                 self.ballistics_density = autocvar_g_ballistics_density_player;
 779
 780                 self.metertime = 0;
 781
 782                 self.runes = 0;
 783
 784                 self.deadflag = DEAD_NO;
 785
 786                 self.angles = spot.angles;
 787
 788                 self.angles_z = 0; // never spawn tilted even if the spot says to
 789                 self.fixangle = TRUE; // turn this way immediately
 790                 self.velocity = '0 0 0';
 791                 self.avelocity = '0 0 0';
 792                 self.punchangle = '0 0 0';
 793                 self.punchvector = '0 0 0';
 794                 self.oldvelocity = self.velocity;
 795                 self.fire_endtime = -1;
 796
 797                 msg_entity = self;
 798                 WRITESPECTATABLE_MSG_ONE({
 799                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 800                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 801                 });
 802
 803                 self.model = "";
 804                 FixPlayermodel();
 805                 self.drawonlytoclient = world;
 806
 807                 self.crouch = FALSE;
 808                 self.view_ofs = PL_VIEW_OFS;
 809                 setsize (self, PL_MIN, PL_MAX);
 810                 self.spawnorigin = spot.origin;
 811                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 812                 // don't reset back to last position, even if new position is stuck in solid
 813                 self.oldorigin = self.origin;
 814                 self.prevorigin = self.origin;
 815                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 816                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 817         self.hud = HUD_NORMAL;
 818
 819                 self.event_damage = PlayerDamage;
 820
 821                 self.bot_attack = TRUE;
 822
 823                 self.statdraintime = time + 5;
 824                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 825
 826                 if(self.killcount == -666) {
 827                         PlayerScore_Clear(self);
 828                         self.killcount = 0;
 829                 }
 830
 831                 CL_SpawnWeaponentity();
 832                 self.alpha = default_player_alpha;
 833                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 834                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 835
 836                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 837                 self.lms_traveled_distance = 0;
 838                 self.speedrunning = FALSE;
 839
 840                 race_PostSpawn(spot);
 841
 842                 //stuffcmd(self, "chase_active 0");
 843                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 844
 845                 if(g_assault) {
 846                         if(self.team == assault_attacker_team)
 847                                 centerprint(self, "You are attacking!");
 848                         else
 849                                 centerprint(self, "You are defending!");
 850                 }
 851
 852                 target_voicescript_clear(self);
 853
 854                 // reset fields the weapons may use
 855                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 856                 {
 857                         weapon_action(j, WR_RESETPLAYER);
 858
 859                         // all weapons must be fully loaded when we spawn
 860                         entity e;
 861                         e = get_weaponinfo(j);
 862                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 863                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 864                 }
 865
 866                 oldself = self;
 867                 self = spot;
 868                         activator = oldself;
 869                                 string s;
 870                                 s = self.target;
 871                                 self.target = string_null;
 872                                 SUB_UseTargets();
 873                                 self.target = s;
 874                         activator = world;
 875                 self = oldself;
 876
 877                 spawn_spot = spot;
 878                 MUTATOR_CALLHOOK(PlayerSpawn);
 879
 880                 if(autocvar_spawn_debug)
 881                 {
 882                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 883                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 884                 }
 885
 886                 self.switchweapon = w_getbestweapon(self);
 887                 self.cnt = -1; // W_LastWeapon will not complain
 888                 self.weapon = 0;
 889                 self.weaponname = "";
 890                 self.switchingweapon = 0;
 891
 892                 if(!inWarmupStage)
 893                         if(!self.alivetime)
 894                                 self.alivetime = time;
 895
 896                 antilag_clear(self);
 897
 898                 if (autocvar_g_spawnsound)
 899                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 900         } else if(self.classname == "observer") {
 901                 PutObserverInServer ();
 902         }
 903 }
 904
 905 .float ebouncefactor, ebouncestop; // electro's values
 906 // TODO do we need all these fields, or should we stop autodetecting runtime
 907 // changes and just have a console command to update this?
 908 float ClientInit_SendEntity(entity to, float sf)
 909 {
 910         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 911         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 912         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 913         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 914         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 915         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 916         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 917         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 918         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 919         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 920         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 921         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 922         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 923         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 924         if(sv_foginterval && world.fog != "")
 925                 WriteString(MSG_ENTITY, world.fog);
 926         else
 927                 WriteString(MSG_ENTITY, "");
 928         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 929         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 930         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 931         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 932         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 933         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 934         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 935         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 936         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 937         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 938         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 939         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 940         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 941         return TRUE;
 942 }
 943
 944 void ClientInit_CheckUpdate()
 945 {
 946         self.nextthink = time;
 947         if(self.count != autocvar_g_balance_armor_blockpercent)
 948         {
 949                 self.count = autocvar_g_balance_armor_blockpercent;
 950                 self.SendFlags |= 1;
 951         }
 952         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 953         {
 954                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 955                 self.SendFlags |= 1;
 956         }
 957         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 958         {
 959                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 960                 self.SendFlags |= 1;
 961         }
 962         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 963         {
 964                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 965                 self.SendFlags |= 1;
 966         }
 967         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 968         {
 969                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 970                 self.SendFlags |= 1;
 971         }
 972         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 973         {
 974                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 975                 self.SendFlags |= 1;
 976         }
 977 }
 978
 979 void ClientInit_Spawn()
 980 {
 981         entity o;
 982         entity e;
 983         e = spawn();
 984         e.classname = "clientinit";
 985         e.think = ClientInit_CheckUpdate;
 986         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 987
 988         o = self;
 989         self = e;
 990         ClientInit_CheckUpdate();
 991         self = o;
 992 }
 993
 994 /*
 995 =============
 996 SetNewParms
 997 =============
 998 */
 999 void SetNewParms (void)
1000 {
1001         // initialize parms for a new player
1002         parm1 = -(86400 * 366);
1003 }
1004
1005 /*
1006 =============
1007 SetChangeParms
1008 =============
1009 */
1010 void SetChangeParms (void)
1011 {
1012         // save parms for level change
1013         parm1 = self.parm_idlesince - time;
1014 }
1015
1016 /*
1017 =============
1018 DecodeLevelParms
1019 =============
1020 */
1021 void DecodeLevelParms (void)
1022 {
1023         // load parms
1024         self.parm_idlesince = parm1;
1025         if(self.parm_idlesince == -(86400 * 366))
1026                 self.parm_idlesince = time;
1027
1028         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1029         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1030 }
1031
1032 /*
1033 =============
1034 ClientKill
1035
1036 Called when a client types 'kill' in the console
1037 =============
1038 */
1039
1040 .float clientkill_nexttime;
1041 void ClientKill_Now_TeamChange()
1042 {
1043         if(self.killindicator_teamchange == -1)
1044         {
1045                 JoinBestTeam( self, FALSE, TRUE );
1046         }
1047         else if(self.killindicator_teamchange == -2)
1048         {
1049                 if(blockSpectators)
1050                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1051                 PutObserverInServer();
1052         }
1053         else
1054                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1055         self.killindicator_teamchange = 0;
1056 }
1057
1058 void ClientKill_Now()
1059 {
1060         if(self.vehicle)
1061         {
1062             vehicles_exit(VHEF_RELESE);
1063             if(!self.killindicator_teamchange)
1064             {
1065             self.vehicle_health = -1;
1066             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1067             }
1068         }
1069
1070         if(self.killindicator && !wasfreed(self.killindicator))
1071                 remove(self.killindicator);
1072
1073         self.killindicator = world;
1074
1075         if(self.killindicator_teamchange)
1076                 ClientKill_Now_TeamChange();
1077
1078         // in any case:
1079         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1080
1081         // now I am sure the player IS dead
1082 }
1083 void KillIndicator_Think()
1084 {
1085         if (gameover)
1086         {
1087                 self.owner.killindicator = world;
1088                 remove(self);
1089                 return;
1090         }
1091
1092         if (self.owner.alpha < 0 && !self.owner.vehicle)
1093         {
1094                 self.owner.killindicator = world;
1095                 remove(self);
1096                 return;
1097         }
1098
1099         if(self.cnt <= 0)
1100         {
1101                 self = self.owner;
1102                 ClientKill_Now(); // no oldself needed
1103                 return;
1104         }
1105     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1106     {
1107         self.nextthink = time + 1;
1108         self.cnt -= 1;
1109     }
1110         else
1111         {
1112                 if(self.cnt <= 10)
1113                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1114                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1115                 {
1116                         if(self.cnt <= 10)
1117                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1118                 }
1119                 self.nextthink = time + 1;
1120                 self.cnt -= 1;
1121         }
1122 }
1123
1124 float clientkilltime;
1125 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1126 {
1127         float killtime;
1128         float starttime;
1129         entity e;
1130
1131         if (gameover)
1132                 return;
1133
1134         killtime = autocvar_g_balance_kill_delay;
1135
1136         if(g_race_qualifying || g_cts)
1137                 killtime = 0;
1138
1139     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1140     {
1141                 remove(self.killindicator);
1142                 self.killindicator = world;
1143
1144         ClientKill_Now(); // allow instant kill in this case
1145         return;
1146     }
1147
1148         self.killindicator_teamchange = targetteam;
1149
1150     if(!self.killindicator)
1151         {
1152                 if(self.deadflag == DEAD_NO)
1153                 {
1154                         killtime = max(killtime, self.clientkill_nexttime - time);
1155                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1156                 }
1157
1158                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1159                 {
1160                         ClientKill_Now();
1161                 }
1162                 else
1163                 {
1164                         starttime = max(time, clientkilltime);
1165
1166                         self.killindicator = spawn();
1167                         self.killindicator.owner = self;
1168                         self.killindicator.scale = 0.5;
1169                         setattachment(self.killindicator, self, "");
1170                         setorigin(self.killindicator, '0 0 52');
1171                         self.killindicator.think = KillIndicator_Think;
1172                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1173                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1174                         self.killindicator.cnt = ceil(killtime);
1175                         self.killindicator.count = bound(0, ceil(killtime), 10);
1176                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1177
1178                         for(e = world; (e = find(e, classname, "body")) != world; )
1179                         {
1180                                 if(e.enemy != self)
1181                                         continue;
1182                                 e.killindicator = spawn();
1183                                 e.killindicator.owner = e;
1184                                 e.killindicator.scale = 0.5;
1185                                 setattachment(e.killindicator, e, "");
1186                                 setorigin(e.killindicator, '0 0 52');
1187                                 e.killindicator.think = KillIndicator_Think;
1188                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1189                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1190                                 e.killindicator.cnt = ceil(killtime);
1191                         }
1192                         self.lip = 0;
1193                 }
1194         }
1195         if(self.killindicator)
1196         {
1197                 if(targetteam == 0) // just die
1198                 {
1199                         self.killindicator.colormod = '0 0 0';
1200                         if(clienttype(self) == CLIENTTYPE_REAL)
1201                         if(self.killindicator.cnt > 0)
1202                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "^1Suicide in %d seconds", 1, self.killindicator.cnt);
1203                 }
1204                 else if(targetteam == -1) // auto
1205                 {
1206                         self.killindicator.colormod = '0 1 0';
1207                         if(clienttype(self) == CLIENTTYPE_REAL)
1208                         if(self.killindicator.cnt > 0)
1209                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Changing team in %d seconds", 1, self.killindicator.cnt);
1210                 }
1211                 else if(targetteam == -2) // spectate
1212                 {
1213                         self.killindicator.colormod = '0.5 0.5 0.5';
1214                         if(clienttype(self) == CLIENTTYPE_REAL)
1215                         if(self.killindicator.cnt > 0)
1216                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, "Spectating in %d seconds", 1, self.killindicator.cnt);
1217                 }
1218                 else
1219                 {
1220                         self.killindicator.colormod = TeamColor(targetteam);
1221                         if(clienttype(self) == CLIENTTYPE_REAL)
1222                         if(self.killindicator.cnt > 0)
1223                                 Send_CSQC_Centerprint_Generic(self, CPID_TEAMCHANGE, strcat("Changing to ", ColoredTeamName(targetteam), " in %d seconds"), 1, self.killindicator.cnt);
1224                 }
1225         }
1226
1227 }
1228
1229 void ClientKill (void)
1230 {
1231         if(gameover) return;
1232         if(self.player_blocked) return;
1233         if(self.freezetag_frozen) return;
1234
1235         ClientKill_TeamChange(0);
1236 }
1237
1238 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1239 {
1240     e.killindicator = spawn();
1241     e.killindicator.owner = e;
1242     e.killindicator.think = KillIndicator_Think;
1243     e.killindicator.nextthink = time + (e.lip) * 0.05;
1244     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1245     e.killindicator.health = 1; // this is used to indicate that it should be silent
1246     e.lip = 0;
1247 }
1248
1249 void FixClientCvars(entity e)
1250 {
1251         // send prediction settings to the client
1252         stuffcmd(e, "\nin_bindmap 0 0\n");
1253         if(g_race || g_cts)
1254                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1255         if(autocvar_g_antilag == 3) // client side hitscan
1256                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1257         if(sv_gentle)
1258                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1259         /*
1260          * we no longer need to stuff this. Remove this comment block if you feel
1261          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1262         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1263         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1264         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1265         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1266         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1267         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1268         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1269         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1270         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1271         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1272         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1273         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1274         stuffcmd(e, "cl_movement_edgefriction 1\n");
1275          */
1276 }
1277
1278 float PlayerInIDList(entity p, string idlist)
1279 {
1280         float n, i;
1281         string s;
1282
1283         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1284         if not(p.crypto_idfp)
1285                 return 0;
1286
1287         // this function allows abbreviated player IDs too!
1288         n = tokenize_console(idlist);
1289         for(i = 0; i < n; ++i)
1290         {
1291                 s = argv(i);
1292                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1293                         return 1;
1294         }
1295
1296         return 0;
1297 }
1298
1299 /*
1300 =============
1301 ClientConnect
1302
1303 Called when a client connects to the server
1304 =============
1305 */
1306 string ColoredTeamName(float t);
1307 void DecodeLevelParms (void);
1308 //void dom_player_join_team(entity pl);
1309 void set_dom_state(entity e);
1310 void ClientConnect (void)
1311 {
1312         float t;
1313
1314         if(self.flags & FL_CLIENT)
1315         {
1316                 print("Warning: ClientConnect, but already connected!\n");
1317                 return;
1318         }
1319
1320         if(Ban_MaybeEnforceBanOnce(self))
1321                 return;
1322
1323         DecodeLevelParms();
1324
1325 #ifdef WATERMARK
1326         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK, "\n"));
1327 #endif
1328
1329         self.classname = "player_joining";
1330
1331         self.flags = FL_CLIENT;
1332         self.version_nagtime = time + 10 + random() * 10;
1333
1334         if(player_count<0)
1335         {
1336                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1337                 player_count = 0;
1338         }
1339
1340         PlayerScore_Attach(self);
1341         ClientData_Attach();
1342         accuracy_init(self);
1343
1344         bot_clientconnect();
1345
1346         playerdemo_init();
1347
1348         anticheat_init();
1349
1350         race_PreSpawnObserver();
1351
1352         // identify the right forced team
1353         if(autocvar_g_campaign)
1354         {
1355                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1356                 {
1357                         switch(autocvar_g_campaign_forceteam)
1358                         {
1359                                 case 1: self.team_forced = COLOR_TEAM1; break;
1360                                 case 2: self.team_forced = COLOR_TEAM2; break;
1361                                 case 3: self.team_forced = COLOR_TEAM3; break;
1362                                 case 4: self.team_forced = COLOR_TEAM4; break;
1363                                 default: self.team_forced = 0;
1364                         }
1365                 }
1366         }
1367         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1368                 self.team_forced = COLOR_TEAM1;
1369         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1370                 self.team_forced = COLOR_TEAM2;
1371         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1372                 self.team_forced = COLOR_TEAM3;
1373         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1374                 self.team_forced = COLOR_TEAM4;
1375         else if(autocvar_g_forced_team_otherwise == "red")
1376                 self.team_forced = COLOR_TEAM1;
1377         else if(autocvar_g_forced_team_otherwise == "blue")
1378                 self.team_forced = COLOR_TEAM2;
1379         else if(autocvar_g_forced_team_otherwise == "yellow")
1380                 self.team_forced = COLOR_TEAM3;
1381         else if(autocvar_g_forced_team_otherwise == "pink")
1382                 self.team_forced = COLOR_TEAM4;
1383         else if(autocvar_g_forced_team_otherwise == "spectate")
1384                 self.team_forced = -1;
1385         else if(autocvar_g_forced_team_otherwise == "spectator")
1386                 self.team_forced = -1;
1387         else
1388                 self.team_forced = 0;
1389
1390         if(!teamplay)
1391                 if(self.team_forced > 0)
1392                         self.team_forced = 0;
1393
1394         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1395
1396         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1397                 self.classname = "observer";
1398         } else {
1399                 if(teamplay)
1400                 {
1401                         if(autocvar_g_balance_teams)
1402                         {
1403                                 self.classname = "player";
1404                                 campaign_bots_may_start = 1;
1405                         }
1406                         else
1407                         {
1408                                 self.classname = "observer"; // do it anyway
1409                         }
1410                 }
1411                 else
1412                 {
1413                         self.classname = "player";
1414                         campaign_bots_may_start = 1;
1415                 }
1416         }
1417
1418         self.playerid = (playerid_last = playerid_last + 1);
1419
1420         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1421
1422     if(clienttype(self) == CLIENTTYPE_BOT)
1423         PlayerStats_AddPlayer(self);
1424
1425         if(autocvar_sv_eventlog)
1426                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1427
1428         LogTeamchange(self.playerid, self.team, 1);
1429
1430         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1431
1432         self.netname_previous = strzone(self.netname);
1433
1434         bprint("^4", self.netname, "^4 connected");
1435
1436         if(self.classname != "observer" && (g_domination || g_ctf))
1437                 bprint(" and joined the ", ColoredTeamName(self.team));
1438
1439         bprint("\n");
1440
1441         stuffcmd(self, strcat(clientstuff, "\n"));
1442         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1443
1444         FixClientCvars(self);
1445
1446         // spawnfunc_waypoint sprites
1447         WaypointSprite_InitClient(self);
1448
1449         // Wazat's grappling hook
1450         SetGrappleHookBindings();
1451
1452         // get version info from player
1453         stuffcmd(self, "cmd clientversion $gameversion\n");
1454
1455         // get other cvars from player
1456         GetCvars(0);
1457
1458         // notify about available teams
1459         if(teamplay)
1460         {
1461                 CheckAllowedTeams(self);
1462                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1463                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1464         }
1465         else
1466                 stuffcmd(self, "set _teams_available 0\n");
1467
1468         attach_entcs();
1469
1470         bot_relinkplayerlist();
1471
1472         self.spectatortime = time;
1473         if(blockSpectators)
1474         {
1475                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1476         }
1477
1478         self.jointime = time;
1479         self.allowed_timeouts = autocvar_sv_timeout_number;
1480
1481         if(clienttype(self) == CLIENTTYPE_REAL)
1482         {
1483                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1484                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1485         }
1486
1487         if(g_lms)
1488         {
1489                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1490                 {
1491                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1492                         self.frags = FRAGS_SPECTATOR;
1493                 }
1494         }
1495
1496         if(!sv_foginterval && world.fog != "")
1497                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1498
1499         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1500         {
1501                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1502                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1503         }
1504         else
1505                 self.hitplotfh = -1;
1506
1507         if(g_race || g_cts) {
1508                 string rr;
1509                 if(g_cts)
1510                         rr = CTS_RECORD;
1511                 else
1512                         rr = RACE_RECORD;
1513
1514                 msg_entity = self;
1515                 race_send_recordtime(MSG_ONE);
1516                 race_send_speedaward(MSG_ONE);
1517
1518                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1519                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1520                 race_send_speedaward_alltimebest(MSG_ONE);
1521
1522                 float i;
1523                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1524                         race_SendRankings(i, 0, 0, MSG_ONE);
1525                 }
1526         }
1527         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1528                 send_CSQC_teamnagger();
1529
1530         CheatInitClient();
1531
1532         if(!autocvar_g_campaign)
1533                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), autocvar_welcome_message_time, 0);
1534
1535         CSQCMODEL_AUTOINIT();
1536
1537         self.model_randomizer = random();
1538
1539         if(clienttype(self) == CLIENTTYPE_REAL)
1540                 sv_notice_join();
1541
1542         MUTATOR_CALLHOOK(ClientConnect);
1543 }
1544 /*
1545 =============
1546 ClientDisconnect
1547
1548 Called when a client disconnects from the server
1549 =============
1550 */
1551 .entity chatbubbleentity;
1552 void ReadyCount();
1553 void ClientDisconnect (void)
1554 {
1555         if(self.vehicle)
1556             vehicles_exit(VHEF_RELESE);
1557
1558         if not(self.flags & FL_CLIENT)
1559         {
1560                 print("Warning: ClientDisconnect without ClientConnect\n");
1561                 return;
1562         }
1563
1564         PlayerStats_AddGlobalInfo(self);
1565
1566         CheatShutdownClient();
1567
1568         if(self.hitplotfh >= 0)
1569         {
1570                 fclose(self.hitplotfh);
1571                 self.hitplotfh = -1;
1572         }
1573
1574         anticheat_report();
1575         anticheat_shutdown();
1576
1577         playerdemo_shutdown();
1578
1579         bot_clientdisconnect();
1580
1581         if(self.entcs)
1582                 detach_entcs();
1583
1584         if(autocvar_sv_eventlog)
1585                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1586         bprint ("^4",self.netname);
1587         bprint ("^4 disconnected\n");
1588
1589         DropAllRunes(self);
1590         MUTATOR_CALLHOOK(ClientDisconnect);
1591
1592         Portal_ClearAll(self);
1593
1594         RemoveGrapplingHook(self);
1595
1596         // Here, everything has been done that requires this player to be a client.
1597
1598         self.flags &~= FL_CLIENT;
1599
1600         if (self.chatbubbleentity)
1601                 remove (self.chatbubbleentity);
1602
1603         if (self.killindicator)
1604                 remove (self.killindicator);
1605
1606         WaypointSprite_PlayerGone();
1607
1608         bot_relinkplayerlist();
1609
1610         accuracy_free(self);
1611         ClientData_Detach();
1612         PlayerScore_Detach(self);
1613
1614         if(self.netname_previous)
1615                 strunzone(self.netname_previous);
1616         if(self.clientstatus)
1617                 strunzone(self.clientstatus);
1618         if(self.weaponorder_byimpulse)
1619                 strunzone(self.weaponorder_byimpulse);
1620
1621         ClearPlayerSounds();
1622
1623         if(self.personal)
1624                 remove(self.personal);
1625
1626         self.playerid = 0;
1627         ReadyCount();
1628
1629         // free cvars
1630         GetCvars(-1);
1631 }
1632
1633 .float BUTTON_CHAT;
1634 void ChatBubbleThink()
1635 {
1636         self.nextthink = time;
1637         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1638         {
1639                 if(self.owner) // but why can that ever be world?
1640                         self.owner.chatbubbleentity = world;
1641                 remove(self);
1642                 return;
1643         }
1644         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1645 #ifdef TETRIS
1646                 || self.owner.tetris_on
1647 #endif
1648         )
1649                 self.model = self.mdl;
1650         else
1651                 self.model = "";
1652 }
1653
1654 void UpdateChatBubble()
1655 {
1656         if (self.alpha < 0)
1657                 return;
1658         // spawn a chatbubble entity if needed
1659         if (!self.chatbubbleentity)
1660         {
1661                 self.chatbubbleentity = spawn();
1662                 self.chatbubbleentity.owner = self;
1663                 self.chatbubbleentity.exteriormodeltoclient = self;
1664                 self.chatbubbleentity.think = ChatBubbleThink;
1665                 self.chatbubbleentity.nextthink = time;
1666                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1667                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1668                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1669                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1670                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1671                 self.chatbubbleentity.model = "";
1672                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1673         }
1674 }
1675
1676
1677 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1678 // added to the model skins
1679 /*void UpdateColorModHack()
1680 {
1681         float c;
1682         c = self.clientcolors & 15;
1683         // LordHavoc: only bothering to support white, green, red, yellow, blue
1684              if (!teamplay) self.colormod = '0 0 0';
1685         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1686         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1687         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1688         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1689         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1690         else self.colormod = '1 1 1';
1691 }*/
1692
1693 void respawn(void)
1694 {
1695         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1696         {
1697                 self.solid = SOLID_NOT;
1698                 self.takedamage = DAMAGE_NO;
1699                 self.movetype = MOVETYPE_FLY;
1700                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1701                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1702                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1703                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1704                 if(autocvar_g_respawn_ghosts_maxtime)
1705                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1706         }
1707
1708         CopyBody(1);
1709
1710         self.effects |= EF_NODRAW; // prevent another CopyBody
1711         PutClientInServer();
1712 }
1713
1714 void play_countdown(float finished, string samp)
1715 {
1716         if(clienttype(self) == CLIENTTYPE_REAL)
1717                 if(floor(finished - time - frametime) != floor(finished - time))
1718                         if(finished - time < 6)
1719                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1720 }
1721
1722 void player_powerups (void)
1723 {
1724         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1725         olditems = self.items;
1726
1727         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1728                 self.modelflags |= MF_ROCKET;
1729         else
1730                 self.modelflags &~= MF_ROCKET;
1731
1732         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1733
1734         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1735                 return;
1736
1737         Fire_ApplyDamage(self);
1738         Fire_ApplyEffect(self);
1739
1740         if (g_minstagib)
1741         {
1742                 self.effects |= EF_FULLBRIGHT;
1743
1744                 if (self.items & IT_STRENGTH)
1745                 {
1746                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1747                         if (time > self.strength_finished)
1748                         {
1749                                 self.alpha = default_player_alpha;
1750                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1751                                 self.items &~= IT_STRENGTH;
1752                                 sprint(self, "^3Invisibility has worn off\n");
1753                         }
1754                 }
1755                 else
1756                 {
1757                         if (time < self.strength_finished)
1758                         {
1759                                 self.alpha = g_minstagib_invis_alpha;
1760                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1761                                 self.items |= IT_STRENGTH;
1762                                 sprint(self, "^3You are invisible\n");
1763                         }
1764                 }
1765
1766                 if (self.items & IT_INVINCIBLE)
1767                 {
1768                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1769                         if (time > self.invincible_finished)
1770                         {
1771                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1772                                 sprint(self, "^3Speed has worn off\n");
1773                         }
1774                 }
1775                 else
1776                 {
1777                         if (time < self.invincible_finished)
1778                         {
1779                                 self.items = self.items | IT_INVINCIBLE;
1780                                 sprint(self, "^3You are on speed\n");
1781                         }
1782                 }
1783         }
1784         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1785         {
1786                 if (self.items & IT_STRENGTH)
1787                 {
1788                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1789                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1790                         if (time > self.strength_finished)
1791                         {
1792                                 self.items = self.items - (self.items & IT_STRENGTH);
1793                                 sprint(self, "^3Strength has worn off\n");
1794                         }
1795                 }
1796                 else
1797                 {
1798                         if (time < self.strength_finished)
1799                         {
1800                                 self.items = self.items | IT_STRENGTH;
1801                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
1802                         }
1803                 }
1804                 if (self.items & IT_INVINCIBLE)
1805                 {
1806                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1807                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1808                         if (time > self.invincible_finished)
1809                         {
1810                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1811                                 sprint(self, "^3Shield has worn off\n");
1812                         }
1813                 }
1814                 else
1815                 {
1816                         if (time < self.invincible_finished)
1817                         {
1818                                 self.items = self.items | IT_INVINCIBLE;
1819                                 sprint(self, "^3Shield surrounds you\n");
1820                         }
1821                 }
1822                 if (self.items & IT_SUPERWEAPON)
1823                 {
1824                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1825                         {
1826                                 self.superweapons_finished = 0;
1827                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1828                                 sprint(self, "^3Superweapons have been lost\n");
1829                         }
1830                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1831                         {
1832                                 // don't let them run out
1833                         }
1834                         else
1835                         {
1836                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1837                                 if (time > self.superweapons_finished)
1838                                 {
1839                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1840                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1841                                         sprint(self, "^3Superweapons have broken down\n");
1842                                 }
1843                         }
1844                 }
1845                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1846                 {
1847                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1848                         {
1849                                 self.items = self.items | IT_SUPERWEAPON;
1850                                 sprint(self, "^3You now have a superweapon\n");
1851                         }
1852                         else
1853                         {
1854                                 self.superweapons_finished = 0;
1855                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1856                         }
1857                 }
1858                 else
1859                 {
1860                         self.superweapons_finished = 0;
1861                 }
1862         }
1863
1864         if(autocvar_g_nodepthtestplayers)
1865                 self.effects = self.effects | EF_NODEPTHTEST;
1866
1867         if(autocvar_g_fullbrightplayers)
1868                 self.effects = self.effects | EF_FULLBRIGHT;
1869
1870         // midair gamemode: damage only while in the air
1871         // if in midair mode, being on ground grants temporary invulnerability
1872         // (this is so that multishot weapon don't clear the ground flag on the
1873         // first damage in the frame, leaving the player vulnerable to the
1874         // remaining hits in the same frame)
1875         if (self.flags & FL_ONGROUND)
1876         if (g_midair)
1877                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1878
1879         if (time >= game_starttime)
1880         if (time < self.spawnshieldtime)
1881                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1882
1883         MUTATOR_CALLHOOK(PlayerPowerups);
1884 }
1885
1886 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1887 {
1888         if(current > stable)
1889                 return current;
1890         else if(current > stable - 0.25) // when close enough, "snap"
1891                 return stable;
1892         else
1893                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1894 }
1895
1896 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1897 {
1898         if(current < stable)
1899                 return current;
1900         else if(current < stable + 0.25) // when close enough, "snap"
1901                 return stable;
1902         else
1903                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1904 }
1905
1906 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1907 {
1908         if(current > rotstable)
1909         {
1910                 if(rotframetime > 0)
1911                 {
1912                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1913                         current = max(rotstable, current - rotlinear * rotframetime);
1914                 }
1915         }
1916         else if(current < regenstable)
1917         {
1918                 if(regenframetime > 0)
1919                 {
1920                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1921                         current = min(regenstable, current + regenlinear * regenframetime);
1922                 }
1923         }
1924
1925         if(current > limit)
1926                 current = limit;
1927
1928         return current;
1929 }
1930
1931 void player_regen (void)
1932 {
1933         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1934         maxh = autocvar_g_balance_health_rotstable;
1935         maxa = autocvar_g_balance_armor_rotstable;
1936         maxf = autocvar_g_balance_fuel_rotstable;
1937         minh = autocvar_g_balance_health_regenstable;
1938         mina = autocvar_g_balance_armor_regenstable;
1939         minf = autocvar_g_balance_fuel_regenstable;
1940         limith = autocvar_g_balance_health_limit;
1941         limita = autocvar_g_balance_armor_limit;
1942         limitf = autocvar_g_balance_fuel_limit;
1943
1944         max_mod = regen_mod = rot_mod = limit_mod = 1;
1945
1946         if (self.runes & RUNE_REGEN)
1947         {
1948                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1949                 {
1950                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
1951                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
1952                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
1953                 }
1954                 else
1955                 {
1956                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
1957                         max_mod = autocvar_g_balance_rune_regen_hpmod;
1958                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
1959                 }
1960         }
1961         else if (self.runes & CURSE_VENOM)
1962         {
1963                 max_mod = autocvar_g_balance_curse_venom_hpmod;
1964                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1965                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
1966                 else
1967                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
1968                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
1969                 //if (!self.runes & RUNE_REGEN)
1970                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
1971         }
1972         maxh = maxh * max_mod;
1973         //maxa = maxa * max_mod;
1974         //maxf = maxf * max_mod;
1975         minh = minh * max_mod;
1976         //mina = mina * max_mod;
1977         //minf = minf * max_mod;
1978         limith = limith * limit_mod;
1979         limita = limita * limit_mod;
1980         //limitf = limitf * limit_mod;
1981
1982         if(g_ca)
1983                 rot_mod = 0;
1984
1985         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1986         {
1987                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1988                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1989
1990                 // if player rotted to death...  die!
1991                 if(self.health < 1)
1992                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1993         }
1994
1995         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1996                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1997 }
1998
1999 float zoomstate_set;
2000 void SetZoomState(float z)
2001 {
2002         if(z != self.zoomstate)
2003         {
2004                 self.zoomstate = z;
2005                 ClientData_Touch(self);
2006         }
2007         zoomstate_set = 1;
2008 }
2009
2010 void GetPressedKeys(void) {
2011         MUTATOR_CALLHOOK(GetPressedKeys);
2012         if (self.movement_x > 0) // get if movement keys are pressed
2013         {       // forward key pressed
2014                 self.pressedkeys |= KEY_FORWARD;
2015                 self.pressedkeys &~= KEY_BACKWARD;
2016         }
2017         else if (self.movement_x < 0)
2018         {       // backward key pressed
2019                 self.pressedkeys |= KEY_BACKWARD;
2020                 self.pressedkeys &~= KEY_FORWARD;
2021         }
2022         else
2023         {       // no x input
2024                 self.pressedkeys &~= KEY_FORWARD;
2025                 self.pressedkeys &~= KEY_BACKWARD;
2026         }
2027
2028         if (self.movement_y > 0)
2029         {       // right key pressed
2030                 self.pressedkeys |= KEY_RIGHT;
2031                 self.pressedkeys &~= KEY_LEFT;
2032         }
2033         else if (self.movement_y < 0)
2034         {       // left key pressed
2035                 self.pressedkeys |= KEY_LEFT;
2036                 self.pressedkeys &~= KEY_RIGHT;
2037         }
2038         else
2039         {       // no y input
2040                 self.pressedkeys &~= KEY_RIGHT;
2041                 self.pressedkeys &~= KEY_LEFT;
2042         }
2043
2044         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2045                 self.pressedkeys |= KEY_JUMP;
2046         else
2047                 self.pressedkeys &~= KEY_JUMP;
2048         if (self.BUTTON_CROUCH)
2049                 self.pressedkeys |= KEY_CROUCH;
2050         else
2051                 self.pressedkeys &~= KEY_CROUCH;
2052
2053         if (self.BUTTON_ATCK)
2054                 self.pressedkeys |= KEY_ATCK;
2055         else
2056                 self.pressedkeys &~= KEY_ATCK;
2057         if (self.BUTTON_ATCK2)
2058                 self.pressedkeys |= KEY_ATCK2;
2059         else
2060                 self.pressedkeys &~= KEY_ATCK2;
2061 }
2062
2063 /*
2064 ======================
2065 spectate mode routines
2066 ======================
2067 */
2068
2069 void SpectateCopy(entity spectatee) {
2070         other = spectatee;
2071         MUTATOR_CALLHOOK(SpectateCopy);
2072         self.armortype = spectatee.armortype;
2073         self.armorvalue = spectatee.armorvalue;
2074         self.ammo_cells = spectatee.ammo_cells;
2075         self.ammo_shells = spectatee.ammo_shells;
2076         self.ammo_nails = spectatee.ammo_nails;
2077         self.ammo_rockets = spectatee.ammo_rockets;
2078         self.ammo_fuel = spectatee.ammo_fuel;
2079         self.clip_load = spectatee.clip_load;
2080         self.clip_size = spectatee.clip_size;
2081         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2082         self.health = spectatee.health;
2083         self.impulse = 0;
2084         self.items = spectatee.items;
2085         self.last_pickup = spectatee.last_pickup;
2086         self.hit_time = spectatee.hit_time;
2087         self.metertime = spectatee.metertime;
2088         self.strength_finished = spectatee.strength_finished;
2089         self.invincible_finished = spectatee.invincible_finished;
2090         self.pressedkeys = spectatee.pressedkeys;
2091         WEPSET_COPY_EE(self, spectatee);
2092         self.switchweapon = spectatee.switchweapon;
2093         self.switchingweapon = spectatee.switchingweapon;
2094         self.weapon = spectatee.weapon;
2095         self.nex_charge = spectatee.nex_charge;
2096         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2097         self.hagar_load = spectatee.hagar_load;
2098         self.minelayer_mines = spectatee.minelayer_mines;
2099         self.punchangle = spectatee.punchangle;
2100         self.view_ofs = spectatee.view_ofs;
2101         self.velocity = spectatee.velocity;
2102         self.dmg_take = spectatee.dmg_take;
2103         self.dmg_save = spectatee.dmg_save;
2104         self.dmg_inflictor = spectatee.dmg_inflictor;
2105         self.v_angle = spectatee.v_angle;
2106         self.angles = spectatee.v_angle;
2107         self.stat_respawn_time = spectatee.stat_respawn_time;
2108         if(!self.BUTTON_USE)
2109                 self.fixangle = TRUE;
2110         setorigin(self, spectatee.origin);
2111         setsize(self, spectatee.mins, spectatee.maxs);
2112         SetZoomState(spectatee.zoomstate);
2113
2114     anticheat_spectatecopy(spectatee);
2115         self.hud = spectatee.hud;
2116         if(spectatee.vehicle)
2117     {
2118         self.fixangle = FALSE;
2119         //self.velocity = spectatee.vehicle.velocity;
2120         self.vehicle_health = spectatee.vehicle_health;
2121         self.vehicle_shield = spectatee.vehicle_shield;
2122         self.vehicle_energy = spectatee.vehicle_energy;
2123         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2124         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2125         self.vehicle_reload1 = spectatee.vehicle_reload1;
2126         self.vehicle_reload2 = spectatee.vehicle_reload2;
2127
2128         msg_entity = self;
2129
2130         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2131             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2132             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2133             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2134
2135         //WriteByte (MSG_ONE, SVC_SETVIEW);
2136         //    WriteEntity(MSG_ONE, self);
2137         //makevectors(spectatee.v_angle);
2138         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2139     }
2140 }
2141
2142 float SpectateUpdate() {
2143         if(!self.enemy)
2144             return 0;
2145
2146         if (self == self.enemy)
2147                 return 0;
2148
2149         if(self.enemy.classname != "player")
2150                 return 0;
2151
2152         SpectateCopy(self.enemy);
2153
2154         return 1;
2155 }
2156
2157
2158 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2159 entity CA_SpectateNext(entity start) {
2160         if (start.team == self.team) {
2161                 return start;
2162         }
2163
2164         other = start;
2165         // continue from current player
2166         while(other && other.team != self.team) {
2167                 other = find(other, classname, "player");
2168         }
2169
2170         if (!other) {
2171                 // restart from begining
2172                 other = find(other, classname, "player");
2173                 while(other && other.team != self.team) {
2174                         other = find(other, classname, "player");
2175                 }
2176         }
2177
2178         return other;
2179 }
2180
2181 float SpectateNext(entity _prefer) {
2182
2183         if(_prefer)
2184                 other = _prefer;
2185         else
2186                 other = find(self.enemy, classname, "player");
2187
2188         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2189                 // CA and ca players when spectating enemies is forbidden
2190                 other = CA_SpectateNext(other);
2191         } else {
2192                 // other modes and ca spectators or spectating enemies is allowed
2193                 if (!other)
2194                         other = find(other, classname, "player");
2195         }
2196
2197         if (other)
2198                 self.enemy = other;
2199
2200         if(self.enemy.classname == "player") {
2201             /*if(self.enemy.vehicle)
2202             {
2203
2204             msg_entity = self;
2205             WriteByte(MSG_ONE, SVC_SETVIEW);
2206             WriteEntity(MSG_ONE, self.enemy);
2207             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2208
2209             self.movetype = MOVETYPE_NONE;
2210             accuracy_resend(self);
2211             }
2212             else
2213             {*/
2214             msg_entity = self;
2215             WriteByte(MSG_ONE, SVC_SETVIEW);
2216             WriteEntity(MSG_ONE, self.enemy);
2217             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2218             self.movetype = MOVETYPE_NONE;
2219             accuracy_resend(self);
2220
2221             if(!SpectateUpdate())
2222                 PutObserverInServer();
2223         //}
2224         return 1;
2225         } else {
2226                 return 0;
2227         }
2228 }
2229
2230 /*
2231 =============
2232 ShowRespawnCountdown()
2233
2234 Update a respawn countdown display.
2235 =============
2236 */
2237 void ShowRespawnCountdown()
2238 {
2239         float number;
2240         if(self.deadflag == DEAD_NO) // just respawned?
2241                 return;
2242         else
2243         {
2244                 number = ceil(self.respawn_time - time);
2245                 if(number <= 0)
2246                         return;
2247                 if(number <= self.respawn_countdown)
2248                 {
2249                         self.respawn_countdown = number - 1;
2250                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2251                                 AnnounceTo(self, strcat(ftos(number), ""));
2252                 }
2253         }
2254 }
2255
2256 .float prevent_join_msgtime;
2257 void LeaveSpectatorMode()
2258 {
2259         if(self.caplayer)
2260                 return;
2261         if(nJoinAllowed(self)) {
2262                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2263                         self.classname = "player";
2264
2265                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2266                                 JoinBestTeam(self, FALSE, TRUE);
2267
2268                         if(autocvar_g_campaign)
2269                                 campaign_bots_may_start = 1;
2270
2271                         PutClientInServer();
2272
2273                         if(self.classname == "player")
2274                                 bprint ("^4", self.netname, "^4 is playing now\n");
2275
2276                         if(!autocvar_g_campaign)
2277                         if (time < self.jointime + autocvar_welcome_message_time)
2278                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD); // clear MOTD
2279
2280                         if (self.prevent_join_msgtime)
2281                         {
2282                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_PREVENT_JOIN);
2283                                 self.prevent_join_msgtime = 0;
2284                         }
2285                 } else {
2286                         stuffcmd(self, "menu_showteamselect\n");
2287                 }
2288         }
2289         else {
2290                 //player may not join because of g_maxplayers is set
2291                 if (time - self.prevent_join_msgtime > 2)
2292                 {
2293                         Send_CSQC_Centerprint_Generic(self, CPID_PREVENT_JOIN, PREVENT_JOIN_TEXT, 0, 0);
2294                         self.prevent_join_msgtime = time;
2295                 }
2296         }
2297 }
2298
2299 /**
2300  * Determines whether the player is allowed to join. This depends on cvar
2301  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2302  * it checks whether the number of currently playing players exceeds g_maxplayers.
2303  * @return int number of free slots for players, 0 if none
2304  */
2305 float nJoinAllowed(entity ignore) {
2306         if(!ignore)
2307         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2308         // so report 0 free slots if restricted
2309         {
2310                 if(autocvar_g_forced_team_otherwise == "spectate")
2311                         return 0;
2312                 if(autocvar_g_forced_team_otherwise == "spectator")
2313                         return 0;
2314         }
2315
2316         if(self.team_forced < 0)
2317                 return 0; // forced spectators can never join
2318
2319         // TODO simplify this
2320         entity e;
2321         float totalClients = 0;
2322         FOR_EACH_CLIENT(e)
2323                 if(e != ignore)
2324                         totalClients += 1;
2325
2326         if (!autocvar_g_maxplayers)
2327                 return maxclients - totalClients;
2328
2329         float currentlyPlaying = 0;
2330         FOR_EACH_REALCLIENT(e)
2331                 if(e.classname == "player" || e.caplayer == 1)
2332                         currentlyPlaying += 1;
2333
2334         if(currentlyPlaying < autocvar_g_maxplayers)
2335                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2336
2337         return 0;
2338 }
2339
2340 /**
2341  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2342  * g_maxplayers_spectator_blocktime seconds
2343  */
2344 void checkSpectatorBlock() {
2345         if(self.classname == "spectator" || self.classname == "observer") {
2346                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2347                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2348                         dropclient(self);
2349                 }
2350         }
2351 }
2352
2353 .float motd_actived_time; // used for both motd and campaign_message
2354 void PrintWelcomeMessage()
2355 {
2356         if (self.motd_actived_time == 0) { // is there already a message showing?
2357                 if (autocvar_g_campaign) {
2358                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2359                                 self.motd_actived_time = time;
2360                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, campaign_message, -1, 0);
2361                         }
2362                 } else {
2363                         if ((time - self.jointime > autocvar_welcome_message_time) && self.BUTTON_INFO) {
2364                                 self.motd_actived_time = time;
2365                                 Send_CSQC_Centerprint_Generic(self, CPID_MOTD, getwelcomemessage(), -1, 0);
2366                         }
2367                 }
2368         } else { // showing MOTD or campaign message
2369                 if (autocvar_g_campaign) {
2370                         if (self.BUTTON_INFO)
2371                                 self.motd_actived_time = time;
2372                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2373                                 self.motd_actived_time = 0;
2374                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2375                         }
2376                 } else {
2377                         if ((time - self.jointime) > autocvar_welcome_message_time) {
2378                                 if (self.BUTTON_INFO)
2379                                         self.motd_actived_time = time;
2380                                 else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2381                                         self.motd_actived_time = 0;
2382                                         Send_CSQC_Centerprint_Generic_Expire(self, CPID_MOTD);
2383                                 }
2384                         }
2385                 }
2386         }
2387 }
2388
2389 void ObserverThink()
2390 {
2391         float prefered_movetype;
2392         if (self.flags & FL_JUMPRELEASED) {
2393                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2394                         self.flags &~= FL_JUMPRELEASED;
2395                         self.flags |= FL_SPAWNING;
2396                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2397                         self.flags &~= FL_JUMPRELEASED;
2398                         if(SpectateNext(world) == 1) {
2399                                 self.classname = "spectator";
2400                         }
2401                 } else {
2402                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2403                         if (self.movetype != prefered_movetype)
2404                                 self.movetype = prefered_movetype;
2405                 }
2406         } else {
2407                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2408                         self.flags |= FL_JUMPRELEASED;
2409                         if(self.flags & FL_SPAWNING)
2410                         {
2411                                 self.flags &~= FL_SPAWNING;
2412                                 LeaveSpectatorMode();
2413                                 return;
2414                         }
2415                 }
2416         }
2417
2418         PrintWelcomeMessage();
2419 }
2420
2421 void SpectatorThink()
2422 {
2423         if (self.flags & FL_JUMPRELEASED) {
2424                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2425                         self.flags &~= FL_JUMPRELEASED;
2426                         self.flags |= FL_SPAWNING;
2427                 } else if(self.BUTTON_ATCK) {
2428                         self.flags &~= FL_JUMPRELEASED;
2429                         if(SpectateNext(world) == 1) {
2430                                 self.classname = "spectator";
2431                         } else {
2432                                 self.classname = "observer";
2433                                 PutClientInServer();
2434                         }
2435                 } else if (self.BUTTON_ATCK2) {
2436                         self.flags &~= FL_JUMPRELEASED;
2437                         self.classname = "observer";
2438                         PutClientInServer();
2439                 } else {
2440                         if(!SpectateUpdate())
2441                                 PutObserverInServer();
2442                 }
2443         } else {
2444                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2445                         self.flags |= FL_JUMPRELEASED;
2446                         if(self.flags & FL_SPAWNING)
2447                         {
2448                                 self.flags &~= FL_SPAWNING;
2449                                 LeaveSpectatorMode();
2450                                 return;
2451                         }
2452                 }
2453                 if(!SpectateUpdate())
2454                         PutObserverInServer();
2455         }
2456
2457         PrintWelcomeMessage();
2458         self.flags |= FL_CLIENT | FL_NOTARGET;
2459 }
2460
2461 void PlayerUseKey()
2462 {
2463         if(self.classname != "player")
2464                 return;
2465
2466         if(self.vehicle)
2467         {
2468         vehicles_exit(VHEF_NORMAL);
2469         return;
2470         }
2471
2472         // a use key was pressed; call handlers
2473         MUTATOR_CALLHOOK(PlayerUseKey);
2474 }
2475
2476 .float touchexplode_time;
2477
2478 /*
2479 =============
2480 PlayerPreThink
2481
2482 Called every frame for each client before the physics are run
2483 =============
2484 */
2485 .float usekeypressed;
2486 void() nexball_setstatus;
2487 .float items_added;
2488 void PlayerPreThink (void)
2489 {
2490         WarpZone_PlayerPhysics_FixVAngle();
2491
2492         self.stat_game_starttime = game_starttime;
2493         self.stat_round_starttime = round_starttime;
2494         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2495         self.stat_leadlimit = autocvar_leadlimit;
2496
2497         self.stat_respawn_time = self.respawn_time;
2498
2499         if(frametime)
2500         {
2501                 // physics frames: update anticheat stuff
2502                 anticheat_prethink();
2503         }
2504
2505         if(blockSpectators && frametime)
2506                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2507                 checkSpectatorBlock();
2508
2509         zoomstate_set = 0;
2510
2511         if(self.netname_previous != self.netname)
2512         {
2513                 if(autocvar_sv_eventlog)
2514                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2515                 if(self.netname_previous)
2516                         strunzone(self.netname_previous);
2517                 self.netname_previous = strzone(self.netname);
2518         }
2519
2520         // version nagging
2521         if(self.version_nagtime)
2522                 if(self.cvar_g_xonoticversion)
2523                         if(time > self.version_nagtime)
2524                         {
2525                                 // don't notify git users
2526                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2527                                 {
2528                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2529                                         {
2530                                                 // notify release users if connecting to git
2531                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2532                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2533                                         }
2534                                         else
2535                                         {
2536                                                 float r;
2537                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2538                                                 if(r < 0)
2539                                                 {
2540                                                         // give users new version
2541                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2542                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n"));
2543                                                 }
2544                                                 else if(r > 0)
2545                                                 {
2546                                                         // notify users about old server version
2547                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2548                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2549                                                 }
2550                                         }
2551                                 }
2552                                 self.version_nagtime = 0;
2553                         }
2554
2555         // GOD MODE info
2556         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2557         {
2558                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2559                 self.max_armorvalue = 0;
2560         }
2561
2562 #ifdef TETRIS
2563         if (TetrisPreFrame())
2564                 return;
2565 #endif
2566
2567         MUTATOR_CALLHOOK(PlayerPreThink);
2568
2569         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2570         {
2571                 if(self.BUTTON_USE && !self.usekeypressed)
2572                         PlayerUseKey();
2573                 self.usekeypressed = self.BUTTON_USE;
2574         }
2575
2576         PrintWelcomeMessage();
2577
2578         if(self.classname == "player") {
2579 //              if(self.netname == "Wazat")
2580 //                      bprint(self.classname, "\n");
2581
2582                 CheckRules_Player();
2583
2584                 if (intermission_running)
2585                 {
2586                         IntermissionThink ();   // otherwise a button could be missed between
2587                         return;                                 // the think tics
2588                 }
2589
2590                 //don't allow the player to turn around while game is paused!
2591                 if(timeout_status == TIMEOUT_ACTIVE) {
2592                         // FIXME turn this into CSQC stuff
2593                         self.v_angle = self.lastV_angle;
2594                         self.angles = self.lastV_angle;
2595                         self.fixangle = TRUE;
2596                 }
2597
2598                 if(frametime)
2599                 {
2600                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2601                         {
2602                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2603                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2604                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2605
2606                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2607                                 {
2608                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2609                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2610                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2611                                 }
2612                         }
2613                         else
2614                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2615
2616                         player_powerups();
2617                 }
2618
2619                 if (g_minstagib)
2620                         minstagib_ammocheck();
2621
2622                 if (self.deadflag != DEAD_NO)
2623                 {
2624                         float button_pressed, force_respawn;
2625                         if(self.personal && g_race_qualifying)
2626                         {
2627                                 if(time > self.respawn_time)
2628                                 {
2629                                         self.respawn_time = time + 1; // only retry once a second
2630                                         respawn();
2631                                         self.impulse = 141;
2632                                 }
2633                         }
2634                         else
2635                         {
2636                                 if(frametime)
2637                                         player_anim();
2638                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2639                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2640                                 if (self.deadflag == DEAD_DYING)
2641                                 {
2642                                         if(force_respawn)
2643                                                 self.deadflag = DEAD_RESPAWNING;
2644                                         else if(!button_pressed)
2645                                                 self.deadflag = DEAD_DEAD;
2646                                 }
2647                                 else if (self.deadflag == DEAD_DEAD)
2648                                 {
2649                                         if(button_pressed)
2650                                                 self.deadflag = DEAD_RESPAWNABLE;
2651                                 }
2652                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2653                                 {
2654                                         if(!button_pressed)
2655                                                 self.deadflag = DEAD_RESPAWNING;
2656                                 }
2657                                 else if (self.deadflag == DEAD_RESPAWNING)
2658                                 {
2659                                         if(time > self.respawn_time)
2660                                         {
2661                                                 self.respawn_time = time + 1; // only retry once a second
2662                                                 respawn();
2663                                         }
2664                                 }
2665                                 ShowRespawnCountdown();
2666                         }
2667
2668                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2669                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2670                                 self.stat_respawn_time *= -1;
2671
2672                         return;
2673                 }
2674                 // FIXME from now on self.deadflag is always 0 (and self.health is never < 1)
2675                 // so (self.deadflag == DEAD_NO) is always true in the code below
2676
2677                 if(g_touchexplode)
2678                 if(time > self.touchexplode_time)
2679                 if(self.classname == "player")
2680                 if(self.deadflag == DEAD_NO)
2681                 if not(IS_INDEPENDENT_PLAYER(self))
2682                 FOR_EACH_PLAYER(other) if(self != other)
2683                 {
2684                         if(time > other.touchexplode_time)
2685                         if(other.deadflag == DEAD_NO)
2686                         if not(IS_INDEPENDENT_PLAYER(other))
2687                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2688                         {
2689                                 PlayerTouchExplode(self, other);
2690                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2691                         }
2692                 }
2693
2694                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2695                 {
2696                         vector dist;
2697
2698                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2699                         dist = self.prevorigin - self.origin;
2700                         dist_z = 0;
2701                         self.lms_traveled_distance += fabs(vlen(dist));
2702
2703                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2704                         {
2705                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2706                                 self.lms_traveled_distance = 0;
2707                         }
2708
2709                         if(time > self.lms_nextcheck)
2710                         {
2711                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2712                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2713                                 {
2714                                         centerprint(self, autocvar_g_lms_campcheck_message);
2715                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2716                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2717                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2718                                 }
2719                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2720                                 self.lms_traveled_distance = 0;
2721                         }
2722                 }
2723
2724                 self.prevorigin = self.origin;
2725
2726                 float do_crouch = self.BUTTON_CROUCH;
2727                 if(self.hook.state)
2728                         do_crouch = 0;
2729                 if(self.health <= g_bloodloss)
2730                         do_crouch = 1;
2731                 if(self.vehicle)
2732                         do_crouch = 0;
2733                 if(self.freezetag_frozen)
2734                         do_crouch = 0;
2735                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2736                         do_crouch = 0;
2737
2738                 if (do_crouch)
2739                 {
2740                         if (!self.crouch)
2741                         {
2742                                 self.crouch = TRUE;
2743                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2744                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2745                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2746                         }
2747                 }
2748                 else
2749                 {
2750                         if (self.crouch)
2751                         {
2752                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2753                                 if (!trace_startsolid)
2754                                 {
2755                                         self.crouch = FALSE;
2756                                         self.view_ofs = PL_VIEW_OFS;
2757                                         setsize (self, PL_MIN, PL_MAX);
2758                                 }
2759                         }
2760                 }
2761
2762                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2763                 {
2764                         if(self.bloodloss_timer < time)
2765                         {
2766                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2767                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2768                         }
2769                 }
2770
2771                 FixPlayermodel();
2772
2773                 GrapplingHookFrame();
2774
2775                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2776                 //if(frametime)
2777                 {
2778                         self.items &~= self.items_added;
2779
2780                         W_WeaponFrame();
2781
2782                         self.items_added = 0;
2783                         if(self.items & IT_JETPACK)
2784                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2785                                         self.items_added |= IT_FUEL;
2786
2787                         self.items |= self.items_added;
2788                 }
2789
2790                 player_regen();
2791
2792                 // rot nex charge to the charge limit
2793                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2794                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2795
2796                 if(frametime)
2797                         player_anim();
2798
2799                 if(g_nexball)
2800                         nexball_setstatus();
2801
2802                 // secret status
2803                 secrets_setstatus();
2804
2805                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2806
2807                 //self.angles_y=self.v_angle_y + 90;   // temp
2808         } else if(gameover) {
2809                 if (intermission_running)
2810                         IntermissionThink ();   // otherwise a button could be missed between
2811                 return;
2812         } else if(self.classname == "observer") {
2813                 ObserverThink();
2814         } else if(self.classname == "spectator") {
2815                 SpectatorThink();
2816         }
2817
2818         if(!zoomstate_set)
2819                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2820
2821         float oldspectatee_status;
2822         oldspectatee_status = self.spectatee_status;
2823         if(self.classname == "spectator")
2824                 self.spectatee_status = num_for_edict(self.enemy);
2825         else if(self.classname == "observer")
2826                 self.spectatee_status = num_for_edict(self);
2827         else
2828                 self.spectatee_status = 0;
2829         if(self.spectatee_status != oldspectatee_status)
2830         {
2831                 ClientData_Touch(self);
2832                 if(g_race || g_cts)
2833                         race_InitSpectator();
2834         }
2835
2836         if(self.teamkill_soundtime)
2837         if(time > self.teamkill_soundtime)
2838         {
2839                 self.teamkill_soundtime = 0;
2840
2841                 entity oldpusher, oldself;
2842
2843                 oldself = self; self = self.teamkill_soundsource;
2844                 oldpusher = self.pusher; self.pusher = oldself;
2845
2846                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2847
2848                 self.pusher = oldpusher;
2849                 self = oldself;
2850         }
2851
2852         if(self.taunt_soundtime)
2853         if(time > self.taunt_soundtime)
2854         {
2855                 self.taunt_soundtime = 0;
2856                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2857         }
2858
2859         target_voicescript_next(self);
2860
2861         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2862         if(!self.weapon)
2863                 self.clip_load = self.clip_size = 0;
2864 }
2865
2866 float isInvisibleString(string s)
2867 {
2868         float i, n, c;
2869         s = strdecolorize(s);
2870         for((i = 0), (n = strlen(s)); i < n; ++i)
2871         {
2872                 c = str2chr(s, i);
2873                 switch(c)
2874                 {
2875                         case 0:
2876                         case 32: // space
2877                                 break;
2878                         case 192: // charmap space
2879                                 if (!autocvar_utf8_enable)
2880                                         break;
2881                                 return FALSE;
2882                         case 160: // space in unicode fonts
2883                         case 0xE000 + 192: // utf8 charmap space
2884                                 if (autocvar_utf8_enable)
2885                                         break;
2886                         default:
2887                                 return FALSE;
2888                 }
2889         }
2890         return TRUE;
2891 }
2892
2893 /*
2894 =============
2895 PlayerPostThink
2896
2897 Called every frame for each client after the physics are run
2898 =============
2899 */
2900 .float idlekick_lasttimeleft;
2901 void PlayerPostThink (void)
2902 {
2903         // Savage: Check for nameless players
2904         if (isInvisibleString(self.netname)) {
2905                 self.netname = "Player";
2906                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2907         }
2908
2909         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2910         {
2911                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2912                 {
2913                         if(self.idlekick_lasttimeleft)
2914                         {
2915                                 Send_CSQC_Centerprint_Generic_Expire(self, CPID_DISCONNECT_IDLING);
2916                                 self.idlekick_lasttimeleft = 0;
2917                         }
2918                 }
2919                 else
2920                 {
2921                         float timeleft;
2922                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2923                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2924                         {
2925                                 if(!self.idlekick_lasttimeleft)
2926                                         Send_CSQC_Centerprint_Generic(self, CPID_DISCONNECT_IDLING, "^3Stop idling!\n^3Disconnecting in %d seconds...", 1, timeleft);
2927                         }
2928                         if(timeleft <= 0)
2929                         {
2930                                 bprint("^3", self.netname, "^3 was kicked for idling.\n");
2931                                 AnnounceTo(self, "terminated");
2932                                 dropclient(self);
2933                                 return;
2934                         }
2935                         else if(timeleft <= 10)
2936                         {
2937                                 if(timeleft != self.idlekick_lasttimeleft)
2938                                         AnnounceTo(self, ftos(timeleft));
2939                                 self.idlekick_lasttimeleft = timeleft;
2940                         }
2941                 }
2942         }
2943
2944 #ifdef TETRIS
2945         if(self.impulse == 100)
2946                 ImpulseCommands();
2947         if (!TetrisPostFrame())
2948         {
2949 #endif
2950
2951         CheatFrame();
2952
2953         //CheckPlayerJump();
2954
2955         if(self.classname == "player") {
2956                 CheckRules_Player();
2957                 UpdateChatBubble();
2958                 if (self.impulse)
2959                         ImpulseCommands();
2960                 if (intermission_running)
2961                         return;         // intermission or finale
2962                 GetPressedKeys();
2963         }
2964
2965 #ifdef TETRIS
2966         }
2967 #endif
2968
2969         /*
2970         float i;
2971         for(i = 0; i < 1000; ++i)
2972         {
2973                 vector end;
2974                 end = self.origin + '0 0 1024' + 512 * randomvec();
2975                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2976                 if(trace_fraction < 1)
2977                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2978                 {
2979                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2980                         break;
2981                 }
2982         }
2983         */
2984
2985         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2986
2987         if(self.waypointsprite_attachedforcarrier)
2988                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2989
2990         playerdemo_write();
2991
2992         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2993         {
2994                 if not(self.stored_netname)
2995                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2996                 if(self.stored_netname != self.netname)
2997                 {
2998                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2999                         strunzone(self.stored_netname);
3000                         self.stored_netname = strzone(self.netname);
3001                 }
3002         }
3003
3004         /*
3005         if(g_race)
3006                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3007         */
3008
3009         CSQCMODEL_AUTOUPDATE();
3010 }