qcsrc/server/cheats.qc

   1 #include "cheats.qh"
   2
   3 #include "weapons/tracing.qh"
   4 #include <common/constants.qh>
   5 #include <common/deathtypes/all.qh>
   6 #include <common/effects/all.qh>
   7 #include <common/items/_mod.qh>
   8 #include <common/mapobjects/func/breakable.qh>
   9 #include <common/mapobjects/subs.qh>
  10 #include <common/mapobjects/teleporters.qh>
  11 #include <common/mapobjects/triggers.qh>
  12 #include <common/monsters/_mod.qh>
  13 #include <common/physics/player.qh>
  14 #include <common/stats.qh>
  15 #include <common/util.qh>
  16 #include <common/weapons/_all.qh>
  17 #include <common/weapons/_all.qh>
  18 #include <lib/csqcmodel/sv_model.qh>
  19 #include <lib/warpzone/anglestransform.qh>
  20 #include <lib/warpzone/common.qh>
  21 #include <lib/warpzone/util_server.qh>
  22 #include <server/clientkill.qh>
  23 #include <server/damage.qh>
  24 #include <server/main.qh>
  25 #include <server/mutators/_mod.qh>
  26 #include <server/player.qh>
  27 #include <server/race.qh>
  28 #include <server/resources.qh>
  29 #include <server/world.qh>
  30
  31 #ifdef NOCHEATS
  32
  33 float CheatImpulse(entity this, int imp) { return 0; }
  34 float CheatCommand(entity this, int argc) { return 0; }
  35 float CheatFrame(entity this) { return 0; }
  36 void CheatInit() { cheatcount_total = world.cheatcount; }
  37 void CheatShutdown() { }
  38 void Drag_MoveDrag(entity from, entity to) { }
  39
  40 #else
  41
  42 .bool maycheat;
  43 float gamestart_sv_cheats;
  44
  45
  46
  47 void CheatInit()
  48 {
  49         gamestart_sv_cheats = autocvar_sv_cheats;
  50 }
  51
  52 void CheatShutdown()
  53 {
  54 }
  55
  56 float CheatsAllowed(entity this, float i, int argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  57 {
  58         if(IS_DEAD(this))
  59                 return 0;
  60         if(gamestart_sv_cheats < 2 && !IS_PLAYER(this))
  61                 return 0;
  62
  63         if(i == CHIMPULSE_CLONE_MOVING.impulse || i == CHIMPULSE_CLONE_STANDING.impulse)
  64                 if(this.lip < autocvar_sv_clones)
  65                         return 1;
  66
  67         // haha
  68         if(this.maycheat)
  69                 return 1;
  70
  71         if(gamestart_sv_cheats && autocvar_sv_cheats)
  72                 return 1;
  73
  74         // if we get here, player is not allowed to cheat. Log it.
  75         if(i)
  76                 bprintf("Player %s^7 tried to use cheat 'impulse %d'\n", playername(this.netname, this.team, false), i);
  77         else if(argc)
  78                 bprintf("Player %s^7 tried to use cheat '%s'\n", playername(this.netname, this.team, false), argv(0));
  79         else if(fr)
  80                 bprintf("Player %s^7 tried to use cheat frame %d\n", playername(this.netname, this.team, false), fr);
  81         else
  82                 bprintf("Player %s^7 tried to use an unknown cheat\n", playername(this.netname, this.team, false));
  83
  84         return 0;
  85 }
  86
  87 #define BEGIN_CHEAT_FUNCTION() \
  88         float cheating = 0, attempting = 0
  89 #define DID_CHEAT() \
  90         ++cheating
  91 #define ADD_CHEATS(e,n) \
  92         cheatcount_total += n; \
  93         e.cheatcount += n
  94 #define END_CHEAT_FUNCTION() \
  95         ADD_CHEATS(this, cheating); \
  96         return attempting
  97 #define IS_CHEAT(ent,i,argc,fr) \
  98         if((++attempting, !CheatsAllowed(ent,i,argc,fr))) \
  99                 break
 100
 101 float num_autoscreenshot;
 102 void info_autoscreenshot_findtarget(entity this)
 103 {
 104         entity e;
 105         e = find(NULL, targetname, this.target);
 106         if(!e)
 107         {
 108                 objerror(this, "Missing target. FAIL!");
 109                 return;
 110         }
 111         vector a = vectoangles(e.origin - this.origin);
 112         a.x = -a.x; // don't ask
 113         this.angles_x = a.x;
 114         this.angles_y = a.y;
 115         // we leave Rick Roll alone
 116 }
 117 spawnfunc(info_autoscreenshot)
 118 {
 119         // this one just has to exist
 120         if(++num_autoscreenshot > autocvar_g_max_info_autoscreenshot)
 121         {
 122                 objerror(this, "Too many info_autoscreenshot entitites. FAIL!");
 123                 return;
 124         }
 125         if(this.target != "")
 126                 InitializeEntity(this, info_autoscreenshot_findtarget, INITPRIO_FINDTARGET);
 127 }
 128
 129 float CheatImpulse(entity this, int imp)
 130 {
 131         BEGIN_CHEAT_FUNCTION();
 132         switch(imp)
 133         {
 134                 entity e, e2;
 135
 136                 case CHIMPULSE_SPEEDRUN_INIT.impulse: // deploy personal waypoint
 137                         // shared with regular waypoint init, so this is not a cheat by itself
 138                         if(!this.personal)
 139                         {
 140                                 this.personal = new(personal_wp);
 141                         }
 142                         this.personal.origin = this.origin;
 143                         this.personal.v_angle = this.v_angle;
 144                         this.personal.velocity = this.velocity;
 145                         SetResource(this.personal, RES_ROCKETS, GetResource(this, RES_ROCKETS));
 146                         SetResource(this.personal, RES_BULLETS, GetResource(this, RES_BULLETS));
 147                         SetResource(this.personal, RES_CELLS, GetResource(this, RES_CELLS));
 148                         SetResource(this.personal, RES_PLASMA, GetResource(this, RES_PLASMA));
 149                         SetResource(this.personal, RES_SHELLS, GetResource(this, RES_SHELLS));
 150                         SetResource(this.personal, RES_FUEL, GetResource(this, RES_FUEL));
 151                         SetResource(this.personal, RES_HEALTH, max(1, GetResource(this, RES_HEALTH)));
 152                         SetResource(this.personal, RES_ARMOR, GetResource(this, RES_ARMOR));
 153                         STAT(WEAPONS, this.personal) = STAT(WEAPONS, this);
 154                         STAT(BUFFS, this.personal) = STAT(BUFFS, this);
 155                         STAT(BUFF_TIME, this.personal) = STAT(BUFF_TIME, this);
 156                         this.personal.items = this.items;
 157                         this.personal.pauserotarmor_finished = this.pauserotarmor_finished;
 158                         this.personal.pauserothealth_finished = this.pauserothealth_finished;
 159                         this.personal.pauserotfuel_finished = this.pauserotfuel_finished;
 160                         this.personal.pauseregen_finished = this.pauseregen_finished;
 161                         STAT(STRENGTH_FINISHED, this.personal) = STAT(STRENGTH_FINISHED, this);
 162                         STAT(INVINCIBLE_FINISHED, this.personal) = STAT(INVINCIBLE_FINISHED, this);
 163                         this.personal.teleport_time = time;
 164                         break; // this part itself doesn't cheat, so let's not count this
 165                 case CHIMPULSE_CLONE_MOVING.impulse:
 166                         IS_CHEAT(this, imp, 0, 0);
 167                         makevectors (this.v_angle);
 168                         this.velocity = this.velocity + v_forward * 300;
 169                         CopyBody(this, 1);
 170                         this.lip += 1;
 171                         this.velocity = this.velocity - v_forward * 300;
 172                         DID_CHEAT();
 173                         break;
 174                 case CHIMPULSE_CLONE_STANDING.impulse:
 175                         IS_CHEAT(this, imp, 0, 0);
 176                         CopyBody(this, 0);
 177                         this.lip += 1;
 178                         DID_CHEAT();
 179                         break;
 180                 case CHIMPULSE_GIVE_ALL.impulse:
 181                         IS_CHEAT(this, imp, 0, 0);
 182                         CheatCommand(this, tokenize_console("give all"));
 183                         break; // already counted as cheat
 184                 case CHIMPULSE_SPEEDRUN.impulse:
 185                         if(!autocvar_g_allow_checkpoints)
 186                                 IS_CHEAT(this, imp, 0, 0);
 187                         if(this.personal)
 188                         {
 189                                 this.speedrunning = true;
 190                                 tracebox(this.personal.origin, this.mins, this.maxs, this.personal.origin, MOVE_WORLDONLY, this);
 191                                 if(trace_startsolid)
 192                                 {
 193                                         sprint(this, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 194                                 }
 195                                 else
 196                                 {
 197                                         // Abort speedrun, teleport back
 198                                         setorigin(this, this.personal.origin);
 199                                         this.oldvelocity = this.velocity = this.personal.velocity;
 200                                         this.angles = this.personal.v_angle;
 201                                         this.fixangle = true;
 202
 203                                         MUTATOR_CALLHOOK(AbortSpeedrun, this);
 204                                 }
 205
 206                                 SetResource(this, RES_ROCKETS, GetResource(this.personal, RES_ROCKETS));
 207                                 SetResource(this, RES_BULLETS, GetResource(this.personal, RES_BULLETS));
 208                                 SetResource(this, RES_CELLS, GetResource(this.personal, RES_CELLS));
 209                                 SetResource(this, RES_PLASMA, GetResource(this.personal, RES_PLASMA));
 210                                 SetResource(this, RES_SHELLS, GetResource(this.personal, RES_SHELLS));
 211                                 SetResource(this, RES_FUEL, GetResource(this.personal, RES_FUEL));
 212                                 SetResource(this, RES_HEALTH, GetResource(this.personal, RES_HEALTH));
 213                                 SetResource(this, RES_ARMOR, GetResource(this.personal, RES_ARMOR));
 214                                 STAT(WEAPONS, this) = STAT(WEAPONS, this.personal);
 215                                 STAT(BUFFS, this) = STAT(BUFFS, this.personal);
 216                                 STAT(BUFF_TIME, this) = STAT(BUFF_TIME, this.personal);
 217                                 this.items = this.personal.items;
 218                                 this.pauserotarmor_finished = time + this.personal.pauserotarmor_finished - this.personal.teleport_time;
 219                                 this.pauserothealth_finished = time + this.personal.pauserothealth_finished - this.personal.teleport_time;
 220                                 this.pauserotfuel_finished = time + this.personal.pauserotfuel_finished - this.personal.teleport_time;
 221                                 this.pauseregen_finished = time + this.personal.pauseregen_finished - this.personal.teleport_time;
 222                                 STAT(STRENGTH_FINISHED, this) = time + STAT(STRENGTH_FINISHED, this.personal) - this.personal.teleport_time;
 223                                 STAT(INVINCIBLE_FINISHED, this) = time + STAT(INVINCIBLE_FINISHED, this.personal) - this.personal.teleport_time;
 224
 225                                 if(!autocvar_g_allow_checkpoints)
 226                                         DID_CHEAT();
 227                                 break;
 228                         }
 229                         if(IS_DEAD(this))
 230                                 sprint(this, "UR DEAD AHAHAH))\n");
 231                         else
 232                                 sprint(this, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 233                         break;
 234                 case CHIMPULSE_TELEPORT.impulse:
 235                         IS_CHEAT(this, imp, 0, 0);
 236                         if(this.move_movetype == MOVETYPE_NOCLIP)
 237                         {
 238                                 e = find(NULL, classname, "info_autoscreenshot");
 239                                 if(e)
 240                                 {
 241                                         sprint(this, "Emergency teleport used info_autoscreenshot location\n");
 242                                         setorigin(this, e.origin);
 243                                         this.angles = e.angles;
 244                                         delete(e);
 245                                         // should we? this.angles_x = -this.angles_x;
 246                                         this.fixangle = true;
 247                                         this.velocity = '0 0 0';
 248                                         DID_CHEAT();
 249                                         break;
 250                                 }
 251                         }
 252                         if(MoveToRandomMapLocation(this, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((gamestart_sv_cheats < 2) ? 100 : 100000), 384, 384))
 253                         {
 254                                 sprint(this, "Emergency teleport used random location\n");
 255                                 this.angles_x = -this.angles.x;
 256                                 this.fixangle = true;
 257                                 this.velocity = '0 0 0';
 258                                 DID_CHEAT();
 259                                 break;
 260                         }
 261                         sprint(this, "Emergency teleport could not find a good location, forget it!\n");
 262                         break;
 263                 case CHIMPULSE_R00T.impulse:
 264                         IS_CHEAT(this, imp, 0, 0);
 265                         RandomSelection_Init();
 266                         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it) && DIFF_TEAM(it, this), { RandomSelection_AddEnt(it, 1, 1); });
 267                         if(RandomSelection_chosen_ent)
 268                                 e = RandomSelection_chosen_ent;
 269                         else
 270                                 e = this;
 271
 272                         Send_Effect(EFFECT_ROCKET_EXPLODE, e.origin, '0 0 0', 1);
 273                         sound(e, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 274
 275                         e2 = spawn();
 276                         setorigin(e2, e.origin);
 277                         RadiusDamage(e2, this, 1000, 0, 128, NULL, NULL, 500, DEATH_CHEAT.m_id, DMG_NOWEP, e);
 278                         delete(e2);
 279
 280                         LOG_INFO("404 Sportsmanship not found.");
 281                         DID_CHEAT();
 282                         break;
 283         }
 284
 285         END_CHEAT_FUNCTION();
 286 }
 287
 288 float drag_lastcnt;
 289 float CheatCommand(entity this, int argc)
 290 {
 291         BEGIN_CHEAT_FUNCTION();
 292         string cmd;
 293         cmd = argv(0);
 294         switch(cmd)
 295         {
 296                 float effectnum, f;
 297                 vector start, end;
 298
 299                 case "pointparticles":
 300                         IS_CHEAT(this, 0, argc, 0);
 301                         if(argc == 5)
 302                         {
 303                                 // arguments:
 304                                 //   effectname
 305                                 //   origin (0..1, on crosshair line)
 306                                 //   velocity
 307                                 //   howmany
 308                                 f = stof(argv(2));
 309                                 crosshair_trace(this);
 310                                 start = (1-f) * this.origin + f * trace_endpos;
 311                                 end = stov(argv(3));
 312                                 f = stof(argv(4));
 313                                 Send_Effect_(argv(1), start, end, f);
 314                                 DID_CHEAT();
 315                                 break;
 316                         }
 317                         sprint(this, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 318                         break;
 319                 case "trailparticles":
 320                         IS_CHEAT(this, 0, argc, 0);
 321                         if(argc == 2)
 322                         {
 323                                 // arguments:
 324                                 //   effectname
 325                                 effectnum = _particleeffectnum(argv(1));
 326                                 W_SetupShot(this, weaponentities[0], false, false, SND_Null, CH_WEAPON_A, 0, 0);
 327                                 traceline(w_shotorg, w_shotorg + w_shotdir * max_shot_distance, MOVE_NORMAL, this);
 328                                 __trailparticles(this, effectnum, w_shotorg, trace_endpos);
 329                                 DID_CHEAT();
 330                                 break;
 331                         }
 332                         sprint(this, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 333                         break;
 334                 case "make":
 335                         IS_CHEAT(this, 0, argc, 0);
 336                         if(argc == 3)
 337                         {
 338                                 // arguments:
 339                                 //   modelname mode
 340                                 f = stof(argv(2));
 341                                 W_SetupShot(this, weaponentities[0], false, false, SND_Null, CH_WEAPON_A, 0, 0);
 342                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, this);
 343                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 344                                 {
 345                                         sprint(this, "cannot make stuff there (bad surface)\n");
 346                                 }
 347                                 else
 348                                 {
 349                                         entity e = spawn();
 350                                         e.model = strzone(argv(1));
 351                                         e.mdl = "rocket_explode";
 352                                         SetResourceExplicit(e, RES_HEALTH, 1000);
 353                                         setorigin(e, trace_endpos);
 354                                         e.effects = EF_NOMODELFLAGS;
 355                                         if(f == 1)
 356                                         {
 357                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 358                                                 e.angles = AnglesTransform_ApplyToAngles(e.angles, '-90 0 0'); // so unrotated models work
 359                                         }
 360                                         spawnfunc_func_breakable(e);
 361                                         // now, is it valid?
 362                                         if(f == 0)
 363                                         {
 364                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 365                                                 if(trace_startsolid)
 366                                                 {
 367                                                         delete(e);
 368                                                         sprint(this, "cannot make stuff there (no space)\n");
 369                                                 }
 370                                                 else
 371                                                         DID_CHEAT();
 372                                         }
 373                                         else
 374                                                 DID_CHEAT();
 375                                 }
 376                         }
 377                         else
 378                                 sprint(this, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 379                         break;
 380                 case "penalty":
 381                         IS_CHEAT(this, 0, argc, 0);
 382                         if(argc == 3)
 383                         {
 384                                 race_ImposePenaltyTime(this, stof(argv(1)), argv(2));
 385                                 DID_CHEAT();
 386                                 break;
 387                         }
 388                         sprint(this, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 389                         break;
 390                 case "dragbox_spawn": {
 391                         IS_CHEAT(this, 0, argc, 0);
 392                         entity e = new(dragbox_box);
 393                         setthink(e, DragBox_Think);
 394                         e.nextthink = time;
 395                         e.solid = -1; // black
 396                         setmodel(e, MDL_Null); // network it
 397                         if(argc == 4)
 398                                 e.cnt = stof(argv(1));
 399                         else
 400                                 e.cnt = max(0, drag_lastcnt);
 401
 402                         e.aiment = new(dragbox_corner_1);
 403                         e.aiment.owner = e;
 404                         setmodel(e.aiment, MDL_MARKER);
 405                         e.aiment.skin = 0;
 406                         setsize(e.aiment, '0 0 0', '0 0 0');
 407                         if(argc == 4)
 408                                 setorigin(e.aiment, stov(argv(2)));
 409                         else
 410                         {
 411                                 crosshair_trace(this);
 412                                 setorigin(e.aiment, trace_endpos);
 413                         }
 414
 415                         e.enemy = new(dragbox_corner_2);
 416                         e.enemy.owner = e;
 417                         setmodel(e.enemy, MDL_MARKER);
 418                         e.enemy.skin = 1;
 419                         setsize(e.enemy, '0 0 0', '0 0 0');
 420                         end = normalize(this.origin + this.view_ofs - e.aiment.origin);
 421                         end.x = (end.x > 0) * 2 - 1;
 422                         end.y = (end.y > 0) * 2 - 1;
 423                         end.z = (end.z > 0) * 2 - 1;
 424                         if(argc == 4)
 425                                 setorigin(e.enemy, stov(argv(3)));
 426                         else
 427                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 428
 429                         e.killindicator = new(drag_digit);
 430                         e.killindicator.owner = e;
 431                         setattachment(e.killindicator, e, "");
 432                         setorigin(e.killindicator, '0 0 -8');
 433                         e.killindicator.killindicator = new(drag_digit);
 434                         e.killindicator.killindicator.owner = e;
 435                         setattachment(e.killindicator.killindicator, e, "");
 436                         setorigin(e.killindicator.killindicator, '0 0 8');
 437                         DID_CHEAT();
 438                         break;
 439                 }
 440                 case "dragpoint_spawn": {
 441                         IS_CHEAT(this, 0, argc, 0);
 442                         entity e = new(dragpoint);
 443                         setthink(e, DragBox_Think);
 444                         e.nextthink = time;
 445                         e.solid = 0; // nothing special
 446                         setmodel(e, MDL_MARKER);
 447                         setsize(e, STAT(PL_MIN, this), STAT(PL_MAX, this));
 448                         e.skin = 2;
 449                         if(argc == 3)
 450                                 e.cnt = stof(argv(1));
 451                         else
 452                                 e.cnt = drag_lastcnt;
 453                         if(argc == 3)
 454                                 setorigin(e, stov(argv(2)));
 455                         else
 456                         {
 457                                 crosshair_trace(this);
 458                                 setorigin(e, trace_endpos + normalize(this.origin + this.view_ofs - trace_endpos));
 459                                 move_out_of_solid(e);
 460                         }
 461
 462                         e.killindicator = new(drag_digit);
 463                         e.killindicator.owner = e;
 464                         setattachment(e.killindicator, e, "");
 465                         setorigin(e.killindicator, '0 0 40');
 466                         e.killindicator.killindicator = new(drag_digit);
 467                         e.killindicator.killindicator.owner = e;
 468                         setattachment(e.killindicator.killindicator, e, "");
 469                         setorigin(e.killindicator.killindicator, '0 0 56');
 470                         DID_CHEAT();
 471                         break;
 472                 }
 473                 case "drag_remove":
 474                         IS_CHEAT(this, 0, argc, 0);
 475                         RandomSelection_Init();
 476                         crosshair_trace(this);
 477                         for(entity e = NULL; (e = find(e, classname, "dragbox_box")); )
 478                                 RandomSelection_AddEnt(e, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 479                         for(entity e = NULL; (e = find(e, classname, "dragpoint")); )
 480                                 RandomSelection_AddEnt(e, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 481                         if(RandomSelection_chosen_ent)
 482                         {
 483                                 delete(RandomSelection_chosen_ent.killindicator.killindicator);
 484                                 delete(RandomSelection_chosen_ent.killindicator);
 485                                 if(RandomSelection_chosen_ent.aiment)
 486                                         delete(RandomSelection_chosen_ent.aiment);
 487                                 if(RandomSelection_chosen_ent.enemy)
 488                                         delete(RandomSelection_chosen_ent.enemy);
 489                                 delete(RandomSelection_chosen_ent);
 490                         }
 491                         DID_CHEAT();
 492                         break;
 493                 case "drag_setcnt":
 494                         IS_CHEAT(this, 0, argc, 0);
 495                         if(argc == 2)
 496                         {
 497                                 RandomSelection_Init();
 498                                 crosshair_trace(this);
 499                                 for(entity e = NULL; (e = find(e, classname, "dragbox_box")); )
 500                                         RandomSelection_AddEnt(e, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 501                                 for(entity e = NULL; (e = find(e, classname, "dragpoint")); )
 502                                         RandomSelection_AddEnt(e, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 503                                 if(RandomSelection_chosen_ent)
 504                                 {
 505                                         if(substring(argv(1), 0, 1) == "*")
 506                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 507                                         else
 508                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 509                                 }
 510                                 DID_CHEAT();
 511                                 break;
 512                         }
 513                         sprint(this, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 514                         break;
 515                 case "drag_save":
 516                         IS_CHEAT(this, 0, argc, 0);
 517                         if(argc == 2)
 518                         {
 519                                 f = fopen(argv(1), FILE_WRITE);
 520                                 fputs(f, "cmd drag_clear\n");
 521                                 for(entity e = NULL; (e = find(e, classname, "dragbox_box")); )
 522                                 {
 523                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 524                                 }
 525                                 for(entity e = NULL; (e = find(e, classname, "dragpoint")); )
 526                                 {
 527                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 528                                 }
 529                                 fclose(f);
 530                                 DID_CHEAT();
 531                                 break;
 532                         }
 533                         sprint(this, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 534                         break;
 535                 case "drag_saveraceent":
 536                         IS_CHEAT(this, 0, argc, 0);
 537                         if(argc == 2)
 538                         {
 539                                 f = fopen(argv(1), FILE_WRITE);
 540                                 for(entity e = NULL; (e = find(e, classname, "dragbox_box")); )
 541                                 {
 542                                         fputs(f, "{\n");
 543                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 544                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin.x), " ", ftos(e.absmin.y), " ", ftos(e.absmin.z), "\"\n"));
 545                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax.x - e.absmin.x), " ", ftos(e.absmax.y - e.absmin.y), " ", ftos(e.absmax.z - e.absmin.z), "\"\n"));
 546                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 547                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 548                                         fputs(f, "}\n");
 549                                 }
 550                                 for(entity e = NULL; (e = find(e, classname, "dragpoint")); )
 551                                 {
 552                                         start = '0 0 0';
 553                                         effectnum = 0;
 554                                         for(entity ent = NULL; (ent = find(ent, classname, "dragbox_box")); )
 555                                         {
 556                                                 if((e.cnt <= 0 && ent.cnt == 0) || e.cnt == ent.cnt)
 557                                                 {
 558                                                         start = start + ent.origin;
 559                                                         ++effectnum;
 560                                                 }
 561                                         }
 562                                         start *= 1 / effectnum;
 563                                         fputs(f, "{\n");
 564                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 565                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 566                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin.x), " ", ftos(e.origin.y), " ", ftos(e.origin.z), "\"\n"));
 567                                         if(e.cnt == -2)
 568                                         {
 569                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 570                                                 fputs(f, "\"race_place\" \"0\"\n");
 571                                         }
 572                                         else if(e.cnt == -1)
 573                                         {
 574                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 575                                                 fputs(f, "\"race_place\" \"-1\"\n");
 576                                         }
 577                                         else
 578                                         {
 579                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 580                                                 if(e.cnt == 0)
 581                                                 {
 582                                                         // these need race_place
 583                                                         // counting...
 584                                                         effectnum = 1;
 585                                                         for(entity ent = NULL; (ent = find(ent, classname, "dragpoint")); )
 586                                                         if(ent.cnt == 0)
 587                                                         {
 588                                                                 if(vlen2(ent.origin - start) < vlen2(e.origin - start))
 589                                                                         ++effectnum;
 590                                                                 else if(vlen2(ent.origin - start) == vlen2(e.origin - start) && etof(ent) < etof(e))
 591                                                                         ++effectnum;
 592                                                         }
 593                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 594                                                 }
 595                                         }
 596                                         fputs(f, "}\n");
 597                                 }
 598                                 fclose(f);
 599                                 DID_CHEAT();
 600                                 break;
 601                         }
 602                         sprint(this, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 603                         break;
 604                 case "drag_clear":
 605                         IS_CHEAT(this, 0, argc, 0);
 606                         for(entity e = NULL; (e = find(e, classname, "dragbox_box")); )
 607                                 delete(e);
 608                         for(entity e = NULL; (e = find(e, classname, "dragbox_corner_1")); )
 609                                 delete(e);
 610                         for(entity e = NULL; (e = find(e, classname, "dragbox_corner_2")); )
 611                                 delete(e);
 612                         for(entity e = NULL; (e = find(e, classname, "dragpoint")); )
 613                                 delete(e);
 614                         for(entity e = NULL; (e = find(e, classname, "drag_digit")); )
 615                                 delete(e);
 616                         DID_CHEAT();
 617                         break;
 618                 case "god":
 619                         IS_CHEAT(this, 0, argc, 0);
 620                         BITXOR_ASSIGN(this.flags, FL_GODMODE);
 621                         if(this.flags & FL_GODMODE)
 622                         {
 623                                 sprint(this, "godmode ON\n");
 624                                 DID_CHEAT();
 625                         }
 626                         else
 627                                 sprint(this, "godmode OFF\n");
 628                         break;
 629                 case "notarget":
 630                         IS_CHEAT(this, 0, argc, 0);
 631                         BITXOR_ASSIGN(this.flags, FL_NOTARGET);
 632                         if(this.flags & FL_NOTARGET)
 633                         {
 634                                 sprint(this, "notarget ON\n");
 635                                 DID_CHEAT();
 636                         }
 637                         else
 638                                 sprint(this, "notarget OFF\n");
 639                         break;
 640                 case "noclip":
 641                         IS_CHEAT(this, 0, argc, 0);
 642                         if(this.move_movetype != MOVETYPE_NOCLIP)
 643                         {
 644                                 set_movetype(this, MOVETYPE_NOCLIP);
 645                                 sprint(this, "noclip ON\n");
 646                                 DID_CHEAT();
 647                         }
 648                         else
 649                         {
 650                                 set_movetype(this, MOVETYPE_WALK);
 651                                 sprint(this, "noclip OFF\n");
 652                         }
 653                         break;
 654                 case "fly":
 655                         IS_CHEAT(this, 0, argc, 0);
 656                         if(this.move_movetype != MOVETYPE_FLY)
 657                         {
 658                                 set_movetype(this, MOVETYPE_FLY);
 659                                 sprint(this, "flymode ON\n");
 660                                 DID_CHEAT();
 661                         }
 662                         else
 663                         {
 664                                 set_movetype(this, MOVETYPE_WALK);
 665                                 sprint(this, "flymode OFF\n");
 666                         }
 667                         break;
 668                 case "give":
 669                         IS_CHEAT(this, 0, argc, 0);
 670                         if(GiveItems(this, 1, argc))
 671                                 DID_CHEAT();
 672                         break;
 673                 case "usetarget":
 674                         IS_CHEAT(this, 0, argc, 0);
 675                         entity e = spawn();
 676                         e.target = argv(1);
 677                         SUB_UseTargets(e, this, NULL);
 678                         delete(e);
 679                         DID_CHEAT();
 680                         break;
 681                 case "killtarget":
 682                         IS_CHEAT(this, 0, argc, 0);
 683                         entity e2 = spawn();
 684                         e2.killtarget = argv(1);
 685                         SUB_UseTargets(e2, this, NULL);
 686                         delete(e2);
 687                         DID_CHEAT();
 688                         break;
 689                 case "teleporttotarget":
 690                         IS_CHEAT(this, 0, argc, 0);
 691                         entity ent = new(cheattriggerteleport);
 692                         setorigin(ent, ent.origin);
 693                         ent.target = argv(1);
 694                         teleport_findtarget(ent);
 695                         if(!wasfreed(ent))
 696                         {
 697                                 Simple_TeleportPlayer(ent, this);
 698                                 delete(ent);
 699                                 DID_CHEAT();
 700                         }
 701                         break;
 702         }
 703
 704         END_CHEAT_FUNCTION();
 705 }
 706
 707 .entity dragentity;
 708
 709 float CheatFrame(entity this)
 710 {
 711         BEGIN_CHEAT_FUNCTION();
 712
 713         // Dragging can be used as either a cheat, or a function for some objects. If sv_cheats is active,
 714         // the cheat dragging is used (unlimited pickup range and any entity can be carried). If sv_cheats
 715         // is disabled, normal dragging is used (limited pickup range and only dragable objects can be carried),
 716         // grabbing itself no longer being accounted as cheating.
 717
 718         switch(0)
 719         {
 720                 default:
 721                         if(this.maycheat || (gamestart_sv_cheats && autocvar_sv_cheats))
 722                         {
 723                                 // use cheat dragging if cheats are enabled
 724                                 //if(Drag_IsDragging(this))
 725                                         //crosshair_trace_plusvisibletriggers(this);
 726                                 Drag(this, true, true);
 727                         }
 728                         else
 729                         {
 730                                 Drag(this, false, false); // execute dragging
 731                         }
 732                         break;
 733         }
 734
 735         END_CHEAT_FUNCTION();
 736 }
 737
 738
 739
 740
 741
 742 // ENTITY DRAGGING
 743
 744 // on dragger:
 745 .float draggravity;
 746 .float dragspeed; // speed of mouse wheel action
 747 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 748 .vector draglocalvector; // local attachment vector of the dragentity
 749 .float draglocalangle;
 750 // on draggee:
 751 .entity draggedby;
 752 .float dragmovetype;
 753
 754 float Drag(entity this, float force_allow_pick, float ischeat)
 755 {
 756         BEGIN_CHEAT_FUNCTION();
 757
 758         // returns true when an entity has been picked up
 759         // If pick is true, the object can also be picked up if it's not being held already
 760         // If pick is false, only keep dragging the object if it's already being held
 761
 762         switch(0)
 763         {
 764                 default:
 765                         if(Drag_IsDragging(this))
 766                         {
 767                                 if(PHYS_INPUT_BUTTON_DRAG(this))
 768                                 {
 769                                         if(CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18)
 770                                         {
 771                                                 Drag_MoveForward(this);
 772                                                 CS(this).impulse = 0;
 773                                         }
 774                                         else if(CS(this).impulse == 12 || CS(this).impulse == 16 || CS(this).impulse == 19)
 775                                         {
 776                                                 Drag_MoveBackward(this);
 777                                                 CS(this).impulse = 0;
 778                                         }
 779                                         else if(CS(this).impulse >= 1 && CS(this).impulse <= 9)
 780                                         {
 781                                                 Drag_SetSpeed(this, CS(this).impulse - 1);
 782                                         }
 783                                         else if(CS(this).impulse == 14)
 784                                         {
 785                                                 Drag_SetSpeed(this, 9);
 786                                         }
 787
 788                                         if(frametime)
 789                                                 Drag_Update(this);
 790                                 }
 791                                 else
 792                                 {
 793                                         Drag_Finish(this);
 794                                 }
 795                         }
 796                         else if(Drag_CanDrag(this) && PHYS_INPUT_BUTTON_DRAG(this))
 797                         {
 798                                 crosshair_trace_plusvisibletriggers(this);
 799                                 entity e = trace_ent;
 800                                 float pick = force_allow_pick;
 801                                 if (e && !pick && vdist(this.origin - e.origin, <=, autocvar_g_grab_range))
 802                                 {
 803                                         // pick is true if the object can be picked up. While an object is being carried, the Drag() function
 804                                         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 805                                         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 806                                         // it goes out of range while slinging it around.
 807
 808                                         switch(e.grab)
 809                                         {
 810                                                 case 0: // can't grab
 811                                                         break;
 812                                                 case 1: // owner can grab
 813                                                         if(e.owner == this || e.realowner == this)
 814                                                                 pick = true;
 815                                                         break;
 816                                                 case 2: // owner and team mates can grab
 817                                                         if(SAME_TEAM(e.owner, this) || SAME_TEAM(e.realowner, this) || e.team == this.team)
 818                                                                 pick = true;
 819                                                         break;
 820                                                 case 3: // anyone can grab
 821                                                         pick = true;
 822                                                         break;
 823                                                 default:
 824                                                         break;
 825                                         }
 826                                 }
 827                                 // Find e and pick
 828                                 if(e && pick && Drag_IsDraggable(e, this))
 829                                 {
 830                                         if(ischeat)
 831                                                 IS_CHEAT(this, 0, 0, CHRAME_DRAG);
 832                                         if(e.draggedby)
 833                                                 Drag_Finish(e.draggedby);
 834                                         if(e.tag_entity)
 835                                                 detach_sameorigin(e);
 836                                         Drag_Begin(this, e, trace_endpos);
 837                                         if(ischeat)
 838                                                 DID_CHEAT();
 839                                         return true;
 840                                 }
 841                         }
 842                         break;
 843         }
 844         return false;
 845 }
 846
 847 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 848 {
 849         float tagscale;
 850
 851         draggee.dragmovetype = draggee.move_movetype;
 852         draggee.draggravity = draggee.gravity;
 853         set_movetype(draggee, MOVETYPE_WALK);
 854         draggee.gravity = 0.00001;
 855         UNSET_ONGROUND(draggee);
 856         draggee.draggedby = dragger;
 857
 858         dragger.dragentity = draggee;
 859
 860         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 861         dragger.draglocalangle = draggee.angles.y - dragger.v_angle.y;
 862         touchpoint = touchpoint - gettaginfo(draggee, 0);
 863         tagscale = (vlen(v_forward) ** -2);
 864         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 865         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 866         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 867
 868         dragger.dragspeed = 64;
 869 }
 870
 871 void Drag_Finish(entity dragger)
 872 {
 873         entity draggee;
 874         draggee = dragger.dragentity;
 875         if(dragger)
 876                 dragger.dragentity = NULL;
 877         draggee.draggedby = NULL;
 878         set_movetype(draggee, draggee.dragmovetype);
 879         draggee.gravity = draggee.draggravity;
 880
 881         switch(draggee.move_movetype)
 882         {
 883                 case MOVETYPE_TOSS:
 884                 case MOVETYPE_WALK:
 885                 case MOVETYPE_STEP:
 886                 case MOVETYPE_FLYMISSILE:
 887                 case MOVETYPE_BOUNCE:
 888                 case MOVETYPE_BOUNCEMISSILE:
 889                 case MOVETYPE_PHYSICS:
 890                         break;
 891                 default:
 892                         draggee.velocity = '0 0 0';
 893                         break;
 894         }
 895
 896         if((draggee.flags & FL_ITEM) && (vdist(draggee.velocity, <, 32)))
 897         {
 898                 draggee.velocity = '0 0 0';
 899                 SET_ONGROUND(draggee); // floating items are FUN
 900         }
 901 }
 902
 903 bool drag_undraggable(entity draggee, entity dragger)
 904 {
 905         // stuff probably shouldn't need this, we should figure out why they do!
 906         // exceptions of course are observers and weapon entities, where things mess up
 907         return false;
 908 }
 909
 910 float Drag_IsDraggable(entity draggee, entity dragger)
 911 {
 912         // TODO add more checks for bad stuff here
 913         if(draggee == NULL)
 914                 return false;
 915         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 916                 return false; // probably due to BSP collision
 917         //if(draggee.model == "")
 918         //      return false;
 919
 920         return ((draggee.draggable) ? draggee.draggable(draggee, dragger) : true);
 921 }
 922
 923 float Drag_MayChangeAngles(entity draggee)
 924 {
 925         // TODO add more checks for bad stuff here
 926         if(substring(draggee.model, 0, 1) == "*")
 927                 return false;
 928         return true;
 929 }
 930
 931 void Drag_MoveForward(entity dragger)
 932 {
 933         dragger.dragdistance += dragger.dragspeed;
 934 }
 935
 936 void Drag_SetSpeed(entity dragger, float s)
 937 {
 938         dragger.dragspeed = (2 ** s);
 939 }
 940
 941 void Drag_MoveBackward(entity dragger)
 942 {
 943         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
 944 }
 945
 946 void Drag_Update(entity dragger)
 947 {
 948         vector curorigin, neworigin, goodvelocity;
 949         float f;
 950         entity draggee;
 951
 952         draggee = dragger.dragentity;
 953         UNSET_ONGROUND(draggee);
 954
 955         curorigin = gettaginfo(draggee, 0);
 956         curorigin = curorigin + v_forward * dragger.draglocalvector.x + v_right * dragger.draglocalvector.y + v_up * dragger.draglocalvector.z;
 957         makevectors(dragger.v_angle);
 958         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
 959         goodvelocity = (neworigin - curorigin) * (1 / frametime);
 960
 961         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle > 180)
 962                 dragger.draglocalangle += 360;
 963         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle <= -180)
 964                 dragger.draglocalangle -= 360;
 965
 966         f = min(frametime * 10, 1);
 967         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
 968
 969         if(Drag_MayChangeAngles(draggee))
 970                 draggee.angles_y = draggee.angles.y * (1 - f) + (dragger.v_angle.y + dragger.draglocalangle) * f;
 971
 972         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
 973
 974         vector vecs = '0 0 0';
 975         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 976         if(dragger.(weaponentity).movedir.x > 0)
 977                 vecs = dragger.(weaponentity).movedir;
 978
 979         vector dv = v_right * -vecs_y + v_up * vecs_z;
 980
 981         te_lightning1(draggee, dragger.origin + dragger.view_ofs + dv, curorigin);
 982 }
 983
 984 float Drag_CanDrag(entity dragger)
 985 {
 986         return (!IS_DEAD(dragger)) || (IS_PLAYER(dragger));
 987 }
 988
 989 float Drag_IsDragging(entity dragger)
 990 {
 991         if(!dragger.dragentity)
 992                 return false;
 993         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
 994         {
 995                 dragger.dragentity = NULL;
 996                 return false;
 997         }
 998         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity, dragger))
 999         {
1000                 Drag_Finish(dragger);
1001                 return false;
1002         }
1003         return true;
1004 }
1005
1006 void Drag_MoveDrag(entity from, entity to)
1007 {
1008         if(from.draggedby)
1009         {
1010                 to.draggedby = from.draggedby;
1011                 to.draggedby.dragentity = to;
1012                 from.draggedby = NULL;
1013         }
1014 }
1015
1016 void DragBox_Think(entity this)
1017 {
1018         if(this.aiment && this.enemy)
1019         {
1020                 this.origin_x = (this.aiment.origin.x + this.enemy.origin.x) * 0.5;
1021                 this.origin_y = (this.aiment.origin.y + this.enemy.origin.y) * 0.5;
1022                 this.origin_z = (this.aiment.origin.z + this.enemy.origin.z) * 0.5;
1023                 this.maxs_x = fabs(this.aiment.origin.x - this.enemy.origin.x) * 0.5;
1024                 this.maxs_y = fabs(this.aiment.origin.y - this.enemy.origin.y) * 0.5;
1025                 this.maxs_z = fabs(this.aiment.origin.z - this.enemy.origin.z) * 0.5;
1026                 this.mins = -1 * this.maxs;
1027                 setorigin(this, this.origin);
1028                 setsize(this, this.mins, this.maxs); // link edict
1029         }
1030
1031         if(this.cnt == -1) // actually race_place -1
1032         {
1033                 // show "10 10" for qualifying spawns
1034                 setmodel(this.killindicator, MDL_NUM(10));
1035                 setmodel(this.killindicator.killindicator, MDL_NUM(10));
1036         }
1037         else if(this.cnt == -2) // actually race_place 0
1038         {
1039                 // show "10 0" for loser spawns
1040                 setmodel(this.killindicator, MDL_NUM(10));
1041                 setmodel(this.killindicator.killindicator, MDL_NUM(0));
1042         }
1043         else
1044         {
1045                 setmodel(this.killindicator, MDL_NUM(this.cnt % 10));
1046                 setmodel(this.killindicator.killindicator, MDL_NUM(floor(this.cnt / 10)));
1047         }
1048
1049         this.nextthink = time;
1050 }
1051
1052 #endif