qcsrc/common/weapons/w_seeker.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ SEEKER,
   4 /* function */ W_Seeker,
   5 /* ammotype */ ammo_rockets,
   6 /* impulse  */ 8,
   7 /* flags    */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_MID,
   9 /* color        */ '0.5 1 0',
  10 /* model    */ "seeker",
  11 /* netname  */ "seeker",
  12 /* fullname */ _("T.A.G. Seeker")
  13 );
  14
  15 #define SEEKER_SETTINGS(w_cvar,w_prop) SEEKER_SETTINGS_LIST(w_cvar, w_prop, SEEKER, seeker)
  16 #define SEEKER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  17         w_cvar(id, sn, NONE, type) \
  18         w_cvar(id, sn, NONE, flac_ammo) \
  19         w_cvar(id, sn, NONE, flac_animtime) \
  20         w_cvar(id, sn, NONE, flac_damage) \
  21         w_cvar(id, sn, NONE, flac_edgedamage) \
  22         w_cvar(id, sn, NONE, flac_force) \
  23         w_cvar(id, sn, NONE, flac_lifetime) \
  24         w_cvar(id, sn, NONE, flac_lifetime_rand) \
  25         w_cvar(id, sn, NONE, flac_radius) \
  26         w_cvar(id, sn, NONE, flac_refire) \
  27         w_cvar(id, sn, NONE, flac_speed) \
  28         w_cvar(id, sn, NONE, flac_speed_up) \
  29         w_cvar(id, sn, NONE, flac_speed_z) \
  30         w_cvar(id, sn, NONE, flac_spread) \
  31         w_cvar(id, sn, NONE, missile_accel) \
  32         w_cvar(id, sn, NONE, missile_ammo) \
  33         w_cvar(id, sn, NONE, missile_animtime) \
  34         w_cvar(id, sn, NONE, missile_count) \
  35         w_cvar(id, sn, NONE, missile_damage) \
  36         w_cvar(id, sn, NONE, missile_damageforcescale) \
  37         w_cvar(id, sn, NONE, missile_decel) \
  38         w_cvar(id, sn, NONE, missile_delay) \
  39         w_cvar(id, sn, NONE, missile_edgedamage) \
  40         w_cvar(id, sn, NONE, missile_force) \
  41         w_cvar(id, sn, NONE, missile_health) \
  42         w_cvar(id, sn, NONE, missile_lifetime) \
  43         w_cvar(id, sn, NONE, missile_proxy) \
  44         w_cvar(id, sn, NONE, missile_proxy_delay) \
  45         w_cvar(id, sn, NONE, missile_proxy_maxrange) \
  46         w_cvar(id, sn, NONE, missile_radius) \
  47         w_cvar(id, sn, NONE, missile_refire) \
  48         w_cvar(id, sn, NONE, missile_smart) \
  49         w_cvar(id, sn, NONE, missile_smart_mindist) \
  50         w_cvar(id, sn, NONE, missile_smart_trace_max) \
  51         w_cvar(id, sn, NONE, missile_smart_trace_min) \
  52         w_cvar(id, sn, NONE, missile_speed) \
  53         w_cvar(id, sn, NONE, missile_speed_max) \
  54         w_cvar(id, sn, NONE, missile_speed_up) \
  55         w_cvar(id, sn, NONE, missile_speed_z) \
  56         w_cvar(id, sn, NONE, missile_spread) \
  57         w_cvar(id, sn, NONE, missile_turnrate) \
  58         w_cvar(id, sn, NONE, tag_ammo) \
  59         w_cvar(id, sn, NONE, tag_animtime) \
  60         w_cvar(id, sn, NONE, tag_damageforcescale) \
  61         w_cvar(id, sn, NONE, tag_health) \
  62         w_cvar(id, sn, NONE, tag_lifetime) \
  63         w_cvar(id, sn, NONE, tag_refire) \
  64         w_cvar(id, sn, NONE, tag_speed) \
  65         w_cvar(id, sn, NONE, tag_spread) \
  66         w_cvar(id, sn, NONE, tag_tracker_lifetime) \
  67         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  68         w_prop(id, sn, float,  reloading_time, reload_time) \
  69         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  70         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  71         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  72         w_prop(id, sn, float,  weaponstart, weaponstart) \
  73         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  74
  75 #ifdef SVQC
  76 SEEKER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  77 .entity tag_target, wps_tag_tracker;
  78 .float tag_time;
  79 #endif
  80 #else
  81 #ifdef SVQC
  82 void spawnfunc_weapon_seeker (void) { weapon_defaultspawnfunc(WEP_SEEKER); }
  83
  84 // ============================
  85 // Begin: Missile functions, these are general functions to be manipulated by other code
  86 // ============================
  87 void W_Seeker_Missile_Explode()
  88 {
  89         self.event_damage = func_null;
  90         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), world, world, WEP_CVAR(seeker, missile_force), self.projectiledeathtype, other);
  91
  92         remove (self);
  93 }
  94
  95 void W_Seeker_Missile_Touch()
  96 {
  97         PROJECTILE_TOUCH;
  98
  99         W_Seeker_Missile_Explode();
 100 }
 101
 102 void W_Seeker_Missile_Think()
 103 {
 104         entity e;
 105         vector desireddir, olddir, newdir, eorg;
 106         float turnrate;
 107         float dist;
 108         float spd;
 109
 110         if (time > self.cnt)
 111         {
 112                 self.projectiledeathtype |= HITTYPE_SPLASH;
 113                 W_Seeker_Missile_Explode();
 114         }
 115
 116         spd = vlen(self.velocity);
 117         spd = bound(
 118                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
 119                 WEP_CVAR(seeker, missile_speed_max),
 120                 spd + WEP_CVAR(seeker, missile_accel) * frametime
 121         );
 122
 123         if (self.enemy != world)
 124                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 125                         self.enemy = world;
 126
 127         if (self.enemy != world)
 128         {
 129                 e               = self.enemy;
 130                 eorg            = 0.5 * (e.absmin + e.absmax);
 131                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
 132                 desireddir      = normalize(eorg - self.origin);
 133                 olddir          = normalize(self.velocity); // get my current direction
 134                 dist            = vlen(eorg - self.origin);
 135
 136                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 137                 if (WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
 138                 {
 139                         // Is it a better idea (shorter distance) to trace to the target itself?
 140                         if ( vlen(self.origin + olddir * self.wait) < dist)
 141                                 traceline(self.origin, self.origin + olddir * self.wait, FALSE, self);
 142                         else
 143                                 traceline(self.origin, eorg, FALSE, self);
 144
 145                         // Setup adaptive tracelength
 146                         self.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = WEP_CVAR(seeker, missile_smart_trace_max));
 147
 148                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 149                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 150                 }
 151
 152                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 153                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 154         }
 155         else
 156                 dist = 0;
 157
 158         // Proxy
 159         if (WEP_CVAR(seeker, missile_proxy))
 160         {
 161                 if ( dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
 162                 {
 163                         if (self.autoswitch == 0)
 164                         {
 165                                 self.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
 166                         }
 167                         else
 168                         {
 169                                 if (self.autoswitch <= time)
 170                                 {
 171                                         W_Seeker_Missile_Explode();
 172                                         self.autoswitch = 0;
 173                                 }
 174                         }
 175                 }
 176                 else
 177                 {
 178                         if (self.autoswitch != 0)
 179                                 self.autoswitch = 0;
 180                 }
 181         }
 182         ///////////////
 183
 184         if (self.enemy.deadflag != DEAD_NO)
 185         {
 186                 self.enemy = world;
 187                 self.cnt = time + 1 + (random() * 4);
 188                 self.nextthink = self.cnt;
 189                 return;
 190         }
 191
 192         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 193         self.nextthink = time;// + 0.05; // csqc projectiles
 194         UpdateCSQCProjectile(self);
 195 }
 196
 197
 198
 199 void W_Seeker_Missile_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 200 {
 201         if (self.health <= 0)
 202                 return;
 203
 204         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 205                 return; // g_projectiles_damage says to halt
 206
 207         if (self.realowner == attacker)
 208                 self.health = self.health - (damage * 0.25);
 209         else
 210                 self.health = self.health - damage;
 211
 212         if (self.health <= 0)
 213                 W_PrepareExplosionByDamage(attacker, W_Seeker_Missile_Explode);
 214 }
 215
 216 /*
 217 void W_Seeker_Missile_Animate()
 218 {
 219         self.frame = self.frame +1;
 220         self.nextthink = time + 0.05;
 221
 222         if (self.enemy != world)
 223                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 224                         self.enemy = world;
 225
 226         if(self.frame == 5)
 227         {
 228                 self.think           = W_Seeker_Missile_Think;
 229                 self.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 230
 231                 if (autocvar_g_balance_seeker_missile_proxy)
 232                         self.movetype    = MOVETYPE_BOUNCEMISSILE;
 233                 else
 234                         self.movetype    = MOVETYPE_FLYMISSILE;
 235         }
 236
 237         UpdateCSQCProjectile(self);
 238 }
 239 */
 240
 241 void W_Seeker_Fire_Missile(vector f_diff, entity m_target)
 242 {
 243         entity missile;
 244
 245         W_DecreaseAmmo(WEP_CVAR(seeker, missile_ammo));
 246
 247         makevectors(self.v_angle);
 248         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/seeker_fire.wav", CH_WEAPON_A, 0);
 249         w_shotorg += f_diff;
 250         pointparticles(particleeffectnum("seeker_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 251
 252         //self.detornator         = FALSE;
 253
 254         missile                 = spawn();
 255         missile.owner           = missile.realowner = self;
 256         missile.classname       = "seeker_missile";
 257         missile.bot_dodge       = TRUE;
 258         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 259
 260         missile.think           = W_Seeker_Missile_Think;
 261         missile.touch           = W_Seeker_Missile_Touch;
 262         missile.event_damage    = W_Seeker_Missile_Damage;
 263         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 264         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 265         missile.enemy           = m_target;
 266         missile.solid           = SOLID_BBOX;
 267         missile.scale           = 2;
 268         missile.takedamage      = DAMAGE_YES;
 269         missile.health          = WEP_CVAR(seeker, missile_health);
 270         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 271         missile.damagedbycontents = TRUE;
 272         //missile.think           = W_Seeker_Missile_Animate; // csqc projectiles.
 273
 274         if (missile.enemy != world)
 275                 missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 276         else
 277                 missile.projectiledeathtype = WEP_SEEKER;
 278
 279
 280         setorigin (missile, w_shotorg);
 281         setsize (missile, '-4 -4 -4', '4 4 4');
 282         missile.movetype    = MOVETYPE_FLYMISSILE;
 283         missile.flags       = FL_PROJECTILE;
 284         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 285
 286         WEP_SPV_UP_NONE(missile, seeker, missile_);
 287
 288         missile.angles = vectoangles (missile.velocity);
 289
 290         CSQCProjectile(missile, FALSE, PROJECTILE_SEEKER, TRUE);
 291
 292         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 293 }
 294
 295 // ============================
 296 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 297 // ============================
 298 void W_Seeker_Flac_Explode()
 299 {
 300         self.event_damage = func_null;
 301
 302         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), world, world, WEP_CVAR(seeker, flac_force), self.projectiledeathtype, other);
 303
 304         remove (self);
 305 }
 306
 307 void W_Seeker_Flac_Touch()
 308 {
 309         PROJECTILE_TOUCH;
 310
 311         W_Seeker_Flac_Explode();
 312 }
 313
 314 void W_Seeker_Fire_Flac()
 315 {
 316         entity missile;
 317         vector f_diff;
 318         float c;
 319
 320         W_DecreaseAmmo(WEP_CVAR(seeker, flac_ammo));
 321
 322         c = mod(self.bulletcounter, 4);
 323         switch(c)
 324         {
 325                 case 0:
 326                         f_diff = '-1.25 -3.75 0';
 327                         break;
 328                 case 1:
 329                         f_diff = '+1.25 -3.75 0';
 330                         break;
 331                 case 2:
 332                         f_diff = '-1.25 +3.75 0';
 333                         break;
 334                 case 3:
 335                 default:
 336                         f_diff = '+1.25 +3.75 0';
 337                         break;
 338         }
 339         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/flac_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
 340         w_shotorg += f_diff;
 341
 342         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 343
 344         missile                                 = spawn ();
 345         missile.owner                   = missile.realowner = self;
 346         missile.classname               = "missile";
 347         missile.bot_dodge               = TRUE;
 348         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 349         missile.touch                   = W_Seeker_Flac_Explode;
 350         missile.use                     = W_Seeker_Flac_Explode;
 351         missile.think                   = adaptor_think2use_hittype_splash;
 352         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 353         missile.solid                   = SOLID_BBOX;
 354         missile.movetype                = MOVETYPE_FLY;
 355         missile.projectiledeathtype = WEP_SEEKER;
 356         missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 357         missile.flags                           = FL_PROJECTILE;
 358         missile.missile_flags       = MIF_SPLASH;
 359
 360         // csqc projectiles
 361         //missile.angles                                = vectoangles (missile.velocity);
 362         //missile.scale = 0.4; // BUG: the model is too big
 363
 364         setorigin (missile, w_shotorg);
 365         setsize (missile, '-2 -2 -2', '2 2 2');
 366
 367         WEP_SPV_UP_NONE(missile, seeker, flac_);
 368         CSQCProjectile(missile, TRUE, PROJECTILE_FLAC, TRUE);
 369
 370         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 371 }
 372
 373 // ============================
 374 // Begin: Tag and rocket controllers
 375 // ============================
 376 entity W_Seeker_Tagged_Info(entity isowner, entity istarget)
 377 {
 378         entity tag;
 379         for(tag = world; (tag = find(tag, classname, "tag_tracker")); )
 380                 if ((tag.realowner == isowner) && (tag.tag_target == istarget))
 381                         return tag;
 382
 383         return world;
 384 }
 385
 386 void W_Seeker_Attack()
 387 {
 388         entity tracker, closest_target;
 389
 390         closest_target = world;
 391         for(tracker = world; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == self)
 392         {
 393                 if (closest_target)
 394                 {
 395                         if (vlen(self.origin - tracker.tag_target.origin) < vlen(self.origin - closest_target.origin))
 396                                 closest_target = tracker.tag_target;
 397                 }
 398                 else
 399                         closest_target = tracker.tag_target;
 400         }
 401
 402         traceline(self.origin + self.view_ofs, closest_target.origin, MOVE_NOMONSTERS, self);
 403         if ((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
 404                 closest_target = world;
 405
 406         W_Seeker_Fire_Missile('0 0 0', closest_target);
 407 }
 408
 409 void W_Seeker_Vollycontroller_Think() // TODO: Merge this with W_Seeker_Attack
 410 {
 411         float c;
 412         entity oldself,oldenemy;
 413         self.cnt = self.cnt - 1;
 414
 415         if((!(self.realowner.items & IT_UNLIMITED_AMMO) && self.realowner.AMMO_VAL(WEP_SEEKER) < WEP_CVAR(seeker, missile_ammo)) || (self.cnt <= -1) || (self.realowner.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER))
 416         {
 417                 remove(self);
 418                 return;
 419         }
 420
 421         self.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor();
 422
 423         oldself = self;
 424         self = self.realowner;
 425
 426         oldenemy = self.enemy;
 427         self.enemy = oldself.enemy;
 428
 429         c = mod(self.cnt, 4);
 430         switch(c)
 431         {
 432                 case 0:
 433                         W_Seeker_Fire_Missile('-1.25 -3.75 0', self.enemy);
 434                         break;
 435                 case 1:
 436                         W_Seeker_Fire_Missile('+1.25 -3.75 0', self.enemy);
 437                         break;
 438                 case 2:
 439                         W_Seeker_Fire_Missile('-1.25 +3.75 0', self.enemy);
 440                         break;
 441                 case 3:
 442                 default:
 443                         W_Seeker_Fire_Missile('+1.25 +3.75 0', self.enemy);
 444                         break;
 445         }
 446
 447         self.enemy = oldenemy;
 448         self = oldself;
 449 }
 450
 451 void W_Seeker_Tracker_Think()
 452 {
 453         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 454         if ((self.realowner.deadflag != DEAD_NO) || (self.tag_target.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER)
 455         || (time > self.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 456         {
 457                 if (self)
 458                 {
 459                         WaypointSprite_Kill(self.tag_target.wps_tag_tracker);
 460                         remove(self);
 461                 }
 462                 return;
 463         }
 464
 465         // Update the think method information
 466         self.nextthink = time;
 467 }
 468
 469 // ============================
 470 // Begin: Tag projectile
 471 // ============================
 472 void W_Seeker_Tag_Explode()
 473 {
 474         //if(other==self.realowner)
 475         //    return;
 476         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE, other.species, self);
 477
 478         remove (self);
 479 }
 480
 481 void W_Seeker_Tag_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 482 {
 483         if (self.health <= 0)
 484                 return;
 485         self.health = self.health - damage;
 486         if (self.health <= 0)
 487                 W_Seeker_Tag_Explode();
 488 }
 489
 490 void W_Seeker_Tag_Touch()
 491 {
 492         vector dir;
 493         vector org2;
 494         entity e;
 495
 496         PROJECTILE_TOUCH;
 497
 498         dir     = normalize (self.realowner.origin - self.origin);
 499         org2    = findbetterlocation (self.origin, 8);
 500
 501         te_knightspike(org2);
 502
 503         self.event_damage = func_null;
 504         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE | HITTYPE_SECONDARY, other.species, self);
 505
 506         if (other.takedamage == DAMAGE_AIM && other.deadflag == DEAD_NO)
 507         {
 508                 // check to see if this person is already tagged by me
 509                 entity tag = W_Seeker_Tagged_Info(self.realowner, other);
 510
 511                 if (tag != world)
 512                 {
 513                         if (other.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 514                                 WaypointSprite_Kill(other.wps_tag_tracker);
 515
 516                         tag.tag_time = time;
 517                 }
 518                 else
 519                 {
 520                         //sprint(self.realowner, strcat("You just tagged ^2", other.netname, "^7 with a tracking device!\n"));
 521                         e             = spawn();
 522                         e.cnt         = WEP_CVAR(seeker, missile_count);
 523                         e.classname   = "tag_tracker";
 524                         e.owner       = self.owner;
 525                         e.realowner   = self.realowner;
 526
 527                         if(WEP_CVAR(seeker, type) == 1)
 528                         {
 529                                 e.tag_target  = other;
 530                                 e.tag_time    = time;
 531                                 e.think       = W_Seeker_Tracker_Think;
 532                         }
 533                         else
 534                         {
 535                                 e.enemy     = other;
 536                                 e.think     = W_Seeker_Vollycontroller_Think;
 537                         }
 538
 539                         e.nextthink   = time;
 540                 }
 541
 542                 if(WEP_CVAR(seeker, type) == 1)
 543                 {
 544                         WaypointSprite_Spawn("tagged-target", WEP_CVAR(seeker, tag_tracker_lifetime), 0, other, '0 0 64', self.realowner, 0, other, wps_tag_tracker, TRUE, RADARICON_TAGGED, '0.5 1 0');
 545                         WaypointSprite_UpdateRule(other.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 546                 }
 547         }
 548
 549         remove(self);
 550         return;
 551 }
 552
 553 void W_Seeker_Fire_Tag()
 554 {
 555         entity missile;
 556         W_DecreaseAmmo(WEP_CVAR(seeker, tag_ammo));
 557
 558         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/tag_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
 559
 560         missile                 = spawn();
 561         missile.owner           = missile.realowner = self;
 562         missile.classname       = "seeker_tag";
 563         missile.bot_dodge       = TRUE;
 564         missile.bot_dodgerating = 50;
 565         missile.touch           = W_Seeker_Tag_Touch;
 566         missile.think           = SUB_Remove;
 567         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 568         missile.movetype        = MOVETYPE_FLY;
 569         missile.solid           = SOLID_BBOX;
 570
 571         missile.takedamage       = DAMAGE_YES;
 572         missile.event_damage     = W_Seeker_Tag_Damage;
 573         missile.health           = WEP_CVAR(seeker, tag_health);
 574         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 575
 576         setorigin (missile, w_shotorg);
 577         setsize (missile, '-2 -2 -2', '2 2 2');
 578
 579         missile.flags       = FL_PROJECTILE;
 580         //missile.missile_flags = MIF_..?;
 581
 582         missile.movetype    = MOVETYPE_FLY;
 583         WEP_SPV_NONE(missile, seeker, tag_);
 584         missile.angles = vectoangles (missile.velocity);
 585
 586         CSQCProjectile(missile, TRUE, PROJECTILE_TAG, FALSE); // has sound
 587
 588         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 589 }
 590
 591 // ============================
 592 // Begin: Genereal weapon functions
 593 // ============================
 594
 595 float W_Seeker(float req)
 596 {
 597         float ammo_amount;
 598
 599         switch(req)
 600         {
 601                 case WR_AIM:
 602                 {
 603                         if (WEP_CVAR(seeker, type) == 1)
 604                                 if (W_Seeker_Tagged_Info(self, self.enemy) != world)
 605                                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), FALSE);
 606                                 else
 607                                         self.BUTTON_ATCK2 = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 608                         else
 609                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 610                         return TRUE;
 611                 }
 612                 case WR_THINK:
 613                 {
 614                         if(autocvar_g_balance_seeker_reload_ammo && self.clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) // forced reload
 615                                 WEP_ACTION(self.weapon, WR_RELOAD);
 616
 617                         else if (self.BUTTON_ATCK)
 618                         {
 619                                 if (WEP_CVAR(seeker, type) == 1)
 620                                 {
 621                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, missile_refire)))
 622                                         {
 623                                                 W_Seeker_Attack();
 624                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 625                                         }
 626                                 }
 627                                 else
 628                                 {
 629                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 630                                         {
 631                                                 W_Seeker_Fire_Tag();
 632                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 633                                         }
 634                                 }
 635                         }
 636
 637                         else if (self.BUTTON_ATCK2)
 638                         {
 639                                 if (WEP_CVAR(seeker, type) == 1)
 640                                 {
 641                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 642                                         {
 643                                                 W_Seeker_Fire_Tag();
 644                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 645                                         }
 646                                 }
 647                                 else
 648                                 {
 649                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, flac_refire)))
 650                                         {
 651                                                 W_Seeker_Fire_Flac();
 652                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 653                                         }
 654                                 }
 655                         }
 656
 657                         return TRUE;
 658                 }
 659                 case WR_INIT:
 660                 {
 661                         precache_model ("models/weapons/g_seeker.md3");
 662                         precache_model ("models/weapons/v_seeker.md3");
 663                         precache_model ("models/weapons/h_seeker.iqm");
 664                         precache_sound ("weapons/tag_fire.wav");
 665                         precache_sound ("weapons/flac_fire.wav");
 666                         precache_sound ("weapons/seeker_fire.wav");
 667                         SEEKER_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 668                         return TRUE;
 669                 }
 670                 case WR_CHECKAMMO1:
 671                 {
 672                         if (WEP_CVAR(seeker, type) == 1)
 673                         {
 674                                 ammo_amount = self.AMMO_VAL(WEP_SEEKER) >= WEP_CVAR(seeker, missile_ammo);
 675                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, missile_ammo);
 676                         }
 677                         else
 678                         {
 679                                 ammo_amount = self.AMMO_VAL(WEP_SEEKER) >= WEP_CVAR(seeker, tag_ammo);
 680                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 681                         }
 682                         return ammo_amount;
 683                 }
 684                 case WR_CHECKAMMO2:
 685                 {
 686                         if (WEP_CVAR(seeker, type) == 1)
 687                         {
 688                                 ammo_amount = self.AMMO_VAL(WEP_SEEKER) >= WEP_CVAR(seeker, tag_ammo);
 689                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 690                         }
 691                         else
 692                         {
 693                                 ammo_amount = self.AMMO_VAL(WEP_SEEKER) >= WEP_CVAR(seeker, flac_ammo);
 694                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, flac_ammo);
 695                         }
 696                         return ammo_amount;
 697                 }
 698                 case WR_CONFIG:
 699                 {
 700                         SEEKER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 701                         return TRUE;
 702                 }
 703                 case WR_RELOAD:
 704                 {
 705                         W_Reload(min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), "weapons/reload.wav");
 706                         return TRUE;
 707                 }
 708                 case WR_SUICIDEMESSAGE:
 709                 {
 710                         return WEAPON_SEEKER_SUICIDE;
 711                 }
 712                 case WR_KILLMESSAGE:
 713                 {
 714                         if(w_deathtype & HITTYPE_SECONDARY)
 715                                 return WEAPON_SEEKER_MURDER_TAG;
 716                         else
 717                                 return WEAPON_SEEKER_MURDER_SPRAY;
 718                 }
 719         }
 720         return TRUE;
 721 }
 722 #endif
 723 #ifdef CSQC
 724 float W_Seeker(float req)
 725 {
 726         switch(req)
 727         {
 728                 case WR_IMPACTEFFECT:
 729                 {
 730                         vector org2;
 731                         org2 = w_org + w_backoff * 6;
 732                         if(w_deathtype & HITTYPE_BOUNCE)
 733                         {
 734                                 if(w_deathtype & HITTYPE_SECONDARY)
 735                                 {
 736                                         if(!w_issilent)
 737                                                 sound(self, CH_SHOTS, "weapons/tag_impact.wav", 1, ATTEN_NORM);
 738                                 }
 739                                 else
 740                                 {
 741                                         pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 742                                         if(!w_issilent)
 743                                         {
 744                                                 if (w_random<0.15)
 745                                                         sound(self, CH_SHOTS, "weapons/tagexp1.wav", 1, ATTEN_NORM);
 746                                                 else if (w_random<0.7)
 747                                                         sound(self, CH_SHOTS, "weapons/tagexp2.wav", 1, ATTEN_NORM);
 748                                                 else
 749                                                         sound(self, CH_SHOTS, "weapons/tagexp3.wav", 1, ATTEN_NORM);
 750                                         }
 751                                 }
 752                         }
 753                         else
 754                         {
 755                                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 756                                 if(!w_issilent)
 757                                 {
 758                                         if (w_random<0.15)
 759                                                 sound(self, CH_SHOTS, "weapons/seekerexp1.wav", 1, ATTEN_NORM);
 760                                         else if (w_random<0.7)
 761                                                 sound(self, CH_SHOTS, "weapons/seekerexp2.wav", 1, ATTEN_NORM);
 762                                         else
 763                                                 sound(self, CH_SHOTS, "weapons/seekerexp3.wav", 1, ATTEN_NORM);
 764                                 }
 765                         }
 766                         return TRUE;
 767                 }
 768                 case WR_INIT:
 769                 {
 770                         precache_sound("weapons/seekerexp1.wav");
 771                         precache_sound("weapons/seekerexp2.wav");
 772                         precache_sound("weapons/seekerexp3.wav");
 773                         precache_sound("weapons/tagexp1.wav");
 774                         precache_sound("weapons/tagexp2.wav");
 775                         precache_sound("weapons/tagexp3.wav");
 776                         precache_sound("weapons/tag_impact.wav");
 777                         return TRUE;
 778                 }
 779         }
 780
 781         return TRUE;
 782 }
 783 #endif
 784 #endif