qcsrc/common/triggers/func/breakable.qc

   1 #ifdef SVQC
   2 #include "../../../server/weapons/common.qh"
   3 #include "../../../server/_all.qh"
   4
   5 .entity sprite;
   6
   7 .float dmg;
   8 .float dmg_edge;
   9 .float dmg_radius;
  10 .float dmg_force;
  11 .float debrismovetype;
  12 .float debrissolid;
  13 .vector debrisvelocity;
  14 .vector debrisvelocityjitter;
  15 .vector debrisavelocityjitter;
  16 .float debristime;
  17 .float debristimejitter;
  18 .float debrisfadetime;
  19 .float debrisdamageforcescale;
  20 .float debrisskin;
  21
  22 .string mdl_dead; // or "" to hide when broken
  23 .string debris; // space separated list of debris models
  24 // other fields:
  25 //   mdl = particle effect name
  26 //   count = particle effect multiplier
  27 //   targetname = target to trigger to unbreak the model
  28 //   target = targets to trigger when broken
  29 //   health = amount of damage it can take
  30 //   spawnflags:
  31 //     1 = start disabled (needs to be triggered to activate)
  32 //     2 = indicate damage
  33 // notes:
  34 //   for mdl_dead to work, origin must be set (using a common/origin brush).
  35 //   Otherwise mdl_dead will be displayed at the map origin, and nobody would
  36 //   want that!
  37
  38 void func_breakable_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force);
  39
  40 //
  41 // func_breakable
  42 // - basically func_assault_destructible for general gameplay use
  43 //
  44 void LaunchDebris (string debrisname, vector force)
  45 {
  46         entity dbr = spawn();
  47         setorigin(dbr, self.absmin
  48                    + '1 0 0' * random() * (self.absmax.x - self.absmin.x)
  49                    + '0 1 0' * random() * (self.absmax.y - self.absmin.y)
  50                    + '0 0 1' * random() * (self.absmax.z - self.absmin.z));
  51         setmodel (dbr, debrisname );
  52         dbr.skin = self.debrisskin;
  53         dbr.colormap = self.colormap; // inherit team colors
  54         dbr.owner = self; // do not be affected by our own explosion
  55         dbr.movetype = self.debrismovetype;
  56         dbr.solid = self.debrissolid;
  57         if(dbr.solid != SOLID_BSP) // SOLID_BSP has exact collision, MAYBE this works? TODO check this out
  58                 setsize(dbr, '0 0 0', '0 0 0'); // needed for performance, until engine can deal better with it
  59         dbr.velocity_x = self.debrisvelocity.x + self.debrisvelocityjitter.x * crandom();
  60         dbr.velocity_y = self.debrisvelocity.y + self.debrisvelocityjitter.y * crandom();
  61         dbr.velocity_z = self.debrisvelocity.z + self.debrisvelocityjitter.z * crandom();
  62         self.velocity = self.velocity + force * self.debrisdamageforcescale;
  63         dbr.avelocity_x = random()*self.debrisavelocityjitter.x;
  64         dbr.avelocity_y = random()*self.debrisavelocityjitter.y;
  65         dbr.avelocity_z = random()*self.debrisavelocityjitter.z;
  66         dbr.damageforcescale = self.debrisdamageforcescale;
  67         if(dbr.damageforcescale)
  68                 dbr.takedamage = DAMAGE_YES;
  69         SUB_SetFade(dbr, time + self.debristime + crandom() * self.debristimejitter, self.debrisfadetime);
  70 }
  71
  72 void func_breakable_colormod()
  73 {
  74         float h;
  75         if (!(self.spawnflags & 2))
  76                 return;
  77         h = self.health / self.max_health;
  78         if(h < 0.25)
  79                 self.colormod = '1 0 0';
  80         else if(h <= 0.75)
  81                 self.colormod = '1 0 0' + '0 1 0' * (2 * h - 0.5);
  82         else
  83                 self.colormod = '1 1 1';
  84
  85         CSQCMODEL_AUTOUPDATE();
  86 }
  87
  88 void func_breakable_look_destroyed()
  89 {
  90         float floorZ;
  91
  92         if(self.solid == SOLID_BSP) // in case a misc_follow moved me, save the current origin first
  93                 self.dropped_origin = self.origin;
  94
  95         if(self.mdl_dead == "")
  96                 self.effects |= EF_NODRAW;
  97         else {
  98                 if (self.origin == '0 0 0')     {       // probably no origin brush, so don't spawn in the middle of the map..
  99                         floorZ = self.absmin.z;
 100                         setorigin(self,((self.absmax+self.absmin)*.5));
 101                         self.origin_z = floorZ;
 102                 }
 103                 setmodel(self, self.mdl_dead);
 104                 self.effects &= ~EF_NODRAW;
 105         }
 106
 107         CSQCMODEL_AUTOUPDATE();
 108
 109         self.solid = SOLID_NOT;
 110 }
 111
 112 void func_breakable_look_restore()
 113 {
 114         setmodel(self, self.mdl);
 115         self.effects &= ~EF_NODRAW;
 116
 117         if(self.mdl_dead != "") // only do this if we use mdl_dead, to behave better with misc_follow
 118                 setorigin(self, self.dropped_origin);
 119
 120         CSQCMODEL_AUTOUPDATE();
 121
 122         self.solid = SOLID_BSP;
 123 }
 124
 125 void func_breakable_behave_destroyed()
 126 {
 127         self.health = self.max_health;
 128         self.takedamage = DAMAGE_NO;
 129         self.bot_attack = false;
 130         self.event_damage = func_null;
 131         self.state = 1;
 132         func_breakable_colormod();
 133         if (self.noise1)
 134                 stopsound (self, CH_TRIGGER_SINGLE);
 135 }
 136
 137 void func_breakable_behave_restore()
 138 {
 139         self.health = self.max_health;
 140         if(self.sprite)
 141         {
 142                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 143                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 144         }
 145         self.takedamage = DAMAGE_AIM;
 146         self.bot_attack = true;
 147         self.event_damage = func_breakable_damage;
 148         self.state = 0;
 149         self.nextthink = 0; // cancel auto respawn
 150         func_breakable_colormod();
 151         if (self.noise1)
 152                 sound (self, CH_TRIGGER_SINGLE, self.noise1, VOL_BASE, ATTEN_NORM);
 153 }
 154
 155 void func_breakable_init_for_player(entity player)
 156 {
 157         if (self.noise1 && self.state == 0 && clienttype(player) == CLIENTTYPE_REAL)
 158         {
 159                 msg_entity = player;
 160                 soundto (MSG_ONE, self, CH_TRIGGER_SINGLE, self.noise1, VOL_BASE, ATTEN_NORM);
 161         }
 162 }
 163
 164 void func_breakable_destroyed()
 165 {
 166         func_breakable_look_destroyed();
 167         func_breakable_behave_destroyed();
 168
 169         CSQCMODEL_AUTOUPDATE();
 170 }
 171
 172 void func_breakable_restore()
 173 {
 174         func_breakable_look_restore();
 175         func_breakable_behave_restore();
 176
 177         CSQCMODEL_AUTOUPDATE();
 178 }
 179
 180 vector debrisforce; // global, set before calling this
 181 void func_breakable_destroy() {
 182         float n, i;
 183         string oldmsg;
 184
 185         activator = self.owner;
 186         self.owner = world; // set by W_PrepareExplosionByDamage
 187
 188         // now throw around the debris
 189         n = tokenize_console(self.debris);
 190         for(i = 0; i < n; ++i)
 191                 LaunchDebris(argv(i), debrisforce);
 192
 193         func_breakable_destroyed();
 194
 195         if(self.noise)
 196                 sound (self, CH_TRIGGER, self.noise, VOL_BASE, ATTEN_NORM);
 197
 198         if(self.dmg)
 199                 RadiusDamage(self, activator, self.dmg, self.dmg_edge, self.dmg_radius, self, world, self.dmg_force, DEATH_HURTTRIGGER, world);
 200
 201         if(self.cnt)
 202                 pointparticles(self.cnt, self.absmin * 0.5 + self.absmax * 0.5, '0 0 0', self.count);
 203
 204         if(self.respawntime)
 205         {
 206                 self.think = func_breakable_restore;
 207                 self.nextthink = time + self.respawntime + crandom() * self.respawntimejitter;
 208         }
 209
 210         oldmsg = self.message;
 211         self.message = "";
 212         SUB_UseTargets();
 213         self.message = oldmsg;
 214 }
 215
 216 void func_breakable_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 217 {
 218         if(self.state == 1)
 219                 return;
 220         if(self.spawnflags & DOOR_NOSPLASH)
 221                 if(!(DEATH_ISSPECIAL(deathtype)) && (deathtype & HITTYPE_SPLASH))
 222                         return;
 223         if(self.team)
 224                 if(attacker.team == self.team)
 225                         return;
 226         self.health = self.health - damage;
 227         if(self.sprite)
 228         {
 229                 WaypointSprite_Ping(self.sprite);
 230                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 231         }
 232         func_breakable_colormod();
 233
 234         if(self.health <= 0)
 235         {
 236                 debrisforce = force;
 237                 W_PrepareExplosionByDamage(attacker, func_breakable_destroy);
 238         }
 239 }
 240
 241 void func_breakable_reset()
 242 {
 243         self.team = self.team_saved;
 244         func_breakable_look_restore();
 245         if(self.spawnflags & 1)
 246                 func_breakable_behave_destroyed();
 247         else
 248                 func_breakable_behave_restore();
 249
 250         CSQCMODEL_AUTOUPDATE();
 251 }
 252
 253 // destructible walls that can be used to trigger target_objective_decrease
 254 void spawnfunc_func_breakable()
 255 {
 256         float n, i;
 257         if(!self.health)
 258                 self.health = 100;
 259         self.max_health = self.health;
 260
 261         // yes, I know, MOVETYPE_NONE is not available here, not that one would want it here anyway
 262         if(!self.debrismovetype) self.debrismovetype = MOVETYPE_BOUNCE;
 263         if(!self.debrissolid) self.debrissolid = SOLID_NOT;
 264         if(self.debrisvelocity == '0 0 0') self.debrisvelocity = '0 0 140';
 265         if(self.debrisvelocityjitter == '0 0 0') self.debrisvelocityjitter = '70 70 70';
 266         if(self.debrisavelocityjitter == '0 0 0') self.debrisavelocityjitter = '600 600 600';
 267         if(!self.debristime) self.debristime = 3.5;
 268         if(!self.debristimejitter) self.debristime = 2.5;
 269
 270         if(self.mdl != "")
 271                 self.cnt = particleeffectnum(self.mdl);
 272         if(self.count == 0)
 273                 self.count = 1;
 274
 275         if(self.message == "")
 276                 self.message = "got too close to an explosion";
 277         if(self.message2 == "")
 278                 self.message2 = "was pushed into an explosion by";
 279         if(!self.dmg_radius)
 280                 self.dmg_radius = 150;
 281         if(!self.dmg_force)
 282                 self.dmg_force = 200;
 283
 284         self.mdl = self.model;
 285         SetBrushEntityModel();
 286
 287         self.use = func_breakable_restore;
 288
 289         // precache all the models
 290         if (self.mdl_dead)
 291                 precache_model(self.mdl_dead);
 292         n = tokenize_console(self.debris);
 293         for(i = 0; i < n; ++i)
 294                 precache_model(argv(i));
 295         if(self.noise)
 296                 precache_sound(self.noise);
 297         if(self.noise1)
 298                 precache_sound(self.noise1);
 299
 300         self.team_saved = self.team;
 301         self.dropped_origin = self.origin;
 302
 303         self.reset = func_breakable_reset;
 304         func_breakable_reset();
 305
 306         self.init_for_player_needed = 1;
 307         self.init_for_player = func_breakable_init_for_player;
 308
 309         CSQCMODEL_AUTOINIT();
 310 }
 311
 312 // for use in maps with a "model" key set
 313 void spawnfunc_misc_breakablemodel() {
 314         spawnfunc_func_breakable();
 315 }
 316 #endif