qcsrc/menu/xonotic/playlist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticPlayList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticPlayList, configureXonoticPlayList, void(entity))
   4         ATTRIB(XonoticPlayList, rowsPerItem, float, 1)
   5         METHOD(XonoticPlayList, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(XonoticPlayList, draw, void(entity))
   7         METHOD(XonoticPlayList, drawListBoxItem, void(entity, float, vector, float))
   8         METHOD(XonoticPlayList, stopSound, void(entity))
   9         METHOD(XonoticPlayList, startSound, void(entity, float))
  10         METHOD(XonoticPlayList, pauseSound, void(entity))
  11         METHOD(XonoticPlayList, clickListBoxItem, void(entity, float, vector))
  12         METHOD(XonoticPlayList, keyDown, float(entity, float, float, float))
  13         METHOD(XonoticPlayList, mouseDrag, float(entity, vector))
  14
  15         METHOD(XonoticPlayList, addToPlayList, void(entity, string))
  16         METHOD(XonoticPlayList, removeFromPlayList, void(entity, string))
  17         ATTRIB(XonoticPlayList, playingTrack, string, string_null)
  18
  19         ATTRIB(XonoticPlayList, realFontSize, vector, '0 0 0')
  20         ATTRIB(XonoticPlayList, columnNameOrigin, float, 0)
  21         ATTRIB(XonoticPlayList, columnNameSize, float, 0)
  22         ATTRIB(XonoticPlayList, columnNumberOrigin, float, 0)
  23         ATTRIB(XonoticPlayList, columnNumberSize, float, 0)
  24         ATTRIB(XonoticPlayList, realUpperMargin, float, 0)
  25         ATTRIB(XonoticPlayList, origin, vector, '0 0 0')
  26         ATTRIB(XonoticPlayList, itemAbsSize, vector, '0 0 0')
  27
  28         ATTRIB(XonoticPlayList, lastClickedSound, float, -1)
  29         ATTRIB(XonoticPlayList, lastClickedTime, float, 0)
  30 ENDCLASS(XonoticPlayList)
  31
  32 entity makeXonoticPlayList();
  33 void StopSound_Click(entity btn, entity me);
  34 void StartSound_Click(entity btn, entity me);
  35 void PauseSound_Click(entity btn, entity me);
  36 void PrevSound_Click(entity btn, entity me);
  37 void NextSound_Click(entity btn, entity me);
  38 #endif
  39
  40 #ifdef IMPLEMENTATION
  41
  42 entity makeXonoticPlayList()
  43 {
  44         entity me;
  45         me = spawnXonoticPlayList();
  46         me.configureXonoticPlayList(me);
  47         return me;
  48 }
  49
  50 void XonoticPlayList_configureXonoticPlayList(entity me)
  51 {
  52         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
  53         me.configureXonoticListBox(me);
  54 }
  55
  56 void XonoticPlayList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  57 {
  58         me.itemAbsSize = '0 0 0';
  59         SUPER(XonoticPlayList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  60
  61         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
  62         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
  63         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
  64
  65         me.columnNumberOrigin = 0;
  66         me.columnNumberSize = 3 * me.realFontSize_x;
  67
  68         me.columnNameOrigin = me.columnNumberSize + me.realFontSize_x;
  69         me.columnNameSize = 1 - me.columnNameOrigin - me.realFontSize_x;
  70 }
  71
  72 void XonoticPlayList_addToPlayList(entity me, string track)
  73 {
  74         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
  75         if(me.nItems == 0)
  76         {
  77                 cvar_set("music_playlist_list0", track);
  78                 return;
  79         }
  80         float i;
  81         for(i = 0; i < me.nItems; ++i)
  82         {
  83                 if(argv(i) == track)
  84                         return; // track is already in playlist
  85         }
  86         cvar_set("music_playlist_list0", strcat(cvar_string("music_playlist_list0"), " ", track));
  87 }
  88
  89 void XonoticPlayList_removeFromPlayList(entity me, string track)
  90 {
  91         float i, cpt = FALSE;
  92         string s = "";
  93         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
  94         if(me.nItems == 0)
  95                 return;
  96         for(i = 0; i < me.nItems; ++i)
  97         {
  98                 if(argv(i) == track)
  99                 {
 100                         if(i == me.nItems - 1)
 101                                 me.setSelected(me, me.selectedItem - 1);
 102                         if(cvar("music_playlist_index") == 0 || cvar("music_playlist_index") == 999)
 103                         {
 104                                 if(cvar("music_playlist_current0") == i)
 105                                         cpt = TRUE; // current playing track (we can't start next track here because startSound calls tokenize_console)
 106                                 else
 107                                 {
 108                                         if(cvar("music_playlist_current0") > i)
 109                                                 cvar_set("music_playlist_current0", ftos(cvar("music_playlist_current0") - 1));
 110                                 }
 111                         }
 112                         continue;
 113                 }
 114                 s = strcat(s, " ", argv(i));
 115         }
 116         if(s == "")
 117                 cvar_set("music_playlist_list0", "");
 118         else
 119                 cvar_set("music_playlist_list0", substring(s, 1, strlen(s))); //remove initial space
 120         if(cpt)
 121                 me.startSound(me, 0); // stop current playing track otherwise pause/play button will resume from another track
 122 }
 123
 124 float XonoticPlayList_mouseDrag(entity me, vector pos)
 125 {
 126         float f, i;
 127         i = me.selectedItem;
 128         f = SUPER(XonoticPlayList).mouseDrag(me, pos);
 129
 130         if(me.pressed != 1) // don't change priority if the person is just scrolling
 131         {
 132                 if(me.selectedItem != i)
 133                 {
 134                         cvar_set("music_playlist_list0", swapInPriorityList(cvar_string("music_playlist_list0"), me.selectedItem, i));
 135                         float c = cvar("music_playlist_current0");
 136                         if(c == i)
 137                                 cvar_set("music_playlist_current0", ftos(me.selectedItem));
 138                         else if(c == me.selectedItem)
 139                                 cvar_set("music_playlist_current0", ftos(i));
 140                 }
 141         }
 142
 143         return f;
 144 }
 145
 146 void XonoticPlayList_draw(entity me)
 147 {
 148         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
 149         SUPER(XonoticPlayList).draw(me);
 150 }
 151
 152 void XonoticPlayList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 153 {
 154         string s;
 155         if(isSelected)
 156                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 157
 158         if(argv(i) == me.playingTrack)
 159         {
 160                 float f = cvar("music_playlist_sampleposition0");
 161                 if(f == 0 || (((time * 2) & 1) && f > 0))
 162                         draw_Text(me.realUpperMargin * eY + (me.columnNumberOrigin + me.columnNumberSize) * eX, chr(0xE000 + 141), me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 163         }
 164
 165         s = ftos(i+1);
 166         draw_CenterText(me.realUpperMargin * eY + (me.columnNumberOrigin + 0.5 * me.columnNumberSize) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 167
 168         s = draw_TextShortenToWidth(argv(i), me.columnNameSize, 0, me.realFontSize);
 169         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 170 }
 171
 172 void XonoticPlayList_stopSound(entity me)
 173 {
 174         // STOP: list 0 is disabled by setting the index to -1
 175         // we set sampleposition0 to -1 to indicate that music is stopped
 176         if(cvar("music_playlist_index") != -1) // == 0 doesn't work when paused
 177         {
 178                 cvar_set("music_playlist_index", "-1");
 179                 localcmd("\nwait; music_playlist_sampleposition0 -1\n");
 180                 localcmd("\ndefer 3 \"cd play $menu_cdtrack\"\n");
 181         }
 182 }
 183
 184 void StopSound_Click(entity btn, entity me)
 185 {
 186         me.stopSound(me);
 187 }
 188
 189 void XonoticPlayList_startSound(entity me, float offset)
 190 {
 191         float f;
 192         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
 193         if(offset)
 194         {
 195                 f = bound(0, cvar("music_playlist_current0") + offset, me.nItems - 1);
 196                 if(f == cvar("music_playlist_current0"))
 197                         return;
 198         }
 199         else
 200                 f = me.selectedItem;
 201         if(me.playingTrack)
 202                 strunzone(me.playingTrack);
 203         me.playingTrack = strzone(argv(f));
 204         // START: list 0 is disabled by setting the index to 999
 205         // we set current0 to the selected track and sampleposition0 to 0 to forget value saved by the engine
 206         // then we switch back to list 0
 207         cvar_set("music_playlist_index", "999");
 208         cvar_set("music_playlist_current0", ftos(f));
 209         localcmd("\nwait; music_playlist_sampleposition0 0; wait; music_playlist_index 0\n");
 210 }
 211
 212 void StartSound_Click(entity btn, entity me)
 213 {
 214         me.startSound(me, 0);
 215 }
 216
 217 void PrevSound_Click(entity btn, entity me)
 218 {
 219         me.startSound(me, -1);
 220 }
 221
 222 void NextSound_Click(entity btn, entity me)
 223 {
 224         me.startSound(me, +1);
 225 }
 226
 227 void XonoticPlayList_pauseSound(entity me)
 228 {
 229         // PAUSE: list 0 is disabled by setting the index to 999
 230         // (we know the track is paused because the engine sets sampleposition0 to remember current position)
 231         // RESUME: list 0 is enabled by setting the index to 0
 232         // (we reset sampleposition0 to 0 to mark the track as in playing back state)
 233         if(cvar("music_playlist_index") == 0)
 234                 localcmd("\nmusic_playlist_index 999\n");
 235         else
 236                 localcmd("\nmusic_playlist_index 0; wait; music_playlist_sampleposition0 0\n");
 237 }
 238
 239 void PauseSound_Click(entity btn, entity me)
 240 {
 241         me.pauseSound(me);
 242 }
 243
 244 void XonoticPlayList_clickListBoxItem(entity me, float i, vector where)
 245 {
 246         if(i == me.lastClickedSound)
 247                 if(time < me.lastClickedTime + 0.3)
 248                 {
 249                         // DOUBLE CLICK!
 250                         me.setSelected(me, i);
 251                         me.startSound(me, 0);
 252                 }
 253         me.lastClickedSound = i;
 254         me.lastClickedTime = time;
 255 }
 256
 257 float XonoticPlayList_keyDown(entity me, float scan, float ascii, float shift)
 258 {
 259         if(scan == K_ENTER || scan == K_KP_ENTER) {
 260                 me.startSound(me, 0);
 261                 return 1;
 262         }
 263         else if(scan == K_SPACE) {
 264                 me.pauseSound(me);
 265                 return 1;
 266         }
 267         else if(scan == K_DEL || scan == K_KP_DEL || scan == K_BACKSPACE || scan == K_MOUSE3) {
 268                 me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
 269                 me.removeFromPlayList(me, argv(me.selectedItem));
 270                 return 1;
 271         }
 272         else
 273                 return SUPER(XonoticPlayList).keyDown(me, scan, ascii, shift);
 274 }
 275 #endif
 276