qcsrc/common/weapons/w_seeker.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ SEEKER,
   4 /* function */ w_seeker,
   5 /* ammotype */ IT_ROCKETS,
   6 /* impulse  */ 8,
   7 /* flags    */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_MID,
   9 /* model    */ "seeker",
  10 /* netname  */ "seeker",
  11 /* fullname */ _("T.A.G. Seeker")
  12 );
  13
  14 #define SEEKER_SETTINGS(w_cvar,w_prop) \
  15         w_cvar(WEP_SEEKER, seeker, MO_NONE, type) \
  16         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_ammo) \
  17         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_animtime) \
  18         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_damage) \
  19         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_edgedamage) \
  20         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_force) \
  21         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_lifetime) \
  22         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_lifetime_rand) \
  23         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_radius) \
  24         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_refire) \
  25         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_speed) \
  26         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_speed_up) \
  27         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_speed_z) \
  28         w_cvar(WEP_SEEKER, seeker, MO_NONE, flac_spread) \
  29         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_accel) \
  30         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_ammo) \
  31         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_animtime) \
  32         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_count) \
  33         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_damage) \
  34         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_damageforcescale) \
  35         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_decel) \
  36         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_delay) \
  37         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_edgedamage) \
  38         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_force) \
  39         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_health) \
  40         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_lifetime) \
  41         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_proxy) \
  42         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_proxy_delay) \
  43         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_proxy_maxrange) \
  44         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_radius) \
  45         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_refire) \
  46         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_smart) \
  47         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_smart_mindist) \
  48         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_smart_trace_max) \
  49         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_smart_trace_min) \
  50         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_speed) \
  51         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_speed_max) \
  52         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_speed_up) \
  53         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_speed_z) \
  54         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_spread) \
  55         w_cvar(WEP_SEEKER, seeker, MO_NONE, missile_turnrate) \
  56         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_ammo) \
  57         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_animtime) \
  58         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_damageforcescale) \
  59         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_health) \
  60         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_lifetime) \
  61         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_refire) \
  62         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_speed) \
  63         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_spread) \
  64         w_cvar(WEP_SEEKER, seeker, MO_NONE, tag_tracker_lifetime) \
  65         w_prop(WEP_SEEKER, seeker, float,  reloading_ammo, reload_ammo) \
  66         w_prop(WEP_SEEKER, seeker, float,  reloading_time, reload_time) \
  67         w_prop(WEP_SEEKER, seeker, float,  switchdelay_raise, switchdelay_raise) \
  68         w_prop(WEP_SEEKER, seeker, float,  switchdelay_drop, switchdelay_drop)
  69
  70 #ifdef SVQC
  71 SEEKER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  72 .entity tag_target, wps_tag_tracker;
  73 .float tag_time;
  74 #endif
  75 #else
  76 #ifdef SVQC
  77 void spawnfunc_weapon_seeker (void) { weapon_defaultspawnfunc(WEP_SEEKER); }
  78
  79 // ============================
  80 // Begin: Missile functions, these are general functions to be manipulated by other code
  81 // ============================
  82 void Seeker_Missile_Explode ()
  83 {
  84         self.event_damage = func_null;
  85         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), world, world, WEP_CVAR(seeker, missile_force), self.projectiledeathtype, other);
  86
  87         remove (self);
  88 }
  89
  90 void Seeker_Missile_Touch()
  91 {
  92         PROJECTILE_TOUCH;
  93
  94         Seeker_Missile_Explode();
  95 }
  96
  97 void Seeker_Missile_Think()
  98 {
  99         entity e;
 100         vector desireddir, olddir, newdir, eorg;
 101         float turnrate;
 102         float dist;
 103         float spd;
 104
 105         if (time > self.cnt)
 106         {
 107                 self.projectiledeathtype |= HITTYPE_SPLASH;
 108                 Seeker_Missile_Explode();
 109         }
 110
 111         spd = vlen(self.velocity);
 112         spd = bound(
 113                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
 114                 WEP_CVAR(seeker, missile_speed_max),
 115                 spd + WEP_CVAR(seeker, missile_accel) * frametime
 116         );
 117
 118         if (self.enemy != world)
 119                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 120                         self.enemy = world;
 121
 122         if (self.enemy != world)
 123         {
 124                 e               = self.enemy;
 125                 eorg            = 0.5 * (e.absmin + e.absmax);
 126                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
 127                 desireddir      = normalize(eorg - self.origin);
 128                 olddir          = normalize(self.velocity); // get my current direction
 129                 dist            = vlen(eorg - self.origin);
 130
 131                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 132                 if (WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
 133                 {
 134                         // Is it a better idea (shorter distance) to trace to the target itself?
 135                         if ( vlen(self.origin + olddir * self.wait) < dist)
 136                                 traceline(self.origin, self.origin + olddir * self.wait, FALSE, self);
 137                         else
 138                                 traceline(self.origin, eorg, FALSE, self);
 139
 140                         // Setup adaptive tracelength
 141                         self.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = WEP_CVAR(seeker, missile_smart_trace_max));
 142
 143                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 144                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 145                 }
 146
 147                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 148                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 149         }
 150         else
 151                 dist = 0;
 152
 153         // Proxy
 154         if (WEP_CVAR(seeker, missile_proxy))
 155         {
 156                 if ( dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
 157                 {
 158                         if (self.autoswitch == 0)
 159                         {
 160                                 self.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
 161                         }
 162                         else
 163                         {
 164                                 if (self.autoswitch <= time)
 165                                 {
 166                                         Seeker_Missile_Explode();
 167                                         self.autoswitch = 0;
 168                                 }
 169                         }
 170                 }
 171                 else
 172                 {
 173                         if (self.autoswitch != 0)
 174                                 self.autoswitch = 0;
 175                 }
 176         }
 177         ///////////////
 178
 179         if (self.enemy.deadflag != DEAD_NO)
 180         {
 181                 self.enemy = world;
 182                 self.cnt = time + 1 + (random() * 4);
 183                 self.nextthink = self.cnt;
 184                 return;
 185         }
 186
 187         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 188         self.nextthink = time;// + 0.05; // csqc projectiles
 189         UpdateCSQCProjectile(self);
 190 }
 191
 192
 193
 194 void Seeker_Missile_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 195 {
 196         if (self.health <= 0)
 197                 return;
 198
 199         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 200                 return; // g_projectiles_damage says to halt
 201
 202         if (self.realowner == attacker)
 203                 self.health = self.health - (damage * 0.25);
 204         else
 205                 self.health = self.health - damage;
 206
 207         if (self.health <= 0)
 208                 W_PrepareExplosionByDamage(attacker, Seeker_Missile_Explode);
 209 }
 210
 211 /*
 212 void Seeker_Missile_Animate()
 213 {
 214         self.frame = self.frame +1;
 215         self.nextthink = time + 0.05;
 216
 217         if (self.enemy != world)
 218                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 219                         self.enemy = world;
 220
 221         if(self.frame == 5)
 222         {
 223                 self.think           = Seeker_Missile_Think;
 224                 self.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 225
 226                 if (autocvar_g_balance_seeker_missile_proxy)
 227                         self.movetype    = MOVETYPE_BOUNCEMISSILE;
 228                 else
 229                         self.movetype    = MOVETYPE_FLYMISSILE;
 230         }
 231
 232         UpdateCSQCProjectile(self);
 233 }
 234 */
 235
 236 void Seeker_Fire_Missile(vector f_diff, entity m_target)
 237 {
 238         entity missile;
 239
 240         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(seeker, missile_ammo), autocvar_g_balance_seeker_reload_ammo);
 241
 242         makevectors(self.v_angle);
 243         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/seeker_fire.wav", CH_WEAPON_A, 0);
 244         w_shotorg += f_diff;
 245         pointparticles(particleeffectnum("seeker_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 246
 247         //self.detornator         = FALSE;
 248
 249         missile                 = spawn();
 250         missile.owner           = missile.realowner = self;
 251         missile.classname       = "seeker_missile";
 252         missile.bot_dodge       = TRUE;
 253         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 254
 255         missile.think           = Seeker_Missile_Think;
 256         missile.touch           = Seeker_Missile_Touch;
 257         missile.event_damage    = Seeker_Missile_Damage;
 258         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 259         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 260         missile.enemy           = m_target;
 261         missile.solid           = SOLID_BBOX;
 262         missile.scale           = 2;
 263         missile.takedamage      = DAMAGE_YES;
 264         missile.health          = WEP_CVAR(seeker, missile_health);
 265         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 266         missile.damagedbycontents = TRUE;
 267         //missile.think           = Seeker_Missile_Animate; // csqc projectiles.
 268
 269         if (missile.enemy != world)
 270                 missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 271         else
 272                 missile.projectiledeathtype = WEP_SEEKER;
 273
 274
 275         setorigin (missile, w_shotorg);
 276         setsize (missile, '-4 -4 -4', '4 4 4');
 277         missile.movetype    = MOVETYPE_FLYMISSILE;
 278         missile.flags       = FL_PROJECTILE;
 279         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 280
 281         WEP_SETUPPROJVELOCITY_UP_NONE(missile, seeker, missile_);
 282
 283         missile.angles = vectoangles (missile.velocity);
 284
 285         CSQCProjectile(missile, FALSE, PROJECTILE_SEEKER, TRUE);
 286
 287         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 288 }
 289
 290 // ============================
 291 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 292 // ============================
 293 void Seeker_Flac_Explode ()
 294 {
 295         self.event_damage = func_null;
 296
 297         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), world, world, WEP_CVAR(seeker, flac_force), self.projectiledeathtype, other);
 298
 299         remove (self);
 300 }
 301
 302 void Seeker_Flac_Touch()
 303 {
 304         PROJECTILE_TOUCH;
 305
 306         Seeker_Flac_Explode();
 307 }
 308
 309 void Seeker_Fire_Flac()
 310 {
 311         entity missile;
 312         vector f_diff;
 313         float c;
 314
 315         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(seeker, flac_ammo), autocvar_g_balance_seeker_reload_ammo);
 316
 317         c = mod(self.bulletcounter, 4);
 318         switch(c)
 319         {
 320                 case 0:
 321                         f_diff = '-1.25 -3.75 0';
 322                         break;
 323                 case 1:
 324                         f_diff = '+1.25 -3.75 0';
 325                         break;
 326                 case 2:
 327                         f_diff = '-1.25 +3.75 0';
 328                         break;
 329                 case 3:
 330                 default:
 331                         f_diff = '+1.25 +3.75 0';
 332                         break;
 333         }
 334         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/flac_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
 335         w_shotorg += f_diff;
 336
 337         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 338
 339         missile                                 = spawn ();
 340         missile.owner                   = missile.realowner = self;
 341         missile.classname               = "missile";
 342         missile.bot_dodge               = TRUE;
 343         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 344         missile.touch                   = Seeker_Flac_Explode;
 345         missile.use                     = Seeker_Flac_Explode;
 346         missile.think                   = adaptor_think2use_hittype_splash;
 347         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 348         missile.solid                   = SOLID_BBOX;
 349         missile.movetype                = MOVETYPE_FLY;
 350         missile.projectiledeathtype = WEP_SEEKER;
 351         missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 352         missile.flags                           = FL_PROJECTILE;
 353         missile.missile_flags       = MIF_SPLASH;
 354
 355         // csqc projectiles
 356         //missile.angles                                = vectoangles (missile.velocity);
 357         //missile.scale = 0.4; // BUG: the model is too big
 358
 359         setorigin (missile, w_shotorg);
 360         setsize (missile, '-2 -2 -2', '2 2 2');
 361
 362         WEP_SETUPPROJVELOCITY_UP_NONE(missile, seeker, flac_);
 363         CSQCProjectile(missile, TRUE, PROJECTILE_FLAC, TRUE);
 364
 365         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 366 }
 367
 368 // ============================
 369 // Begin: Tag and rocket controllers
 370 // ============================
 371 entity Seeker_Tagged_Info(entity isowner, entity istarget)
 372 {
 373         entity tag;
 374         for(tag = world; (tag = find(tag, classname, "tag_tracker")); )
 375                 if ((tag.realowner == isowner) && (tag.tag_target == istarget))
 376                         return tag;
 377
 378         return world;
 379 }
 380
 381 void Seeker_Attack()
 382 {
 383         entity tracker, closest_target;
 384
 385         closest_target = world;
 386         for(tracker = world; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == self)
 387         {
 388                 if (closest_target)
 389                 {
 390                         if (vlen(self.origin - tracker.tag_target.origin) < vlen(self.origin - closest_target.origin))
 391                                 closest_target = tracker.tag_target;
 392                 }
 393                 else
 394                         closest_target = tracker.tag_target;
 395         }
 396
 397         traceline(self.origin + self.view_ofs, closest_target.origin, MOVE_NOMONSTERS, self);
 398         if ((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
 399                 closest_target = world;
 400
 401         Seeker_Fire_Missile('0 0 0', closest_target);
 402 }
 403
 404 void Seeker_Vollycontroller_Think() // TODO: Merge this with Seeker_Attack
 405 {
 406         float c;
 407         entity oldself,oldenemy;
 408         self.cnt = self.cnt - 1;
 409
 410         if((!(self.realowner.items & IT_UNLIMITED_AMMO) && self.realowner.ammo_rockets < WEP_CVAR(seeker, missile_ammo)) || (self.cnt <= -1) || (self.realowner.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER))
 411         {
 412                 remove(self);
 413                 return;
 414         }
 415
 416         self.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor();
 417
 418         oldself = self;
 419         self = self.realowner;
 420
 421         oldenemy = self.enemy;
 422         self.enemy = oldself.enemy;
 423
 424         c = mod(self.cnt, 4);
 425         switch(c)
 426         {
 427                 case 0:
 428                         Seeker_Fire_Missile('-1.25 -3.75 0', self.enemy);
 429                         break;
 430                 case 1:
 431                         Seeker_Fire_Missile('+1.25 -3.75 0', self.enemy);
 432                         break;
 433                 case 2:
 434                         Seeker_Fire_Missile('-1.25 +3.75 0', self.enemy);
 435                         break;
 436                 case 3:
 437                 default:
 438                         Seeker_Fire_Missile('+1.25 +3.75 0', self.enemy);
 439                         break;
 440         }
 441
 442         self.enemy = oldenemy;
 443         self = oldself;
 444 }
 445
 446 void Seeker_Tracker_Think()
 447 {
 448         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 449         if ((self.realowner.deadflag != DEAD_NO) || (self.tag_target.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER)
 450         || (time > self.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 451         {
 452                 if (self)
 453                 {
 454                         WaypointSprite_Kill(self.tag_target.wps_tag_tracker);
 455                         remove(self);
 456                 }
 457                 return;
 458         }
 459
 460         // Update the think method information
 461         self.nextthink = time;
 462 }
 463
 464 // ============================
 465 // Begin: Tag projectile
 466 // ============================
 467 void Seeker_Tag_Explode ()
 468 {
 469         //if(other==self.realowner)
 470         //    return;
 471         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE, other.species, self);
 472
 473         remove (self);
 474 }
 475
 476 void Seeker_Tag_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 477 {
 478         if (self.health <= 0)
 479                 return;
 480         self.health = self.health - damage;
 481         if (self.health <= 0)
 482                 Seeker_Tag_Explode();
 483 }
 484
 485 void Seeker_Tag_Touch()
 486 {
 487         vector dir;
 488         vector org2;
 489         entity e;
 490
 491         PROJECTILE_TOUCH;
 492
 493         dir     = normalize (self.realowner.origin - self.origin);
 494         org2    = findbetterlocation (self.origin, 8);
 495
 496         te_knightspike(org2);
 497
 498         self.event_damage = func_null;
 499         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE | HITTYPE_SECONDARY, other.species, self);
 500
 501         if (other.takedamage == DAMAGE_AIM && other.deadflag == DEAD_NO)
 502         {
 503                 // check to see if this person is already tagged by me
 504                 entity tag = Seeker_Tagged_Info(self.realowner, other);
 505
 506                 if (tag != world)
 507                 {
 508                         if (other.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 509                                 WaypointSprite_Kill(other.wps_tag_tracker);
 510
 511                         tag.tag_time = time;
 512                 }
 513                 else
 514                 {
 515                         //sprint(self.realowner, strcat("You just tagged ^2", other.netname, "^7 with a tracking device!\n"));
 516                         e             = spawn();
 517                         e.cnt         = WEP_CVAR(seeker, missile_count);
 518                         e.classname   = "tag_tracker";
 519                         e.owner       = self.owner;
 520                         e.realowner   = self.realowner;
 521
 522                         if(WEP_CVAR(seeker, type) == 1)
 523                         {
 524                                 e.tag_target  = other;
 525                                 e.tag_time    = time;
 526                                 e.think       = Seeker_Tracker_Think;
 527                         }
 528                         else
 529                         {
 530                                 e.enemy     = other;
 531                                 e.think     = Seeker_Vollycontroller_Think;
 532                         }
 533
 534                         e.nextthink   = time;
 535                 }
 536
 537                 if(WEP_CVAR(seeker, type) == 1)
 538                 {
 539                         WaypointSprite_Spawn("tagged-target", WEP_CVAR(seeker, tag_tracker_lifetime), 0, other, '0 0 64', self.realowner, 0, other, wps_tag_tracker, TRUE, RADARICON_TAGGED, '0.5 1 0');
 540                         WaypointSprite_UpdateRule(other.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 541                 }
 542         }
 543
 544         remove(self);
 545         return;
 546 }
 547
 548 void Seeker_Fire_Tag()
 549 {
 550         entity missile;
 551         W_DecreaseAmmo(ammo_rockets, WEP_CVAR(seeker, tag_ammo), autocvar_g_balance_seeker_reload_ammo);
 552
 553         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/tag_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
 554
 555         missile                 = spawn();
 556         missile.owner           = missile.realowner = self;
 557         missile.classname       = "seeker_tag";
 558         missile.bot_dodge       = TRUE;
 559         missile.bot_dodgerating = 50;
 560         missile.touch           = Seeker_Tag_Touch;
 561         missile.think           = SUB_Remove;
 562         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 563         missile.movetype        = MOVETYPE_FLY;
 564         missile.solid           = SOLID_BBOX;
 565
 566         missile.takedamage       = DAMAGE_YES;
 567         missile.event_damage     = Seeker_Tag_Damage;
 568         missile.health           = WEP_CVAR(seeker, tag_health);
 569         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 570
 571         setorigin (missile, w_shotorg);
 572         setsize (missile, '-2 -2 -2', '2 2 2');
 573
 574         missile.flags       = FL_PROJECTILE;
 575         //missile.missile_flags = MIF_..?;
 576
 577         missile.movetype    = MOVETYPE_FLY;
 578         WEP_SETUPPROJVELOCITY_NONE(missile, seeker, tag_);
 579         missile.angles = vectoangles (missile.velocity);
 580
 581         CSQCProjectile(missile, TRUE, PROJECTILE_TAG, FALSE); // has sound
 582
 583         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 584 }
 585
 586 // ============================
 587 // Begin: Genereal weapon functions
 588 // ============================
 589
 590 float w_seeker(float req)
 591 {
 592         float ammo_amount;
 593
 594         switch(req)
 595         {
 596                 case WR_AIM:
 597                 {
 598                         if (WEP_CVAR(seeker, type) == 1)
 599                                 if (Seeker_Tagged_Info(self, self.enemy) != world)
 600                                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), FALSE);
 601                                 else
 602                                         self.BUTTON_ATCK2 = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 603                         else
 604                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 605                         return TRUE;
 606                 }
 607                 case WR_THINK:
 608                 {
 609                         if(autocvar_g_balance_seeker_reload_ammo && self.clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) // forced reload
 610                                 WEP_ACTION(self.weapon, WR_RELOAD);
 611
 612                         else if (self.BUTTON_ATCK)
 613                         {
 614                                 if (WEP_CVAR(seeker, type) == 1)
 615                                 {
 616                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, missile_refire)))
 617                                         {
 618                                                 Seeker_Attack();
 619                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 620                                         }
 621                                 }
 622                                 else
 623                                 {
 624                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 625                                         {
 626                                                 Seeker_Fire_Tag();
 627                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 628                                         }
 629                                 }
 630                         }
 631
 632                         else if (self.BUTTON_ATCK2)
 633                         {
 634                                 if (WEP_CVAR(seeker, type) == 1)
 635                                 {
 636                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 637                                         {
 638                                                 Seeker_Fire_Tag();
 639                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 640                                         }
 641                                 }
 642                                 else
 643                                 {
 644                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, flac_refire)))
 645                                         {
 646                                                 Seeker_Fire_Flac();
 647                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 648                                         }
 649                                 }
 650                         }
 651
 652                         return TRUE;
 653                 }
 654                 case WR_INIT:
 655                 {
 656                         precache_model ("models/weapons/g_seeker.md3");
 657                         precache_model ("models/weapons/v_seeker.md3");
 658                         precache_model ("models/weapons/h_seeker.iqm");
 659                         precache_sound ("weapons/tag_fire.wav");
 660                         precache_sound ("weapons/flac_fire.wav");
 661                         precache_sound ("weapons/seeker_fire.wav");
 662                         SEEKER_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 663                         return TRUE;
 664                 }
 665                 case WR_SETUP:
 666                 {
 667                         self.current_ammo = ammo_rockets;
 668                         return TRUE;
 669                 }
 670                 case WR_CHECKAMMO1:
 671                 {
 672                         if (WEP_CVAR(seeker, type) == 1)
 673                         {
 674                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, missile_ammo);
 675                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, missile_ammo);
 676                         }
 677                         else
 678                         {
 679                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, tag_ammo);
 680                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 681                         }
 682                         return ammo_amount;
 683                 }
 684                 case WR_CHECKAMMO2:
 685                 {
 686                         if (WEP_CVAR(seeker, type) == 1)
 687                         {
 688                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, tag_ammo);
 689                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 690                         }
 691                         else
 692                         {
 693                                 ammo_amount = self.ammo_rockets >= WEP_CVAR(seeker, flac_ammo);
 694                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, flac_ammo);
 695                         }
 696                         return ammo_amount;
 697                 }
 698                 case WR_CONFIG:
 699                 {
 700                         SEEKER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 701                         return TRUE;
 702                 }
 703                 case WR_RELOAD:
 704                 {
 705                         W_Reload(min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), "weapons/reload.wav");
 706                         return TRUE;
 707                 }
 708                 case WR_SUICIDEMESSAGE:
 709                 {
 710                         return WEAPON_SEEKER_SUICIDE;
 711                 }
 712                 case WR_KILLMESSAGE:
 713                 {
 714                         if(w_deathtype & HITTYPE_SECONDARY)
 715                                 return WEAPON_SEEKER_MURDER_TAG;
 716                         else
 717                                 return WEAPON_SEEKER_MURDER_SPRAY;
 718                 }
 719         }
 720         return TRUE;
 721 }
 722 #endif
 723 #ifdef CSQC
 724 float w_seeker(float req)
 725 {
 726         switch(req)
 727         {
 728                 case WR_IMPACTEFFECT:
 729                 {
 730                         vector org2;
 731                         org2 = w_org + w_backoff * 6;
 732                         if(w_deathtype & HITTYPE_BOUNCE)
 733                         {
 734                                 if(w_deathtype & HITTYPE_SECONDARY)
 735                                 {
 736                                         if(!w_issilent)
 737                                                 sound(self, CH_SHOTS, "weapons/tag_impact.wav", 1, ATTEN_NORM);
 738                                 }
 739                                 else
 740                                 {
 741                                         pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 742                                         if(!w_issilent)
 743                                         {
 744                                                 if (w_random<0.15)
 745                                                         sound(self, CH_SHOTS, "weapons/tagexp1.wav", 1, ATTEN_NORM);
 746                                                 else if (w_random<0.7)
 747                                                         sound(self, CH_SHOTS, "weapons/tagexp2.wav", 1, ATTEN_NORM);
 748                                                 else
 749                                                         sound(self, CH_SHOTS, "weapons/tagexp3.wav", 1, ATTEN_NORM);
 750                                         }
 751                                 }
 752                         }
 753                         else
 754                         {
 755                                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 756                                 if(!w_issilent)
 757                                 {
 758                                         if (w_random<0.15)
 759                                                 sound(self, CH_SHOTS, "weapons/seekerexp1.wav", 1, ATTEN_NORM);
 760                                         else if (w_random<0.7)
 761                                                 sound(self, CH_SHOTS, "weapons/seekerexp2.wav", 1, ATTEN_NORM);
 762                                         else
 763                                                 sound(self, CH_SHOTS, "weapons/seekerexp3.wav", 1, ATTEN_NORM);
 764                                 }
 765                         }
 766                         return TRUE;
 767                 }
 768                 case WR_INIT:
 769                 {
 770                         precache_sound("weapons/seekerexp1.wav");
 771                         precache_sound("weapons/seekerexp2.wav");
 772                         precache_sound("weapons/seekerexp3.wav");
 773                         precache_sound("weapons/tagexp1.wav");
 774                         precache_sound("weapons/tagexp2.wav");
 775                         precache_sound("weapons/tagexp3.wav");
 776                         precache_sound("weapons/tag_impact.wav");
 777                         return TRUE;
 778                 }
 779         }
 780
 781         return TRUE;
 782 }
 783 #endif
 784 #endif