qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "../cvars.qh"
   6
   7 #include "../aim.qh"
   8 #include "../bot.qh"
   9 #include "../navigation.qh"
  10 #include "../scripting.qh"
  11 #include "../waypoints.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/impulses/all.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17 #include <common/state.qh>
  18 #include <common/items/_mod.qh>
  19 #include <common/wepent.qh>
  20
  21 #include <common/triggers/teleporters.qh>
  22 #include <common/triggers/trigger/jumppads.qh>
  23
  24 #include <lib/warpzone/common.qh>
  25
  26 .float speed;
  27
  28 void havocbot_ai(entity this)
  29 {
  30         if(this.draggedby)
  31                 return;
  32
  33         if(bot_execute_commands(this))
  34                 return;
  35
  36         if (bot_strategytoken == this && !bot_strategytoken_taken)
  37         {
  38                 if(this.havocbot_blockhead)
  39                 {
  40                         this.havocbot_blockhead = false;
  41                 }
  42                 else
  43                 {
  44                         if (!this.jumppadcount && !STAT(FROZEN, this))
  45                                 this.havocbot_role(this); // little too far down the rabbit hole
  46                 }
  47
  48                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  49                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  50                 if(!this.goalcurrent)
  51                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  52                 {
  53                         // Look for the closest waypoint out of water
  54                         entity newgoal = NULL;
  55                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  56                         {
  57                                 if(it.origin.z < this.origin.z)
  58                                         continue;
  59
  60                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  61                                         continue;
  62
  63                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  64                                         continue;
  65
  66                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  67
  68                                 if(trace_fraction < 1)
  69                                         continue;
  70
  71                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  72                                         newgoal = it;
  73                         });
  74
  75                         if(newgoal)
  76                         {
  77                         //      te_wizspike(newgoal.origin);
  78                                 navigation_pushroute(this, newgoal);
  79                         }
  80                 }
  81
  82                 // token has been used this frame
  83                 bot_strategytoken_taken = true;
  84         }
  85
  86         if(IS_DEAD(this) || STAT(FROZEN, this))
  87         {
  88                 if (this.goalcurrent)
  89                         navigation_clearroute(this);
  90                 return;
  91         }
  92
  93         havocbot_chooseenemy(this);
  94
  95         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  96         {
  97                 .entity weaponentity = weaponentities[slot];
  98                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
  99                 if(this.(weaponentity).bot_chooseweapontime < time)
 100                 {
 101                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 102                         havocbot_chooseweapon(this, weaponentity);
 103                 }
 104         }
 105         havocbot_aim(this);
 106         lag_update(this);
 107         if (this.bot_aimtarg)
 108         {
 109                 this.aistatus |= AI_STATUS_ATTACKING;
 110                 this.aistatus &= ~AI_STATUS_ROAMING;
 111
 112                 if(this.weapons)
 113                 {
 114                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 115                         {
 116                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 117                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 118                         }
 119                         else
 120                         {
 121                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 122                                 {
 123                                         .entity weaponentity = weaponentities[slot];
 124                                         Weapon w = this.(weaponentity).m_weapon;
 125                                         if(w == WEP_Null && slot != 0)
 126                                                 continue;
 127                                         w.wr_aim(w, this, weaponentity);
 128                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 129                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 130                                 }
 131                         }
 132                 }
 133                 else
 134                 {
 135                         if(IS_PLAYER(this.bot_aimtarg))
 136                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
 137                 }
 138         }
 139         else if (this.goalcurrent)
 140         {
 141                 this.aistatus |= AI_STATUS_ROAMING;
 142                 this.aistatus &= ~AI_STATUS_ATTACKING;
 143
 144                 vector now, next;
 145                 float aimdistance,skillblend,distanceblend,blend;
 146
 147                 vector v = get_closer_dest(this.goalcurrent, this.origin);
 148                 if(this.goalcurrent.wpisbox)
 149                 {
 150                         // avoid a glitch when bot is teleported but teleport waypoint isn't removed yet
 151                         if(this.goalstack02 && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT
 152                         && this.lastteleporttime > 0 && time - this.lastteleporttime < 0.15)
 153                                 v = (this.goalstack02.absmin + this.goalstack02.absmax) * 0.5;
 154                         // aim to teleport origin if bot is inside teleport waypoint but hasn't touched the real teleport yet
 155                         else if(boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
 156                                 v = this.goalcurrent.origin;
 157                 }
 158                 next = now = v - (this.origin + this.view_ofs);
 159                 aimdistance = vlen(now);
 160
 161                 //dprint(this.goalstack01.classname,etos(this.goalstack01),"\n");
 162                 if(
 163                         this.goalstack01 != this && this.goalstack01 && !wasfreed(this.goalstack01) && ((this.aistatus & AI_STATUS_RUNNING) == 0) &&
 164                         !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 165                 )
 166                         next = ((this.goalstack01.absmin + this.goalstack01.absmax) * 0.5) - (this.origin + this.view_ofs);
 167
 168                 skillblend=bound(0,(skill+this.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 169                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 170                 blend = skillblend * (1-distanceblend);
 171                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 172                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 173                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 174                 v = now + blend * (next - now);
 175                 //dprint(etos(this), " ");
 176                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 177                 //v = now * (distanceblend) + next * (1-distanceblend);
 178                 if (this.waterlevel < WATERLEVEL_SWIMMING)
 179                         v.z = 0;
 180                 //dprint("walk at:", vtos(v), "\n");
 181                 //te_lightning2(NULL, this.origin, this.goalcurrent.origin);
 182                 bot_aimdir(this, v, -1);
 183         }
 184         havocbot_movetogoal(this);
 185
 186         // if the bot is not attacking, consider reloading weapons
 187         if (!(this.aistatus & AI_STATUS_ATTACKING))
 188         {
 189                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 190                 {
 191                         .entity weaponentity = weaponentities[slot];
 192
 193                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 194                                 continue;
 195
 196                         // we are currently holding a weapon that's not fully loaded, reload it
 197                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 198                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 199                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 200
 201                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 202                         // the code above executes next frame, starting the reloading then
 203                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 204                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 205                         {
 206                                 FOREACH(Weapons, it != WEP_Null, {
 207                                         if((this.weapons & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 208                                         {
 209                                                 this.(weaponentity).m_switchweapon = it;
 210                                                 break;
 211                                         }
 212                                 });
 213                         }
 214                 }
 215         }
 216 }
 217
 218 void havocbot_keyboard_movement(entity this, vector destorg)
 219 {
 220         vector keyboard;
 221
 222         if (time > this.havocbot_keyboardtime)
 223         {
 224                 float sk = skill + this.bot_moveskill;
 225                 this.havocbot_keyboardtime =
 226                         max(
 227                                 this.havocbot_keyboardtime
 228                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 229                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 230                         , time);
 231                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 232
 233                 float trigger = autocvar_bot_ai_keyboard_threshold;
 234                 float trigger1 = -trigger;
 235
 236                 // categorize forward movement
 237                 // at skill < 1.5 only forward
 238                 // at skill < 2.5 only individual directions
 239                 // at skill < 4.5 only individual directions, and forward diagonals
 240                 // at skill >= 4.5, all cases allowed
 241                 if (keyboard.x > trigger)
 242                 {
 243                         keyboard.x = 1;
 244                         if (sk < 2.5)
 245                                 keyboard.y = 0;
 246                 }
 247                 else if (keyboard.x < trigger1 && sk > 1.5)
 248                 {
 249                         keyboard.x = -1;
 250                         if (sk < 4.5)
 251                                 keyboard.y = 0;
 252                 }
 253                 else
 254                 {
 255                         keyboard.x = 0;
 256                         if (sk < 1.5)
 257                                 keyboard.y = 0;
 258                 }
 259                 if (sk < 4.5)
 260                         keyboard.z = 0;
 261
 262                 if (keyboard.y > trigger)
 263                         keyboard.y = 1;
 264                 else if (keyboard.y < trigger1)
 265                         keyboard.y = -1;
 266                 else
 267                         keyboard.y = 0;
 268
 269                 if (keyboard.z > trigger)
 270                         keyboard.z = 1;
 271                 else if (keyboard.z < trigger1)
 272                         keyboard.z = -1;
 273                 else
 274                         keyboard.z = 0;
 275
 276                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 277                 if (this.havocbot_ducktime > time)
 278                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 279         }
 280
 281         keyboard = this.havocbot_keyboard;
 282         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 283         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 284         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 285 }
 286
 287 void havocbot_bunnyhop(entity this, vector dir)
 288 {
 289         float bunnyhopdistance;
 290         vector deviation;
 291         float maxspeed;
 292
 293         // Don't jump when attacking
 294         if(this.aistatus & AI_STATUS_ATTACKING)
 295                 return;
 296
 297         if(IS_PLAYER(this.goalcurrent))
 298                 return;
 299
 300         maxspeed = autocvar_sv_maxspeed;
 301
 302         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 303                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 304         {
 305                 this.aistatus &= ~AI_STATUS_RUNNING;
 306                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 307                 this.bot_canruntogoal = 0;
 308                 this.bot_timelastseengoal = 0;
 309                 return;
 310         }
 311
 312         if(this.waterlevel > WATERLEVEL_WETFEET)
 313         {
 314                 this.aistatus &= ~AI_STATUS_RUNNING;
 315                 return;
 316         }
 317
 318         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 319         {
 320                 this.bot_canruntogoal = 0;
 321                 this.bot_timelastseengoal = 0;
 322         }
 323
 324         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 325         bunnyhopdistance = vlen(this.origin - gco);
 326
 327         // Run only to visible goals
 328         if(IS_ONGROUND(this))
 329         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 330         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 331         {
 332                         this.bot_lastseengoal = this.goalcurrent;
 333
 334                         // seen it before
 335                         if(this.bot_timelastseengoal)
 336                         {
 337                                 // for a period of time
 338                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 339                                 {
 340                                         float checkdistance;
 341                                         checkdistance = true;
 342
 343                                         // don't run if it is too close
 344                                         if(this.bot_canruntogoal==0)
 345                                         {
 346                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 347                                                         this.bot_canruntogoal = 1;
 348                                                 else
 349                                                         this.bot_canruntogoal = -1;
 350                                         }
 351
 352                                         if(this.bot_canruntogoal != 1)
 353                                                 return;
 354
 355                                         if(this.aistatus & AI_STATUS_ROAMING)
 356                                         if(this.goalcurrent.classname=="waypoint")
 357                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 358                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 359                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 360                                         {
 361                                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 362                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 363                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 364                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 365
 366                                                 if(fabs(deviation.y) < 20)
 367                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 368                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 369                                                 {
 370                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 371                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 372                                                         {
 373                                                                 checkdistance = false;
 374                                                         }
 375                                                 }
 376                                         }
 377
 378                                         if(checkdistance)
 379                                         {
 380                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 381                                                 // increase stop distance in case the goal is on a slope or a lower platform
 382                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 383                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 384                                         }
 385                                         else
 386                                         {
 387                                                 this.aistatus |= AI_STATUS_RUNNING;
 388                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 389                                         }
 390                                 }
 391                         }
 392                         else
 393                         {
 394                                 this.bot_timelastseengoal = time;
 395                         }
 396         }
 397         else
 398         {
 399                 this.bot_timelastseengoal = 0;
 400         }
 401
 402 #if 0
 403         // Release jump button
 404         if(!cvar("sv_pogostick"))
 405         if((IS_ONGROUND(this)) == 0)
 406         {
 407                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 408                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 409
 410                 // Strafe
 411                 if(this.aistatus & AI_STATUS_RUNNING)
 412                 if(vlen(this.velocity)>maxspeed)
 413                 {
 414                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 415                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 416                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 417
 418                         if(fabs(deviation.y)>10)
 419                                 CS(this).movement_x = 0;
 420
 421                         if(deviation.y>10)
 422                                 CS(this).movement_y = maxspeed * -1;
 423                         else if(deviation.y<10)
 424                                 CS(this).movement_y = maxspeed;
 425
 426                 }
 427         }
 428 #endif
 429 }
 430
 431 // return true when bot isn't getting closer to the current goal
 432 bool havocbot_checkgoaldistance(entity this, vector gco)
 433 {
 434         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 435         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 436         float distance_time = this.goalcurrent_distance_time;
 437         if(distance_time < 0)
 438                 distance_time = -distance_time;
 439         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 440         {
 441                 if(!distance_time)
 442                         this.goalcurrent_distance_time = time;
 443                 else if (time - distance_time > 0.5)
 444                         return true;
 445         }
 446         else
 447         {
 448                 // reduce it a little bit so it works even with very small approaches to the goal
 449                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 450                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 451                 this.goalcurrent_distance_time = 0;
 452         }
 453         return false;
 454 }
 455
 456 entity havocbot_select_an_item_of_group(entity this, int gr)
 457 {
 458         entity selected = NULL;
 459         float selected_dist2 = 0;
 460         // select farthest item of this group from bot's position
 461         IL_EACH(g_items, it.item_group == gr && it.solid,
 462         {
 463                 float dist2 = vlen2(this.origin - it.origin);
 464                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 465                 {
 466                         selected = it;
 467                         selected_dist2 = vlen2(this.origin - selected.origin);
 468                 }
 469         });
 470
 471         if (!selected)
 472                 return NULL;
 473
 474         set_tracewalk_dest(selected, this.origin, false);
 475         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 476                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 477         {
 478                 return NULL;
 479         }
 480
 481         return selected;
 482 }
 483
 484 void havocbot_movetogoal(entity this)
 485 {
 486         vector diff;
 487         vector dir;
 488         vector flatdir;
 489         vector evadeobstacle;
 490         vector evadelava;
 491         float maxspeed;
 492         //float dist;
 493         vector dodge;
 494         //if (this.goalentity)
 495         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 496         CS(this).movement = '0 0 0';
 497         maxspeed = autocvar_sv_maxspeed;
 498
 499         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 500         // Jetpack navigation
 501         if(this.navigation_jetpack_goal)
 502         if(this.goalcurrent==this.navigation_jetpack_goal)
 503         if(this.ammo_fuel)
 504         {
 505                 if(autocvar_bot_debug_goalstack)
 506                 {
 507                         debuggoalstack(this);
 508                         te_wizspike(this.navigation_jetpack_point);
 509                 }
 510
 511                 // Take off
 512                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 513                 {
 514                         // Brake almost completely so it can get a good direction
 515                         if(vdist(this.velocity, >, 10))
 516                                 return;
 517                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 518                 }
 519
 520                 makevectors(this.v_angle.y * '0 1 0');
 521                 dir = normalize(this.navigation_jetpack_point - this.origin);
 522
 523                 // Landing
 524                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 525                 {
 526                         // Calculate brake distance in xy
 527                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 528                         float v = vlen(vec2(this.velocity));
 529                         float db = ((v ** 2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 530                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 531                         if(d < db || d < 500)
 532                         {
 533                                 // Brake
 534                                 if(v > maxspeed * 0.3)
 535                                 {
 536                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 537                                         return;
 538                                 }
 539                                 // Switch to normal mode
 540                                 this.navigation_jetpack_goal = NULL;
 541                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 542                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 543                                 return;
 544                         }
 545                 }
 546                 else if(checkpvs(this.origin,this.goalcurrent))
 547                 {
 548                         // If I can see the goal switch to landing code
 549                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 550                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 551                         return;
 552                 }
 553
 554                 // Flying
 555                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 556                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 557                 {
 558                         CS(this).movement_x = dir * v_forward * maxspeed;
 559                         CS(this).movement_y = dir * v_right * maxspeed;
 560                 }
 561                 return;
 562         }
 563
 564         // Handling of jump pads
 565         if(this.jumppadcount)
 566         {
 567                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 568                 {
 569                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 570                         navigation_poptouchedgoals(this);
 571                         return;
 572                 }
 573                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 574                 {
 575                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 576                         // but with some randomness so it can try out different paths
 577                         if(!this.goalcurrent)
 578                         {
 579                                 entity newgoal = NULL;
 580                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 581                                 {
 582                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 583                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 584                                                 continue;
 585
 586                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 587
 588                                         if(trace_fraction < 1)
 589                                                 continue;
 590
 591                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 592                                                 newgoal = it;
 593                                 });
 594
 595                                 if(newgoal)
 596                                 {
 597                                         this.ignoregoal = this.goalcurrent;
 598                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 599                                         navigation_clearroute(this);
 600                                         navigation_routetogoal(this, newgoal, this.origin);
 601                                         if(autocvar_bot_debug_goalstack)
 602                                                 debuggoalstack(this);
 603                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 604                                 }
 605                         }
 606                         else
 607                         {
 608                                 if (this.goalcurrent.bot_pickup)
 609                                 {
 610                                         entity jumppad_wp = this.goalcurrent_prev;
 611                                         navigation_poptouchedgoals(this);
 612                                         if(!this.goalcurrent && jumppad_wp.wp00)
 613                                         {
 614                                                 // head to the jumppad destination once bot reaches the goal item
 615                                                 navigation_pushroute(this, jumppad_wp.wp00);
 616                                         }
 617                                 }
 618                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 619                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 620                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 621                                 else if(havocbot_checkgoaldistance(this, gco))
 622                                 {
 623                                         navigation_clearroute(this);
 624                                         navigation_goalrating_timeout_force(this);
 625                                 }
 626                                 else
 627                                         return;
 628                         }
 629                 }
 630                 else
 631                 {
 632                         if(time - this.lastteleporttime > 0.2 && this.velocity.z > 0)
 633                         {
 634                                 vector velxy = this.velocity; velxy_z = 0;
 635                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 636                                 {
 637                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 638                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 639                                 }
 640                                 return;
 641                         }
 642
 643                         // Don't chase players while using a jump pad
 644                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 645                                 return;
 646                 }
 647         }
 648         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 649                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 650
 651         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 652         if (skill > 6 && !(IS_ONGROUND(this)))
 653         {
 654                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 655                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 656                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 657
 658                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 659                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 660                 if(this.items & IT_JETPACK)
 661                 {
 662                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 663                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 664                         {
 665                                 if(this.velocity.z<0)
 666                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 667                         }
 668                         else
 669                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 670
 671                         // If there is no goal try to move forward
 672
 673                         if(this.goalcurrent==NULL)
 674                                 dir = v_forward;
 675                         else
 676                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 677
 678                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 679                         float xyspeed = xyvelocity * dir;
 680
 681                         if(xyspeed < (maxspeed / 2))
 682                         {
 683                                 makevectors(this.v_angle.y * '0 1 0');
 684                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 685                                 if(trace_fraction==1)
 686                                 {
 687                                         CS(this).movement_x = dir * v_forward * maxspeed;
 688                                         CS(this).movement_y = dir * v_right * maxspeed;
 689                                         if (skill < 10)
 690                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 691                                 }
 692                         }
 693
 694                         this.havocbot_blockhead = true;
 695
 696                         return;
 697                 }
 698                 else if(this.health + this.armorvalue > ROCKETJUMP_DAMAGE())
 699                 {
 700                         if(this.velocity.z < 0)
 701                         {
 702                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 703                                 {
 704                                         .entity weaponentity = weaponentities[slot];
 705
 706                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 707                                                 continue;
 708
 709                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 710                                         {
 711                                                 CS(this).movement_x = maxspeed;
 712
 713                                                 if(this.rocketjumptime)
 714                                                 {
 715                                                         if(time > this.rocketjumptime)
 716                                                         {
 717                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 718                                                                 this.rocketjumptime = 0;
 719                                                         }
 720                                                         return;
 721                                                 }
 722
 723                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 724                                                 this.v_angle_x = 90;
 725                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 726                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 727                                                 return;
 728                                         }
 729                                 }
 730                         }
 731                 }
 732                 else
 733                 {
 734                         // If there is no goal try to move forward
 735                         if(this.goalcurrent==NULL)
 736                                 CS(this).movement_x = maxspeed;
 737                 }
 738         }
 739
 740         // If we are under water with no goals, swim up
 741         if(this.waterlevel && !this.goalcurrent)
 742         {
 743                 dir = '0 0 0';
 744                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 745                         dir.z = 1;
 746                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 747                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 748                 else
 749                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 750                 makevectors(this.v_angle.y * '0 1 0');
 751                 CS(this).movement_x = dir * v_forward * maxspeed;
 752                 CS(this).movement_y = dir * v_right * maxspeed;
 753                 CS(this).movement_z = dir * v_up * maxspeed;
 754         }
 755
 756         // if there is nowhere to go, exit
 757         if (this.goalcurrent == NULL)
 758                 return;
 759
 760
 761         bool locked_goal = false;
 762         if((this.goalentity && wasfreed(this.goalentity))
 763                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 764         {
 765                 navigation_clearroute(this);
 766                 navigation_goalrating_timeout_force(this);
 767                 return;
 768         }
 769         else if(this.goalentity.tag_entity)
 770         {
 771                 navigation_goalrating_timeout_expire(this, 2);
 772         }
 773         else if(this.goalentity.bot_pickup)
 774         {
 775                 if(this.goalentity.bot_pickup_respawning)
 776                 {
 777                         if(this.goalentity.solid) // item respawned
 778                                 this.goalentity.bot_pickup_respawning = false;
 779                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 780                         {
 781                                 if(checkpvs(this.origin, this.goalentity))
 782                                 {
 783                                         this.goalentity.bot_pickup_respawning = false;
 784                                         navigation_goalrating_timeout_expire(this, random());
 785                                 }
 786                                 locked_goal = true; // wait for item to respawn
 787                         }
 788                         else if(this.goalentity == this.goalcurrent)
 789                                 locked_goal = true; // wait for item to respawn
 790                 }
 791                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 792                 {
 793                         if(checkpvs(this.origin, this.goalentity))
 794                         {
 795                                 navigation_goalrating_timeout_expire(this, random());
 796                         }
 797                 }
 798         }
 799         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 800                 locked_goal = true;
 801
 802         navigation_shortenpath(this);
 803
 804         bool goalcurrent_can_be_removed = false;
 805         if (IS_MOVABLE(this.goalcurrent))
 806         {
 807                 // if is movable  =>  not frozen
 808                 if (IS_DEAD(this.goalcurrent) || (this.goalentity_shouldbefrozen && this.goalentity == this.goalcurrent))
 809                 {
 810                         goalcurrent_can_be_removed = true;
 811                         // don't remove if not visible
 812                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 813                         {
 814                                 navigation_goalrating_timeout_force(this);
 815                                 return;
 816                         }
 817                 }
 818                 else if (this.bot_tracewalk_time < time)
 819                 {
 820                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 821                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 822                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 823                         {
 824                                 navigation_goalrating_timeout_force(this);
 825                                 return;
 826                         }
 827                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 828                 }
 829         }
 830         if(!locked_goal)
 831         {
 832                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 833                 // in this case path finding can start directly from a waypoint instead of
 834                 // looking for all the reachable waypoints up to a certain distance
 835                 if (navigation_poptouchedgoals(this))
 836                 {
 837                         if (this.goalcurrent)
 838                         {
 839                                 if (goalcurrent_can_be_removed)
 840                                 {
 841                                         // remove even if not visible
 842                                         navigation_goalrating_timeout_force(this);
 843                                         return;
 844                                 }
 845                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 846                                         navigation_goalrating_timeout_force(this);
 847                         }
 848                         else
 849                         {
 850                                 entity old_goal = this.goalcurrent_prev;
 851                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 852                                 {
 853                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 854                                         // item of the group by telling the bot to head directly to the farthest item.
 855                                         // Next time we let the bot select a goal as usual which can be another item
 856                                         // of this group (the closest one) and so on
 857                                         this.item_group = old_goal.item_group;
 858                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 859                                         if (new_goal)
 860                                                 navigation_pushroute(this, new_goal);
 861                                 }
 862                         }
 863                 }
 864         }
 865
 866         // if ran out of goals try to use an alternative goal or get a new strategy asap
 867         if(this.goalcurrent == NULL)
 868         {
 869                 navigation_goalrating_timeout_force(this);
 870                 return;
 871         }
 872
 873
 874         if(autocvar_bot_debug_goalstack)
 875                 debuggoalstack(this);
 876
 877         bool bunnyhop_forbidden = false;
 878         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 879
 880         // in case bot ends up inside the teleport waypoint without touching
 881         // the teleport itself, head to the teleport origin
 882         if(this.goalcurrent.wpisbox && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z))
 883         {
 884                 bunnyhop_forbidden = true;
 885                 destorg = this.goalcurrent.origin;
 886                 if(destorg.z > this.origin.z)
 887                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 888         }
 889
 890         diff = destorg - this.origin;
 891
 892         // 1. stop if too close to target player (even if frozen)
 893         // 2. stop if the locked goal has been reached
 894         if ((IS_PLAYER(this.goalcurrent) && vdist(diff, <, 80))
 895                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 896         {
 897                 destorg = this.origin;
 898                 diff = '0 0 0';
 899         }
 900
 901         dir = normalize(diff);
 902         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 903
 904         //if (this.bot_dodgevector_time < time)
 905         {
 906                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 907                 //this.bot_dodgevector_jumpbutton = 1;
 908                 evadeobstacle = '0 0 0';
 909                 evadelava = '0 0 0';
 910
 911                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 912                 makevectors(this.v_angle.y * '0 1 0');
 913                 if (this.waterlevel)
 914                 {
 915                         if(this.waterlevel>WATERLEVEL_SWIMMING)
 916                         {
 917                                 if(!this.goalcurrent)
 918                                         this.aistatus |= AI_STATUS_OUT_WATER;
 919                                 else if(destorg.z > this.origin.z)
 920                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 921                         }
 922                         else
 923                         {
 924                                 dir = flatdir;
 925                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 926                                         ( !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER) || this.aistatus & AI_STATUS_OUT_WATER))
 927                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 928                                 else
 929                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 930                         }
 931                 }
 932                 else
 933                 {
 934                         float s;
 935                         vector offset;
 936                         if(this.aistatus & AI_STATUS_OUT_WATER)
 937                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 938
 939                         // jump if going toward an obstacle that doesn't look like stairs we
 940                         // can walk up directly
 941                         vector deviation = '0 0 0';
 942                         if (this.velocity)
 943                         {
 944                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 945                                 while (deviation.y < -180) deviation.y += 360;
 946                                 while (deviation.y > 180) deviation.y -= 360;
 947                         }
 948                         vector flat_diff = vec2(diff);
 949                         offset = max(32, vlen(vec2(this.velocity)) * cos(deviation.y * DEG2RAD) * 0.2) * flatdir;
 950                         vector actual_destorg = this.origin + offset;
 951                         if (!this.goalstack01 || this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER))
 952                         {
 953                                 if (vlen2(flat_diff) < vlen2(offset))
 954                                 {
 955                                         actual_destorg.x = destorg.x;
 956                                         actual_destorg.y = destorg.y;
 957                                 }
 958                         }
 959                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
 960                         {
 961                                 actual_destorg.x = destorg.x;
 962                                 actual_destorg.y = destorg.y;
 963                         }
 964                         else if (vlen2(flat_diff) < vlen2(offset))
 965                         {
 966                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 967                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
 968                                 float dist = vlen(vec2(this.origin + offset - destorg));
 969                                 // if current and next goal are close to each other make sure
 970                                 // actual_destorg isn't set beyond next_goal_org
 971                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
 972                                         actual_destorg = next_goal_org;
 973                                 else
 974                                         actual_destorg = vec2(destorg) + dist * next_dir;
 975                                 actual_destorg.z = this.origin.z;
 976
 977                         }
 978
 979                         tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
 980                         if (trace_fraction < 1)
 981                         if (trace_plane_normal.z < 0.7)
 982                         {
 983                                 s = trace_fraction;
 984                                 tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
 985                                 if (trace_fraction < s + 0.01)
 986                                 if (trace_plane_normal.z < 0.7)
 987                                 {
 988                                         s = trace_fraction;
 989                                         // don't artificially reduce max jump height in real-time
 990                                         // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
 991                                         vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
 992                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
 993                                         if (trace_fraction > s)
 994                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 995                                         else
 996                                         {
 997                                                 jump_height = stepheightvec + jumpheight_vec / 2;
 998                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
 999                                                 if (trace_fraction > s)
1000                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1001                                         }
1002                                 }
1003                         }
1004
1005                         // if bot for some reason doesn't get close to the current goal find another one
1006                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1007                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1008                         if(havocbot_checkgoaldistance(this, destorg))
1009                         {
1010                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1011                                 {
1012                                         navigation_clearroute(this);
1013                                         navigation_goalrating_timeout_force(this);
1014                                         return;
1015                                 }
1016
1017                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1018                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1019                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1020                                 {
1021                                         navigation_clearroute(this);
1022                                         navigation_goalrating_timeout_force(this);
1023                                         return;
1024                                 }
1025
1026                                 // give bot only another chance to prevent bot getting stuck
1027                                 // in case it thinks it can walk but actually can't
1028                                 this.goalcurrent_distance_z = FLOAT_MAX;
1029                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1030                                 this.goalcurrent_distance_time = -time; // mark second try
1031                         }
1032
1033                         // Check for water/slime/lava and dangerous edges
1034                         // (only when the bot is on the ground or jumping intentionally)
1035
1036                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
1037                         vector dst_ahead = this.origin + this.view_ofs + offset;
1038                         vector dst_down = dst_ahead - '0 0 3000';
1039                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1040
1041                         bool unreachable = false;
1042                         s = CONTENT_SOLID;
1043                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
1044                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1045                         {
1046                                 // Look downwards
1047                                 traceline(dst_ahead , dst_down, true, NULL);
1048                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1049                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
1050                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1051                                 {
1052                                         s = pointcontents(trace_endpos + '0 0 1');
1053                                         if (s != CONTENT_SOLID)
1054                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1055                                                 evadelava = normalize(this.velocity) * -1;
1056                                         else if (s == CONTENT_SKY)
1057                                                 evadeobstacle = normalize(this.velocity) * -1;
1058                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1059                                         {
1060                                                 // the traceline check isn't enough but is good as optimization,
1061                                                 // when not true (most of the time) this tracebox call is avoided
1062                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1063                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1064                                                 {
1065                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1066                                                         {
1067                                                                 // the goal is probably on an upper platform, assume bot can't get there
1068                                                                 unreachable = true;
1069                                                         }
1070                                                         else
1071                                                                 evadelava = normalize(this.velocity) * -1;
1072                                                 }
1073                                         }
1074                                 }
1075                         }
1076
1077                         dir = flatdir;
1078                         evadeobstacle.z = 0;
1079                         evadelava.z = 0;
1080                         makevectors(this.v_angle.y * '0 1 0');
1081
1082                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
1083                         {
1084                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1085                                 if(IS_PLAYER(this.goalcurrent))
1086                                         unreachable = true;
1087                         }
1088
1089                         // slow down if bot is in the air and goal is under it
1090                         if (!this.goalcurrent.wphardwired
1091                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1092                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1093                         {
1094                                 // tracebox wouldn't work when bot is still on the ledge
1095                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1096                                 if (this.origin.z - trace_endpos.z > 120)
1097                                         evadeobstacle = normalize(this.velocity) * -1;
1098                         }
1099
1100                         if(unreachable)
1101                         {
1102                                 navigation_clearroute(this);
1103                                 navigation_goalrating_timeout_force(this);
1104                                 this.ignoregoal = this.goalcurrent;
1105                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1106                         }
1107                 }
1108
1109                 dodge = havocbot_dodge(this);
1110                 if (dodge)
1111                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1112                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
1113                 if (this.enemy)
1114                 {
1115                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1116                         if (IS_PLAYER(trace_ent))
1117                                 dir = dir * bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1118                 }
1119
1120                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
1121         //      this.bot_dodgevector = dir;
1122         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1123         }
1124
1125         if(time < this.ladder_time)
1126         {
1127                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1128                 {
1129                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1130                                 dir.z = 1;
1131                 }
1132                 else
1133                 {
1134                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1135                                 dir.z = -1;
1136                 }
1137         }
1138
1139         //dir = this.bot_dodgevector;
1140         //if (this.bot_dodgevector_jumpbutton)
1141         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1142         CS(this).movement_x = dir * v_forward * maxspeed;
1143         CS(this).movement_y = dir * v_right * maxspeed;
1144         CS(this).movement_z = dir * v_up * maxspeed;
1145
1146         // Emulate keyboard interface
1147         if (skill < 10)
1148                 havocbot_keyboard_movement(this, destorg);
1149
1150         // Bunnyhop!
1151         //if(this.aistatus & AI_STATUS_ROAMING)
1152         if(!bunnyhop_forbidden && this.goalcurrent)
1153         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1154                 havocbot_bunnyhop(this, dir);
1155
1156         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
1157         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
1158         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
1159 }
1160
1161 entity havocbot_gettarget(entity this, bool secondary)
1162 {
1163         entity best = NULL;
1164         vector eye = CENTER_OR_VIEWOFS(this);
1165         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1166         {
1167                 vector v = CENTER_OR_VIEWOFS(it);
1168                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1169                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1170                 if(bot_shouldattack(this, it))
1171                 {
1172                         traceline(eye, v, true, this);
1173                         if (trace_ent == it || trace_fraction >= 1)
1174                                 best = it;
1175                 }
1176         });
1177
1178         return best;
1179 }
1180
1181 void havocbot_chooseenemy(entity this)
1182 {
1183         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1184         {
1185                 this.enemy = NULL;
1186                 return;
1187         }
1188         if (this.enemy)
1189         {
1190                 if (!bot_shouldattack(this, this.enemy))
1191                 {
1192                         // enemy died or something, find a new target
1193                         this.enemy = NULL;
1194                         this.havocbot_chooseenemy_finished = time;
1195                 }
1196                 else if (this.havocbot_stickenemy)
1197                 {
1198                         // tracking last chosen enemy
1199                         // if enemy is visible
1200                         // and not really really far away
1201                         // and we're not severely injured
1202                         // then keep tracking for a half second into the future
1203                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1204                         if (trace_ent == this.enemy || trace_fraction == 1)
1205                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1206                         if (this.health > 30)
1207                         {
1208                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1209                                 this.havocbot_chooseenemy_finished = time + 0.5;
1210                                 return;
1211                         }
1212                         // enemy isn't visible, or is far away, or we're injured severely
1213                         // so stop preferring this enemy
1214                         // (it will still take a half second until a new one is chosen)
1215                         this.havocbot_stickenemy = 0;
1216                 }
1217         }
1218         if (time < this.havocbot_chooseenemy_finished)
1219                 return;
1220         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1221         vector eye = this.origin + this.view_ofs;
1222         entity best = NULL;
1223         float bestrating = 100000000;
1224
1225         // Backup hit flags
1226         int hf = this.dphitcontentsmask;
1227
1228         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1229
1230         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1231
1232         bool scan_transparent = false;
1233         bool scan_secondary_targets = false;
1234         bool have_secondary_targets = false;
1235         while(true)
1236         {
1237                 scan_secondary_targets = false;
1238 LABEL(scan_targets)
1239                 IL_EACH(g_bot_targets, it.bot_attack,
1240                 {
1241                         if(!scan_secondary_targets)
1242                         {
1243                                 if(it.classname == "misc_breakablemodel")
1244                                 {
1245                                         have_secondary_targets = true;
1246                                         continue;
1247                                 }
1248                         }
1249                         else if(it.classname != "misc_breakablemodel")
1250                                 continue;
1251
1252                         vector v = (it.absmin + it.absmax) * 0.5;
1253                         float rating = vlen2(v - eye);
1254                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1255                         if (bestrating > rating)
1256                         if (bot_shouldattack(this, it))
1257                         {
1258                                 traceline(eye, v, true, this);
1259                                 if (trace_ent == it || trace_fraction >= 1)
1260                                 {
1261                                         best = it;
1262                                         bestrating = rating;
1263                                 }
1264                         }
1265                 });
1266
1267                 if(!best && have_secondary_targets && !scan_secondary_targets)
1268                 {
1269                         scan_secondary_targets = true;
1270                         // restart the loop
1271                         bestrating = 100000000;
1272                         goto scan_targets;
1273                 }
1274
1275                 // I want to do a second scan if no enemy was found or I don't have weapons
1276                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1277                 if(best || this.weapons) // || this.weapon == WEP_RIFLE.m_id
1278                         break;
1279                 if(scan_transparent)
1280                         break;
1281
1282                 // Set flags to see through transparent objects
1283                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1284
1285                 scan_transparent = true;
1286         }
1287
1288         // Restore hit flags
1289         this.dphitcontentsmask = hf;
1290
1291         this.enemy = best;
1292         this.havocbot_stickenemy = true;
1293         if(best && best.classname == "misc_breakablemodel")
1294                 this.havocbot_stickenemy = false;
1295 }
1296
1297 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1298 {
1299         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1300         // so skip this for them, or they'll never get to reload their weapons at all.
1301         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1302         if(skill < 5)
1303                 return false;
1304
1305         // if this weapon is scheduled for reloading, don't switch to it during combat
1306         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1307         {
1308                 FOREACH(Weapons, it != WEP_Null, {
1309                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1310                                 return true; // other weapon available
1311                 });
1312         }
1313
1314         return false;
1315 }
1316
1317 void havocbot_chooseweapon(entity this, .entity weaponentity)
1318 {
1319         int i;
1320
1321         // ;)
1322         if(g_weaponarena_weapons == WEPSET(TUBA))
1323         {
1324                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1325                 return;
1326         }
1327
1328         // TODO: clean this up by moving it to weapon code
1329         if(this.enemy==NULL)
1330         {
1331                 // If no weapon was chosen get the first available weapon
1332                 if(this.(weaponentity).m_weapon==WEP_Null)
1333                 FOREACH(Weapons, it != WEP_Null, {
1334                         if(client_hasweapon(this, it, weaponentity, true, false))
1335                         {
1336                                 this.(weaponentity).m_switchweapon = it;
1337                                 return;
1338                         }
1339                 });
1340                 return;
1341         }
1342
1343         // Do not change weapon during the next second after a combo
1344         float f = time - this.lastcombotime;
1345         if(f < 1)
1346                 return;
1347
1348         float w;
1349         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1350
1351         // Should it do a weapon combo?
1352         float af, ct, combo_time, combo;
1353
1354         af = ATTACK_FINISHED(this, 0);
1355         ct = autocvar_bot_ai_weapon_combo_threshold;
1356
1357         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1358         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1359         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1360
1361         combo = false;
1362
1363         if(autocvar_bot_ai_weapon_combo)
1364         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1365         if(af > combo_time)
1366         {
1367                 combo = true;
1368                 this.lastcombotime = time;
1369         }
1370
1371         distance *= (2 ** this.bot_rangepreference);
1372
1373         // Custom weapon list based on distance to the enemy
1374         if(bot_custom_weapon){
1375
1376                 // Choose weapons for far distance
1377                 if ( distance > bot_distance_far ) {
1378                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1379                                 w = bot_weapons_far[i];
1380                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1381                                 {
1382                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1383                                                 continue;
1384                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1385                                         return;
1386                                 }
1387                         }
1388                 }
1389
1390                 // Choose weapons for mid distance
1391                 if ( distance > bot_distance_close) {
1392                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1393                                 w = bot_weapons_mid[i];
1394                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1395                                 {
1396                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1397                                                 continue;
1398                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1399                                         return;
1400                                 }
1401                         }
1402                 }
1403
1404                 // Choose weapons for close distance
1405                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1406                         w = bot_weapons_close[i];
1407                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1408                         {
1409                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1410                                         continue;
1411                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1412                                 return;
1413                         }
1414                 }
1415         }
1416 }
1417
1418 void havocbot_aim(entity this)
1419 {
1420         if (time < this.nextaim)
1421                 return;
1422         this.nextaim = time + 0.1;
1423         vector myvel = this.velocity;
1424         if (!this.waterlevel)
1425                 myvel.z = 0;
1426         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1427         else if (this.enemy)
1428         {
1429                 vector enemyvel = this.enemy.velocity;
1430                 if (!this.enemy.waterlevel)
1431                         enemyvel.z = 0;
1432                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1433         }
1434         else
1435                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1436 }
1437
1438 bool havocbot_moveto_refresh_route(entity this)
1439 {
1440         // Refresh path to goal if necessary
1441         entity wp;
1442         wp = this.havocbot_personal_waypoint;
1443         navigation_goalrating_start(this);
1444         navigation_routerating(this, wp, 10000, 10000);
1445         navigation_goalrating_end(this);
1446         return (this.goalentity != NULL);
1447 }
1448
1449 float havocbot_moveto(entity this, vector pos)
1450 {
1451         entity wp;
1452
1453         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1454         {
1455                 // Step 4: Move to waypoint
1456                 if(this.havocbot_personal_waypoint==NULL)
1457                 {
1458                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1459                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1460                         return CMD_STATUS_ERROR;
1461                 }
1462
1463                 if (!bot_strategytoken_taken)
1464                 if(this.havocbot_personal_waypoint_searchtime<time)
1465                 {
1466                         bot_strategytoken_taken = true;
1467                         if(havocbot_moveto_refresh_route(this))
1468                         {
1469                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1470                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1471                                 this.havocbot_personal_waypoint_failcounter = 0;
1472                         }
1473                         else
1474                         {
1475                                 this.havocbot_personal_waypoint_failcounter += 1;
1476                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1477                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1478                                 {
1479                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1480                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1481                                         delete(this.havocbot_personal_waypoint);
1482                                         return CMD_STATUS_ERROR;
1483                                 }
1484                                 else
1485                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1486                         }
1487                 }
1488
1489                 if(autocvar_bot_debug_goalstack)
1490                         debuggoalstack(this);
1491
1492                 // Heading
1493                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
1494                 dir = dir - (this.origin + this.view_ofs);
1495                 dir.z = 0;
1496                 bot_aimdir(this, dir, -1);
1497
1498                 // Go!
1499                 havocbot_movetogoal(this);
1500
1501                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1502                 {
1503                         // Step 5: Waypoint reached
1504                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1505                         delete(this.havocbot_personal_waypoint);
1506                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1507                         return CMD_STATUS_FINISHED;
1508                 }
1509
1510                 return CMD_STATUS_EXECUTING;
1511         }
1512
1513         // Step 2: Linking waypoint
1514         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1515         {
1516                 // Wait until it is linked
1517                 if(!this.havocbot_personal_waypoint.wplinked)
1518                 {
1519                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1520                         return CMD_STATUS_EXECUTING;
1521                 }
1522
1523                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1524                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1525                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1526
1527                 // Step 3: Route to waypoint
1528                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1529
1530                 return CMD_STATUS_EXECUTING;
1531         }
1532
1533         // Step 1: Spawning waypoint
1534         wp = waypoint_spawnpersonal(this, pos);
1535         if(wp==NULL)
1536         {
1537                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1538                 return CMD_STATUS_ERROR;
1539         }
1540
1541         this.havocbot_personal_waypoint = wp;
1542         this.havocbot_personal_waypoint_failcounter = 0;
1543         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1544
1545         // if pos is inside a teleport, then let's mark it as teleport waypoint
1546         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1547         {
1548                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1549                 this.lastteleporttime = 0;
1550         });
1551
1552 /*
1553         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1554                 print("routing to a teleporter\n");
1555         else
1556                 print("routing to a non-teleporter\n");
1557 */
1558
1559         return CMD_STATUS_EXECUTING;
1560 }
1561
1562 float havocbot_resetgoal(entity this)
1563 {
1564         navigation_clearroute(this);
1565         return CMD_STATUS_FINISHED;
1566 }
1567
1568 void havocbot_setupbot(entity this)
1569 {
1570         this.bot_ai = havocbot_ai;
1571         this.cmd_moveto = havocbot_moveto;
1572         this.cmd_resetgoal = havocbot_resetgoal;
1573
1574         havocbot_chooserole(this);
1575 }
1576
1577 vector havocbot_dodge(entity this)
1578 {
1579         // LordHavoc: disabled because this is too expensive
1580         return '0 0 0';
1581 #if 0
1582         entity head;
1583         vector dodge, v, n;
1584         float danger, bestdanger, vl, d;
1585         dodge = '0 0 0';
1586         bestdanger = -20;
1587         // check for dangerous objects near bot or approaching bot
1588         head = findchainfloat(bot_dodge, true);
1589         while(head)
1590         {
1591                 if (head.owner != this)
1592                 {
1593                         vl = vlen(head.velocity);
1594                         if (vl > autocvar_sv_maxspeed * 0.3)
1595                         {
1596                                 n = normalize(head.velocity);
1597                                 v = this.origin - head.origin;
1598                                 d = v * n;
1599                                 if (d > (0 - head.bot_dodgerating))
1600                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1601                                 {
1602                                         // calculate direction and distance from the flight path, by removing the forward axis
1603                                         v = v - (n * (v * n));
1604                                         danger = head.bot_dodgerating - vlen(v);
1605                                         if (bestdanger < danger)
1606                                         {
1607                                                 bestdanger = danger;
1608                                                 // dodge to the side of the object
1609                                                 dodge = normalize(v);
1610                                         }
1611                                 }
1612                         }
1613                         else
1614                         {
1615                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1616                                 if (bestdanger < danger)
1617                                 {
1618                                         bestdanger = danger;
1619                                         dodge = normalize(this.origin - head.origin);
1620                                 }
1621                         }
1622                 }
1623                 head = head.chain;
1624         }
1625         return dodge;
1626 #endif
1627 }