qcsrc/common/weapons/weapon/arc.qc

   1 #include "arc.qh"
   2
   3 #ifdef SVQC
   4 #include <common/gamemodes/gamemode/onslaught/sv_onslaught.qh>
   5 #include <common/gamemodes/gamemode/onslaught/sv_generator.qh>
   6
   7 bool W_Arc_Beam_Send(entity this, entity to, int sf)
   8 {
   9         WriteHeader(MSG_ENTITY, ENT_CLIENT_ARC_BEAM);
  10
  11         // Truncate information when this beam is displayed to the owner client
  12         // - The owner client has no use for beam start position or directions,
  13         //    it always figures this information out for itself with csqc code.
  14         // - Spectating the owner also truncates this information.
  15         float drawlocal = ((to == this.owner) || ((to.enemy == this.owner) && IS_SPEC(to)));
  16         if(drawlocal) { sf &= ~ARC_SF_LOCALMASK; }
  17
  18         WriteByte(MSG_ENTITY, sf);
  19         WriteByte(MSG_ENTITY, weaponslot(this.weaponentity_fld));
  20
  21         if(sf & ARC_SF_SETTINGS) // settings information
  22         {
  23                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_degreespersegment));
  24                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_distancepersegment));
  25                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_maxangle));
  26                 WriteCoord(MSG_ENTITY, WEP_CVAR(arc, beam_range));
  27                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_returnspeed));
  28                 WriteByte(MSG_ENTITY, WEP_CVAR(arc, beam_tightness) * 10);
  29
  30                 WriteByte(MSG_ENTITY, drawlocal);
  31                 WriteByte(MSG_ENTITY, etof(this.owner));
  32         }
  33         if(sf & ARC_SF_START) // starting location
  34         {
  35                 WriteVector(MSG_ENTITY, this.beam_start);
  36         }
  37         if(sf & ARC_SF_WANTDIR) // want/aim direction
  38         {
  39                 WriteVector(MSG_ENTITY, this.beam_wantdir);
  40         }
  41         if(sf & ARC_SF_BEAMDIR) // beam direction
  42         {
  43                 WriteAngleVector(MSG_ENTITY, this.beam_dir);
  44         }
  45         if(sf & ARC_SF_BEAMTYPE) // beam type
  46         {
  47                 WriteByte(MSG_ENTITY, this.beam_type);
  48         }
  49
  50         return true;
  51 }
  52
  53 void Reset_ArcBeam(entity player, vector forward)
  54 {
  55         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  56         {
  57                 .entity weaponentity = weaponentities[slot];
  58                 if(!player.(weaponentity).arc_beam)
  59                         continue;
  60                 player.(weaponentity).arc_beam.beam_dir = forward;
  61                 player.(weaponentity).arc_beam.beam_teleporttime = time;
  62         }
  63 }
  64
  65 float Arc_GetHeat_Percent(entity player, .entity weaponentity)
  66 {
  67         if ( WEP_CVAR(arc, overheat_max) <= 0 ||  WEP_CVAR(arc, overheat_max) <= 0 )
  68         {
  69                 player.arc_overheat = 0;
  70                 return 0;
  71         }
  72
  73         if ( player.(weaponentity).arc_beam )
  74                 return player.(weaponentity).arc_beam.beam_heat/WEP_CVAR(arc, overheat_max);
  75
  76         if ( player.arc_overheat > time )
  77         {
  78                 return (player.arc_overheat-time) / WEP_CVAR(arc, overheat_max)
  79                         * player.arc_cooldown;
  80         }
  81
  82         return 0;
  83 }
  84 void Arc_Player_SetHeat(entity player, .entity weaponentity)
  85 {
  86         player.(weaponentity).arc_heat_percent = Arc_GetHeat_Percent(player, weaponentity);
  87         //dprint("Heat: ",ftos(player.arc_heat_percent*100),"%\n");
  88 }
  89
  90 void W_Arc_Bolt_Explode(entity this, entity directhitentity)
  91 {
  92         this.event_damage = func_null;
  93         RadiusDamage(this, this.realowner, WEP_CVAR(arc, bolt_damage), WEP_CVAR(arc, bolt_edgedamage), WEP_CVAR(arc, bolt_radius), NULL, NULL, WEP_CVAR(arc, bolt_force), this.projectiledeathtype, this.weaponentity_fld, directhitentity);
  94
  95         delete(this);
  96 }
  97
  98 void W_Arc_Bolt_Explode_use(entity this, entity actor, entity trigger)
  99 {
 100         W_Arc_Bolt_Explode(this, trigger);
 101 }
 102
 103 void W_Arc_Bolt_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 104 {
 105         if(GetResource(this, RES_HEALTH) <= 0)
 106                 return;
 107
 108         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1))
 109                 return; // g_projectiles_damage says to halt
 110
 111         TakeResource(this, RES_HEALTH, damage);
 112         this.angles = vectoangles(this.velocity);
 113
 114         if(GetResource(this, RES_HEALTH) <= 0)
 115                 W_PrepareExplosionByDamage(this, attacker, getthink(this));
 116 }
 117
 118 void W_Arc_Bolt_Touch(entity this, entity toucher)
 119 {
 120         PROJECTILE_TOUCH(this, toucher);
 121         if(this.cnt >= WEP_CVAR(arc, bolt_bounce_count) || !WEP_CVAR(arc, bolt_bounce_count) || toucher.takedamage == DAMAGE_AIM) {
 122                 this.use(this, NULL, toucher);
 123         } else {
 124                 this.cnt++;
 125                 Send_Effect(EFFECT_BALL_SPARKS, this.origin, this.velocity, 1);
 126                 this.angles = vectoangles(this.velocity);
 127                 this.owner = NULL;
 128                 this.projectiledeathtype |= HITTYPE_BOUNCE;
 129                 if(WEP_CVAR(arc, bolt_bounce_explode))
 130                         RadiusDamage(this, this.realowner, WEP_CVAR(arc, bolt_damage), WEP_CVAR(arc, bolt_edgedamage), WEP_CVAR(arc, bolt_radius), NULL, NULL, WEP_CVAR(arc, bolt_force), this.projectiledeathtype, this.weaponentity_fld, toucher);
 131                 if(this.cnt == 1 && WEP_CVAR(arc, bolt_bounce_lifetime))
 132                         this.nextthink = time + WEP_CVAR(arc, bolt_bounce_lifetime);
 133         }
 134 }
 135
 136 void W_Arc_Attack_Bolt(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 137 {
 138         W_SetupShot(actor, weaponentity, false, 2, SND_ELECTRO_FIRE2, CH_WEAPON_A, WEP_CVAR(arc, bolt_damage), thiswep.m_id | HITTYPE_SECONDARY);
 139
 140         W_MuzzleFlash(thiswep, actor, weaponentity, w_shotorg, w_shotdir);
 141
 142         entity missile = new(missile);
 143         missile.owner = missile.realowner = actor;
 144         missile.bot_dodge = true;
 145         IL_PUSH(g_bot_dodge, missile);
 146         missile.bot_dodgerating = WEP_CVAR(arc, bolt_damage);
 147
 148         missile.takedamage = DAMAGE_YES;
 149         SetResourceExplicit(missile, RES_HEALTH, WEP_CVAR(arc, bolt_health));
 150         missile.damageforcescale = WEP_CVAR(arc, bolt_damageforcescale);
 151         missile.event_damage = W_Arc_Bolt_Damage;
 152         missile.damagedbycontents = true;
 153         IL_PUSH(g_damagedbycontents, missile);
 154
 155         settouch(missile, W_Arc_Bolt_Touch);
 156         missile.cnt = 0;
 157         missile.use = W_Arc_Bolt_Explode_use;
 158         setthink(missile, adaptor_think2use_hittype_splash);
 159         missile.nextthink = time + WEP_CVAR(arc, bolt_lifetime);
 160         PROJECTILE_MAKETRIGGER(missile);
 161         missile.projectiledeathtype = thiswep.m_id | HITTYPE_SECONDARY;
 162         missile.weaponentity_fld = weaponentity;
 163         setorigin(missile, w_shotorg);
 164         setsize(missile, '0 0 0', '0 0 0');
 165
 166         set_movetype(missile, MOVETYPE_BOUNCEMISSILE);
 167         W_SetupProjVelocity_PRE(missile, arc, bolt_);
 168
 169         missile.angles = vectoangles(missile.velocity);
 170         missile.flags = FL_PROJECTILE;
 171         IL_PUSH(g_projectiles, missile);
 172         missile.missile_flags = MIF_SPLASH;
 173
 174         CSQCProjectile(missile, true, PROJECTILE_ARC_BOLT, true);
 175
 176         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 177
 178         actor.(weaponentity).misc_bulletcounter = actor.(weaponentity).misc_bulletcounter + 1;
 179         if(actor.(weaponentity).misc_bulletcounter == 0)
 180         {
 181                 ATTACK_FINISHED(actor, weaponentity) = time + WEP_CVAR(arc, bolt_refire2) * W_WeaponRateFactor(actor);
 182                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, bolt_refire), w_ready);
 183         }
 184         else
 185         {
 186                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, bolt_refire), W_Arc_Attack_Bolt);
 187         }
 188 }
 189
 190 void W_Arc_Beam_Think(entity this)
 191 {
 192         .entity weaponentity = this.weaponentity_fld;
 193         entity own = this.owner;
 194         if(this != own.(weaponentity).arc_beam)
 195         {
 196                 delete(this);
 197                 return;
 198         }
 199
 200         float burst = 0;
 201         if( (PHYS_INPUT_BUTTON_ATCK2(own) && !WEP_CVAR(arc, bolt)) || this.beam_bursting)
 202         {
 203                 if(!this.beam_bursting)
 204                         this.beam_bursting = true;
 205                 burst = ARC_BT_BURSTMASK;
 206         }
 207
 208         Weapon thiswep = WEP_ARC;
 209
 210         if(
 211                 !IS_PLAYER(own)
 212                 ||
 213                 IS_DEAD(own)
 214                 ||
 215                 !weapon_prepareattack_check(thiswep, own, weaponentity, this.beam_bursting, -1)
 216                 ||
 217                 own.(weaponentity).m_switchweapon != WEP_ARC
 218                 ||
 219                 (!PHYS_INPUT_BUTTON_ATCK(own) && !burst )
 220                 ||
 221                 own.vehicle
 222                 ||
 223                 (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max))
 224         )
 225         {
 226                 if ( WEP_CVAR(arc, cooldown) > 0 )
 227                 {
 228                         float cooldown_speed = 0;
 229                         if ( this.beam_heat > WEP_CVAR(arc, overheat_min) && WEP_CVAR(arc, cooldown) > 0 )
 230                         {
 231                                 cooldown_speed = WEP_CVAR(arc, cooldown);
 232                         }
 233                         else if ( !burst )
 234                         {
 235                                 cooldown_speed = this.beam_heat / WEP_CVAR(arc, beam_refire);
 236                         }
 237
 238                         if ( cooldown_speed )
 239                         {
 240                                 if ( WEP_CVAR(arc, cooldown_release) || (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max)) )
 241                                         own.arc_overheat = time + this.beam_heat / cooldown_speed;
 242                                 own.arc_cooldown = cooldown_speed;
 243                         }
 244
 245                         if ( WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max) )
 246                         {
 247                                 Send_Effect(EFFECT_ARC_OVERHEAT,
 248                                         this.beam_start, this.beam_wantdir, 1 );
 249                                 sound(this, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 250                         }
 251                 }
 252
 253                 if(this == own.(weaponentity).arc_beam) { own.(weaponentity).arc_beam = NULL; }
 254                 if(!thiswep.wr_checkammo1(thiswep, own, weaponentity) && !(own.items & IT_UNLIMITED_AMMO))
 255                 {
 256                         // note: this doesn't force the switch
 257                         W_SwitchToOtherWeapon(own, weaponentity);
 258                 }
 259                 own.(weaponentity).arc_BUTTON_ATCK_prev = false; // allow switching weapons
 260                 delete(this);
 261                 return;
 262         }
 263
 264         // decrease ammo
 265         float coefficient = frametime;
 266         if(!(own.items & IT_UNLIMITED_AMMO))
 267         {
 268                 float rootammo;
 269                 if(burst)
 270                         { rootammo = WEP_CVAR(arc, burst_ammo); }
 271                 else
 272                         { rootammo = WEP_CVAR(arc, beam_ammo); }
 273
 274                 if(rootammo)
 275                 {
 276                         coefficient = min(coefficient, GetResource(own, thiswep.ammo_type) / rootammo);
 277                         SetResource(own, thiswep.ammo_type, max(0, GetResource(own, thiswep.ammo_type) - (rootammo * frametime)));
 278                 }
 279         }
 280         float heat_speed = burst ? WEP_CVAR(arc, burst_heat) : WEP_CVAR(arc, beam_heat);
 281         this.beam_heat = min( WEP_CVAR(arc, overheat_max), this.beam_heat + heat_speed*frametime );
 282
 283         makevectors(own.v_angle);
 284
 285         W_SetupShot_Range(
 286                 own,
 287                 weaponentity,
 288                 true,
 289                 0,
 290                 SND_Null,
 291                 0,
 292                 WEP_CVAR(arc, beam_damage) * coefficient,
 293                 WEP_CVAR(arc, beam_range),
 294                 thiswep.m_id
 295         );
 296
 297         // After teleport, "lock" the beam until the teleport is confirmed.
 298         if (time < this.beam_teleporttime + ANTILAG_LATENCY(own)) {
 299                 w_shotdir = this.beam_dir;
 300         }
 301
 302         // network information: shot origin and want/aim direction
 303         if(this.beam_start != w_shotorg)
 304         {
 305                 this.SendFlags |= ARC_SF_START;
 306                 this.beam_start = w_shotorg;
 307         }
 308         if(this.beam_wantdir != w_shotdir)
 309         {
 310                 this.SendFlags |= ARC_SF_WANTDIR;
 311                 this.beam_wantdir = w_shotdir;
 312         }
 313
 314         if(!this.beam_initialized)
 315         {
 316                 this.beam_dir = w_shotdir;
 317                 this.beam_initialized = true;
 318         }
 319
 320         // WEAPONTODO: Detect player velocity so that the beam curves when moving too
 321         // idea: blend together this.beam_dir with the inverted direction the player is moving in
 322         // might have to make some special accomodation so that it only uses view_right and view_up
 323
 324         // note that if we do this, it'll always be corrected to a maximum angle by beam_maxangle handling
 325
 326         float segments;
 327         if(this.beam_dir != w_shotdir)
 328         {
 329                 // calculate how much we're going to move the end of the beam to the want position
 330                 // WEAPONTODO (server and client):
 331                 // blendfactor never actually becomes 0 in this situation, which is a problem
 332                 // regarding precision... this means that this.beam_dir and w_shotdir approach
 333                 // eachother, however they never actually become the same value with this method.
 334                 // Perhaps we should do some form of rounding/snapping?
 335                 float angle = vlen(w_shotdir - this.beam_dir) * RAD2DEG;
 336                 if(angle && (angle > WEP_CVAR(arc, beam_maxangle)))
 337                 {
 338                         // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 339                         float blendfactor = bound(
 340                                 0,
 341                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 342                                 min(WEP_CVAR(arc, beam_maxangle) / angle, 1)
 343                         );
 344                         if(vdist(this.beam_dir - w_shotdir, <, 0.01))
 345                                 this.beam_dir = w_shotdir;
 346                         else
 347                                 this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 348                 }
 349                 else
 350                 {
 351                         // the radius is not too far yet, no worries :D
 352                         float blendfactor = bound(
 353                                 0,
 354                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 355                                 1
 356                         );
 357                         if(vdist(this.beam_dir - w_shotdir, <, 0.01))
 358                                 this.beam_dir = w_shotdir;
 359                         else
 360                                 this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 361                 }
 362
 363                 // network information: beam direction
 364                 this.SendFlags |= ARC_SF_BEAMDIR;
 365
 366                 // calculate how many segments are needed
 367                 float max_allowed_segments;
 368
 369                 if(WEP_CVAR(arc, beam_distancepersegment))
 370                 {
 371                         max_allowed_segments = min(
 372                                 ARC_MAX_SEGMENTS,
 373                                 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment)))
 374                         );
 375                 }
 376                 else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 377
 378                 if(WEP_CVAR(arc, beam_degreespersegment))
 379                 {
 380                         segments = bound(
 381                                 1,
 382                                 (
 383                                         min(
 384                                                 angle,
 385                                                 WEP_CVAR(arc, beam_maxangle)
 386                                         )
 387                                         /
 388                                         WEP_CVAR(arc, beam_degreespersegment)
 389                                 ),
 390                                 max_allowed_segments
 391                         );
 392                 }
 393                 else { segments = 1; }
 394         }
 395         else { segments = 1; }
 396
 397         vector beam_endpos = (w_shotorg + (this.beam_dir * WEP_CVAR(arc, beam_range)));
 398         vector beam_controlpoint = w_shotorg + w_shotdir * (WEP_CVAR(arc, beam_range) * (1 - WEP_CVAR(arc, beam_tightness)));
 399
 400         float i;
 401         float new_beam_type = 0;
 402         vector last_origin = w_shotorg;
 403         for(i = 1; i <= segments; ++i)
 404         {
 405                 // WEAPONTODO (client):
 406                 // In order to do nice fading and pointing on the starting segment, we must always
 407                 // have that drawn as a separate triangle... However, that is difficult to do when
 408                 // keeping in mind the above problems and also optimizing the amount of segments
 409                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
 410
 411                 vector new_origin = bezier_quadratic_getpoint(
 412                         w_shotorg,
 413                         beam_controlpoint,
 414                         beam_endpos,
 415                         i / segments);
 416                 vector new_dir = normalize(new_origin - last_origin);
 417
 418                 WarpZone_traceline_antilag(
 419                         own,
 420                         last_origin,
 421                         new_origin,
 422                         MOVE_NORMAL,
 423                         own,
 424                         ANTILAG_LATENCY(own)
 425                 );
 426
 427                 // Do all the transforms for warpzones right now, as we already
 428                 // "are" in the post-trace system (if we hit a player, that's
 429                 // always BEHIND the last passed wz).
 430                 last_origin = trace_endpos;
 431                 w_shotorg = WarpZone_TransformOrigin(WarpZone_trace_transform, w_shotorg);
 432                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
 433                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
 434                 new_dir = WarpZone_TransformVelocity(WarpZone_trace_transform, new_dir);
 435
 436                 bool is_player = (
 437                         IS_PLAYER(trace_ent)
 438                         ||
 439                         trace_ent.classname == "body"
 440                         ||
 441                         IS_MONSTER(trace_ent)
 442                 );
 443
 444                 if(trace_ent)
 445                 {
 446                         if(SAME_TEAM(own, trace_ent))
 447                         {
 448                                 float roothealth = ((burst) ? WEP_CVAR(arc, burst_healing_hps) : WEP_CVAR(arc, beam_healing_hps));
 449                                 float rootarmor = ((burst) ? WEP_CVAR(arc, burst_healing_aps) : WEP_CVAR(arc, beam_healing_aps));
 450                                 float hplimit = ((IS_PLAYER(trace_ent)) ? WEP_CVAR(arc, beam_healing_hmax) : RES_LIMIT_NONE);
 451                                 Heal(trace_ent, own, (roothealth * coefficient), hplimit);
 452                                 if(IS_PLAYER(trace_ent) && rootarmor)
 453                                 {
 454                                         if(GetResource(trace_ent, RES_ARMOR) <= WEP_CVAR(arc, beam_healing_amax))
 455                                         {
 456                                                 GiveResourceWithLimit(trace_ent, RES_ARMOR, (rootarmor * coefficient), WEP_CVAR(arc, beam_healing_amax));
 457                                                 trace_ent.pauserotarmor_finished = max(
 458                                                         trace_ent.pauserotarmor_finished,
 459                                                         time + autocvar_g_balance_pause_armor_rot
 460                                                 );
 461                                         }
 462                                 }
 463                                 if(roothealth || rootarmor)
 464                                         new_beam_type = ARC_BT_HEAL;
 465                         }
 466                         else if(trace_ent.takedamage && (is_player || WEP_CVAR(arc, beam_nonplayerdamage)))
 467                         {
 468                                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 469                                 // NO. trace_endpos should be just fine. If not,
 470                                 // that's an engine bug that needs proper debugging.
 471                                 vector hitorigin = trace_endpos;
 472
 473                                 float falloff = ExponentialFalloff(
 474                                         WEP_CVAR(arc, beam_falloff_mindist),
 475                                         WEP_CVAR(arc, beam_falloff_maxdist),
 476                                         WEP_CVAR(arc, beam_falloff_halflifedist),
 477                                         vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, hitorigin) - w_shotorg)
 478                                 );
 479
 480                                 float rootdamage;
 481                                 if(is_player)
 482                                 {
 483                                         if(burst)
 484                                                 { rootdamage = WEP_CVAR(arc, burst_damage); }
 485                                         else
 486                                                 { rootdamage = WEP_CVAR(arc, beam_damage); }
 487                                 }
 488                                 else
 489                                         { rootdamage = WEP_CVAR(arc, beam_nonplayerdamage); }
 490
 491                                 if(accuracy_isgooddamage(own, trace_ent))
 492                                 {
 493                                         accuracy_add(
 494                                                 own,
 495                                                 WEP_ARC,
 496                                                 0,
 497                                                 rootdamage * coefficient * falloff
 498                                         );
 499                                 }
 500
 501                                 Damage(
 502                                         trace_ent,
 503                                         own,
 504                                         own,
 505                                         rootdamage * coefficient * falloff,
 506                                         WEP_ARC.m_id,
 507                                         weaponentity,
 508                                         hitorigin,
 509                                         WEP_CVAR(arc, beam_force) * new_dir * coefficient * falloff
 510                                 );
 511
 512                                 new_beam_type = ARC_BT_HIT;
 513                         }
 514                         break;
 515                 }
 516                 else if(trace_fraction != 1)
 517                 {
 518                         // we collided with geometry
 519                         new_beam_type = ARC_BT_WALL;
 520                         break;
 521                 }
 522         }
 523
 524         // te_explosion(trace_endpos);
 525
 526         // if we're bursting, use burst visual effects
 527         new_beam_type |= burst;
 528
 529         // network information: beam type
 530         if(new_beam_type != this.beam_type)
 531         {
 532                 this.SendFlags |= ARC_SF_BEAMTYPE;
 533                 this.beam_type = new_beam_type;
 534         }
 535
 536         own.(weaponentity).beam_prev = time;
 537         this.nextthink = time;
 538 }
 539
 540 void W_Arc_Beam(float burst, entity actor, .entity weaponentity)
 541 {
 542
 543         // only play fire sound if 1 sec has passed since player let go the fire button
 544         if(time - actor.(weaponentity).beam_prev > 1)
 545                 sound(actor, CH_WEAPON_A, SND_ARC_FIRE, VOL_BASE, ATTN_NORM);
 546
 547         entity beam = actor.(weaponentity).arc_beam = new(W_Arc_Beam);
 548         beam.weaponentity_fld = weaponentity;
 549         beam.solid = SOLID_NOT;
 550         setthink(beam, W_Arc_Beam_Think);
 551         beam.owner = actor;
 552         set_movetype(beam, MOVETYPE_NONE);
 553         beam.bot_dodge = true;
 554         IL_PUSH(g_bot_dodge, beam);
 555         beam.bot_dodgerating = WEP_CVAR(arc, beam_damage);
 556         beam.beam_bursting = burst;
 557         Net_LinkEntity(beam, false, 0, W_Arc_Beam_Send);
 558
 559         getthink(beam)(beam);
 560 }
 561 void W_Arc_Attack(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 562 {
 563         if(!actor.(weaponentity).arc_beam || wasfreed(actor.(weaponentity).arc_beam))
 564         {
 565                 w_ready(thiswep, actor, weaponentity, fire);
 566                 return;
 567         }
 568
 569         // attack handled by the beam itself, this is just a loop to keep the attack happening!
 570
 571         // NOTE: arc doesn't use a refire
 572         //ATTACK_FINISHED(actor, weaponentity) = time + WEP_CVAR_PRI(arc, refire) * W_WeaponRateFactor(actor);
 573         actor.(weaponentity).wframe = WFRAME_FIRE1;
 574         weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), W_Arc_Attack);
 575 }
 576 void Arc_Smoke(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 577 {
 578         // TODO: spamming this without checking any refires is asking for trouble!
 579         makevectors(actor.v_angle);
 580         W_SetupShot_Range(actor,weaponentity,false,0,SND_Null,0,0,0,thiswep.m_id); // TODO: probably doesn't need deathtype, since this is just a prefire effect
 581
 582         vector smoke_origin = w_shotorg + actor.velocity*frametime;
 583         if ( actor.arc_overheat > time )
 584         {
 585                 if ( random() < actor.(weaponentity).arc_heat_percent )
 586                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 587                 if ( (fire & 1) || (fire & 2) )
 588                 {
 589                         Send_Effect(EFFECT_ARC_OVERHEAT_FIRE, smoke_origin, w_shotdir, 1 );
 590                         if ( !actor.arc_smoke_sound )
 591                         {
 592                                 actor.arc_smoke_sound = 1;
 593                                 sound(actor, CH_SHOTS_SINGLE, SND_ARC_LOOP_OVERHEAT, VOL_BASE, ATTN_NORM);
 594                         }
 595                 }
 596         }
 597         else if ( actor.(weaponentity).arc_beam && WEP_CVAR(arc, overheat_max) > 0 &&
 598                         actor.(weaponentity).arc_beam.beam_heat > WEP_CVAR(arc, overheat_min) )
 599         {
 600                 if ( random() < (actor.(weaponentity).arc_beam.beam_heat-WEP_CVAR(arc, overheat_min)) /
 601                                 ( WEP_CVAR(arc, overheat_max)-WEP_CVAR(arc, overheat_min) ) )
 602                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 603         }
 604
 605         bool attacking = PHYS_INPUT_BUTTON_ATCK(actor) || PHYS_INPUT_BUTTON_ATCK2(actor);
 606         bool stop_smoke_sound = actor.arc_overheat <= time || !attacking;
 607         if ((actor.arc_smoke_sound && stop_smoke_sound) || actor.(weaponentity).m_switchweapon != thiswep)
 608         {
 609                 actor.arc_smoke_sound = 0;
 610                 sound(actor, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 611         }
 612 }
 613
 614 METHOD(Arc, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 615 {
 616     if(WEP_CVAR(arc, beam_botaimspeed))
 617     {
 618         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 619                 actor,
 620                 weaponentity,
 621             WEP_CVAR(arc, beam_botaimspeed),
 622             0,
 623             WEP_CVAR(arc, beam_botaimlifetime),
 624             false
 625         );
 626     }
 627     else
 628     {
 629         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 630                 actor,
 631                 weaponentity,
 632             1000000,
 633             0,
 634             0.001,
 635             false
 636         );
 637     }
 638 }
 639 METHOD(Arc, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 640 {
 641     Arc_Player_SetHeat(actor, weaponentity);
 642     Arc_Smoke(thiswep, actor, weaponentity, fire);
 643
 644     bool beam_fire2 = ((fire & 2) && !WEP_CVAR(arc, bolt));
 645
 646     if (time >= actor.arc_overheat)
 647     if ((fire & 1) || beam_fire2 || actor.(weaponentity).arc_beam.beam_bursting)
 648     {
 649         #if 0
 650         if(actor.(weaponentity).arc_BUTTON_ATCK_prev)
 651         {
 652             #if 0
 653             if(actor.animstate_startframe == actor.anim_shoot.x && actor.animstate_numframes == actor.anim_shoot.y)
 654                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, autocvar_g_balance_arc_primary_animtime, w_ready);
 655             else
 656             #endif
 657                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), w_ready);
 658         }
 659         #endif
 660
 661         if((!actor.(weaponentity).arc_beam) || wasfreed(actor.(weaponentity).arc_beam))
 662         {
 663             if(weapon_prepareattack(thiswep, actor, weaponentity, boolean(beam_fire2), 0))
 664             {
 665                 W_Arc_Beam(boolean(beam_fire2), actor, weaponentity);
 666
 667                 if(!actor.(weaponentity).arc_BUTTON_ATCK_prev)
 668                 {
 669                         actor.(weaponentity).wframe = WFRAME_FIRE1;
 670                     weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), W_Arc_Attack);
 671                     actor.(weaponentity).arc_BUTTON_ATCK_prev = true;
 672                 }
 673             }
 674         }
 675
 676         return;
 677     }
 678     else if(fire & 2)
 679     {
 680         if(weapon_prepareattack(thiswep, actor, weaponentity, true, 0))
 681         {
 682                 if(!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
 683             if(!(actor.items & IT_UNLIMITED_AMMO))
 684             {
 685                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 686                 w_ready(thiswep, actor, weaponentity, fire);
 687                 return;
 688             }
 689             float ammo_available = GetResource(actor, thiswep.ammo_type);
 690             // We don't want to shoot 3 rounds if there's 2 left in the mag, so we'll use a fraction.
 691             // Also keep the fraction <= 1 otherwise we'd mag dump in one burst.
 692             float burst_fraction = min(1, ammo_available / WEP_CVAR(arc, bolt_ammo));
 693             int to_shoot = floor(WEP_CVAR(arc, bolt_count) * burst_fraction);
 694
 695             // We also don't want to use 3 rounds if there's only 2 left.
 696             int to_use = min(WEP_CVAR(arc, bolt_ammo), ammo_available);
 697             W_DecreaseAmmo(thiswep, actor, to_use, weaponentity);
 698
 699             // Bursting counts up to 0 from a negative.
 700             actor.(weaponentity).misc_bulletcounter = -to_shoot;
 701             W_Arc_Attack_Bolt(thiswep, actor, weaponentity, fire);
 702         }
 703     }
 704
 705     if(actor.(weaponentity).arc_BUTTON_ATCK_prev)
 706     {
 707         sound(actor, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 708         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 709         ATTACK_FINISHED(actor, weaponentity) = time + WEP_CVAR(arc, beam_refire) * W_WeaponRateFactor(actor);
 710     }
 711     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 712
 713     #if 0
 714     if(fire & 2)
 715     if(weapon_prepareattack(thiswep, actor, weaponentity, true, autocvar_g_balance_arc_secondary_refire))
 716     {
 717         W_Arc_Attack2();
 718         actor.arc_count = autocvar_g_balance_arc_secondary_count;
 719         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, autocvar_g_balance_arc_secondary_animtime, w_arc_checkattack);
 720         actor.arc_secondarytime = time + autocvar_g_balance_arc_secondary_refire2 * W_WeaponRateFactor(actor);
 721     }
 722     #endif
 723 }
 724 METHOD(Arc, wr_init, void(entity thiswep))
 725 {
 726     if(!arc_shotorigin[0])
 727     {
 728         arc_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 1);
 729         arc_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 2);
 730         arc_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 3);
 731         arc_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 4);
 732     }
 733 }
 734 METHOD(Arc, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 735 {
 736     return ((!WEP_CVAR(arc, beam_ammo)) || (GetResource(actor, thiswep.ammo_type) > 0));
 737 }
 738 METHOD(Arc, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 739 {
 740     if(WEP_CVAR(arc, bolt))
 741     {
 742         float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR(arc, bolt_ammo);
 743         ammo_amount += actor.(weaponentity).(weapon_load[WEP_ARC.m_id]) >= WEP_CVAR(arc, bolt_ammo);
 744         return ammo_amount;
 745     }
 746     else
 747         return WEP_CVAR(arc, overheat_max) > 0 &&
 748             ((!WEP_CVAR(arc, burst_ammo)) || (GetResource(actor, thiswep.ammo_type) > 0));
 749 }
 750 METHOD(Arc, wr_killmessage, Notification(entity thiswep))
 751 {
 752     if(w_deathtype & HITTYPE_SECONDARY)
 753         return WEAPON_ARC_MURDER_SPRAY;
 754     else
 755         return WEAPON_ARC_MURDER;
 756 }
 757 METHOD(Arc, wr_drop, void(entity thiswep, entity actor, .entity weaponentity))
 758 {
 759     weapon_dropevent_item.arc_overheat = actor.arc_overheat;
 760     weapon_dropevent_item.arc_cooldown = actor.arc_cooldown;
 761     actor.arc_overheat = 0;
 762     actor.arc_cooldown = 0;
 763     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 764 }
 765 METHOD(Arc, wr_pickup, void(entity thiswep, entity actor, .entity weaponentity))
 766 {
 767     if ( !client_hasweapon(actor, thiswep, weaponentity, false, false) &&
 768         weapon_dropevent_item.arc_overheat > time )
 769     {
 770         actor.arc_overheat = weapon_dropevent_item.arc_overheat;
 771         actor.arc_cooldown = weapon_dropevent_item.arc_cooldown;
 772     }
 773 }
 774 METHOD(Arc, wr_resetplayer, void(entity thiswep, entity actor))
 775 {
 776     actor.arc_overheat = 0;
 777     actor.arc_cooldown = 0;
 778     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 779     {
 780         .entity weaponentity = weaponentities[slot];
 781         actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 782     }
 783 }
 784 METHOD(Arc, wr_playerdeath, void(entity thiswep, entity actor, .entity weaponentity))
 785 {
 786     actor.arc_overheat = 0;
 787     actor.arc_cooldown = 0;
 788     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 789 }
 790 #endif
 791 #ifdef CSQC
 792 bool autocvar_cl_arcbeam_teamcolor = true;
 793 bool autocvar_cl_arcbeam_simple = true;
 794
 795 .int beam_slot;
 796
 797 METHOD(Arc, wr_impacteffect, void(entity thiswep, entity actor))
 798 {
 799     if(w_deathtype & HITTYPE_SECONDARY)
 800     {
 801         vector org2;
 802         org2 = w_org + w_backoff * 6;
 803         pointparticles(EFFECT_ELECTRO_IMPACT, org2, w_backoff * 1000, 1);
 804         if(!w_issilent) { sound(actor, CH_SHOTS, SND_ELECTRO_IMPACT, VOL_BASE, ATTN_NORM); }
 805     }
 806 }
 807
 808 void Draw_ArcBeam_callback(vector start, vector hit, vector end)
 809 {
 810         entity beam = Draw_ArcBeam_callback_entity;
 811         vector transformed_view_org;
 812         transformed_view_org = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 813
 814         // Thickdir shall be perpendicular to the beam and to the view-to-beam direction (WEAPONTODO: WHY)
 815         // WEAPONTODO: Wouldn't it be better to be perpendicular to the beam and to the view FORWARD direction?
 816         vector thickdir = normalize(cross(normalize(start - hit), transformed_view_org - start));
 817
 818         vector hitorigin;
 819
 820         // draw segment
 821         #if 0
 822         if(trace_fraction != 1)
 823         {
 824                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 825                 hitorigin = start + (Draw_ArcBeam_callback_new_dir * Draw_ArcBeam_callback_segmentdist * trace_fraction);
 826                 hitorigin = WarpZone_TransformOrigin(WarpZone_trace_transform, hitorigin);
 827         }
 828         else
 829         {
 830                 hitorigin = hit;
 831         }
 832         #else
 833         hitorigin = hit;
 834         #endif
 835
 836         // decide upon thickness
 837         float thickness = beam.beam_thickness;
 838
 839         // draw primary beam render
 840         vector top    = hitorigin + (thickdir * thickness);
 841         vector bottom = hitorigin - (thickdir * thickness);
 842
 843         vector last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
 844         vector last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
 845
 846         if(autocvar_cl_arcbeam_simple)
 847                 Draw_CylindricLine(start, end, thickness, beam.beam_image, 0.25, -time * 3, beam.beam_color, beam.beam_alpha, DRAWFLAG_NORMAL, transformed_view_org);
 848         else
 849         {
 850                 R_BeginPolygon(beam.beam_image, DRAWFLAG_NORMAL, false); // DRAWFLAG_ADDITIVE
 851                 R_PolygonVertex(
 852                         top,
 853                         '0 0.5 0' + ('0 0.5 0' * (thickness / beam.beam_thickness)),
 854                         beam.beam_color,
 855                         beam.beam_alpha
 856                 );
 857                 R_PolygonVertex(
 858                         last_top,
 859                         '0 0.5 0' + ('0 0.5 0' * (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 860                         beam.beam_color,
 861                         beam.beam_alpha
 862                 );
 863                 R_PolygonVertex(
 864                         last_bottom,
 865                         '0 0.5 0' * (1 - (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 866                         beam.beam_color,
 867                         beam.beam_alpha
 868                 );
 869                 R_PolygonVertex(
 870                         bottom,
 871                         '0 0.5 0' * (1 - (thickness / beam.beam_thickness)),
 872                         beam.beam_color,
 873                         beam.beam_alpha
 874                 );
 875                 R_EndPolygon();
 876         }
 877
 878         // draw trailing particles
 879         // NOTES:
 880         //  - Don't use spammy particle counts here, use a FEW small particles around the beam
 881         //  - We're not using WarpZone_TrailParticles here because we will handle warpzones ourselves.
 882         if(beam.beam_traileffect)
 883         {
 884                 trailparticles(beam, beam.beam_traileffect, start, hitorigin);
 885         }
 886
 887         // set up for the next
 888         Draw_ArcBeam_callback_last_thickness = thickness;
 889         Draw_ArcBeam_callback_last_top = WarpZone_UnTransformOrigin(WarpZone_trace_transform, top);
 890         Draw_ArcBeam_callback_last_bottom = WarpZone_UnTransformOrigin(WarpZone_trace_transform, bottom);
 891 }
 892
 893 void Reset_ArcBeam()
 894 {
 895         entity e;
 896         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 1)); ) {
 897                 e.beam_initialized = false;
 898         }
 899         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 2)); ) {
 900                 e.beam_initialized = false;
 901         }
 902 }
 903
 904 void Draw_ArcBeam(entity this)
 905 {
 906         float dt = time - this.move_time;
 907         this.move_time = time;
 908         if(dt <= 0) { return; }
 909
 910         if(!this.beam_usevieworigin)
 911         {
 912                 InterpolateOrigin_Do(this);
 913         }
 914
 915         // origin = beam starting origin
 916         // v_angle = wanted/aim direction
 917         // angles = current direction of beam
 918
 919         vector start_pos;
 920         vector wantdir; //= view_forward;
 921         vector beamdir; //= this.beam_dir;
 922
 923         float segments;
 924         if(this.beam_usevieworigin)
 925         {
 926                 // WEAPONTODO:
 927                 // Currently we have to replicate nearly the same method of figuring
 928                 // out the shotdir that the server does... Ideally in the future we
 929                 // should be able to acquire this from a generalized function built
 930                 // into a weapon system for client code.
 931
 932                 // find where we are aiming
 933                 vector myviewangle = ((autocvar_chase_active) ? warpzone_save_view_angles : view_angles);
 934                 vector forward, right, up;
 935                 MAKE_VECTORS(myviewangle, forward, right, up);
 936                 entity wepent = viewmodels[this.beam_slot];
 937
 938                 this.beam_usevieworigin = (autocvar_chase_active) ? 1 : 2;
 939
 940                 // decide upon start position
 941                 if(this.beam_usevieworigin == 2)
 942                         { start_pos = warpzone_save_view_origin; }
 943                 else if(csqcplayer)
 944                         { start_pos = csqcplayer.origin + csqcplayer.view_ofs; }
 945                 else
 946                         { start_pos = this.origin; }
 947
 948                 // trace forward with an estimation
 949                 WarpZone_TraceLine(
 950                         start_pos,
 951                         start_pos + forward * this.beam_range,
 952                         MOVE_NOMONSTERS,
 953                         this
 954                 );
 955
 956                 int v_shot_idx;  // used later
 957                 (v_shot_idx = gettagindex(wepent, "shot")) || (v_shot_idx = gettagindex(wepent, "tag_shot"));
 958                 if(v_shot_idx && this.beam_usevieworigin == 2)
 959                         start_pos = gettaginfo(wepent, v_shot_idx) - '0 0 2';
 960
 961                 // untransform in case our trace went through a warpzone
 962                 vector end_pos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 963
 964                 // un-adjust trueaim if shotend is too close
 965                 if(vdist(end_pos - start_pos, <, g_trueaim_minrange))
 966                         end_pos = start_pos + (forward * g_trueaim_minrange);
 967
 968                 // move shot origin to the actual gun muzzle origin
 969                 vector origin_offset = '0 0 0';
 970                 if(!v_shot_idx || this.beam_usevieworigin != 2)
 971                 {
 972                         this.beam_shotorigin = wepent.movedir;
 973                         origin_offset = right * -this.beam_shotorigin.y + up * this.beam_shotorigin.z;
 974                 }
 975                 else
 976                         this.beam_shotorigin = '0 0 0';
 977
 978                 start_pos = start_pos + origin_offset;
 979
 980                 // Move it also forward, but only as far as possible without hitting anything. Don't poke into walls!
 981                 traceline(start_pos, start_pos + forward * this.beam_shotorigin.x, MOVE_NORMAL, this);
 982                 start_pos = trace_endpos;
 983
 984                 // calculate the aim direction now
 985                 wantdir = normalize(end_pos - start_pos);
 986
 987                 if(!this.beam_initialized)
 988                 {
 989                         this.beam_dir = wantdir;
 990                         this.beam_initialized = true;
 991
 992                         this.beam_muzzleentity.drawmask = MASK_NORMAL; // NOTE: this works around the muzzle entity flashing on the middle of the screen for a frame
 993                 }
 994
 995                 if(this.beam_dir != wantdir)
 996                 {
 997                         // calculate how much we're going to move the end of the beam to the want position
 998                         // WEAPONTODO (server and client):
 999                         // blendfactor never actually becomes 0 in this situation, which is a problem
1000                         // regarding precision... this means that this.beam_dir and w_shotdir approach
1001                         // eachother, however they never actually become the same value with this method.
1002                         // Perhaps we should do some form of rounding/snapping?
1003                         float angle = vlen(wantdir - this.beam_dir) * RAD2DEG;
1004                         if(angle && (angle > this.beam_maxangle))
1005                         {
1006                                 // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
1007                                 float blendfactor = bound(
1008                                         0,
1009                                         (1 - (this.beam_returnspeed * dt)),
1010                                         min(this.beam_maxangle / angle, 1)
1011                                 );
1012                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
1013                         }
1014                         else
1015                         {
1016                                 // the radius is not too far yet, no worries :D
1017                                 float blendfactor = bound(
1018                                         0,
1019                                         (1 - (this.beam_returnspeed * dt)),
1020                                         1
1021                                 );
1022                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
1023                         }
1024
1025                         // calculate how many segments are needed
1026                         float max_allowed_segments;
1027
1028                         if(this.beam_distancepersegment)
1029                         {
1030                                 max_allowed_segments = min(
1031                                         ARC_MAX_SEGMENTS,
1032                                         1 + (vlen(wantdir / this.beam_distancepersegment))
1033                                 );
1034                         }
1035                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1036
1037                         if(this.beam_degreespersegment)
1038                         {
1039                                 segments = bound(
1040                                         1,
1041                                         (
1042                                                 min(
1043                                                         angle,
1044                                                         this.beam_maxangle
1045                                                 )
1046                                                 /
1047                                                 this.beam_degreespersegment
1048                                         ),
1049                                         max_allowed_segments
1050                                 );
1051                         }
1052                         else { segments = 1; }
1053                 }
1054                 else { segments = 1; }
1055
1056                 // set the beam direction which the rest of the code will refer to
1057                 beamdir = this.beam_dir;
1058
1059                 // finally, set this.angles to the proper direction so that muzzle attachment points in proper direction
1060                 this.angles = fixedvectoangles2(forward, up); // TODO(Samual): is this == warpzone_save_view_angles?
1061         }
1062         else
1063         {
1064                 // set the values from the provided info from the networked entity
1065                 start_pos = this.origin;
1066                 wantdir = this.v_angle;
1067                 beamdir = this.angles;
1068
1069                 if(beamdir != wantdir)
1070                 {
1071                         float angle = vlen(wantdir - beamdir) * RAD2DEG;
1072
1073                         // calculate how many segments are needed
1074                         float max_allowed_segments;
1075
1076                         if(this.beam_distancepersegment)
1077                         {
1078                                 max_allowed_segments = min(
1079                                         ARC_MAX_SEGMENTS,
1080                                         1 + (vlen(wantdir / this.beam_distancepersegment))
1081                                 );
1082                         }
1083                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1084
1085                         if(this.beam_degreespersegment)
1086                         {
1087                                 segments = bound(
1088                                         1,
1089                                         (
1090                                                 min(
1091                                                         angle,
1092                                                         this.beam_maxangle
1093                                                 )
1094                                                 /
1095                                                 this.beam_degreespersegment
1096                                         ),
1097                                         max_allowed_segments
1098                                 );
1099                         }
1100                         else { segments = 1; }
1101                 }
1102                 else { segments = 1; }
1103         }
1104
1105         setorigin(this, start_pos);
1106         this.beam_muzzleentity.angles_z = random() * 360; // WEAPONTODO: use avelocity instead?
1107
1108         vector beam_endpos = (start_pos + (beamdir * this.beam_range));
1109         vector beam_controlpoint = start_pos + wantdir * (this.beam_range * (1 - this.beam_tightness));
1110
1111         Draw_ArcBeam_callback_entity = this;
1112         Draw_ArcBeam_callback_last_thickness = 0;
1113         Draw_ArcBeam_callback_last_top = start_pos;
1114         Draw_ArcBeam_callback_last_bottom = start_pos;
1115
1116         vector last_origin = start_pos;
1117         vector original_start_pos = start_pos;
1118
1119         float i;
1120         for(i = 1; i <= segments; ++i)
1121         {
1122                 // WEAPONTODO (client):
1123                 // In order to do nice fading and pointing on the starting segment, we must always
1124                 // have that drawn as a separate triangle... However, that is difficult to do when
1125                 // keeping in mind the above problems and also optimizing the amount of segments
1126                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
1127
1128                 vector new_origin = bezier_quadratic_getpoint(
1129                         start_pos,
1130                         beam_controlpoint,
1131                         beam_endpos,
1132                         i / segments);
1133
1134                 WarpZone_TraceBox_ThroughZone(
1135                         last_origin,
1136                         '0 0 0',
1137                         '0 0 0',
1138                         new_origin,
1139                         MOVE_NORMAL,
1140                         NULL,
1141                         NULL,
1142                         Draw_ArcBeam_callback
1143                 );
1144
1145                 // Do all the transforms for warpzones right now, as we already "are" in the post-trace
1146                 // system (if we hit a player, that's always BEHIND the last passed wz).
1147                 last_origin = trace_endpos;
1148                 start_pos = WarpZone_TransformOrigin(WarpZone_trace_transform, start_pos);
1149                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
1150                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
1151                 beamdir = WarpZone_TransformVelocity(WarpZone_trace_transform, beamdir);
1152                 Draw_ArcBeam_callback_last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
1153                 Draw_ArcBeam_callback_last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
1154
1155                 if(trace_fraction < 1) { break; }
1156         }
1157
1158         // visual effects for startpoint and endpoint
1159         if(this.beam_hiteffect)
1160         {
1161                 // FIXME we really should do this on the server so it actually
1162                 // matches gameplay. What this client side stuff is doing is no
1163                 // more than guesswork.
1164                 if((trace_ent || trace_fraction < 1) && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
1165                 pointparticles(
1166                         this.beam_hiteffect,
1167                         last_origin,
1168                         beamdir * -1,
1169                         dt * 2
1170                 );
1171         }
1172         if(this.beam_hitlight[0])
1173         {
1174                 adddynamiclight(
1175                         last_origin,
1176                         this.beam_hitlight[0],
1177                         vec3(
1178                                 this.beam_hitlight[1],
1179                                 this.beam_hitlight[2],
1180                                 this.beam_hitlight[3]
1181                         )
1182                 );
1183         }
1184         if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1185         {
1186                 pointparticles(
1187                         this.beam_muzzleeffect,
1188                         original_start_pos + wantdir * 20,
1189                         wantdir * 1000,
1190                         dt * 0.1
1191                 );
1192         }
1193         if(this.beam_muzzlelight[0])
1194         {
1195                 adddynamiclight(
1196                         original_start_pos + wantdir * 20,
1197                         this.beam_muzzlelight[0],
1198                         vec3(
1199                                 this.beam_muzzlelight[1],
1200                                 this.beam_muzzlelight[2],
1201                                 this.beam_muzzlelight[3]
1202                         )
1203                 );
1204         }
1205
1206         // cleanup
1207         Draw_ArcBeam_callback_entity = NULL;
1208         Draw_ArcBeam_callback_last_thickness = 0;
1209         Draw_ArcBeam_callback_last_top = '0 0 0';
1210         Draw_ArcBeam_callback_last_bottom = '0 0 0';
1211 }
1212
1213 void Remove_ArcBeam(entity this)
1214 {
1215         delete(this.beam_muzzleentity);
1216         sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
1217 }
1218
1219 NET_HANDLE(ENT_CLIENT_ARC_BEAM, bool isnew)
1220 {
1221         int sf = ReadByte();
1222         int slot = ReadByte();
1223         entity flash;
1224
1225         this.beam_slot = slot;
1226
1227         if(isnew)
1228         {
1229                 int gunalign = W_GunAlign(viewmodels[slot], STAT(GUNALIGN)) - 1;
1230
1231                 this.beam_shotorigin = arc_shotorigin[gunalign]; // get a starting point
1232
1233                 // set other main attributes of the beam
1234                 this.draw = Draw_ArcBeam;
1235                 IL_PUSH(g_drawables, this);
1236                 this.entremove = Remove_ArcBeam;
1237                 this.move_time = time;
1238                 loopsound(this, CH_SHOTS_SINGLE, SND_ARC_LOOP, VOL_BASE, ATTEN_NORM);
1239
1240                 flash = spawn();
1241                 flash.owner = this;
1242                 flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
1243                 //flash.drawmask = MASK_NORMAL;
1244                 flash.solid = SOLID_NOT;
1245                 flash.avelocity_z = 5000;
1246                 setattachment(flash, this, "");
1247                 setorigin(flash, '0 0 0');
1248
1249                 this.beam_muzzleentity = flash;
1250         }
1251         else
1252         {
1253                 flash = this.beam_muzzleentity;
1254         }
1255
1256         if(sf & ARC_SF_SETTINGS) // settings information
1257         {
1258                 this.beam_degreespersegment = ReadShort();
1259                 this.beam_distancepersegment = ReadShort();
1260                 this.beam_maxangle = ReadShort();
1261                 this.beam_range = ReadCoord();
1262                 this.beam_returnspeed = ReadShort();
1263                 this.beam_tightness = (ReadByte() / 10);
1264
1265                 if(ReadByte())
1266                 {
1267                         this.beam_usevieworigin = (autocvar_chase_active) ? 1 : 2;
1268                 }
1269                 else
1270                 {
1271                         this.beam_usevieworigin = 0;
1272                 }
1273
1274                 this.sv_entnum = ReadByte();
1275         }
1276
1277         if(!this.beam_usevieworigin)
1278         {
1279                 // this.iflags = IFLAG_ORIGIN | IFLAG_ANGLES | IFLAG_V_ANGLE; // why doesn't this work?
1280                 this.iflags = IFLAG_ORIGIN;
1281
1282                 InterpolateOrigin_Undo(this);
1283         }
1284
1285         if(sf & ARC_SF_START) // starting location
1286         {
1287                 this.origin = ReadVector();
1288         }
1289         else if(this.beam_usevieworigin) // infer the location from player location
1290         {
1291                 if(this.beam_usevieworigin == 2)
1292                 {
1293                         // use view origin
1294                         this.origin = view_origin;
1295                 }
1296                 else
1297                 {
1298                         // use player origin so that third person display still works
1299                         this.origin = entcs_receiver(player_localnum).origin + ('0 0 1' * STAT(VIEWHEIGHT));
1300                 }
1301         }
1302
1303         setorigin(this, this.origin);
1304
1305         if(sf & ARC_SF_WANTDIR) // want/aim direction
1306         {
1307                 this.v_angle = ReadVector();
1308         }
1309
1310         if(sf & ARC_SF_BEAMDIR) // beam direction
1311         {
1312                 this.angles = ReadAngleVector();
1313         }
1314
1315         if(sf & ARC_SF_BEAMTYPE) // beam type
1316         {
1317                 this.beam_type = ReadByte();
1318
1319                 vector beamcolor = ((autocvar_cl_arcbeam_teamcolor) ? colormapPaletteColor(entcs_GetClientColors(this.sv_entnum - 1) & 0x0F, true) : '1 1 1');
1320                 switch(this.beam_type)
1321                 {
1322                         case ARC_BT_MISS:
1323                         {
1324                                 this.beam_color = beamcolor;
1325                                 this.beam_alpha = 0.5;
1326                                 this.beam_thickness = 8;
1327                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1328                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1329                                 this.beam_hitlight[0] = 0;
1330                                 this.beam_hitlight[1] = 1;
1331                                 this.beam_hitlight[2] = 1;
1332                                 this.beam_hitlight[3] = 1;
1333                                 this.beam_muzzleeffect = EFFECT_Null;
1334                                 this.beam_muzzlelight[0] = 0;
1335                                 this.beam_muzzlelight[1] = 1;
1336                                 this.beam_muzzlelight[2] = 1;
1337                                 this.beam_muzzlelight[3] = 1;
1338                                 this.beam_image = "particles/lgbeam";
1339                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1340                                 {
1341                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1342                                         flash.alpha = this.beam_alpha;
1343                                         flash.colormod = this.beam_color;
1344                                         flash.scale = 0.35;
1345                                 }
1346                                 break;
1347                         }
1348                         case ARC_BT_WALL: // grenadelauncher_muzzleflash healray_muzzleflash
1349                         {
1350                                 this.beam_color = beamcolor;
1351                                 this.beam_alpha = 0.5;
1352                                 this.beam_thickness = 8;
1353                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1354                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1355                                 this.beam_hitlight[0] = 0;
1356                                 this.beam_hitlight[1] = 1;
1357                                 this.beam_hitlight[2] = 1;
1358                                 this.beam_hitlight[3] = 1;
1359                                 this.beam_muzzleeffect = EFFECT_Null; // (EFFECT_GRENADE_MUZZLEFLASH);
1360                                 this.beam_muzzlelight[0] = 0;
1361                                 this.beam_muzzlelight[1] = 1;
1362                                 this.beam_muzzlelight[2] = 1;
1363                                 this.beam_muzzlelight[3] = 1;
1364                                 this.beam_image = "particles/lgbeam";
1365                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1366                                 {
1367                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1368                                         flash.alpha = this.beam_alpha;
1369                                         flash.colormod = this.beam_color;
1370                                         flash.scale = 0.35;
1371                                 }
1372                                 break;
1373                         }
1374                         case ARC_BT_HEAL:
1375                         {
1376                                 this.beam_color = beamcolor;
1377                                 this.beam_alpha = 0.5;
1378                                 this.beam_thickness = 8;
1379                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1380                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT);
1381                                 this.beam_hitlight[0] = 0;
1382                                 this.beam_hitlight[1] = 1;
1383                                 this.beam_hitlight[2] = 1;
1384                                 this.beam_hitlight[3] = 1;
1385                                 this.beam_muzzleeffect = EFFECT_Null;
1386                                 this.beam_muzzlelight[0] = 0;
1387                                 this.beam_muzzlelight[1] = 1;
1388                                 this.beam_muzzlelight[2] = 1;
1389                                 this.beam_muzzlelight[3] = 1;
1390                                 this.beam_image = "particles/lgbeam";
1391                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1392                                 {
1393                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1394                                         flash.alpha = this.beam_alpha;
1395                                         flash.colormod = this.beam_color;
1396                                         flash.scale = 0.35;
1397                                 }
1398                                 break;
1399                         }
1400                         case ARC_BT_HIT:
1401                         {
1402                                 this.beam_color = beamcolor;
1403                                 this.beam_alpha = 0.5;
1404                                 this.beam_thickness = 8;
1405                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1406                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1407                                 this.beam_hitlight[0] = 20;
1408                                 this.beam_hitlight[1] = 1;
1409                                 this.beam_hitlight[2] = 0;
1410                                 this.beam_hitlight[3] = 0;
1411                                 this.beam_muzzleeffect = EFFECT_Null;
1412                                 this.beam_muzzlelight[0] = 50;
1413                                 this.beam_muzzlelight[1] = 1;
1414                                 this.beam_muzzlelight[2] = 0;
1415                                 this.beam_muzzlelight[3] = 0;
1416                                 this.beam_image = "particles/lgbeam";
1417                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1418                                 {
1419                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1420                                         flash.alpha = this.beam_alpha;
1421                                         flash.colormod = this.beam_color;
1422                                         flash.scale = 0.35;
1423                                 }
1424                                 break;
1425                         }
1426                         case ARC_BT_BURST_MISS:
1427                         {
1428                                 this.beam_color = beamcolor;
1429                                 this.beam_alpha = 0.5;
1430                                 this.beam_thickness = 14;
1431                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1432                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1433                                 this.beam_hitlight[0] = 0;
1434                                 this.beam_hitlight[1] = 1;
1435                                 this.beam_hitlight[2] = 1;
1436                                 this.beam_hitlight[3] = 1;
1437                                 this.beam_muzzleeffect = EFFECT_Null;
1438                                 this.beam_muzzlelight[0] = 0;
1439                                 this.beam_muzzlelight[1] = 1;
1440                                 this.beam_muzzlelight[2] = 1;
1441                                 this.beam_muzzlelight[3] = 1;
1442                                 this.beam_image = "particles/lgbeam";
1443                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1444                                 {
1445                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1446                                         flash.alpha = this.beam_alpha;
1447                                         flash.colormod = this.beam_color;
1448                                         flash.scale = 0.35;
1449                                 }
1450                                 break;
1451                         }
1452                         case ARC_BT_BURST_WALL:
1453                         {
1454                                 this.beam_color = beamcolor;
1455                                 this.beam_alpha = 0.5;
1456                                 this.beam_thickness = 14;
1457                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1458                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1459                                 this.beam_hitlight[0] = 0;
1460                                 this.beam_hitlight[1] = 1;
1461                                 this.beam_hitlight[2] = 1;
1462                                 this.beam_hitlight[3] = 1;
1463                                 this.beam_muzzleeffect = EFFECT_Null;
1464                                 this.beam_muzzlelight[0] = 0;
1465                                 this.beam_muzzlelight[1] = 1;
1466                                 this.beam_muzzlelight[2] = 1;
1467                                 this.beam_muzzlelight[3] = 1;
1468                                 this.beam_image = "particles/lgbeam";
1469                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1470                                 {
1471                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1472                                         flash.alpha = this.beam_alpha;
1473                                         flash.colormod = this.beam_color;
1474                                         flash.scale = 0.35;
1475                                 }
1476                                 break;
1477                         }
1478                         case ARC_BT_BURST_HEAL:
1479                         {
1480                                 this.beam_color = beamcolor;
1481                                 this.beam_alpha = 0.5;
1482                                 this.beam_thickness = 14;
1483                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1484                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT2);
1485                                 this.beam_hitlight[0] = 0;
1486                                 this.beam_hitlight[1] = 1;
1487                                 this.beam_hitlight[2] = 1;
1488                                 this.beam_hitlight[3] = 1;
1489                                 this.beam_muzzleeffect = EFFECT_Null;
1490                                 this.beam_muzzlelight[0] = 0;
1491                                 this.beam_muzzlelight[1] = 1;
1492                                 this.beam_muzzlelight[2] = 1;
1493                                 this.beam_muzzlelight[3] = 1;
1494                                 this.beam_image = "particles/lgbeam";
1495                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1496                                 {
1497                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1498                                         flash.alpha = this.beam_alpha;
1499                                         flash.colormod = this.beam_color;
1500                                         flash.scale = 0.35;
1501                                 }
1502                                 break;
1503                         }
1504                         case ARC_BT_BURST_HIT:
1505                         {
1506                                 this.beam_color = beamcolor;
1507                                 this.beam_alpha = 0.5;
1508                                 this.beam_thickness = 14;
1509                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1510                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1511                                 this.beam_hitlight[0] = 0;
1512                                 this.beam_hitlight[1] = 1;
1513                                 this.beam_hitlight[2] = 1;
1514                                 this.beam_hitlight[3] = 1;
1515                                 this.beam_muzzleeffect = EFFECT_Null;
1516                                 this.beam_muzzlelight[0] = 0;
1517                                 this.beam_muzzlelight[1] = 1;
1518                                 this.beam_muzzlelight[2] = 1;
1519                                 this.beam_muzzlelight[3] = 1;
1520                                 this.beam_image = "particles/lgbeam";
1521                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1522                                 {
1523                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1524                                         flash.alpha = this.beam_alpha;
1525                                         flash.colormod = this.beam_color;
1526                                         flash.scale = 0.35;
1527                                 }
1528                                 break;
1529                         }
1530
1531                         // shouldn't be possible, but lets make it colorful if it does :D
1532                         default:
1533                         {
1534                                 this.beam_color = randomvec();
1535                                 this.beam_alpha = 1;
1536                                 this.beam_thickness = 8;
1537                                 this.beam_traileffect = NULL;
1538                                 this.beam_hiteffect = NULL;
1539                                 this.beam_hitlight[0] = 0;
1540                                 this.beam_hitlight[1] = 1;
1541                                 this.beam_hitlight[2] = 1;
1542                                 this.beam_hitlight[3] = 1;
1543                                 this.beam_muzzleeffect = EFFECT_Null;
1544                                 this.beam_muzzlelight[0] = 0;
1545                                 this.beam_muzzlelight[1] = 1;
1546                                 this.beam_muzzlelight[2] = 1;
1547                                 this.beam_muzzlelight[3] = 1;
1548                                 this.beam_image = "particles/lgbeam";
1549                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1550                                 {
1551                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1552                                         flash.alpha = this.beam_alpha;
1553                                         flash.colormod = this.beam_color;
1554                                         flash.scale = 0.35;
1555                                 }
1556                                 break;
1557                         }
1558                 }
1559         }
1560
1561         if(!this.beam_usevieworigin)
1562         {
1563                 InterpolateOrigin_Note(this);
1564         }
1565         return true;
1566 }
1567
1568 #endif