qcsrc/server/anticheat.qc

   1 #include "anticheat.qh"
   2
   3 #include "antilag.qh"
   4 #include "autocvars.qh"
   5 #include "defs.qh"
   6 #include <server/client.qh>
   7 #include <server/gamelog.qh>
   8 #include <server/sv_main.qh>
   9 #include "miscfunctions.qh"
  10
  11 #include "command/common.qh"
  12 #include <common/playerstats.qh>
  13 #include <common/state.qh>
  14
  15 .float anticheat_jointime;
  16
  17 .float anticheat_fixangle_endtime;
  18
  19 float anticheat_div0_evade_evasion_delta;
  20 .float anticheat_div0_evade_offset;
  21 .vector anticheat_div0_evade_v_angle;
  22 .vector anticheat_div0_evade_forward_initial;
  23 MEAN_DECLARE(anticheat_div0_evade, 5);
  24
  25 .vector anticheat_div0_strafebot_movement_prev;
  26 MEAN_DECLARE(anticheat_div0_strafebot_old, 5);
  27
  28 .vector anticheat_div0_strafebot_forward_prev;
  29 MEAN_DECLARE(anticheat_div0_strafebot_new, 5);
  30
  31 // Snap-aim detection: we track the average angular speed of aiming over time, in "radians per second".
  32 // Signal: a high-power mean. Cheaters will have high "signal" here.
  33 // Noise: a low-power mean. Active/shivery players will have high "noise" here.
  34 // Note one can always artificially add noise - so very high values of both signal and noise need to be checked too.
  35 MEAN_DECLARE(anticheat_idle_snapaim_signal, 5);
  36 MEAN_DECLARE(anticheat_idle_snapaim_noise, 1);
  37
  38 // TEMP DEBUG STUFF.
  39 MEAN_DECLARE(anticheat_idle_snapaim_m2, 2);
  40 MEAN_DECLARE(anticheat_idle_snapaim_m3, 3);
  41 MEAN_DECLARE(anticheat_idle_snapaim_m4, 4);
  42 MEAN_DECLARE(anticheat_idle_snapaim_m7, 7);
  43 MEAN_DECLARE(anticheat_idle_snapaim_m10, 10);
  44
  45 .float anticheat_speedhack_offset;
  46 .float anticheat_speedhack_movetime, anticheat_speedhack_movetime_count, anticheat_speedhack_movetime_frac;
  47 MEAN_DECLARE(anticheat_speedhack, 5);
  48
  49 .float anticheat_speedhack_accu;
  50 .float anticheat_speedhack_lasttime;
  51 MEAN_DECLARE(anticheat_speedhack_m1, 1);
  52 MEAN_DECLARE(anticheat_speedhack_m2, 2);
  53 MEAN_DECLARE(anticheat_speedhack_m3, 3);
  54 MEAN_DECLARE(anticheat_speedhack_m4, 4);
  55 MEAN_DECLARE(anticheat_speedhack_m5, 5);
  56
  57 float movement_oddity(vector m0, vector m1)
  58 {
  59         float cosangle = normalize(m0) * normalize(m1);
  60         if(cosangle >= 0)
  61                 return 0;
  62         return 0.5 - 0.5 * cos(cosangle * cosangle * 4 * M_PI);
  63                 // returns 0 for: -1, -sqrt(0.5), 0 (angles that commonly happen with kbd)
  64 }
  65
  66 void anticheat_physics(entity this)
  67 {
  68         float f;
  69
  70         // div0_evade -> SPECTATORS
  71         makevectors(this.v_angle);
  72         if(CS(this).anticheat_div0_evade_offset == 0)
  73         {
  74                 f = fabs(anticheat_div0_evade_evasion_delta - floor(anticheat_div0_evade_evasion_delta) - 0.5) * 2; // triangle function
  75                 CS(this).anticheat_div0_evade_offset = servertime + sys_frametime * (3 * f - 1);
  76                 CS(this).anticheat_div0_evade_v_angle = this.v_angle;
  77                 CS(this).anticheat_div0_evade_forward_initial = v_forward;
  78                 MEAN_ACCUMULATE(CS(this), anticheat_div0_evade, 0, 1);
  79         }
  80         else
  81         {
  82                 if(time < CS(this).anticheat_div0_evade_offset)
  83                         CS(this).anticheat_div0_evade_v_angle = this.v_angle;
  84                 MEAN_ACCUMULATE(CS(this), anticheat_div0_evade, 0.5 - 0.5 * (CS(this).anticheat_div0_evade_forward_initial * v_forward), 1);
  85         }
  86
  87         MEAN_ACCUMULATE(CS(this), anticheat_div0_strafebot_old, movement_oddity(CS(this).movement, CS(this).anticheat_div0_strafebot_movement_prev), 1);
  88         CS(this).anticheat_div0_strafebot_movement_prev = CS(this).movement;
  89
  90         // Note: this actually tries to detect snap-aim.
  91         if(CS(this).anticheat_div0_strafebot_forward_prev && time > CS(this).anticheat_fixangle_endtime) {
  92                 float cosangle = CS(this).anticheat_div0_strafebot_forward_prev * v_forward;
  93                 float angle = cosangle < -1 ? M_PI : cosangle > 1 ? 0 : acos(cosangle);
  94                 /*
  95                 if (angle >= 10 * M_PI / 180)
  96                         printf("SNAP %s: %f for %f, %f since fixangle\n", this.netname, angle * 180 / M_PI, cosangle, time - CS(this).anticheat_fixangle_endtime);
  97                 */
  98                 MEAN_ACCUMULATE(CS(this), anticheat_div0_strafebot_new, angle / M_PI, 1);
  99
 100                 if (autocvar_slowmo > 0) {
 101                         // Technically this is a NOP, as the engine should be ensuring
 102                         // this in the first place. Let's guard against dividing by
 103                         // zero anyway.
 104                         float dt = max(0.001, frametime) / autocvar_slowmo;
 105
 106                         float anglespeed = angle / dt;
 107                         MEAN_ACCUMULATE(CS(this), anticheat_idle_snapaim_signal, anglespeed, dt);
 108                         MEAN_ACCUMULATE(CS(this), anticheat_idle_snapaim_noise, anglespeed, dt);
 109                         MEAN_ACCUMULATE(CS(this), anticheat_idle_snapaim_m2, anglespeed, dt);
 110                         MEAN_ACCUMULATE(CS(this), anticheat_idle_snapaim_m3, anglespeed, dt);
 111                         MEAN_ACCUMULATE(CS(this), anticheat_idle_snapaim_m4, anglespeed, dt);
 112                         MEAN_ACCUMULATE(CS(this), anticheat_idle_snapaim_m7, anglespeed, dt);
 113                         MEAN_ACCUMULATE(CS(this), anticheat_idle_snapaim_m10, anglespeed, dt);
 114                 }
 115         }
 116         CS(this).anticheat_div0_strafebot_forward_prev = v_forward;
 117
 118         // generic speedhack detection: correlate anticheat_speedhack_movetime (UPDATED BEFORE THIS) and server time
 119         CS(this).anticheat_speedhack_movetime_frac += frametime;
 120         f = floor(CS(this).anticheat_speedhack_movetime_frac);
 121         CS(this).anticheat_speedhack_movetime_frac -= f;
 122         CS(this).anticheat_speedhack_movetime_count += f;
 123         CS(this).anticheat_speedhack_movetime = CS(this).anticheat_speedhack_movetime_frac + CS(this).anticheat_speedhack_movetime_count;
 124         f = CS(this).anticheat_speedhack_movetime - servertime;
 125         if(CS(this).anticheat_speedhack_offset == 0)
 126                 CS(this).anticheat_speedhack_offset = f;
 127         else
 128         {
 129                 MEAN_ACCUMULATE(CS(this), anticheat_speedhack, max(0, f - CS(this).anticheat_speedhack_offset), 1);
 130                 CS(this).anticheat_speedhack_offset += (f - CS(this).anticheat_speedhack_offset) * frametime * 0.1;
 131         }
 132
 133         // new generic speedhack detection
 134         if (CS(this).anticheat_speedhack_lasttime > 0) {
 135                 float dt = servertime - CS(this).anticheat_speedhack_lasttime;
 136                 const float falloff = 0.2;
 137                 CS(this).anticheat_speedhack_accu *= exp(-dt * falloff);
 138                 CS(this).anticheat_speedhack_accu += frametime * falloff;
 139                 // NOTE: at cl_netfps x, this actually averages not to 1, but to 1/x * falloff / (1 - exp(-1/x * falloff))
 140                 // For 15 netfps (absolute minimum bearable), and 0.2 falloff, this is: 1.0067
 141                 CS(this).anticheat_speedhack_lasttime = servertime;
 142                 MEAN_ACCUMULATE(CS(this), anticheat_speedhack_m1, CS(this).anticheat_speedhack_accu, frametime);
 143                 MEAN_ACCUMULATE(CS(this), anticheat_speedhack_m2, CS(this).anticheat_speedhack_accu, frametime);
 144                 MEAN_ACCUMULATE(CS(this), anticheat_speedhack_m3, CS(this).anticheat_speedhack_accu, frametime);
 145                 MEAN_ACCUMULATE(CS(this), anticheat_speedhack_m4, CS(this).anticheat_speedhack_accu, frametime);
 146                 MEAN_ACCUMULATE(CS(this), anticheat_speedhack_m5, CS(this).anticheat_speedhack_accu, frametime);
 147         } else {
 148                 CS(this).anticheat_speedhack_accu = 1;
 149                 CS(this).anticheat_speedhack_lasttime = servertime;
 150         }
 151 }
 152
 153 void anticheat_spectatecopy(entity this, entity spectatee)
 154 {
 155         // div0_evade -> SPECTATORS
 156         this.angles = CS(spectatee).anticheat_div0_evade_v_angle;
 157 }
 158
 159 void anticheat_prethink(entity this)
 160 {
 161         // div0_evade -> SPECTATORS
 162         CS(this).anticheat_div0_evade_offset = 0;
 163 }
 164
 165 string anticheat_display(float f, float t, float tmin, float mi, float ma)
 166 {
 167         string s;
 168         s = ftos(f);
 169         if (t >= tmin) {
 170                 if(f <= mi)
 171                         return strcat(s, ":N");
 172                 if(f >= ma)
 173                         return strcat(s, ":Y");
 174         }
 175         return strcat(s, ":-");
 176 }
 177
 178 #define ANTICHEATS(ANTICHEAT) \
 179         ANTICHEAT("speedhack", MEAN_EVALUATE(CS(this), anticheat_speedhack), 240, 0, 9999); /* Actually this one seems broken. */ \
 180         ANTICHEAT("speedhack_m1", MEAN_EVALUATE(CS(this), anticheat_speedhack_m1), 240, 1.01, 1.25); \
 181         ANTICHEAT("speedhack_m2", MEAN_EVALUATE(CS(this), anticheat_speedhack_m2), 240, 1.01, 1.25); \
 182         ANTICHEAT("speedhack_m3", MEAN_EVALUATE(CS(this), anticheat_speedhack_m3), 240, 1.01, 1.25); \
 183         ANTICHEAT("speedhack_m4", MEAN_EVALUATE(CS(this), anticheat_speedhack_m4), 240, 1.01, 1.25); \
 184         ANTICHEAT("speedhack_m5", MEAN_EVALUATE(CS(this), anticheat_speedhack_m5), 240, 1.01, 1.25); \
 185         ANTICHEAT("div0_strafebot_old", MEAN_EVALUATE(CS(this), anticheat_div0_strafebot_old), 120, 0.15, 0.4); \
 186         ANTICHEAT("div0_strafebot_new", MEAN_EVALUATE(CS(this), anticheat_div0_strafebot_new), 120, 0.25, 0.8); \
 187         ANTICHEAT("div0_evade", MEAN_EVALUATE(CS(this), anticheat_div0_evade), 120, 0.2, 0.5); \
 188         ANTICHEAT("idle_snapaim", MEAN_EVALUATE(CS(this), anticheat_idle_snapaim_signal) - MEAN_EVALUATE(CS(this), anticheat_idle_snapaim_noise), 120, 0, 9999); \
 189         ANTICHEAT("idle_snapaim_signal", MEAN_EVALUATE(CS(this), anticheat_idle_snapaim_signal), 120, 0, 9999); \
 190         ANTICHEAT("idle_snapaim_noise", MEAN_EVALUATE(CS(this), anticheat_idle_snapaim_noise), 120, 0, 9999); \
 191         ANTICHEAT("idle_snapaim_m2", MEAN_EVALUATE(CS(this), anticheat_idle_snapaim_m2), 120, 0, 9999); \
 192         ANTICHEAT("idle_snapaim_m3", MEAN_EVALUATE(CS(this), anticheat_idle_snapaim_m3), 120, 0, 9999); \
 193         ANTICHEAT("idle_snapaim_m4", MEAN_EVALUATE(CS(this), anticheat_idle_snapaim_m4), 120, 0, 9999); \
 194         ANTICHEAT("idle_snapaim_m7", MEAN_EVALUATE(CS(this), anticheat_idle_snapaim_m7), 120, 0, 9999); \
 195         ANTICHEAT("idle_snapaim_m10", MEAN_EVALUATE(CS(this), anticheat_idle_snapaim_m10), 120, 0, 9999)
 196
 197 void anticheat_report_to_eventlog(entity this) {
 198         if(!autocvar_sv_eventlog)
 199                 return;
 200         GameLogEcho(strcat(":anticheat:_time:", ftos(this.playerid), ":", ftos(servertime - CS(this).anticheat_jointime)));
 201 #define ANTICHEAT_REPORT_ONE(name, f, tmin, mi, ma) \
 202         GameLogEcho(strcat(":anticheat:", name, ":", anticheat_display(f, servertime - CS(this).anticheat_jointime, tmin, mi, ma)))
 203         ANTICHEATS(ANTICHEAT_REPORT_ONE);
 204 #undef ANTICHEAT_REPORT_ONE
 205 }
 206
 207 void anticheat_report_to_playerstats(entity this) {
 208         PlayerStats_GameReport_Event_Player(this,
 209                 strcat(PLAYERSTATS_ANTICHEAT, "_time"), servertime - CS(this).anticheat_jointime);
 210 #define ANTICHEAT_REPORT_ONE(name, f, tmin, mi, ma) \
 211         PlayerStats_GameReport_Event_Player(this, strcat(PLAYERSTATS_ANTICHEAT, name), f)
 212         ANTICHEATS(ANTICHEAT_REPORT_ONE);
 213 #undef ANTICHEAT_REPORT_ONE
 214 }
 215
 216 void anticheat_register_to_playerstats() {
 217         PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_ANTICHEAT, "_time"));
 218 #define ANTICHEAT_REGISTER_ONE(name, unused_f, unused_tmin, unused_mi, unused_ma) \
 219         PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_ANTICHEAT, name))
 220         ANTICHEATS(ANTICHEAT_REGISTER_ONE);
 221 #undef ANTICHEAT_REGISTER_ONE
 222 }
 223
 224 #undef ANTICHEATS
 225
 226 void anticheat_startframe()
 227 {
 228         anticheat_div0_evade_evasion_delta += frametime * (0.5 + random());
 229 }
 230
 231 void anticheat_fixangle(entity this)
 232 {
 233         CS(this).anticheat_fixangle_endtime = servertime + ANTILAG_LATENCY(this) + 0.2;
 234 }
 235
 236 void anticheat_endframe()
 237 {
 238         FOREACH_CLIENT(it.fixangle, anticheat_fixangle(it));
 239         anticheat_div0_evade_evasion_delta += frametime * (0.5 + random());
 240 }
 241
 242 void anticheat_init(entity this)
 243 {
 244         CS(this).anticheat_speedhack_offset = 0;
 245         CS(this).anticheat_jointime = servertime;
 246 }