qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include <common/stats.qh>
  20 #include <server/world.qh>
  21 #include <server/damage.qh>
  22 #include "../../race.qh"
  23 #include <server/items/items.qh>
  24
  25 #include <server/mutators/_mod.qh>
  26
  27 #include "../../weapons/accuracy.qh"
  28
  29 #include <common/physics/player.qh>
  30 #include <common/constants.qh>
  31 #include <common/net_linked.qh>
  32 #include <common/mapinfo.qh>
  33 #include <common/teams.qh>
  34 #include <common/util.qh>
  35
  36 #include <server/scores_rules.qh>
  37
  38 #include <common/weapons/_all.qh>
  39
  40 #include <lib/csqcmodel/sv_model.qh>
  41
  42 #include <lib/warpzone/common.qh>
  43 #include <lib/warpzone/util_server.qh>
  44
  45 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  46
  47 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  48 void bot_setclientfields(entity this)
  49 {
  50         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  51         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  52 }
  53
  54 entity bot_spawn()
  55 {
  56         entity bot = spawnclient();
  57         if (bot)
  58         {
  59                 setItemGroupCount();
  60                 currentbots = currentbots + 1;
  61                 bot_setnameandstuff(bot);
  62                 ClientConnect(bot);
  63                 bot_setclientfields(bot);
  64                 PutClientInServer(bot);
  65         }
  66         return bot;
  67 }
  68
  69 void bot_think(entity this)
  70 {
  71         if (this.bot_nextthink > time)
  72                 return;
  73
  74         this.flags &= ~FL_GODMODE;
  75         if(autocvar_bot_god)
  76                 this.flags |= FL_GODMODE;
  77
  78         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  79
  80         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  81         {
  82                 CS(this).movement = '0 0 0';
  83                 this.bot_nextthink = time + 0.5;
  84                 return;
  85         }
  86
  87         if (this.fixangle)
  88         {
  89                 this.v_angle = this.angles;
  90                 this.v_angle_z = 0;
  91                 this.fixangle = false;
  92         }
  93
  94         this.dmg_take = 0;
  95         this.dmg_save = 0;
  96         this.dmg_inflictor = NULL;
  97
  98         // calculate an aiming latency based on the skill setting
  99         // (simulated network latency + naturally delayed reflexes)
 100         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
 101         // minimum ping 20+10 random
 102         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 103         // skill 10 = ping 0.2 (adrenaline)
 104         // skill 0 = ping 0.7 (slightly drunk)
 105
 106         // clear buttons
 107         PHYS_INPUT_BUTTON_ATCK(this) = false;
 108         // keep jump button pressed for a short while, useful with ramp jumps
 109         PHYS_INPUT_BUTTON_JUMP(this) = (!IS_DEAD(this) && time < this.bot_jump_time + 0.2);
 110         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 111         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 112         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 113         PHYS_INPUT_BUTTON_HOOK(this) = false;
 114         PHYS_INPUT_BUTTON_INFO(this) = false;
 115         PHYS_INPUT_BUTTON_DRAG(this) = false;
 116         PHYS_INPUT_BUTTON_CHAT(this) = false;
 117         PHYS_INPUT_BUTTON_USE(this) = false;
 118
 119         if (time < game_starttime)
 120         {
 121                 // block the bot during the countdown to game start
 122                 CS(this).movement = '0 0 0';
 123                 this.bot_nextthink = game_starttime;
 124                 return;
 125         }
 126
 127         // if dead, just wait until we can respawn
 128         if (IS_DEAD(this))
 129         {
 130                 if (bot_waypoint_queue_owner == this)
 131                         bot_waypoint_queue_owner = NULL;
 132                 this.aistatus = 0;
 133                 CS(this).movement = '0 0 0';
 134                 if (this.deadflag == DEAD_DEAD)
 135                 {
 136                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 137                         navigation_goalrating_timeout_force(this);
 138                 }
 139         }
 140         else if(this.aistatus & AI_STATUS_STUCK)
 141                 navigation_unstuck(this);
 142
 143         // now call the current bot AI (havocbot for example)
 144         this.bot_ai(this);
 145 }
 146
 147 void bot_setnameandstuff(entity this)
 148 {
 149         string readfile, s;
 150         int file, tokens, prio;
 151
 152         file = fopen(autocvar_bot_config_file, FILE_READ);
 153
 154         if(file < 0)
 155         {
 156                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 157                 readfile = "";
 158         }
 159         else
 160         {
 161                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
 162                 TeamBalance_GetTeamCounts(balance, NULL);
 163                 int smallest_team = -1;
 164                 int smallest_count = -1;
 165                 if (teamplay)
 166                 {
 167                         for (int i = 1; i <= AvailableTeams(); ++i)
 168                         {
 169                                 // NOTE if (autocvar_g_campaign && autocvar_g_campaign_forceteam == i)
 170                                 // TeamBalance_GetNumberOfPlayers(balance, i); returns the number of players + 1
 171                                 // since it keeps a spot for the real player in the desired team
 172                                 int count = TeamBalance_GetNumberOfPlayers(balance, i);
 173                                 if (smallest_count < 0 || count < smallest_count)
 174                                 {
 175                                         smallest_team = i;
 176                                         smallest_count = count;
 177                                 }
 178                         }
 179                 }
 180                 TeamBalance_Destroy(balance);
 181                 RandomSelection_Init();
 182                 while((readfile = fgets(file)))
 183                 {
 184                         if(substring(readfile, 0, 2) == "//")
 185                                 continue;
 186                         if(substring(readfile, 0, 1) == "#")
 187                                 continue;
 188                         // NOTE if the line is empty tokenizebyseparator(readfile, "\t")
 189                         // will create 1 empty token because there's no separator (bug?)
 190                         if (readfile == "")
 191                                 continue;
 192                         tokens = tokenizebyseparator(readfile, "\t");
 193                         if(tokens == 0)
 194                                 continue;
 195                         s = argv(0);
 196                         prio = 0;
 197                         bool conflict = false;
 198                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 199                                 if (s == it.cleanname)
 200                                 {
 201                                         conflict = true;
 202                                         break;
 203                                 }
 204                         });
 205                         if (!conflict)
 206                                 prio += 1;
 207                         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 208                         {
 209                                 int forced_team = stof(argv(5));
 210                                 if (!Team_IsValidIndex(forced_team))
 211                                         forced_team = 0;
 212                                 if (!forced_team || forced_team == smallest_team)
 213                                         prio += 2;
 214                         }
 215                         RandomSelection_AddString(readfile, 1, prio);
 216                 }
 217                 readfile = RandomSelection_chosen_string;
 218                 fclose(file);
 219         }
 220
 221         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 222
 223         tokens = tokenizebyseparator(readfile, "\t");
 224         if(argv(0) != "") bot_name = argv(0);
 225         else bot_name = "Bot";
 226
 227         if(argv(1) != "") bot_model = argv(1);
 228         else bot_model = "";
 229
 230         if(argv(2) != "") bot_skin = argv(2);
 231         else bot_skin = "0";
 232
 233         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 234         else bot_shirt = ftos(floor(random() * 15));
 235
 236         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 237         else bot_pants = ftos(floor(random() * 15));
 238
 239         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 240                 this.bot_forced_team = stof(argv(5));
 241         else
 242                 this.bot_forced_team = 0;
 243
 244         prio = 6;
 245
 246         #define READSKILL(f, w, r) MACRO_BEGIN \
 247                 if(argv(prio) != "") \
 248                         this.f = stof(argv(prio)) * w; \
 249                 else \
 250                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 251                 prio++; \
 252         MACRO_END
 253         //print(bot_name, ": ping=", argv(9), "\n");
 254
 255         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 256         READSKILL(bot_moveskill, 2, 0); // move skill
 257         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 258
 259         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 260
 261         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 262         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 263         READSKILL(bot_rangepreference, 1, 0); // read skill
 264
 265         READSKILL(bot_aimskill, 2, 0); // aim skill
 266         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 267         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 268
 269         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 270         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 271
 272         if (file >= 0 && argv(prio) != "")
 273                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
 274
 275         this.bot_config_loaded = true;
 276
 277         // this is really only a default, TeamBalance_JoinBestTeam is called later
 278         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 279         this.bot_preferredcolors = this.clientcolors;
 280
 281         string prefix = (autocvar_g_campaign ? "" : autocvar_bot_prefix);
 282         string suffix = (autocvar_g_campaign ? "" : autocvar_bot_suffix);
 283         string name = (autocvar_bot_usemodelnames ? bot_model : bot_name);
 284
 285         if (name == "")
 286         {
 287                 name = ftos(etof(this));
 288                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 289         }
 290         else
 291         {
 292                 // number bots with identical names
 293                 int j = 0;
 294                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 295                         if(it.cleanname == name)
 296                                 ++j;
 297                 });
 298                 if (j)
 299                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 300                 else
 301                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 302         }
 303         this.cleanname = strzone(name);
 304
 305         // pick the model and skin
 306         if(substring(bot_model, -4, 1) != ".")
 307                 bot_model = strcat(bot_model, ".iqm");
 308         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 309         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 310 }
 311
 312 void bot_custom_weapon_priority_setup()
 313 {
 314         static string bot_priority_far_prev;
 315         static string bot_priority_mid_prev;
 316         static string bot_priority_close_prev;
 317         static string bot_priority_distances_prev;
 318         float tokens, i, w;
 319
 320         bot_custom_weapon = false;
 321
 322         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 323                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 324                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 325                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 326         )
 327                 return;
 328
 329         if (bot_priority_distances_prev != autocvar_bot_ai_custom_weapon_priority_distances)
 330         {
 331                 strcpy(bot_priority_distances_prev, autocvar_bot_ai_custom_weapon_priority_distances);
 332                 tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 333
 334                 if (tokens!=2)
 335                         return;
 336
 337                 bot_distance_far = stof(argv(0));
 338                 bot_distance_close = stof(argv(1));
 339
 340                 if(bot_distance_far < bot_distance_close){
 341                         bot_distance_far = stof(argv(1));
 342                         bot_distance_close = stof(argv(0));
 343                 }
 344         }
 345
 346         int c;
 347
 348         #define PARSE_WEAPON_PRIORITIES(dist) MACRO_BEGIN \
 349                 if (bot_priority_##dist##_prev != autocvar_bot_ai_custom_weapon_priority_##dist) { \
 350                         strcpy(bot_priority_##dist##_prev, autocvar_bot_ai_custom_weapon_priority_##dist); \
 351                         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_##dist)," "); \
 352                         bot_weapons_##dist[0] = -1; \
 353                         c = 0; \
 354                         for(i = 0; i < tokens && c < REGISTRY_COUNT(Weapons); ++i) { \
 355                                 w = stof(argv(i)); \
 356                                 if (w >= WEP_FIRST && w <= WEP_LAST) { \
 357                                         bot_weapons_##dist[c] = w; \
 358                                         ++c; \
 359                                 } \
 360                         } \
 361                         if (c < REGISTRY_COUNT(Weapons)) \
 362                                 bot_weapons_##dist[c] = -1; \
 363                 } \
 364         MACRO_END
 365
 366         PARSE_WEAPON_PRIORITIES(far);
 367         PARSE_WEAPON_PRIORITIES(mid);
 368         PARSE_WEAPON_PRIORITIES(close);
 369
 370         bot_custom_weapon = true;
 371 }
 372
 373 void bot_endgame()
 374 {
 375         bot_relinkplayerlist();
 376         entity e = bot_list;
 377         while (e)
 378         {
 379                 setcolor(e, e.bot_preferredcolors);
 380                 e = e.nextbot;
 381         }
 382         // if dynamic waypoints are ever implemented, save them here
 383 }
 384
 385 void bot_relinkplayerlist()
 386 {
 387         player_count = 0;
 388         currentbots = 0;
 389         bot_list = NULL;
 390
 391         entity prevbot = NULL;
 392         FOREACH_CLIENT(true,
 393         {
 394                 ++player_count;
 395
 396                 if(IS_BOT_CLIENT(it))
 397                 {
 398                         if(prevbot)
 399                                 prevbot.nextbot = it;
 400                         else
 401                                 bot_list = it;
 402                         prevbot = it;
 403                         ++currentbots;
 404                 }
 405         });
 406         if(prevbot)
 407                 prevbot.nextbot = NULL;
 408         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 409         bot_strategytoken = bot_list;
 410         bot_strategytoken_taken = true;
 411 }
 412
 413 void bot_clientdisconnect(entity this)
 414 {
 415         if (!IS_BOT_CLIENT(this))
 416                 return;
 417         bot_clearqueue(this);
 418         strfree(this.cleanname);
 419         strfree(this.netname_freeme);
 420         strfree(this.playermodel_freeme);
 421         strfree(this.playerskin_freeme);
 422         if(this.bot_cmd_current)
 423                 delete(this.bot_cmd_current);
 424         if(bot_waypoint_queue_owner == this)
 425                 bot_waypoint_queue_owner = NULL;
 426 }
 427
 428 void bot_clientconnect(entity this)
 429 {
 430         if (!IS_BOT_CLIENT(this)) return;
 431         this.bot_preferredcolors = this.clientcolors;
 432         this.bot_nextthink = time - random();
 433         this.lag_func = bot_lagfunc;
 434         this.isbot = true;
 435         this.createdtime = this.bot_nextthink;
 436
 437         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 438         {
 439                 bot_setnameandstuff(this);
 440                 bot_setclientfields(this);
 441         }
 442
 443         if (teamplay && Team_IsValidIndex(this.bot_forced_team))
 444         {
 445                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 446         }
 447         else
 448         {
 449                 this.bot_forced_team = 0;
 450                 TeamBalance_JoinBestTeam(this);
 451         }
 452
 453         havocbot_setupbot(this);
 454 }
 455
 456 void bot_removefromlargestteam()
 457 {
 458         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 459         TeamBalance_GetTeamCounts(balance, NULL);
 460
 461         entity best = NULL;
 462         float besttime = 0;
 463         int bestcount = 0;
 464
 465         int bcount = 0;
 466         FOREACH_CLIENT(it.isbot,
 467         {
 468                 ++bcount;
 469
 470                 if(!best)
 471                 {
 472                         best = it;
 473                         besttime = it.createdtime;
 474                 }
 475
 476                 int thiscount = 0;
 477
 478                 if (Team_IsValidTeam(it.team))
 479                 {
 480                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 481                                 Team_TeamToIndex(it.team));
 482                 }
 483
 484                 if(thiscount > bestcount)
 485                 {
 486                         bestcount = thiscount;
 487                         besttime = it.createdtime;
 488                         best = it;
 489                 }
 490                 else if(thiscount == bestcount && besttime < it.createdtime)
 491                 {
 492                         besttime = it.createdtime;
 493                         best = it;
 494                 }
 495         });
 496         TeamBalance_Destroy(balance);
 497         if(!bcount)
 498                 return; // no bots to remove
 499         currentbots = currentbots - 1;
 500         dropclient(best);
 501 }
 502
 503 void bot_removenewest()
 504 {
 505         if(teamplay)
 506         {
 507                 bot_removefromlargestteam();
 508                 return;
 509         }
 510
 511         float besttime = 0;
 512         entity best = NULL;
 513         int bcount = 0;
 514
 515         FOREACH_CLIENT(it.isbot,
 516         {
 517                 ++bcount;
 518
 519                 if(!best)
 520                 {
 521                         best = it;
 522                         besttime = it.createdtime;
 523                 }
 524
 525                 if(besttime < it.createdtime)
 526                 {
 527                         besttime = it.createdtime;
 528                         best = it;
 529                 }
 530         });
 531
 532         if(!bcount)
 533                 return; // no bots to remove
 534
 535         currentbots = currentbots - 1;
 536         dropclient(best);
 537 }
 538
 539 void autoskill(float factor)
 540 {
 541         float bestbot;
 542         float bestplayer;
 543
 544         bestbot = -1;
 545         bestplayer = -1;
 546         FOREACH_CLIENT(IS_PLAYER(it), {
 547                 if(IS_REAL_CLIENT(it))
 548                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 549                 else
 550                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 551         });
 552
 553         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 554         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 555         if(bestbot < 0 || bestplayer < 0)
 556         {
 557                 LOG_DEBUG("not doing anything");
 558                 // don't return, let it reset all counters below
 559         }
 560         else if(bestbot <= bestplayer * factor - 2)
 561         {
 562                 if(autocvar_skill < 17)
 563                 {
 564                         LOG_DEBUG("2 frags difference, increasing skill");
 565                         cvar_set("skill", ftos(autocvar_skill + 1));
 566                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 567                 }
 568         }
 569         else if(bestbot >= bestplayer * factor + 2)
 570         {
 571                 if(autocvar_skill > 0)
 572                 {
 573                         LOG_DEBUG("2 frags difference, decreasing skill");
 574                         cvar_set("skill", ftos(autocvar_skill - 1));
 575                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 576                 }
 577         }
 578         else
 579         {
 580                 LOG_DEBUG("not doing anything");
 581                 return;
 582                 // don't reset counters, wait for them to accumulate
 583         }
 584
 585         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 586 }
 587
 588 void bot_calculate_stepheightvec()
 589 {
 590         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 591         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 592         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 593         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
 594 }
 595
 596 bool bot_fixcount()
 597 {
 598         int activerealplayers = 0;
 599         int realplayers = 0;
 600         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 601                 activerealplayers = M_ARGV(0, int);
 602                 realplayers = M_ARGV(1, int);
 603         } else {
 604                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 605                         if(IS_PLAYER(it))
 606                                 ++activerealplayers;
 607                         ++realplayers;
 608                 });
 609         }
 610
 611         int bots;
 612         // But don't remove bots immediately on level change, as the real players
 613         // usually haven't rejoined yet
 614         bots_would_leave = false;
 615         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 616                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 617         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 618         {
 619                 int minplayers = max(0, floor(autocvar_minplayers));
 620                 if (teamplay)
 621                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
 622                 int minbots = max(0, floor(autocvar_bot_number));
 623
 624                 // add bots to reach minplayers if needed
 625                 bots = max(minbots, minplayers - activerealplayers);
 626                 // cap bots to the max players allowed by the server
 627                 int player_limit = GetPlayerLimit();
 628                 if(player_limit)
 629                         bots = min(bots, max(player_limit - activerealplayers, 0));
 630                 bots = min(bots, maxclients - realplayers);
 631
 632                 if(bots > minbots)
 633                         bots_would_leave = true;
 634         }
 635         else
 636         {
 637                 // if there are no players, remove bots
 638                 bots = 0;
 639         }
 640
 641         // only add one bot per frame to avoid utter chaos
 642         if(time > botframe_nextthink)
 643         {
 644                 if (currentbots < bots)
 645                 {
 646                         if (bot_spawn() == NULL)
 647                         {
 648                                 bprint("Can not add bot, server full.\n");
 649                                 return false;
 650                         }
 651                 }
 652                 while (currentbots > bots && bots >= 0)
 653                         bot_removenewest();
 654         }
 655
 656         return true;
 657 }
 658
 659 void bot_remove_from_bot_list(entity this)
 660 {
 661         entity e = bot_list;
 662         entity prev_bot = NULL;
 663         while (e)
 664         {
 665                 if(e == this)
 666                 {
 667                         if(!prev_bot)
 668                                 bot_list = this.nextbot;
 669                         else
 670                                 prev_bot.nextbot = this.nextbot;
 671                         if(bot_strategytoken == this)
 672                         {
 673                                 bot_strategytoken = this.nextbot;
 674                                 bot_strategytoken_taken = true;
 675                         }
 676                         this.nextbot = NULL;
 677                         break;
 678                 }
 679                 prev_bot = e;
 680                 e = e.nextbot;
 681         }
 682 }
 683
 684 void bot_clear(entity this)
 685 {
 686         bot_remove_from_bot_list(this);
 687         if(bot_waypoint_queue_owner == this)
 688                 bot_waypoint_queue_owner = NULL;
 689         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 690 }
 691
 692 void bot_serverframe()
 693 {
 694         if (intermission_running && currentbots > 0)
 695         {
 696                 // after the end of the match all bots stay unless all human players disconnect
 697                 int realplayers = 0;
 698                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 699                 if (!realplayers)
 700                 {
 701                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 702                         currentbots = 0;
 703                 }
 704                 return;
 705         }
 706
 707         if (game_stopped)
 708                 return;
 709
 710         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 711         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 712         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 713         // either intentionally or automatically (sv_spectate 0)
 714         if (time < 2.5)
 715         {
 716                 currentbots = -1;
 717                 return;
 718         }
 719
 720         if (currentbots == -1)
 721         {
 722                 // count bots already in the server from the previous match
 723                 currentbots = 0;
 724                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 725         }
 726
 727         if(autocvar_skill != skill)
 728         {
 729                 float wpcost_update = false;
 730                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 731                         wpcost_update = true;
 732                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 733                         wpcost_update = true;
 734
 735                 skill = autocvar_skill;
 736                 if (wpcost_update)
 737                         waypoint_updatecost_foralllinks();
 738         }
 739
 740         bot_calculate_stepheightvec();
 741         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 742
 743         if(time > autoskill_nextthink)
 744         {
 745                 float a;
 746                 a = autocvar_skill_auto;
 747                 if(a)
 748                         autoskill(a);
 749                 autoskill_nextthink = time + 5;
 750         }
 751
 752         if(time > botframe_nextthink)
 753         {
 754                 if(!bot_fixcount())
 755                         botframe_nextthink = time + 10;
 756         }
 757
 758         if(botframe_spawnedwaypoints)
 759         {
 760                 if(autocvar_waypoint_benchmark)
 761                         localcmd("quit\n");
 762         }
 763
 764         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 765         if (botframe_spawnedwaypoints)
 766         {
 767                 if(botframe_cachedwaypointlinks)
 768                 {
 769                         if(!botframe_loadedforcedlinks)
 770                                 waypoint_load_hardwiredlinks();
 771                 }
 772                 else
 773                 {
 774                         // TODO: Make this check cleaner
 775                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 776                         {
 777                                 waypoint_save_links();
 778                                 break;
 779                         });
 780                 }
 781         }
 782         else
 783         {
 784                 botframe_spawnedwaypoints = true;
 785                 waypoint_loadall();
 786                 waypoint_load_links();
 787         }
 788
 789         if (bot_list)
 790         {
 791                 // cycle the goal token from one bot to the next each frame
 792                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 793                 //  frame, which causes choppy framerates)
 794                 if (bot_strategytoken_taken)
 795                 {
 796                         // give goal token to the first bot without goals; if all bots don't have
 797                         // any goal (or are dead/frozen) simply give it to the next one
 798                         bot_strategytoken_taken = false;
 799                         entity bot_strategytoken_save = bot_strategytoken;
 800                         while (true)
 801                         {
 802                                 if (bot_strategytoken)
 803                                         bot_strategytoken = bot_strategytoken.nextbot;
 804                                 if (!bot_strategytoken)
 805                                         bot_strategytoken = bot_list;
 806
 807                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 808                                         && !bot_strategytoken.goalcurrent)
 809                                         break;
 810
 811                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 812                                         break;
 813                                 if (bot_strategytoken == bot_strategytoken_save)
 814                                         bot_strategytoken_save = NULL; // looped through all the bots
 815                         }
 816                 }
 817
 818                 if (botframe_nextdangertime < time)
 819                 {
 820                         float interval;
 821                         interval = autocvar_bot_ai_dangerdetectioninterval;
 822                         if (botframe_nextdangertime < time - interval * 1.5)
 823                                 botframe_nextdangertime = time;
 824                         botframe_nextdangertime = botframe_nextdangertime + interval;
 825                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 826                 }
 827         }
 828
 829         if (autocvar_g_waypointeditor)
 830                 botframe_showwaypointlinks();
 831
 832         if (autocvar_g_waypointeditor_auto)
 833                 botframe_autowaypoints();
 834
 835         if (currentbots > 0)
 836                 bot_custom_weapon_priority_setup();
 837 }