qcsrc/menu/xonotic/playlist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticPlayList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticPlayList, configureXonoticPlayList, void(entity))
   4         ATTRIB(XonoticPlayList, rowsPerItem, float, 1)
   5         METHOD(XonoticPlayList, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(XonoticPlayList, draw, void(entity))
   7         METHOD(XonoticPlayList, drawListBoxItem, void(entity, float, vector, float))
   8         METHOD(XonoticPlayList, stopSound, void(entity))
   9         METHOD(XonoticPlayList, startSound, void(entity, float))
  10         METHOD(XonoticPlayList, pauseSound, void(entity))
  11         METHOD(XonoticPlayList, clickListBoxItem, void(entity, float, vector))
  12         METHOD(XonoticPlayList, keyDown, float(entity, float, float, float))
  13         METHOD(XonoticPlayList, mouseDrag, float(entity, vector))
  14
  15         METHOD(XonoticPlayList, addToPlayList, void(entity, string))
  16         METHOD(XonoticPlayList, removeFromPlayList, void(entity, string))
  17         ATTRIB(XonoticPlayList, playingTrack, string, string_null)
  18
  19         ATTRIB(XonoticPlayList, realFontSize, vector, '0 0 0')
  20         ATTRIB(XonoticPlayList, columnNameOrigin, float, 0)
  21         ATTRIB(XonoticPlayList, columnNameSize, float, 0)
  22         ATTRIB(XonoticPlayList, realUpperMargin, float, 0)
  23         ATTRIB(XonoticPlayList, origin, vector, '0 0 0')
  24         ATTRIB(XonoticPlayList, itemAbsSize, vector, '0 0 0')
  25
  26         ATTRIB(XonoticPlayList, lastClickedSound, float, -1)
  27         ATTRIB(XonoticPlayList, lastClickedTime, float, 0)
  28 ENDCLASS(XonoticPlayList)
  29
  30 entity makeXonoticPlayList();
  31 void StopSound_Click(entity btn, entity me);
  32 void StartSound_Click(entity btn, entity me);
  33 void PauseSound_Click(entity btn, entity me);
  34 void PrevSound_Click(entity btn, entity me);
  35 void NextSound_Click(entity btn, entity me);
  36 #endif
  37
  38 #ifdef IMPLEMENTATION
  39
  40 entity makeXonoticPlayList()
  41 {
  42         entity me;
  43         me = spawnXonoticPlayList();
  44         me.configureXonoticPlayList(me);
  45         return me;
  46 }
  47
  48 void XonoticPlayList_configureXonoticPlayList(entity me)
  49 {
  50         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
  51         me.configureXonoticListBox(me);
  52 }
  53
  54 void XonoticPlayList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  55 {
  56         me.itemAbsSize = '0 0 0';
  57         SUPER(XonoticPlayList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  58
  59         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
  60         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
  61         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
  62
  63         me.columnNameOrigin = me.realFontSize_x;
  64         me.columnNameSize = 1 - 2 * me.realFontSize_x;
  65 }
  66
  67 void XonoticPlayList_addToPlayList(entity me, string track)
  68 {
  69         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
  70         if(me.nItems == 0)
  71         {
  72                 cvar_set("music_playlist_list0", track);
  73                 return;
  74         }
  75         float i;
  76         for(i = 0; i < me.nItems; ++i)
  77         {
  78                 if(argv(i) == track)
  79                         return; // track is already in playlist
  80         }
  81         cvar_set("music_playlist_list0", strcat(cvar_string("music_playlist_list0"), " ", track));
  82 }
  83
  84 void XonoticPlayList_removeFromPlayList(entity me, string track)
  85 {
  86         float i;
  87         string s = "";
  88         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
  89         if(me.nItems == 0)
  90                 return;
  91         for(i = 0; i < me.nItems; ++i)
  92         {
  93                 if(argv(i) == track)
  94                 if(cvar("music_playlist_current0") != i) // forbid removing the current playing track, otherwise pause button will resume from another track
  95                 {
  96                         if(cvar("music_playlist_current0") > i)
  97                                 cvar_set("music_playlist_current0", ftos(cvar("music_playlist_current0") - 1));
  98                         continue;
  99                 }
 100                 s = strcat(s, " ", argv(i));
 101         }
 102         if(s == "")
 103                 cvar_set("music_playlist_list0", "");
 104         else
 105                 cvar_set("music_playlist_list0", substring(s, 1, strlen(s))); //remove initial space
 106 }
 107
 108 float XonoticPlayList_mouseDrag(entity me, vector pos)
 109 {
 110         float f, i;
 111         i = me.selectedItem;
 112         f = SUPER(XonoticPlayList).mouseDrag(me, pos);
 113
 114         if(me.pressed != 1) // don't change priority if the person is just scrolling
 115         {
 116                 if(me.selectedItem != i)
 117                 {
 118                         cvar_set("music_playlist_list0", swapInPriorityList(cvar_string("music_playlist_list0"), me.selectedItem, i));
 119                         float c = cvar("music_playlist_current0");
 120                         if(c == i)
 121                                 cvar_set("music_playlist_current0", ftos(me.selectedItem));
 122                         else if(c == me.selectedItem)
 123                                 cvar_set("music_playlist_current0", ftos(i));
 124                 }
 125         }
 126
 127         return f;
 128 }
 129
 130 void XonoticPlayList_draw(entity me)
 131 {
 132         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
 133         SUPER(XonoticPlayList).draw(me);
 134 }
 135
 136 void XonoticPlayList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 137 {
 138         string s;
 139         if(isSelected)
 140                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 141
 142         if(argv(i) == me.playingTrack)
 143         {
 144                 float f = cvar("music_playlist_sampleposition0");
 145                 if(f == 0 || (((time * 2) & 1) && f > 0))
 146                         draw_Text(me.realUpperMargin * eY, chr(0xE000 + 141), me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 147         }
 148
 149         s = argv(i);
 150         s = strcat(ftos(i+1), ") ", s);
 151         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 152         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 153 }
 154
 155 void XonoticPlayList_stopSound(entity me)
 156 {
 157         // STOP: list 0 is disabled by setting the index to -1
 158         // we set sampleposition0 to -1 to indicate that music is stopped
 159         if(cvar("music_playlist_index") != -1) // == 0 doesn't work when paused
 160         {
 161                 cvar_set("music_playlist_index", "-1");
 162                 localcmd("\nwait; music_playlist_sampleposition0 -1\n");
 163                 localcmd("\ndefer 3 \"cd play $menu_cdtrack\"\n");
 164         }
 165 }
 166
 167 void StopSound_Click(entity btn, entity me)
 168 {
 169         me.stopSound(me);
 170 }
 171
 172 void XonoticPlayList_startSound(entity me, float offset)
 173 {
 174         float f;
 175         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
 176         if(offset)
 177         {
 178                 f = bound(0, cvar("music_playlist_current0") + offset, me.nItems - 1);
 179                 if(f == cvar("music_playlist_current0"))
 180                         return;
 181         }
 182         else
 183                 f = me.selectedItem;
 184         if(me.playingTrack)
 185                 strunzone(me.playingTrack);
 186         me.playingTrack = strzone(argv(f));
 187         // START: list 0 is disabled by setting the index to 999
 188         // we set current0 to the selected track and sampleposition0 to 0 to forget value saved by the engine
 189         // then we switch back to list 0
 190         cvar_set("music_playlist_index", "999");
 191         cvar_set("music_playlist_current0", ftos(f));
 192         localcmd("\nwait; music_playlist_sampleposition0 0; wait; music_playlist_index 0\n");
 193 }
 194
 195 void StartSound_Click(entity btn, entity me)
 196 {
 197         me.startSound(me, 0);
 198 }
 199
 200 void PrevSound_Click(entity btn, entity me)
 201 {
 202         me.startSound(me, -1);
 203 }
 204
 205 void NextSound_Click(entity btn, entity me)
 206 {
 207         me.startSound(me, +1);
 208 }
 209
 210 void XonoticPlayList_pauseSound(entity me)
 211 {
 212         // PAUSE: list 0 is disabled by setting the index to 999
 213         // (we know the track is paused because the engine sets sampleposition0 to remember current position)
 214         // RESUME: list 0 is enabled by setting the index to 0
 215         // (we reset sampleposition0 to 0 to mark the track as in playing back state)
 216         if(cvar("music_playlist_index") == 0)
 217                 localcmd("\nmusic_playlist_index 999\n");
 218         else
 219                 localcmd("\nmusic_playlist_index 0; wait; music_playlist_sampleposition0 0\n");
 220 }
 221
 222 void PauseSound_Click(entity btn, entity me)
 223 {
 224         me.pauseSound(me);
 225 }
 226
 227 void XonoticPlayList_clickListBoxItem(entity me, float i, vector where)
 228 {
 229         if(i == me.lastClickedSound)
 230                 if(time < me.lastClickedTime + 0.3)
 231                 {
 232                         // DOUBLE CLICK!
 233                         me.setSelected(me, i);
 234                         me.startSound(me, 0);
 235                 }
 236         me.lastClickedSound = i;
 237         me.lastClickedTime = time;
 238 }
 239
 240 float XonoticPlayList_keyDown(entity me, float scan, float ascii, float shift)
 241 {
 242         if(scan == K_ENTER || scan == K_KP_ENTER) {
 243                 me.startSound(me, 0);
 244                 return 1;
 245         }
 246         else if(scan == K_SPACE) {
 247                 me.pauseSound(me);
 248                 return 1;
 249         }
 250         else if(scan == K_DEL || scan == K_KP_DEL || scan == K_BACKSPACE || scan == K_MOUSE3) {
 251                 me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
 252                 me.removeFromPlayList(me, argv(me.selectedItem));
 253                 return 1;
 254         }
 255         else
 256                 return SUPER(XonoticPlayList).keyDown(me, scan, ascii, shift);
 257 }
 258 #endif
 259